CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 # ----------------------------------------------------------------------------
   8
   9 # Disable in-source builds to prevent source tree corruption.
  10 if(" ${CMAKE_SOURCE_DIR}" STREQUAL " ${CMAKE_BINARY_DIR}")
  11   message(FATAL_ERROR "
  12 FATAL: In-source builds are not allowed.
  13        You should create a separate directory for build files.
  14 ")
  15 endif()
  16
  17
  18 include(cmake/OpenCVMinDepVersions.cmake)
  19
  20 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  21   cmake_minimum_required(VERSION 3.0 FATAL_ERROR)
  22 elseif(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  23   cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
  24   #Required to resolve linker error issues due to incompatibility with CMake v3.0+ policies.
  25   #CMake fails to find _fseeko() which leads to subsequent linker error.
  26   #See details here: http://www.cmake.org/Wiki/CMake/Policies
  27   cmake_policy(VERSION 2.8)
  28 else()
  29   cmake_minimum_required(VERSION "${MIN_VER_CMAKE}" FATAL_ERROR)
  30 endif()
  31
  32 #
  33 # Configure CMake policies
  34 #
  35 if(POLICY CMP0026)
  36   cmake_policy(SET CMP0026 NEW)
  37 endif()
  38
  39 if(POLICY CMP0042)
  40   cmake_policy(SET CMP0042 NEW)  # CMake 3.0+ (2.8.12): MacOS "@rpath" in target's install name
  41 endif()
  42
  43 if(POLICY CMP0046)
  44   cmake_policy(SET CMP0046 NEW)  # warn about non-existed dependencies
  45 endif()
  46
  47 if(POLICY CMP0051)
  48   cmake_policy(SET CMP0051 NEW)
  49 endif()
  50
  51 if(POLICY CMP0054)  # CMake 3.1: Only interpret if() arguments as variables or keywords when unquoted.
  52   cmake_policy(SET CMP0054 NEW)
  53 endif()
  54
  55 if(POLICY CMP0056)
  56   cmake_policy(SET CMP0056 NEW)  # try_compile(): link flags
  57 endif()
  58
  59 if(POLICY CMP0066)
  60   cmake_policy(SET CMP0066 NEW)  # CMake 3.7: try_compile(): use per-config flags, like CMAKE_CXX_FLAGS_RELEASE
  61 endif()
  62
  63 if(POLICY CMP0067)
  64   cmake_policy(SET CMP0067 NEW)  # CMake 3.8: try_compile(): honor language standard variables (like C++11)
  65 endif()
  66
  67 if(POLICY CMP0068)
  68   cmake_policy(SET CMP0068 NEW)  # CMake 3.9+: `RPATH` settings on macOS do not affect `install_name`.
  69 endif()
  70
  71 if(POLICY CMP0075)
  72   cmake_policy(SET CMP0075 NEW)  # CMake 3.12+: Include file check macros honor `CMAKE_REQUIRED_LIBRARIES`
  73 endif()
  74
  75 if(POLICY CMP0077)
  76   cmake_policy(SET CMP0077 NEW)  # CMake 3.13+: option() honors normal variables.
  77 endif()
  78
  79 #
  80 # Configure OpenCV CMake hooks
  81 #
  82 include(cmake/OpenCVUtils.cmake)
  83 ocv_cmake_reset_hooks()
  84 ocv_check_environment_variables(OPENCV_CMAKE_HOOKS_DIR)
  85 if(DEFINED OPENCV_CMAKE_HOOKS_DIR)
  86   foreach(__dir ${OPENCV_CMAKE_HOOKS_DIR})
  87     get_filename_component(__dir "${__dir}" ABSOLUTE)
  88     ocv_cmake_hook_register_dir(${__dir})
  89   endforeach()
  90 endif()
  91
  92 ocv_cmake_hook(CMAKE_INIT)
  93
  94 # must go before the project()/enable_language() commands
  95 ocv_update(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  96 if(DEFINED CMAKE_BUILD_TYPE)
  97   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "${CMAKE_CONFIGURATION_TYPES}")
  98 endif()
  99
 100 option(ENABLE_PIC "Generate position independent code (necessary for shared libraries)" TRUE)
 101 set(CMAKE_POSITION_INDEPENDENT_CODE ${ENABLE_PIC})
 102
 103 ocv_cmake_hook(PRE_CMAKE_BOOTSTRAP)
 104
 105 # Bootstap CMake system: setup CMAKE_SYSTEM_NAME and other vars
 106 enable_language(CXX C)
 107
 108 ocv_cmake_hook(POST_CMAKE_BOOTSTRAP)
 109
 110 if(NOT OPENCV_SKIP_CMAKE_SYSTEM_FILE)
 111   include("cmake/platforms/OpenCV-${CMAKE_SYSTEM_NAME}.cmake" OPTIONAL RESULT_VARIABLE "OPENCV_CMAKE_SYSTEM_FILE")
 112   if(NOT OPENCV_CMAKE_SYSTEM_FILE)
 113     message(STATUS "OpenCV: system-specific configuration file is not found: '${CMAKE_SYSTEM_NAME}'")
 114   endif()
 115 endif()
 116
 117 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)  # https://cmake.org/cmake/help/latest/variable/CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT.html
 118   if(NOT CMAKE_TOOLCHAIN_FILE)
 119     if(WIN32)
 120       set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory" FORCE)
 121     else()
 122       set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory" FORCE)
 123     endif()
 124   else()
 125     # any cross-compiling
 126     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory" FORCE)
 127   endif()
 128 endif()
 129
 130 enable_testing()
 131
 132 project(OpenCV CXX C)
 133
 134 if(MSVC)
 135   set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
 136 endif()
 137
 138 ocv_cmake_eval(DEBUG_PRE ONCE)
 139
 140 ocv_clear_vars(OpenCVModules_TARGETS)
 141
 142 include(cmake/OpenCVDownload.cmake)
 143
 144 set(BUILD_LIST "" CACHE STRING "Build only listed modules (comma-separated, e.g. 'videoio,dnn,ts')")
 145
 146 # ----------------------------------------------------------------------------
 147 # Break in case of popular CMake configuration mistakes
 148 # ----------------------------------------------------------------------------
 149 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
 150   message(FATAL_ERROR "CMake fails to determine the bitness of the target platform.
 151   Please check your CMake and compiler installation. If you are cross-compiling then ensure that your CMake toolchain file correctly sets the compiler details.")
 152 endif()
 153
 154 # ----------------------------------------------------------------------------
 155 # Detect compiler and target platform architecture
 156 # ----------------------------------------------------------------------------
 157 OCV_OPTION(ENABLE_CXX11 "Enable C++11 compilation mode" "${OPENCV_CXX11}")
 158 include(cmake/OpenCVDetectCXXCompiler.cmake)
 159 ocv_cmake_hook(POST_DETECT_COMPILER)
 160
 161 # Add these standard paths to the search paths for FIND_LIBRARY
 162 # to find libraries from these locations first
 163 if(UNIX AND NOT ANDROID)
 164   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
 165     if(EXISTS /lib64)
 166       list(APPEND CMAKE_LIBRARY_PATH /lib64)
 167     else()
 168       list(APPEND CMAKE_LIBRARY_PATH /lib)
 169     endif()
 170     if(EXISTS /usr/lib64)
 171       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
 172     else()
 173       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 174     endif()
 175   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
 176     if(EXISTS /lib32)
 177       list(APPEND CMAKE_LIBRARY_PATH /lib32)
 178     else()
 179       list(APPEND CMAKE_LIBRARY_PATH /lib)
 180     endif()
 181     if(EXISTS /usr/lib32)
 182       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 183     else()
 184       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 185     endif()
 186   endif()
 187 endif()
 188
 189 # Add these standard paths to the search paths for FIND_PATH
 190 # to find include files from these locations first
 191 if(MINGW)
 192   if(EXISTS /mingw)
 193       list(APPEND CMAKE_INCLUDE_PATH /mingw)
 194   endif()
 195   if(EXISTS /mingw32)
 196       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
 197   endif()
 198   if(EXISTS /mingw64)
 199       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 200   endif()
 201 endif()
 202
 203 # ----------------------------------------------------------------------------
 204 # OpenCV cmake options
 205 # ----------------------------------------------------------------------------
 206
 207 OCV_OPTION(OPENCV_ENABLE_NONFREE "Enable non-free algorithms" OFF)
 208
 209 # 3rd party libs
 210 OCV_OPTION(OPENCV_FORCE_3RDPARTY_BUILD   "Force using 3rdparty code from source" OFF)
 211 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             (WIN32 OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 212 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 213 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 214 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 215 OCV_OPTION(BUILD_PNG                "Build libpng from source"           (WIN32 OR ANDROID OR APPLE OR OPENCV_FORCE_3RDPARTY_BUILD) )
 216 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          (((WIN32 OR ANDROID OR APPLE) AND NOT WINRT) OR OPENCV_FORCE_3RDPARTY_BUILD) )
 217 OCV_OPTION(BUILD_WEBP               "Build WebP from source"             (((WIN32 OR ANDROID OR APPLE) AND NOT WINRT) OR OPENCV_FORCE_3RDPARTY_BUILD) )
 218 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" (ANDROID OR OPENCV_FORCE_3RDPARTY_BUILD) )
 219 OCV_OPTION(BUILD_IPP_IW             "Build IPP IW from source"           (NOT MINGW OR OPENCV_FORCE_3RDPARTY_BUILD) IF (X86_64 OR X86) AND NOT WINRT )
 220 OCV_OPTION(BUILD_ITT                "Build Intel ITT from source"
 221     (NOT MINGW OR OPENCV_FORCE_3RDPARTY_BUILD)
 222     IF (X86_64 OR X86 OR ARM OR AARCH64 OR PPC64 OR PPC64LE) AND NOT WINRT AND NOT APPLE_FRAMEWORK
 223 )
 224
 225 # Optional 3rd party components
 226 # ===================================================
 227 OCV_OPTION(WITH_1394 "Include IEEE1394 support" ON
 228   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 229   VERIFY HAVE_DC1394)
 230 OCV_OPTION(WITH_AVFOUNDATION "Use AVFoundation for Video I/O (iOS/Mac)" ON
 231   VISIBLE_IF APPLE
 232   VERIFY HAVE_AVFOUNDATION)
 233 OCV_OPTION(WITH_CARBON "Use Carbon for UI instead of Cocoa (OBSOLETE)" OFF
 234   VISIBLE_IF (APPLE OR HAVE_COCOA)
 235   VERIFY HAVE_CARBON)
 236 OCV_OPTION(WITH_CAROTENE "Use NVidia carotene acceleration library for ARM platform" ON
 237   VISIBLE_IF (ARM OR AARCH64) AND NOT IOS AND NOT (CMAKE_VERSION VERSION_LESS "2.8.11"))
 238 OCV_OPTION(WITH_CPUFEATURES "Use cpufeatures Android library" ON
 239   VISIBLE_IF ANDROID
 240   VERIFY HAVE_CPUFEATURES)
 241 OCV_OPTION(WITH_VTK "Include VTK library support (and build opencv_viz module eiher)" ON
 242   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT CMAKE_CROSSCOMPILING
 243   VERIFY HAVE_VTK)
 244 OCV_OPTION(WITH_CUDA "Include NVidia Cuda Runtime support" OFF
 245   VISIBLE_IF NOT IOS AND NOT WINRT
 246   VERIFY HAVE_CUDA)
 247 OCV_OPTION(WITH_CUFFT "Include NVidia Cuda Fast Fourier Transform (FFT) library support" WITH_CUDA
 248   VISIBLE_IF WITH_CUDA
 249   VERIFY HAVE_CUFFT)
 250 OCV_OPTION(WITH_CUBLAS "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" WITH_CUDA
 251   VISIBLE_IF WITH_CUDA
 252   VERIFY HAVE_CUBLAS)
 253 OCV_OPTION(WITH_NVCUVID "Include NVidia Video Decoding library support" WITH_CUDA
 254   VISIBLE_IF WITH_CUDA
 255   VERIFY HAVE_NVCUVID)
 256 OCV_OPTION(WITH_EIGEN "Include Eigen2/Eigen3 support" (NOT CV_DISABLE_OPTIMIZATION AND NOT CMAKE_CROSSCOMPILING)
 257   VISIBLE_IF NOT WINRT
 258   VERIFY HAVE_EIGEN)
 259 OCV_OPTION(WITH_VFW "Include Video for Windows support (deprecated, consider using MSMF)" OFF
 260   VISIBLE_IF WIN32
 261   VERIFY HAVE_VFW)
 262 OCV_OPTION(WITH_FFMPEG "Include FFMPEG support" (NOT ANDROID)
 263   VISIBLE_IF NOT IOS AND NOT WINRT
 264   VERIFY HAVE_FFMPEG)
 265 OCV_OPTION(WITH_GSTREAMER "Include Gstreamer support" ON
 266   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 267   VERIFY HAVE_GSTREAMER AND GSTREAMER_BASE_VERSION VERSION_GREATER "0.99")
 268 OCV_OPTION(WITH_GSTREAMER_0_10 "Enable Gstreamer 0.10 support (instead of 1.x)" OFF
 269   VISIBLE_IF TRUE
 270   VERIFY HAVE_GSTREAMER AND GSTREAMER_BASE_VERSION VERSION_LESS "1.0")
 271 OCV_OPTION(WITH_GTK "Include GTK support" ON
 272   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 273   VERIFY HAVE_GTK)
 274 OCV_OPTION(WITH_GTK_2_X "Use GTK version 2" OFF
 275   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 276   VERIFY HAVE_GTK AND NOT HAVE_GTK3)
 277 OCV_OPTION(WITH_IPP "Include Intel IPP support" (NOT MINGW AND NOT CV_DISABLE_OPTIMIZATION)
 278   VISIBLE_IF (X86_64 OR X86) AND NOT WINRT AND NOT IOS
 279   VERIFY HAVE_IPP)
 280 OCV_OPTION(WITH_HALIDE "Include Halide support" OFF
 281   VISIBLE_IF TRUE
 282   VERIFY HAVE_HALIDE)
 283 OCV_OPTION(WITH_INF_ENGINE "Include Intel Inference Engine support" OFF
 284   VISIBLE_IF TRUE
 285   VERIFY INF_ENGINE_TARGET)
 286 OCV_OPTION(WITH_NGRAPH "Include nGraph support" WITH_INF_ENGINE
 287   VISIBLE_IF TRUE
 288   VERIFY TARGET ngraph::ngraph)
 289 OCV_OPTION(WITH_JASPER "Include JPEG2K support" ON
 290   VISIBLE_IF NOT IOS
 291   VERIFY HAVE_JASPER)
 292 OCV_OPTION(WITH_JPEG "Include JPEG support" ON
 293   VISIBLE_IF TRUE
 294   VERIFY HAVE_JPEG)
 295 OCV_OPTION(WITH_WEBP "Include WebP support" ON
 296   VISIBLE_IF NOT WINRT
 297   VERIFY HAVE_WEBP)
 298 OCV_OPTION(WITH_OPENEXR "Include ILM support via OpenEXR" BUILD_OPENEXR OR NOT CMAKE_CROSSCOMPILING
 299   VISIBLE_IF NOT APPLE_FRAMEWORK AND NOT WINRT
 300   VERIFY HAVE_OPENEXR)
 301 OCV_OPTION(WITH_OPENGL "Include OpenGL support" OFF
 302   VISIBLE_IF NOT ANDROID AND NOT WINRT
 303   VERIFY HAVE_OPENGL)
 304 OCV_OPTION(WITH_OPENVX "Include OpenVX support" OFF
 305   VISIBLE_IF TRUE
 306   VERIFY HAVE_OPENVX)
 307 OCV_OPTION(WITH_OPENNI "Include OpenNI support" OFF
 308   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 309   VERIFY HAVE_OPENNI)
 310 OCV_OPTION(WITH_OPENNI2 "Include OpenNI2 support" OFF
 311   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 312   VERIFY HAVE_OPENNI2)
 313 OCV_OPTION(WITH_PNG "Include PNG support" ON
 314   VISIBLE_IF TRUE
 315   VERIFY HAVE_PNG)
 316 OCV_OPTION(WITH_GDCM "Include DICOM support" OFF
 317   VISIBLE_IF TRUE
 318   VERIFY HAVE_GDCM)
 319 OCV_OPTION(WITH_PVAPI "Include Prosilica GigE support" OFF
 320   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 321   VERIFY HAVE_PVAPI)
 322 OCV_OPTION(WITH_GIGEAPI "Include Smartek GigE support" OFF
 323   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 324   VERIFY HAVE_GIGE_API)
 325 OCV_OPTION(WITH_ARAVIS "Include Aravis GigE support" OFF
 326   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT WIN32
 327   VERIFY HAVE_ARAVIS_API)
 328 OCV_OPTION(WITH_QT "Build with Qt Backend support" OFF
 329   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 330   VERIFY HAVE_QT)
 331 OCV_OPTION(WITH_WIN32UI "Build with Win32 UI Backend support" ON
 332   VISIBLE_IF WIN32 AND NOT WINRT
 333   VERIFY HAVE_WIN32UI)
 334 OCV_OPTION(WITH_QUICKTIME "Use QuickTime for Video I/O (OBSOLETE)" OFF
 335   VISIBLE_IF APPLE
 336   VERIFY HAVE_QUICKTIME)
 337 OCV_OPTION(WITH_QTKIT "Use QTKit Video I/O backend" OFF
 338   VISIBLE_IF APPLE
 339   VERIFY HAVE_QTKIT)
 340 OCV_OPTION(WITH_TBB "Include Intel TBB support" OFF
 341   VISIBLE_IF NOT IOS AND NOT WINRT
 342   VERIFY HAVE_TBB)
 343 OCV_OPTION(WITH_OPENMP "Include OpenMP support" OFF
 344   VISIBLE_IF TRUE
 345   VERIFY HAVE_OPENMP)
 346 OCV_OPTION(WITH_CSTRIPES "Include C= support" OFF
 347   VISIBLE_IF WIN32 AND NOT WINRT
 348   VERIFY HAVE_CSTRIPES)
 349 OCV_OPTION(WITH_PTHREADS_PF "Use pthreads-based parallel_for" ON
 350   VISIBLE_IF NOT WIN32 OR MINGW
 351   VERIFY HAVE_PTHREADS_PF)
 352 OCV_OPTION(WITH_TIFF "Include TIFF support" ON
 353   VISIBLE_IF NOT IOS
 354   VERIFY HAVE_TIFF)
 355 OCV_OPTION(WITH_UNICAP "Include Unicap support (GPL)" OFF
 356   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 357   VERIFY HAVE_UNICAP)
 358 OCV_OPTION(WITH_V4L "Include Video 4 Linux support" ON
 359   VISIBLE_IF UNIX AND NOT ANDROID AND NOT APPLE
 360   VERIFY HAVE_CAMV4L OR HAVE_CAMV4L2 OR HAVE_VIDEOIO)
 361 OCV_OPTION(WITH_LIBV4L "Use libv4l for Video 4 Linux support" OFF
 362   VISIBLE_IF UNIX AND NOT ANDROID AND NOT APPLE
 363   VERIFY HAVE_LIBV4L)
 364 OCV_OPTION(WITH_DSHOW "Build VideoIO with DirectShow support" ON
 365   VISIBLE_IF WIN32 AND NOT ARM AND NOT WINRT
 366   VERIFY HAVE_DSHOW)
 367 OCV_OPTION(WITH_MSMF "Build VideoIO with Media Foundation support" NOT MINGW
 368   VISIBLE_IF WIN32
 369   VERIFY HAVE_MSMF)
 370 OCV_OPTION(WITH_MSMF_DXVA "Enable hardware acceleration in Media Foundation backend" WITH_MSMF
 371   VISIBLE_IF WIN32
 372   VERIFY HAVE_MSMF_DXVA)
 373 OCV_OPTION(WITH_XIMEA "Include XIMEA cameras support" OFF
 374   VISIBLE_IF NOT ANDROID AND NOT WINRT
 375   VERIFY HAVE_XIMEA)
 376 OCV_OPTION(WITH_XINE "Include Xine support (GPL)" OFF
 377   VISIBLE_IF UNIX AND NOT APPLE AND NOT ANDROID
 378   VERIFY HAVE_XINE)
 379 OCV_OPTION(WITH_CLP "Include Clp support (EPL)" OFF
 380   VISIBLE_IF TRUE
 381   VERIFY HAVE_CLP)
 382 OCV_OPTION(WITH_OPENCL "Include OpenCL Runtime support" (NOT ANDROID AND NOT CV_DISABLE_OPTIMIZATION)
 383   VISIBLE_IF NOT IOS AND NOT WINRT
 384   VERIFY HAVE_OPENCL)
 385 OCV_OPTION(WITH_OPENCL_SVM "Include OpenCL Shared Virtual Memory support" OFF
 386   VISIBLE_IF TRUE
 387   VERIFY HAVE_OPENCL_SVM) # experimental
 388 OCV_OPTION(WITH_OPENCLAMDFFT "Include AMD OpenCL FFT library support" ON
 389   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 390   VERIFY HAVE_CLAMDFFT)
 391 OCV_OPTION(WITH_OPENCLAMDBLAS "Include AMD OpenCL BLAS library support" ON
 392   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 393   VERIFY HAVE_CLAMDBLAS)
 394 OCV_OPTION(WITH_DIRECTX "Include DirectX support" ON
 395   VISIBLE_IF WIN32 AND NOT WINRT
 396   VERIFY HAVE_DIRECTX)
 397 OCV_OPTION(WITH_OPENCL_D3D11_NV "Include NVIDIA OpenCL D3D11 support" WITH_DIRECTX
 398   VISIBLE_IF WIN32 AND NOT WINRT
 399   VERIFY HAVE_OPENCL_D3D11_NV)
 400 OCV_OPTION(WITH_INTELPERC "Include Intel Perceptual Computing support" OFF
 401   VISIBLE_IF WIN32 AND NOT WINRT
 402   VERIFY HAVE_INTELPERC)
 403 OCV_OPTION(WITH_VA "Include VA support" OFF
 404   VISIBLE_IF UNIX AND NOT ANDROID
 405   VERIFY HAVE_VA)
 406 OCV_OPTION(WITH_VA_INTEL "Include Intel VA-API/OpenCL support" OFF
 407   VISIBLE_IF UNIX AND NOT ANDROID
 408   VERIFY HAVE_VA_INTEL)
 409 OCV_OPTION(WITH_MFX "Include Intel Media SDK support" OFF
 410   VISIBLE_IF (UNIX AND NOT ANDROID) OR (WIN32 AND NOT WINRT AND NOT MINGW)
 411   VERIFY HAVE_MFX)
 412 OCV_OPTION(WITH_GDAL "Include GDAL Support" OFF
 413   VISIBLE_IF NOT ANDROID AND NOT IOS AND NOT WINRT
 414   VERIFY HAVE_GDAL)
 415 OCV_OPTION(WITH_GPHOTO2 "Include gPhoto2 library support" OFF
 416   VISIBLE_IF UNIX AND NOT ANDROID AND NOT IOS
 417   VERIFY HAVE_GPHOTO2)
 418 OCV_OPTION(WITH_LAPACK "Include Lapack library support" (NOT CV_DISABLE_OPTIMIZATION)
 419   VISIBLE_IF NOT ANDROID AND NOT IOS
 420   VERIFY HAVE_LAPACK)
 421 OCV_OPTION(WITH_ITT "Include Intel ITT support" ON
 422   VISIBLE_IF NOT APPLE_FRAMEWORK
 423   VERIFY HAVE_ITT)
 424 OCV_OPTION(WITH_PROTOBUF "Enable libprotobuf" ON
 425   VISIBLE_IF TRUE
 426   VERIFY HAVE_PROTOBUF)
 427 OCV_OPTION(WITH_IMGCODEC_HDR "Include HDR support" ON
 428   VISIBLE_IF TRUE
 429   VERIFY HAVE_IMGCODEC_HDR)
 430 OCV_OPTION(WITH_IMGCODEC_SUNRASTER "Include SUNRASTER support" ON
 431   VISIBLE_IF TRUE
 432   VERIFY HAVE_IMGCODEC_SUNRASTER)
 433 OCV_OPTION(WITH_IMGCODEC_PXM "Include PNM (PBM,PGM,PPM) and PAM formats support" ON
 434   VISIBLE_IF TRUE
 435   VERIFY HAVE_IMGCODEC_PXM)
 436 OCV_OPTION(WITH_QUIRC "Include library QR-code decoding" ON
 437   VISIBLE_IF TRUE
 438   VERIFY HAVE_QUIRC)
 439 OCV_OPTION(WITH_TENGINE "Include Arm Inference Tengine support" OFF
 440   VISIBLE_IF (ARM OR AARCH64) AND (UNIX OR ANDROID) AND NOT IOS
 441   VERIFY HAVE_TENGINE)
 442
 443 # OpenCV build components
 444 # ===================================================
 445 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR APPLE_FRAMEWORK) )
 446 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID AND NOT WINRT) IF (NOT APPLE_FRAMEWORK) )
 447 OCV_OPTION(BUILD_opencv_js          "Build JavaScript bindings by Emscripten" OFF )
 448 OCV_OPTION(BUILD_ANDROID_PROJECTS   "Build Android projects providing .apk files" ON  IF ANDROID )
 449 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 450 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" OFF  IF (NOT WINRT AND NOT APPLE_FRAMEWORK))
 451 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 452 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON  IF NOT WINRT)
 453 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     NOT INSTALL_CREATE_DISTRIB  IF (NOT APPLE_FRAMEWORK) )
 454 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           NOT INSTALL_CREATE_DISTRIB  IF (NOT APPLE_FRAMEWORK) )
 455 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into release binaries ('OFF' means default settings)" OFF )
 456 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of statically linked CRT for statically linked OpenCV" ON IF MSVC )
 457 OCV_OPTION(BUILD_WITH_DYNAMIC_IPP   "Enables dynamic linking of IPP (only for standalone IPP)" OFF )
 458 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create Java wrapper exporting all functions of OpenCV library (requires static build of OpenCV modules)" ANDROID IF NOT BUILD_SHARED_LIBS)
 459 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID )
 460 OCV_OPTION(BUILD_CUDA_STUBS         "Build CUDA modules stubs when no CUDA SDK" OFF  IF (NOT APPLE_FRAMEWORK) )
 461 OCV_OPTION(BUILD_JAVA               "Enable Java support"                         (ANDROID OR NOT CMAKE_CROSSCOMPILING)  IF (ANDROID OR (NOT APPLE_FRAMEWORK AND NOT WINRT)) )
 462
 463 # OpenCV installation options
 464 # ===================================================
 465 OCV_OPTION(INSTALL_CREATE_DISTRIB   "Change install rules to build the distribution package" OFF )
 466 OCV_OPTION(INSTALL_BIN_EXAMPLES     "Install prebuilt examples" WIN32 IF BUILD_EXAMPLES)
 467 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 468 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 469 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 470 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT APPLE_FRAMEWORK AND BUILD_SHARED_LIBS) )
 471 OCV_OPTION(INSTALL_TESTS            "Install accuracy and performance test binaries and test data" OFF)
 472
 473 # OpenCV build options
 474 # ===================================================
 475 OCV_OPTION(ENABLE_CCACHE              "Use ccache"                                               (UNIX AND NOT IOS AND (CMAKE_GENERATOR MATCHES "Makefile" OR CMAKE_GENERATOR MATCHES "Ninja")) )
 476 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  MSVC IF (MSVC OR (NOT IOS AND NOT CMAKE_CROSSCOMPILING) ) )
 477 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) )
 478 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CV_GCC )
 479 OCV_OPTION(ENABLE_COVERAGE            "Enable coverage collection with  GCov"                    OFF  IF CV_GCC )
 480 OCV_OPTION(OPENCV_ENABLE_MEMORY_SANITIZER "Better support for memory/address sanitizers"         OFF)
 481 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CV_GCC )
 482 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CV_GCC AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 483 OCV_OPTION(ENABLE_FAST_MATH           "Enable compiler options for fast math optimizations on FP computations (not recommended)" OFF)
 484 if(NOT IOS)  # Use CPU_BASELINE instead
 485 OCV_OPTION(ENABLE_NEON                "Enable NEON instructions"                                 (NEON OR ANDROID_ARM_NEON OR AARCH64) IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 486 OCV_OPTION(ENABLE_VFPV3               "Enable VFPv3-D32 instructions"                            OFF  IF (CV_GCC OR CV_CLANG) AND (ARM OR AARCH64 OR IOS) )
 487 endif()
 488 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 489 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 490 OCV_OPTION(ANDROID_EXAMPLES_WITH_LIBS "Build binaries of Android examples with native libraries" OFF  IF ANDROID )
 491 OCV_OPTION(ENABLE_IMPL_COLLECTION     "Collect implementation data on function call"             OFF )
 492 OCV_OPTION(ENABLE_INSTRUMENTATION     "Instrument functions to collect calls trace and performance" OFF )
 493 OCV_OPTION(ENABLE_GNU_STL_DEBUG       "Enable GNU STL Debug mode (defines _GLIBCXX_DEBUG)"       OFF IF ((NOT CMAKE_VERSION VERSION_LESS "2.8.11") AND CV_GCC) )
 494 OCV_OPTION(ENABLE_BUILD_HARDENING     "Enable hardening of the resulting binaries (against security attacks, detects memory corruption, etc)" OFF)
 495 OCV_OPTION(ENABLE_LTO                 "Enable Link Time Optimization" OFF IF CV_GCC OR MSVC)
 496 OCV_OPTION(ENABLE_THIN_LTO            "Enable Thin LTO" OFF IF CV_CLANG)
 497 OCV_OPTION(GENERATE_ABI_DESCRIPTOR    "Generate XML file for abi_compliance_checker tool" OFF IF UNIX)
 498 OCV_OPTION(OPENCV_GENERATE_PKGCONFIG  "Generate .pc file for pkg-config build tool (deprecated)" ON IF (UNIX AND NOT MSVC AND NOT IOS AND NOT ANDROID) )
 499 OCV_OPTION(CV_ENABLE_INTRINSICS       "Use intrinsic-based optimized code" ON )
 500 OCV_OPTION(CV_DISABLE_OPTIMIZATION    "Disable explicit optimized code (dispatched code/intrinsics/loop unrolling/etc)" OFF )
 501 OCV_OPTION(CV_TRACE                   "Enable OpenCV code trace" ON)
 502 OCV_OPTION(OPENCV_GENERATE_SETUPVARS  "Generate setup_vars* scripts" ON IF (NOT ANDROID AND NOT APPLE_FRAMEWORK) )
 503 OCV_OPTION(ENABLE_CONFIG_VERIFICATION "Fail build if actual configuration doesn't match requested (WITH_XXX != HAVE_XXX)" OFF)
 504 OCV_OPTION(OPENCV_ENABLE_MEMALIGN     "Enable posix_memalign or memalign usage" ON)
 505
 506 OCV_OPTION(ENABLE_PYLINT              "Add target with Pylint checks"                            (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 507 OCV_OPTION(ENABLE_FLAKE8              "Add target with Python flake8 checker"                    (BUILD_DOCS OR BUILD_EXAMPLES) IF (NOT CMAKE_CROSSCOMPILING AND NOT APPLE_FRAMEWORK) )
 508
 509 if(ENABLE_IMPL_COLLECTION)
 510   add_definitions(-DCV_COLLECT_IMPL_DATA)
 511 endif()
 512
 513 set(OPENCV_MATHJAX_RELPATH "https://cdnjs.cloudflare.com/ajax/libs/mathjax/2.7.0" CACHE STRING "URI to a MathJax installation")
 514
 515 # ----------------------------------------------------------------------------
 516 #  Get actual OpenCV version number from sources
 517 # ----------------------------------------------------------------------------
 518 include(cmake/OpenCVVersion.cmake)
 519
 520 ocv_cmake_hook(POST_OPTIONS)
 521
 522 # ----------------------------------------------------------------------------
 523 #  Build & install layouts
 524 # ----------------------------------------------------------------------------
 525
 526 if(OPENCV_TEST_DATA_PATH)
 527   get_filename_component(OPENCV_TEST_DATA_PATH ${OPENCV_TEST_DATA_PATH} ABSOLUTE)
 528 endif()
 529
 530 # Save libs and executables in the same place
 531 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications")
 532
 533 if(ANDROID)
 534   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 535   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 536 else()
 537   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib")
 538   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib")
 539 endif()
 540
 541 if(ANDROID)
 542   if(ANDROID_ABI MATCHES "NEON")
 543     set(ENABLE_NEON ON)
 544   endif()
 545   if(ANDROID_ABI MATCHES "VFPV3")
 546     set(ENABLE_VFPV3 ON)
 547   endif()
 548 endif()
 549
 550 if(WIN32)
 551   # Postfix of DLLs:
 552   ocv_update(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 553   ocv_update(OPENCV_DEBUG_POSTFIX d)
 554 else()
 555   # Postfix of so's:
 556   ocv_update(OPENCV_DLLVERSION "")
 557   ocv_update(OPENCV_DEBUG_POSTFIX "")
 558 endif()
 559
 560 if(DEFINED CMAKE_DEBUG_POSTFIX)
 561   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 562 endif()
 563
 564 if((INSTALL_CREATE_DISTRIB AND BUILD_SHARED_LIBS AND NOT DEFINED BUILD_opencv_world) OR APPLE_FRAMEWORK)
 565   set(BUILD_opencv_world ON CACHE INTERNAL "")
 566 endif()
 567
 568 include(cmake/OpenCVInstallLayout.cmake)
 569
 570 # ----------------------------------------------------------------------------
 571 #  Path for build/platform -specific headers
 572 # ----------------------------------------------------------------------------
 573 ocv_update(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 574 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 575
 576 # ----------------------------------------------------------------------------
 577 #  Path for additional modules
 578 # ----------------------------------------------------------------------------
 579 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules (can be ;-separated list of paths)")
 580
 581 # ----------------------------------------------------------------------------
 582 #  Autodetect if we are in a GIT repository
 583 # ----------------------------------------------------------------------------
 584 find_host_package(Git QUIET)
 585
 586 if(NOT DEFINED OPENCV_VCSVERSION AND GIT_FOUND)
 587   ocv_git_describe(OPENCV_VCSVERSION "${OpenCV_SOURCE_DIR}")
 588 elseif(NOT DEFINED OPENCV_VCSVERSION)
 589   # We don't have git:
 590   set(OPENCV_VCSVERSION "unknown")
 591 endif()
 592
 593
 594 # ----------------------------------------------------------------------------
 595 # OpenCV compiler and linker options
 596 # ----------------------------------------------------------------------------
 597 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 598 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 599   set(CMAKE_BUILD_TYPE Release)
 600 endif()
 601
 602 ocv_cmake_hook(POST_CMAKE_BUILD_OPTIONS)
 603
 604 # --- Python Support ---
 605 if(NOT IOS)
 606   include(cmake/OpenCVDetectPython.cmake)
 607 endif()
 608
 609 include(cmake/OpenCVCompilerOptions.cmake)
 610
 611 ocv_cmake_hook(POST_COMPILER_OPTIONS)
 612
 613 # ----------------------------------------------------------------------------
 614 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 615 # ----------------------------------------------------------------------------
 616 if(UNIX)
 617   if(NOT APPLE_FRAMEWORK OR OPENCV_ENABLE_PKG_CONFIG)
 618     if(CMAKE_CROSSCOMPILING AND NOT DEFINED ENV{PKG_CONFIG_LIBDIR} AND NOT DEFINED ENV{PKG_CONFIG_SYSROOT_DIR}
 619         AND NOT OPENCV_ENABLE_PKG_CONFIG
 620     )
 621       if(NOT PkgConfig_FOUND)
 622         message(STATUS "OpenCV disables pkg-config to avoid using of host libraries. Consider using PKG_CONFIG_LIBDIR to specify target SYSROOT")
 623       elseif(OPENCV_SKIP_PKG_CONFIG_WARNING)
 624         message(WARNING "pkg-config is enabled in cross-compilation mode without defining of PKG_CONFIG_LIBDIR environment variable. This may lead to misconfigured host-based dependencies.")
 625       endif()
 626     elseif(OPENCV_DISABLE_PKG_CONFIG)
 627       if(PkgConfig_FOUND)
 628         message(WARNING "OPENCV_DISABLE_PKG_CONFIG flag has no effect")
 629       endif()
 630     else()
 631       find_package(PkgConfig QUIET)
 632     endif()
 633   endif()
 634   include(CheckFunctionExists)
 635   include(CheckIncludeFile)
 636   include(CheckSymbolExists)
 637
 638   if(NOT APPLE)
 639     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD)
 640     if(ANDROID)
 641       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 642     elseif(CMAKE_SYSTEM_NAME MATCHES "FreeBSD|NetBSD|DragonFly|OpenBSD|Haiku")
 643       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 644     elseif(EMSCRIPTEN)
 645       # no need to link to system libs with emscripten
 646     else()
 647       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 648     endif()
 649   else()
 650     set(HAVE_PTHREAD 1)
 651   endif()
 652
 653   if(OPENCV_ENABLE_MEMALIGN)
 654     CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN)
 655     CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 656     if(HAVE_MALLOC_H)
 657       CHECK_SYMBOL_EXISTS(memalign malloc.h HAVE_MEMALIGN)
 658     endif()
 659     # TODO:
 660     # - _aligned_malloc() on Win32
 661     # - std::aligned_alloc() C++17 / C11
 662   endif()
 663 endif()
 664
 665 include(cmake/OpenCVPCHSupport.cmake)
 666 include(cmake/OpenCVModule.cmake)
 667
 668 # ----------------------------------------------------------------------------
 669 #  Detect endianness of build platform
 670 # ----------------------------------------------------------------------------
 671
 672 if(IOS)
 673   # test_big_endian needs try_compile, which doesn't work for iOS
 674   # http://public.kitware.com/Bug/view.php?id=12288
 675   set(WORDS_BIGENDIAN 0)
 676 else()
 677   include(TestBigEndian)
 678   test_big_endian(WORDS_BIGENDIAN)
 679 endif()
 680
 681 # ----------------------------------------------------------------------------
 682 #  Detect 3rd-party libraries
 683 # ----------------------------------------------------------------------------
 684
 685 if(ANDROID AND WITH_CPUFEATURES)
 686   add_subdirectory(3rdparty/cpufeatures)
 687   set(HAVE_CPUFEATURES 1)
 688 endif()
 689
 690 include(cmake/OpenCVFindFrameworks.cmake)
 691
 692 include(cmake/OpenCVFindLibsGrfmt.cmake)
 693 include(cmake/OpenCVFindLibsGUI.cmake)
 694 include(cmake/OpenCVFindLibsVideo.cmake)
 695 include(cmake/OpenCVFindLibsPerf.cmake)
 696 include(cmake/OpenCVFindLAPACK.cmake)
 697 include(cmake/OpenCVFindProtobuf.cmake)
 698 if(WITH_TENGINE)
 699   include(cmake/OpenCVFindTengine.cmake)
 700 endif()
 701
 702 # ----------------------------------------------------------------------------
 703 #  Detect other 3rd-party libraries/tools
 704 # ----------------------------------------------------------------------------
 705
 706 # --- Java Support ---
 707 if(BUILD_JAVA)
 708   if(ANDROID)
 709     include(cmake/android/OpenCVDetectAndroidSDK.cmake)
 710   else()
 711     include(cmake/OpenCVDetectApacheAnt.cmake)
 712     find_package(JNI)
 713   endif()
 714 endif()
 715
 716 if(ENABLE_PYLINT AND PYTHON_DEFAULT_AVAILABLE)
 717   include(cmake/OpenCVPylint.cmake)
 718 endif()
 719 if(ENABLE_FLAKE8 AND PYTHON_DEFAULT_AVAILABLE)
 720   find_package(Flake8 QUIET)
 721   if(NOT FLAKE8_FOUND OR NOT FLAKE8_EXECUTABLE)
 722     include("${CMAKE_CURRENT_LIST_DIR}/cmake/FindFlake8.cmake")
 723   endif()
 724   if(FLAKE8_FOUND)
 725     add_custom_target(check_flake8
 726         COMMAND "${FLAKE8_EXECUTABLE}" . --count --select=E9,E901,E999,F821,F822,F823 --show-source --statistics --exclude='.git,__pycache__,*.config.py,svgfig.py'
 727         WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 728         COMMENT "Running flake8"
 729     )
 730   endif()
 731 endif()
 732
 733
 734 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 735   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 736 else()
 737   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 738 endif()
 739
 740 # --- OpenCL ---
 741 if(WITH_OPENCL)
 742   include(cmake/OpenCVDetectOpenCL.cmake)
 743 endif()
 744
 745 # --- Halide ---
 746 if(WITH_HALIDE)
 747   include(cmake/OpenCVDetectHalide.cmake)
 748 endif()
 749
 750 # --- Inference Engine ---
 751 if(WITH_INF_ENGINE)
 752   include(cmake/OpenCVDetectInferenceEngine.cmake)
 753 endif()
 754
 755 # --- DirectX ---
 756 if(WITH_DIRECTX)
 757   include(cmake/OpenCVDetectDirectX.cmake)
 758 endif()
 759
 760 if(WITH_VTK)
 761   include(cmake/OpenCVDetectVTK.cmake)
 762 endif()
 763
 764 if(WITH_OPENVX)
 765   include(cmake/FindOpenVX.cmake)
 766 endif()
 767
 768 if(WITH_QUIRC)
 769   add_subdirectory(3rdparty/quirc)
 770   set(HAVE_QUIRC TRUE)
 771 endif()
 772 # ----------------------------------------------------------------------------
 773 # OpenCV HAL
 774 # ----------------------------------------------------------------------------
 775 set(_hal_includes "")
 776 macro(ocv_hal_register HAL_LIBRARIES_VAR HAL_HEADERS_VAR HAL_INCLUDE_DIRS_VAR)
 777   # 1. libraries
 778   foreach (l ${${HAL_LIBRARIES_VAR}})
 779     if(NOT TARGET ${l})
 780       get_filename_component(l "${l}" ABSOLUTE)
 781     endif()
 782     list(APPEND OPENCV_HAL_LINKER_LIBS ${l})
 783   endforeach()
 784   # 2. headers
 785   foreach (h ${${HAL_HEADERS_VAR}})
 786     set(_hal_includes "${_hal_includes}\n#include \"${h}\"")
 787   endforeach()
 788   # 3. include paths
 789   ocv_include_directories(${${HAL_INCLUDE_DIRS_VAR}})
 790 endmacro()
 791
 792 if(NOT DEFINED OpenCV_HAL)
 793   set(OpenCV_HAL "OpenCV_HAL")
 794 endif()
 795
 796 if(HAVE_OPENVX)
 797   if(NOT ";${OpenCV_HAL};" MATCHES ";openvx;")
 798     set(OpenCV_HAL "openvx;${OpenCV_HAL}")
 799   endif()
 800 endif()
 801
 802 if(WITH_CAROTENE)
 803   ocv_debug_message(STATUS "Enable carotene acceleration")
 804   if(NOT ";${OpenCV_HAL};" MATCHES ";carotene;")
 805     set(OpenCV_HAL "carotene;${OpenCV_HAL}")
 806   endif()
 807 endif()
 808
 809 foreach(hal ${OpenCV_HAL})
 810   if(hal STREQUAL "carotene")
 811     if(";${CPU_BASELINE_FINAL};" MATCHES ";NEON;")
 812       add_subdirectory(3rdparty/carotene/hal)
 813       ocv_hal_register(CAROTENE_HAL_LIBRARIES CAROTENE_HAL_HEADERS CAROTENE_HAL_INCLUDE_DIRS)
 814       list(APPEND OpenCV_USED_HAL "carotene (ver ${CAROTENE_HAL_VERSION})")
 815     else()
 816       message(STATUS "Carotene: NEON is not available, disabling carotene...")
 817     endif()
 818   elseif(hal STREQUAL "openvx")
 819     add_subdirectory(3rdparty/openvx)
 820     ocv_hal_register(OPENVX_HAL_LIBRARIES OPENVX_HAL_HEADERS OPENVX_HAL_INCLUDE_DIRS)
 821     list(APPEND OpenCV_USED_HAL "openvx (ver ${OPENVX_HAL_VERSION})")
 822   else()
 823     ocv_debug_message(STATUS "OpenCV HAL: ${hal} ...")
 824     ocv_clear_vars(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 825     find_package(${hal} NO_MODULE QUIET)
 826     if(${hal}_FOUND)
 827       ocv_hal_register(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 828       list(APPEND OpenCV_USED_HAL "${hal} (ver ${${hal}_VERSION})")
 829     endif()
 830   endif()
 831 endforeach()
 832 configure_file("${OpenCV_SOURCE_DIR}/cmake/templates/custom_hal.hpp.in" "${CMAKE_BINARY_DIR}/custom_hal.hpp" @ONLY)
 833 unset(_hal_includes)
 834
 835
 836 # ----------------------------------------------------------------------------
 837 # Add CUDA libraries (needed for apps/tools, samples)
 838 # ----------------------------------------------------------------------------
 839 if(HAVE_CUDA)
 840   set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_LIBRARIES} ${CUDA_npp_LIBRARY})
 841   if(HAVE_CUBLAS)
 842     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cublas_LIBRARY})
 843   endif()
 844   if(HAVE_CUFFT)
 845     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cufft_LIBRARY})
 846   endif()
 847   foreach(p ${CUDA_LIBS_PATH})
 848     if(MSVC AND CMAKE_GENERATOR MATCHES "Ninja|JOM")
 849       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CMAKE_LIBRARY_PATH_FLAG}"${p}")
 850     else()
 851       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CMAKE_LIBRARY_PATH_FLAG}${p})
 852     endif()
 853   endforeach()
 854 endif()
 855
 856
 857 # ----------------------------------------------------------------------------
 858 # Code trace support
 859 # ----------------------------------------------------------------------------
 860 if(CV_TRACE)
 861   include(cmake/OpenCVDetectTrace.cmake)
 862 endif()
 863
 864 ocv_cmake_hook(POST_DETECT_DEPENDECIES)  # typo, deprecated (2019-06)
 865 ocv_cmake_hook(POST_DETECT_DEPENDENCIES)
 866
 867 # ----------------------------------------------------------------------------
 868 # Solution folders:
 869 # ----------------------------------------------------------------------------
 870 if(ENABLE_SOLUTION_FOLDERS)
 871   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 872   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 873 endif()
 874
 875 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 876 include(cmake/OpenCVExtraTargets.cmake)
 877
 878 # ----------------------------------------------------------------------------
 879 # Process subdirectories
 880 # ----------------------------------------------------------------------------
 881
 882 # opencv.hpp and legacy headers
 883 add_subdirectory(include)
 884
 885 # Enable compiler options for OpenCV modules/apps/samples only (ignore 3rdparty)
 886 ocv_add_modules_compiler_options()
 887
 888 # OpenCV modules
 889 add_subdirectory(modules)
 890
 891 # Generate targets for documentation
 892 add_subdirectory(doc)
 893
 894 # various data that is used by cv libraries and/or demo applications.
 895 add_subdirectory(data)
 896
 897 # extra applications
 898 if(BUILD_opencv_apps)
 899   add_subdirectory(apps)
 900 endif()
 901
 902 # examples
 903 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES OR INSTALL_C_EXAMPLES)
 904   add_subdirectory(samples)
 905 endif()
 906
 907 if(ANDROID)
 908   add_subdirectory(platforms/android/service)
 909 endif()
 910
 911 # ----------------------------------------------------------------------------
 912 # Finalization: generate configuration-based files
 913 # ----------------------------------------------------------------------------
 914
 915 ocv_cmake_hook(PRE_FINALIZE)
 916
 917 # Generate platform-dependent and configuration-dependent headers
 918 include(cmake/OpenCVGenHeaders.cmake)
 919
 920 # Generate opencv.pc for pkg-config command
 921 if(NOT OPENCV_SKIP_PKGCONFIG_GENERATION
 922     AND OPENCV_GENERATE_PKGCONFIG
 923     AND NOT CMAKE_GENERATOR MATCHES "Xcode")
 924   include(cmake/OpenCVGenPkgconfig.cmake)
 925 endif()
 926
 927 # Generate OpenCV.mk for ndk-build (Android build tool)
 928 include(cmake/OpenCVGenAndroidMK.cmake)
 929
 930 # Generate OpenCVConfig.cmake and OpenCVConfig-version.cmake for cmake projects
 931 include(cmake/OpenCVGenConfig.cmake)
 932
 933 # Generate Info.plist for the IOS framework
 934 if(APPLE_FRAMEWORK)
 935   include(cmake/OpenCVGenInfoPlist.cmake)
 936 endif()
 937
 938 # Generate ABI descriptor
 939 include(cmake/OpenCVGenABI.cmake)
 940
 941 # Generate environment setup file
 942 if(INSTALL_TESTS AND OPENCV_TEST_DATA_PATH)
 943   if(ANDROID)
 944     get_filename_component(TEST_PATH ${OPENCV_TEST_INSTALL_PATH} DIRECTORY)
 945     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_android.sh.in"
 946                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 947     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 948             DESTINATION ./ COMPONENT tests)
 949   elseif(WIN32)
 950     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_windows.cmd.in"
 951                    "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd" @ONLY)
 952     install(PROGRAMS "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd"
 953             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 954   elseif(UNIX)
 955     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_unix.sh.in"
 956                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 957     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 958             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 959   endif()
 960 endif()
 961
 962 if(NOT OPENCV_README_FILE)
 963   if(ANDROID)
 964     set(OPENCV_README_FILE ${CMAKE_CURRENT_SOURCE_DIR}/platforms/android/README.android)
 965   endif()
 966 endif()
 967
 968 if(NOT OPENCV_LICENSE_FILE)
 969   set(OPENCV_LICENSE_FILE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
 970 endif()
 971
 972 # for UNIX it does not make sense as LICENSE and readme will be part of the package automatically
 973 if(ANDROID OR NOT UNIX)
 974   install(FILES ${OPENCV_LICENSE_FILE}
 975         PERMISSIONS OWNER_READ OWNER_WRITE GROUP_READ WORLD_READ
 976         DESTINATION ./ COMPONENT libs)
 977   if(OPENCV_README_FILE)
 978     install(FILES ${OPENCV_README_FILE}
 979             PERMISSIONS OWNER_READ OWNER_WRITE GROUP_READ WORLD_READ
 980             DESTINATION ./ COMPONENT libs)
 981   endif()
 982 endif()
 983
 984 if(COMMAND ocv_pylint_finalize)
 985   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/modules/python/test)
 986   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/python)
 987   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/dnn)
 988   ocv_pylint_add_directory_recurse(${CMAKE_CURRENT_LIST_DIR}/samples/python/tutorial_code)
 989   ocv_pylint_finalize()
 990 endif()
 991
 992 if(OPENCV_GENERATE_SETUPVARS)
 993   include(cmake/OpenCVGenSetupVars.cmake)
 994 endif()
 995
 996 # ----------------------------------------------------------------------------
 997 # Summary:
 998 # ----------------------------------------------------------------------------
 999 status("")
1000 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
1001 if(OPENCV_VCSVERSION)
1002   status("  Version control:" ${OPENCV_VCSVERSION})
1003 endif()
1004 if(OPENCV_EXTRA_MODULES_PATH AND NOT BUILD_INFO_SKIP_EXTRA_MODULES)
1005   set(__dump_extra_header OFF)
1006   foreach(p ${OPENCV_EXTRA_MODULES_PATH})
1007     if(EXISTS ${p})
1008       if(NOT __dump_extra_header)
1009         set(__dump_extra_header ON)
1010         status("")
1011         status("  Extra modules:")
1012       else()
1013         status("")
1014       endif()
1015       ocv_git_describe(EXTRA_MODULES_VCSVERSION "${p}")
1016       status("    Location (extra):" ${p})
1017       status("    Version control (extra):" ${EXTRA_MODULES_VCSVERSION})
1018     endif()
1019   endforeach()
1020   unset(__dump_extra_header)
1021 endif()
1022
1023 # ========================== build platform ==========================
1024 status("")
1025 status("  Platform:")
1026 if(NOT DEFINED OPENCV_TIMESTAMP
1027     AND NOT CMAKE_VERSION VERSION_LESS 2.8.11
1028     AND NOT BUILD_INFO_SKIP_TIMESTAMP
1029 )
1030   string(TIMESTAMP OPENCV_TIMESTAMP "" UTC)
1031   set(OPENCV_TIMESTAMP "${OPENCV_TIMESTAMP}" CACHE STRING "Timestamp of OpenCV build configuration" FORCE)
1032 endif()
1033 if(OPENCV_TIMESTAMP)
1034   status("    Timestamp:"      ${OPENCV_TIMESTAMP})
1035 endif()
1036 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
1037 if(CMAKE_CROSSCOMPILING)
1038   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
1039 endif()
1040 status("    CMake:"            ${CMAKE_VERSION})
1041 status("    CMake generator:"  ${CMAKE_GENERATOR})
1042 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
1043 if(MSVC)
1044   status("    MSVC:"           ${MSVC_VERSION})
1045 endif()
1046 if(CMAKE_GENERATOR MATCHES Xcode)
1047   status("    Xcode:"          ${XCODE_VERSION})
1048 endif()
1049 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
1050   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
1051 endif()
1052
1053
1054 # ========================= CPU code generation mode =========================
1055 status("")
1056 status("  CPU/HW features:")
1057 status("    Baseline:"  "${CPU_BASELINE_FINAL}")
1058 if(NOT CPU_BASELINE STREQUAL CPU_BASELINE_FINAL)
1059   status("      requested:"  "${CPU_BASELINE}")
1060 endif()
1061 if(CPU_BASELINE_REQUIRE)
1062   status("      required:"  "${CPU_BASELINE_REQUIRE}")
1063 endif()
1064 if(CPU_BASELINE_DISABLE)
1065   status("      disabled:"  "${CPU_BASELINE_DISABLE}")
1066 endif()
1067 if(CPU_DISPATCH_FINAL OR CPU_DISPATCH)
1068   status("    Dispatched code generation:"  "${CPU_DISPATCH_FINAL}")
1069   if(NOT CPU_DISPATCH STREQUAL CPU_DISPATCH_FINAL)
1070     status("      requested:"  "${CPU_DISPATCH}")
1071   endif()
1072   if(CPU_DISPATCH_REQUIRE)
1073     status("      required:"  "${CPU_DISPATCH_REQUIRE}")
1074   endif()
1075   foreach(OPT ${CPU_DISPATCH_FINAL})
1076     status("      ${OPT} (${CPU_${OPT}_USAGE_COUNT} files):"  "+ ${CPU_DISPATCH_${OPT}_INCLUDED}")
1077   endforeach()
1078 endif()
1079
1080 # ========================== C/C++ options ==========================
1081 if(CMAKE_CXX_COMPILER_VERSION)
1082   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
1083 else()
1084   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
1085 endif()
1086 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
1087
1088 status("")
1089 status("  C/C++:")
1090 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
1091 if(ENABLE_CXX11 OR HAVE_CXX11)
1092 status("    C++11:" HAVE_CXX11 THEN YES ELSE NO)
1093 endif()
1094 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
1095 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
1096 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
1097 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
1098 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
1099 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
1100 if(WIN32)
1101   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
1102   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
1103 else()
1104   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
1105   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
1106 endif()
1107 status("    ccache:"                  OPENCV_COMPILER_IS_CCACHE THEN YES ELSE NO)
1108 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
1109
1110 # ========================== Dependencies ============================
1111 ocv_get_all_libs(deps_modules deps_extra deps_3rdparty)
1112 status("    Extra dependencies:" ${deps_extra})
1113 status("    3rdparty dependencies:" ${deps_3rdparty})
1114
1115 # ========================== OpenCV modules ==========================
1116 status("")
1117 status("  OpenCV modules:")
1118 set(OPENCV_MODULES_BUILD_ST "")
1119 foreach(the_module ${OPENCV_MODULES_BUILD})
1120   if(NOT OPENCV_MODULE_${the_module}_CLASS STREQUAL "INTERNAL" OR the_module STREQUAL "opencv_ts")
1121     list(APPEND OPENCV_MODULES_BUILD_ST "${the_module}")
1122   endif()
1123 endforeach()
1124 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD_ST}")
1125 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
1126 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO}")
1127 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
1128 list(SORT OPENCV_MODULES_BUILD_ST)
1129 list(SORT OPENCV_MODULES_DISABLED_USER_ST)
1130 list(SORT OPENCV_MODULES_DISABLED_AUTO_ST)
1131 list(SORT OPENCV_MODULES_DISABLED_FORCE_ST)
1132 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
1133 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
1134 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
1135 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
1136
1137 ocv_build_features_string(apps_status
1138   IF BUILD_TESTS AND HAVE_opencv_ts THEN "tests"
1139   IF BUILD_PERF_TESTS AND HAVE_opencv_ts THEN "perf_tests"
1140   IF BUILD_EXAMPLES THEN "examples"
1141   IF BUILD_opencv_apps THEN "apps"
1142   IF BUILD_ANDROID_SERVICE THEN "android_service"
1143   IF BUILD_ANDROID_EXAMPLES AND CAN_BUILD_ANDROID_PROJECTS THEN "android_examples"
1144   ELSE "-")
1145 status("    Applications:" "${apps_status}")
1146 ocv_build_features_string(docs_status
1147     IF TARGET doxygen_cpp THEN "doxygen"
1148     IF TARGET doxygen_python THEN "python"
1149     IF TARGET doxygen_javadoc THEN "javadoc"
1150     IF BUILD_opencv_js OR DEFINED OPENCV_JS_LOCATION THEN "js"
1151     ELSE "NO"
1152 )
1153 status("    Documentation:" "${docs_status}")
1154 status("    Non-free algorithms:" OPENCV_ENABLE_NONFREE THEN "YES" ELSE "NO")
1155
1156 # ========================== Android details ==========================
1157 if(ANDROID)
1158   status("")
1159   if(DEFINED ANDROID_NDK_REVISION)
1160     set(__msg "${ANDROID_NDK} (ver ${ANDROID_NDK_REVISION})")
1161   else()
1162     set(__msg "location: ${ANDROID_NDK}")
1163   endif()
1164   status("  Android NDK: " ${__msg})
1165   status("    Android ABI:" ${ANDROID_ABI})
1166   if(BUILD_WITH_STANDALONE_TOOLCHAIN)
1167     status("    NDK toolchain:" "standalone: ${ANDROID_STANDALONE_TOOLCHAIN}")
1168   elseif(BUILD_WITH_ANDROID_NDK OR DEFINED ANDROID_TOOLCHAIN_NAME)
1169     status("    NDK toolchain:" "${ANDROID_TOOLCHAIN_NAME}")
1170   endif()
1171   status("    STL type:" ${ANDROID_STL})
1172   status("    Native API level:" ${ANDROID_NATIVE_API_LEVEL})
1173
1174   if(BUILD_ANDROID_PROJECTS)
1175     status("  Android SDK: " "${ANDROID_SDK} (tools: ${ANDROID_SDK_TOOLS_VERSION} build tools: ${ANDROID_SDK_BUILD_TOOLS_VERSION})")
1176     if(ANDROID_EXECUTABLE)
1177       status("    android tool:"  "${ANDROID_EXECUTABLE}")
1178     endif()
1179   else()
1180     status("  Android SDK: " "not used, projects are not built")
1181   endif()
1182   if(DEFINED ANDROID_SDK_COMPATIBLE_TARGET)
1183     status("    SDK target:" "${ANDROID_SDK_COMPATIBLE_TARGET}")
1184   endif()
1185   if(DEFINED ANDROID_PROJECTS_BUILD_TYPE)
1186     if(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1187       status("    Projects build scripts:" "Ant/Eclipse compatible")
1188     elseif(ANDROID_PROJECTS_BUILD_TYPE STREQUAL "ANT")
1189       status("    Projects build scripts:" "Gradle")
1190     endif()
1191   endif()
1192 endif()
1193
1194 # ================== Windows RT features ==================
1195 if(WIN32)
1196 status("")
1197 status("  Windows RT support:" WINRT THEN YES ELSE NO)
1198   if(WINRT)
1199     status("    Building for Microsoft platform: " ${CMAKE_SYSTEM_NAME})
1200     status("    Building for architectures: " ${CMAKE_VS_EFFECTIVE_PLATFORMS})
1201     status("    Building for version: " ${CMAKE_SYSTEM_VERSION})
1202     if (DEFINED ENABLE_WINRT_MODE_NATIVE)
1203       status("    Building for C++ without CX extensions")
1204     endif()
1205   endif()
1206 endif(WIN32)
1207
1208 # ========================== GUI ==========================
1209 status("")
1210 status("  GUI: ")
1211
1212 if(WITH_QT OR HAVE_QT)
1213   if(HAVE_QT5)
1214     status("    QT:" "YES (ver ${Qt5Core_VERSION_STRING})")
1215     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt5OpenGL_LIBRARIES} ${Qt5OpenGL_VERSION_STRING})" ELSE NO)
1216   elseif(HAVE_QT)
1217     status("    QT:" "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})")
1218     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
1219   else()
1220     status("    QT:" "NO")
1221   endif()
1222 endif()
1223
1224 if(WITH_WIN32UI)
1225   status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
1226 endif()
1227
1228 if(APPLE)
1229   if(WITH_CARBON)
1230     status("    Carbon:" YES)
1231   else()
1232     status("    Cocoa:"  YES)
1233   endif()
1234 endif()
1235
1236 if(WITH_GTK OR HAVE_GTK)
1237   if(HAVE_GTK3)
1238     status("    GTK+:" "YES (ver ${GTK3_VERSION})")
1239   elseif(HAVE_GTK)
1240     status("    GTK+:" "YES (ver ${GTK2_VERSION})")
1241   else()
1242     status("    GTK+:" "NO")
1243   endif()
1244   if(HAVE_GTK)
1245     status(  "      GThread :" HAVE_GTHREAD THEN "YES (ver ${GTHREAD_VERSION})" ELSE NO)
1246     status(  "      GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${GTKGLEXT_VERSION})" ELSE NO)
1247   endif()
1248 endif()
1249
1250 if(WITH_OPENGL OR HAVE_OPENGL)
1251   status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
1252 endif()
1253
1254 if(WITH_VTK OR HAVE_VTK)
1255   status("    VTK support:" HAVE_VTK THEN "YES (ver ${VTK_VERSION})" ELSE NO)
1256 endif()
1257
1258 # ========================== MEDIA IO ==========================
1259 status("")
1260 status("  Media I/O: ")
1261 status("    ZLib:"   ZLIB_FOUND THEN "${ZLIB_LIBRARIES} (ver ${ZLIB_VERSION_STRING})" ELSE "build (ver ${ZLIB_VERSION_STRING})")
1262
1263 if(WITH_JPEG OR HAVE_JPEG)
1264   if(NOT HAVE_JPEG)
1265     status("    JPEG:" NO)
1266   elseif(BUILD_JPEG)
1267     status("    JPEG:" "build-${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1268   else()
1269     status("    JPEG:" "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})")
1270   endif()
1271 endif()
1272
1273 if(WITH_WEBP OR HAVE_WEBP)
1274   status("    WEBP:" WEBP_FOUND THEN "${WEBP_LIBRARY} (ver ${WEBP_VERSION})" ELSE "build (ver ${WEBP_VERSION})")
1275 endif()
1276
1277 if(WITH_PNG OR HAVE_PNG)
1278   status("    PNG:"  PNG_FOUND  THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})" ELSE "build (ver ${PNG_VERSION})")
1279 endif()
1280
1281 if(WITH_TIFF OR HAVE_TIFF)
1282   status("    TIFF:" TIFF_FOUND THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION} / ${TIFF_VERSION_STRING})" ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
1283 endif()
1284
1285 if(WITH_JASPER OR HAVE_JASPER)
1286   status("    JPEG 2000:" JASPER_FOUND THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
1287 endif()
1288
1289 if(WITH_OPENEXR OR HAVE_OPENEXR)
1290   if(HAVE_OPENEXR)
1291     status("    OpenEXR:" OPENEXR_FOUND THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
1292   else()
1293     status("    OpenEXR:" "NO")
1294   endif()
1295 endif()
1296
1297 if(WITH_GDAL OR HAVE_GDAL)
1298   status("    GDAL:" HAVE_GDAL THEN "YES (${GDAL_LIBRARY})" ELSE "NO")
1299 endif()
1300
1301 if(WITH_GDCM OR HAVE_GDCM)
1302   status("    GDCM:" HAVE_GDCM THEN "YES (ver ${GDCM_VERSION})" ELSE "NO")
1303 endif()
1304
1305 if(WITH_IMGCODEC_HDR OR DEFINED HAVE_IMGCODEC_HDR)
1306   status("    HDR:" HAVE_IMGCODEC_HDR THEN "YES" ELSE "NO")
1307 endif()
1308
1309 if(WITH_IMGCODEC_SUNRASTER OR DEFINED HAVE_IMGCODEC_SUNRASTER)
1310   status("    SUNRASTER:" HAVE_IMGCODEC_SUNRASTER THEN "YES" ELSE "NO")
1311 endif()
1312
1313 if(WITH_IMGCODEC_PXM OR DEFINED HAVE_IMGCODEC_PXM)
1314   status("    PXM:" HAVE_IMGCODEC_PXM THEN "YES" ELSE "NO")
1315 endif()
1316
1317 # ========================== VIDEO IO ==========================
1318 status("")
1319 status("  Video I/O:")
1320
1321 if(WITH_VFW OR HAVE_VFW)
1322   status("    Video for Windows:" HAVE_VFW         THEN YES                                        ELSE NO)
1323 endif()
1324
1325 if(WITH_1394 OR HAVE_DC1394)
1326   if (HAVE_DC1394_2)
1327     status("    DC1394:" "YES (ver ${DC1394_2_VERSION})")
1328   elseif (HAVE_DC1394)
1329     status("    DC1394:" "YES (ver ${DC1394_VERSION})")
1330   else()
1331     status("    DC1394:" "NO")
1332   endif()
1333 endif()
1334
1335 if(WITH_FFMPEG OR HAVE_FFMPEG)
1336   if(OPENCV_FFMPEG_USE_FIND_PACKAGE)
1337     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (find_package)"                       ELSE "NO (find_package)")
1338   elseif(WIN32)
1339     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
1340   else()
1341     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
1342   endif()
1343   status("      avcodec:"      FFMPEG_libavcodec_FOUND    THEN "YES (ver ${FFMPEG_libavcodec_VERSION})"    ELSE NO)
1344   status("      avformat:"     FFMPEG_libavformat_FOUND   THEN "YES (ver ${FFMPEG_libavformat_VERSION})"   ELSE NO)
1345   status("      avutil:"       FFMPEG_libavutil_FOUND     THEN "YES (ver ${FFMPEG_libavutil_VERSION})"     ELSE NO)
1346   status("      swscale:"      FFMPEG_libswscale_FOUND    THEN "YES (ver ${FFMPEG_libswscale_VERSION})"    ELSE NO)
1347   status("      avresample:"   FFMPEG_libavresample_FOUND THEN "YES (ver ${FFMPEG_libavresample_VERSION})" ELSE NO)
1348 endif()
1349
1350 if(WITH_GSTREAMER OR HAVE_GSTREAMER)
1351   status("    GStreamer:"      HAVE_GSTREAMER      THEN "YES"                                      ELSE NO)
1352   if(HAVE_GSTREAMER)
1353     status("      base:"       "YES (ver ${GSTREAMER_BASE_VERSION})")
1354     status("      video:"      "YES (ver ${GSTREAMER_VIDEO_VERSION})")
1355     status("      app:"        "YES (ver ${GSTREAMER_APP_VERSION})")
1356     status("      riff:"       "YES (ver ${GSTREAMER_RIFF_VERSION})")
1357     status("      pbutils:"    "YES (ver ${GSTREAMER_PBUTILS_VERSION})")
1358   endif(HAVE_GSTREAMER)
1359 endif()
1360
1361 if(WITH_OPENNI OR HAVE_OPENNI)
1362   status("    OpenNI:"         HAVE_OPENNI         THEN "YES (ver ${OPENNI_VERSION_STRING}, build ${OPENNI_VERSION_BUILD})" ELSE NO)
1363   status("    OpenNI PrimeSensor Modules:" HAVE_OPENNI_PRIME_SENSOR_MODULE THEN "YES (${OPENNI_PRIME_SENSOR_MODULE})"      ELSE NO)
1364 endif()
1365
1366 if(WITH_OPENNI2 OR HAVE_OPENNI2)
1367   status("    OpenNI2:"        HAVE_OPENNI2    THEN "YES (ver ${OPENNI2_VERSION_STRING}, build ${OPENNI2_VERSION_BUILD})" ELSE NO)
1368 endif()
1369
1370 if(WITH_PVAPI OR HAVE_PVAPI)
1371   status("    PvAPI:"          HAVE_PVAPI          THEN YES                                        ELSE NO)
1372 endif()
1373
1374 if(WITH_GIGEAPI OR HAVE_GIGE_API)
1375   status("    GigEVisionSDK:"  HAVE_GIGE_API       THEN YES                                        ELSE NO)
1376 endif()
1377
1378 if(WITH_ARAVIS OR HAVE_ARAVIS_API)
1379   status("    Aravis SDK:"     HAVE_ARAVIS_API     THEN "YES (${ARAVIS_LIBRARIES})"                ELSE NO)
1380 endif()
1381
1382 if(APPLE)
1383   status("    AVFoundation:"   HAVE_AVFOUNDATION   THEN YES                                        ELSE NO)
1384   if(WITH_QUICKTIME OR HAVE_QUICKTIME)
1385     status("    QuickTime:"      HAVE_QUICKTIME      THEN YES                                        ELSE NO)
1386   endif()
1387   if(WITH_QTKIT OR HAVE_QTKIT)
1388     status("    QTKit:"          HAVE_QTKIT          THEN "YES (deprecated)"                         ELSE NO)
1389   endif()
1390 endif()
1391
1392 if(WITH_UNICAP OR HAVE_UNICAP)
1393   status("    UniCap:"         HAVE_UNICAP         THEN "YES (ver ${UNICAP_libunicap_VERSION})"   ELSE NO)
1394   status("    UniCap ucil:"    HAVE_UNICAP         THEN "YES (ver ${UNICAP_libucil_VERSION})"     ELSE NO)
1395 endif()
1396
1397 if(WITH_V4L OR WITH_LIBV4L OR HAVE_LIBV4L OR HAVE_CAMV4L OR HAVE_CAMV4L2 OR HAVE_VIDEOIO)
1398   status("    libv4l/libv4l2:" HAVE_LIBV4L THEN "${LIBV4L_libv4l1_VERSION} / ${LIBV4L_libv4l2_VERSION}" ELSE "NO")
1399   ocv_build_features_string(v4l_status
1400     IF HAVE_CAMV4L THEN "linux/videodev.h"
1401     IF HAVE_CAMV4L2 THEN "linux/videodev2.h"
1402     IF HAVE_VIDEOIO THEN "sys/videoio.h"
1403     ELSE "NO")
1404   status("    v4l/v4l2:" "${v4l_status}")
1405 endif()
1406
1407 if(WITH_DSHOW OR HAVE_DSHOW)
1408   status("    DirectShow:"     HAVE_DSHOW     THEN YES                                        ELSE NO)
1409 endif()
1410
1411 if(WITH_MSMF OR HAVE_MSMF)
1412   status("    Media Foundation:" HAVE_MSMF    THEN YES                                        ELSE NO)
1413   status("      DXVA:"           HAVE_MSMF_DXVA    THEN YES    ELSE NO)
1414 endif()
1415
1416 if(WITH_XIMEA OR HAVE_XIMEA)
1417   status("    XIMEA:"          HAVE_XIMEA          THEN YES                                        ELSE NO)
1418 endif()
1419
1420 if(WITH_XINE OR HAVE_XINE)
1421   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${XINE_VERSION})"     ELSE NO)
1422 endif()
1423
1424 if(WITH_INTELPERC OR HAVE_INTELPERC)
1425   status("    Intel PerC:"     HAVE_INTELPERC      THEN "YES"                                 ELSE NO)
1426 endif()
1427
1428 if(WITH_MFX OR HAVE_MFX)
1429   status("    Intel Media SDK:" HAVE_MFX      THEN "YES (${MFX_LIBRARY})" ELSE NO)
1430 endif()
1431
1432 if(WITH_GPHOTO2 OR HAVE_GPHOTO2)
1433   status("    gPhoto2:"        HAVE_GPHOTO2        THEN "YES"                                 ELSE NO)
1434 endif()
1435
1436 # Order is similar to CV_PARALLEL_FRAMEWORK in core/src/parallel.cpp
1437 ocv_build_features_string(parallel_status EXCLUSIVE
1438   IF HAVE_TBB THEN "TBB (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})"
1439   IF HAVE_CSTRIPES THEN "C="
1440   IF HAVE_OPENMP THEN "OpenMP"
1441   IF HAVE_GCD THEN "GCD"
1442   IF WINRT OR HAVE_CONCURRENCY THEN "Concurrency"
1443   IF HAVE_PTHREADS_PF THEN "pthreads"
1444   ELSE "none")
1445 status("")
1446 status("  Parallel framework:" "${parallel_status}")
1447
1448 if(CV_TRACE OR OPENCV_TRACE)
1449   ocv_build_features_string(trace_status EXCLUSIVE
1450     IF HAVE_ITT THEN "with Intel ITT"
1451     ELSE "built-in")
1452   status("")
1453   status("  Trace: " OPENCV_TRACE THEN "YES (${trace_status})" ELSE NO)
1454 endif()
1455
1456 # ========================== Other third-party libraries ==========================
1457 status("")
1458 status("  Other third-party libraries:")
1459
1460 if(WITH_IPP AND HAVE_IPP)
1461   status("    Intel IPP:" "${IPP_VERSION_STR} [${IPP_VERSION_MAJOR}.${IPP_VERSION_MINOR}.${IPP_VERSION_BUILD}]")
1462   status("           at:" "${IPP_ROOT_DIR}")
1463   if(NOT HAVE_IPP_ICV)
1464     status("       linked:" BUILD_WITH_DYNAMIC_IPP THEN "dynamic" ELSE "static")
1465   endif()
1466   if(HAVE_IPP_IW)
1467     if(BUILD_IPP_IW)
1468       status("    Intel IPP IW:" "sources (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1469     else()
1470       status("    Intel IPP IW:" "binaries (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1471     endif()
1472     status("              at:" "${IPP_IW_PATH}")
1473   else()
1474     status("    Intel IPP IW:"   NO)
1475   endif()
1476 endif()
1477
1478 if(WITH_VA OR HAVE_VA)
1479   status("    VA:"            HAVE_VA          THEN "YES" ELSE NO)
1480 endif()
1481
1482 if(WITH_VA_INTEL OR HAVE_VA_INTEL)
1483   status("    Intel VA-API/OpenCL:"  HAVE_VA_INTEL       THEN "YES (OpenCL: ${VA_INTEL_IOCL_ROOT})" ELSE NO)
1484 endif()
1485
1486 if(WITH_TENGINE OR HAVE_TENGINE)
1487   status("    Tengine:"      HAVE_TENGINE     THEN "YES (${TENGINE_LIBRARIES})" ELSE NO)
1488 endif()
1489
1490 if(WITH_LAPACK OR HAVE_LAPACK)
1491   status("    Lapack:"      HAVE_LAPACK     THEN "YES (${LAPACK_LIBRARIES})" ELSE NO)
1492 endif()
1493
1494 if(WITH_HALIDE OR HAVE_HALIDE)
1495   status("    Halide:"     HAVE_HALIDE      THEN "YES (${HALIDE_LIBRARIES} ${HALIDE_INCLUDE_DIRS})" ELSE NO)
1496 endif()
1497
1498 if(WITH_INF_ENGINE OR INF_ENGINE_TARGET)
1499   if(INF_ENGINE_TARGET)
1500     list(GET INF_ENGINE_TARGET 0 ie_target)
1501     set(__msg "YES (${INF_ENGINE_RELEASE} / ${INF_ENGINE_VERSION})")
1502     get_target_property(_lib ${ie_target} IMPORTED_LOCATION)
1503     get_target_property(_lib_imp_rel ${ie_target} IMPORTED_IMPLIB_RELEASE)
1504     get_target_property(_lib_imp_dbg ${ie_target} IMPORTED_IMPLIB_DEBUG)
1505     get_target_property(_lib_rel ${ie_target} IMPORTED_LOCATION_RELEASE)
1506     get_target_property(_lib_dbg ${ie_target} IMPORTED_LOCATION_DEBUG)
1507     ocv_build_features_string(_lib
1508       IF _lib THEN "${_lib}"
1509       IF _lib_imp_rel AND _lib_imp_dbg THEN "${_lib_imp_rel} / ${_lib_imp_dbg}"
1510       IF _lib_rel AND _lib_dbg THEN "${_lib_rel} / ${_lib_dbg}"
1511       IF _lib_rel  THEN "${_lib_rel}"
1512       IF _lib_dbg  THEN "${_lib_dbg}"
1513       ELSE "unknown"
1514     )
1515     get_target_property(_inc ${ie_target} INTERFACE_INCLUDE_DIRECTORIES)
1516     status("    Inference Engine:" "${__msg}")
1517     status("        * libs:" "${_lib}")
1518     status("        * includes:" "${_inc}")
1519   else()
1520     status("    Inference Engine:"     "NO")
1521   endif()
1522 endif()
1523 if(WITH_NGRAPH OR HAVE_NGRAPH)
1524   if(HAVE_NGRAPH)
1525     set(__target ngraph::ngraph)
1526     set(__msg "YES (${ngraph_VERSION})")
1527     get_target_property(_lib ${__target} IMPORTED_LOCATION)
1528     get_target_property(_lib_imp_rel ${__target} IMPORTED_IMPLIB_RELEASE)
1529     get_target_property(_lib_imp_dbg ${__target} IMPORTED_IMPLIB_DEBUG)
1530     get_target_property(_lib_rel ${__target} IMPORTED_LOCATION_RELEASE)
1531     get_target_property(_lib_dbg ${__target} IMPORTED_LOCATION_DEBUG)
1532     ocv_build_features_string(_lib
1533       IF _lib THEN "${_lib}"
1534       IF _lib_imp_rel AND _lib_imp_dbg THEN "${_lib_imp_rel} / ${_lib_imp_dbg}"
1535       IF _lib_rel AND _lib_dbg THEN "${_lib_rel} / ${_lib_dbg}"
1536       IF _lib_rel  THEN "${_lib_rel}"
1537       IF _lib_dbg  THEN "${_lib_dbg}"
1538       ELSE "unknown"
1539     )
1540     get_target_property(_inc ${__target} INTERFACE_INCLUDE_DIRECTORIES)
1541     status("    nGraph:" "${__msg}")
1542     status("        * libs:" "${_lib}")
1543     status("        * includes:" "${_inc}")
1544   else()
1545     status("    nGraph:"     "NO")
1546   endif()
1547 endif()
1548
1549 if(WITH_EIGEN OR HAVE_EIGEN)
1550   status("    Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
1551 endif()
1552
1553 if(WITH_OPENVX OR HAVE_OPENVX)
1554   status("    OpenVX:"     HAVE_OPENVX      THEN "YES (${OPENVX_LIBRARIES})" ELSE "NO")
1555 endif()
1556
1557 status("    Custom HAL:" OpenCV_USED_HAL  THEN "YES (${OpenCV_USED_HAL})" ELSE "NO")
1558
1559 foreach(s ${CUSTOM_STATUS})
1560   status(${CUSTOM_STATUS_${s}})
1561 endforeach()
1562
1563 if(WITH_CUDA OR HAVE_CUDA)
1564   ocv_build_features_string(cuda_features
1565     IF HAVE_CUFFT THEN "CUFFT"
1566     IF HAVE_CUBLAS THEN "CUBLAS"
1567     IF HAVE_NVCUVID THEN "NVCUVID"
1568     IF CUDA_FAST_MATH THEN "FAST_MATH"
1569     ELSE "no extra features")
1570   status("")
1571   status("  NVIDIA CUDA:" HAVE_CUDA THEN "YES (ver ${CUDA_VERSION_STRING}, ${cuda_features})" ELSE NO)
1572   if(HAVE_CUDA)
1573     status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
1574     status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
1575   endif()
1576 endif()
1577
1578 if(WITH_OPENCL OR HAVE_OPENCL)
1579   ocv_build_features_string(opencl_features
1580     IF HAVE_OPENCL_SVM THEN "SVM"
1581     IF HAVE_CLAMDFFT THEN "AMDFFT"
1582     IF HAVE_CLAMDBLAS THEN "AMDBLAS"
1583     IF HAVE_OPENCL_D3D11_NV THEN "NVD3D11"
1584     ELSE "no extra features")
1585   status("")
1586   status("  OpenCL:"     HAVE_OPENCL   THEN   "YES (${opencl_features})" ELSE "NO")
1587   if(HAVE_OPENCL)
1588     status("    Include path:"  OPENCL_INCLUDE_DIRS THEN "${OPENCL_INCLUDE_DIRS}" ELSE "NO")
1589     status("    Link libraries:"       OPENCL_LIBRARIES THEN "${OPENCL_LIBRARIES}" ELSE "Dynamic load")
1590   endif()
1591 endif()
1592
1593 # ========================== python ==========================
1594 if(BUILD_opencv_python2)
1595   status("")
1596   status("  Python 2:")
1597   status("    Interpreter:"     PYTHON2INTERP_FOUND  THEN "${PYTHON2_EXECUTABLE} (ver ${PYTHON2_VERSION_STRING})"       ELSE NO)
1598   if(PYTHON2LIBS_VERSION_STRING)
1599     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES} (ver ${PYTHON2LIBS_VERSION_STRING})"   ELSE NO)
1600   else()
1601     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES}"                                      ELSE NO)
1602   endif()
1603   status("    numpy:"         PYTHON2_NUMPY_INCLUDE_DIRS THEN "${PYTHON2_NUMPY_INCLUDE_DIRS} (ver ${PYTHON2_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
1604   status("    install path:"  HAVE_opencv_python2  THEN "${__INSTALL_PATH_PYTHON2}"                            ELSE "-")
1605 endif()
1606
1607 if(BUILD_opencv_python3)
1608   status("")
1609   status("  Python 3:")
1610   status("    Interpreter:"     PYTHON3INTERP_FOUND  THEN "${PYTHON3_EXECUTABLE} (ver ${PYTHON3_VERSION_STRING})"       ELSE NO)
1611   if(PYTHON3LIBS_VERSION_STRING)
1612     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES} (ver ${PYTHON3LIBS_VERSION_STRING})"   ELSE NO)
1613   else()
1614     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES}"                                      ELSE NO)
1615   endif()
1616   status("    numpy:"         PYTHON3_NUMPY_INCLUDE_DIRS THEN "${PYTHON3_NUMPY_INCLUDE_DIRS} (ver ${PYTHON3_NUMPY_VERSION})" ELSE "NO (Python3 wrappers can not be generated)")
1617   status("    install path:"  HAVE_opencv_python3  THEN "${__INSTALL_PATH_PYTHON3}"                            ELSE "-")
1618 endif()
1619
1620 status("")
1621 status("  Python (for build):"  PYTHON_DEFAULT_AVAILABLE THEN "${PYTHON_DEFAULT_EXECUTABLE}" ELSE NO)
1622 if(PYLINT_FOUND AND PYLINT_EXECUTABLE)
1623   status("    Pylint:"  PYLINT_FOUND THEN "${PYLINT_EXECUTABLE} (ver: ${PYLINT_VERSION}, checks: ${PYLINT_TOTAL_TARGETS})" ELSE NO)
1624 endif()
1625 if(FLAKE8_FOUND AND FLAKE8_EXECUTABLE)
1626   status("    Flake8:"  FLAKE8_FOUND THEN "${FLAKE8_EXECUTABLE} (ver: ${FLAKE8_VERSION})" ELSE NO)
1627 endif()
1628
1629 # ========================== java ==========================
1630 if(BUILD_JAVA)
1631   status("")
1632   status("  Java:"            BUILD_FAT_JAVA_LIB  THEN "export all functions"                                      ELSE "")
1633   status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
1634   if(NOT ANDROID)
1635     status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
1636   endif()
1637   status("    Java wrappers:" HAVE_opencv_java                                                            THEN YES ELSE NO)
1638   status("    Java tests:"    BUILD_TESTS AND opencv_test_java_BINARY_DIR                                 THEN YES ELSE NO)
1639 endif()
1640
1641 ocv_cmake_hook(STATUS_DUMP_EXTRA)
1642
1643 # ========================== auxiliary ==========================
1644 status("")
1645 status("  Install to:" "${CMAKE_INSTALL_PREFIX}")
1646 status("-----------------------------------------------------------------")
1647 status("")
1648
1649
1650 ocv_finalize_status()
1651
1652 if(ENABLE_CONFIG_VERIFICATION)
1653   ocv_verify_config()
1654 endif()
1655
1656 if(HAVE_CUDA AND COMMAND CUDA_BUILD_CLEAN_TARGET)
1657   CUDA_BUILD_CLEAN_TARGET()
1658 endif()
1659
1660 ocv_cmake_hook(POST_FINALIZE)
1661
1662 # ----------------------------------------------------------------------------
1663 # CPack stuff
1664 # ----------------------------------------------------------------------------
1665
1666 include(cmake/OpenCVPackaging.cmake)
1667
1668 # This should be the last command
1669 ocv_cmake_dump_vars("" TOFILE "CMakeVars.txt")
1670 ocv_cmake_eval(DEBUG_POST ONCE)