CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 #
   8 #   - OCT-2008: Initial version <joseluisblancoc@gmail.com>
   9 #
  10 # ----------------------------------------------------------------------------
  11
  12 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  13
  14 # --------------------------------------------------------------
  15 # Indicate CMake 2.7 and above that we don't want to mix relative
  16 #  and absolute paths in linker lib lists.
  17 # Run "cmake --help-policy CMP0003" for more information.
  18 # --------------------------------------------------------------
  19 if(COMMAND cmake_policy)
  20   cmake_policy(SET CMP0003 NEW)
  21 endif()
  22
  23 # Following block can broke build in case of cross-compilng
  24 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  25 # so we will try to detect crosscompiling by presense of CMAKE_TOOLCHAIN_FILE
  26 if(NOT CMAKE_TOOLCHAIN_FILE)
  27   # it _must_ go before project(OpenCV) in order to work
  28   if(WIN32)
  29     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  30   else()
  31     set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  32   endif()
  33
  34   if(MSVC)
  35     set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
  36   endif()
  37 else(NOT CMAKE_TOOLCHAIN_FILE)
  38   #Android: set output folder to ${CMAKE_BINARY_DIR}
  39   set( LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  40   # any crosscompiling
  41   set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  42 endif(NOT CMAKE_TOOLCHAIN_FILE)
  43
  44 # --------------------------------------------------------------
  45 # Top level OpenCV project
  46 # --------------------------------------------------------------
  47 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  48   cmake_minimum_required(VERSION 2.8.8)
  49 elseif(IOS)
  50   cmake_minimum_required(VERSION 2.8.0)
  51 else()
  52   cmake_minimum_required(VERSION 2.6.3)
  53 endif()
  54
  55 # must go before the project command
  56 set(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  57 if(DEFINED CMAKE_BUILD_TYPE AND CMAKE_VERSION VERSION_GREATER "2.8")
  58   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
  59 endif()
  60
  61 project(OpenCV CXX C)
  62
  63 include(cmake/OpenCVUtils.cmake REQUIRED)
  64
  65 # ----------------------------------------------------------------------------
  66 # Break in case of popular CMake configuration mistakes
  67 # ----------------------------------------------------------------------------
  68 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
  69   message(FATAL_ERROR "CMake fails to deterimine the bitness of target platform.
  70   Please check your CMake and compiler installation. If you are crosscompiling then ensure that your CMake toolchain file correctly sets the compiler details.")
  71 endif()
  72
  73 # ----------------------------------------------------------------------------
  74 # Detect compiler and target platform architecture
  75 # ----------------------------------------------------------------------------
  76 include(cmake/OpenCVDetectCXXCompiler.cmake REQUIRED)
  77
  78 # Add these standard paths to the search paths for FIND_LIBRARY
  79 # to find libraries from these locations first
  80 if(UNIX AND NOT ANDROID)
  81   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
  82     if(EXISTS /lib64)
  83       list(APPEND CMAKE_LIBRARY_PATH /lib64)
  84     else()
  85       list(APPEND CMAKE_LIBRARY_PATH /lib)
  86     endif()
  87     if(EXISTS /usr/lib64)
  88       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
  89     else()
  90       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
  91     endif()
  92   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
  93     if(EXISTS /lib32)
  94       list(APPEND CMAKE_LIBRARY_PATH /lib32)
  95     else()
  96       list(APPEND CMAKE_LIBRARY_PATH /lib)
  97     endif()
  98     if(EXISTS /usr/lib32)
  99       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 100     else()
 101       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 102     endif()
 103   endif()
 104 endif()
 105
 106
 107 # ----------------------------------------------------------------------------
 108 # OpenCV cmake options
 109 # ----------------------------------------------------------------------------
 110
 111 # Optional 3rd party components
 112 # ===================================================
 113 OCV_OPTION(WITH_1394           "Include IEEE1394 support"                    ON   IF (UNIX AND NOT ANDROID AND NOT IOS) )
 114 OCV_OPTION(WITH_AVFOUNDATION   "Use AVFoundation for Video I/O"              ON   IF IOS)
 115 OCV_OPTION(WITH_CARBON         "Use Carbon for UI instead of Cocoa"          OFF  IF APPLE )
 116 OCV_OPTION(WITH_CUBLAS         "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" OFF IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 117 OCV_OPTION(WITH_CUDA           "Include NVidia Cuda Runtime support"         ON   IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 118 OCV_OPTION(WITH_CUFFT          "Include NVidia Cuda Fast Fourier Transform (FFT) library support"            ON  IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 119 OCV_OPTION(WITH_EIGEN          "Include Eigen2/Eigen3 support"               ON)
 120 OCV_OPTION(WITH_FFMPEG         "Include FFMPEG support"                      ON   IF (NOT ANDROID AND NOT IOS) )
 121 OCV_OPTION(WITH_GSTREAMER      "Include Gstreamer support"                   ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 122 OCV_OPTION(WITH_GTK            "Include GTK support"                         ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 123 OCV_OPTION(WITH_IMAGEIO        "ImageIO support for OS X"                    OFF  IF APPLE)
 124 OCV_OPTION(WITH_IPP            "Include Intel IPP support"                   OFF  IF (MSVC OR X86 OR X86_64) )
 125 OCV_OPTION(WITH_JASPER         "Include JPEG2K support"                      ON   IF (NOT IOS) )
 126 OCV_OPTION(WITH_JPEG           "Include JPEG support"                        ON   IF (NOT IOS) )
 127 OCV_OPTION(WITH_OPENEXR        "Include ILM support via OpenEXR"             ON   IF (NOT IOS) )
 128 OCV_OPTION(WITH_OPENGL         "Include OpenGL support"                      OFF  IF (NOT ANDROID AND NOT APPLE) )
 129 OCV_OPTION(WITH_OPENNI         "Include OpenNI support"                      OFF  IF (NOT ANDROID AND NOT IOS) )
 130 OCV_OPTION(WITH_PNG            "Include PNG support"                         ON   IF (NOT IOS) )
 131 OCV_OPTION(WITH_PVAPI          "Include Prosilica GigE support"              ON   IF (NOT ANDROID AND NOT IOS) )
 132 OCV_OPTION(WITH_QT             "Build with Qt Backend support"               OFF  IF (NOT ANDROID AND NOT IOS) )
 133 OCV_OPTION(WITH_QUICKTIME      "Use QuickTime for Video I/O insted of QTKit" OFF  IF APPLE )
 134 OCV_OPTION(WITH_TBB            "Include Intel TBB support"                   OFF  IF (NOT IOS) )
 135 OCV_OPTION(WITH_TIFF           "Include TIFF support"                        ON   IF (NOT IOS) )
 136 OCV_OPTION(WITH_UNICAP         "Include Unicap support (GPL)"                OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 137 OCV_OPTION(WITH_V4L            "Include Video 4 Linux support"               ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 138 OCV_OPTION(WITH_VIDEOINPUT     "Build HighGUI with DirectShow support"       ON   IF WIN32 )
 139 OCV_OPTION(WITH_XIMEA          "Include XIMEA cameras support"               OFF  IF (NOT ANDROID AND NOT APPLE) )
 140 OCV_OPTION(WITH_XINE           "Include Xine support (GPL)"                  OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 141 OCV_OPTION(WITH_CLP            "Include Clp support (EPL)"                   OFF)
 142 OCV_OPTION(WITH_OPENCL         "Include OpenCL Runtime support"              OFF  IF (NOT ANDROID AND NOT IOS) )
 143 OCV_OPTION(WITH_OPENCLAMDFFT   "Include AMD OpenCL FFT library support"      OFF  IF (NOT ANDROID AND NOT IOS) )
 144 OCV_OPTION(WITH_OPENCLAMDBLAS  "Include AMD OpenCL BLAS library support"     OFF  IF (NOT ANDROID AND NOT IOS) )
 145
 146
 147 # OpenCV build components
 148 # ===================================================
 149 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR IOS) )
 150 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 151 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" ON )
 152 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 153 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON )
 154 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     ON  IF (NOT IOS) )
 155 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           ON  IF (NOT IOS) )
 156 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into debug libs (not MSCV only)" ON )
 157 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of staticaly linked CRT for staticaly linked OpenCV" ON IF MSVC )
 158 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create fat java wrapper containing the whole OpenCV library" ON IF ANDROID AND NOT BUILD_SHARED_LIBS AND CMAKE_COMPILER_IS_GNUCXX )
 159 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID AND ANDROID_USE_STLPORT AND ANDROID_SOURCE_TREE )
 160 OCV_OPTION(BUILD_ANDROID_PACKAGE    "Build platform-specific package for Google Play" OFF IF ANDROID )
 161
 162
 163 # 3rd party libs
 164 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"         WIN32 OR APPLE )
 165 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"      WIN32 OR ANDROID OR APPLE )
 166 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"    WIN32 OR ANDROID OR APPLE )
 167 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"      WIN32 OR ANDROID OR APPLE )
 168 OCV_OPTION(BUILD_PNG                "Build libpng from source"       WIN32 OR ANDROID OR APPLE )
 169 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"      WIN32 OR ANDROID OR APPLE )
 170
 171 # OpenCV installation options
 172 # ===================================================
 173 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 174 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 175 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF  IF ANDROID )
 176 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT IOS AND BUILD_SHARED_LIBS) )
 177
 178
 179 if(MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode)
 180   set(ENABLE_SOLUTION_FOLDERS0 ON)
 181 else()
 182   set(ENABLE_SOLUTION_FOLDERS0 OFF)
 183 endif()
 184
 185 # OpenCV build options
 186 # ===================================================
 187 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON   IF (NOT IOS) )
 188 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        ${ENABLE_SOLUTION_FOLDERS0} IF (CMAKE_VERSION VERSION_GREATER "2.8.0") )
 189 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CMAKE_COMPILER_IS_GNUCXX )
 190 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CMAKE_COMPILER_IS_GNUCXX )
 191 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CMAKE_COMPILER_IS_GNUCXX AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 192 OCV_OPTION(ENABLE_FAST_MATH           "Enable -ffast-math (not recommended for GCC 4.6.x)"       OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 193 OCV_OPTION(ENABLE_SSE                 "Enable SSE instructions"                                  ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 194 OCV_OPTION(ENABLE_SSE2                "Enable SSE2 instructions"                                 ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 195 OCV_OPTION(ENABLE_SSE3                "Enable SSE3 instructions"                                 ON   IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 196 OCV_OPTION(ENABLE_SSSE3               "Enable SSSE3 instructions"                                OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 197 OCV_OPTION(ENABLE_SSE41               "Enable SSE4.1 instructions"                               OFF  IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 198 OCV_OPTION(ENABLE_SSE42               "Enable SSE4.2 instructions"                               OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 199 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 200 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 201
 202
 203 # uncategorized options
 204 # ===================================================
 205 OCV_OPTION(CMAKE_VERBOSE "Verbose mode" OFF )
 206
 207 # backward compatibility
 208 # ===================================================
 209 include(cmake/OpenCVLegacyOptions.cmake OPTIONAL)
 210
 211
 212 # ----------------------------------------------------------------------------
 213 #  Get actual OpenCV version number from sources
 214 # ----------------------------------------------------------------------------
 215 include(cmake/OpenCVVersion.cmake REQUIRED)
 216
 217
 218 # ----------------------------------------------------------------------------
 219 #  Build & install layouts
 220 # ----------------------------------------------------------------------------
 221
 222 # Save libs and executables in the same place
 223 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications" )
 224
 225 if(ANDROID OR WIN32)
 226     set(OPENCV_DOC_INSTALL_PATH doc)
 227 elseif(INSTALL_TO_MANGLED_PATHS)
 228     set(OPENCV_DOC_INSTALL_PATH share/OpenCV-${OPENCV_VERSION}/doc)
 229 else()
 230     set(OPENCV_DOC_INSTALL_PATH share/OpenCV/doc)
 231 endif()
 232
 233 if(ANDROID)
 234     set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 235     set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 236     set(OPENCV_LIB_INSTALL_PATH     sdk/native/libs/${ANDROID_NDK_ABI_NAME})
 237     set(OPENCV_3P_LIB_INSTALL_PATH  sdk/native/3rdparty/libs/${ANDROID_NDK_ABI_NAME})
 238     set(OPENCV_CONFIG_INSTALL_PATH  sdk/native/jni)
 239     set(OPENCV_INCLUDE_INSTALL_PATH sdk/native/jni/include)
 240 else()
 241     set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib")
 242     set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib${LIB_SUFFIX}")
 243     set(OPENCV_LIB_INSTALL_PATH     lib${LIB_SUFFIX})
 244     set(OPENCV_3P_LIB_INSTALL_PATH  share/OpenCV/3rdparty/${OPENCV_LIB_INSTALL_PATH})
 245     set(OPENCV_INCLUDE_INSTALL_PATH include)
 246
 247     math(EXPR SIZEOF_VOID_P_BITS "8 * ${CMAKE_SIZEOF_VOID_P}")
 248     if(LIB_SUFFIX AND NOT SIZEOF_VOID_P_BITS EQUAL LIB_SUFFIX)
 249       set(OPENCV_CONFIG_INSTALL_PATH lib${LIB_SUFFIX}/cmake/opencv)
 250     else()
 251       set(OPENCV_CONFIG_INSTALL_PATH share/OpenCV)
 252     endif()
 253 endif()
 254
 255 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 256 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 257
 258 if(INSTALL_TO_MANGLED_PATHS)
 259   set(OPENCV_INCLUDE_INSTALL_PATH ${OPENCV_INCLUDE_INSTALL_PATH}/opencv-${OPENCV_VERSION})
 260 endif()
 261
 262 if(WIN32)
 263   # Postfix of DLLs:
 264   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 265   set(OPENCV_DEBUG_POSTFIX d)
 266 else()
 267   # Postfix of so's:
 268   set(OPENCV_DLLVERSION "")
 269   set(OPENCV_DEBUG_POSTFIX "")
 270 endif()
 271
 272 if(DEFINED CMAKE_DEBUG_POSTFIX)
 273   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 274 endif()
 275
 276 if(CMAKE_VERBOSE)
 277   set(CMAKE_VERBOSE_MAKEFILE 1)
 278 endif()
 279
 280
 281 # ----------------------------------------------------------------------------
 282 #  Path for build/platform -specific headers
 283 # ----------------------------------------------------------------------------
 284 set(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 285 add_definitions(-DHAVE_CVCONFIG_H)
 286 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 287
 288
 289 # ----------------------------------------------------------------------------
 290 #  Autodetect if we are in a GIT repository
 291 # ----------------------------------------------------------------------------
 292
 293 # don't use FindGit because it requires CMake 2.8.2
 294 set(git_names git eg) # eg = easy git
 295 # Prefer .cmd variants on Windows unless running in a Makefile in the MSYS shell
 296 if(WIN32)
 297   if(NOT CMAKE_GENERATOR MATCHES "MSYS")
 298     set(git_names git.cmd git eg.cmd eg)
 299   endif()
 300 endif()
 301
 302 find_host_program(GIT_EXECUTABLE NAMES ${git_names} PATH_SUFFIXES Git/cmd Git/bin DOC "git command line client")
 303 mark_as_advanced(GIT_EXECUTABLE)
 304
 305 if(GIT_EXECUTABLE)
 306   execute_process(COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
 307     WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 308     OUTPUT_VARIABLE OPENCV_GIT_HASH_SORT
 309     RESULT_VARIABLE GIT_RESULT
 310     ERROR_QUIET
 311     OUTPUT_STRIP_TRAILING_WHITESPACE
 312   )
 313   if(GIT_RESULT EQUAL 0)
 314     set(OPENCV_VCSVERSION "commit:${OPENCV_GIT_HASH_SORT}")
 315   else()
 316     set(OPENCV_VCSVERSION "exported")
 317   endif()
 318 else()
 319   # We don't have git:
 320   set(OPENCV_VCSVERSION "")
 321 endif()
 322
 323
 324 # ----------------------------------------------------------------------------
 325 # OpenCV compiler and linker options
 326 # ----------------------------------------------------------------------------
 327 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 328 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 329   set(CMAKE_BUILD_TYPE Release)
 330 endif()
 331
 332 include(cmake/OpenCVCompilerOptions.cmake REQUIRED)
 333
 334
 335 # ----------------------------------------------------------------------------
 336 # Use statically or dynamically linked CRT?
 337 # Default: dynamic
 338 # ----------------------------------------------------------------------------
 339 if(MSVC)
 340   include(cmake/OpenCVCRTLinkage.cmake REQUIRED)
 341 endif(MSVC)
 342
 343 if(WIN32 AND NOT MINGW)
 344   add_definitions(-D_VARIADIC_MAX=10)
 345 endif(WIN32 AND NOT MINGW)
 346
 347
 348 # ----------------------------------------------------------------------------
 349 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 350 # ----------------------------------------------------------------------------
 351 if(UNIX)
 352   include(cmake/OpenCVFindPkgConfig.cmake OPTIONAL)
 353   include(CheckFunctionExists)
 354   include(CheckIncludeFile)
 355
 356   if(NOT APPLE)
 357     CHECK_INCLUDE_FILE(alloca.h HAVE_ALLOCA_H)
 358     CHECK_FUNCTION_EXISTS(alloca HAVE_ALLOCA)
 359     CHECK_INCLUDE_FILE(unistd.h HAVE_UNISTD_H)
 360     CHECK_INCLUDE_FILE(pthread.h HAVE_LIBPTHREAD)
 361     if(ANDROID)
 362       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 363     elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD|NetBSD|DragonFly")
 364       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 365     else()
 366       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 367     endif()
 368   else()
 369     add_definitions(-DHAVE_ALLOCA -DHAVE_ALLOCA_H -DHAVE_LIBPTHREAD -DHAVE_UNISTD_H)
 370   endif()
 371 endif()
 372
 373 include(cmake/OpenCVPCHSupport.cmake REQUIRED)
 374 include(cmake/OpenCVModule.cmake REQUIRED)
 375
 376 # ----------------------------------------------------------------------------
 377 #  Detect 3rd-party libraries
 378 # ----------------------------------------------------------------------------
 379
 380 include(cmake/OpenCVFindLibsGrfmt.cmake REQUIRED)
 381 include(cmake/OpenCVFindLibsGUI.cmake   REQUIRED)
 382 include(cmake/OpenCVFindLibsVideo.cmake REQUIRED)
 383 include(cmake/OpenCVFindLibsPerf.cmake  REQUIRED)
 384
 385
 386 # ----------------------------------------------------------------------------
 387 #  Detect other 3rd-party libraries/tools
 388 # ----------------------------------------------------------------------------
 389
 390 # --- LATEX for pdf documentation ---
 391 if(BUILD_DOCS)
 392   include(cmake/OpenCVFindLATEX.cmake REQUIRED)
 393 endif(BUILD_DOCS)
 394
 395 # --- Python Support ---
 396 include(cmake/OpenCVDetectPython.cmake REQUIRED)
 397
 398 # --- Java Support ---
 399 if(ANDROID)
 400   include(cmake/OpenCVDetectApacheAnt.cmake REQUIRED)
 401   include(cmake/OpenCVDetectAndroidSDK.cmake REQUIRED)
 402
 403   if(NOT ANDROID_TOOLS_Pkg_Revision GREATER 13)
 404     message(WARNING "OpenCV requires Android SDK tools revision 14 or newer. Otherwise tests and samples will no be compiled.")
 405   endif()
 406 endif(ANDROID)
 407
 408 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 409   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 410 else()
 411   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 412 endif()
 413
 414 # --- OpenCL ---
 415 if(WITH_OPENCL)
 416   include(cmake/OpenCVDetectOpenCL.cmake REQUIRED)
 417   if(OPENCL_FOUND)
 418     set(HAVE_OPENCL 1)
 419   endif()
 420   if(WITH_OPENCLAMDFFT)
 421     set(HAVE_CLAMDFFT 1)
 422   endif()
 423   if(WITH_OPENCLAMDBLAS)
 424     set(HAVE_CLAMDBLAS 1)
 425   endif()
 426 endif()
 427
 428 # ----------------------------------------------------------------------------
 429 # Solution folders:
 430 # ----------------------------------------------------------------------------
 431 if(ENABLE_SOLUTION_FOLDERS)
 432   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 433   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 434 endif()
 435
 436 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 437 include(cmake/OpenCVExtraTargets.cmake REQUIRED)
 438
 439
 440 # ----------------------------------------------------------------------------
 441 # Process subdirectories
 442 # ----------------------------------------------------------------------------
 443
 444 # opencv.hpp and legacy headers
 445 add_subdirectory(include)
 446
 447 # OpenCV modules
 448 add_subdirectory(modules)
 449
 450 # Generate targets for documentation
 451 add_subdirectory(doc)
 452
 453 # various data that is used by cv libraries and/or demo applications.
 454 add_subdirectory(data)
 455
 456 # extra applications
 457 add_subdirectory(apps)
 458
 459 # examples
 460 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES)
 461   add_subdirectory(samples)
 462 endif()
 463
 464 if(BUILD_ANDROID_SERVICE)
 465   add_subdirectory(android/service)
 466 endif()
 467
 468 if(BUILD_ANDROID_PACKAGE)
 469   add_subdirectory(android/package)
 470 endif()
 471
 472 # ----------------------------------------------------------------------------
 473 # Finalization: generate configuration-based files
 474 # ----------------------------------------------------------------------------
 475 ocv_track_build_dependencies()
 476
 477 # Generate platform-dependent and configuration-dependent headers
 478 include(cmake/OpenCVGenHeaders.cmake REQUIRED)
 479
 480 # Generate opencv.pc for pkg-config command
 481 include(cmake/OpenCVGenPkgconfig.cmake REQUIRED)
 482
 483 # Generate OpenCV.mk for ndk-build (Android build tool)
 484 include(cmake/OpenCVGenAndroidMK.cmake REQUIRED)
 485
 486 # Generate OpenCVСonfig.cmake and OpenCVConfig-version.cmake for cmake projects
 487 include(cmake/OpenCVGenConfig.cmake REQUIRED)
 488
 489
 490 # ----------------------------------------------------------------------------
 491 # Summary:
 492 # ----------------------------------------------------------------------------
 493 status("")
 494 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 495 if(OPENCV_VCSVERSION)
 496   status("  Version control:" ${OPENCV_VCSVERSION})
 497 endif()
 498
 499 # ========================== build platform ==========================
 500 status("")
 501 status("  Platform:")
 502 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
 503 if(CMAKE_CROSSCOMPILING)
 504   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
 505 endif()
 506 status("    CMake:"            ${CMAKE_VERSION})
 507 status("    CMake generator:"  ${CMAKE_GENERATOR})
 508 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
 509 if(MSVC)
 510   status("    MSVC:"           ${MSVC_VERSION})
 511 endif()
 512 if(CMAKE_GENERATOR MATCHES Xcode)
 513   status("    Xcode:"          ${XCODE_VERSION})
 514 endif()
 515 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
 516   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
 517 endif()
 518
 519 # ========================== C/C++ options ==========================
 520 status("")
 521 status("  C/C++:")
 522 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
 523 status("    C++ Compiler:"           CMAKE_COMPILER_IS_GNUCXX THEN "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_GCC_REGEX_VERSION})" ELSE "${CMAKE_CXX_COMPILER}" )
 524 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
 525 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
 526 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
 527 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
 528 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
 529 if(WIN32)
 530   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
 531   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
 532 else()
 533   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
 534   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
 535 endif()
 536 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
 537
 538 # ========================== OpenCV modules ==========================
 539 status("")
 540 status("  OpenCV modules:")
 541 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD}")
 542 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
 543 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
 544 set(OPENCV_MODULES_DISABLED_AUTO_ST "")
 545 foreach(m ${OPENCV_MODULES_DISABLED_AUTO})
 546   set(__mdeps "")
 547   foreach(d ${OPENCV_MODULE_${m}_DEPS})
 548     if(d MATCHES "^opencv_" AND NOT HAVE_${d})
 549       list(APPEND __mdeps ${d})
 550     endif()
 551   endforeach()
 552   list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}(deps: ${__mdeps})")
 553 endforeach()
 554 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO_ST}")
 555
 556 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
 557 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
 558 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
 559 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
 560
 561 # ========================== Android details ==========================
 562 if(ANDROID)
 563   status("")
 564   status("  Android: ")
 565   status("    Android ABI:" ${ANDROID_ABI})
 566   status("    Native API level:" android-${ANDROID_NATIVE_API_LEVEL})
 567   status("    SDK target:" "${ANDROID_SDK_TARGET}")
 568   if(BUILD_WITH_ANDROID_NDK)
 569     status("    Android NDK:" "${ANDROID_NDK} (toolchain: ${ANDROID_TOOLCHAIN_NAME})")
 570   elseif(BUILD_WITH_STANDALONE_TOOLCHAIN)
 571     status("    Android toolchain:" "${ANDROID_STANDALONE_TOOLCHAIN}")
 572   endif()
 573   status("    android tool:"  ANDROID_EXECUTABLE  THEN "${ANDROID_EXECUTABLE} (${ANDROID_TOOLS_Pkg_Desc})" ELSE NO)
 574   status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"            ELSE NO)
 575   status("    Google Play package:" BUILD_ANDROID_PACKAGE THEN YES ELSE NO)
 576 endif()
 577
 578 # ========================== GUI ==========================
 579 status("")
 580 status("  GUI: ")
 581
 582 if(HAVE_QT)
 583   status("    QT 4.x:"            HAVE_QT        THEN "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})" ELSE NO)
 584   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
 585 else()
 586   if(DEFINED WITH_QT)
 587     status("    QT 4.x:" NO)
 588   endif()
 589   if(WIN32)
 590     status("    Win32 UI:" YES)
 591   else()
 592     if(APPLE)
 593       if(WITH_CARBON)
 594         status("    Carbon:" YES)
 595       else()
 596         status("    Cocoa:"  YES)
 597       endif()
 598     else()
 599       status("    GTK+ 2.x:" HAVE_GTK      THEN "YES (ver ${ALIASOF_gtk+-2.0_VERSION})"     ELSE NO)
 600       status("    GThread :" HAVE_GTHREAD  THEN "YES (ver ${ALIASOF_gthread-2.0_VERSION})"  ELSE NO)
 601       status("    GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${ALIASOF_gtkglext-1.0_VERSION})" ELSE NO)
 602     endif()
 603   endif()
 604 endif()
 605
 606 status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
 607
 608 # ========================== MEDIA IO ==========================
 609 status("")
 610 status("  Media I/O: ")
 611 status("    ZLib:"         BUILD_ZLIB    THEN "build (ver ${ZLIB_VERSION_STRING})"               ELSE "${ZLIB_LIBRARY} (ver ${ZLIB_VERSION_STRING})")
 612
 613 if(WITH_JPEG)
 614   status("    JPEG:"       JPEG_FOUND    THEN "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})"        ELSE "build (ver ${JPEG_LIB_VERSION})")
 615 else()
 616   status("    JPEG:"       "NO")
 617 endif()
 618 if(WITH_PNG)
 619   status("    PNG:"        PNG_FOUND     THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})"              ELSE "build (ver ${PNG_VERSION})")
 620 else()
 621   status("    PNG:"        "NO")
 622 endif()
 623 if(WITH_TIFF)
 624   if(TIFF_VERSION_STRING AND TIFF_FOUND)
 625     status("    TIFF:"     "${TIFF_LIBRARY} (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 626   else()
 627     status("    TIFF:"     TIFF_FOUND    THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION})"            ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 628   endif()
 629 else()
 630   status("    TIFF:"       "NO")
 631 endif()
 632 if(WITH_JASPER)
 633   status("    JPEG 2000:"  JASPER_FOUND  THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
 634 else()
 635   status("    JPEG 2000:"  "NO")
 636 endif()
 637 if(WITH_OPENEXR)
 638   status("    OpenEXR:"  OPENEXR_FOUND  THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
 639 else()
 640   status("    OpenEXR:"  "NO")
 641 endif()
 642
 643 # ========================== VIDEO IO ==========================
 644 status("")
 645 status("  Video I/O:")
 646
 647 if(DEFINED WITH_1394)
 648   status("    DC1394 1.x:"     HAVE_DC1394         THEN "YES (ver ${ALIASOF_libdc1394_VERSION})"   ELSE NO)
 649   status("    DC1394 2.x:"     HAVE_DC1394_2       THEN "YES (ver ${ALIASOF_libdc1394-2_VERSION})" ELSE NO)
 650 endif(DEFINED WITH_1394)
 651
 652 if(ANDROID)
 653   if(HAVE_opencv_androidcamera)
 654     status("    AndroidNativeCamera:" BUILD_ANDROID_CAMERA_WRAPPER
 655                                                    THEN "YES, build for Android${ANDROID_VERSION}" ELSE "YES, use prebuilt libraries")
 656   else()
 657     status("    AndroidNativeCamera:" "NO (native camera requires Android API level 8 or higher)")
 658   endif()
 659 endif()
 660
 661 if(DEFINED WITH_AVFOUNDATION)
 662   status("    AVFoundation:"   WITH_AVFOUNDATION   THEN YES                                        ELSE NO)
 663 endif(DEFINED WITH_AVFOUNDATION)
 664
 665 if(DEFINED WITH_FFMPEG)
 666   if(WIN32)
 667     status("    FFMPEG:"       WITH_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
 668   else()
 669     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
 670   endif()
 671   status("      codec:"        HAVE_FFMPEG_CODEC   THEN "YES (ver ${ALIASOF_libavcodec_VERSION})"  ELSE NO)
 672   status("      format:"       HAVE_FFMPEG_FORMAT  THEN "YES (ver ${ALIASOF_libavformat_VERSION})" ELSE NO)
 673   status("      util:"         HAVE_FFMPEG_UTIL    THEN "YES (ver ${ALIASOF_libavutil_VERSION})"   ELSE NO)
 674   status("      swscale:"      HAVE_FFMPEG_SWSCALE THEN "YES (ver ${ALIASOF_libswscale_VERSION})"  ELSE NO)
 675   status("      gentoo-style:" HAVE_GENTOO_FFMPEG  THEN YES                                        ELSE NO)
 676 endif(DEFINED WITH_FFMPEG)
 677
 678 if(DEFINED WITH_GSTREAMER)
 679   status("    GStreamer:"      HAVE_GSTREAMER      THEN ""                                         ELSE NO)
 680   if(HAVE_GSTREAMER)
 681     status("      base:"       "YES (ver ${ALIASOF_gstreamer-base-0.10_VERSION})")
 682     status("      app:"        "YES (ver ${ALIASOF_gstreamer-app-0.10_VERSION})")
 683     status("      video:"      "YES (ver ${ALIASOF_gstreamer-video-0.10_VERSION})")
 684   endif()
 685 endif(DEFINED WITH_GSTREAMER)
 686
 687 if(DEFINED WITH_OPENNI)
 688   status("    OpenNI:"         HAVE_OPENNI         THEN "YES (ver ${OPENNI_VERSION_STRING}, build ${OPENNI_VERSION_BUILD})"
 689                                                                                                    ELSE NO)
 690   status("    OpenNI PrimeSensor Modules:" HAVE_OPENNI_PRIME_SENSOR_MODULE
 691                                                    THEN "YES (${OPENNI_PRIME_SENSOR_MODULE})"      ELSE NO)
 692 endif(DEFINED WITH_OPENNI)
 693
 694 if(DEFINED WITH_PVAPI)
 695   status("    PvAPI:"          HAVE_PVAPI          THEN YES                                        ELSE NO)
 696 endif(DEFINED WITH_PVAPI)
 697
 698 if(DEFINED WITH_QUICKTIME)
 699   status("    QuickTime:"      WITH_QUICKTIME      THEN YES                                        ELSE NO)
 700   status("    QTKit:"          WITH_QUICKTIME      THEN NO                                         ELSE YES)
 701 endif(DEFINED WITH_QUICKTIME)
 702
 703 if(DEFINED WITH_UNICAP)
 704   status("    UniCap:"         HAVE_UNICAP         THEN "YES (ver ${ALIASOF_libunicap_VERSION})"   ELSE NO)
 705   status("    UniCap ucil:"    HAVE_UNICAP_UCIL    THEN "YES (ver ${ALIASOF_libucil_VERSION})"     ELSE NO)
 706 endif(DEFINED WITH_UNICAP)
 707
 708 if(DEFINED WITH_V4L)
 709   if(HAVE_CAMV4L)
 710     set(HAVE_CAMV4L_STR "YES")
 711   else()
 712     set(HAVE_CAMV4L_STR "NO")
 713   endif()
 714   if(HAVE_CAMV4L2)
 715     set(HAVE_CAMV4L2_STR "YES")
 716   else()
 717     set(HAVE_CAMV4L2_STR "NO")
 718   endif()
 719   status("    V4L/V4L2:"       HAVE_LIBV4L         THEN "Using libv4l (ver ${ALIASOF_libv4l1_VERSION})"
 720                                                                                                    ELSE "${HAVE_CAMV4L_STR}/${HAVE_CAMV4L2_STR}")
 721 endif(DEFINED WITH_V4L)
 722
 723 if(DEFINED WITH_VIDEOINPUT)
 724   status("    DirectShow:"     HAVE_VIDEOINPUT     THEN YES                                        ELSE NO)
 725 endif(DEFINED WITH_VIDEOINPUT)
 726
 727 if(DEFINED WITH_XIMEA)
 728   status("    XIMEA:"          HAVE_XIMEA          THEN YES                                        ELSE NO)
 729 endif(DEFINED WITH_XIMEA)
 730
 731 if(DEFINED WITH_XINE)
 732   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${ALIASOF_libxine_VERSION})"     ELSE NO)
 733 endif(DEFINED WITH_XINE)
 734
 735 # ========================== Other third-party libraries ==========================
 736 status("")
 737 status("  Other third-party libraries:")
 738
 739 if(DEFINED WITH_IPP)
 740   if(WITH_IPP AND IPP_FOUND)
 741     status("    Use IPP:" "${IPP_LATEST_VERSION_STR} [${IPP_LATEST_VERSION_MAJOR}.${IPP_LATEST_VERSION_MINOR}.${IPP_LATEST_VERSION_BUILD}]")
 742     status("         at:" "${IPP_ROOT_DIR}")
 743   else()
 744     status("    Use IPP:"   WITH_IPP AND NOT IPP_FOUND THEN "IPP not found" ELSE NO)
 745   endif()
 746 endif(DEFINED WITH_IPP)
 747
 748 if(DEFINED WITH_TBB)
 749   status("    Use TBB:"   HAVE_TBB   THEN "YES (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})" ELSE NO)
 750 endif(DEFINED WITH_TBB)
 751
 752 if(DEFINED WITH_CUDA)
 753   status("    Use Cuda:"  HAVE_CUDA  THEN "YES (ver ${CUDA_VERSION_STRING})" ELSE NO)
 754 endif(DEFINED WITH_CUDA)
 755
 756 status("    Use OpenCL:"  HAVE_OPENCL  THEN YES ELSE NO)
 757
 758 status("    Use Eigen:" HAVE_EIGEN THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
 759 status("    Use Clp:"   HAVE_CLP   THEN YES ELSE NO)
 760
 761 if(HAVE_CUDA)
 762   status("")
 763   status("  NVIDIA CUDA:"            "(ver ${CUDA_VERSION_STRING})")
 764
 765   status("    Use CUFFT:"            HAVE_CUFFT  THEN YES ELSE NO)
 766   status("    Use CUBLAS:"           HAVE_CUBLAS THEN YES ELSE NO)
 767   status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
 768   status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
 769 endif()
 770
 771 # ========================== python ==========================
 772 status("")
 773 status("  Python:")
 774 status("    Interpreter:"   PYTHON_EXECUTABLE     THEN "${PYTHON_EXECUTABLE} (ver ${PYTHON_VERSION_FULL})"         ELSE NO)
 775 if(BUILD_opencv_python)
 776   if(PYTHONLIBS_VERSION_STRING)
 777     status("    Libraries:"     HAVE_opencv_python  THEN  "${PYTHON_LIBRARIES} (ver ${PYTHONLIBS_VERSION_STRING})" ELSE NO)
 778   else()
 779     status("    Libraries:"     HAVE_opencv_python  THEN  ${PYTHON_LIBRARIES}                                      ELSE NO)
 780   endif()
 781   status("    numpy:"         PYTHON_USE_NUMPY    THEN "${PYTHON_NUMPY_INCLUDE_DIR} (ver ${PYTHON_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
 782   status("    packages path:" PYTHON_EXECUTABLE   THEN "${PYTHON_PACKAGES_PATH}"                                   ELSE "-")
 783 endif()
 784
 785 # ========================== documentation ==========================
 786 if(BUILD_DOCS)
 787   status("")
 788   status("  Documentation:")
 789   if(HAVE_SPHINX)
 790     status("    Build Documentation:" PDFLATEX_COMPILER      THEN YES ELSE "YES (only HTML and without math expressions)")
 791   else()
 792     status("    Build Documentation:" NO)
 793   endif()
 794   status("    Sphinx:"              HAVE_SPHINX              THEN "${SPHINX_BUILD} (ver ${SPHINX_VERSION})" ELSE NO)
 795   status("    PdfLaTeX compiler:"   PDFLATEX_COMPILER        THEN "${PDFLATEX_COMPILER}" ELSE NO)
 796 endif()
 797
 798 # ========================== samples and tests ==========================
 799 status("")
 800 status("  Tests and samples:")
 801 status("    Tests:"             BUILD_TESTS AND HAVE_opencv_ts       THEN YES ELSE NO)
 802 status("    Performance tests:" BUILD_PERF_TESTS AND HAVE_opencv_ts  THEN YES ELSE NO)
 803 status("    Examples:"          BUILD_EXAMPLES                       THEN YES ELSE NO)
 804
 805 if(ANDROID)
 806   status("    Android tests:"    BUILD_TESTS AND CAN_BUILD_ANDROID_PROJECTS            THEN YES ELSE NO)
 807   status("    Android examples:" BUILD_ANDROID_EXAMPLES AND CAN_BUILD_ANDROID_PROJECTS THEN YES ELSE NO)
 808 endif()
 809
 810 # ========================== auxiliary ==========================
 811 status("")
 812 status("  Install path:" "${CMAKE_INSTALL_PREFIX}")
 813 status("")
 814 status("  cvconfig.h is in:" "${OPENCV_CONFIG_FILE_INCLUDE_DIR}")
 815 status("-----------------------------------------------------------------")
 816 status("")
 817
 818 ocv_finalize_status()
 819
 820 # ----------------------------------------------------------------------------
 821 # Warn in the case of in-source build
 822 # ----------------------------------------------------------------------------
 823 if("${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 824   message(WARNING "The source directory is the same as binary directory. \"make clean\" may damage the source tree")
 825 endif()
 826