CMakeLists.txt

   1 # Copyright (C) 2018-2020 Intel Corporation
   2 # SPDX-License-Identifier: Apache-2.0
   3 #
   4
   5 cmake_policy(SET CMP0054 NEW)
   6
   7 # TODO: for make instal / package we need to use 3.13.3 version because
   8 # it allows to install targets created outside of current projects
   9 # See https://blog.kitware.com/cmake-3-13-0-available-for-download/
  10
  11 cmake_minimum_required(VERSION 3.13 FATAL_ERROR)
  12
  13 project(OpenVINO)
  14
  15 set(OpenVINO_MAIN_SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  16 set(IE_MAIN_SOURCE_DIR ${OpenVINO_MAIN_SOURCE_DIR}/inference-engine)
  17 list(APPEND CMAKE_MODULE_PATH "${OpenVINO_MAIN_SOURCE_DIR}/cmake")
  18
  19 include(CTest)
  20 include(features)
  21
  22 # include developer package
  23 include(developer_package)
  24
  25 # These options are shared with 3rdparty plugins by means of developer package
  26 include(check_features)
  27 include(dependencies)
  28
  29 # resolving dependencies for the project
  30 message (STATUS "PROJECT ............................... " ${PROJECT_NAME})
  31 message (STATUS "CMAKE_BINARY_DIR ...................... " ${CMAKE_BINARY_DIR})
  32 message (STATUS "OpenVINO_MAIN_SOURCE_DIR .............. " ${OpenVINO_MAIN_SOURCE_DIR})
  33 message (STATUS "IE_MAIN_SOURCE_DIR .................... " ${IE_MAIN_SOURCE_DIR})
  34 message (STATUS "CMAKE_GENERATOR ....................... " ${CMAKE_GENERATOR})
  35 message (STATUS "CMAKE_C_COMPILER_ID ................... " ${CMAKE_C_COMPILER_ID})
  36 message (STATUS "CMAKE_BUILD_TYPE ...................... " ${CMAKE_BUILD_TYPE})
  37
  38 # remove file with exported developer targets to force its regeneration
  39 file(REMOVE "${CMAKE_BINARY_DIR}/targets_developer.cmake")
  40 file(REMOVE "${CMAKE_BINARY_DIR}/targets.cmake")
  41
  42 #
  43 # Build
  44 #
  45
  46 function(build_ngraph)
  47     function(ngraph_set option value)
  48         if(NOT DEFINED ${option})
  49             set(${option} ${value} CACHE BOOL "" FORCE)
  50         endif()
  51     endfunction()
  52
  53     set(NGRAPH_BUILD_DIR ${CMAKE_LIBRARY_OUTPUT_DIRECTORY} CACHE STRING "" FORCE)
  54     set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${OpenVINO_MAIN_SOURCE_DIR}/ngraph/cmake/Modules/")
  55
  56     if (ENABLE_SANITIZER)
  57         ngraph_set(NGRAPH_ADDRESS_SANITIZER TRUE)
  58     else ()
  59         ngraph_set(NGRAPH_ADDRESS_SANITIZER FALSE)
  60     endif ()
  61     ngraph_set(NGRAPH_PYTHON_BUILD_ENABLE FALSE)
  62
  63     if(ENABLE_TESTS AND NOT ANDROID)
  64         ngraph_set(NGRAPH_UNIT_TEST_ENABLE TRUE)
  65     else()
  66         ngraph_set(NGRAPH_UNIT_TEST_ENABLE FALSE)
  67     endif()
  68
  69     if(NOT (ANDROID OR WINDOWS_STORE))
  70         ngraph_set(NGRAPH_ONNX_IMPORT_ENABLE TRUE)
  71     else()
  72         ngraph_set(NGRAPH_ONNX_IMPORT_ENABLE FALSE)
  73     endif()
  74     ngraph_set(NGRAPH_INTERPRETER_ENABLE TRUE)
  75
  76     if(CMAKE_CXX_COMPILER_ID MATCHES "^(Apple)?Clang$")
  77         ie_add_compiler_flags(-Wno-error=uninitialized -Wno-error=literal-conversion)
  78     elseif(UNIX)
  79         ie_add_compiler_flags(-Wno-error=maybe-uninitialized -Wno-error=return-type -fPIC)
  80     endif()
  81     if(ANDROID)
  82         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-error=defaulted-function-deleted -Wno-error=unused-command-line-argument")
  83     endif()
  84
  85     # WA for GCC 7.0
  86     if (UNIX)
  87         ie_add_compiler_flags(-Wno-error=return-type -Wno-undef)
  88     elseif(WIN32)
  89         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4308 /wd4146 /wd4703 /wd4244 /wd4819")
  90     endif()
  91
  92     if(ENABLE_LTO)
  93         set(CMAKE_INTERPROCEDURAL_OPTIMIZATION_RELEASE ON)
  94     endif()
  95
  96     ie_cpack_add_component(ngraph)
  97
  98     set(SDL_cmake_included ON)
  99     # set(NGRAPH_COMPONENT_PREFIX "deployment_tools/ngraph/")
 100     add_subdirectory(ngraph)
 101     set(NGRAPH_LIBRARIES ngraph PARENT_SCOPE)
 102 endfunction()
 103
 104 file(REMOVE "${CMAKE_BINARY_DIR}/openvino_targets_developer.cmake")
 105
 106 unset(OpenVINODeveloperPackageTargets CACHE)
 107
 108 function(openvino_developer_export_targets)
 109     set(OpenVINODeveloperPackageTargets "${OpenVINODeveloperPackageTargets};${ARGV}")
 110
 111     # to allow exporting of aliased targets with the original names
 112     foreach(target_name ${OpenVINODeveloperPackageTargets})
 113         if(TARGET "${target_name}")
 114             get_target_property(original_name ${target_name} ALIASED_TARGET)
 115             if(TARGET "${original_name}")
 116                 message(STATUS "The name ${target_name} is an ALIAS for ${original_name}. "
 117                         "It will be exported to the InferenceEngineDeveloperPackage with the original name.")
 118                 list(REMOVE_ITEM OpenVINODeveloperPackageTargets ${target_name})
 119                 list(APPEND OpenVINODeveloperPackageTargets ${original_name})
 120             endif()
 121         endif()
 122     endforeach()
 123
 124     list(REMOVE_DUPLICATES OpenVINODeveloperPackageTargets)
 125     set(OpenVINODeveloperPackageTargets "${OpenVINODeveloperPackageTargets}" CACHE INTERNAL
 126         "Paths to extra Inference Engine plugins" FORCE)
 127 endfunction()
 128
 129 add_subdirectory(openvino)
 130
 131 build_ngraph()
 132
 133 add_subdirectory(inference-engine)
 134
 135 add_subdirectory(docs)
 136
 137 #
 138 # Shellcheck
 139 #
 140
 141 ie_shellcheck_process(DIRECTORY "${OpenVINO_MAIN_SOURCE_DIR}"
 142                       SKIP "${OpenVINO_MAIN_SOURCE_DIR}/bin"
 143                            "${OpenVINO_MAIN_SOURCE_DIR}/build"
 144                            "${IE_MAIN_SOURCE_DIR}/tests/ie_test_utils/common_test_utils/gtest"
 145                            "${IE_MAIN_SOURCE_DIR}/samples/thirdparty"
 146                            "${IE_MAIN_SOURCE_DIR}/thirdparty"
 147                            "${IE_MAIN_SOURCE_DIR}/temp"
 148                            # TODO fix and enable back:
 149                            "${OpenVINO_MAIN_SOURCE_DIR}/scripts/install_dependencies"
 150                            "${OpenVINO_MAIN_SOURCE_DIR}/scripts/demo"
 151                            "${OpenVINO_MAIN_SOURCE_DIR}/ngraph"
 152                            "${IE_MAIN_SOURCE_DIR}/scripts")
 153
 154 #
 155 # cpack
 156 #
 157
 158 # install setupvars
 159
 160 ie_cpack_add_component(setupvars REQUIRED)
 161
 162 if(UNIX)
 163     install(PROGRAMS scripts/setupvars/setupvars.sh
 164             DESTINATION bin
 165             COMPONENT setupvars)
 166 elseif(WIN32)
 167     install(PROGRAMS scripts/setupvars/setupvars.bat
 168             DESTINATION bin
 169             COMPONENT setupvars)
 170 endif()
 171
 172 # install install_dependencies
 173
 174 if(UNIX)
 175     ie_cpack_add_component(install_dependencies REQUIRED)
 176     install(DIRECTORY scripts/install_dependencies/
 177             DESTINATION install_dependencies
 178             COMPONENT install_dependencies)
 179 endif()
 180
 181 # install files for demo
 182
 183 ie_cpack_add_component(demo_scripts REQUIRED DEPENDS core)
 184
 185 if(UNIX)
 186     install(DIRECTORY scripts/demo/
 187             DESTINATION deployment_tools/demo
 188             COMPONENT demo_scripts
 189             USE_SOURCE_PERMISSIONS
 190             PATTERN *.bat EXCLUDE)
 191 elseif(WIN32)
 192     install(DIRECTORY scripts/demo/
 193             DESTINATION deployment_tools/demo
 194             COMPONENT demo_scripts
 195             USE_SOURCE_PERMISSIONS
 196             PATTERN *.sh EXCLUDE)
 197 endif()
 198
 199 ie_cpack(${IE_CPACK_COMPONENTS_ALL})