CMakeLists.txt

   1 ##
   2 ## Author: Hank Anderson <hank@statease.com>
   3 ##
   4
   5 cmake_minimum_required(VERSION 2.8.5)
   6 project(OpenBLAS C ASM)
   7 set(OpenBLAS_MAJOR_VERSION 0)
   8 set(OpenBLAS_MINOR_VERSION 3)
   9 set(OpenBLAS_PATCH_VERSION 13.dev)
  10 set(OpenBLAS_VERSION "${OpenBLAS_MAJOR_VERSION}.${OpenBLAS_MINOR_VERSION}.${OpenBLAS_PATCH_VERSION}")
  11
  12 # Adhere to GNU filesystem layout conventions
  13 include(GNUInstallDirs)
  14
  15 include(CMakePackageConfigHelpers)
  16
  17
  18 #######
  19 if(MSVC)
  20 option(BUILD_WITHOUT_LAPACK "Do not build LAPACK and LAPACKE (Only BLAS or CBLAS)" ON)
  21 endif()
  22 option(BUILD_WITHOUT_CBLAS "Do not build the C interface (CBLAS) to the BLAS functions" OFF)
  23 option(DYNAMIC_ARCH "Include support for multiple CPU targets, with automatic selection at runtime (x86/x86_64, aarch64 or ppc only)" OFF)
  24 option(DYNAMIC_OLDER "Include specific support for older x86 cpu models (Penryn,Dunnington,Atom,Nano,Opteron) with DYNAMIC_ARCH" OFF)
  25 option(BUILD_RELAPACK "Build with ReLAPACK (recursive implementation of several LAPACK functions on top of standard LAPACK)" OFF)
  26 option(USE_LOCKING "Use locks even in single-threaded builds to make them callable from multiple threads" OFF)
  27 if(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
  28 option(NO_AFFINITY "Disable support for CPU affinity masks to avoid binding processes from e.g. R or numpy/scipy to a single core" ON)
  29 else()
  30 set(NO_AFFINITY 1)
  31 endif()
  32 option(CPP_THREAD_SAFETY_TEST "Run a massively parallel DGEMM test to confirm thread safety of the library (requires OpenMP and about 1.3GB of RAM)" OFF)
  33 option(CPP_THREAD_SAFETY_GEMV "Run a massively parallel DGEMV test to confirm thread safety of the library (requires OpenMP)" OFF)
  34
  35 # Add a prefix or suffix to all exported symbol names in the shared library.
  36 # Avoids conflicts with other BLAS libraries, especially when using
  37 # 64 bit integer interfaces in OpenBLAS.
  38
  39 set(SYMBOLPREFIX "" CACHE STRING  "Add a prefix to all exported symbol names in the shared library to avoid conflicts with other BLAS libraries" )
  40 set(SYMBOLSUFFIX "" CACHE STRING  "Add a suffix to all exported symbol names in the shared library, e.g. _64 for INTERFACE64 builds" )
  41 #######
  42 if(BUILD_WITHOUT_LAPACK)
  43 set(NO_LAPACK 1)
  44 set(NO_LAPACKE 1)
  45 endif()
  46
  47 if(BUILD_WITHOUT_CBLAS)
  48 set(NO_CBLAS 1)
  49 endif()
  50
  51 #######
  52
  53 if(MSVC AND MSVC_STATIC_CRT)
  54     set(CompilerFlags
  55             CMAKE_CXX_FLAGS
  56             CMAKE_CXX_FLAGS_DEBUG
  57             CMAKE_CXX_FLAGS_RELEASE
  58             CMAKE_C_FLAGS
  59             CMAKE_C_FLAGS_DEBUG
  60             CMAKE_C_FLAGS_RELEASE
  61             )
  62     foreach(CompilerFlag ${CompilerFlags})
  63       string(REPLACE "/MD" "/MT" ${CompilerFlag} "${${CompilerFlag}}")
  64     endforeach()
  65 endif()
  66
  67 message(WARNING "CMake support is experimental. It does not yet support all build options and may not produce the same Makefiles that OpenBLAS ships with.")
  68
  69 include("${PROJECT_SOURCE_DIR}/cmake/utils.cmake")
  70 include("${PROJECT_SOURCE_DIR}/cmake/system.cmake")
  71
  72 set(OpenBLAS_LIBNAME openblas${SUFFIX64_UNDERSCORE})
  73
  74 set(BLASDIRS interface driver/level2 driver/level3 driver/others)
  75
  76 if (NOT DYNAMIC_ARCH)
  77   list(APPEND BLASDIRS kernel)
  78 endif ()
  79
  80 if (DEFINED SANITY_CHECK)
  81   list(APPEND BLASDIRS reference)
  82 endif ()
  83
  84 set(SUBDIRS     ${BLASDIRS})
  85 if (NOT NO_LAPACK)
  86   if(BUILD_RELAPACK)
  87     list(APPEND SUBDIRS relapack/src)
  88   endif()
  89   list(APPEND SUBDIRS lapack)
  90 endif ()
  91
  92 if (NOT DEFINED BUILD_BFLOAT16)
  93  set (BUILD_BFLOAT16 false)
  94 endif ()
  95 # set which float types we want to build for
  96 if (NOT DEFINED BUILD_SINGLE AND NOT DEFINED BUILD_DOUBLE AND NOT DEFINED BUILD_COMPLEX AND NOT DEFINED BUILD_COMPLEX16)
  97   # if none are defined, build for all
  98 #  set(BUILD_BFLOAT16 true)
  99   set(BUILD_SINGLE true)
 100   set(BUILD_DOUBLE true)
 101   set(BUILD_COMPLEX true)
 102   set(BUILD_COMPLEX16 true)
 103 endif ()
 104
 105 if (NOT DEFINED BUILD_MATGEN)
 106   set(BUILD_MATGEN true)
 107 endif()
 108
 109 set(FLOAT_TYPES "")
 110 if (BUILD_SINGLE)
 111   message(STATUS "Building Single Precision")
 112   list(APPEND FLOAT_TYPES "SINGLE") # defines nothing
 113 endif ()
 114
 115 if (BUILD_DOUBLE)
 116   message(STATUS "Building Double Precision")
 117   list(APPEND FLOAT_TYPES "DOUBLE") # defines DOUBLE
 118 endif ()
 119
 120 if (BUILD_COMPLEX)
 121   message(STATUS "Building Complex Precision")
 122   list(APPEND FLOAT_TYPES "COMPLEX") # defines COMPLEX
 123 endif ()
 124
 125 if (BUILD_COMPLEX16)
 126   message(STATUS "Building Double Complex Precision")
 127   list(APPEND FLOAT_TYPES "ZCOMPLEX") # defines COMPLEX and DOUBLE
 128 endif ()
 129
 130 if (BUILD_BFLOAT16)
 131   message(STATUS "Building Half Precision")
 132   list(APPEND FLOAT_TYPES "BFLOAT16") # defines nothing
 133 endif ()
 134
 135 if (NOT DEFINED CORE OR "${CORE}" STREQUAL "UNKNOWN")
 136   message(FATAL_ERROR "Detecting CPU failed. Please set TARGET explicitly, e.g. make TARGET=your_cpu_target. Please read README for details.")
 137 endif ()
 138
 139 #Set default output directory
 140 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
 141 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
 142 if(MSVC)
 143 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG ${PROJECT_BINARY_DIR}/lib/Debug)
 144 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELEASE ${PROJECT_BINARY_DIR}/lib/Release)
 145 endif ()
 146 # get obj vars into format that add_library likes: $<TARGET_OBJS:objlib> (see http://www.cmake.org/cmake/help/v3.0/command/add_library.html)
 147 set(TARGET_OBJS "")
 148 foreach (SUBDIR ${SUBDIRS})
 149   add_subdirectory(${SUBDIR})
 150   string(REPLACE "/" "_" subdir_obj ${SUBDIR})
 151   list(APPEND TARGET_OBJS "$<TARGET_OBJECTS:${subdir_obj}>")
 152 endforeach ()
 153
 154 # netlib:
 155
 156 # Can't just use lapack-netlib's CMake files, since they are set up to search for BLAS, build and install a binary. We just want to build a couple of lib files out of lapack and lapacke.
 157 # Not using add_subdirectory here because lapack-netlib already has its own CMakeLists.txt. Instead include a cmake script with the sources we want.
 158 if (NOT NOFORTRAN AND NOT NO_LAPACK)
 159   include("${PROJECT_SOURCE_DIR}/cmake/lapack.cmake")
 160   if (NOT NO_LAPACKE)
 161     include("${PROJECT_SOURCE_DIR}/cmake/lapacke.cmake")
 162   endif ()
 163 endif ()
 164
 165 # Only generate .def for dll on MSVC and always produce pdb files for debug and release
 166 if(MSVC)
 167   if (${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} VERSION_LESS 3.4)
 168     set(OpenBLAS_DEF_FILE "${PROJECT_BINARY_DIR}/openblas.def")
 169   endif()
 170   set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} /Zi")
 171   set(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE} /DEBUG /OPT:REF /OPT:ICF")
 172 endif()
 173
 174 if (${DYNAMIC_ARCH})
 175   add_subdirectory(kernel)
 176   foreach(TARGET_CORE ${DYNAMIC_CORE})
 177     message("${TARGET_CORE}")
 178     list(APPEND TARGET_OBJS "$<TARGET_OBJECTS:kernel_${TARGET_CORE}>")
 179   endforeach()
 180 endif ()
 181
 182 # add objects to the openblas lib
 183 add_library(${OpenBLAS_LIBNAME} ${LA_SOURCES} ${LAPACKE_SOURCES} ${RELA_SOURCES} ${TARGET_OBJS} ${OpenBLAS_DEF_FILE})
 184 target_include_directories(${OpenBLAS_LIBNAME} INTERFACE $<INSTALL_INTERFACE:include/openblas${SUFFIX64}>)
 185
 186 # Android needs to explicitly link against libm
 187 if(ANDROID)
 188   target_link_libraries(${OpenBLAS_LIBNAME} m)
 189 endif()
 190
 191 # Handle MSVC exports
 192 if(MSVC AND BUILD_SHARED_LIBS)
 193   if (${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} VERSION_LESS 3.4)
 194     include("${PROJECT_SOURCE_DIR}/cmake/export.cmake")
 195   else()
 196     # Creates verbose .def file (51KB vs 18KB)
 197     set_target_properties(${OpenBLAS_LIBNAME} PROPERTIES WINDOWS_EXPORT_ALL_SYMBOLS true)
 198   endif()
 199 endif()
 200
 201 # Set output for libopenblas
 202 set_target_properties( ${OpenBLAS_LIBNAME} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
 203 set_target_properties( ${OpenBLAS_LIBNAME} PROPERTIES LIBRARY_OUTPUT_NAME_DEBUG "${OpenBLAS_LIBNAME}_d")
 204 set_target_properties( ${OpenBLAS_LIBNAME} PROPERTIES EXPORT_NAME "OpenBLAS")
 205
 206 foreach (OUTPUTCONFIG ${CMAKE_CONFIGURATION_TYPES})
 207   string( TOUPPER ${OUTPUTCONFIG} OUTPUTCONFIG )
 208
 209   set_target_properties( ${OpenBLAS_LIBNAME} PROPERTIES RUNTIME_OUTPUT_DIRECTORY_${OUTPUTCONFIG} ${PROJECT_BINARY_DIR}/lib/${OUTPUTCONFIG} )
 210   set_target_properties( ${OpenBLAS_LIBNAME} PROPERTIES LIBRARY_OUTPUT_DIRECTORY_${OUTPUTCONFIG} ${PROJECT_BINARY_DIR}/lib/${OUTPUTCONFIG} )
 211   set_target_properties( ${OpenBLAS_LIBNAME} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY_${OUTPUTCONFIG} ${PROJECT_BINARY_DIR}/lib/${OUTPUTCONFIG} )
 212 endforeach()
 213
 214 enable_testing()
 215
 216 if (USE_THREAD)
 217   # Add threading library to linker
 218   find_package(Threads)
 219   if (THREADS_HAVE_PTHREAD_ARG)
 220     set_property(TARGET ${OpenBLAS_LIBNAME} PROPERTY COMPILE_OPTIONS "-pthread")
 221     set_property(TARGET ${OpenBLAS_LIBNAME} PROPERTY INTERFACE_COMPILE_OPTIONS "-pthread")
 222   endif()
 223   target_link_libraries(${OpenBLAS_LIBNAME} ${CMAKE_THREAD_LIBS_INIT})
 224 endif()
 225
 226 #if (MSVC OR NOT NOFORTRAN)
 227 if (NOT NO_CBLAS)
 228   # Broken without fortran on unix
 229   add_subdirectory(utest)
 230 endif()
 231
 232 if (NOT MSVC AND NOT NOFORTRAN)
 233   # Build test and ctest
 234   add_subdirectory(test)
 235   if(NOT NO_CBLAS)
 236     add_subdirectory(ctest)
 237   endif()
 238   add_subdirectory(lapack-netlib/TESTING)
 239           if (CPP_THREAD_SAFETY_TEST OR CPP_THREAD_SAFETY_GEMV)
 240                 add_subdirectory(cpp_thread_test)
 241           endif()
 242 endif()
 243
 244 set_target_properties(${OpenBLAS_LIBNAME} PROPERTIES
 245   VERSION ${OpenBLAS_MAJOR_VERSION}.${OpenBLAS_MINOR_VERSION}
 246   SOVERSION ${OpenBLAS_MAJOR_VERSION}
 247 )
 248
 249 if (BUILD_SHARED_LIBS AND BUILD_RELAPACK)
 250   if (NOT MSVC)
 251     target_link_libraries(${OpenBLAS_LIBNAME} "-Wl,-allow-multiple-definition")
 252   else()
 253    set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /FORCE:MULTIPLE")
 254   endif()
 255 endif()
 256
 257 if (BUILD_SHARED_LIBS AND NOT ${SYMBOLPREFIX}${SYMBOLSUFFIX} STREQUAL "")
 258 if (NOT DEFINED ARCH)
 259   set(ARCH_IN "x86_64")
 260 else()
 261   set(ARCH_IN ${ARCH})
 262 endif()
 263
 264 if (${CORE} STREQUAL "generic")
 265   set(ARCH_IN "GENERIC")
 266 endif ()
 267
 268 if (NOT DEFINED EXPRECISION)
 269   set(EXPRECISION_IN 0)
 270 else()
 271   set(EXPRECISION_IN ${EXPRECISION})
 272 endif()
 273
 274 if (NOT DEFINED NO_CBLAS)
 275   set(NO_CBLAS_IN 0)
 276 else()
 277   set(NO_CBLAS_IN ${NO_CBLAS})
 278 endif()
 279
 280 if (NOT DEFINED NO_LAPACK)
 281   set(NO_LAPACK_IN 0)
 282 else()
 283   set(NO_LAPACK_IN ${NO_LAPACK})
 284 endif()
 285
 286 if (NOT DEFINED NO_LAPACKE)
 287   set(NO_LAPACKE_IN 0)
 288 else()
 289   set(NO_LAPACKE_IN ${NO_LAPACKE})
 290 endif()
 291
 292 if (NOT DEFINED NEED2UNDERSCORES)
 293   set(NEED2UNDERSCORES_IN 0)
 294 else()
 295   set(NEED2UNDERSCORES_IN ${NEED2UNDERSCORES})
 296 endif()
 297
 298 if (NOT DEFINED ONLY_CBLAS)
 299   set(ONLY_CBLAS_IN 0)
 300 else()
 301   set(ONLY_CBLAS_IN ${ONLY_CBLAS})
 302 endif()
 303
 304 if (NOT DEFINED BU)
 305   set(BU _)
 306 endif()
 307
 308 if (NOT ${SYMBOLPREFIX} STREQUAL "")
 309 message(STATUS "adding prefix ${SYMBOLPREFIX} to names of exported symbols in ${OpenBLAS_LIBNAME}")
 310 endif()
 311 if (NOT ${SYMBOLSUFFIX} STREQUAL "")
 312 message(STATUS "adding suffix ${SYMBOLSUFFIX} to names of exported symbols in ${OpenBLAS_LIBNAME}")
 313 endif()
 314         add_custom_command(TARGET ${OpenBLAS_LIBNAME} POST_BUILD
 315         COMMAND perl  ${PROJECT_SOURCE_DIR}/exports/gensymbol "objcopy" "${ARCH}" "${BU}" "${EXPRECISION_IN}" "${NO_CBLAS_IN}" "${NO_LAPACK_IN}" "${NO_LAPACKE_IN}" "${NEED2UNDERSCORES_IN}" "${ONLY_CBLAS_IN}" \"${SYMBOLPREFIX}\" \"${SYMBOLSUFFIX}\" "${BUILD_LAPACK_DEPRECATED}" > ${PROJECT_BINARY_DIR}/objcopy.def
 316         COMMAND objcopy -v --redefine-syms ${PROJECT_BINARY_DIR}/objcopy.def  ${PROJECT_BINARY_DIR}/lib/lib${OpenBLAS_LIBNAME}.so
 317         COMMENT "renaming symbols"
 318         )
 319 endif()
 320
 321
 322 # Install project
 323
 324 # Install libraries
 325 install(TARGETS ${OpenBLAS_LIBNAME}
 326         EXPORT "OpenBLAS${SUFFIX64}Targets"
 327         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 328         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 329   LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR} )
 330
 331 # Install headers
 332 set(CMAKE_INSTALL_INCLUDEDIR ${CMAKE_INSTALL_INCLUDEDIR}/openblas${SUFFIX64})
 333 set(CMAKE_INSTALL_FULL_INCLUDEDIR ${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_INCLUDEDIR})
 334
 335 message(STATUS "Generating openblas_config.h in ${CMAKE_INSTALL_INCLUDEDIR}")
 336
 337 set(OPENBLAS_CONFIG_H ${CMAKE_BINARY_DIR}/openblas_config.h)
 338 file(WRITE  ${OPENBLAS_CONFIG_H} "#ifndef OPENBLAS_CONFIG_H\n")
 339 file(APPEND ${OPENBLAS_CONFIG_H} "#define OPENBLAS_CONFIG_H\n")
 340 file(STRINGS ${PROJECT_BINARY_DIR}/config.h __lines)
 341 foreach(line ${__lines})
 342   string(REPLACE "#define " "" line ${line})
 343   file(APPEND ${OPENBLAS_CONFIG_H} "#define OPENBLAS_${line}\n")
 344 endforeach()
 345 file(APPEND ${OPENBLAS_CONFIG_H} "#define OPENBLAS_VERSION \"OpenBLAS ${OpenBLAS_VERSION}\"\n")
 346 file(READ   ${CMAKE_CURRENT_SOURCE_DIR}/openblas_config_template.h OPENBLAS_CONFIG_TEMPLATE_H_CONTENTS)
 347 file(APPEND ${OPENBLAS_CONFIG_H} "${OPENBLAS_CONFIG_TEMPLATE_H_CONTENTS}\n")
 348 file(APPEND ${OPENBLAS_CONFIG_H} "#endif /* OPENBLAS_CONFIG_H */\n")
 349 install (FILES ${OPENBLAS_CONFIG_H} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 350
 351 if(NOT NOFORTRAN)
 352   message(STATUS "Generating f77blas.h in ${CMAKE_INSTALL_INCLUDEDIR}")
 353
 354   set(F77BLAS_H ${CMAKE_BINARY_DIR}/generated/f77blas.h)
 355   file(WRITE  ${F77BLAS_H} "#ifndef OPENBLAS_F77BLAS_H\n")
 356   file(APPEND ${F77BLAS_H} "#define OPENBLAS_F77BLAS_H\n")
 357   file(APPEND ${F77BLAS_H} "#include \"openblas_config.h\"\n")
 358   file(READ ${CMAKE_CURRENT_SOURCE_DIR}/common_interface.h COMMON_INTERFACE_H_CONTENTS)
 359   file(APPEND ${F77BLAS_H} "${COMMON_INTERFACE_H_CONTENTS}\n")
 360   file(APPEND ${F77BLAS_H} "#endif")
 361   install (FILES ${F77BLAS_H} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 362 endif()
 363
 364 if(NOT NO_CBLAS)
 365         message (STATUS "Generating cblas.h in ${CMAKE_INSTALL_INCLUDEDIR}")
 366         set(CBLAS_H ${CMAKE_BINARY_DIR}/generated/cblas.h)
 367         file(READ ${CMAKE_CURRENT_SOURCE_DIR}/cblas.h CBLAS_H_CONTENTS)
 368         string(REPLACE "common" "openblas_config" CBLAS_H_CONTENTS_NEW "${CBLAS_H_CONTENTS}")
 369         if (NOT ${SYMBOLPREFIX} STREQUAL "")
 370         string(REPLACE " cblas" " ${SYMBOLPREFIX}cblas" CBLAS_H_CONTENTS        "${CBLAS_H_CONTENTS_NEW}")
 371         string(REPLACE " openblas" " ${SYMBOLPREFIX}openblas" CBLAS_H_CONTENTS_NEW      "${CBLAS_H_CONTENTS}")
 372         string (REPLACE " ${SYMBOLPREFIX}openblas_complex" " openblas_complex" CBLAS_H_CONTENTS "${CBLAS_H_CONTENTS_NEW}")
 373         string(REPLACE " goto" " ${SYMBOLPREFIX}goto" CBLAS_H_CONTENTS_NEW "${CBLAS_H_CONTENTS}")
 374         endif()
 375         if (NOT ${SYMBOLSUFFIX} STREQUAL "")
 376         string(REGEX REPLACE "(cblas[^ (]*)" "\\1${SYMBOLSUFFIX}" CBLAS_H_CONTENTS      "${CBLAS_H_CONTENTS_NEW}")
 377         string(REGEX REPLACE "(openblas[^ (]*)" "\\1${SYMBOLSUFFIX}" CBLAS_H_CONTENTS_NEW "${CBLAS_H_CONTENTS}")
 378         string(REGEX REPLACE "(openblas_complex[^ ]*)${SYMBOLSUFFIX}" "\\1" CBLAS_H_CONTENTS    "${CBLAS_H_CONTENTS_NEW}")
 379         string(REGEX REPLACE "(goto[^ (]*)" "\\1${SYMBOLSUFFIX}" CBLAS_H_CONTENTS_NEW   "${CBLAS_H_CONTENTS}")
 380         endif()
 381         file(WRITE ${CBLAS_H} "${CBLAS_H_CONTENTS_NEW}")
 382         install (FILES ${CBLAS_H} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 383 endif()
 384
 385 if(NOT NO_LAPACKE)
 386         message (STATUS "Copying LAPACKE header files to ${CMAKE_INSTALL_INCLUDEDIR}")
 387         add_dependencies( ${OpenBLAS_LIBNAME} genlapacke)
 388         FILE(GLOB_RECURSE INCLUDE_FILES "${CMAKE_CURRENT_SOURCE_DIR}/lapack-netlib/LAPACKE/*.h")
 389         install (FILES ${INCLUDE_FILES} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 390
 391         ADD_CUSTOM_TARGET(genlapacke
 392         COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/lapack-netlib/LAPACKE/include/lapacke_mangling_with_flags.h.in "${CMAKE_BINARY_DIR}/lapacke_mangling.h"
 393         )
 394         install (FILES ${CMAKE_BINARY_DIR}/lapacke_mangling.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/openblas${SUFFIX64})
 395 endif()
 396
 397 # Install pkg-config files
 398 configure_file(${PROJECT_SOURCE_DIR}/cmake/openblas.pc.in ${PROJECT_BINARY_DIR}/openblas${SUFFIX64}.pc @ONLY)
 399 install (FILES ${PROJECT_BINARY_DIR}/openblas${SUFFIX64}.pc DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig/)
 400
 401
 402 # GNUInstallDirs "DATADIR" wrong here; CMake search path wants "share".
 403 set(PN OpenBLAS)
 404 set(CMAKECONFIG_INSTALL_DIR "share/cmake/${PN}${SUFFIX64}")
 405 configure_package_config_file(cmake/${PN}Config.cmake.in
 406                               "${CMAKE_CURRENT_BINARY_DIR}/${PN}${SUFFIX64}Config.cmake"
 407                               INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR})
 408 write_basic_package_version_file(${CMAKE_CURRENT_BINARY_DIR}/${PN}ConfigVersion.cmake
 409                                  VERSION ${${PN}_VERSION}
 410                                  COMPATIBILITY AnyNewerVersion)
 411 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${PN}${SUFFIX64}Config.cmake
 412         DESTINATION ${CMAKECONFIG_INSTALL_DIR})
 413 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${PN}ConfigVersion.cmake
 414         RENAME ${PN}${SUFFIX64}ConfigVersion.cmake
 415         DESTINATION ${CMAKECONFIG_INSTALL_DIR})
 416 install(EXPORT "${PN}${SUFFIX64}Targets"
 417         NAMESPACE "${PN}${SUFFIX64}::"
 418         DESTINATION ${CMAKECONFIG_INSTALL_DIR})
 419