CMakeLists.txt

   1 # ~~~
   2 # Copyright (c) 2014-2018 Valve Corporation
   3 # Copyright (c) 2014-2018 LunarG, Inc.
   4 #
   5 # Licensed under the Apache License, Version 2.0 (the "License");
   6 # you may not use this file except in compliance with the License.
   7 # You may obtain a copy of the License at
   8 #
   9 #     http://www.apache.org/licenses/LICENSE-2.0
  10 #
  11 # Unless required by applicable law or agreed to in writing, software
  12 # distributed under the License is distributed on an "AS IS" BASIS,
  13 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  14 # See the License for the specific language governing permissions and
  15 # limitations under the License.
  16 # ~~~
  17
  18 # CMake project initialization ---------------------------------------------------------------------------------------------------
  19 # This section contains pre-project() initialization, and ends with the project() command.
  20
  21 cmake_minimum_required(VERSION 3.4)
  22
  23 # Apple: Must be set before enable_language() or project() as it may influence configuration of the toolchain and flags.
  24 set(CMAKE_OSX_DEPLOYMENT_TARGET "10.12" CACHE STRING "Minimum OS X deployment version")
  25
  26 project(Vulkan-Tools)
  27
  28 # find_package(), include() and global project settings --------------------------------------------------------------------------
  29
  30 find_package(PythonInterp 3 REQUIRED)
  31
  32 # User-interface declarations ----------------------------------------------------------------------------------------------------
  33 # This section contains variables that affect development GUIs (e.g. CMake GUI and IDEs), such as option(), folders, and variables
  34 # with the CACHE property.
  35
  36 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  37
  38 option(BUILD_CUBE "Build cube" ON)
  39 option(BUILD_VULKANINFO "Build vulkaninfo" ON)
  40 option(BUILD_ICD "Build icd" ON)
  41 # Installing the Mock ICD to system directories is probably not desired since this ICD is not a very complete implementation.
  42 # Require the user to ask that it be installed if they really want it.
  43 option(INSTALL_ICD "Install icd" OFF)
  44
  45 # Enable IDE GUI folders
  46 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  47 # "Helper" targets that don't have interesting source code should set their FOLDER property to this
  48 set(TOOLS_HELPER_FOLDER "Helper Targets")
  49
  50 option(USE_CCACHE "Use ccache" OFF)
  51 if(USE_CCACHE)
  52     find_program(CCACHE_FOUND ccache)
  53     if(CCACHE_FOUND)
  54         set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
  55     endif()
  56 endif()
  57
  58 # ~~~
  59 # Find Vulkan Headers and Loader
  60 # Search order:
  61 #  User-supplied CMAKE_PREFIX_PATH containing paths to the header and/or loader install dirs
  62 #  CMake options VULKAN_HEADERS_INSTALL_DIR and/or VULKAN_LOADER_INSTALL_DIR
  63 #  Env vars VULKAN_HEADERS_INSTALL_DIR and/or VULKAN_LOADER_INSTALL_DIR
  64 #  If on MacOS
  65 #   CMake option MOTLENVK_REPO_ROOT
  66 #   Env vars MOLTENVK_REPO_ROOT
  67 #  Fallback to FindVulkan operation using SDK install or system installed components.
  68 # ~~~
  69 set(VULKAN_HEADERS_INSTALL_DIR "HEADERS-NOTFOUND" CACHE PATH "Absolute path to a Vulkan-Headers install directory")
  70 set(VULKAN_LOADER_INSTALL_DIR "LOADER-NOTFOUND" CACHE PATH "Absolute path to a Vulkan-Loader install directory")
  71 set(CMAKE_PREFIX_PATH ${CMAKE_PREFIX_PATH};${VULKAN_HEADERS_INSTALL_DIR};${VULKAN_LOADER_INSTALL_DIR};
  72     $ENV{VULKAN_HEADERS_INSTALL_DIR};$ENV{VULKAN_LOADER_INSTALL_DIR})
  73
  74 if(APPLE)
  75     set(MOLTENVK_REPO_ROOT "MOLTENVK-NOTFOUND" CACHE PATH "Absolute path to a MoltenVK repo directory")
  76     if(NOT MOLTENVK_REPO_ROOT AND NOT DEFINED ENV{MOLTENVK_REPO_ROOT})
  77         message(FATAL_ERROR "Must define location of MoltenVK repo -- see BUILD.md")
  78     endif()
  79
  80     if(NOT MOLTENVK_REPO_ROOT)
  81         set(MOLTENVK_REPO_ROOT $ENV{MOLTENVK_REPO_ROOT})
  82     endif()
  83     message(STATUS "Using MoltenVK repo location at ${MOLTENVK_REPO_ROOT}")
  84 endif()
  85 message(STATUS "Using find_package to locate Vulkan")
  86 find_package(Vulkan)
  87 find_package(VulkanHeaders)
  88 get_filename_component(Vulkan_LIBRARY_DIR ${Vulkan_LIBRARY} DIRECTORY)
  89 message(STATUS "Vulkan FOUND = ${Vulkan_FOUND}")
  90 message(STATUS "Vulkan Lib Dir = ${Vulkan_LIBRARY_DIR}")
  91 message(STATUS "Vulkan Lib = ${Vulkan_LIBRARY}")
  92 message(STATUS "Vulkan Headers Include = ${VulkanHeaders_INCLUDE_DIR}")
  93 message(STATUS "Vulkan Headers Registry = ${VulkanRegistry_DIR}")
  94
  95 include(GNUInstallDirs)
  96
  97 if(WIN32 AND CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
  98     # Windows: if install locations not set by user, set install prefix to "<build_dir>\install".
  99     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "default install path" FORCE)
 100 endif()
 101
 102 # uninstall target
 103 if(NOT TARGET uninstall)
 104     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 105                    "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 106                    IMMEDIATE
 107                    @ONLY)
 108
 109     add_custom_target(uninstall COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)
 110     set_target_properties(uninstall PROPERTIES FOLDER ${TOOLS_HELPER_FOLDER})
 111 endif()
 112
 113 if(APPLE)
 114     # CMake versions 3 or later need CMAKE_MACOSX_RPATH defined. This avoids the CMP0042 policy message.
 115     set(CMAKE_MACOSX_RPATH 1)
 116 endif()
 117
 118 if(CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Clang")
 119     set(COMMON_COMPILE_FLAGS "-Wall -Wextra -Wno-unused-parameter -Wno-missing-field-initializers")
 120     set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -fno-strict-aliasing -fno-builtin-memcmp")
 121
 122     # For GCC version 7.1 or greater, we need to disable the implicit fallthrough warning since there's no consistent way to satisfy
 123     # all compilers until they all accept the C++17 standard
 124     if(CMAKE_COMPILER_IS_GNUCC AND NOT (CMAKE_CXX_COMPILER_VERSION LESS 7.1))
 125         set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -Wimplicit-fallthrough=0")
 126     endif()
 127
 128     if(APPLE)
 129         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${COMMON_COMPILE_FLAGS}")
 130     else()
 131         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=c99 ${COMMON_COMPILE_FLAGS}")
 132     endif()
 133     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${COMMON_COMPILE_FLAGS} -std=c++11 -fno-rtti")
 134     if(UNIX)
 135         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden")
 136         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")
 137     endif()
 138 endif()
 139
 140 if(APPLE)
 141     include(mac_common.cmake)
 142 endif()
 143
 144 if(BUILD_CUBE)
 145     add_subdirectory(cube)
 146 endif()
 147
 148 if(BUILD_VULKANINFO)
 149     add_subdirectory(vulkaninfo)
 150 endif()
 151
 152 if(BUILD_ICD)
 153     add_subdirectory(icd)
 154 endif()