CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8 FATAL_ERROR)
   2
   3 # ----------------------------------------------------------------------------
   4 # includes
   5 set (CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
   6
   7 include (utils)
   8
   9 # ----------------------------------------------------------------------------
  10 # package information
  11 set (PROJECT_NAME      "gflags")
  12 set (PACKAGE_NAME      "${PROJECT_NAME}")
  13 set (PACKAGE_VERSION   "2.1.0")
  14 set (PACKAGE_STRING    "${PROJECT_NAME} ${PACKAGE_VERSION}")
  15 set (PACKAGE_TARNAME   "${PROJECT_NAME}-${PACKAGE_VERSION}")
  16 set (PACKAGE_BUGREPORT "https://code.google.com/p/gflags/issues/")
  17
  18 project (${PROJECT_NAME} CXX)
  19
  20 version_numbers (
  21   ${PACKAGE_VERSION}
  22     PACKAGE_VERSION_MAJOR
  23     PACKAGE_VERSION_MINOR
  24     PACKAGE_VERSION_PATCH
  25 )
  26
  27 # ----------------------------------------------------------------------------
  28 # configure options
  29 option (BUILD_SHARED_LIBS "Request build of shared libraries." OFF)
  30 set (GFLAGS_SHARED_LIBS ${BUILD_SHARED_LIBS})
  31
  32 option (BUILD_gflags_LIB           "Request build of the multi-threaded gflags library."  ON)
  33 option (BUILD_gflags_nothreads_LIB "Request build of the single-threaded gflags library." ON)
  34
  35 if (NOT BUILD_gflags_LIB AND NOT BUILD_gflags_nothreads_LIB)
  36  message (FATAL_ERROR "At least one of BUILD_gflags_LIB and BUILD_gflags_nothreads_LIB must be ON.")
  37 endif ()
  38
  39 option (BUILD_NEGATIVE_COMPILATION_TESTS "Request addition of negative compilation tests." OFF)
  40 mark_as_advanced (BUILD_NEGATIVE_COMPILATION_TESTS)
  41
  42 set (GFLAGS_NAMESPACE "gflags" CACHE STRING "C++ namespace identifier of gflags library.")
  43 mark_as_advanced (GFLAGS_NAMESPACE)
  44
  45 mark_as_advanced (CLEAR CMAKE_INSTALL_PREFIX)
  46 mark_as_advanced (CMAKE_CONFIGURATION_TYPES)
  47 if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CXX_FLAGS AND NOT CMAKE_C_FLAGS)
  48   set (
  49     CMAKE_BUILD_TYPE "Release"
  50     CACHE STRING "Choose the type of build, options are: None (CMAKE_C_FLAGS and CMAKE_CXX_FLAGS used) Debug Release RelWithDebInfo MinSizeRel."
  51     FORCE
  52   )
  53 endif ()
  54
  55 if (APPLE)
  56   mark_as_advanced(CMAKE_OSX_ARCHITECTURES
  57                    CMAKE_OSX_DEPLOYMENT_TARGET
  58                    CMAKE_OSX_SYSROOT)
  59 endif ()
  60
  61 # ----------------------------------------------------------------------------
  62 # system checks
  63 include (CheckTypeSize)
  64 include (CheckIncludeFileCXX)
  65 include (CheckCXXSymbolExists)
  66
  67 set (GFLAGS_INTTYPES_FORMAT "" CACHE STRING "Format of integer types: \"C99\" (uint32_t), \"BSD\" (u_int32_t), \"VC7\" (__int32)")
  68 mark_as_advanced (GFLAGS_INTTYPES_FORMAT)
  69 if (NOT GFLAGS_INTTYPES_FORMAT)
  70   foreach (type IN ITEMS uint32_t u_int32_t __int32)
  71     check_type_size (${type} SIZE LANGUAGE CXX)
  72     if (SIZE)
  73       set (HAVE_${type} TRUE)
  74     else ()
  75       set (HAVE_${type} FALSE)
  76     endif ()
  77   endforeach ()
  78   if (HAVE_uint32_t)
  79     set_property (CACHE GFLAGS_INTTYPES_FORMAT PROPERTY VALUE C99)
  80   elseif (HAVE_u_int32_t)
  81     set_property (CACHE GFLAGS_INTTYPES_FORMAT PROPERTY VALUE BSD)
  82   elseif (HAVE___int32)
  83     set_property (CACHE GFLAGS_INTTYPES_FORMAT PROPERTY VALUE VC7)
  84   else ()
  85     mark_as_advanced (CLEAR GFLAGS_INTTYPES_FORMAT)
  86     message (FATAL_ERROR "Do not know how to define a 32-bit integer quantity on your system!"
  87                          " Neither uint32_t, u_int32_t, nor __int32 seem to be available."
  88                          " Set GFLAGS_INTTYPES_FORMAT to either C99, BSD, or VC7 and try again.")
  89   endif ()
  90 endif ()
  91 set ("GFLAGS_INTTYPES_FORMAT_${GFLAGS_INTTYPES_FORMAT}" TRUE)
  92
  93 foreach (fname IN ITEMS stdint sys/types fnmatch inttypes unistd sys/stat)
  94   string (TOUPPER "${fname}" FNAME)
  95   string (REGEX REPLACE "/" "_" FNAME "${FNAME}")
  96   check_include_file_cxx ("${fname}.h" GFLAGS_HAVE_${FNAME}_H)
  97 endforeach ()
  98
  99 foreach (fname IN ITEMS strtoll strtoq)
 100   string (TOUPPER "${fname}" FNAME)
 101   check_cxx_symbol_exists ("${fname}" stdlib.h GFLAGS_HAVE_${FNAME})
 102 endforeach ()
 103
 104 set (CMAKE_THREAD_PREFER_PTHREAD TRUE)
 105 find_package (ThreadsCXX)
 106 if (Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 107   set (GFLAGS_HAVE_PTHREAD TRUE)
 108   check_type_size (pthread_rwlock_t GFLAGS_HAVE_RWLOCK LANGUAGE CXX)
 109 else ()
 110   set (GFLAGS_HAVE_PTHREAD FALSE)
 111 endif ()
 112
 113 if (UNIX AND NOT GFLAGS_HAVE_PTHREAD AND BUILD_gflags_LIB)
 114   set_property (CACHE BUILD_gflags_LIB PROPERTY VALUE OFF)
 115   message (WARNING "Could not find the <pthread.h> header file."
 116                    " Disabling the build of the multi-threaded gflags library.")
 117 endif ()
 118
 119 # ----------------------------------------------------------------------------
 120 # source files - excluding root subdirectory and/or .in suffix
 121 set (PUBLIC_HDRS
 122   "gflags.h"
 123   "gflags_declare.h"
 124   "gflags_completions.h"
 125 )
 126
 127 set (PRIVATE_HDRS
 128   "config.h"
 129 )
 130
 131 set (GFLAGS_SRCS
 132   "gflags.cc"
 133   "gflags_reporting.cc"
 134   "gflags_completions.cc"
 135 )
 136
 137 if (WIN32)
 138   list (APPEND PRIVATE_HDRS "windows_port.h")
 139   list (APPEND GFLAGS_SRCS  "windows_port.cc")
 140 endif ()
 141
 142 # ----------------------------------------------------------------------------
 143 # configure source files
 144 if (CMAKE_COMPILER_IS_GNUCXX)
 145   set (GFLAGS_ATTRIBUTE_UNUSED "__attribute((unused))")
 146 else ()
 147   set (GFLAGS_ATTRIBUTE_UNUSED)
 148 endif ()
 149
 150 configure_headers (PUBLIC_HDRS  ${PUBLIC_HDRS})
 151 configure_sources (PRIVATE_HDRS ${PRIVATE_HDRS})
 152 configure_sources (GFLAGS_SRCS  ${GFLAGS_SRCS})
 153
 154 # ----------------------------------------------------------------------------
 155 # output directories
 156 set (CMAKE_RUNTIME_OUTPUT_DIRECTORY "bin")
 157 set (CMAKE_LIBRARY_OUTPUT_DIRECTORY "lib")
 158 set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY "lib")
 159
 160 # ----------------------------------------------------------------------------
 161 # add library target
 162 include_directories ("${PROJECT_SOURCE_DIR}/src")
 163 include_directories ("${PROJECT_BINARY_DIR}/include")
 164 include_directories ("${PROJECT_BINARY_DIR}/include/${GFLAGS_NAMESPACE}")
 165
 166 set (LIB_TARGETS)
 167 if (BUILD_gflags_LIB)
 168   add_library (gflags ${GFLAGS_SRCS} ${PRIVATE_HDRS} ${PUBLIC_HDRS})
 169   if (WIN32 AND BUILD_SHARED_LIBS)
 170     set_target_properties (gflags PROPERTIES COMPILE_DEFINITIONS GFLAGS_DLL_EXPORT)
 171   endif ()
 172   list (APPEND LIB_TARGETS gflags)
 173 endif ()
 174 if (BUILD_gflags_nothreads_LIB)
 175   add_library (gflags_nothreads ${GFLAGS_SRCS} ${PRIVATE_HDRS} ${PUBLIC_HDRS})
 176   if (WIN32 AND BUILD_SHARED_LIBS)
 177     set_target_properties (gflags_nothreads PROPERTIES COMPILE_DEFINITIONS "GFLAGS_DLL_EXPORT;NO_THREADS")
 178   else ()
 179     set_target_properties (gflags_nothreads PROPERTIES COMPILE_DEFINITIONS NO_THREADS)
 180   endif ()
 181   list (APPEND LIB_TARGETS gflags_nothreads)
 182 endif ()
 183
 184 # ----------------------------------------------------------------------------
 185 # installation
 186 if (WIN32)
 187   set (RUNTIME_INSTALL_DIR Bin)
 188   set (LIBRARY_INSTALL_DIR Lib)
 189   set (INCLUDE_INSTALL_DIR Include)
 190   set (CONFIG_INSTALL_DIR  CMake)
 191 else ()
 192   set (RUNTIME_INSTALL_DIR bin)
 193   set (LIBRARY_INSTALL_DIR lib)
 194   set (INCLUDE_INSTALL_DIR include)
 195   set (CONFIG_INSTALL_DIR  lib/cmake/${PACKAGE_NAME})
 196 endif ()
 197
 198 install (TARGETS ${LIB_TARGETS} DESTINATION ${LIBRARY_INSTALL_DIR} EXPORT gflags-lib)
 199 install (FILES   ${PUBLIC_HDRS} DESTINATION ${INCLUDE_INSTALL_DIR}/${GFLAGS_NAMESPACE})
 200
 201 file (RELATIVE_PATH INSTALL_PREFIX_REL2CONFIG_DIR "${CMAKE_INSTALL_PREFIX}/${CONFIG_INSTALL_DIR}" "${CMAKE_INSTALL_PREFIX}")
 202 configure_file (cmake/config.cmake.in  "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-config-install.cmake" @ONLY)
 203 configure_file (cmake/version.cmake.in "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-config-version.cmake" @ONLY)
 204
 205 install (
 206   FILES "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-config-install.cmake"
 207   RENAME ${PACKAGE_NAME}-config.cmake
 208   DESTINATION ${CONFIG_INSTALL_DIR}
 209 )
 210
 211 install (
 212   FILES "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-config-version.cmake"
 213   DESTINATION ${CONFIG_INSTALL_DIR}
 214 )
 215
 216 install (EXPORT gflags-lib DESTINATION ${CONFIG_INSTALL_DIR} FILE ${PACKAGE_NAME}-export.cmake)
 217
 218 if (UNIX)
 219   install (PROGRAMS src/gflags_completions.sh DESTINATION ${RUNTIME_INSTALL_DIR})
 220 endif ()
 221
 222 # ----------------------------------------------------------------------------
 223 # support direct use of build tree
 224 set (INSTALL_PREFIX_REL2CONFIG_DIR .)
 225 export (TARGETS ${LIB_TARGETS} FILE "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-export.cmake")
 226 export (PACKAGE gflags)
 227 configure_file (cmake/config.cmake.in "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-config.cmake" @ONLY)
 228
 229 # ----------------------------------------------------------------------------
 230 # testing - MUST follow the generation of the build tree config file
 231 include (CTest)
 232 if (BUILD_TESTING)
 233   enable_testing ()
 234   add_subdirectory (test)
 235 endif ()