CMakeLists.txt

   1 # The name of our project is "VULKAN". CMakeLists files in this project can
   2 # refer to the root source directory of the project as ${VULKAN_SOURCE_DIR} and
   3 # to the root binary directory of the project as ${VULKAN_BINARY_DIR}.
   4 cmake_minimum_required(VERSION 2.8.11)
   5 project (VULKAN)
   6 # set (CMAKE_VERBOSE_MAKEFILE 1)
   7
   8 # The API_NAME allows renaming builds to avoid conflicts with installed SDKs
   9 # The MAJOR number of the version we're building, used in naming
  10 # <api-name>-<major>.dll (and other files).
  11 set(API_NAME "Vulkan" CACHE STRING "API name to use when building")
  12 set(MAJOR "1")
  13 string(TOLOWER ${API_NAME} API_LOWERCASE)
  14
  15 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  16 find_package(PythonInterp 3 REQUIRED)
  17
  18 option(USE_CCACHE "Use ccache" OFF)
  19 if (USE_CCACHE)
  20     find_program(CCACHE_FOUND ccache)
  21     if(CCACHE_FOUND)
  22         set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
  23         set_property(GLOBAL PROPERTY RULE_LAUNCH_LINK ccache)
  24     endif(CCACHE_FOUND)
  25 endif()
  26
  27 if(APPLE)
  28     # CMake versions 3 or later need CMAKE_MACOSX_RPATH defined.
  29     # This avoids the CMP0042 policy message.
  30     set(CMAKE_MACOSX_RPATH 1)
  31     # The "install" target for MacOS fixes up bundles in place.
  32     set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR})
  33 endif()
  34
  35 # Enable cmake folders
  36 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  37 set(LVL_TARGET_FOLDER lvl_cmake_targets)
  38
  39 if(CMAKE_SYSTEM_NAME STREQUAL "Linux" OR CMAKE_SYSTEM_NAME STREQUAL "Darwin")
  40     set(FALLBACK_CONFIG_DIRS "/etc/xdg" CACHE STRING
  41         "Search path to use when XDG_CONFIG_DIRS is unset or empty or the current process is SUID/SGID. Default is freedesktop compliant.")
  42     set(FALLBACK_DATA_DIRS "/usr/local/share:/usr/share" CACHE STRING
  43         "Search path to use when XDG_DATA_DIRS is unset or empty or the current process is SUID/SGID. Default is freedesktop compliant.")
  44 endif()
  45
  46 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
  47     include(FindPkgConfig)
  48     option(BUILD_WSI_XCB_SUPPORT "Build XCB WSI support" ON)
  49     option(BUILD_WSI_XLIB_SUPPORT "Build Xlib WSI support" ON)
  50     option(BUILD_WSI_WAYLAND_SUPPORT "Build Wayland WSI support" ON)
  51     option(BUILD_WSI_MIR_SUPPORT "Build Mir WSI support" OFF)
  52     set(DEMOS_WSI_SELECTION "XCB" CACHE STRING "Select WSI target for demos (XCB, XLIB, WAYLAND, MIR, DISPLAY)")
  53
  54     if (BUILD_WSI_XCB_SUPPORT)
  55         find_package(XCB REQUIRED)
  56     endif()
  57
  58     if (BUILD_WSI_XLIB_SUPPORT)
  59         find_package(X11 REQUIRED)
  60     endif()
  61
  62     if (BUILD_WSI_WAYLAND_SUPPORT)
  63         find_package(Wayland REQUIRED)
  64         include_directories(${WAYLAND_CLIENT_INCLUDE_DIR})
  65     endif()
  66
  67     if (BUILD_WSI_MIR_SUPPORT)
  68         find_package(Mir REQUIRED)
  69     endif()
  70
  71     # This option can be used to suppress the installation of artifacts from the
  72     # Vulkan-LoaderAndValidationLayers repo while running "make install" for the
  73     # VulkanTools and VulkanSamples repos.  This can be used to prevent the
  74     # overwriting of LVL artifacts when installing these downstream repos.
  75     option(INSTALL_LVL_FILES "Install content from LoaderAndValidationLayers repo" ON)
  76 endif()
  77
  78 set(SCRIPTS_DIR "${CMAKE_CURRENT_SOURCE_DIR}/scripts")
  79
  80 # Header file for CMake settings
  81 include_directories("${PROJECT_SOURCE_DIR}/include")
  82
  83 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Clang")
  84     set(COMMON_COMPILE_FLAGS "-Wall -Wextra -Wno-unused-parameter -Wno-missing-field-initializers")
  85     set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -fno-strict-aliasing -fno-builtin-memcmp")
  86
  87     # For GCC version 7.1 or greater, we need to disable the implicit fallthrough warning since
  88     # there's no consistent way to satisfy all compilers until they all accept the C++17 standard
  89     if (CMAKE_COMPILER_IS_GNUCC AND NOT (CMAKE_CXX_COMPILER_VERSION LESS 7.1))
  90         set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -Wimplicit-fallthrough=0")
  91     endif()
  92
  93     if (APPLE)
  94         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${COMMON_COMPILE_FLAGS}")
  95     else()
  96         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=c99 ${COMMON_COMPILE_FLAGS}")
  97     endif()
  98     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${COMMON_COMPILE_FLAGS} -std=c++11 -fno-rtti")
  99     if (UNIX)
 100         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden")
 101         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")
 102     endif()
 103 endif()
 104
 105 if(WIN32)
 106     # Treat warnings as errors
 107     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/WX>")
 108     # Disable RTTI
 109     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/GR->")
 110     # Warn about nested declarations
 111     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34456>")
 112     # Warn about potentially uninitialized variables
 113     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34701>")
 114     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34703>")
 115     # Warn about different indirection types.
 116     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34057>")
 117     # Warn about signed/unsigned mismatch.
 118     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34245>")
 119 endif()
 120
 121 if(NOT WIN32)
 122     set (BUILDTGT_DIR build)
 123     set (BINDATA_DIR Bin)
 124     set (LIBSOURCE_DIR Lib)
 125 else()
 126     # is WIN32
 127     option(DISABLE_BUILD_PATH_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with MSVC build type info" OFF)
 128     option(DISABLE_BUILDTGT_DIR_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with target info" OFF)
 129     option(ENABLE_WIN10_ONECORE "Link the loader with OneCore umbrella libraries" OFF)
 130
 131     # For Windows, since 32-bit and 64-bit items can co-exist, we build each in its own build directory.
 132     # 32-bit target data goes in build32, and 64-bit target data goes into build.  So, include/link the
 133     # appropriate data at build time.
 134     if (DISABLE_BUILDTGT_DIR_DECORATION)
 135         set (BUILDTGT_DIR "")
 136         set (BINDATA_DIR "")
 137         set (LIBSOURCE_DIR "")
 138     elseif (CMAKE_CL_64)
 139         set (BUILDTGT_DIR build)
 140         set (BINDATA_DIR Bin)
 141         set (LIBSOURCE_DIR Lib)
 142     else()
 143         set (BUILDTGT_DIR build32)
 144         set (BINDATA_DIR Bin32)
 145         set (LIBSOURCE_DIR Lib32)
 146     endif()
 147 endif()
 148
 149 option(BUILD_LOADER "Build loader" ON)
 150 option(BUILD_TESTS "Build tests" ON)
 151 option(BUILD_LAYERS "Build layers" ON)
 152 option(BUILD_DEMOS "Build demos" ON)
 153 if (APPLE)
 154     option(BUILD_VKJSON "Build vkjson" OFF)
 155 else()
 156     option(BUILD_VKJSON "Build vkjson" ON)
 157 endif()
 158 option(BUILD_ICD "Build icd" ON)
 159 option(CUSTOM_GLSLANG_BIN_ROOT "Use the user defined GLSLANG_BINARY_ROOT" OFF)
 160 option(CUSTOM_SPIRV_TOOLS_BIN_ROOT "Use the user defined SPIRV_TOOLS*BINARY_ROOT paths" OFF)
 161
 162 #Choose natural default paths for glslang and SPIRV-Tools binaries to support custom definition by the user on the CMake command line or in the GUI
 163 set(GLSLANG_BINARY_ROOT "${CMAKE_BINARY_DIR}/../glslang" CACHE STRING "User defined path to the glslang binaries for this project")
 164 set(SPIRV_TOOLS_BINARY_ROOT "${CMAKE_BINARY_DIR}/../SPIRV-Tools" CACHE STRING "User defined path to the SPIRV-Tools binaries for this project")
 165 set(SPIRV_TOOLS_OPT_BINARY_ROOT "${CMAKE_BINARY_DIR}/../SPIRV-Tools/opt" CACHE STRING "User defined path to the SPIRV-Tools-opt binaries for this project")
 166
 167 # Define a variable for a default root location to the gslang, SPIRV-Tools and other external sources and cache it to allow the user to customize it as needed
 168 set(EXTERNAL_SOURCE_ROOT "${CMAKE_CURRENT_SOURCE_DIR}/external" CACHE STRING "Root path to external sources such as glslang and SPIRV-Tools")
 169
 170
 171 if (WIN32)
 172     if(CUSTOM_GLSLANG_BIN_ROOT)
 173         set(GSLANG_FINAL_BINARY_PATH ${GLSLANG_BINARY_ROOT}/${BUILDTGT_DIR})
 174     else()
 175         set(GSLANG_FINAL_BINARY_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}")
 176     endif()
 177
 178     if(DISABLE_BUILD_PATH_DECORATION)
 179         set (DEBUG_DECORATION "")
 180         set (RELEASE_DECORATION "")
 181     else()
 182         set (DEBUG_DECORATION "Debug")
 183         set (RELEASE_DECORATION "Release")
 184     endif()
 185
 186     # Take some steps to set up a variable pointing to the final glslang binaries given the variety of input options
 187     set (GLSLANG_SEARCH_PATH "${GSLANG_FINAL_BINARY_PATH}/glslang/${RELEASE_DECORATION}"
 188                              "${GSLANG_FINAL_BINARY_PATH}/glslang/OSDependent/Windows/${RELEASE_DECORATION}"
 189                              "${GSLANG_FINAL_BINARY_PATH}/hlsl/${RELEASE_DECORATION}"
 190                              "${GSLANG_FINAL_BINARY_PATH}/OGLCompilersDLL/${RELEASE_DECORATION}"
 191                              "${GSLANG_FINAL_BINARY_PATH}/SPIRV/${RELEASE_DECORATION}" )
 192
 193     set (GLSLANG_DEBUG_SEARCH_PATH "${GSLANG_FINAL_BINARY_PATH}/glslang/${DEBUG_DECORATION}"
 194                                    "${GSLANG_FINAL_BINARY_PATH}/glslang/OSDependent/Windows/${DEBUG_DECORATION}"
 195                                    "${GSLANG_FINAL_BINARY_PATH}/hlsl/${DEBUG_DECORATION}"
 196                                    "${GSLANG_FINAL_BINARY_PATH}/OGLCompilersDLL/${DEBUG_DECORATION}"
 197                                    "${GSLANG_FINAL_BINARY_PATH}/SPIRV/${DEBUG_DECORATION}")
 198
 199     if(CUSTOM_SPIRV_TOOLS_BIN_ROOT)
 200         set (SPIRV_TOOLS_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/${BUILDTGT_DIR}/source/${RELEASE_DECORATION}")
 201         set (SPIRV_TOOLS_DEBUG_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/${BUILDTGT_DIR}/source/${DEBUG_DECORATION}")
 202         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${SPIRV_TOOLS_OPT_BINARY_ROOT}/${BUILDTGT_DIR}/source/opt/${RELEASE_DECORATION}")
 203         set (SPIRV_TOOLS_OPT_DEBUG_SEARCH_PATH "${SPIRV_TOOLS_OPT_BINARY_ROOT}/${BUILDTGT_DIR}/source/opt/${DEBUG_DECORATION}")
 204     else()
 205         set (SPIRV_TOOLS_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source/${RELEASE_DECORATION}")
 206         set (SPIRV_TOOLS_DEBUG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source/${DEBUG_DECORATION}")
 207         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source/opt/${RELEASE_DECORATION}")
 208         set (SPIRV_TOOLS_OPT_DEBUG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source/opt/${DEBUG_DECORATION}")
 209     endif()
 210 else()
 211     # not WIN32
 212     if(CUSTOM_GLSLANG_BIN_ROOT)
 213         set (GLSLANG_SEARCH_PATH "${GLSLANG_BINARY_ROOT}/install/lib"
 214                                  "${GLSLANG_BINARY_ROOT}/glslang"
 215                                  "${GLSLANG_BINARY_ROOT}/glslang/OSDependent/Unix"
 216                                  "${GLSLANG_BINARY_ROOT}/OGLCompilersDLL"
 217                                  "${GLSLANG_BINARY_ROOT}/SPIRV"
 218                                  "${GLSLANG_BINARY_ROOT}/hlsl"
 219                                  "${GLSLANG_BINARY_ROOT}/StandAlone")
 220     else()
 221         set (GLSLANG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/install/lib" "${CMAKE_SOURCE_DIR}/../x86_64/lib/glslang" )
 222     endif()
 223
 224     if(CUSTOM_SPIRV_TOOLS_BIN_ROOT)
 225         set (SPIRV_TOOLS_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/source" )
 226         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${SPIRV_TOOLS_OPT_BINARY_ROOT}/source/opt" )
 227     else()
 228         set (SPIRV_TOOLS_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source" "${CMAKE_SOURCE_DIR}/../x86_64/lib/spirv-tools" )
 229         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source/opt" "${CMAKE_SOURCE_DIR}/../x86_64/lib/spirv-tools" )
 230     endif()
 231 endif()
 232
 233 find_program(GLSLANG_VALIDATOR NAMES glslangValidator
 234              HINTS "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/install/bin"
 235                    "${GLSLANG_BINARY_ROOT}/StandAlone"
 236                    "${PROJECT_SOURCE_DIR}/external/${BINDATA_DIR}")
 237
 238 find_path(GLSLANG_SPIRV_INCLUDE_DIR SPIRV/spirv.hpp HINTS "${EXTERNAL_SOURCE_ROOT}/glslang"
 239                                                     "${CMAKE_SOURCE_DIR}/../glslang"
 240                                               DOC "Path to SPIRV/spirv.hpp")
 241
 242 find_path(SPIRV_TOOLS_INCLUDE_DIR spirv-tools/libspirv.h HINTS "${EXTERNAL_SOURCE_ROOT}/glslang/External/spirv-tools/include"
 243                                                    "${CMAKE_SOURCE_DIR}/../glslang/External/spirv-tools/include"
 244                                              DOC "Path to spirv-tools/libspirv.h")
 245
 246 find_library(GLSLANG_LIB NAMES glslang
 247              HINTS ${GLSLANG_SEARCH_PATH} )
 248
 249 find_library(OGLCompiler_LIB NAMES OGLCompiler
 250              HINTS ${GLSLANG_SEARCH_PATH} )
 251
 252 find_library(OSDependent_LIB NAMES OSDependent
 253              HINTS ${GLSLANG_SEARCH_PATH} )
 254
 255 find_library(HLSL_LIB NAMES HLSL
 256              HINTS ${GLSLANG_SEARCH_PATH} )
 257
 258 find_library(SPIRV_LIB NAMES SPIRV
 259              HINTS ${GLSLANG_SEARCH_PATH} )
 260
 261 find_library(SPIRV_REMAPPER_LIB NAMES SPVRemapper
 262              HINTS ${GLSLANG_SEARCH_PATH} )
 263
 264 find_library(SPIRV_TOOLS_LIB NAMES SPIRV-Tools
 265              HINTS ${SPIRV_TOOLS_SEARCH_PATH} )
 266
 267 find_library(SPIRV_TOOLS_OPT_LIB NAMES SPIRV-Tools-opt
 268              HINTS ${SPIRV_TOOLS_OPT_SEARCH_PATH} )
 269
 270 if (WIN32)
 271     add_library(glslang         STATIC IMPORTED)
 272     add_library(OGLCompiler     STATIC IMPORTED)
 273     add_library(OSDependent     STATIC IMPORTED)
 274     add_library(HLSL            STATIC IMPORTED)
 275     add_library(SPIRV           STATIC IMPORTED)
 276     add_library(SPVRemapper     STATIC IMPORTED)
 277     add_library(Loader          STATIC IMPORTED)
 278     add_library(SPIRV-Tools-opt STATIC IMPORTED)
 279     add_library(SPIRV-Tools     STATIC IMPORTED)
 280
 281     find_library(GLSLANG_DLIB NAMES glslangd
 282                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 283     find_library(OGLCompiler_DLIB NAMES OGLCompilerd
 284                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 285     find_library(OSDependent_DLIB NAMES OSDependentd
 286                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 287     find_library(HLSL_DLIB NAMES HLSLd
 288                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 289     find_library(SPIRV_DLIB NAMES SPIRVd
 290                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 291     find_library(SPIRV_REMAPPER_DLIB NAMES SPVRemapperd
 292                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 293     find_library(SPIRV_TOOLS_DLIB NAMES SPIRV-Toolsd
 294                  HINTS ${SPIRV_TOOLS_DEBUG_SEARCH_PATH} )
 295     find_library(SPIRV_TOOLS_OPT_DLIB NAMES SPIRV-Tools-optd
 296                  HINTS ${SPIRV_TOOLS_OPT_DEBUG_SEARCH_PATH} )
 297
 298     set_target_properties(glslang PROPERTIES
 299                          IMPORTED_LOCATION       "${GLSLANG_LIB}"
 300                          IMPORTED_LOCATION_DEBUG "${GLSLANG_DLIB}")
 301     set_target_properties(OGLCompiler PROPERTIES
 302                          IMPORTED_LOCATION       "${OGLCompiler_LIB}"
 303                          IMPORTED_LOCATION_DEBUG "${OGLCompiler_DLIB}")
 304     set_target_properties(OSDependent PROPERTIES
 305                          IMPORTED_LOCATION       "${OSDependent_LIB}"
 306                          IMPORTED_LOCATION_DEBUG "${OSDependent_DLIB}")
 307     set_target_properties(HLSL PROPERTIES
 308                          IMPORTED_LOCATION       "${HLSL_LIB}"
 309                          IMPORTED_LOCATION_DEBUG "${HLSL_DLIB}")
 310     set_target_properties(SPIRV PROPERTIES
 311                          IMPORTED_LOCATION       "${SPIRV_LIB}"
 312                          IMPORTED_LOCATION_DEBUG "${SPIRV_DLIB}")
 313     set_target_properties(SPVRemapper PROPERTIES
 314                          IMPORTED_LOCATION       "${SPIRV_REMAPPER_LIB}"
 315                          IMPORTED_LOCATION_DEBUG "${SPIRV_REMAPPER_DLIB}")
 316     set_target_properties(SPIRV-Tools PROPERTIES
 317                          IMPORTED_LOCATION       "${SPIRV_TOOLS_LIB}"
 318                          IMPORTED_LOCATION_DEBUG "${SPIRV_TOOLS_DLIB}")
 319     set_target_properties(SPIRV-Tools-opt PROPERTIES
 320                          IMPORTED_LOCATION       "${SPIRV_TOOLS_OPT_LIB}"
 321                          IMPORTED_LOCATION_DEBUG "${SPIRV_TOOLS_OPT_DLIB}")
 322
 323     set (SPIRV_TOOLS_LIBRARIES SPIRV-Tools-opt SPIRV-Tools)
 324     set (GLSLANG_LIBRARIES glslang OGLCompiler OSDependent HLSL SPIRV SPVRemapper ${SPIRV_TOOLS_LIBRARIES})
 325 else ()
 326     # not WIN32
 327     set (SPIRV_TOOLS_LIBRARIES ${SPIRV_TOOLS_OPT_LIB} ${SPIRV_TOOLS_LIB})
 328     set (GLSLANG_LIBRARIES ${GLSLANG_LIB} ${OGLCompiler_LIB} ${OSDependent_LIB} ${HLSL_LIB} ${SPIRV_LIB} ${SPIRV_REMAPPER_LIB} ${SPIRV_TOOLS_LIBRARIES})
 329 endif()
 330
 331 set (PYTHON_CMD ${PYTHON_EXECUTABLE})
 332
 333 # Define macro used for building vkxml generated files
 334 macro(run_vk_xml_generate dependency output)
 335     add_custom_command(OUTPUT ${output}
 336     COMMAND ${PYTHON_CMD} ${SCRIPTS_DIR}/lvl_genvk.py -registry ${SCRIPTS_DIR}/vk.xml ${output}
 337     DEPENDS ${SCRIPTS_DIR}/vk.xml ${SCRIPTS_DIR}/generator.py ${SCRIPTS_DIR}/${dependency} ${SCRIPTS_DIR}/lvl_genvk.py ${SCRIPTS_DIR}/reg.py
 338     )
 339 endmacro()
 340
 341 # Define macro used for generating header files containing commit IDs for external dependencies
 342 macro(run_external_revision_generate source_dir symbol_name output)
 343     add_custom_command(OUTPUT ${output}
 344     # NOTE: If you modify this call to use --rev_file instead of --git_dir (to read the commit ID from a file instead of
 345     # parsing from a Git repository), you probably also want to add the revision file to the list of DEPENDS on the
 346     # subsequent line (to ensure that the script is re-run when the revision file is modified).
 347     COMMAND ${PYTHON_CMD} ${SCRIPTS_DIR}/external_revision_generator.py --git_dir ${source_dir} -s ${symbol_name} -o ${output}
 348     DEPENDS ${SCRIPTS_DIR}/external_revision_generator.py ${source_dir}/.git/HEAD ${source_dir}/.git/index
 349     )
 350 endmacro()
 351
 352 # Custom target for generated vulkan helper file dependencies
 353 set(generate_helper_files_DEPENDS)
 354 if(BUILD_LAYERS)
 355     LIST(APPEND generate_helper_files_DEPENDS spirv_tools_commit_id.h)
 356 endif()
 357 add_custom_target(generate_helper_files DEPENDS
 358     vk_enum_string_helper.h
 359     vk_safe_struct.h
 360     vk_safe_struct.cpp
 361     vk_object_types.h
 362     vk_layer_dispatch_table.h
 363     vk_dispatch_table_helper.h
 364     vk_extension_helper.h
 365     vk_typemap_helper.h
 366     ${generate_helper_files_DEPENDS}
 367     )
 368 set_target_properties(generate_helper_files PROPERTIES FOLDER ${LVL_TARGET_FOLDER})
 369
 370 # Rules to build generated helper files
 371 run_vk_xml_generate(loader_extension_generator.py vk_layer_dispatch_table.h)
 372 run_vk_xml_generate(dispatch_table_helper_generator.py vk_dispatch_table_helper.h)
 373 run_vk_xml_generate(helper_file_generator.py vk_safe_struct.h)
 374 run_vk_xml_generate(helper_file_generator.py vk_safe_struct.cpp)
 375 run_vk_xml_generate(helper_file_generator.py vk_enum_string_helper.h)
 376 run_vk_xml_generate(helper_file_generator.py vk_object_types.h)
 377 run_vk_xml_generate(helper_file_generator.py vk_extension_helper.h)
 378 run_vk_xml_generate(helper_file_generator.py vk_typemap_helper.h)
 379 if(BUILD_LAYERS)
 380     run_external_revision_generate(${EXTERNAL_SOURCE_ROOT}/glslang/External/spirv-tools SPIRV_TOOLS_COMMIT_ID spirv_tools_commit_id.h)
 381 endif()
 382
 383
 384
 385 if(NOT WIN32)
 386     include(GNUInstallDirs)
 387
 388     add_definitions(-DFALLBACK_CONFIG_DIRS="${FALLBACK_CONFIG_DIRS}")
 389     add_definitions(-DFALLBACK_DATA_DIRS="${FALLBACK_DATA_DIRS}")
 390     add_definitions(-DSYSCONFDIR="${CMAKE_INSTALL_FULL_SYSCONFDIR}")
 391
 392     # Make sure /etc is searched by the loader
 393     if(NOT (CMAKE_INSTALL_FULL_SYSCONFDIR STREQUAL "/etc"))
 394         add_definitions(-DEXTRASYSCONFDIR="/etc")
 395     endif()
 396 endif()
 397
 398 if(UNIX)
 399     if(INSTALL_LVL_FILES)
 400         install(DIRECTORY "${PROJECT_SOURCE_DIR}/include/vulkan" DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 401         install(FILES "${CMAKE_CURRENT_BINARY_DIR}/vk_layer_dispatch_table.h" DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/vulkan")
 402     endif()
 403
 404 # uninstall target
 405 configure_file(
 406     "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 407     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 408     IMMEDIATE @ONLY)
 409
 410 add_custom_target(uninstall
 411     COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)
 412 endif()
 413
 414 # Layer Utils Library
 415 # For Windows, we use a static lib because the Windows loader has a fairly restrictive loader search
 416 # path that can't be easily modified to point it to the same directory that contains the layers.
 417 set(VKLAYER_UTILS_VLF_SOURCES
 418     layers/vk_layer_config.cpp
 419     layers/vk_layer_extension_utils.cpp
 420     layers/vk_layer_utils.cpp
 421     layers/vk_format_utils.cpp
 422     )
 423 if (WIN32)
 424     add_library(VkLayer_utils STATIC ${VKLAYER_UTILS_VLF_SOURCES})
 425     target_compile_definitions(VkLayer_utils PUBLIC _CRT_SECURE_NO_WARNINGS)
 426 else()
 427     add_library(VkLayer_utils SHARED ${VKLAYER_UTILS_VLF_SOURCES})
 428     if(INSTALL_LVL_FILES)
 429         install(TARGETS VkLayer_utils DESTINATION ${CMAKE_INSTALL_LIBDIR})
 430     endif()
 431 endif()
 432 add_dependencies(VkLayer_utils generate_helper_files)
 433 target_include_directories(
 434     VkLayer_utils PUBLIC
 435     ${CMAKE_CURRENT_SOURCE_DIR}/loader
 436     ${CMAKE_CURRENT_SOURCE_DIR}/include/vulkan
 437     ${CMAKE_CURRENT_BINARY_DIR}
 438     )
 439
 440 add_definitions(-DAPI_NAME="${API_NAME}")
 441
 442 # loader: Generic VULKAN ICD loader
 443 # tests: VULKAN tests
 444 if(BUILD_LOADER)
 445     add_subdirectory(loader)
 446 endif()
 447
 448 if(BUILD_TESTS)
 449     add_subdirectory(tests)
 450 endif()
 451
 452 if(BUILD_LAYERS)
 453     add_subdirectory(layers)
 454 endif()
 455
 456 if(BUILD_DEMOS)
 457     add_subdirectory(demos)
 458 endif()
 459
 460 if(BUILD_VKJSON)
 461     add_subdirectory(libs/vkjson)
 462 endif()
 463
 464 if(BUILD_ICD)
 465     add_subdirectory(icd)
 466 endif()