CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(libwebsockets)
   4
   5 set(PACKAGE "libwebsockets")
   6 set(CPACK_PACKAGE_NAME "${PACKAGE}")
   7 set(CPACK_PACKAGE_VERSION_MAJOR "1")
   8 set(CPACK_PACKAGE_VERSION_MINOR "3")
   9 set(CPACK_PACKAGE_VERSION "${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}")
  10 set(CPACK_PACKAGE_VENDOR "andy@warmcat.com")
  11 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "${PACKAGE} ${PACKAGE_VERSION}")
  12 set(SOVERSION "4.0.0")
  13 set(CPACK_SOURCE_GENERATOR "TGZ")
  14 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
  15 set(VERSION "${CPACK_PACKAGE_VERSION}")
  16
  17 set(LWS_LIBRARY_VERSION ${CPACK_PACKAGE_VERSION})
  18 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${PROJECT_SOURCE_DIR}/cmake/")
  19
  20 message(STATUS "CMAKE_TOOLCHAIN_FILE='${CMAKE_TOOLCHAIN_FILE}'")
  21
  22 # Try to find the current Git hash.
  23 find_package(Git)
  24 if(GIT_EXECUTABLE)
  25         execute_process(
  26     WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
  27     COMMAND "${GIT_EXECUTABLE}" log -n 1 --pretty=%h
  28     OUTPUT_VARIABLE GIT_HASH
  29     OUTPUT_STRIP_TRAILING_WHITESPACE
  30     )
  31
  32     set(LWS_BUILD_HASH ${GIT_HASH})
  33     message("Git commit hash: ${LWS_BUILD_HASH}")
  34 endif()
  35
  36 option(LWS_WITH_SSL "Include SSL support (default OpenSSL, CyaSSL if LWS_USE_CYASSL is set)" ON)
  37 option(LWS_SSL_CLIENT_USE_OS_CA_CERTS "SSL support should make use of OS installed CA root certs" ON)
  38 option(LWS_USE_EXTERNAL_ZLIB "Search the system for ZLib instead of using the included one (on Windows)" OFF)
  39 option(LWS_USE_CYASSL "Use CyaSSL replacement for OpenSSL. When settings this, you also need to specify LWS_CYASSL_LIB and LWS_CYASSL_INCLUDE_DIRS" OFF)
  40 option(LWS_WITHOUT_BUILTIN_GETIFADDRS "Don't use BSD getifaddrs implementation from libwebsockets if it is missing (this will result in a compilation error) ... Default is your libc provides it. On some systems such as uclibc it doesn't exist." OFF)
  41 option(LWS_WITHOUT_CLIENT "Don't build the client part of the library" OFF)
  42 option(LWS_WITHOUT_SERVER "Don't build the server part of the library" OFF)
  43 #option(LWS_WITH_LIBCRYPTO "Use libcrypto MD5 and SHA1 implementations" ON)
  44 option(LWS_LINK_TESTAPPS_DYNAMIC "Link the test apps to the shared version of the library. Default is to link statically" OFF)
  45 option(LWS_WITHOUT_TESTAPPS "Don't build the libwebsocket-test-apps" OFF)
  46 option(LWS_WITHOUT_TEST_SERVER "Don't build the test server" OFF)
  47 option(LWS_WITHOUT_TEST_SERVER_EXTPOLL "Don't build the test server version that uses external poll" OFF)
  48 option(LWS_WITHOUT_TEST_PING "Don't build the ping test application" OFF)
  49 option(LWS_WITHOUT_TEST_CLIENT "Don't build the client test application" OFF)
  50 option(LWS_WITHOUT_TEST_FRAGGLE "Don't build the ping test application" OFF)
  51 option(LWS_WITHOUT_DEBUG "Don't compile debug related code" OFF)
  52 option(LWS_WITHOUT_EXTENSIONS "Don't compile with extensions" OFF)
  53 option(LWS_WITH_LATENCY "Build latency measuring code into the library" OFF)
  54 option(LWS_WITHOUT_DAEMONIZE "Don't build the daemonization api" OFF)
  55 option(LWS_WITH_LIBEV "Compile without support for libev" OFF)
  56
  57 # Allow the user to override installation directories.
  58 set(LWS_INSTALL_LIB_DIR       lib CACHE PATH "Installation directory for libraries")
  59 set(LWS_INSTALL_BIN_DIR       bin CACHE PATH "Installation directory for executables")
  60 set(LWS_INSTALL_INCLUDE_DIR   include CACHE PATH "Installation directory for header files")
  61 set(LWS_INSTALL_EXAMPLES_DIR  bin CACHE PATH "Installation directory for example files")
  62
  63 if (LWS_WITHOUT_CLIENT AND LWS_WITHOUT_SERVER)
  64         message(FATAL_ERROR "Makes no sense to compile without both client or server.")
  65 endif()
  66
  67 # The base dir where the test-apps look for the SSL certs.
  68 set(LWS_OPENSSL_CLIENT_CERTS ../share CACHE PATH "Server SSL certificate directory")
  69 if (WIN32)
  70         set(LWS_OPENSSL_CLIENT_CERTS . CACHE PATH "Client SSL certificate directory")
  71 else()
  72         set(LWS_OPENSSL_CLIENT_CERTS /etc/pki/tls/certs/ CACHE PATH "Client SSL certificate directory")
  73 endif()
  74
  75 set(LWS_CYASSL_LIB CACHE PATH "Path to the CyaSSL library")
  76 set(LWS_CYASSL_INCLUDE_DIRS CACHE PATH "Path to the CyaSSL include directory")
  77
  78 if (LWS_USE_CYASSL)
  79         if ("${LWS_CYASSL_LIB}" STREQUAL "" OR "${LWS_CYASSL_INCLUDE_DIRS}" STREQUAL "")
  80                 message(FATAL_ERROR "You must set LWS_CYASSL_LIB and LWS_CYASSL_INCLUDE_DIRS when LWS_USE_CYASSL is turned on")
  81         endif()
  82         set(USE_CYASSL 1)
  83 endif()
  84
  85 if (LWS_WITHOUT_EXTENSIONS)
  86         set(LWS_NO_EXTENSIONS 1)
  87 endif()
  88
  89 if (LWS_WITH_SSL)
  90         set(LWS_OPENSSL_SUPPORT 1)
  91 endif()
  92
  93 if (LWS_SSL_CLIENT_USE_OS_CA_CERTS)
  94         set(LWS_SSL_CLIENT_USE_OS_CA_CERTS 1)
  95 endif()
  96
  97 if (LWS_WITH_LATENCY)
  98         set(LWS_LATENCY 1)
  99 endif()
 100
 101 if (LWS_WITHOUT_DAEMONIZE OR WIN32)
 102         set(LWS_NO_DAEMONIZE 1)
 103 endif()
 104
 105 if (LWS_WITHOUT_SERVER)
 106         set(LWS_NO_SERVER 1)
 107 endif()
 108
 109 if (LWS_WITHOUT_CLIENT)
 110         set(LWS_NO_CLIENT 1)
 111 endif()
 112
 113 if (LWS_WITHOUT_DEBUG)
 114         set(_DEBUG 0)
 115 else()
 116         set(_DEBUG 1)
 117 endif()
 118
 119 if (LWS_WITH_LIBEV)
 120         set(LWS_USE_LIBEV 1)
 121         set(LWS_NO_EXTERNAL_POLL 1)
 122 endif()
 123
 124 if (MINGW)
 125         set(LWS_MINGW_SUPPORT 1)
 126 endif()
 127
 128 include_directories("${PROJECT_BINARY_DIR}")
 129
 130 include(CheckCSourceCompiles)
 131
 132 # Check for different inline keyword versions.
 133 foreach(KEYWORD "inline" "__inline__" "__inline")
 134         set(CMAKE_REQUIRED_DEFINITIONS "-DKEYWORD=${KEYWORD}")
 135         CHECK_C_SOURCE_COMPILES(
 136                 "
 137                 #include <stdio.h>
 138                 KEYWORD void a() {}
 139                 int main(int argc, char **argv) { a(); return 0; }
 140                 " HAVE_${KEYWORD})
 141 endforeach()
 142
 143 if (NOT HAVE_inline)
 144         if (HAVE___inline__)
 145                 set(inline __inline__)
 146         elseif(HAVE___inline)
 147                 set(inline __inline)
 148         endif()
 149 endif()
 150
 151 # Put the libaries and binaries that get built into directories at the
 152 # top of the build tree rather than in hard-to-find leaf directories.
 153 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin")
 154 SET(CMAKE_LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/lib")
 155 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/lib")
 156
 157 # Put absolute path of dynamic libraries into the object code. Some
 158 # architectures, notably Mac OS X, need this.
 159 SET(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}")
 160
 161 # So we can include the CMake generated config file only when
 162 # building with CMAKE.
 163 add_definitions(-DCMAKE_BUILD)
 164
 165 include(CheckFunctionExists)
 166 include(CheckIncludeFile)
 167 include(CheckIncludeFiles)
 168 include(CheckLibraryExists)
 169 include(CheckTypeSize)
 170
 171 CHECK_FUNCTION_EXISTS(bzero HAVE_BZERO)
 172 CHECK_FUNCTION_EXISTS(fork HAVE_FORK)
 173 CHECK_FUNCTION_EXISTS(getenv HAVE_GETENV)
 174 CHECK_FUNCTION_EXISTS(malloc HAVE_MALLOC)
 175 CHECK_FUNCTION_EXISTS(memset HAVE_MEMSET)
 176 CHECK_FUNCTION_EXISTS(realloc HAVE_REALLOC)
 177 CHECK_FUNCTION_EXISTS(socket HAVE_SOCKET)
 178 CHECK_FUNCTION_EXISTS(strerror HAVE_STRERROR)
 179 CHECK_FUNCTION_EXISTS(vfork HAVE_VFORK)
 180 CHECK_FUNCTION_EXISTS(getifaddrs HAVE_GETIFADDRS)
 181
 182 if (NOT HAVE_GETIFADDRS)
 183         if (LWS_WITHOUT_BUILTIN_GETIFADDRS)
 184                 message(FATAL_ERROR "No getifaddrs was found on the system. Turn off the LWS_WITHOUT_BUILTIN_GETIFADDRS compile option to use the supplied BSD version.")
 185         endif()
 186
 187         set(LWS_BUILTIN_GETIFADDRS 1)
 188 endif()
 189
 190 CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 191 CHECK_INCLUDE_FILE(fcntl.h HAVE_FCNTL_H)
 192 CHECK_INCLUDE_FILE(inttypes.h HAVE_INTTYPES_H)
 193 CHECK_INCLUDE_FILE(memory.h HAVE_MEMORY_H)
 194 CHECK_INCLUDE_FILE(netinet/in.h HAVE_NETINET_IN_H)
 195 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 196 CHECK_INCLUDE_FILE(stdlib.h HAVE_STDLIB_H)
 197 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 198 CHECK_INCLUDE_FILE(string.h HAVE_STRING_H)
 199 CHECK_INCLUDE_FILE(sys/prctl.h HAVE_SYS_PRCTL_H)
 200 CHECK_INCLUDE_FILE(sys/socket.h HAVE_SYS_SOCKET_H)
 201 CHECK_INCLUDE_FILE(sys/stat.h HAVE_SYS_STAT_H)
 202 CHECK_INCLUDE_FILE(sys/types.h HAVE_SYS_TYPES_H)
 203 CHECK_INCLUDE_FILE(unistd.h HAVE_UNISTD_H)
 204 CHECK_INCLUDE_FILE(vfork.h HAVE_VFORK_H)
 205 CHECK_INCLUDE_FILE(zlib.h HAVE_ZLIB_H)
 206
 207 # TODO: These can be tested if they actually work also...
 208 set(HAVE_WORKING_FORK HAVE_FORK)
 209 set(HAVE_WORKING_VFORK HAVE_VFORK)
 210
 211 CHECK_INCLUDE_FILES("stdlib.h;stdarg.h;string.h;float.h" STDC_HEADERS)
 212
 213 CHECK_TYPE_SIZE(pid_t PID_T_SIZE)
 214 CHECK_TYPE_SIZE(size_t SIZE_T_SIZE)
 215
 216 if (NOT PID_T_SIZE)
 217         set(pid_t int)
 218 endif()
 219
 220 if (NOT SIZE_T_SIZE)
 221         set(size_t "unsigned int")
 222 endif()
 223
 224 if (NOT HAVE_MALLOC)
 225         set(malloc rpl_malloc)
 226 endif()
 227
 228 if (NOT HAVE_REALLOC)
 229         set(realloc rpl_realloc)
 230 endif()
 231
 232 # Generate the config.h that includes all the compilation settings.
 233 configure_file(
 234        "${PROJECT_SOURCE_DIR}/config.h.cmake"
 235        "${PROJECT_BINARY_DIR}/lws_config.h")
 236
 237 if (MSVC)
 238         # Turn off stupid microsoft security warnings.
 239         add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
 240 endif(MSVC)
 241
 242 include_directories("${PROJECT_SOURCE_DIR}/lib")
 243
 244 # Group headers and sources.
 245 # Some IDEs use this for nicer file structure.
 246 set(HDR_PRIVATE
 247         lib/private-libwebsockets.h
 248         "${PROJECT_BINARY_DIR}/lws_config.h"
 249         )
 250
 251 set(HDR_PUBLIC
 252         "${PROJECT_SOURCE_DIR}/lib/libwebsockets.h"
 253         )
 254
 255 set(SOURCES
 256         lib/base64-decode.c
 257         lib/handshake.c
 258         lib/libwebsockets.c
 259         lib/output.c
 260         lib/parsers.c
 261         lib/sha-1.c
 262         )
 263
 264 if (NOT LWS_WITHOUT_CLIENT)
 265         list(APPEND SOURCES
 266                 lib/client.c
 267                 lib/client-handshake.c
 268                 lib/client-parser.c
 269                 )
 270 endif()
 271
 272 if (NOT LWS_WITHOUT_SERVER)
 273         list(APPEND SOURCES
 274                 lib/server.c
 275                 lib/server-handshake.c
 276                 )
 277 endif()
 278
 279 if (NOT LWS_WITHOUT_EXTENSIONS)
 280         list(APPEND HDR_PRIVATE
 281                 lib/extension-deflate-frame.h
 282                 lib/extension-deflate-stream.h
 283                 )
 284
 285         list(APPEND SOURCES
 286                 lib/extension.c
 287                 lib/extension-deflate-frame.c
 288                 lib/extension-deflate-stream.c
 289                 )
 290 endif()
 291
 292 # Add helper files for Windows.
 293 if (WIN32)
 294         set(WIN32_HELPERS_PATH win32port/win32helpers)
 295
 296         list(APPEND HDR_PUBLIC
 297                 ${WIN32_HELPERS_PATH}/websock-w32.h
 298                 )
 299         if (NOT MINGW)
 300                 list(APPEND SOURCES
 301                         ${WIN32_HELPERS_PATH}/websock-w32.c
 302                         )
 303         endif()
 304         include_directories(${WIN32_HELPERS_PATH})
 305 else(WIN32)
 306         # Unix.
 307         if (NOT LWS_WITHOUT_DAEMONIZE)
 308                 list(APPEND SOURCES
 309                         lib/daemonize.c
 310                         )
 311         endif()
 312 endif(WIN32)
 313
 314 if (UNIX)
 315         if (NOT HAVE_GETIFADDRS)
 316                 list(APPEND HDR_PRIVATE lib/getifaddrs.h)
 317                 list(APPEND SOURCES lib/getifaddrs.c)
 318         endif()
 319 endif(UNIX)
 320
 321
 322 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
 323     if (UNIX)
 324         set( CMAKE_C_FLAGS "-Wall -Werror -O4 -fvisibility=hidden ${CMAKE_C_FLAGS}" )
 325     else(UNIX)
 326         set( CMAKE_C_FLAGS "-Wall -O4 -fvisibility=hidden ${CMAKE_C_FLAGS}" )
 327     endif(UNIX)
 328 endif ()
 329
 330 source_group("Headers Private"  FILES ${HDR_PRIVATE})
 331 source_group("Headers Public"   FILES ${HDR_PUBLIC})
 332 source_group("Sources"          FILES ${SOURCES})
 333
 334 #
 335 # Create the lib.
 336 #
 337 add_library(websockets STATIC
 338                         ${HDR_PRIVATE}
 339                         ${HDR_PUBLIC}
 340                         ${SOURCES})
 341 add_library(websockets_shared SHARED
 342                         ${HDR_PRIVATE}
 343                         ${HDR_PUBLIC}
 344                         ${SOURCES})
 345
 346 if (WIN32)
 347         # On Windows libs have the same file ending (.lib)
 348         # for both static and shared libraries, so we
 349         # need a unique name for the static one.
 350         set_target_properties(websockets
 351                 PROPERTIES
 352                 OUTPUT_NAME websockets_static)
 353
 354         # Compile as DLL (export function declarations)
 355         set_property(
 356                 TARGET websockets_shared
 357                 PROPERTY COMPILE_DEFINITIONS
 358                 LWS_DLL
 359                 LWS_INTERNAL
 360                 )
 361 endif(WIN32)
 362
 363 # We want the shared lib to be named "libwebsockets"
 364 # not "libwebsocket_shared".
 365 set_target_properties(websockets_shared
 366                 PROPERTIES
 367                 OUTPUT_NAME websockets)
 368
 369 # Set the so version of the lib.
 370 # Equivalent to LDFLAGS=-version-info x:x:x
 371 if(CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
 372         foreach(lib websockets websockets_shared)
 373                 set_target_properties(${lib}
 374                         PROPERTIES
 375                         SOVERSION ${SOVERSION})
 376         endforeach()
 377 endif()
 378
 379 set(LIB_LIST)
 380
 381 #
 382 # Find libraries.
 383 #
 384
 385 #
 386 # ZLIB (Only needed for deflate extensions).
 387 #
 388 if (NOT LWS_WITHOUT_EXTENSIONS)
 389         if (WIN32 AND NOT LWS_USE_EXTERNAL_ZLIB)
 390                 message("Using included Zlib version")
 391
 392                 # Compile ZLib if needed.
 393                 set(WIN32_ZLIB_PATH "win32port/zlib")
 394                 set(ZLIB_SRCS
 395                         ${WIN32_ZLIB_PATH}/adler32.c
 396                         ${WIN32_ZLIB_PATH}/compress.c
 397                         ${WIN32_ZLIB_PATH}/crc32.c
 398                         ${WIN32_ZLIB_PATH}/deflate.c
 399                         ${WIN32_ZLIB_PATH}/gzclose.c
 400                         ${WIN32_ZLIB_PATH}/gzio.c
 401                         ${WIN32_ZLIB_PATH}/gzlib.c
 402                         ${WIN32_ZLIB_PATH}/gzread.c
 403                         ${WIN32_ZLIB_PATH}/gzwrite.c
 404                         ${WIN32_ZLIB_PATH}/infback.c
 405                         ${WIN32_ZLIB_PATH}/inffast.c
 406                         ${WIN32_ZLIB_PATH}/inflate.c
 407                         ${WIN32_ZLIB_PATH}/inftrees.c
 408                         ${WIN32_ZLIB_PATH}/trees.c
 409                         ${WIN32_ZLIB_PATH}/uncompr.c
 410                         ${WIN32_ZLIB_PATH}/zutil.c
 411                 )
 412
 413                 # Create the library.
 414                 add_library(ZLIB STATIC ${ZLIB_SRCS})
 415
 416                 # Set the same variables as find_package would.
 417                 set(ZLIB_INCLUDE_DIRS ${WIN32_ZLIB_PATH})
 418                 get_property(ZLIB_LIBRARIES TARGET ZLIB PROPERTY LOCATION)
 419                 set(ZLIB_FOUND 1)
 420         else()
 421                 find_package(ZLIB REQUIRED)
 422         endif()
 423
 424         # Make sure ZLib is compiled before the libs.
 425         foreach (lib websockets websockets_shared)
 426                 add_dependencies(${lib} ZLIB)
 427         endforeach()
 428
 429         message("ZLib include dirs: ${ZLIB_INCLUDE_DIRS}")
 430         message("ZLib libraries: ${ZLIB_LIBRARIES}")
 431         include_directories(${ZLIB_INCLUDE_DIRS})
 432         list(APPEND LIB_LIST ${ZLIB_LIBRARIES})
 433 endif(NOT LWS_WITHOUT_EXTENSIONS)
 434
 435 #
 436 # OpenSSL
 437 #
 438 if (LWS_WITH_SSL)
 439         message("Compiling with SSL support")
 440
 441         if (LWS_USE_CYASSL)
 442                 # Use CyaSSL as OpenSSL replacement.
 443                 # TODO: Add a find_package command for this also.
 444                 message("CyaSSL include dir: ${LWS_CYASSL_INCLUDE_DIRS}")
 445                 message("CyaSSL libraries: ${LWS_CYASSL_LIB}")
 446
 447                 # Additional to the root directory we need to include
 448                 # the cyassl/ subdirectory which contains the OpenSSL
 449                 # compatability layer headers.
 450                 foreach(inc ${LWS_CYASSL_INCLUDE_DIRS})
 451                         include_directories("${inc}" "${inc}/cyassl")
 452                 endforeach()
 453
 454                 list(APPEND LIB_LIST "${LWS_CYASSL_LIB}")
 455         else()
 456                 # TODO: Add support for STATIC also.
 457                 find_package(OpenSSL REQUIRED)
 458
 459                 message("OpenSSL include dir: ${OPENSSL_INCLUDE_DIR}")
 460                 message("OpenSSL libraries: ${OPENSSL_LIBRARIES}")
 461
 462                 include_directories("${OPENSSL_INCLUDE_DIR}")
 463                 list(APPEND LIB_LIST ${OPENSSL_LIBRARIES})
 464         endif()
 465 endif(LWS_WITH_SSL)
 466
 467 if (LWS_WITH_LIBEV)
 468         list(APPEND LIB_LIST "ev")
 469 endif(LWS_WITH_LIBEV)
 470
 471 #
 472 # Platform specific libs.
 473 #
 474 if (WINCE)
 475         list(APPEND LIB_LIST ws2.lib)
 476 elseif (WIN32)
 477         list(APPEND LIB_LIST ws2_32.lib)
 478 endif()
 479
 480 if (UNIX)
 481         list(APPEND LIB_LIST m)
 482 endif()
 483
 484 # Setup the linking for all libs.
 485 foreach (lib websockets websockets_shared)
 486         target_link_libraries(${lib} ${LIB_LIST})
 487 endforeach()
 488
 489 #
 490 # Test applications
 491 #
 492 set(TEST_APP_LIST)
 493 if (NOT LWS_WITHOUT_TESTAPPS)
 494         #
 495         # Helper function for adding a test app.
 496         #
 497         macro(create_test_app TEST_NAME MAIN_SRC WIN32_SRCS WIN32_HDRS)
 498
 499                 set(TEST_SRCS ${MAIN_SRC})
 500                 set(TEST_HDR)
 501
 502                 if (WIN32)
 503                         list(APPEND TEST_SRCS
 504                                 ${WIN32_HELPERS_PATH}/getopt.c
 505                                 ${WIN32_HELPERS_PATH}/getopt_long.c
 506                                 ${WIN32_HELPERS_PATH}/gettimeofday.c
 507                                 ${WIN32_SRCS})
 508
 509                         list(APPEND TEST_HDR
 510                                 ${WIN32_HELPERS_PATH}/getopt.h
 511                                 ${WIN32_HELPERS_PATH}/gettimeofday.h
 512                                 ${WIN32_HDRS})
 513                 endif(WIN32)
 514
 515                 source_group("Headers Private"   FILES ${TEST_HDR})
 516                 source_group("Sources"   FILES ${TEST_SRCS})
 517                 add_executable(${TEST_NAME} ${TEST_SRCS} ${TEST_HDR})
 518
 519                 if (LWS_LINK_TESTAPPS_DYNAMIC)
 520                         target_link_libraries(${TEST_NAME} websockets_shared)
 521                         add_dependencies(${TEST_NAME} websockets_shared)
 522                 else(LWS_LINK_TESTAPPS_DYNAMIC)
 523                         target_link_libraries(${TEST_NAME} websockets)
 524                         add_dependencies(${TEST_NAME} websockets)
 525                 endif(LWS_LINK_TESTAPPS_DYNAMIC)
 526
 527                 # Set test app specific defines.
 528                 set_property(TARGET ${TEST_NAME}
 529                                         PROPERTY COMPILE_DEFINITIONS
 530                                                 INSTALL_DATADIR="${CMAKE_INSTALL_PREFIX}/share"
 531                                         )
 532
 533                 # Prefix the binary names with libwebsockets.
 534                 set_target_properties(${TEST_NAME}
 535                         PROPERTIES
 536                         OUTPUT_NAME libwebsockets-${TEST_NAME})
 537
 538                 # Add to the list of tests.
 539                 list(APPEND TEST_APP_LIST ${TEST_NAME})
 540         endmacro()
 541
 542         if (LWS_WITH_SSL AND NOT LWS_USE_CYASSL)
 543                 message("Searching for OpenSSL executable and dlls")
 544                 find_package(OpenSSLbins)
 545                 message("OpenSSL executable: ${OPENSSL_EXECUTABLE}")
 546         endif()
 547
 548         if (NOT LWS_WITHOUT_SERVER)
 549                 #
 550                 # test-server
 551                 #
 552                 if (NOT LWS_WITHOUT_TEST_SERVER)
 553                         create_test_app(test-server
 554                                 "test-server/test-server.c"
 555                                 ""
 556                                 "${WIN32_HELPERS_PATH}/netdb.h;${WIN32_HELPERS_PATH}/strings.h;${WIN32_HELPERS_PATH}/unistd.h;${WIN32_HELPERS_PATH}/websock-w32.h")
 557                 endif()
 558
 559                 #
 560                 # test-server-extpoll
 561                 #
 562                 if (NOT LWS_WITHOUT_TEST_SERVER_EXTPOLL)
 563                         create_test_app(test-server-extpoll
 564                                 "test-server/test-server.c"
 565                                 "win32port/win32helpers/websock-w32.c"
 566                                 "${WIN32_HELPERS_PATH}/netdb.h;${WIN32_HELPERS_PATH}/strings.h;${WIN32_HELPERS_PATH}/unistd.h;${WIN32_HELPERS_PATH}/websock-w32.h")
 567                         # Set defines for this executable only.
 568                         set_property(
 569                                 TARGET test-server-extpoll
 570                                 PROPERTY COMPILE_DEFINITIONS
 571                                         EXTERNAL_POLL
 572                                         INSTALL_DATADIR="${CMAKE_INSTALL_PREFIX}/share"
 573                                 )
 574
 575                         # We need to link against winsock code.
 576                         if (WIN32)
 577                                 target_link_libraries(test-server-extpoll ws2_32.lib)
 578                         endif(WIN32)
 579                 endif()
 580
 581                 # Data files for running the test server.
 582                 set(TEST_SERVER_DATA
 583                         "${PROJECT_SOURCE_DIR}/test-server/favicon.ico"
 584                         "${PROJECT_SOURCE_DIR}/test-server/leaf.jpg"
 585                         "${PROJECT_SOURCE_DIR}/test-server/libwebsockets.org-logo.png"
 586                         "${PROJECT_SOURCE_DIR}/test-server/test.html")
 587
 588                 # Generate self-signed SSL certs for the test-server.
 589                 if (LWS_WITH_SSL AND OPENSSL_EXECUTABLE AND NOT LWS_WITHOUT_TEST_SERVER)
 590                         message("Generating SSL Certificates for the test-server...")
 591
 592                         set(TEST_SERVER_SSL_KEY "${PROJECT_BINARY_DIR}/libwebsockets-test-server.key.pem")
 593                         set(TEST_SERVER_SSL_CERT "${PROJECT_BINARY_DIR}/libwebsockets-test-server.pem")
 594
 595                         if (WIN32)
 596                                 file(WRITE "${PROJECT_BINARY_DIR}/openssl_input.txt"
 597                                         "GB\n"
 598                                         "Erewhon\n"
 599                                         "All around\n"
 600                                         "libwebsockets-test\n"
 601                                         "localhost\n"
 602                                         "none@invalid.org\n\n"
 603                                         )
 604
 605                                 # The "type" command is a bit picky with paths.
 606                                 file(TO_NATIVE_PATH "${PROJECT_BINARY_DIR}/openssl_input.txt" OPENSSL_INPUT_WIN_PATH)
 607                                 message("OPENSSL_INPUT_WIN_PATH = ${OPENSSL_INPUT_WIN_PATH}")
 608                                 message("cmd = \"${OPENSSL_EXECUTABLE}\" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout \"${TEST_SERVER_SSL_KEY}\" -out \"${TEST_SERVER_SSL_CERT}\"")
 609
 610                                 execute_process(
 611                                         COMMAND cmd /c type "${OPENSSL_INPUT_WIN_PATH}"
 612                                         COMMAND "${OPENSSL_EXECUTABLE}" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 613                                         RESULT_VARIABLE OPENSSL_RETURN_CODE)
 614
 615                                 message("\n")
 616
 617                                 if (OPENSSL_RETURN_CODE)
 618                                         message(WARNING "!!! Failed to generate SSL certificate for Test Server using cmd.exe !!!:\nOpenSSL return code = ${OPENSSL_RETURN_CODE}")
 619                                 else()
 620                                         message("SUCCSESFULLY generated SSL certificate")
 621                                 endif()
 622                         else()
 623                                 # Unix.
 624                                 execute_process(
 625                                         COMMAND printf "GB\\nErewhon\\nAll around\\nlibwebsockets-test\\n\\nlocalhost\\nnone@invalid.org\\n"
 626                                         COMMAND "${OPENSSL_EXECUTABLE}"
 627                                                 req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 628                                         RESULT_VARIABLE OPENSSL_RETURN_CODE)
 629
 630                                 if (OPENSSL_RETURN_CODE)
 631                                         message(WARNING "!!! Failed to generate SSL certificate for Test Server!!!:\nOpenSSL return code = ${OPENSSL_RETURN_CODE}")
 632                                 else()
 633                                         message("SUCCSESFULLY generated SSL certificate")
 634                                 endif()
 635                         endif()
 636
 637                         list(APPEND TEST_SERVER_DATA
 638                                 "${TEST_SERVER_SSL_KEY}"
 639                                 "${TEST_SERVER_SSL_CERT}")
 640                 endif()
 641
 642                 add_custom_command(TARGET test-server
 643                                                 POST_BUILD
 644                                                 COMMAND "${CMAKE_COMMAND}" -E make_directory "$<TARGET_FILE_DIR:test-server>/../share/libwebsockets-test-server")
 645
 646                 # Copy the file needed to run the server so that the test apps can
 647                 # reach them from their default output location
 648                 foreach (TEST_FILE ${TEST_SERVER_DATA})
 649                         if (EXISTS ${TEST_FILE})
 650                                 add_custom_command(TARGET test-server
 651                                                         POST_BUILD
 652                                                         COMMAND "${CMAKE_COMMAND}" -E copy "${TEST_FILE}" "$<TARGET_FILE_DIR:test-server>/../share/libwebsockets-test-server" VERBATIM)
 653                         endif()
 654                 endforeach()
 655         endif(NOT LWS_WITHOUT_SERVER)
 656
 657         if (NOT LWS_WITHOUT_CLIENT)
 658                 #
 659                 # test-client
 660                 #
 661                 if (NOT LWS_WITHOUT_TEST_CLIENT)
 662                         create_test_app(test-client
 663                                 "test-server/test-client.c"
 664                                 ""
 665                                 "")
 666                 endif()
 667
 668                 #
 669                 # test-fraggle
 670                 #
 671                 if (NOT LWS_WITHOUT_TEST_FRAGGLE)
 672                         create_test_app(test-fraggle
 673                                 "test-server/test-fraggle.c"
 674                                 ""
 675                                 "${WIN32_HELPERS_PATH}/unistd.h;${WIN32_HELPERS_PATH}/sys/time.h")
 676                 endif()
 677
 678                 #
 679                 # test-ping
 680                 #
 681                 if (NOT LWS_WITHOUT_TEST_PING)
 682                         create_test_app(test-ping
 683                                 "test-server/test-ping.c"
 684                                 ""
 685                                 "${WIN32_HELPERS_PATH}/unistd.h;${WIN32_HELPERS_PATH}/sys/time.h")
 686                 endif()
 687                 #
 688                 # test-echo
 689                 #
 690                 if (NOT WITHOUT_TEST_ECHO)
 691                         create_test_app(test-echo
 692                                 "test-server/test-echo.c"
 693                                 ""
 694                                 "${WIN32_HELPERS_PATH}/unistd.h;${WIN32_HELPERS_PATH}/sys/time.h")
 695                 endif()
 696
 697         endif(NOT LWS_WITHOUT_CLIENT)
 698
 699         #
 700         # Copy OpenSSL dlls to the output directory on Windows.
 701         # (Otherwise we'll get an error when trying to run)
 702         #
 703         if (WIN32 AND LWS_WITH_SSL AND NOT LWS_USE_CYASSL)
 704                 if(OPENSSL_BIN_FOUND)
 705                         message("OpenSSL dlls found:")
 706                         message("  Libeay: ${LIBEAY_BIN}")
 707                         message("  SSLeay: ${SSLEAY_BIN}")
 708
 709                         foreach(TARGET_BIN ${TEST_APP_LIST})
 710                                 add_custom_command(TARGET ${TARGET_BIN}
 711                                         POST_BUILD
 712                                         COMMAND "${CMAKE_COMMAND}" -E copy "${LIBEAY_BIN}" "$<TARGET_FILE_DIR:${TARGET_BIN}>" VERBATIM)
 713
 714                                 add_custom_command(TARGET ${TARGET_BIN}
 715                                         POST_BUILD
 716                                         COMMAND "${CMAKE_COMMAND}" -E copy "${SSLEAY_BIN}" "$<TARGET_FILE_DIR:${TARGET_BIN}>" VERBATIM)
 717                         endforeach()
 718                 endif()
 719         endif()
 720 endif(NOT LWS_WITHOUT_TESTAPPS)
 721
 722 if (UNIX)
 723         # Generate documentation.
 724         # TODO: Fix this on Windows.
 725         message("Generating API documentation")
 726         file(GLOB C_FILES "${PROJECT_SOURCE_DIR}/lib/*.c")
 727         execute_process(COMMAND "${CMAKE_COMMAND}" -E make_directory "${PROJECT_BINARY_DIR}/doc/")
 728
 729         execute_process(
 730                 COMMAND "${PROJECT_SOURCE_DIR}/scripts/kernel-doc" -html ${C_FILES} ${HDR_PUBLIC}
 731                 OUTPUT_FILE "${PROJECT_BINARY_DIR}/doc/libwebsockets-api-doc.html"
 732                 ERROR_QUIET)
 733
 734         execute_process(
 735                 COMMAND "${PROJECT_SOURCE_DIR}/scripts/kernel-doc" -text ${C_FILES} ${HDR_PUBLIC}
 736                 OUTPUT_FILE "${PROJECT_BINARY_DIR}/doc/libwebsockets-api-doc.txt"
 737                 ERROR_QUIET)
 738
 739 # Generate and install pkgconfig.
 740 # (This is not indented, because the tabs will be part of the output)
 741 file(WRITE "${PROJECT_BINARY_DIR}/libwebsockets.pc"
 742 "prefix=\"${CMAKE_INSTALL_PREFIX}\"
 743 exec_prefix=\${prefix}
 744 libdir=\${exec_prefix}/lib${LIB_SUFFIX}
 745 includedir=\${prefix}/include
 746
 747 Name: libwebsockets
 748 Description: Websockets server and client library
 749 Version: ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}
 750
 751 Libs: -L\${libdir} -lwebsockets
 752 Cflags: -I\${includedir}"
 753 )
 754
 755         install(FILES "${PROJECT_BINARY_DIR}/libwebsockets.pc"
 756                 DESTINATION lib${LIB_SUFFIX}/pkgconfig)
 757 endif(UNIX)
 758
 759 #
 760 # Installation preparations.
 761 #
 762
 763 if(WIN32 AND NOT CYGWIN)
 764   set(DEF_INSTALL_CMAKE_DIR cmake)
 765 else()
 766   set(DEF_INSTALL_CMAKE_DIR lib/cmake/libwebsockets)
 767 endif()
 768
 769 set(LWS_INSTALL_CMAKE_DIR ${DEF_INSTALL_CMAKE_DIR} CACHE PATH "Installation directory for CMake files")
 770
 771 # Export targets (This is used for other CMake projects to easily find the libraries and include files).
 772 export(TARGETS websockets websockets_shared
 773         FILE "${PROJECT_BINARY_DIR}/LibwebsocketsTargets.cmake")
 774 export(PACKAGE libwebsockets)
 775
 776 # Generate the config file for the build-tree.
 777 set(LWS__INCLUDE_DIRS
 778     "${PROJECT_SOURCE_DIR}/lib"
 779     "${PROJECT_BINARY_DIR}")
 780 set(LIBWEBSOCKETS_INCLUDE_DIRS ${LWS__INCLUDE_DIRS} CACHE PATH "Libwebsockets include directories")
 781 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfig.cmake.in
 782                 ${PROJECT_BINARY_DIR}/LibwebsocketsConfig.cmake
 783                 @ONLY)
 784
 785 # Generate the config file for the installation tree.
 786 get_filename_component(LWS_ABSOLUTE_INSTALL_CMAKE_DIR ${LWS_INSTALL_CMAKE_DIR} ABSOLUTE)
 787 get_filename_component(LWS_ABSOLUTE_INSTALL_INCLUDE_DIR ${LWS_INSTALL_INCLUDE_DIR} ABSOLUTE)
 788 file(RELATIVE_PATH
 789     REL_INCLUDE_DIR
 790     "${LWS_ABSOLUTE_INSTALL_CMAKE_DIR}"
 791     "${LWS_ABSOLUTE_INSTALL_INCLUDE_DIR}") # Calculate the relative directory from the cmake dir.
 792
 793 # Note the EVENT_CMAKE_DIR is defined in JanssonConfig.cmake.in,
 794 # we escape it here so it's evaluated when it is included instead
 795 # so that the include dirs are given relative to where the
 796 # config file is located.
 797 set(LWS__INCLUDE_DIRS
 798     "\${LWS_CMAKE_DIR}/${REL_INCLUDE_DIR}")
 799 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfig.cmake.in
 800                 ${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/LibwebsocketsConfig.cmake
 801                 @ONLY)
 802
 803 # Generate version info for both build-tree and install-tree.
 804 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfigVersion.cmake.in
 805                 ${PROJECT_BINARY_DIR}/LibwebsocketsConfigVersion.cmake
 806                 @ONLY)
 807
 808 set_target_properties(websockets websockets_shared
 809                                         PROPERTIES PUBLIC_HEADER "${HDR_PUBLIC}")
 810
 811 #
 812 # Installation.
 813 #
 814
 815 # Install libs and headers.
 816 install(TARGETS websockets websockets_shared
 817                 EXPORT LibwebsocketsTargets
 818                 LIBRARY DESTINATION "${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}" COMPONENT libraries
 819                 ARCHIVE DESTINATION "${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}" COMPONENT libraries
 820                 RUNTIME DESTINATION "${LWS_INSTALL_BIN_DIR}" COMPONENT libraries # Windows DLLs
 821                 PUBLIC_HEADER DESTINATION "${LWS_INSTALL_INCLUDE_DIR}" COMPONENT dev)
 822 set(CPACK_COMPONENT_LIBRARIES_DISPLAY_NAME "Libraries")
 823 set(CPACK_COMPONENT_DEV_DISPLAY_NAME "Development files")
 824
 825 # Install test apps.
 826 if (NOT LWS_WITHOUT_TESTAPPS AND NOT LWS_WITHOUT_CLIENT)
 827         install(TARGETS test-client ${TEST_APP_LIST}
 828                         RUNTIME DESTINATION ${LWS_INSTALL_EXAMPLES_DIR}
 829                         COMPONENT examples)
 830         set(CPACK_COMPONENT_EXAMPLES_DISPLAY_NAME "Example files")
 831 endif()
 832
 833 # Programs shared files used by the test-server.
 834 if (NOT LWS_WITHOUT_TESTAPPS AND NOT LWS_WITHOUT_SERVER)
 835         install(FILES ${TEST_SERVER_DATA}
 836                         DESTINATION share/libwebsockets-test-server
 837                         COMPONENT examples)
 838 endif()
 839
 840 # Install exports for the install-tree.
 841 install(EXPORT LibwebsocketsTargets
 842                 DESTINATION "${LWS_INSTALL_CMAKE_DIR}" COMPONENT dev)
 843
 844 # build subdir is not part of sources
 845 set(CPACK_SOURCE_IGNORE_FILES $(CPACK_SOURCE_IGNORE_FILES) ".git" "build" "tgz" "tar.gz")
 846
 847 # Most people are more used to "make dist" compared to "make package_source"
 848 add_custom_target(dist COMMAND "${CMAKE_MAKE_PROGRAM}" package_source)
 849
 850 include(UseRPMTools)
 851 if (RPMTools_FOUND)
 852         RPMTools_ADD_RPM_TARGETS(libwebsockets libwebsockets.spec)
 853 endif()
 854
 855 message("---------------------------------------------------------------------")
 856 message("  Settings:  (For more help do cmake -LH <srcpath>")
 857 message("---------------------------------------------------------------------")
 858 message(" LWS_WITH_SSL = ${LWS_WITH_SSL}  (SSL Support)")
 859 message(" LWS_SSL_CLIENT_USE_OS_CA_CERTS = ${LWS_SSL_CLIENT_USE_OS_CA_CERTS}")
 860 message(" LWS_USE_CYASSL = ${LWS_USE_CYASSL} (CyaSSL replacement for OpenSSL)")
 861 if (LWS_USE_CYASSL)
 862         message("   LWS_CYASSL_LIB = ${LWS_CYASSL_LIB}")
 863         message("   LWS_CYASSL_INCLUDE_DIRS = ${LWS_CYASSL_INCLUDE_DIRS}")
 864 endif()
 865 message(" LWS_WITHOUT_BUILTIN_GETIFADDRS = ${LWS_WITHOUT_BUILTIN_GETIFADDRS}")
 866 message(" LWS_WITHOUT_CLIENT = ${LWS_WITHOUT_CLIENT}")
 867 message(" LWS_WITHOUT_SERVER = ${LWS_WITHOUT_SERVER}")
 868 message(" LWS_LINK_TESTAPPS_DYNAMIC = ${LWS_LINK_TESTAPPS_DYNAMIC}")
 869 message(" LWS_WITHOUT_TESTAPPS = ${LWS_WITHOUT_TESTAPPS}")
 870 message(" LWS_WITHOUT_TEST_SERVER = ${LWS_WITHOUT_TEST_SERVER}")
 871 message(" LWS_WITHOUT_TEST_SERVER_EXTPOLL = ${LWS_WITHOUT_TEST_SERVER_EXTPOLL}")
 872 message(" LWS_WITHOUT_TEST_PING = ${LWS_WITHOUT_TEST_PING}")
 873 message(" LWS_WITHOUT_TEST_CLIENT = ${LWS_WITHOUT_TEST_CLIENT}")
 874 message(" LWS_WITHOUT_TEST_FRAGGLE = ${LWS_WITHOUT_TEST_FRAGGLE}")
 875 message(" LWS_WITHOUT_DEBUG = ${LWS_WITHOUT_DEBUG}")
 876 message(" LWS_WITHOUT_EXTENSIONS = ${LWS_WITHOUT_EXTENSIONS}")
 877 message(" LWS_WITH_LATENCY = ${LWS_WITH_LATENCY}")
 878 message(" LWS_WITHOUT_DAEMONIZE = ${LWS_WITHOUT_DAEMONIZE}")
 879 message(" LWS_USE_LIBEV = ${LWS_USE_LIBEV}")
 880 message("---------------------------------------------------------------------")
 881
 882 # These will be available to parent projects including libwebsockets using add_subdirectory()
 883 set(LIBWEBSOCKETS_LIBRARIES websocket websockets_shared CACHE STRING "Libwebsocket libraries")
 884 set(LIBWEBSOCKETS_LIBRARIES_STATIC websocket CACHE STRING "Libwebsocket static library")
 885 set(LIBWEBSOCKETS_LIBRARIES_SHARED websockets_shared CACHE STRING "Libwebsocket shared library")
 886
 887 # This must always be last!
 888 include(CPack)