CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.0)
   2 project(harfbuzz)
   3
   4 enable_testing()
   5
   6 ## Limit framework build to Xcode generator
   7 if (BUILD_FRAMEWORK)
   8   # for a framework build on macOS, use:
   9   # cmake -DBUILD_FRAMEWORK=ON -Bbuild -H. -GXcode && cmake --build build
  10   if (NOT "${CMAKE_GENERATOR}" STREQUAL "Xcode")
  11     message(FATAL_ERROR
  12       "You should use Xcode generator with BUILD_FRAMEWORK enabled")
  13   endif ()
  14   set (CMAKE_OSX_ARCHITECTURES "$(ARCHS_STANDARD_32_64_BIT)")
  15   set (CMAKE_MACOSX_RPATH ON)
  16   set (BUILD_SHARED_LIBS ON)
  17 endif ()
  18
  19
  20 ## Disallow in-source builds, as CMake generated make files can collide with autotools ones
  21 if (NOT MSVC AND "${PROJECT_BINARY_DIR}" STREQUAL "${PROJECT_SOURCE_DIR}")
  22   message(FATAL_ERROR
  23     "
  24 In-source builds are not permitted!  Make a separate folder for"
  25     " building, e.g.,"
  26     "
  27   mkdir build; cd build; cmake .."
  28     "
  29 Before that, remove the files created by this failed run with"
  30     "
  31   rm -rf CMakeCache.txt CMakeFiles")
  32 endif ()
  33
  34
  35 ## HarfBuzz build configurations
  36 option(HB_HAVE_FREETYPE "Enable freetype interop helpers" OFF)
  37 option(HB_HAVE_GRAPHITE2 "Enable Graphite2 complementary shaper" OFF)
  38 option(HB_HAVE_GLIB "Enable glib unicode functions" OFF)
  39 option(HB_HAVE_ICU "Enable icu unicode functions" OFF)
  40 if (APPLE)
  41   option(HB_HAVE_CORETEXT "Enable CoreText shaper backend on macOS" ON)
  42   set (CMAKE_MACOSX_RPATH ON)
  43 endif ()
  44 if (WIN32)
  45   option(HB_HAVE_UNISCRIBE "Enable Uniscribe shaper backend on Windows" OFF)
  46   option(HB_HAVE_DIRECTWRITE "Enable DirectWrite shaper backend on Windows" OFF)
  47 endif ()
  48 option(HB_BUILD_UTILS "Build harfbuzz utils, needs cairo, freetype, and glib properly be installed" OFF)
  49 if (HB_BUILD_UTILS)
  50   set (HB_HAVE_GLIB ON)
  51   set (HB_HAVE_FREETYPE ON)
  52 endif ()
  53
  54 option(HB_BUILD_SUBSET "Build harfbuzz-subset" ON)
  55 option(HB_BUILD_TESTS "Build harfbuzz tests" ON)
  56
  57 option(HB_HAVE_GOBJECT "Enable GObject Bindings" OFF)
  58 if (HB_HAVE_GOBJECT)
  59   set (HB_HAVE_GLIB ON)
  60 endif ()
  61
  62 option(HB_HAVE_INTROSPECTION "Enable building introspection (.gir/.typelib) files" OFF)
  63 if (HB_HAVE_INTROSPECTION)
  64   set (HB_HAVE_GOBJECT ON)
  65   set (HB_HAVE_GLIB ON)
  66 endif ()
  67
  68 option(HB_CHECK OFF "Do a configuration suitable for testing (shared library and enable all options)")
  69 if (HB_CHECK)
  70   set (BUILD_SHARED_LIBS ON)
  71   set (HB_BUILD_UTILS ON)
  72   set (HB_HAVE_ICU)
  73   set (HB_HAVE_GLIB ON)
  74   #set (HB_HAVE_GOBJECT ON)
  75   #set (HB_HAVE_INTROSPECTION ON)
  76   set (HB_HAVE_FREETYPE ON)
  77   set (HB_HAVE_GRAPHITE2 ON)
  78   if (WIN32)
  79     set (HB_HAVE_UNISCRIBE ON)
  80     set (HB_HAVE_DIRECTWRITE ON)
  81   elseif (APPLE)
  82     set (HB_HAVE_CORETEXT ON)
  83   endif ()
  84 endif ()
  85
  86 include_directories(AFTER
  87   ${PROJECT_SOURCE_DIR}/src
  88   ${PROJECT_BINARY_DIR}/src
  89 )
  90
  91 # We need PYTHON_EXECUTABLE to be set for running the tests...
  92 include (FindPythonInterp)
  93
  94 ## Functions and headers
  95 include (CheckFunctionExists)
  96 include (CheckIncludeFile)
  97 macro (check_funcs) # Similar to AC_CHECK_FUNCS of autotools
  98   foreach (func_name ${ARGN})
  99     string(TOUPPER ${func_name} definition_to_add)
 100     check_function_exists(${func_name} HAVE_${definition_to_add})
 101     if (${HAVE_${definition_to_add}})
 102       add_definitions(-DHAVE_${definition_to_add})
 103     endif ()
 104   endforeach ()
 105 endmacro ()
 106 if (UNIX)
 107   list(APPEND CMAKE_REQUIRED_LIBRARIES m)
 108 endif ()
 109 check_funcs(atexit mprotect sysconf getpagesize mmap isatty newlocale strtod_l)
 110 check_include_file(unistd.h HAVE_UNISTD_H)
 111 if (${HAVE_UNISTD_H})
 112   add_definitions(-DHAVE_UNISTD_H)
 113 endif ()
 114 check_include_file(sys/mman.h HAVE_SYS_MMAN_H)
 115 if (${HAVE_SYS_MMAN_H})
 116   add_definitions(-DHAVE_SYS_MMAN_H)
 117 endif ()
 118 check_include_file(xlocale.h HAVE_XLOCALE_H)
 119 if (${HAVE_XLOCALE_H})
 120   add_definitions(-DHAVE_XLOCALE_H)
 121 endif ()
 122 check_include_file(stdbool.h HAVE_STDBOOL_H)
 123 if (${HAVE_STDBOOL_H})
 124   add_definitions(-DHAVE_STDBOOL_H)
 125 endif ()
 126
 127
 128 if (MSVC)
 129   add_definitions(-wd4244 -wd4267 -D_CRT_SECURE_NO_WARNINGS -D_CRT_NONSTDC_NO_WARNINGS)
 130 endif ()
 131
 132
 133 ## Detect if we are running inside a distribution or regular repository folder
 134 # if (EXISTS "${PROJECT_SOURCE_DIR}/ChangeLog")
 135 #   # perhaps we are on dist directory
 136 #   set (IN_HB_DIST TRUE)
 137 #   #set (HB_VERSION_H "${PROJECT_SOURCE_DIR}/src/hb-version.h")
 138 # endif ()
 139
 140
 141 ## Extract variables from Makefile files
 142 function (extract_make_variable variable makefile_source)
 143   string(REGEX MATCH "${variable} = ([^$]+)\\$" temp ${makefile_source})
 144   string(REGEX MATCHALL "[^ \n\t\\]+" listVar ${CMAKE_MATCH_1})
 145   set (${variable} ${listVar} PARENT_SCOPE)
 146 endfunction ()
 147
 148 # http://stackoverflow.com/a/27630120
 149 function (add_prefix_to_list var prefix)
 150   set (listVar "")
 151   foreach (f ${${var}})
 152     list(APPEND listVar "${prefix}${f}")
 153   endforeach ()
 154   set (${var} "${listVar}" PARENT_SCOPE)
 155 endfunction ()
 156
 157 file(READ ${PROJECT_SOURCE_DIR}/src/Makefile.sources SRCSOURCES)
 158 file(READ ${PROJECT_SOURCE_DIR}/util/Makefile.sources UTILSOURCES)
 159
 160 extract_make_variable(HB_BASE_headers ${SRCSOURCES})
 161 add_prefix_to_list(HB_BASE_headers "${PROJECT_SOURCE_DIR}/src/")
 162
 163 extract_make_variable(HB_SUBSET_sources ${SRCSOURCES})
 164 add_prefix_to_list(HB_SUBSET_sources "${PROJECT_SOURCE_DIR}/src/")
 165
 166 extract_make_variable(HB_SUBSET_headers ${SRCSOURCES})
 167 add_prefix_to_list(HB_SUBSET_headers "${PROJECT_SOURCE_DIR}/src/")
 168
 169 extract_make_variable(HB_BASE_RAGEL_GENERATED_sources ${SRCSOURCES})
 170 #if (IN_HB_DIST)
 171   add_prefix_to_list(HB_BASE_RAGEL_GENERATED_sources "${PROJECT_SOURCE_DIR}/src/")
 172 #else ()
 173 #  add_prefix_to_list(HB_BASE_RAGEL_GENERATED_sources "${PROJECT_BINARY_DIR}/src/")
 174 #endif ()
 175
 176 extract_make_variable(HB_VIEW_sources ${UTILSOURCES})
 177 add_prefix_to_list(HB_VIEW_sources "${PROJECT_SOURCE_DIR}/util/")
 178 extract_make_variable(HB_SHAPE_sources ${UTILSOURCES})
 179 add_prefix_to_list(HB_SHAPE_sources "${PROJECT_SOURCE_DIR}/util/")
 180 extract_make_variable(HB_SUBSET_CLI_sources ${UTILSOURCES})
 181 add_prefix_to_list(HB_SUBSET_CLI_sources "${PROJECT_SOURCE_DIR}/util/")
 182 extract_make_variable(HB_OT_SHAPE_CLOSURE_sources ${UTILSOURCES})
 183 add_prefix_to_list(HB_OT_SHAPE_CLOSURE_sources "${PROJECT_SOURCE_DIR}/util/")
 184
 185
 186 file(READ configure.ac CONFIGUREAC)
 187 string(REGEX MATCH "\\[(([0-9]+)\\.([0-9]+)\\.([0-9]+))\\]" HB_VERSION_MATCH ${CONFIGUREAC})
 188 set (HB_VERSION ${CMAKE_MATCH_1})
 189 set (HB_VERSION_MAJOR ${CMAKE_MATCH_2})
 190 set (HB_VERSION_MINOR ${CMAKE_MATCH_3})
 191 set (HB_VERSION_MICRO ${CMAKE_MATCH_4})
 192
 193 ## Define sources and headers of the project
 194 set (project_sources ${PROJECT_SOURCE_DIR}/src/harfbuzz.cc) # use amalgam source
 195 set (subset_project_sources ${HB_SUBSET_sources})
 196 set (project_extra_sources)
 197 set (project_headers ${HB_BASE_headers})
 198 set (subset_project_headers ${HB_SUBSET_headers})
 199
 200 ## Find and include needed header folders and libraries
 201 if (HB_HAVE_FREETYPE)
 202   include (FindFreetype)
 203   if (NOT FREETYPE_FOUND)
 204     message(FATAL_ERROR "HB_HAVE_FREETYPE was set, but we failed to find it. Maybe add a CMAKE_PREFIX_PATH= to your Freetype2 install prefix")
 205   endif ()
 206
 207   list(APPEND THIRD_PARTY_LIBS ${FREETYPE_LIBRARIES})
 208   include_directories(AFTER ${FREETYPE_INCLUDE_DIRS})
 209   add_definitions(-DHAVE_FREETYPE=1)
 210
 211   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-ft.h)
 212
 213   # So check_funcs can find its headers
 214   set (CMAKE_REQUIRED_INCLUDES ${CMAKE_REQUIRED_INCLUDES} ${FREETYPE_INCLUDE_DIRS})
 215   set (CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} ${FREETYPE_LIBRARIES})
 216
 217   check_funcs(FT_Get_Var_Blend_Coordinates FT_Set_Var_Blend_Coordinates FT_Done_MM_Var)
 218 endif ()
 219
 220 if (HB_HAVE_GRAPHITE2)
 221   add_definitions(-DHAVE_GRAPHITE2)
 222
 223   find_path(GRAPHITE2_INCLUDE_DIR graphite2/Font.h)
 224   find_library(GRAPHITE2_LIBRARY graphite2)
 225
 226   include_directories(${GRAPHITE2_INCLUDE_DIR})
 227
 228   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-graphite2.h)
 229
 230   list(APPEND THIRD_PARTY_LIBS ${GRAPHITE2_LIBRARY})
 231
 232   mark_as_advanced(GRAPHITE2_INCLUDE_DIR GRAPHITE2_LIBRARY)
 233 endif ()
 234
 235 if (HB_HAVE_GLIB)
 236   add_definitions(-DHAVE_GLIB)
 237
 238   # https://github.com/WebKit/webkit/blob/master/Source/cmake/FindGLIB.cmake
 239   find_package(PkgConfig)
 240   pkg_check_modules(PC_GLIB QUIET glib-2.0)
 241
 242   find_library(GLIB_LIBRARIES NAMES glib-2.0 HINTS ${PC_GLIB_LIBDIR} ${PC_GLIB_LIBRARY_DIRS})
 243   find_path(GLIBCONFIG_INCLUDE_DIR NAMES glibconfig.h HINTS ${PC_LIBDIR} ${PC_LIBRARY_DIRS} ${PC_GLIB_INCLUDEDIR} ${PC_GLIB_INCLUDE_DIRS} PATH_SUFFIXES glib-2.0/include)
 244   find_path(GLIB_INCLUDE_DIR NAMES glib.h HINTS ${PC_GLIB_INCLUDEDIR} ${PC_GLIB_INCLUDE_DIRS} PATH_SUFFIXES glib-2.0)
 245
 246   include_directories(${GLIBCONFIG_INCLUDE_DIR} ${GLIB_INCLUDE_DIR})
 247
 248   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-glib.h)
 249
 250   list(APPEND THIRD_PARTY_LIBS ${GLIB_LIBRARIES})
 251
 252   mark_as_advanced(GLIB_LIBRARIES GLIBCONFIG_INCLUDE_DIR GLIB_INCLUDE_DIR)
 253 endif ()
 254
 255 if (HB_HAVE_ICU)
 256   add_definitions(-DHAVE_ICU)
 257
 258   # https://github.com/WebKit/webkit/blob/master/Source/cmake/FindICU.cmake
 259   find_package(PkgConfig)
 260   pkg_check_modules(PC_ICU QUIET icu-uc)
 261
 262   find_path(ICU_INCLUDE_DIR NAMES unicode/utypes.h HINTS ${PC_ICU_INCLUDE_DIRS} ${PC_ICU_INCLUDEDIR})
 263   find_library(ICU_LIBRARY NAMES libicuuc cygicuuc cygicuuc32 icuuc HINTS ${PC_ICU_LIBRARY_DIRS} ${PC_ICU_LIBDIR})
 264
 265   include_directories(${ICU_INCLUDE_DIR})
 266
 267   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-icu.h)
 268
 269   list(APPEND THIRD_PARTY_LIBS ${ICU_LIBRARY})
 270
 271   mark_as_advanced(ICU_INCLUDE_DIR ICU_LIBRARY)
 272 endif ()
 273
 274 if (APPLE AND HB_HAVE_CORETEXT)
 275   # Apple Advanced Typography
 276   add_definitions(-DHAVE_CORETEXT)
 277
 278   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-coretext.h)
 279
 280   if (HB_IOS)
 281     find_library(COREFOUNDATION CoreFoundation)
 282     if (COREFOUNDATION)
 283       list(APPEND THIRD_PARTY_LIBS ${COREFOUNDATION})
 284     endif ()
 285     mark_as_advanced(COREFOUNDATION)
 286
 287     find_library(CORETEXT CoreText)
 288     if (CORETEXT)
 289       list(APPEND THIRD_PARTY_LIBS ${CORETEXT})
 290     endif ()
 291     mark_as_advanced(CORETEXT)
 292
 293     find_library(COREGRAPHICS CoreGraphics)
 294     if (COREGRAPHICS)
 295       list(APPEND THIRD_PARTY_LIBS ${COREGRAPHICS})
 296     endif ()
 297     mark_as_advanced(COREGRAPHICS)
 298   else ()
 299     find_library(APPLICATION_SERVICES_FRAMEWORK ApplicationServices)
 300     if (APPLICATION_SERVICES_FRAMEWORK)
 301       list(APPEND THIRD_PARTY_LIBS ${APPLICATION_SERVICES_FRAMEWORK})
 302     endif ()
 303
 304     mark_as_advanced(APPLICATION_SERVICES_FRAMEWORK)
 305   endif ()
 306 endif ()
 307
 308 if (WIN32 AND HB_HAVE_UNISCRIBE)
 309   add_definitions(-DHAVE_UNISCRIBE)
 310   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-uniscribe.h)
 311   list(APPEND THIRD_PARTY_LIBS usp10 gdi32 rpcrt4)
 312 endif ()
 313
 314 if (WIN32 AND HB_HAVE_DIRECTWRITE)
 315   add_definitions(-DHAVE_DIRECTWRITE)
 316   list(APPEND project_headers ${PROJECT_SOURCE_DIR}/src/hb-directwrite.h)
 317   list(APPEND THIRD_PARTY_LIBS dwrite rpcrt4)
 318 endif ()
 319
 320 if (HB_HAVE_GOBJECT)
 321   include (FindPerl)
 322
 323   # Use the hints from glib-2.0.pc to find glib-mkenums
 324   find_package(PkgConfig)
 325   pkg_check_modules(PC_GLIB QUIET glib-2.0)
 326   find_program(GLIB_MKENUMS glib-mkenums
 327     HINTS ${PC_glib_mkenums}
 328   )
 329   set (GLIB_MKENUMS_CMD)
 330
 331   if (WIN32 AND NOT MINGW)
 332     # In Visual Studio builds, shebang lines are not supported
 333     # in the standard cmd.exe shell that we use, so we need to
 334     # first determine whether glib-mkenums is a Python or PERL
 335     # script
 336     execute_process(COMMAND "${PYTHON_EXECUTABLE}" "${GLIB_MKENUMS}" --version
 337       RESULT_VARIABLE GLIB_MKENUMS_PYTHON
 338       OUTPUT_QUIET ERROR_QUIET
 339     )
 340     if (GLIB_MKENUMS_PYTHON EQUAL 0)
 341       message("${GLIB_MKENUMS} is a Python script.")
 342       set (GLIB_MKENUMS_CMD "${PYTHON_EXECUTABLE}" "${GLIB_MKENUMS}")
 343     else ()
 344       execute_process(COMMAND "${PERL_EXECUTABLE}" "${GLIB_MKENUMS}" --version
 345         RESULT_VARIABLE GLIB_MKENUMS_PERL
 346         OUTPUT_QUIET ERROR_QUIET
 347       )
 348       if (GLIB_MKENUMS_PERL EQUAL 0)
 349         message("${GLIB_MKENUMS} is a PERL script.")
 350         set (GLIB_MKENUMS_CMD "${PERL_EXECUTABLE}" "${GLIB_MKENUMS}")
 351       endif ()
 352       if (NOT GLIB_MKENUMS_PERL EQUAL 0 AND NOT GLIB_MKENUMS_PYTHON EQUAL 0)
 353         message(FATAL_ERROR "Unable to determine type of glib-mkenums script")
 354       endif ()
 355     endif ()
 356   else ()
 357     set (GLIB_MKENUMS_CMD "${GLIB_MKENUMS}")
 358   endif ()
 359   if (NOT GLIB_MKENUMS_CMD)
 360     message(FATAL_ERROR "HB_HAVE_GOBJECT was set, but we failed to find glib-mkenums, which is required")
 361   endif ()
 362
 363   pkg_check_modules(PC_GOBJECT QUIET gobject-2.0)
 364
 365   find_library(GOBJECT_LIBRARIES NAMES gobject-2.0 HINTS ${PC_GLIB_LIBDIR} ${PC_GLIB_LIBRARY_DIRS})
 366   find_path(GOBJECT_INCLUDE_DIR NAMES glib-object.h HINTS ${PC_GLIB_INCLUDEDIR} ${PC_GLIB_INCLUDE_DIRS} PATH_SUFFIXES glib-2.0)
 367
 368   include_directories(${GOBJECTCONFIG_INCLUDE_DIR} ${GOBJECT_INCLUDE_DIR})
 369   mark_as_advanced(GOBJECT_LIBRARIES GOBJECT_INCLUDE_DIR)
 370
 371   list(APPEND hb_gobject_sources ${PROJECT_SOURCE_DIR}/src/hb-gobject-structs.cc)
 372   list(APPEND hb_gobject_gen_sources
 373     ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc
 374   )
 375   list(APPEND hb_gobject_structs_headers
 376     ${PROJECT_SOURCE_DIR}/src/hb-gobject-structs.h
 377   )
 378   list(APPEND hb_gobject_headers
 379     ${PROJECT_SOURCE_DIR}/src/hb-gobject.h
 380     ${hb_gobject_structs_headers}
 381   )
 382   list(APPEND hb_gobject_gen_headers
 383     ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h
 384   )
 385
 386   add_custom_command(
 387     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h
 388     COMMAND ${GLIB_MKENUMS_CMD}
 389       --template=${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.h.tmpl
 390       --identifier-prefix hb_
 391       --symbol-prefix hb_gobject
 392       ${hb_gobject_structs_headers}
 393       ${project_headers}
 394       > ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h.tmp
 395     COMMAND "${CMAKE_COMMAND}"
 396       "-DENUM_INPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h.tmp"
 397       "-DENUM_OUTPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h"
 398       -P ${PROJECT_SOURCE_DIR}/replace-enum-strings.cmake
 399     DEPENDS ${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.h.tmpl
 400       ${hb_gobject_header}
 401       ${project_headers}
 402   )
 403
 404   add_custom_command(
 405     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc
 406     COMMAND ${GLIB_MKENUMS_CMD}
 407       --template=${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.cc.tmpl
 408       --identifier-prefix hb_
 409       --symbol-prefix hb_gobject
 410       ${hb_gobject_header}
 411       ${project_headers}
 412       > ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc.tmp
 413     COMMAND "${CMAKE_COMMAND}"
 414       "-DENUM_INPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc.tmp"
 415       "-DENUM_OUTPUT_SRC=${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.cc"
 416       -P ${PROJECT_SOURCE_DIR}/replace-enum-strings.cmake
 417     DEPENDS ${PROJECT_SOURCE_DIR}/src/hb-gobject-enums.cc.tmpl
 418       ${CMAKE_CURRENT_BINARY_DIR}/src/hb-gobject-enums.h
 419       ${hb_gobject_header}
 420       ${project_headers}
 421   )
 422 endif ()
 423
 424 ## Atomic ops availability detection
 425 file(WRITE "${PROJECT_BINARY_DIR}/try_compile_intel_atomic_primitives.c"
 426 "               void memory_barrier (void) { __sync_synchronize (); }
 427                 int atomic_add (int *i) { return __sync_fetch_and_add (i, 1); }
 428                 int mutex_trylock (int *m) { return __sync_lock_test_and_set (m, 1); }
 429                 void mutex_unlock (int *m) { __sync_lock_release (m); }
 430                 int main () { return 0; }
 431 ")
 432 try_compile(HB_HAVE_INTEL_ATOMIC_PRIMITIVES
 433   ${PROJECT_BINARY_DIR}/try_compile_intel_atomic_primitives
 434   ${PROJECT_BINARY_DIR}/try_compile_intel_atomic_primitives.c)
 435 if (HB_HAVE_INTEL_ATOMIC_PRIMITIVES)
 436   add_definitions(-DHAVE_INTEL_ATOMIC_PRIMITIVES)
 437 endif ()
 438
 439 file(WRITE "${PROJECT_BINARY_DIR}/try_compile_solaris_atomic_ops.c"
 440 "               #include <atomic.h>
 441                 /* This requires Solaris Studio 12.2 or newer: */
 442                 #include <mbarrier.h>
 443                 void memory_barrier (void) { __machine_rw_barrier (); }
 444                 int atomic_add (volatile unsigned *i) { return atomic_add_int_nv (i, 1); }
 445                 void *atomic_ptr_cmpxchg (volatile void **target, void *cmp, void *newval) { return atomic_cas_ptr (target, cmp, newval); }
 446                 int main () { return 0; }
 447 ")
 448 try_compile(HB_HAVE_SOLARIS_ATOMIC_OPS
 449   ${PROJECT_BINARY_DIR}/try_compile_solaris_atomic_ops
 450   ${PROJECT_BINARY_DIR}/try_compile_solaris_atomic_ops.c)
 451 if (HB_HAVE_SOLARIS_ATOMIC_OPS)
 452   add_definitions(-DHAVE_SOLARIS_ATOMIC_OPS)
 453 endif ()
 454
 455
 456 ## Define harfbuzz library
 457 add_library(harfbuzz ${project_sources} ${project_extra_sources} ${project_headers})
 458 target_link_libraries(harfbuzz ${THIRD_PARTY_LIBS})
 459
 460 ## Define harfbuzz-subset library
 461 if (HB_BUILD_SUBSET)
 462   add_library(harfbuzz-subset ${subset_project_sources} ${subset_project_headers})
 463   add_dependencies(harfbuzz-subset harfbuzz)
 464   target_link_libraries(harfbuzz-subset harfbuzz ${THIRD_PARTY_LIBS})
 465
 466   if (BUILD_SHARED_LIBS)
 467     set_target_properties(harfbuzz harfbuzz-subset PROPERTIES VISIBILITY_INLINES_HIDDEN TRUE)
 468   endif ()
 469 endif ()
 470
 471 if (UNIX OR MINGW)
 472   # Make symbols link locally
 473   include (CheckCXXCompilerFlag)
 474   CHECK_CXX_COMPILER_FLAG(-Bsymbolic-functions CXX_SUPPORTS_FLAG_BSYMB_FUNCS)
 475   if (CXX_SUPPORTS_FLAG_BSYMB_FUNCS)
 476     link_libraries(-Bsymbolic-functions)
 477   endif ()
 478
 479   if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang" OR CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
 480     # Make sure we don't link to libstdc++
 481     set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-rtti -fno-exceptions")
 482     set (CMAKE_CXX_IMPLICIT_LINK_LIBRARIES "m") # libm
 483     set (CMAKE_CXX_IMPLICIT_LINK_DIRECTORIES "")
 484     set_target_properties(harfbuzz PROPERTIES LINKER_LANGUAGE C)
 485     if (HB_BUILD_SUBSET)
 486       set_target_properties(harfbuzz-subset PROPERTIES LINKER_LANGUAGE C)
 487     endif ()
 488
 489     # No threadsafe statics as we do it ourselves
 490     set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fno-threadsafe-statics")
 491   endif ()
 492
 493   CHECK_CXX_COMPILER_FLAG("-std=c++11" COMPILER_SUPPORTS_CXX11)
 494   if (COMPILER_SUPPORTS_CXX11)
 495     set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
 496   else()
 497     message(STATUS "The compiler ${CMAKE_CXX_COMPILER} has no C++11 support. Please use a different C++ compiler.")
 498   endif()
 499 endif ()
 500
 501
 502 ## Define harfbuzz-gobject library
 503 if (HB_HAVE_GOBJECT)
 504   add_library(harfbuzz-gobject
 505     ${hb_gobject_sources}
 506     ${hb_gobject_gen_sources}
 507     ${hb_gobject_headers}
 508     ${hb_gobject_gen_headers}
 509   )
 510   include_directories(BEFORE ${CMAKE_CURRENT_BINARY_DIR}/src)
 511   add_dependencies(harfbuzz-gobject harfbuzz)
 512   target_link_libraries(harfbuzz-gobject harfbuzz ${GOBJECT_LIBRARIES} ${THIRD_PARTY_LIBS})
 513
 514   if (BUILD_SHARED_LIBS)
 515     set_target_properties(harfbuzz-gobject PROPERTIES VISIBILITY_INLINES_HIDDEN TRUE)
 516   endif ()
 517 endif ()
 518
 519 if (BUILD_SHARED_LIBS AND WIN32 AND NOT MINGW)
 520   add_definitions("-DHB_DLL_EXPORT")
 521 endif ()
 522
 523 # On Windows, g-ir-scanner requires a DLL build in order for it to work
 524 if (WIN32)
 525   if (NOT BUILD_SHARED_LIBS)
 526     message("Building introspection files on Windows requires BUILD_SHARED_LIBS to be enabled.")
 527     set (HB_HAVE_INTROSPECTION OFF)
 528   endif ()
 529 endif ()
 530
 531 if (HB_HAVE_INTROSPECTION)
 532   find_package(PkgConfig)
 533   pkg_check_modules(PC_GI QUIET gobject-introspection-1.0)
 534
 535   find_program(G_IR_SCANNER g-ir-scanner
 536     HINTS ${PC_g_ir_scanner}
 537   )
 538
 539   find_program(G_IR_COMPILER g-ir-compiler
 540     HINTS ${PC_g_ir_compiler}
 541   )
 542
 543   if (WIN32 AND NOT MINGW)
 544     # Note that since we already enable HB_HAVE_GOBJECT
 545     # we would already have PYTHON_EXECUTABLE handy
 546     set (G_IR_SCANNER_CMD "${PYTHON_EXECUTABLE}" "${G_IR_SCANNER}")
 547   else ()
 548     set (G_IR_SCANNER_CMD "${G_IR_SCANNER}")
 549   endif ()
 550
 551   # We need to account for the varying output directories
 552   # when we build using Visual Studio projects
 553   if ("${CMAKE_GENERATOR}" MATCHES "Visual Studio*")
 554     set (hb_libpath "${CMAKE_CURRENT_BINARY_DIR}/$<CONFIGURATION>")
 555   else ()
 556     set (hb_libpath "$<TARGET_FILE_DIR:harfbuzz-gobject>")
 557   endif ()
 558
 559   # Get the CFlags that we used to build HarfBuzz/HarfBuzz-GObject
 560   set (hb_defines_cflags "")
 561   foreach (hb_cflag ${hb_cflags})
 562     list(APPEND hb_defines_cflags "-D${hb_cflag}")
 563   endforeach (hb_cflag)
 564
 565   # Get the other dependent libraries we used to build HarfBuzz/HarfBuzz-GObject
 566   set (extra_libs "")
 567   foreach (extra_lib ${THIRD_PARTY_LIBS})
 568     # We don't want the .lib extension here...
 569     string(REPLACE ".lib" "" extra_lib_stripped "${extra_lib}")
 570     list(APPEND extra_libs "--extra-library=${extra_lib_stripped}")
 571   endforeach ()
 572
 573   set (introspected_sources)
 574   foreach (f
 575     ${project_headers}
 576     ${project_sources}
 577     ${hb_gobject_gen_sources}
 578     ${hb_gobject_gen_headers}
 579     ${hb_gobject_sources}
 580     ${hb_gobject_headers}
 581   )
 582     if (WIN32)
 583       # Nasty issue: We need to make drive letters lower case,
 584       # otherwise g-ir-scanner won't like it and give us a bunch
 585       # of invalid items and unresolved types...
 586       STRING(SUBSTRING "${f}" 0 1 drive)
 587       STRING(SUBSTRING "${f}" 1 -1 path)
 588       if (drive MATCHES "[A-Z]")
 589         STRING(TOLOWER ${drive} drive_lower)
 590         list(APPEND introspected_sources "${drive_lower}${path}")
 591       else ()
 592         list(APPEND introspected_sources "${f}")
 593       endif ()
 594     else ()
 595       list(APPEND introspected_sources "${f}")
 596     endif ()
 597   endforeach ()
 598
 599   file(REMOVE ${CMAKE_CURRENT_BINARY_DIR}/src/hb_gir_list)
 600   foreach (s ${introspected_sources})
 601     file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/src/hb_gir_list "${s}\n")
 602   endforeach ()
 603
 604   # Finally, build the introspection files...
 605   add_custom_command(
 606     TARGET harfbuzz-gobject
 607     POST_BUILD
 608     COMMAND ${G_IR_SCANNER_CMD}
 609       --warn-all --no-libtool --verbose
 610       -n hb
 611       --namespace=HarfBuzz
 612       --nsversion=0.0
 613       --identifier-prefix=hb_
 614       --include GObject-2.0
 615       --pkg-export=harfbuzz
 616       --cflags-begin
 617       -I${PROJECT_SOURCE_DIR}/src
 618       -I${PROJECT_BINARY_DIR}/src
 619       ${hb_includedir_cflags}
 620       ${hb_defines_cflags}
 621       -DHB_H
 622       -DHB_H_IN
 623       -DHB_OT_H
 624       -DHB_OT_H_IN
 625       -DHB_AAT_H
 626       -DHB_AAT_H_IN
 627       -DHB_GOBJECT_H
 628       -DHB_GOBJECT_H_IN
 629       -DHB_EXTERN=
 630       --cflags-end
 631       --library=harfbuzz-gobject
 632       --library=harfbuzz
 633       -L${hb_libpath}
 634       ${extra_libs}
 635       --filelist ${CMAKE_CURRENT_BINARY_DIR}/src/hb_gir_list
 636       -o ${hb_libpath}/HarfBuzz-0.0.gir
 637     DEPENDS harfbuzz-gobject harfbuzz ${CMAKE_CURRENT_BINARY_DIR}/src/hb_gir_list
 638   )
 639
 640   add_custom_command(
 641     TARGET harfbuzz-gobject
 642     POST_BUILD
 643     COMMAND "${G_IR_COMPILER}"
 644       --verbose --debug
 645       --includedir ${CMAKE_CURRENT_BINARY_DIR}
 646       ${hb_libpath}/HarfBuzz-0.0.gir
 647       -o ${hb_libpath}/HarfBuzz-0.0.typelib
 648     DEPENDS ${hb_libpath}/HarfBuzz-0.0.gir harfbuzz-gobject
 649   )
 650 endif ()
 651
 652
 653 ## Additional framework build configs
 654 if (BUILD_FRAMEWORK)
 655   set (CMAKE_MACOSX_RPATH ON)
 656   set_target_properties(harfbuzz PROPERTIES
 657     FRAMEWORK TRUE
 658     PUBLIC_HEADER "${project_headers}"
 659     XCODE_ATTRIBUTE_INSTALL_PATH "@rpath"
 660   )
 661   set (MACOSX_FRAMEWORK_IDENTIFIER "harfbuzz")
 662   set (MACOSX_FRAMEWORK_SHORT_VERSION_STRING "${HB_VERSION}")
 663   set (MACOSX_FRAMEWORK_BUNDLE_VERSION "${HB_VERSION}")
 664 endif ()
 665
 666
 667 ## Additional harfbuzz build artifacts
 668 if (HB_BUILD_UTILS)
 669   # https://github.com/WebKit/webkit/blob/master/Source/cmake/FindCairo.cmake
 670   find_package(PkgConfig)
 671   pkg_check_modules(PC_CAIRO QUIET cairo)
 672
 673   find_path(CAIRO_INCLUDE_DIRS NAMES cairo.h HINTS ${PC_CAIRO_INCLUDEDIR} ${PC_CAIRO_INCLUDE_DIRS} PATH_SUFFIXES cairo)
 674   find_library(CAIRO_LIBRARIESNAMES cairo HINTS ${PC_CAIRO_LIBDIR} ${PC_CAIRO_LIBRARY_DIRS})
 675
 676   add_definitions("-DPACKAGE_NAME=\"HarfBuzz\"")
 677   add_definitions("-DPACKAGE_VERSION=\"${HB_VERSION}\"")
 678   include_directories(${CAIRO_INCLUDE_DIRS})
 679
 680   add_executable(hb-view ${HB_VIEW_sources})
 681   target_link_libraries(hb-view harfbuzz ${CAIRO_LIBRARIESNAMES})
 682
 683   add_executable(hb-shape ${HB_SHAPE_sources})
 684   target_link_libraries(hb-shape harfbuzz)
 685
 686   add_executable(hb-subset ${HB_SUBSET_CLI_sources})
 687   target_link_libraries(hb-subset harfbuzz harfbuzz-subset)
 688
 689   add_executable(hb-ot-shape-closure ${HB_OT_SHAPE_CLOSURE_sources})
 690   target_link_libraries(hb-ot-shape-closure harfbuzz)
 691
 692   mark_as_advanced(CAIRO_INCLUDE_DIRS CAIRO_LIBRARIESNAMES)
 693 endif ()
 694
 695
 696 ## Install
 697 include (GNUInstallDirs)
 698
 699 if (NOT SKIP_INSTALL_HEADERS AND NOT SKIP_INSTALL_ALL)
 700   install(FILES ${project_headers} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/harfbuzz)
 701   if (HB_HAVE_GOBJECT)
 702     install(FILES ${hb_gobject_headers} ${hb_gobject_gen_headers} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/harfbuzz)
 703   endif ()
 704 endif ()
 705
 706 if (NOT SKIP_INSTALL_LIBRARIES AND NOT SKIP_INSTALL_ALL)
 707   install(TARGETS harfbuzz
 708     EXPORT harfbuzzConfig
 709     ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 710     LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 711     RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 712     FRAMEWORK DESTINATION Library/Frameworks
 713   )
 714   install(EXPORT harfbuzzConfig
 715       NAMESPACE harfbuzz::
 716       DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/harfbuzz
 717   )
 718   if (HB_BUILD_UTILS)
 719     if (WIN32 AND BUILD_SHARED_LIBS)
 720       install(TARGETS harfbuzz-subset
 721         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 722       )
 723     endif ()
 724     install(TARGETS hb-view
 725       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 726     )
 727     install(TARGETS hb-subset
 728       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 729     )
 730
 731     install(TARGETS hb-shape
 732       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 733     )
 734
 735     install(TARGETS hb-ot-shape-closure
 736       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 737     )
 738   endif ()
 739   if (HB_HAVE_GOBJECT)
 740     install(TARGETS harfbuzz-gobject
 741       ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 742       LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
 743       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 744     )
 745     if (HB_HAVE_INTROSPECTION)
 746       if ("${CMAKE_GENERATOR}" MATCHES "Visual Studio*")
 747         set (hb_libpath "${CMAKE_CURRENT_BINARY_DIR}/$<CONFIGURATION>")
 748       else ()
 749         set (hb_libpath "$<TARGET_FILE_DIR:harfbuzz-gobject>")
 750       endif ()
 751
 752       install(FILES "${hb_libpath}/HarfBuzz-0.0.gir"
 753         DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/gir-1.0
 754       )
 755
 756       install(FILES "${hb_libpath}/HarfBuzz-0.0.typelib"
 757         DESTINATION ${CMAKE_INSTALL_LIBDIR}/girepository-1.0
 758       )
 759     endif ()
 760   endif ()
 761 endif ()
 762
 763 if (HB_BUILD_TESTS)
 764   ## src/ executables
 765   foreach (prog main test test-gsub-would-substitute test-gpos-size-params test-buffer-serialize test-unicode-ranges) # hb-ot-tag
 766     set (prog_name ${prog})
 767     if (${prog_name} STREQUAL "test")
 768       # test can not be used as a valid executable name on cmake, lets special case it
 769       set (prog_name test-test)
 770     endif ()
 771     add_executable(${prog_name} ${PROJECT_SOURCE_DIR}/src/${prog}.cc)
 772     target_link_libraries(${prog_name} harfbuzz ${THIRD_PARTY_LIBS})
 773   endforeach ()
 774   # set_target_properties(hb-ot-tag PROPERTIES COMPILE_FLAGS "-DMAIN")
 775
 776   ## Tests
 777   if (UNIX OR MINGW)
 778     if (BUILD_SHARED_LIBS)
 779       # generate harfbuzz.def after build completion
 780       add_custom_command(TARGET harfbuzz POST_BUILD
 781         COMMAND "${PYTHON_EXECUTABLE}" ${PROJECT_SOURCE_DIR}/src/gen-def.py ${PROJECT_BINARY_DIR}/harfbuzz.def ${project_headers}
 782         WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}/src)
 783
 784       add_test(NAME check-static-inits.sh
 785         COMMAND ${PROJECT_SOURCE_DIR}/src/check-static-inits.sh
 786         WORKING_DIRECTORY ${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/harfbuzz.dir/src # ugly hack
 787       )
 788       add_test(NAME check-libstdc++.sh COMMAND ${PROJECT_SOURCE_DIR}/src/check-libstdc++.sh)
 789       add_test(NAME check-symbols.sh COMMAND ${PROJECT_SOURCE_DIR}/src/check-symbols.sh)
 790
 791       set_tests_properties(
 792         check-static-inits.sh check-libstdc++.sh check-symbols.sh
 793         PROPERTIES
 794           ENVIRONMENT "libs=.;srcdir=${PROJECT_SOURCE_DIR}/src"
 795           SKIP_RETURN_CODE 77)
 796     endif ()
 797
 798     add_test(NAME check-c-linkage-decls.sh COMMAND ./check-c-linkage-decls.sh)
 799     add_test(NAME check-header-guards.sh COMMAND ./check-header-guards.sh)
 800     add_test(NAME check-externs.sh COMMAND ./check-externs.sh)
 801     add_test(NAME check-includes.sh COMMAND ./check-includes.sh)
 802     set_tests_properties(
 803       check-c-linkage-decls.sh check-header-guards.sh check-externs.sh check-includes.sh
 804       PROPERTIES
 805         WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}/src
 806         SKIP_RETURN_CODE 77)
 807   endif ()
 808
 809   # Needs to come last so that variables defined above are passed to
 810   # subdirectories.
 811   add_subdirectory(test)
 812 endif ()