CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6)
   2
   3 project(libwebsockets)
   4
   5 set(PACKAGE "libwebsockets")
   6 set(CPACK_PACKAGE_NAME "${PACKAGE}")
   7 set(CPACK_PACKAGE_VERSION_MAJOR "1")
   8 set(CPACK_PACKAGE_VERSION_MINOR "3")
   9 set(CPACK_PACKAGE_VERSION "${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}")
  10 set(CPACK_PACKAGE_VENDOR "andy@warmcat.com")
  11 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "${PACKAGE} ${PACKAGE_VERSION}")
  12 set(SOVERSION "4.0.0")
  13 set(CPACK_SOURCE_GENERATOR "TGZ")
  14 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
  15 set(VERSION "${CPACK_PACKAGE_VERSION}")
  16
  17 set(LWS_LIBRARY_VERSION ${CPACK_PACKAGE_VERSION})
  18 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${PROJECT_SOURCE_DIR}/cmake/")
  19
  20 message(STATUS "CMAKE_TOOLCHAIN_FILE='${CMAKE_TOOLCHAIN_FILE}'")
  21
  22 # Try to find the current Git hash.
  23 find_package(Git)
  24 if(GIT_EXECUTABLE)
  25         execute_process(
  26     WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
  27     COMMAND "${GIT_EXECUTABLE}" log -n 1 --pretty=%h
  28     OUTPUT_VARIABLE GIT_HASH
  29     OUTPUT_STRIP_TRAILING_WHITESPACE
  30     )
  31
  32     set(LWS_BUILD_HASH ${GIT_HASH})
  33     message("Git commit hash: ${LWS_BUILD_HASH}")
  34 endif()
  35
  36 option(LWS_WITH_SSL "Include SSL support (default OpenSSL, CyaSSL if LWS_USE_CYASSL is set)" ON)
  37 option(LWS_SSL_CLIENT_USE_OS_CA_CERTS "SSL support should make use of OS installed CA root certs" ON)
  38 option(LWS_USE_EXTERNAL_ZLIB "Search the system for ZLib instead of using the included one (on Windows)" OFF)
  39 option(LWS_USE_CYASSL "Use CyaSSL replacement for OpenSSL. When settings this, you also need to specify LWS_CYASSL_LIB and LWS_CYASSL_INCLUDE_DIRS" OFF)
  40 option(LWS_WITHOUT_BUILTIN_GETIFADDRS "Don't use BSD getifaddrs implementation from libwebsockets if it is missing (this will result in a compilation error) ... Default is your libc provides it. On some systems such as uclibc it doesn't exist." OFF)
  41 option(LWS_WITHOUT_CLIENT "Don't build the client part of the library" OFF)
  42 option(LWS_WITHOUT_SERVER "Don't build the server part of the library" OFF)
  43 #option(LWS_WITH_LIBCRYPTO "Use libcrypto MD5 and SHA1 implementations" ON)
  44 option(LWS_LINK_TESTAPPS_DYNAMIC "Link the test apps to the shared version of the library. Default is to link statically" OFF)
  45 option(LWS_WITHOUT_TESTAPPS "Don't build the libwebsocket-test-apps" OFF)
  46 option(LWS_WITHOUT_TEST_SERVER "Don't build the test server" OFF)
  47 option(LWS_WITHOUT_TEST_SERVER_EXTPOLL "Don't build the test server version that uses external poll" OFF)
  48 option(LWS_WITHOUT_TEST_PING "Don't build the ping test application" OFF)
  49 option(LWS_WITHOUT_TEST_CLIENT "Don't build the client test application" OFF)
  50 option(LWS_WITHOUT_TEST_FRAGGLE "Don't build the ping test application" OFF)
  51 option(LWS_WITHOUT_DEBUG "Don't compile debug related code" OFF)
  52 option(LWS_WITHOUT_EXTENSIONS "Don't compile with extensions" OFF)
  53 option(LWS_WITH_LATENCY "Build latency measuring code into the library" OFF)
  54 option(LWS_WITHOUT_DAEMONIZE "Don't build the daemonization api" OFF)
  55 option(LWS_WITH_LIBEV "Compile with support for libev" OFF)
  56 option(LWS_WITHOUT_IPV6 "Compile without support for ipv6" OFF)
  57
  58 # Allow the user to override installation directories.
  59 set(LWS_INSTALL_LIB_DIR       lib CACHE PATH "Installation directory for libraries")
  60 set(LWS_INSTALL_BIN_DIR       bin CACHE PATH "Installation directory for executables")
  61 set(LWS_INSTALL_INCLUDE_DIR   include CACHE PATH "Installation directory for header files")
  62 set(LWS_INSTALL_EXAMPLES_DIR  bin CACHE PATH "Installation directory for example files")
  63
  64 if (LWS_WITHOUT_CLIENT AND LWS_WITHOUT_SERVER)
  65         message(FATAL_ERROR "Makes no sense to compile without both client or server.")
  66 endif()
  67
  68 # The base dir where the test-apps look for the SSL certs.
  69 set(LWS_OPENSSL_CLIENT_CERTS ../share CACHE PATH "Server SSL certificate directory")
  70 if (WIN32)
  71         set(LWS_OPENSSL_CLIENT_CERTS . CACHE PATH "Client SSL certificate directory")
  72 else()
  73         set(LWS_OPENSSL_CLIENT_CERTS /etc/pki/tls/certs/ CACHE PATH "Client SSL certificate directory")
  74 endif()
  75
  76 set(LWS_CYASSL_LIB CACHE PATH "Path to the CyaSSL library")
  77 set(LWS_CYASSL_INCLUDE_DIRS CACHE PATH "Path to the CyaSSL include directory")
  78
  79 if (LWS_USE_CYASSL)
  80         if ("${LWS_CYASSL_LIB}" STREQUAL "" OR "${LWS_CYASSL_INCLUDE_DIRS}" STREQUAL "")
  81                 message(FATAL_ERROR "You must set LWS_CYASSL_LIB and LWS_CYASSL_INCLUDE_DIRS when LWS_USE_CYASSL is turned on")
  82         endif()
  83         set(USE_CYASSL 1)
  84 endif()
  85
  86 if (LWS_WITHOUT_EXTENSIONS)
  87         set(LWS_NO_EXTENSIONS 1)
  88 endif()
  89
  90 if (LWS_WITH_SSL)
  91         set(LWS_OPENSSL_SUPPORT 1)
  92 endif()
  93
  94 if (LWS_SSL_CLIENT_USE_OS_CA_CERTS)
  95         set(LWS_SSL_CLIENT_USE_OS_CA_CERTS 1)
  96 endif()
  97
  98 if (LWS_WITH_LATENCY)
  99         set(LWS_LATENCY 1)
 100 endif()
 101
 102 if (LWS_WITHOUT_DAEMONIZE OR WIN32)
 103         set(LWS_NO_DAEMONIZE 1)
 104 endif()
 105
 106 if (LWS_WITHOUT_SERVER)
 107         set(LWS_NO_SERVER 1)
 108 endif()
 109
 110 if (LWS_WITHOUT_CLIENT)
 111         set(LWS_NO_CLIENT 1)
 112 endif()
 113
 114 if (LWS_WITHOUT_DEBUG)
 115         set(_DEBUG 0)
 116 else()
 117         set(_DEBUG 1)
 118 endif()
 119
 120 if (LWS_WITH_LIBEV)
 121         set(LWS_USE_LIBEV 1)
 122         set(LWS_NO_EXTERNAL_POLL 1)
 123 endif()
 124
 125 if (LWS_WITHOUT_IPV6)
 126 else()
 127         set(LWS_WITH_IPV6 1)
 128 endif()
 129
 130 if (MINGW)
 131         set(LWS_MINGW_SUPPORT 1)
 132 endif()
 133
 134 include_directories("${PROJECT_BINARY_DIR}")
 135
 136 include(CheckCSourceCompiles)
 137
 138 # Check for different inline keyword versions.
 139 foreach(KEYWORD "inline" "__inline__" "__inline")
 140         set(CMAKE_REQUIRED_DEFINITIONS "-DKEYWORD=${KEYWORD}")
 141         CHECK_C_SOURCE_COMPILES(
 142                 "
 143                 #include <stdio.h>
 144                 KEYWORD void a() {}
 145                 int main(int argc, char **argv) { a(); return 0; }
 146                 " HAVE_${KEYWORD})
 147 endforeach()
 148
 149 if (NOT HAVE_inline)
 150         if (HAVE___inline__)
 151                 set(inline __inline__)
 152         elseif(HAVE___inline)
 153                 set(inline __inline)
 154         endif()
 155 endif()
 156
 157 # Put the libaries and binaries that get built into directories at the
 158 # top of the build tree rather than in hard-to-find leaf directories.
 159 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin")
 160 SET(CMAKE_LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/lib")
 161 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/lib")
 162
 163 # Put absolute path of dynamic libraries into the object code. Some
 164 # architectures, notably Mac OS X, need this.
 165 SET(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}")
 166
 167 # So we can include the CMake generated config file only when
 168 # building with CMAKE.
 169 add_definitions(-DCMAKE_BUILD)
 170
 171 include(CheckFunctionExists)
 172 include(CheckIncludeFile)
 173 include(CheckIncludeFiles)
 174 include(CheckLibraryExists)
 175 include(CheckTypeSize)
 176
 177 CHECK_FUNCTION_EXISTS(bzero HAVE_BZERO)
 178 CHECK_FUNCTION_EXISTS(fork HAVE_FORK)
 179 CHECK_FUNCTION_EXISTS(getenv HAVE_GETENV)
 180 CHECK_FUNCTION_EXISTS(malloc HAVE_MALLOC)
 181 CHECK_FUNCTION_EXISTS(memset HAVE_MEMSET)
 182 CHECK_FUNCTION_EXISTS(realloc HAVE_REALLOC)
 183 CHECK_FUNCTION_EXISTS(socket HAVE_SOCKET)
 184 CHECK_FUNCTION_EXISTS(strerror HAVE_STRERROR)
 185 CHECK_FUNCTION_EXISTS(vfork HAVE_VFORK)
 186 CHECK_FUNCTION_EXISTS(getifaddrs HAVE_GETIFADDRS)
 187
 188 if (NOT HAVE_GETIFADDRS)
 189         if (LWS_WITHOUT_BUILTIN_GETIFADDRS)
 190                 message(FATAL_ERROR "No getifaddrs was found on the system. Turn off the LWS_WITHOUT_BUILTIN_GETIFADDRS compile option to use the supplied BSD version.")
 191         endif()
 192
 193         set(LWS_BUILTIN_GETIFADDRS 1)
 194 endif()
 195
 196 CHECK_INCLUDE_FILE(dlfcn.h HAVE_DLFCN_H)
 197 CHECK_INCLUDE_FILE(fcntl.h HAVE_FCNTL_H)
 198 CHECK_INCLUDE_FILE(inttypes.h HAVE_INTTYPES_H)
 199 CHECK_INCLUDE_FILE(memory.h HAVE_MEMORY_H)
 200 CHECK_INCLUDE_FILE(netinet/in.h HAVE_NETINET_IN_H)
 201 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
 202 CHECK_INCLUDE_FILE(stdlib.h HAVE_STDLIB_H)
 203 CHECK_INCLUDE_FILE(strings.h HAVE_STRINGS_H)
 204 CHECK_INCLUDE_FILE(string.h HAVE_STRING_H)
 205 CHECK_INCLUDE_FILE(sys/prctl.h HAVE_SYS_PRCTL_H)
 206 CHECK_INCLUDE_FILE(sys/socket.h HAVE_SYS_SOCKET_H)
 207 CHECK_INCLUDE_FILE(sys/stat.h HAVE_SYS_STAT_H)
 208 CHECK_INCLUDE_FILE(sys/types.h HAVE_SYS_TYPES_H)
 209 CHECK_INCLUDE_FILE(unistd.h HAVE_UNISTD_H)
 210 CHECK_INCLUDE_FILE(vfork.h HAVE_VFORK_H)
 211 CHECK_INCLUDE_FILE(zlib.h HAVE_ZLIB_H)
 212
 213 # TODO: These can be tested if they actually work also...
 214 set(HAVE_WORKING_FORK HAVE_FORK)
 215 set(HAVE_WORKING_VFORK HAVE_VFORK)
 216
 217 CHECK_INCLUDE_FILES("stdlib.h;stdarg.h;string.h;float.h" STDC_HEADERS)
 218
 219 CHECK_TYPE_SIZE(pid_t PID_T_SIZE)
 220 CHECK_TYPE_SIZE(size_t SIZE_T_SIZE)
 221
 222 if (NOT PID_T_SIZE)
 223         set(pid_t int)
 224 endif()
 225
 226 if (NOT SIZE_T_SIZE)
 227         set(size_t "unsigned int")
 228 endif()
 229
 230 if (NOT HAVE_MALLOC)
 231         set(malloc rpl_malloc)
 232 endif()
 233
 234 if (NOT HAVE_REALLOC)
 235         set(realloc rpl_realloc)
 236 endif()
 237
 238 # Generate the config.h that includes all the compilation settings.
 239 configure_file(
 240        "${PROJECT_SOURCE_DIR}/config.h.cmake"
 241        "${PROJECT_BINARY_DIR}/lws_config.h")
 242
 243 if (MSVC)
 244         # Turn off stupid microsoft security warnings.
 245         add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
 246 endif(MSVC)
 247
 248 include_directories("${PROJECT_SOURCE_DIR}/lib")
 249
 250 # Group headers and sources.
 251 # Some IDEs use this for nicer file structure.
 252 set(HDR_PRIVATE
 253         lib/private-libwebsockets.h
 254         "${PROJECT_BINARY_DIR}/lws_config.h"
 255         )
 256
 257 set(HDR_PUBLIC
 258         "${PROJECT_SOURCE_DIR}/lib/libwebsockets.h"
 259         )
 260
 261 set(SOURCES
 262         lib/base64-decode.c
 263         lib/handshake.c
 264         lib/libwebsockets.c
 265         lib/output.c
 266         lib/parsers.c
 267         lib/sha-1.c
 268         )
 269
 270 if (NOT LWS_WITHOUT_CLIENT)
 271         list(APPEND SOURCES
 272                 lib/client.c
 273                 lib/client-handshake.c
 274                 lib/client-parser.c
 275                 )
 276 endif()
 277
 278 if (NOT LWS_WITHOUT_SERVER)
 279         list(APPEND SOURCES
 280                 lib/server.c
 281                 lib/server-handshake.c
 282                 )
 283 endif()
 284
 285 if (NOT LWS_WITHOUT_EXTENSIONS)
 286         list(APPEND HDR_PRIVATE
 287                 lib/extension-deflate-frame.h
 288                 lib/extension-deflate-stream.h
 289                 )
 290
 291         list(APPEND SOURCES
 292                 lib/extension.c
 293                 lib/extension-deflate-frame.c
 294                 lib/extension-deflate-stream.c
 295                 )
 296 endif()
 297
 298 # Add helper files for Windows.
 299 if (WIN32)
 300         set(WIN32_HELPERS_PATH win32port/win32helpers)
 301
 302         list(APPEND HDR_PUBLIC
 303                 ${WIN32_HELPERS_PATH}/websock-w32.h
 304                 )
 305         if (NOT MINGW)
 306                 list(APPEND SOURCES
 307                         ${WIN32_HELPERS_PATH}/websock-w32.c
 308                         )
 309         endif()
 310         include_directories(${WIN32_HELPERS_PATH})
 311 else(WIN32)
 312         # Unix.
 313         if (NOT LWS_WITHOUT_DAEMONIZE)
 314                 list(APPEND SOURCES
 315                         lib/daemonize.c
 316                         )
 317         endif()
 318 endif(WIN32)
 319
 320 if (UNIX)
 321         if (NOT HAVE_GETIFADDRS)
 322                 list(APPEND HDR_PRIVATE lib/getifaddrs.h)
 323                 list(APPEND SOURCES lib/getifaddrs.c)
 324         endif()
 325 endif(UNIX)
 326
 327
 328 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
 329     if (UNIX)
 330         set( CMAKE_C_FLAGS "-Wall -Werror -O4 -fvisibility=hidden ${CMAKE_C_FLAGS}" )
 331     else(UNIX)
 332         set( CMAKE_C_FLAGS "-Wall -O4 -fvisibility=hidden ${CMAKE_C_FLAGS}" )
 333     endif(UNIX)
 334 endif ()
 335
 336 source_group("Headers Private"  FILES ${HDR_PRIVATE})
 337 source_group("Headers Public"   FILES ${HDR_PUBLIC})
 338 source_group("Sources"          FILES ${SOURCES})
 339
 340 #
 341 # Create the lib.
 342 #
 343 add_library(websockets STATIC
 344                         ${HDR_PRIVATE}
 345                         ${HDR_PUBLIC}
 346                         ${SOURCES})
 347 add_library(websockets_shared SHARED
 348                         ${HDR_PRIVATE}
 349                         ${HDR_PUBLIC}
 350                         ${SOURCES})
 351
 352 if (WIN32)
 353         # On Windows libs have the same file ending (.lib)
 354         # for both static and shared libraries, so we
 355         # need a unique name for the static one.
 356         set_target_properties(websockets
 357                 PROPERTIES
 358                 OUTPUT_NAME websockets_static)
 359
 360         # Compile as DLL (export function declarations)
 361         set_property(
 362                 TARGET websockets_shared
 363                 PROPERTY COMPILE_DEFINITIONS
 364                 LWS_DLL
 365                 LWS_INTERNAL
 366                 )
 367 endif(WIN32)
 368
 369 # We want the shared lib to be named "libwebsockets"
 370 # not "libwebsocket_shared".
 371 set_target_properties(websockets_shared
 372                 PROPERTIES
 373                 OUTPUT_NAME websockets)
 374
 375 # Set the so version of the lib.
 376 # Equivalent to LDFLAGS=-version-info x:x:x
 377 if(CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
 378         foreach(lib websockets websockets_shared)
 379                 set_target_properties(${lib}
 380                         PROPERTIES
 381                         SOVERSION ${SOVERSION})
 382         endforeach()
 383 endif()
 384
 385 set(LIB_LIST)
 386
 387 #
 388 # Find libraries.
 389 #
 390
 391 #
 392 # ZLIB (Only needed for deflate extensions).
 393 #
 394 if (NOT LWS_WITHOUT_EXTENSIONS)
 395         if (WIN32 AND NOT LWS_USE_EXTERNAL_ZLIB)
 396                 message("Using included Zlib version")
 397
 398                 # Compile ZLib if needed.
 399                 set(WIN32_ZLIB_PATH "win32port/zlib")
 400                 set(ZLIB_SRCS
 401                         ${WIN32_ZLIB_PATH}/adler32.c
 402                         ${WIN32_ZLIB_PATH}/compress.c
 403                         ${WIN32_ZLIB_PATH}/crc32.c
 404                         ${WIN32_ZLIB_PATH}/deflate.c
 405                         ${WIN32_ZLIB_PATH}/gzclose.c
 406                         ${WIN32_ZLIB_PATH}/gzio.c
 407                         ${WIN32_ZLIB_PATH}/gzlib.c
 408                         ${WIN32_ZLIB_PATH}/gzread.c
 409                         ${WIN32_ZLIB_PATH}/gzwrite.c
 410                         ${WIN32_ZLIB_PATH}/infback.c
 411                         ${WIN32_ZLIB_PATH}/inffast.c
 412                         ${WIN32_ZLIB_PATH}/inflate.c
 413                         ${WIN32_ZLIB_PATH}/inftrees.c
 414                         ${WIN32_ZLIB_PATH}/trees.c
 415                         ${WIN32_ZLIB_PATH}/uncompr.c
 416                         ${WIN32_ZLIB_PATH}/zutil.c
 417                 )
 418
 419                 # Create the library.
 420                 add_library(ZLIB STATIC ${ZLIB_SRCS})
 421
 422                 # Set the same variables as find_package would.
 423                 set(ZLIB_INCLUDE_DIRS ${WIN32_ZLIB_PATH})
 424                 get_property(ZLIB_LIBRARIES TARGET ZLIB PROPERTY LOCATION)
 425                 set(ZLIB_FOUND 1)
 426         else()
 427                 find_package(ZLIB REQUIRED)
 428         endif()
 429
 430         # Make sure ZLib is compiled before the libs.
 431         foreach (lib websockets websockets_shared)
 432                 add_dependencies(${lib} ZLIB)
 433         endforeach()
 434
 435         message("ZLib include dirs: ${ZLIB_INCLUDE_DIRS}")
 436         message("ZLib libraries: ${ZLIB_LIBRARIES}")
 437         include_directories(${ZLIB_INCLUDE_DIRS})
 438         list(APPEND LIB_LIST ${ZLIB_LIBRARIES})
 439 endif(NOT LWS_WITHOUT_EXTENSIONS)
 440
 441 #
 442 # OpenSSL
 443 #
 444 if (LWS_WITH_SSL)
 445         message("Compiling with SSL support")
 446
 447         if (LWS_USE_CYASSL)
 448                 # Use CyaSSL as OpenSSL replacement.
 449                 # TODO: Add a find_package command for this also.
 450                 message("CyaSSL include dir: ${LWS_CYASSL_INCLUDE_DIRS}")
 451                 message("CyaSSL libraries: ${LWS_CYASSL_LIB}")
 452
 453                 # Additional to the root directory we need to include
 454                 # the cyassl/ subdirectory which contains the OpenSSL
 455                 # compatability layer headers.
 456                 foreach(inc ${LWS_CYASSL_INCLUDE_DIRS})
 457                         include_directories("${inc}" "${inc}/cyassl")
 458                 endforeach()
 459
 460                 list(APPEND LIB_LIST "${LWS_CYASSL_LIB}")
 461         else()
 462                 # TODO: Add support for STATIC also.
 463                 find_package(OpenSSL REQUIRED)
 464
 465                 message("OpenSSL include dir: ${OPENSSL_INCLUDE_DIR}")
 466                 message("OpenSSL libraries: ${OPENSSL_LIBRARIES}")
 467
 468                 include_directories("${OPENSSL_INCLUDE_DIR}")
 469                 list(APPEND LIB_LIST ${OPENSSL_LIBRARIES})
 470         endif()
 471 endif(LWS_WITH_SSL)
 472
 473 if (LWS_WITH_LIBEV)
 474         list(APPEND LIB_LIST "ev")
 475 endif(LWS_WITH_LIBEV)
 476
 477 #
 478 # Platform specific libs.
 479 #
 480 if (WINCE)
 481         list(APPEND LIB_LIST ws2.lib)
 482 elseif (WIN32)
 483         list(APPEND LIB_LIST ws2_32.lib)
 484 endif()
 485
 486 if (UNIX)
 487         list(APPEND LIB_LIST m)
 488 endif()
 489
 490 # Setup the linking for all libs.
 491 foreach (lib websockets websockets_shared)
 492         target_link_libraries(${lib} ${LIB_LIST})
 493 endforeach()
 494
 495 #
 496 # Test applications
 497 #
 498 set(TEST_APP_LIST)
 499 if (NOT LWS_WITHOUT_TESTAPPS)
 500         #
 501         # Helper function for adding a test app.
 502         #
 503         macro(create_test_app TEST_NAME MAIN_SRC WIN32_SRCS WIN32_HDRS)
 504
 505                 set(TEST_SRCS ${MAIN_SRC})
 506                 set(TEST_HDR)
 507
 508                 if (WIN32)
 509                         list(APPEND TEST_SRCS
 510                                 ${WIN32_HELPERS_PATH}/getopt.c
 511                                 ${WIN32_HELPERS_PATH}/getopt_long.c
 512                                 ${WIN32_HELPERS_PATH}/gettimeofday.c
 513                                 ${WIN32_SRCS})
 514
 515                         list(APPEND TEST_HDR
 516                                 ${WIN32_HELPERS_PATH}/getopt.h
 517                                 ${WIN32_HELPERS_PATH}/gettimeofday.h
 518                                 ${WIN32_HDRS})
 519                 endif(WIN32)
 520
 521                 source_group("Headers Private"   FILES ${TEST_HDR})
 522                 source_group("Sources"   FILES ${TEST_SRCS})
 523                 add_executable(${TEST_NAME} ${TEST_SRCS} ${TEST_HDR})
 524
 525                 if (LWS_LINK_TESTAPPS_DYNAMIC)
 526                         target_link_libraries(${TEST_NAME} websockets_shared)
 527                         add_dependencies(${TEST_NAME} websockets_shared)
 528                 else(LWS_LINK_TESTAPPS_DYNAMIC)
 529                         target_link_libraries(${TEST_NAME} websockets)
 530                         add_dependencies(${TEST_NAME} websockets)
 531                 endif(LWS_LINK_TESTAPPS_DYNAMIC)
 532
 533                 # Set test app specific defines.
 534                 set_property(TARGET ${TEST_NAME}
 535                                         PROPERTY COMPILE_DEFINITIONS
 536                                                 INSTALL_DATADIR="${CMAKE_INSTALL_PREFIX}/share"
 537                                         )
 538
 539                 # Prefix the binary names with libwebsockets.
 540                 set_target_properties(${TEST_NAME}
 541                         PROPERTIES
 542                         OUTPUT_NAME libwebsockets-${TEST_NAME})
 543
 544                 # Add to the list of tests.
 545                 list(APPEND TEST_APP_LIST ${TEST_NAME})
 546         endmacro()
 547
 548         if (LWS_WITH_SSL AND NOT LWS_USE_CYASSL)
 549                 message("Searching for OpenSSL executable and dlls")
 550                 find_package(OpenSSLbins)
 551                 message("OpenSSL executable: ${OPENSSL_EXECUTABLE}")
 552         endif()
 553
 554         if (NOT LWS_WITHOUT_SERVER)
 555                 #
 556                 # test-server
 557                 #
 558                 if (NOT LWS_WITHOUT_TEST_SERVER)
 559                         create_test_app(test-server
 560                                 "test-server/test-server.c"
 561                                 ""
 562                                 "${WIN32_HELPERS_PATH}/netdb.h;${WIN32_HELPERS_PATH}/strings.h;${WIN32_HELPERS_PATH}/unistd.h;${WIN32_HELPERS_PATH}/websock-w32.h")
 563                 endif()
 564
 565                 #
 566                 # test-server-extpoll
 567                 #
 568                 if (NOT LWS_WITHOUT_TEST_SERVER_EXTPOLL)
 569                         create_test_app(test-server-extpoll
 570                                 "test-server/test-server.c"
 571                                 "win32port/win32helpers/websock-w32.c"
 572                                 "${WIN32_HELPERS_PATH}/netdb.h;${WIN32_HELPERS_PATH}/strings.h;${WIN32_HELPERS_PATH}/unistd.h;${WIN32_HELPERS_PATH}/websock-w32.h")
 573                         # Set defines for this executable only.
 574                         set_property(
 575                                 TARGET test-server-extpoll
 576                                 PROPERTY COMPILE_DEFINITIONS
 577                                         EXTERNAL_POLL
 578                                         INSTALL_DATADIR="${CMAKE_INSTALL_PREFIX}/share"
 579                                 )
 580
 581                         # We need to link against winsock code.
 582                         if (WIN32)
 583                                 target_link_libraries(test-server-extpoll ws2_32.lib)
 584                         endif(WIN32)
 585                 endif()
 586
 587                 # Data files for running the test server.
 588                 set(TEST_SERVER_DATA
 589                         "${PROJECT_SOURCE_DIR}/test-server/favicon.ico"
 590                         "${PROJECT_SOURCE_DIR}/test-server/leaf.jpg"
 591                         "${PROJECT_SOURCE_DIR}/test-server/libwebsockets.org-logo.png"
 592                         "${PROJECT_SOURCE_DIR}/test-server/test.html")
 593
 594                 # Generate self-signed SSL certs for the test-server.
 595                 if (LWS_WITH_SSL AND OPENSSL_EXECUTABLE AND NOT LWS_WITHOUT_TEST_SERVER)
 596                         message("Generating SSL Certificates for the test-server...")
 597
 598                         set(TEST_SERVER_SSL_KEY "${PROJECT_BINARY_DIR}/libwebsockets-test-server.key.pem")
 599                         set(TEST_SERVER_SSL_CERT "${PROJECT_BINARY_DIR}/libwebsockets-test-server.pem")
 600
 601                         if (WIN32)
 602                                 file(WRITE "${PROJECT_BINARY_DIR}/openssl_input.txt"
 603                                         "GB\n"
 604                                         "Erewhon\n"
 605                                         "All around\n"
 606                                         "libwebsockets-test\n"
 607                                         "localhost\n"
 608                                         "none@invalid.org\n\n"
 609                                         )
 610
 611                                 # The "type" command is a bit picky with paths.
 612                                 file(TO_NATIVE_PATH "${PROJECT_BINARY_DIR}/openssl_input.txt" OPENSSL_INPUT_WIN_PATH)
 613                                 message("OPENSSL_INPUT_WIN_PATH = ${OPENSSL_INPUT_WIN_PATH}")
 614                                 message("cmd = \"${OPENSSL_EXECUTABLE}\" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout \"${TEST_SERVER_SSL_KEY}\" -out \"${TEST_SERVER_SSL_CERT}\"")
 615
 616                                 execute_process(
 617                                         COMMAND cmd /c type "${OPENSSL_INPUT_WIN_PATH}"
 618                                         COMMAND "${OPENSSL_EXECUTABLE}" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 619                                         RESULT_VARIABLE OPENSSL_RETURN_CODE)
 620
 621                                 message("\n")
 622
 623                                 if (OPENSSL_RETURN_CODE)
 624                                         message(WARNING "!!! Failed to generate SSL certificate for Test Server using cmd.exe !!!:\nOpenSSL return code = ${OPENSSL_RETURN_CODE}")
 625                                 else()
 626                                         message("SUCCSESFULLY generated SSL certificate")
 627                                 endif()
 628                         else()
 629                                 # Unix.
 630                                 execute_process(
 631                                         COMMAND printf "GB\\nErewhon\\nAll around\\nlibwebsockets-test\\n\\nlocalhost\\nnone@invalid.org\\n"
 632                                         COMMAND "${OPENSSL_EXECUTABLE}"
 633                                                 req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 634                                         RESULT_VARIABLE OPENSSL_RETURN_CODE)
 635
 636                                 if (OPENSSL_RETURN_CODE)
 637                                         message(WARNING "!!! Failed to generate SSL certificate for Test Server!!!:\nOpenSSL return code = ${OPENSSL_RETURN_CODE}")
 638                                 else()
 639                                         message("SUCCSESFULLY generated SSL certificate")
 640                                 endif()
 641                         endif()
 642
 643                         list(APPEND TEST_SERVER_DATA
 644                                 "${TEST_SERVER_SSL_KEY}"
 645                                 "${TEST_SERVER_SSL_CERT}")
 646                 endif()
 647
 648                 add_custom_command(TARGET test-server
 649                                                 POST_BUILD
 650                                                 COMMAND "${CMAKE_COMMAND}" -E make_directory "$<TARGET_FILE_DIR:test-server>/../share/libwebsockets-test-server")
 651
 652                 # Copy the file needed to run the server so that the test apps can
 653                 # reach them from their default output location
 654                 foreach (TEST_FILE ${TEST_SERVER_DATA})
 655                         if (EXISTS ${TEST_FILE})
 656                                 add_custom_command(TARGET test-server
 657                                                         POST_BUILD
 658                                                         COMMAND "${CMAKE_COMMAND}" -E copy "${TEST_FILE}" "$<TARGET_FILE_DIR:test-server>/../share/libwebsockets-test-server" VERBATIM)
 659                         endif()
 660                 endforeach()
 661         endif(NOT LWS_WITHOUT_SERVER)
 662
 663         if (NOT LWS_WITHOUT_CLIENT)
 664                 #
 665                 # test-client
 666                 #
 667                 if (NOT LWS_WITHOUT_TEST_CLIENT)
 668                         create_test_app(test-client
 669                                 "test-server/test-client.c"
 670                                 ""
 671                                 "")
 672                 endif()
 673
 674                 #
 675                 # test-fraggle
 676                 #
 677                 if (NOT LWS_WITHOUT_TEST_FRAGGLE)
 678                         create_test_app(test-fraggle
 679                                 "test-server/test-fraggle.c"
 680                                 ""
 681                                 "${WIN32_HELPERS_PATH}/unistd.h;${WIN32_HELPERS_PATH}/sys/time.h")
 682                 endif()
 683
 684                 #
 685                 # test-ping
 686                 #
 687                 if (NOT LWS_WITHOUT_TEST_PING)
 688                         create_test_app(test-ping
 689                                 "test-server/test-ping.c"
 690                                 ""
 691                                 "${WIN32_HELPERS_PATH}/unistd.h;${WIN32_HELPERS_PATH}/sys/time.h")
 692                 endif()
 693                 #
 694                 # test-echo
 695                 #
 696                 if (NOT WITHOUT_TEST_ECHO)
 697                         create_test_app(test-echo
 698                                 "test-server/test-echo.c"
 699                                 ""
 700                                 "${WIN32_HELPERS_PATH}/unistd.h;${WIN32_HELPERS_PATH}/sys/time.h")
 701                 endif()
 702
 703         endif(NOT LWS_WITHOUT_CLIENT)
 704
 705         #
 706         # Copy OpenSSL dlls to the output directory on Windows.
 707         # (Otherwise we'll get an error when trying to run)
 708         #
 709         if (WIN32 AND LWS_WITH_SSL AND NOT LWS_USE_CYASSL)
 710                 if(OPENSSL_BIN_FOUND)
 711                         message("OpenSSL dlls found:")
 712                         message("  Libeay: ${LIBEAY_BIN}")
 713                         message("  SSLeay: ${SSLEAY_BIN}")
 714
 715                         foreach(TARGET_BIN ${TEST_APP_LIST})
 716                                 add_custom_command(TARGET ${TARGET_BIN}
 717                                         POST_BUILD
 718                                         COMMAND "${CMAKE_COMMAND}" -E copy "${LIBEAY_BIN}" "$<TARGET_FILE_DIR:${TARGET_BIN}>" VERBATIM)
 719
 720                                 add_custom_command(TARGET ${TARGET_BIN}
 721                                         POST_BUILD
 722                                         COMMAND "${CMAKE_COMMAND}" -E copy "${SSLEAY_BIN}" "$<TARGET_FILE_DIR:${TARGET_BIN}>" VERBATIM)
 723                         endforeach()
 724                 endif()
 725         endif()
 726 endif(NOT LWS_WITHOUT_TESTAPPS)
 727
 728 if (UNIX)
 729         # Generate documentation.
 730         # TODO: Fix this on Windows.
 731         message("Generating API documentation")
 732         file(GLOB C_FILES "${PROJECT_SOURCE_DIR}/lib/*.c")
 733         execute_process(COMMAND "${CMAKE_COMMAND}" -E make_directory "${PROJECT_BINARY_DIR}/doc/")
 734
 735         execute_process(
 736                 COMMAND "${PROJECT_SOURCE_DIR}/scripts/kernel-doc" -html ${C_FILES} ${HDR_PUBLIC}
 737                 OUTPUT_FILE "${PROJECT_BINARY_DIR}/doc/libwebsockets-api-doc.html"
 738                 ERROR_QUIET)
 739
 740         execute_process(
 741                 COMMAND "${PROJECT_SOURCE_DIR}/scripts/kernel-doc" -text ${C_FILES} ${HDR_PUBLIC}
 742                 OUTPUT_FILE "${PROJECT_BINARY_DIR}/doc/libwebsockets-api-doc.txt"
 743                 ERROR_QUIET)
 744
 745 # Generate and install pkgconfig.
 746 # (This is not indented, because the tabs will be part of the output)
 747 file(WRITE "${PROJECT_BINARY_DIR}/libwebsockets.pc"
 748 "prefix=\"${CMAKE_INSTALL_PREFIX}\"
 749 exec_prefix=\${prefix}
 750 libdir=\${exec_prefix}/lib${LIB_SUFFIX}
 751 includedir=\${prefix}/include
 752
 753 Name: libwebsockets
 754 Description: Websockets server and client library
 755 Version: ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}
 756
 757 Libs: -L\${libdir} -lwebsockets
 758 Cflags: -I\${includedir}"
 759 )
 760
 761         install(FILES "${PROJECT_BINARY_DIR}/libwebsockets.pc"
 762                 DESTINATION lib${LIB_SUFFIX}/pkgconfig)
 763 endif(UNIX)
 764
 765 #
 766 # Installation preparations.
 767 #
 768
 769 if(WIN32 AND NOT CYGWIN)
 770   set(DEF_INSTALL_CMAKE_DIR cmake)
 771 else()
 772   set(DEF_INSTALL_CMAKE_DIR lib/cmake/libwebsockets)
 773 endif()
 774
 775 set(LWS_INSTALL_CMAKE_DIR ${DEF_INSTALL_CMAKE_DIR} CACHE PATH "Installation directory for CMake files")
 776
 777 # Export targets (This is used for other CMake projects to easily find the libraries and include files).
 778 export(TARGETS websockets websockets_shared
 779         FILE "${PROJECT_BINARY_DIR}/LibwebsocketsTargets.cmake")
 780 export(PACKAGE libwebsockets)
 781
 782 # Generate the config file for the build-tree.
 783 set(LWS__INCLUDE_DIRS
 784     "${PROJECT_SOURCE_DIR}/lib"
 785     "${PROJECT_BINARY_DIR}")
 786 set(LIBWEBSOCKETS_INCLUDE_DIRS ${LWS__INCLUDE_DIRS} CACHE PATH "Libwebsockets include directories")
 787 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfig.cmake.in
 788                 ${PROJECT_BINARY_DIR}/LibwebsocketsConfig.cmake
 789                 @ONLY)
 790
 791 # Generate the config file for the installation tree.
 792 get_filename_component(LWS_ABSOLUTE_INSTALL_CMAKE_DIR ${LWS_INSTALL_CMAKE_DIR} ABSOLUTE)
 793 get_filename_component(LWS_ABSOLUTE_INSTALL_INCLUDE_DIR ${LWS_INSTALL_INCLUDE_DIR} ABSOLUTE)
 794 file(RELATIVE_PATH
 795     REL_INCLUDE_DIR
 796     "${LWS_ABSOLUTE_INSTALL_CMAKE_DIR}"
 797     "${LWS_ABSOLUTE_INSTALL_INCLUDE_DIR}") # Calculate the relative directory from the cmake dir.
 798
 799 # Note the EVENT_CMAKE_DIR is defined in JanssonConfig.cmake.in,
 800 # we escape it here so it's evaluated when it is included instead
 801 # so that the include dirs are given relative to where the
 802 # config file is located.
 803 set(LWS__INCLUDE_DIRS
 804     "\${LWS_CMAKE_DIR}/${REL_INCLUDE_DIR}")
 805 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfig.cmake.in
 806                 ${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/LibwebsocketsConfig.cmake
 807                 @ONLY)
 808
 809 # Generate version info for both build-tree and install-tree.
 810 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfigVersion.cmake.in
 811                 ${PROJECT_BINARY_DIR}/LibwebsocketsConfigVersion.cmake
 812                 @ONLY)
 813
 814 set_target_properties(websockets websockets_shared
 815                                         PROPERTIES PUBLIC_HEADER "${HDR_PUBLIC}")
 816
 817 #
 818 # Installation.
 819 #
 820
 821 # Install libs and headers.
 822 install(TARGETS websockets websockets_shared
 823                 EXPORT LibwebsocketsTargets
 824                 LIBRARY DESTINATION "${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}" COMPONENT libraries
 825                 ARCHIVE DESTINATION "${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}" COMPONENT libraries
 826                 RUNTIME DESTINATION "${LWS_INSTALL_BIN_DIR}" COMPONENT libraries # Windows DLLs
 827                 PUBLIC_HEADER DESTINATION "${LWS_INSTALL_INCLUDE_DIR}" COMPONENT dev)
 828 set(CPACK_COMPONENT_LIBRARIES_DISPLAY_NAME "Libraries")
 829 set(CPACK_COMPONENT_DEV_DISPLAY_NAME "Development files")
 830
 831 # Install test apps.
 832 if (NOT LWS_WITHOUT_TESTAPPS AND NOT LWS_WITHOUT_CLIENT)
 833         install(TARGETS test-client ${TEST_APP_LIST}
 834                         RUNTIME DESTINATION ${LWS_INSTALL_EXAMPLES_DIR}
 835                         COMPONENT examples)
 836         set(CPACK_COMPONENT_EXAMPLES_DISPLAY_NAME "Example files")
 837 endif()
 838
 839 # Programs shared files used by the test-server.
 840 if (NOT LWS_WITHOUT_TESTAPPS AND NOT LWS_WITHOUT_SERVER)
 841         install(FILES ${TEST_SERVER_DATA}
 842                         DESTINATION share/libwebsockets-test-server
 843                         COMPONENT examples)
 844 endif()
 845
 846 # Install exports for the install-tree.
 847 install(EXPORT LibwebsocketsTargets
 848                 DESTINATION "${LWS_INSTALL_CMAKE_DIR}" COMPONENT dev)
 849
 850 # build subdir is not part of sources
 851 set(CPACK_SOURCE_IGNORE_FILES $(CPACK_SOURCE_IGNORE_FILES) ".git" "build" "tgz" "tar.gz")
 852
 853 # Most people are more used to "make dist" compared to "make package_source"
 854 add_custom_target(dist COMMAND "${CMAKE_MAKE_PROGRAM}" package_source)
 855
 856 include(UseRPMTools)
 857 if (RPMTools_FOUND)
 858         RPMTools_ADD_RPM_TARGETS(libwebsockets libwebsockets.spec)
 859 endif()
 860
 861 message("---------------------------------------------------------------------")
 862 message("  Settings:  (For more help do cmake -LH <srcpath>")
 863 message("---------------------------------------------------------------------")
 864 message(" LWS_WITH_SSL = ${LWS_WITH_SSL}  (SSL Support)")
 865 message(" LWS_SSL_CLIENT_USE_OS_CA_CERTS = ${LWS_SSL_CLIENT_USE_OS_CA_CERTS}")
 866 message(" LWS_USE_CYASSL = ${LWS_USE_CYASSL} (CyaSSL replacement for OpenSSL)")
 867 if (LWS_USE_CYASSL)
 868         message("   LWS_CYASSL_LIB = ${LWS_CYASSL_LIB}")
 869         message("   LWS_CYASSL_INCLUDE_DIRS = ${LWS_CYASSL_INCLUDE_DIRS}")
 870 endif()
 871 message(" LWS_WITHOUT_BUILTIN_GETIFADDRS = ${LWS_WITHOUT_BUILTIN_GETIFADDRS}")
 872 message(" LWS_WITHOUT_CLIENT = ${LWS_WITHOUT_CLIENT}")
 873 message(" LWS_WITHOUT_SERVER = ${LWS_WITHOUT_SERVER}")
 874 message(" LWS_LINK_TESTAPPS_DYNAMIC = ${LWS_LINK_TESTAPPS_DYNAMIC}")
 875 message(" LWS_WITHOUT_TESTAPPS = ${LWS_WITHOUT_TESTAPPS}")
 876 message(" LWS_WITHOUT_TEST_SERVER = ${LWS_WITHOUT_TEST_SERVER}")
 877 message(" LWS_WITHOUT_TEST_SERVER_EXTPOLL = ${LWS_WITHOUT_TEST_SERVER_EXTPOLL}")
 878 message(" LWS_WITHOUT_TEST_PING = ${LWS_WITHOUT_TEST_PING}")
 879 message(" LWS_WITHOUT_TEST_CLIENT = ${LWS_WITHOUT_TEST_CLIENT}")
 880 message(" LWS_WITHOUT_TEST_FRAGGLE = ${LWS_WITHOUT_TEST_FRAGGLE}")
 881 message(" LWS_WITHOUT_DEBUG = ${LWS_WITHOUT_DEBUG}")
 882 message(" LWS_WITHOUT_EXTENSIONS = ${LWS_WITHOUT_EXTENSIONS}")
 883 message(" LWS_WITH_LATENCY = ${LWS_WITH_LATENCY}")
 884 message(" LWS_WITHOUT_DAEMONIZE = ${LWS_WITHOUT_DAEMONIZE}")
 885 message(" LWS_USE_LIBEV = ${LWS_USE_LIBEV}")
 886 message(" LWS_WITH_IPV6 = ${LWS_WITH_IPV6}")
 887 message("---------------------------------------------------------------------")
 888
 889 # These will be available to parent projects including libwebsockets using add_subdirectory()
 890 set(LIBWEBSOCKETS_LIBRARIES websocket websockets_shared CACHE STRING "Libwebsocket libraries")
 891 set(LIBWEBSOCKETS_LIBRARIES_STATIC websocket CACHE STRING "Libwebsocket static library")
 892 set(LIBWEBSOCKETS_LIBRARIES_SHARED websockets_shared CACHE STRING "Libwebsocket shared library")
 893
 894 # This must always be last!
 895 include(CPack)