CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 #
   8 #   - OCT-2008: Initial version <joseluisblancoc@gmail.com>
   9 #
  10 # ----------------------------------------------------------------------------
  11
  12 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  13
  14 # --------------------------------------------------------------
  15 # Indicate CMake 2.7 and above that we don't want to mix relative
  16 #  and absolute paths in linker lib lists.
  17 # Run "cmake --help-policy CMP0003" for more information.
  18 # --------------------------------------------------------------
  19 if(COMMAND cmake_policy)
  20   cmake_policy(SET CMP0003 NEW)
  21 endif()
  22
  23 # Following block can broke build in case of cross-compilng
  24 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  25 # so we will try to detect crosscompiling by presense of CMAKE_TOOLCHAIN_FILE
  26 if(NOT CMAKE_TOOLCHAIN_FILE)
  27   # it _must_ go before project(OpenCV) in order to work
  28   if(WIN32)
  29     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  30   else()
  31     set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  32   endif()
  33
  34   if(MSVC)
  35     set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
  36   endif()
  37 else(NOT CMAKE_TOOLCHAIN_FILE)
  38   #Android: set output folder to ${CMAKE_BINARY_DIR}
  39   set( LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  40   # any crosscompiling
  41   set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  42 endif(NOT CMAKE_TOOLCHAIN_FILE)
  43
  44 # --------------------------------------------------------------
  45 # Top level OpenCV project
  46 # --------------------------------------------------------------
  47 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  48   cmake_minimum_required(VERSION 2.8.8)
  49 elseif(IOS)
  50   cmake_minimum_required(VERSION 2.8.0)
  51 else()
  52   cmake_minimum_required(VERSION 2.6.3)
  53 endif()
  54
  55 # must go before the project command
  56 set(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  57 if(DEFINED CMAKE_BUILD_TYPE AND CMAKE_VERSION VERSION_GREATER "2.8")
  58   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
  59 endif()
  60
  61 project(OpenCV CXX C)
  62
  63 include(cmake/OpenCVUtils.cmake REQUIRED)
  64
  65 # ----------------------------------------------------------------------------
  66 # Break in case of popular CMake configuration mistakes
  67 # ----------------------------------------------------------------------------
  68 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
  69   message(FATAL_ERROR "CMake fails to deterimine the bitness of target platform.
  70   Please check your CMake and compiler installation. If you are crosscompiling then ensure that your CMake toolchain file correctly sets the compiler details.")
  71 endif()
  72
  73 # ----------------------------------------------------------------------------
  74 # Detect compiler and target platform architecture
  75 # ----------------------------------------------------------------------------
  76 include(cmake/OpenCVDetectCXXCompiler.cmake REQUIRED)
  77
  78 # Add these standard paths to the search paths for FIND_LIBRARY
  79 # to find libraries from these locations first
  80 if(UNIX AND NOT ANDROID)
  81   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
  82     if(EXISTS /lib64)
  83       list(APPEND CMAKE_LIBRARY_PATH /lib64)
  84     else()
  85       list(APPEND CMAKE_LIBRARY_PATH /lib)
  86     endif()
  87     if(EXISTS /usr/lib64)
  88       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
  89     else()
  90       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
  91     endif()
  92   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
  93     if(EXISTS /lib32)
  94       list(APPEND CMAKE_LIBRARY_PATH /lib32)
  95     else()
  96       list(APPEND CMAKE_LIBRARY_PATH /lib)
  97     endif()
  98     if(EXISTS /usr/lib32)
  99       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 100     else()
 101       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 102     endif()
 103   endif()
 104 endif()
 105
 106
 107 # ----------------------------------------------------------------------------
 108 # OpenCV cmake options
 109 # ----------------------------------------------------------------------------
 110
 111 # Optional 3rd party components
 112 # ===================================================
 113 OCV_OPTION(WITH_1394           "Include IEEE1394 support"                    ON   IF (UNIX AND NOT ANDROID AND NOT IOS) )
 114 OCV_OPTION(WITH_AVFOUNDATION   "Use AVFoundation for Video I/O"              ON   IF IOS)
 115 OCV_OPTION(WITH_CARBON         "Use Carbon for UI instead of Cocoa"          OFF  IF APPLE )
 116 OCV_OPTION(WITH_CUBLAS         "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" OFF IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 117 OCV_OPTION(WITH_CUDA           "Include NVidia Cuda Runtime support"         ON   IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 118 OCV_OPTION(WITH_CUFFT          "Include NVidia Cuda Fast Fourier Transform (FFT) library support"            ON  IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 119 OCV_OPTION(WITH_EIGEN          "Include Eigen2/Eigen3 support"               ON)
 120 OCV_OPTION(WITH_FFMPEG         "Include FFMPEG support"                      ON   IF (NOT ANDROID AND NOT IOS) )
 121 OCV_OPTION(WITH_GSTREAMER      "Include Gstreamer support"                   ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 122 OCV_OPTION(WITH_GTK            "Include GTK support"                         ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 123 OCV_OPTION(WITH_IMAGEIO        "ImageIO support for OS X"                    OFF  IF APPLE)
 124 OCV_OPTION(WITH_IPP            "Include Intel IPP support"                   OFF  IF (MSVC OR X86 OR X86_64) )
 125 OCV_OPTION(WITH_JASPER         "Include JPEG2K support"                      ON   IF (NOT IOS) )
 126 OCV_OPTION(WITH_JPEG           "Include JPEG support"                        ON   IF (NOT IOS) )
 127 OCV_OPTION(WITH_OPENEXR        "Include ILM support via OpenEXR"             ON   IF (NOT IOS) )
 128 OCV_OPTION(WITH_OPENGL         "Include OpenGL support"                      OFF  IF (NOT ANDROID AND NOT APPLE) )
 129 OCV_OPTION(WITH_OPENNI         "Include OpenNI support"                      OFF  IF (NOT ANDROID AND NOT IOS) )
 130 OCV_OPTION(WITH_PNG            "Include PNG support"                         ON   IF (NOT IOS) )
 131 OCV_OPTION(WITH_PVAPI          "Include Prosilica GigE support"              ON   IF (NOT ANDROID AND NOT IOS) )
 132 OCV_OPTION(WITH_QT             "Build with Qt Backend support"               OFF  IF (NOT ANDROID AND NOT IOS) )
 133 OCV_OPTION(WITH_QUICKTIME      "Use QuickTime for Video I/O insted of QTKit" OFF  IF APPLE )
 134 OCV_OPTION(WITH_TBB            "Include Intel TBB support"                   OFF  IF (NOT IOS) )
 135 OCV_OPTION(WITH_TIFF           "Include TIFF support"                        ON   IF (NOT IOS) )
 136 OCV_OPTION(WITH_UNICAP         "Include Unicap support (GPL)"                OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 137 OCV_OPTION(WITH_V4L            "Include Video 4 Linux support"               ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 138 OCV_OPTION(WITH_VIDEOINPUT     "Build HighGUI with DirectShow support"       ON   IF WIN32 )
 139 OCV_OPTION(WITH_XIMEA          "Include XIMEA cameras support"               OFF  IF (NOT ANDROID AND NOT APPLE) )
 140 OCV_OPTION(WITH_XINE           "Include Xine support (GPL)"                  OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 141 OCV_OPTION(WITH_CLP            "Include Clp support (EPL)"                   OFF)
 142 OCV_OPTION(WITH_OPENCL         "Include OpenCL Runtime support"              OFF  IF (NOT ANDROID AND NOT IOS) )
 143 OCV_OPTION(WITH_OPENCLAMDFFT   "Include AMD OpenCL FFT library support"      OFF  IF (NOT ANDROID AND NOT IOS) )
 144 OCV_OPTION(WITH_OPENCLAMDBLAS  "Include AMD OpenCL BLAS library support"     OFF  IF (NOT ANDROID AND NOT IOS) )
 145
 146
 147 # OpenCV build components
 148 # ===================================================
 149 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR IOS) )
 150 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 151 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" ON )
 152 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 153 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON )
 154 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     ON  IF (NOT IOS) )
 155 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           ON  IF (NOT IOS) )
 156 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into debug libs (not MSCV only)" ON )
 157 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of staticaly linked CRT for staticaly linked OpenCV" ON IF MSVC )
 158 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create fat java wrapper containing the whole OpenCV library" ON IF ANDROID AND NOT BUILD_SHARED_LIBS AND CMAKE_COMPILER_IS_GNUCXX )
 159 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID AND ANDROID_USE_STLPORT AND ANDROID_SOURCE_TREE )
 160 OCV_OPTION(BUILD_ANDROID_PACKAGE    "Build platform-specific package for Google Play" OFF IF ANDROID )
 161
 162
 163 # 3rd party libs
 164 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"         WIN32 OR IOS OR APPLE )
 165 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"      WIN32 OR IOS OR ANDROID OR APPLE )
 166 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"    WIN32 OR IOS OR ANDROID OR APPLE )
 167 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"      WIN32 OR IOS OR ANDROID OR APPLE )
 168 OCV_OPTION(BUILD_PNG                "Build libpng from source"       WIN32 OR IOS OR ANDROID OR APPLE )
 169
 170 # OpenCV installation options
 171 # ===================================================
 172 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 173 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 174 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF  IF ANDROID )
 175 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT IOS AND BUILD_SHARED_LIBS) )
 176
 177
 178 if(MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode)
 179   set(ENABLE_SOLUTION_FOLDERS0 ON)
 180 else()
 181   set(ENABLE_SOLUTION_FOLDERS0 OFF)
 182 endif()
 183
 184 # OpenCV build options
 185 # ===================================================
 186 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON   IF (NOT IOS) )
 187 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        ${ENABLE_SOLUTION_FOLDERS0} IF (CMAKE_VERSION VERSION_GREATER "2.8.0") )
 188 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CMAKE_COMPILER_IS_GNUCXX )
 189 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CMAKE_COMPILER_IS_GNUCXX )
 190 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CMAKE_COMPILER_IS_GNUCXX AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 191 OCV_OPTION(ENABLE_FAST_MATH           "Enable -ffast-math (not recommended for GCC 4.6.x)"       OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 192 OCV_OPTION(ENABLE_SSE                 "Enable SSE instructions"                                  ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 193 OCV_OPTION(ENABLE_SSE2                "Enable SSE2 instructions"                                 ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 194 OCV_OPTION(ENABLE_SSE3                "Enable SSE3 instructions"                                 ON   IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 195 OCV_OPTION(ENABLE_SSSE3               "Enable SSSE3 instructions"                                OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 196 OCV_OPTION(ENABLE_SSE41               "Enable SSE4.1 instructions"                               OFF  IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 197 OCV_OPTION(ENABLE_SSE42               "Enable SSE4.2 instructions"                               OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 198 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 199 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 200
 201
 202 # uncategorized options
 203 # ===================================================
 204 OCV_OPTION(CMAKE_VERBOSE "Verbose mode" OFF )
 205
 206 # backward compatibility
 207 # ===================================================
 208 include(cmake/OpenCVLegacyOptions.cmake OPTIONAL)
 209
 210
 211 # ----------------------------------------------------------------------------
 212 #  Get actual OpenCV version number from sources
 213 # ----------------------------------------------------------------------------
 214 include(cmake/OpenCVVersion.cmake REQUIRED)
 215
 216
 217 # ----------------------------------------------------------------------------
 218 #  Build & install layouts
 219 # ----------------------------------------------------------------------------
 220
 221 # Save libs and executables in the same place
 222 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications" )
 223
 224 if(ANDROID OR WIN32)
 225     set(OPENCV_DOC_INSTALL_PATH doc)
 226 elseif(INSTALL_TO_MANGLED_PATHS)
 227     set(OPENCV_DOC_INSTALL_PATH share/OpenCV-${OPENCV_VERSION}/doc)
 228 else()
 229     set(OPENCV_DOC_INSTALL_PATH share/OpenCV/doc)
 230 endif()
 231
 232 if(ANDROID)
 233     set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 234     set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 235     set(OPENCV_LIB_INSTALL_PATH     sdk/native/libs/${ANDROID_NDK_ABI_NAME})
 236     set(OPENCV_3P_LIB_INSTALL_PATH  sdk/native/3rdparty/libs/${ANDROID_NDK_ABI_NAME})
 237     set(OPENCV_CONFIG_INSTALL_PATH  sdk/native/jni)
 238     set(OPENCV_INCLUDE_INSTALL_PATH sdk/native/jni/include)
 239 else()
 240     set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib")
 241     set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib${LIB_SUFFIX}")
 242     set(OPENCV_LIB_INSTALL_PATH     lib${LIB_SUFFIX})
 243     set(OPENCV_3P_LIB_INSTALL_PATH  share/OpenCV/3rdparty/${OPENCV_LIB_INSTALL_PATH})
 244     set(OPENCV_INCLUDE_INSTALL_PATH include)
 245
 246     math(EXPR SIZEOF_VOID_P_BITS "8 * ${CMAKE_SIZEOF_VOID_P}")
 247     if(LIB_SUFFIX AND NOT SIZEOF_VOID_P_BITS EQUAL LIB_SUFFIX)
 248       set(OPENCV_CONFIG_INSTALL_PATH lib${LIB_SUFFIX}/cmake/opencv)
 249     else()
 250       set(OPENCV_CONFIG_INSTALL_PATH share/OpenCV)
 251     endif()
 252 endif()
 253
 254 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 255 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 256
 257 if(INSTALL_TO_MANGLED_PATHS)
 258   set(OPENCV_INCLUDE_INSTALL_PATH ${OPENCV_INCLUDE_INSTALL_PATH}/opencv-${OPENCV_VERSION})
 259 endif()
 260
 261 if(WIN32)
 262   # Postfix of DLLs:
 263   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 264   set(OPENCV_DEBUG_POSTFIX d)
 265 else()
 266   # Postfix of so's:
 267   set(OPENCV_DLLVERSION "")
 268   set(OPENCV_DEBUG_POSTFIX "")
 269 endif()
 270
 271 if(DEFINED CMAKE_DEBUG_POSTFIX)
 272   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 273 endif()
 274
 275 if(CMAKE_VERBOSE)
 276   set(CMAKE_VERBOSE_MAKEFILE 1)
 277 endif()
 278
 279
 280 # ----------------------------------------------------------------------------
 281 #  Path for build/platform -specific headers
 282 # ----------------------------------------------------------------------------
 283 set(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 284 add_definitions(-DHAVE_CVCONFIG_H)
 285 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 286
 287
 288 # ----------------------------------------------------------------------------
 289 #  Autodetect if we are in a GIT repository
 290 # ----------------------------------------------------------------------------
 291
 292 # don't use FindGit because it requires CMake 2.8.2
 293 set(git_names git eg) # eg = easy git
 294 # Prefer .cmd variants on Windows unless running in a Makefile in the MSYS shell
 295 if(WIN32)
 296   if(NOT CMAKE_GENERATOR MATCHES "MSYS")
 297     set(git_names git.cmd git eg.cmd eg)
 298   endif()
 299 endif()
 300
 301 find_host_program(GIT_EXECUTABLE NAMES ${git_names} PATH_SUFFIXES Git/cmd Git/bin DOC "git command line client")
 302 mark_as_advanced(GIT_EXECUTABLE)
 303
 304 if(GIT_EXECUTABLE)
 305   execute_process(COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
 306     WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 307     OUTPUT_VARIABLE OPENCV_GIT_HASH_SORT
 308     RESULT_VARIABLE GIT_RESULT
 309     ERROR_QUIET
 310     OUTPUT_STRIP_TRAILING_WHITESPACE
 311   )
 312   if(GIT_RESULT EQUAL 0)
 313     set(OPENCV_VCSVERSION "commit:${OPENCV_GIT_HASH_SORT}")
 314   else()
 315     set(OPENCV_VCSVERSION "exported")
 316   endif()
 317 else()
 318   # We don't have git:
 319   set(OPENCV_VCSVERSION "")
 320 endif()
 321
 322
 323 # ----------------------------------------------------------------------------
 324 # OpenCV compiler and linker options
 325 # ----------------------------------------------------------------------------
 326 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 327 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 328   set(CMAKE_BUILD_TYPE Release)
 329 endif()
 330
 331 include(cmake/OpenCVCompilerOptions.cmake REQUIRED)
 332
 333
 334 # ----------------------------------------------------------------------------
 335 # Use statically or dynamically linked CRT?
 336 # Default: dynamic
 337 # ----------------------------------------------------------------------------
 338 if(MSVC)
 339   include(cmake/OpenCVCRTLinkage.cmake REQUIRED)
 340   add_definitions(-D_VARIADIC_MAX=10)
 341 endif(MSVC)
 342
 343
 344 # ----------------------------------------------------------------------------
 345 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 346 # ----------------------------------------------------------------------------
 347 if(UNIX)
 348   include(cmake/OpenCVFindPkgConfig.cmake OPTIONAL)
 349   include(CheckFunctionExists)
 350   include(CheckIncludeFile)
 351
 352   if(NOT APPLE)
 353     CHECK_INCLUDE_FILE(alloca.h HAVE_ALLOCA_H)
 354     CHECK_FUNCTION_EXISTS(alloca HAVE_ALLOCA)
 355     CHECK_INCLUDE_FILE(unistd.h HAVE_UNISTD_H)
 356     CHECK_INCLUDE_FILE(pthread.h HAVE_LIBPTHREAD)
 357     if(ANDROID)
 358       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 359     elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD|NetBSD|DragonFly")
 360       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 361     else()
 362       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 363     endif()
 364   else()
 365     add_definitions(-DHAVE_ALLOCA -DHAVE_ALLOCA_H -DHAVE_LIBPTHREAD -DHAVE_UNISTD_H)
 366   endif()
 367 endif()
 368
 369 include(cmake/OpenCVPCHSupport.cmake REQUIRED)
 370 include(cmake/OpenCVModule.cmake REQUIRED)
 371
 372 # ----------------------------------------------------------------------------
 373 #  Detect 3rd-party libraries
 374 # ----------------------------------------------------------------------------
 375
 376 include(cmake/OpenCVFindLibsGrfmt.cmake REQUIRED)
 377 include(cmake/OpenCVFindLibsGUI.cmake   REQUIRED)
 378 include(cmake/OpenCVFindLibsVideo.cmake REQUIRED)
 379 include(cmake/OpenCVFindLibsPerf.cmake  REQUIRED)
 380
 381
 382 # ----------------------------------------------------------------------------
 383 #  Detect other 3rd-party libraries/tools
 384 # ----------------------------------------------------------------------------
 385
 386 # --- LATEX for pdf documentation ---
 387 if(BUILD_DOCS)
 388   include(cmake/OpenCVFindLATEX.cmake REQUIRED)
 389 endif(BUILD_DOCS)
 390
 391 # --- Python Support ---
 392 include(cmake/OpenCVDetectPython.cmake REQUIRED)
 393
 394 # --- Java Support ---
 395 if(ANDROID)
 396   include(cmake/OpenCVDetectApacheAnt.cmake REQUIRED)
 397   include(cmake/OpenCVDetectAndroidSDK.cmake REQUIRED)
 398
 399   if(NOT ANDROID_TOOLS_Pkg_Revision GREATER 13)
 400     message(WARNING "OpenCV requires Android SDK tools revision 14 or newer. Otherwise tests and samples will no be compiled.")
 401   endif()
 402 endif(ANDROID)
 403
 404 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 405   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 406 else()
 407   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 408 endif()
 409
 410 # --- OpenCL ---
 411 if(WITH_OPENCL)
 412   include(cmake/OpenCVDetectOpenCL.cmake REQUIRED)
 413   if(OPENCL_FOUND)
 414     set(HAVE_OPENCL 1)
 415   endif()
 416   if(WITH_OPENCLAMDFFT)
 417     set(HAVE_CLAMDFFT 1)
 418   endif()
 419   if(WITH_OPENCLAMDBLAS)
 420     set(HAVE_CLAMDBLAS 1)
 421   endif()
 422 endif()
 423
 424 # ----------------------------------------------------------------------------
 425 # Solution folders:
 426 # ----------------------------------------------------------------------------
 427 if(ENABLE_SOLUTION_FOLDERS)
 428   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 429   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 430 endif()
 431
 432 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 433 include(cmake/OpenCVExtraTargets.cmake REQUIRED)
 434
 435
 436 # ----------------------------------------------------------------------------
 437 # Process subdirectories
 438 # ----------------------------------------------------------------------------
 439
 440 # opencv.hpp and legacy headers
 441 add_subdirectory(include)
 442
 443 # OpenCV modules
 444 add_subdirectory(modules)
 445
 446 # Generate targets for documentation
 447 add_subdirectory(doc)
 448
 449 # various data that is used by cv libraries and/or demo applications.
 450 add_subdirectory(data)
 451
 452 # extra applications
 453 add_subdirectory(apps)
 454
 455 # examples
 456 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES)
 457   add_subdirectory(samples)
 458 endif()
 459
 460 if(BUILD_ANDROID_SERVICE)
 461   add_subdirectory(android/service)
 462 endif()
 463
 464 if(BUILD_ANDROID_PACKAGE)
 465   add_subdirectory(android/package)
 466 endif()
 467
 468 # ----------------------------------------------------------------------------
 469 # Finalization: generate configuration-based files
 470 # ----------------------------------------------------------------------------
 471 ocv_track_build_dependencies()
 472
 473 # Generate platform-dependent and configuration-dependent headers
 474 include(cmake/OpenCVGenHeaders.cmake REQUIRED)
 475
 476 # Generate opencv.pc for pkg-config command
 477 include(cmake/OpenCVGenPkgconfig.cmake REQUIRED)
 478
 479 # Generate OpenCV.mk for ndk-build (Android build tool)
 480 include(cmake/OpenCVGenAndroidMK.cmake REQUIRED)
 481
 482 # Generate OpenCVСonfig.cmake and OpenCVConfig-version.cmake for cmake projects
 483 include(cmake/OpenCVGenConfig.cmake REQUIRED)
 484
 485
 486 # ----------------------------------------------------------------------------
 487 # Summary:
 488 # ----------------------------------------------------------------------------
 489 status("")
 490 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 491 if(OPENCV_VCSVERSION)
 492   status("  Version control:" ${OPENCV_VCSVERSION})
 493 endif()
 494
 495 # ========================== build platform ==========================
 496 status("")
 497 status("  Platform:")
 498 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
 499 if(CMAKE_CROSSCOMPILING)
 500   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
 501 endif()
 502 status("    CMake:"            ${CMAKE_VERSION})
 503 status("    CMake generator:"  ${CMAKE_GENERATOR})
 504 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
 505 if(MSVC)
 506   status("    MSVC:"           ${MSVC_VERSION})
 507 endif()
 508 if(CMAKE_GENERATOR MATCHES Xcode)
 509   status("    Xcode:"          ${XCODE_VERSION})
 510 endif()
 511 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
 512   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
 513 endif()
 514
 515 # ========================== C/C++ options ==========================
 516 status("")
 517 status("  C/C++:")
 518 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
 519 status("    C++ Compiler:"           CMAKE_COMPILER_IS_GNUCXX THEN "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_GCC_REGEX_VERSION})" ELSE "${CMAKE_CXX_COMPILER}" )
 520 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
 521 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
 522 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
 523 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
 524 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
 525 if(WIN32)
 526   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
 527   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
 528 else()
 529   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
 530   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
 531 endif()
 532 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
 533
 534 # ========================== OpenCV modules ==========================
 535 status("")
 536 status("  OpenCV modules:")
 537 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD}")
 538 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
 539 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
 540 set(OPENCV_MODULES_DISABLED_AUTO_ST "")
 541 foreach(m ${OPENCV_MODULES_DISABLED_AUTO})
 542   set(__mdeps "")
 543   foreach(d ${OPENCV_MODULE_${m}_DEPS})
 544     if(d MATCHES "^opencv_" AND NOT HAVE_${d})
 545       list(APPEND __mdeps ${d})
 546     endif()
 547   endforeach()
 548   list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}(deps: ${__mdeps})")
 549 endforeach()
 550 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO_ST}")
 551
 552 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
 553 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
 554 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
 555 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
 556
 557 # ========================== Android details ==========================
 558 if(ANDROID)
 559   status("")
 560   status("  Android: ")
 561   status("    Android ABI:" ${ANDROID_ABI})
 562   status("    Native API level:" android-${ANDROID_NATIVE_API_LEVEL})
 563   status("    SDK target:" "${ANDROID_SDK_TARGET}")
 564   if(BUILD_WITH_ANDROID_NDK)
 565     status("    Android NDK:" "${ANDROID_NDK} (toolchain: ${ANDROID_TOOLCHAIN_NAME})")
 566   elseif(BUILD_WITH_STANDALONE_TOOLCHAIN)
 567     status("    Android toolchain:" "${ANDROID_STANDALONE_TOOLCHAIN}")
 568   endif()
 569   status("    android tool:"  ANDROID_EXECUTABLE  THEN "${ANDROID_EXECUTABLE} (${ANDROID_TOOLS_Pkg_Desc})" ELSE NO)
 570   status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"            ELSE NO)
 571   status("    Google Play package:" BUILD_ANDROID_PACKAGE THEN YES ELSE NO)
 572 endif()
 573
 574 # ========================== GUI ==========================
 575 status("")
 576 status("  GUI: ")
 577
 578 if(HAVE_QT)
 579   status("    QT 4.x:"            HAVE_QT        THEN "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})" ELSE NO)
 580   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
 581 else()
 582   if(DEFINED WITH_QT)
 583     status("    QT 4.x:" NO)
 584   endif()
 585   if(WIN32)
 586     status("    Win32 UI:" YES)
 587   else()
 588     if(APPLE)
 589       if(WITH_CARBON)
 590         status("    Carbon:" YES)
 591       else()
 592         status("    Cocoa:"  YES)
 593       endif()
 594     else()
 595       status("    GTK+ 2.x:" HAVE_GTK      THEN "YES (ver ${ALIASOF_gtk+-2.0_VERSION})"     ELSE NO)
 596       status("    GThread :" HAVE_GTHREAD  THEN "YES (ver ${ALIASOF_gthread-2.0_VERSION})"  ELSE NO)
 597       status("    GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${ALIASOF_gtkglext-1.0_VERSION})" ELSE NO)
 598     endif()
 599   endif()
 600 endif()
 601
 602 status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
 603
 604 # ========================== MEDIA IO ==========================
 605 status("")
 606 status("  Media I/O: ")
 607 status("    ZLib:"         BUILD_ZLIB    THEN "build (ver ${ZLIB_VERSION_STRING})"               ELSE "${ZLIB_LIBRARY} (ver ${ZLIB_VERSION_STRING})")
 608
 609 if(WITH_JPEG)
 610   status("    JPEG:"       JPEG_FOUND    THEN "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})"        ELSE "build (ver ${JPEG_LIB_VERSION})")
 611 else()
 612   status("    JPEG:"       "NO")
 613 endif()
 614 if(WITH_PNG)
 615   status("    PNG:"        PNG_FOUND     THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})"              ELSE "build (ver ${PNG_VERSION})")
 616 else()
 617   status("    PNG:"        "NO")
 618 endif()
 619 if(WITH_TIFF)
 620   if(TIFF_VERSION_STRING AND TIFF_FOUND)
 621     status("    TIFF:"     "${TIFF_LIBRARY} (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 622   else()
 623     status("    TIFF:"     TIFF_FOUND    THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION})"            ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 624   endif()
 625 else()
 626   status("    TIFF:"       "NO")
 627 endif()
 628 if(WITH_JASPER)
 629   status("    JPEG 2000:"  JASPER_FOUND  THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
 630 else()
 631   status("    JPEG 2000:"  "NO")
 632 endif()
 633
 634 status("    OpenEXR:"   WITH_OPENEXR AND OPENEXR_FOUND     THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})"                     ELSE NO)
 635
 636 # ========================== VIDEO IO ==========================
 637 status("")
 638 status("  Video I/O:")
 639
 640 if(DEFINED WITH_1394)
 641   status("    DC1394 1.x:"     HAVE_DC1394         THEN "YES (ver ${ALIASOF_libdc1394_VERSION})"   ELSE NO)
 642   status("    DC1394 2.x:"     HAVE_DC1394_2       THEN "YES (ver ${ALIASOF_libdc1394-2_VERSION})" ELSE NO)
 643 endif(DEFINED WITH_1394)
 644
 645 if(ANDROID)
 646   if(HAVE_opencv_androidcamera)
 647     status("    AndroidNativeCamera:" BUILD_ANDROID_CAMERA_WRAPPER
 648                                                    THEN "YES, build for Android${ANDROID_VERSION}" ELSE "YES, use prebuilt libraries")
 649   else()
 650     status("    AndroidNativeCamera:" "NO (native camera requires Android API level 8 or higher)")
 651   endif()
 652 endif()
 653
 654 if(DEFINED WITH_AVFOUNDATION)
 655   status("    AVFoundation:"   WITH_AVFOUNDATION   THEN YES                                        ELSE NO)
 656 endif(DEFINED WITH_AVFOUNDATION)
 657
 658 if(DEFINED WITH_FFMPEG)
 659   if(WIN32)
 660     status("    FFMPEG:"       WITH_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
 661   else()
 662     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
 663   endif()
 664   status("      codec:"        HAVE_FFMPEG_CODEC   THEN "YES (ver ${ALIASOF_libavcodec_VERSION})"  ELSE NO)
 665   status("      format:"       HAVE_FFMPEG_FORMAT  THEN "YES (ver ${ALIASOF_libavformat_VERSION})" ELSE NO)
 666   status("      util:"         HAVE_FFMPEG_UTIL    THEN "YES (ver ${ALIASOF_libavutil_VERSION})"   ELSE NO)
 667   status("      swscale:"      HAVE_FFMPEG_SWSCALE THEN "YES (ver ${ALIASOF_libswscale_VERSION})"  ELSE NO)
 668   status("      gentoo-style:" HAVE_GENTOO_FFMPEG  THEN YES                                        ELSE NO)
 669 endif(DEFINED WITH_FFMPEG)
 670
 671 if(DEFINED WITH_GSTREAMER)
 672   status("    GStreamer:"      HAVE_GSTREAMER      THEN ""                                         ELSE NO)
 673   if(HAVE_GSTREAMER)
 674     status("      base:"       "YES (ver ${ALIASOF_gstreamer-base-0.10_VERSION})")
 675     status("      app:"        "YES (ver ${ALIASOF_gstreamer-app-0.10_VERSION})")
 676     status("      video:"      "YES (ver ${ALIASOF_gstreamer-video-0.10_VERSION})")
 677   endif()
 678 endif(DEFINED WITH_GSTREAMER)
 679
 680 if(DEFINED WITH_OPENNI)
 681   status("    OpenNI:"         HAVE_OPENNI         THEN "YES (ver ${OPENNI_VERSION_STRING}, build ${OPENNI_VERSION_BUILD})"
 682                                                                                                    ELSE NO)
 683   status("    OpenNI PrimeSensor Modules:" HAVE_OPENNI_PRIME_SENSOR_MODULE
 684                                                    THEN "YES (${OPENNI_PRIME_SENSOR_MODULE})"      ELSE NO)
 685 endif(DEFINED WITH_OPENNI)
 686
 687 if(DEFINED WITH_PVAPI)
 688   status("    PvAPI:"          HAVE_PVAPI          THEN YES                                        ELSE NO)
 689 endif(DEFINED WITH_PVAPI)
 690
 691 if(DEFINED WITH_QUICKTIME)
 692   status("    QuickTime:"      WITH_QUICKTIME      THEN YES                                        ELSE NO)
 693   status("    QTKit:"          WITH_QUICKTIME      THEN NO                                         ELSE YES)
 694 endif(DEFINED WITH_QUICKTIME)
 695
 696 if(DEFINED WITH_UNICAP)
 697   status("    UniCap:"         HAVE_UNICAP         THEN "YES (ver ${ALIASOF_libunicap_VERSION})"   ELSE NO)
 698   status("    UniCap ucil:"    HAVE_UNICAP_UCIL    THEN "YES (ver ${ALIASOF_libucil_VERSION})"     ELSE NO)
 699 endif(DEFINED WITH_UNICAP)
 700
 701 if(DEFINED WITH_V4L)
 702   if(HAVE_CAMV4L)
 703     set(HAVE_CAMV4L_STR "YES")
 704   else()
 705     set(HAVE_CAMV4L_STR "NO")
 706   endif()
 707   if(HAVE_CAMV4L2)
 708     set(HAVE_CAMV4L2_STR "YES")
 709   else()
 710     set(HAVE_CAMV4L2_STR "NO")
 711   endif()
 712   status("    V4L/V4L2:"       HAVE_LIBV4L         THEN "Using libv4l (ver ${ALIASOF_libv4l1_VERSION})"
 713                                                                                                    ELSE "${HAVE_CAMV4L_STR}/${HAVE_CAMV4L2_STR}")
 714 endif(DEFINED WITH_V4L)
 715
 716 if(DEFINED WITH_VIDEOINPUT)
 717   status("    DirectShow:"     HAVE_VIDEOINPUT     THEN YES                                        ELSE NO)
 718 endif(DEFINED WITH_VIDEOINPUT)
 719
 720 if(DEFINED WITH_XIMEA)
 721   status("    XIMEA:"          HAVE_XIMEA          THEN YES                                        ELSE NO)
 722 endif(DEFINED WITH_XIMEA)
 723
 724 if(DEFINED WITH_XINE)
 725   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${ALIASOF_libxine_VERSION})"     ELSE NO)
 726 endif(DEFINED WITH_XINE)
 727
 728 # ========================== Other third-party libraries ==========================
 729 status("")
 730 status("  Other third-party libraries:")
 731
 732 if(DEFINED WITH_IPP)
 733   if(WITH_IPP AND IPP_FOUND)
 734     status("    Use IPP:" "${IPP_LATEST_VERSION_STR} [${IPP_LATEST_VERSION_MAJOR}.${IPP_LATEST_VERSION_MINOR}.${IPP_LATEST_VERSION_BUILD}]")
 735     status("         at:" "${IPP_ROOT_DIR}")
 736   else()
 737     status("    Use IPP:"   WITH_IPP AND NOT IPP_FOUND THEN "IPP not found" ELSE NO)
 738   endif()
 739 endif(DEFINED WITH_IPP)
 740
 741 if(DEFINED WITH_TBB)
 742   status("    Use TBB:"   HAVE_TBB   THEN "YES (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})" ELSE NO)
 743 endif(DEFINED WITH_TBB)
 744
 745 if(DEFINED WITH_CUDA)
 746   status("    Use Cuda:"  HAVE_CUDA  THEN "YES (ver ${CUDA_VERSION_STRING})" ELSE NO)
 747 endif(DEFINED WITH_CUDA)
 748
 749 status("    Use OpenCL:"  HAVE_OPENCL  THEN YES ELSE NO)
 750
 751 status("    Use Eigen:" HAVE_EIGEN THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
 752 status("    Use Clp:"   HAVE_CLP   THEN YES ELSE NO)
 753
 754 if(HAVE_CUDA)
 755   status("")
 756   status("  NVIDIA CUDA:"            "(ver ${CUDA_VERSION_STRING})")
 757
 758   status("    Use CUFFT:"            HAVE_CUFFT  THEN YES ELSE NO)
 759   status("    Use CUBLAS:"           HAVE_CUBLAS THEN YES ELSE NO)
 760   status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
 761   status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
 762 endif()
 763
 764 # ========================== python ==========================
 765 status("")
 766 status("  Python:")
 767 status("    Interpreter:"   PYTHON_EXECUTABLE     THEN "${PYTHON_EXECUTABLE} (ver ${PYTHON_VERSION_FULL})"         ELSE NO)
 768 if(BUILD_opencv_python)
 769   if(PYTHONLIBS_VERSION_STRING)
 770     status("    Libraries:"     HAVE_opencv_python  THEN  "${PYTHON_LIBRARIES} (ver ${PYTHONLIBS_VERSION_STRING})" ELSE NO)
 771   else()
 772     status("    Libraries:"     HAVE_opencv_python  THEN  ${PYTHON_LIBRARIES}                                      ELSE NO)
 773   endif()
 774   status("    numpy:"         PYTHON_USE_NUMPY    THEN "${PYTHON_NUMPY_INCLUDE_DIR} (ver ${PYTHON_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
 775   status("    packages path:" PYTHON_EXECUTABLE   THEN "${PYTHON_PACKAGES_PATH}"                                   ELSE "-")
 776 endif()
 777
 778 # ========================== documentation ==========================
 779 if(BUILD_DOCS)
 780   status("")
 781   status("  Documentation:")
 782   if(HAVE_SPHINX)
 783     status("    Build Documentation:" PDFLATEX_COMPILER      THEN YES ELSE "YES (only HTML and without math expressions)")
 784   else()
 785     status("    Build Documentation:" NO)
 786   endif()
 787   status("    Sphinx:"              HAVE_SPHINX              THEN "${SPHINX_BUILD} (ver ${SPHINX_VERSION})" ELSE NO)
 788   status("    PdfLaTeX compiler:"   PDFLATEX_COMPILER        THEN "${PDFLATEX_COMPILER}" ELSE NO)
 789 endif()
 790
 791 # ========================== samples and tests ==========================
 792 status("")
 793 status("  Tests and samples:")
 794 status("    Tests:"             BUILD_TESTS AND HAVE_opencv_ts       THEN YES ELSE NO)
 795 status("    Performance tests:" BUILD_PERF_TESTS AND HAVE_opencv_ts  THEN YES ELSE NO)
 796 status("    Examples:"          BUILD_EXAMPLES                       THEN YES ELSE NO)
 797
 798 if(ANDROID)
 799   status("    Android tests:"    BUILD_TESTS AND CAN_BUILD_ANDROID_PROJECTS            THEN YES ELSE NO)
 800   status("    Android examples:" BUILD_ANDROID_EXAMPLES AND CAN_BUILD_ANDROID_PROJECTS THEN YES ELSE NO)
 801 endif()
 802
 803 # ========================== auxiliary ==========================
 804 status("")
 805 status("  Install path:" "${CMAKE_INSTALL_PREFIX}")
 806 status("")
 807 status("  cvconfig.h is in:" "${OPENCV_CONFIG_FILE_INCLUDE_DIR}")
 808 status("-----------------------------------------------------------------")
 809 status("")
 810
 811 ocv_finalize_status()
 812
 813 # ----------------------------------------------------------------------------
 814 # Warn in the case of in-source build
 815 # ----------------------------------------------------------------------------
 816 if("${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 817   message(WARNING "The source directory is the same as binary directory. \"make clean\" may damage the source tree")
 818 endif()
 819