CMakeLists.txt

   1 # Copyright (C) 2018-2020 Intel Corporation
   2 # SPDX-License-Identifier: Apache-2.0
   3 #
   4
   5 cmake_minimum_required(VERSION 3.13 FATAL_ERROR)
   6
   7 project(OpenVINO)
   8
   9 set(OpenVINO_MAIN_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  10 set(IE_MAIN_SOURCE_DIR ${OpenVINO_MAIN_SOURCE_DIR}/inference-engine)
  11 list(APPEND CMAKE_MODULE_PATH "${OpenVINO_MAIN_SOURCE_DIR}/cmake")
  12
  13 include(CTest)
  14 include(features)
  15
  16 # include developer package
  17 include(developer_package)
  18
  19 # These options are shared with 3rdparty plugins by means of developer package
  20 include(check_features)
  21 include(dependencies)
  22
  23 # resolving dependencies for the project
  24 message (STATUS "PROJECT ............................... " ${PROJECT_NAME})
  25 message (STATUS "CMAKE_BINARY_DIR ...................... " ${CMAKE_BINARY_DIR})
  26 message (STATUS "OpenVINO_MAIN_SOURCE_DIR .............. " ${OpenVINO_MAIN_SOURCE_DIR})
  27 message (STATUS "IE_MAIN_SOURCE_DIR .................... " ${IE_MAIN_SOURCE_DIR})
  28 message (STATUS "CMAKE_GENERATOR ....................... " ${CMAKE_GENERATOR})
  29 message (STATUS "CMAKE_C_COMPILER_ID ................... " ${CMAKE_C_COMPILER_ID})
  30 message (STATUS "CMAKE_BUILD_TYPE ...................... " ${CMAKE_BUILD_TYPE})
  31
  32 # remove file with exported developer targets to force its regeneration
  33 file(REMOVE "${CMAKE_BINARY_DIR}/targets_developer.cmake")
  34 file(REMOVE "${CMAKE_BINARY_DIR}/targets.cmake")
  35
  36 #
  37 # Build
  38 #
  39
  40 function(build_ngraph)
  41     function(ngraph_set option value)
  42         if(NOT DEFINED ${option})
  43             set(${option} ${value} CACHE BOOL "" FORCE)
  44         endif()
  45     endfunction()
  46
  47     set(NGRAPH_BUILD_DIR ${CMAKE_LIBRARY_OUTPUT_DIRECTORY} CACHE STRING "" FORCE)
  48     set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${OpenVINO_MAIN_SOURCE_DIR}/ngraph/cmake/Modules/")
  49
  50     if (ENABLE_SANITIZER)
  51         ngraph_set(NGRAPH_ADDRESS_SANITIZER TRUE)
  52     else ()
  53         ngraph_set(NGRAPH_ADDRESS_SANITIZER FALSE)
  54     endif ()
  55     ngraph_set(NGRAPH_PYTHON_BUILD_ENABLE FALSE)
  56
  57     if(ENABLE_TESTS AND NOT ANDROID)
  58         ngraph_set(NGRAPH_UNIT_TEST_ENABLE TRUE)
  59     else()
  60         ngraph_set(NGRAPH_UNIT_TEST_ENABLE FALSE)
  61     endif()
  62
  63     if(NOT (ANDROID OR WINDOWS_STORE OR (MSVC AND (ARM OR AARCH64)) ))
  64         ngraph_set(NGRAPH_ONNX_IMPORT_ENABLE TRUE)
  65     else()
  66         ngraph_set(NGRAPH_ONNX_IMPORT_ENABLE FALSE)
  67     endif()
  68     ngraph_set(NGRAPH_INTERPRETER_ENABLE TRUE)
  69
  70     if(CMAKE_CXX_COMPILER_ID MATCHES "^(Apple)?Clang$")
  71         ie_add_compiler_flags(-Wno-error=uninitialized -Wno-error=literal-conversion)
  72     elseif(UNIX)
  73         ie_add_compiler_flags(-Wno-error=maybe-uninitialized -Wno-error=return-type -fPIC)
  74     endif()
  75     if(ANDROID)
  76         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-error=defaulted-function-deleted -Wno-error=unused-command-line-argument")
  77     endif()
  78
  79     # WA for GCC 7.0
  80     if (UNIX)
  81         ie_add_compiler_flags(-Wno-error=return-type -Wno-undef)
  82     elseif(WIN32)
  83         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4308 /wd4146 /wd4703 /wd4244 /wd4819")
  84     endif()
  85
  86     if(ENABLE_LTO)
  87         set(CMAKE_INTERPROCEDURAL_OPTIMIZATION_RELEASE ON)
  88     endif()
  89
  90     ie_cpack_add_component(ngraph)
  91
  92     set(SDL_cmake_included ON)
  93     # set(NGRAPH_COMPONENT_PREFIX "deployment_tools/ngraph/")
  94     add_subdirectory(ngraph)
  95     set(NGRAPH_LIBRARIES ngraph PARENT_SCOPE)
  96 endfunction()
  97
  98 file(REMOVE "${CMAKE_BINARY_DIR}/openvino_targets_developer.cmake")
  99
 100 unset(OpenVINODeveloperPackageTargets CACHE)
 101
 102 function(openvino_developer_export_targets)
 103     set(OpenVINODeveloperPackageTargets "${OpenVINODeveloperPackageTargets};${ARGV}")
 104
 105     # to allow exporting of aliased targets with the original names
 106     foreach(target_name ${OpenVINODeveloperPackageTargets})
 107         if(TARGET "${target_name}")
 108             get_target_property(original_name ${target_name} ALIASED_TARGET)
 109             if(TARGET "${original_name}")
 110                 message(STATUS "The name ${target_name} is an ALIAS for ${original_name}. "
 111                         "It will be exported to the InferenceEngineDeveloperPackage with the original name.")
 112                 list(REMOVE_ITEM OpenVINODeveloperPackageTargets ${target_name})
 113                 list(APPEND OpenVINODeveloperPackageTargets ${original_name})
 114             endif()
 115         endif()
 116     endforeach()
 117
 118     list(REMOVE_DUPLICATES OpenVINODeveloperPackageTargets)
 119     set(OpenVINODeveloperPackageTargets "${OpenVINODeveloperPackageTargets}" CACHE INTERNAL
 120         "Paths to extra Inference Engine plugins" FORCE)
 121 endfunction()
 122
 123 add_subdirectory(openvino)
 124
 125 build_ngraph()
 126
 127 add_subdirectory(inference-engine)
 128
 129 add_subdirectory(model-optimizer)
 130 add_subdirectory(docs)
 131
 132 #
 133 # Shellcheck
 134 #
 135
 136 ie_shellcheck_process(DIRECTORY "${OpenVINO_MAIN_SOURCE_DIR}"
 137                       SKIP "${OpenVINO_MAIN_SOURCE_DIR}/bin"
 138                            "${OpenVINO_MAIN_SOURCE_DIR}/build"
 139                            "${IE_MAIN_SOURCE_DIR}/tests/ie_test_utils/common_test_utils/gtest"
 140                            "${IE_MAIN_SOURCE_DIR}/samples/thirdparty"
 141                            "${IE_MAIN_SOURCE_DIR}/thirdparty"
 142                            "${IE_MAIN_SOURCE_DIR}/temp"
 143                            # TODO fix and enable back:
 144                            "${OpenVINO_MAIN_SOURCE_DIR}/scripts/install_dependencies"
 145                            "${OpenVINO_MAIN_SOURCE_DIR}/scripts/demo"
 146                            "${OpenVINO_MAIN_SOURCE_DIR}/ngraph"
 147                            "${IE_MAIN_SOURCE_DIR}/scripts")
 148
 149 #
 150 # cpack
 151 #
 152
 153 # install setupvars
 154
 155 ie_cpack_add_component(setupvars REQUIRED)
 156
 157 if(UNIX)
 158     install(PROGRAMS scripts/setupvars/setupvars.sh
 159             DESTINATION bin
 160             COMPONENT setupvars)
 161 elseif(WIN32)
 162     install(PROGRAMS scripts/setupvars/setupvars.bat
 163             DESTINATION bin
 164             COMPONENT setupvars)
 165 endif()
 166
 167 # install install_dependencies
 168
 169 if(UNIX)
 170     ie_cpack_add_component(install_dependencies REQUIRED)
 171     install(DIRECTORY scripts/install_dependencies/
 172             DESTINATION install_dependencies
 173             COMPONENT install_dependencies)
 174 endif()
 175
 176 # install files for demo
 177
 178 ie_cpack_add_component(demo_scripts REQUIRED DEPENDS core)
 179
 180 if(UNIX)
 181     install(DIRECTORY scripts/demo/
 182             DESTINATION deployment_tools/demo
 183             COMPONENT demo_scripts
 184             USE_SOURCE_PERMISSIONS
 185             PATTERN *.bat EXCLUDE)
 186 elseif(WIN32)
 187     install(DIRECTORY scripts/demo/
 188             DESTINATION deployment_tools/demo
 189             COMPONENT demo_scripts
 190             USE_SOURCE_PERMISSIONS
 191             PATTERN *.sh EXCLUDE)
 192 endif()
 193
 194 ie_cpack(${IE_CPACK_COMPONENTS_ALL})