CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.10)
   2
   3 # Set a default build type if none was specified
   4 if(NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CONFIGURATION_TYPES)
   5   message(STATUS "Setting build type to 'Release' as none was specified.")
   6   set(CMAKE_BUILD_TYPE Release CACHE STRING "Choose the type of build." FORCE)
   7   # Set the possible values of build type for cmake-gui
   8   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release" "MinSizeRel" "RelWithDebInfo" "Coverage")
   9 endif()
  10
  11 project(LAPACK Fortran C)
  12
  13 set(LAPACK_MAJOR_VERSION 3)
  14 set(LAPACK_MINOR_VERSION 7)
  15 set(LAPACK_PATCH_VERSION 0)
  16 set(
  17   LAPACK_VERSION
  18   ${LAPACK_MAJOR_VERSION}.${LAPACK_MINOR_VERSION}.${LAPACK_PATCH_VERSION}
  19   )
  20
  21 include(GNUInstallDirs)
  22
  23 # Updated OSX RPATH settings
  24 # In response to CMake 3.0 generating warnings regarding policy CMP0042,
  25 # the OSX RPATH settings have been updated per recommendations found
  26 # in the CMake Wiki:
  27 #  http://www.cmake.org/Wiki/CMake_RPATH_handling#Mac_OS_X_and_the_RPATH
  28 set(CMAKE_MACOSX_RPATH ON)
  29 set(CMAKE_SKIP_BUILD_RPATH FALSE)
  30 set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
  31 list(FIND CMAKE_PLATFORM_IMPLICIT_LINK_DIRECTORIES ${CMAKE_INSTALL_FULL_LIBDIR} isSystemDir)
  32 if("${isSystemDir}" STREQUAL "-1")
  33   set(CMAKE_INSTALL_RPATH ${CMAKE_INSTALL_FULL_LIBDIR})
  34   set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  35 endif()
  36
  37
  38 # Configure the warning and code coverage suppression file
  39 configure_file(
  40   "${LAPACK_SOURCE_DIR}/CTestCustom.cmake.in"
  41   "${LAPACK_BINARY_DIR}/CTestCustom.cmake"
  42   @ONLY
  43 )
  44
  45 # Add the CMake directory for custon CMake modules
  46 set(CMAKE_MODULE_PATH "${LAPACK_SOURCE_DIR}/CMAKE" ${CMAKE_MODULE_PATH})
  47 include(PreventInSourceBuilds)
  48 include(PreventInBuildInstalls)
  49
  50 if(UNIX)
  51   if("${CMAKE_Fortran_COMPILER}" MATCHES "ifort")
  52     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -fp-model strict")
  53   endif()
  54   if("${CMAKE_Fortran_COMPILER}" MATCHES "xlf")
  55     set(CMAKE_Fortran_FLAGS "${CMAKE_Fortran_FLAGS} -qnosave -qstrict=none")
  56   endif()
  57 # Delete libmtsk in linking sequence for Sun/Oracle Fortran Compiler.
  58 # This library is not present in the Sun package SolarisStudio12.3-linux-x86-bin
  59   string(REPLACE \;mtsk\; \; CMAKE_Fortran_IMPLICIT_LINK_LIBRARIES "${CMAKE_Fortran_IMPLICIT_LINK_LIBRARIES}")
  60 endif()
  61
  62 if(CMAKE_Fortran_COMPILER_ID STREQUAL "Compaq")
  63   if(WIN32)
  64     if(CMAKE_GENERATOR STREQUAL "NMake Makefiles")
  65       get_filename_component(CMAKE_Fortran_COMPILER_CMDNAM ${CMAKE_Fortran_COMPILER} NAME_WE)
  66       message(STATUS "Using Compaq Fortran compiler with command name ${CMAKE_Fortran_COMPILER_CMDNAM}")
  67       set(cmd ${CMAKE_Fortran_COMPILER_CMDNAM})
  68       string(TOLOWER "${cmd}" cmdlc)
  69       if(cmdlc STREQUAL "df")
  70         message(STATUS "Assume the Compaq Visual Fortran Compiler is being used")
  71         set(CMAKE_Fortran_USE_RESPONSE_FILE_FOR_OBJECTS 1)
  72         set(CMAKE_Fortran_USE_RESPONSE_FILE_FOR_INCLUDES 1)
  73         #This is a workaround that is needed to avoid forward-slashes in the
  74         #filenames listed in response files from incorrectly being interpreted as
  75         #introducing compiler command options
  76         if(${BUILD_SHARED_LIBS})
  77           message(FATAL_ERROR "Making of shared libraries with CVF has not been tested.")
  78         endif()
  79         set(str "NMake version 9 or later should be used. NMake version 6.0 which is\n")
  80         set(str "${str}   included with the CVF distribution fails to build Lapack because\n")
  81         set(str "${str}   the number of source files exceeds the limit for NMake v6.0\n")
  82         message(STATUS ${str})
  83         set(CMAKE_Fortran_LINK_EXECUTABLE "LINK /out:<TARGET> <LINK_FLAGS> <LINK_LIBRARIES> <OBJECTS>")
  84       endif()
  85     endif()
  86   endif()
  87 endif()
  88
  89 # Get Python
  90 message(STATUS "Looking for Python greater than 2.6 - ${PYTHONINTERP_FOUND}")
  91 find_package(PythonInterp 2.7) # lapack_testing.py uses features from python 2.7 and greater
  92 if(PYTHONINTERP_FOUND)
  93   message(STATUS "Using Python version ${PYTHON_VERSION_STRING}")
  94 else()
  95   message(STATUS "No suitable Python version found, so skipping summary tests.")
  96 endif()
  97 # --------------------------------------------------
  98
  99 set(LAPACK_INSTALL_EXPORT_NAME lapack-targets)
 100
 101 macro(lapack_install_library lib)
 102   install(TARGETS ${lib}
 103     EXPORT ${LAPACK_INSTALL_EXPORT_NAME}
 104     ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 105     LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 106     RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 107   )
 108 endmacro()
 109
 110 set(PKG_CONFIG_DIR ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 111 set(prefix ${CMAKE_INSTALL_PREFIX})
 112 if(NOT IS_ABSOLUTE ${CMAKE_INSTALL_LIBDIR})
 113   set(libdir "\${prefix}/${CMAKE_INSTALL_LIBDIR}")
 114 else()
 115   set(libdir "${CMAKE_INSTALL_LIBDIR}")
 116 endif()
 117
 118 # --------------------------------------------------
 119 # Testing
 120
 121 enable_testing()
 122 include(CTest)
 123 enable_testing()
 124 # --------------------------------------------------
 125
 126 # Organize output files.  On Windows this also keeps .dll files next
 127 # to the .exe files that need them, making tests easy to run.
 128 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${LAPACK_BINARY_DIR}/bin)
 129 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${LAPACK_BINARY_DIR}/lib)
 130 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY ${LAPACK_BINARY_DIR}/lib)
 131
 132 # --------------------------------------------------
 133 # Check for any necessary platform specific compiler flags
 134 include(CheckLAPACKCompilerFlags)
 135 CheckLAPACKCompilerFlags()
 136
 137 string(TOUPPER ${CMAKE_BUILD_TYPE} CMAKE_BUILD_TYPE_UPPER)
 138 if(${CMAKE_BUILD_TYPE_UPPER} STREQUAL "COVERAGE")
 139   message(STATUS "Adding coverage")
 140   find_package(codecov)
 141 endif()
 142
 143 # --------------------------------------------------
 144 # Check second function
 145
 146 include(CheckTimeFunction)
 147 set(TIME_FUNC NONE ${TIME_FUNC})
 148 CHECK_TIME_FUNCTION(NONE TIME_FUNC)
 149 CHECK_TIME_FUNCTION(INT_CPU_TIME TIME_FUNC)
 150 CHECK_TIME_FUNCTION(EXT_ETIME TIME_FUNC)
 151 CHECK_TIME_FUNCTION(EXT_ETIME_ TIME_FUNC)
 152 CHECK_TIME_FUNCTION(INT_ETIME TIME_FUNC)
 153 message(STATUS "--> Will use second_${TIME_FUNC}.f and dsecnd_${TIME_FUNC}.f as timing function.")
 154
 155 set(SECOND_SRC ${LAPACK_SOURCE_DIR}/INSTALL/second_${TIME_FUNC}.f)
 156 set(DSECOND_SRC ${LAPACK_SOURCE_DIR}/INSTALL/dsecnd_${TIME_FUNC}.f)
 157
 158 # By default static library
 159 option(BUILD_SHARED_LIBS "Build shared libraries" OFF)
 160
 161 option(BUILD_TESTING "Build tests" OFF)
 162 message(STATUS "Build tests: ${BUILD_TESTING}")
 163
 164 # deprecated LAPACK and LAPACKE routines
 165 option(BUILD_DEPRECATED "Build deprecated routines" OFF)
 166 message(STATUS "Build deprecated routines: ${BUILD_DEPRECATED}")
 167
 168 # --------------------------------------------------
 169 # Precision to build
 170 # By default all precisions are generated
 171 option(BUILD_SINGLE "Build single precision real" ON)
 172 option(BUILD_DOUBLE "Build double precision real" ON)
 173 option(BUILD_COMPLEX "Build single precision complex" ON)
 174 option(BUILD_COMPLEX16 "Build double precision complex" ON)
 175 message(STATUS "Build single precision real: ${BUILD_SINGLE}")
 176 message(STATUS "Build double precision real: ${BUILD_DOUBLE}")
 177 message(STATUS "Build single precision complex: ${BUILD_COMPLEX}")
 178 message(STATUS "Build double precision complex: ${BUILD_COMPLEX16}")
 179
 180 if(NOT (BUILD_SINGLE OR BUILD_DOUBLE OR BUILD_COMPLEX OR BUILD_COMPLEX16))
 181   message(FATAL_ERROR "Nothing to build, no precision selected.
 182   Please enable at least one of these:
 183   BUILD_SINGLE, BUILD_DOUBLE, BUILD_COMPLEX, BUILD_COMPLEX16.")
 184 endif()
 185
 186 # --------------------------------------------------
 187 # Subdirectories that need to be processed
 188 option(USE_OPTIMIZED_BLAS "Whether or not to use an optimized BLAS library instead of included netlib BLAS" OFF)
 189
 190 # Check the usage of the user provided BLAS libraries
 191 if(BLAS_LIBRARIES)
 192   include(CheckFortranFunctionExists)
 193   set(CMAKE_REQUIRED_LIBRARIES ${BLAS_LIBRARIES})
 194   CHECK_FORTRAN_FUNCTION_EXISTS("dgemm" BLAS_FOUND)
 195   unset(CMAKE_REQUIRED_LIBRARIES)
 196   if(BLAS_FOUND)
 197     message(STATUS "--> BLAS supplied by user is WORKING, will use ${BLAS_LIBRARIES}.")
 198   else()
 199     message(ERROR "--> BLAS supplied by user is not WORKING, CANNOT USE ${BLAS_LIBRARIES}.")
 200     message(ERROR "-->     Will use REFERENCE BLAS (by default)")
 201     message(ERROR "-->     Or Correct your BLAS_LIBRARIES entry ")
 202     message(ERROR "-->     Or Consider checking USE_OPTIMIZED_BLAS")
 203   endif()
 204
 205 # User did not provide a BLAS Library but specified to search for one
 206 elseif(USE_OPTIMIZED_BLAS)
 207   find_package(BLAS)
 208 endif()
 209
 210 # Neither user specified or optimized BLAS libraries can be used
 211 if(NOT BLAS_FOUND)
 212   message(STATUS "Using supplied NETLIB BLAS implementation")
 213   add_subdirectory(BLAS)
 214   set(BLAS_LIBRARIES blas)
 215 else()
 216   set(CMAKE_EXE_LINKER_FLAGS
 217     "${CMAKE_EXE_LINKER_FLAGS} ${BLAS_LINKER_FLAGS}"
 218     CACHE STRING "Linker flags for executables" FORCE)
 219   set(CMAKE_MODULE_LINKER_FLAGS
 220     "${CMAKE_MODULE_LINKER_FLAGS} ${BLAS_LINKER_FLAGS}"
 221     CACHE STRING "Linker flags for modules" FORCE)
 222   set(CMAKE_SHARED_LINKER_FLAGS
 223     "${CMAKE_SHARED_LINKER_FLAGS} ${BLAS_LINKER_FLAGS}"
 224     CACHE STRING "Linker flags for shared libs" FORCE)
 225 endif()
 226
 227
 228 # --------------------------------------------------
 229 # CBLAS
 230 option(CBLAS "Build CBLAS" OFF)
 231
 232 if(CBLAS)
 233   add_subdirectory(CBLAS)
 234 endif()
 235
 236 # --------------------------------------------------
 237 # XBLAS
 238
 239 option(USE_XBLAS "Build extended precision (needs XBLAS)" OFF)
 240 if(USE_XBLAS)
 241   find_library(XBLAS_LIBRARY NAMES xblas)
 242 endif()
 243
 244 option(USE_OPTIMIZED_LAPACK "Whether or not to use an optimized LAPACK library instead of included netlib LAPACK" OFF)
 245
 246 # --------------------------------------------------
 247 # LAPACK
 248 # User did not provide a LAPACK Library but specified to search for one
 249 if(USE_OPTIMIZED_LAPACK)
 250   find_package(LAPACK)
 251 endif()
 252
 253 # Check the usage of the user provided or automatically found LAPACK libraries
 254 if(LAPACK_LIBRARIES)
 255   include(CheckFortranFunctionExists)
 256   set(CMAKE_REQUIRED_LIBRARIES ${LAPACK_LIBRARIES})
 257   # Check if new routine of 3.4.0 is in LAPACK_LIBRARIES
 258   CHECK_FORTRAN_FUNCTION_EXISTS("dgeqrt" LATESTLAPACK_FOUND)
 259   unset(CMAKE_REQUIRED_LIBRARIES)
 260   if(LATESTLAPACK_FOUND)
 261     message(STATUS "--> LAPACK supplied by user is WORKING, will use ${LAPACK_LIBRARIES}.")
 262   else()
 263     message(ERROR "--> LAPACK supplied by user is not WORKING or is older than LAPACK 3.4.0, CANNOT USE ${LAPACK_LIBRARIES}.")
 264     message(ERROR "-->     Will use REFERENCE LAPACK (by default)")
 265     message(ERROR "-->     Or Correct your LAPACK_LIBRARIES entry ")
 266     message(ERROR "-->     Or Consider checking USE_OPTIMIZED_LAPACK")
 267   endif()
 268 endif()
 269
 270 # Neither user specified or optimized LAPACK libraries can be used
 271 if(NOT LATESTLAPACK_FOUND)
 272   message(STATUS "Using supplied NETLIB LAPACK implementation")
 273   set(LAPACK_LIBRARIES lapack)
 274   add_subdirectory(SRC)
 275 else()
 276   set(CMAKE_EXE_LINKER_FLAGS
 277     "${CMAKE_EXE_LINKER_FLAGS} ${LAPACK_LINKER_FLAGS}"
 278     CACHE STRING "Linker flags for executables" FORCE)
 279   set(CMAKE_MODULE_LINKER_FLAGS
 280     "${CMAKE_MODULE_LINKER_FLAGS} ${LAPACK_LINKER_FLAGS}"
 281     CACHE STRING "Linker flags for modules" FORCE)
 282   set(CMAKE_SHARED_LINKER_FLAGS
 283     "${CMAKE_SHARED_LINKER_FLAGS} ${LAPACK_LINKER_FLAGS}"
 284     CACHE STRING "Linker flags for shared libs" FORCE)
 285 endif()
 286
 287 if(BUILD_TESTING)
 288   add_subdirectory(TESTING)
 289 endif()
 290
 291 # --------------------------------------------------
 292 # LAPACKE
 293 option(LAPACKE "Build LAPACKE" OFF)
 294
 295 # LAPACKE has also the interface to some routines from tmglib,
 296 # if LAPACKE_WITH_TMG is selected, we need to add those routines to LAPACKE
 297 option(LAPACKE_WITH_TMG "Build LAPACKE with tmglib routines" OFF)
 298 if(LAPACKE_WITH_TMG)
 299   set(LAPACKE ON)
 300 endif()
 301 if(BUILD_TESTING OR LAPACKE_WITH_TMG) #already included, avoid double inclusion
 302   add_subdirectory(TESTING/MATGEN)
 303 endif()
 304
 305 if(LAPACKE)
 306   add_subdirectory(LAPACKE)
 307 endif()
 308
 309 # --------------------------------------------------
 310 # CPACK Packaging
 311
 312 set(CPACK_PACKAGE_NAME "LAPACK")
 313 set(CPACK_PACKAGE_VENDOR "University of Tennessee, Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd")
 314 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "LAPACK- Linear Algebra Package")
 315 set(CPACK_PACKAGE_VERSION_MAJOR 3)
 316 set(CPACK_PACKAGE_VERSION_MINOR 5)
 317 set(CPACK_PACKAGE_VERSION_PATCH 0)
 318 set(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/LICENSE")
 319 set(CPACK_PACKAGE_INSTALL_DIRECTORY "LAPACK")
 320 if(WIN32 AND NOT UNIX)
 321   # There is a bug in NSI that does not handle full unix paths properly. Make
 322   # sure there is at least one set of four (4) backlasshes.
 323   set(CPACK_NSIS_HELP_LINK "http:\\\\\\\\http://icl.cs.utk.edu/lapack-forum")
 324   set(CPACK_NSIS_URL_INFO_ABOUT "http:\\\\\\\\www.netlib.org/lapack")
 325   set(CPACK_NSIS_CONTACT "lapack@eecs.utk.edu")
 326   set(CPACK_NSIS_MODIFY_PATH ON)
 327   set(CPACK_NSIS_DISPLAY_NAME "LAPACK-${LAPACK_VERSION}")
 328   set(CPACK_PACKAGE_RELOCATABLE "true")
 329 else()
 330   set(CPACK_GENERATOR "TGZ")
 331   set(CPACK_SOURCE_GENERATOR TGZ)
 332   set(CPACK_SOURCE_PACKAGE_FILE_NAME "lapack-${LAPACK_VERSION}")
 333   set(CPACK_SOURCE_IGNORE_FILES ~$ .svn ${CPACK_SOURCE_IGNORE_FILES})
 334 endif()
 335 include(CPack)
 336
 337
 338 # --------------------------------------------------
 339
 340 if(NOT BLAS_FOUND)
 341   set(ALL_TARGETS ${ALL_TARGETS} blas)
 342 endif()
 343
 344 if(NOT LATESTLAPACK_FOUND)
 345   set(ALL_TARGETS ${ALL_TARGETS} lapack)
 346 endif()
 347
 348 if(BUILD_TESTING OR LAPACKE_WITH_TMG)
 349   set(ALL_TARGETS ${ALL_TARGETS} tmglib)
 350 endif()
 351
 352 # Export lapack targets, not including lapacke, from the
 353 # install tree, if any.
 354 set(_lapack_config_install_guard_target "")
 355 if(ALL_TARGETS)
 356   install(EXPORT lapack-targets
 357     DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/lapack-${LAPACK_VERSION})
 358
 359   # Choose one of the lapack targets to use as a guard for
 360   # lapack-config.cmake to load targets from the install tree.
 361   list(GET ALL_TARGETS 0 _lapack_config_install_guard_target)
 362 endif()
 363
 364 # Include cblas in targets exported from the build tree.
 365 if(CBLAS)
 366   set(ALL_TARGETS ${ALL_TARGETS} cblas)
 367 endif()
 368
 369 # Include lapacke in targets exported from the build tree.
 370 if(LAPACKE)
 371   set(ALL_TARGETS ${ALL_TARGETS} lapacke)
 372 endif()
 373
 374 # Export lapack and lapacke targets from the build tree, if any.
 375 set(_lapack_config_build_guard_target "")
 376 if(ALL_TARGETS)
 377   export(TARGETS ${ALL_TARGETS} FILE lapack-targets.cmake)
 378
 379   # Choose one of the lapack or lapacke targets to use as a guard
 380   # for lapack-config.cmake to load targets from the build tree.
 381   list(GET ALL_TARGETS 0 _lapack_config_build_guard_target)
 382 endif()
 383
 384 configure_file(${LAPACK_SOURCE_DIR}/CMAKE/lapack-config-build.cmake.in
 385   ${LAPACK_BINARY_DIR}/lapack-config.cmake @ONLY)
 386
 387
 388 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/lapack.pc.in ${CMAKE_CURRENT_BINARY_DIR}/lapack.pc @ONLY)
 389   install(FILES
 390   ${CMAKE_CURRENT_BINARY_DIR}/lapack.pc
 391   DESTINATION ${PKG_CONFIG_DIR}
 392   )
 393
 394 configure_file(${LAPACK_SOURCE_DIR}/CMAKE/lapack-config-install.cmake.in
 395   ${LAPACK_BINARY_DIR}/CMakeFiles/lapack-config.cmake @ONLY)
 396
 397 include(CMakePackageConfigHelpers)
 398 write_basic_package_version_file(
 399   ${LAPACK_BINARY_DIR}/lapack-config-version.cmake
 400   VERSION ${LAPACK_VERSION}
 401   COMPATIBILITY SameMajorVersion
 402   )
 403
 404 install(FILES
 405   ${LAPACK_BINARY_DIR}/CMakeFiles/lapack-config.cmake
 406   ${LAPACK_BINARY_DIR}/lapack-config-version.cmake
 407   DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/lapack-${LAPACK_VERSION}
 408   )