CMakeLists.txt

   1 # Copyright (C) 2020 The Khronos Group Inc.
   2 #
   3 # All rights reserved.
   4 #
   5 # Redistribution and use in source and binary forms, with or without
   6 # modification, are permitted provided that the following conditions
   7 # are met:
   8 #
   9 #    Redistributions of source code must retain the above copyright
  10 #    notice, this list of conditions and the following disclaimer.
  11 #
  12 #    Redistributions in binary form must reproduce the above
  13 #    copyright notice, this list of conditions and the following
  14 #    disclaimer in the documentation and/or other materials provided
  15 #    with the distribution.
  16 #
  17 #    Neither the name of The Khronos Group Inc. nor the names of its
  18 #    contributors may be used to endorse or promote products derived
  19 #    from this software without specific prior written permission.
  20 #
  21 # THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  22 # "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  23 # LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
  24 # FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
  25 # COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
  26 # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
  27 # BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  28 # LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER
  29 # CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30 # LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
  31 # ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  32 # POSSIBILITY OF SUCH DAMAGE.
  33
  34 # increase to 3.1 once all major distributions
  35 # include a version of CMake >= 3.1
  36 cmake_minimum_required(VERSION 2.8.12)
  37 if (POLICY CMP0048)
  38   cmake_policy(SET CMP0048 NEW)
  39 endif()
  40 if(POLICY CMP0054)
  41   cmake_policy(SET CMP0054 NEW)
  42 endif()
  43
  44 project(glslang LANGUAGES CXX)
  45
  46 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  47
  48 # Enable compile commands database
  49 set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
  50
  51 # Adhere to GNU filesystem layout conventions
  52 include(GNUInstallDirs)
  53
  54 # Needed for CMAKE_DEPENDENT_OPTION macro
  55 include(CMakeDependentOption)
  56
  57 option(BUILD_SHARED_LIBS "Build Shared Libraries" OFF)
  58 option(BUILD_EXTERNAL "Build external dependencies in /External" ON)
  59
  60 set(LIB_TYPE STATIC)
  61
  62 if(BUILD_SHARED_LIBS)
  63     set(LIB_TYPE SHARED)
  64 endif()
  65
  66 if ("${CMAKE_BUILD_TYPE}" STREQUAL "")
  67     # This logic inside SPIRV-Tools, which can upset build target dependencies
  68     # if changed after targets are already defined. To prevent these issues,
  69     # ensure CMAKE_BUILD_TYPE is assigned early and at the glslang root scope.
  70     message(STATUS "No build type selected, default to Debug")
  71     set(CMAKE_BUILD_TYPE "Debug")
  72 endif()
  73
  74 option(SKIP_GLSLANG_INSTALL "Skip installation" ${SKIP_GLSLANG_INSTALL})
  75 if(NOT ${SKIP_GLSLANG_INSTALL})
  76   set(ENABLE_GLSLANG_INSTALL ON)
  77 endif()
  78 option(ENABLE_SPVREMAPPER "Enables building of SPVRemapper" ON)
  79
  80 option(ENABLE_GLSLANG_BINARIES "Builds glslangValidator and spirv-remap" ON)
  81
  82 option(ENABLE_GLSLANG_JS
  83     "If using Emscripten, build glslang.js. Otherwise, builds a sample executable for binary-size testing." OFF)
  84 CMAKE_DEPENDENT_OPTION(ENABLE_GLSLANG_WEBMIN
  85     "Reduces glslang to minimum needed for web use"
  86     OFF "ENABLE_GLSLANG_JS"
  87     OFF)
  88 CMAKE_DEPENDENT_OPTION(ENABLE_GLSLANG_WEBMIN_DEVEL
  89     "For ENABLE_GLSLANG_WEBMIN builds, enables compilation error messages"
  90     OFF "ENABLE_GLSLANG_WEBMIN"
  91     OFF)
  92 CMAKE_DEPENDENT_OPTION(ENABLE_EMSCRIPTEN_SINGLE_FILE
  93     "If using Emscripten, enables SINGLE_FILE build"
  94     OFF "ENABLE_GLSLANG_JS AND EMSCRIPTEN"
  95     OFF)
  96 CMAKE_DEPENDENT_OPTION(ENABLE_EMSCRIPTEN_ENVIRONMENT_NODE
  97     "If using Emscripten, builds to run on Node instead of Web"
  98     OFF "ENABLE_GLSLANG_JS AND EMSCRIPTEN"
  99     OFF)
 100
 101 CMAKE_DEPENDENT_OPTION(ENABLE_HLSL
 102     "Enables HLSL input support"
 103     ON "NOT ENABLE_GLSLANG_WEBMIN"
 104     OFF)
 105
 106 option(ENABLE_RTTI "Enables RTTI" OFF)
 107 option(ENABLE_EXCEPTIONS "Enables Exceptions" OFF)
 108 option(ENABLE_OPT "Enables spirv-opt capability if present" ON)
 109
 110 if(MINGW OR (CMAKE_SYSTEM_NAME STREQUAL "Darwin" AND ${CMAKE_CXX_COMPILER_ID} MATCHES "GNU"))
 111     # Workaround for CMake behavior on Mac OS with gcc, cmake generates -Xarch_* arguments
 112     # which gcc rejects
 113     option(ENABLE_PCH "Enables Precompiled header" OFF)
 114 else()
 115     option(ENABLE_PCH "Enables Precompiled header" ON)
 116 endif()
 117 option(ENABLE_CTEST "Enables testing" ON)
 118
 119 if(ENABLE_GLSLANG_INSTALL AND CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT AND WIN32)
 120     set(CMAKE_INSTALL_PREFIX "install" CACHE STRING "..." FORCE)
 121 endif()
 122
 123 option(USE_CCACHE "Use ccache" OFF)
 124 if(USE_CCACHE)
 125     find_program(CCACHE_FOUND ccache)
 126     if(CCACHE_FOUND)
 127         set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
 128     endif()
 129 endif()
 130
 131 if(ENABLE_CTEST)
 132     include(CTest)
 133 endif()
 134
 135 if(ENABLE_HLSL)
 136     add_definitions(-DENABLE_HLSL)
 137 endif()
 138
 139 if(ENABLE_GLSLANG_WEBMIN)
 140     add_definitions(-DGLSLANG_WEB)
 141     if(ENABLE_GLSLANG_WEBMIN_DEVEL)
 142         add_definitions(-DGLSLANG_WEB_DEVEL)
 143     endif()
 144 endif()
 145
 146 if(WIN32)
 147     set(CMAKE_DEBUG_POSTFIX "d")
 148     option(OVERRIDE_MSVCCRT "Overrides runtime of MSVC " ON)
 149     if(MSVC AND OVERRIDE_MSVCCRT)
 150         include(ChooseMSVCCRT.cmake)
 151     endif()
 152     add_definitions(-DGLSLANG_OSINCLUDE_WIN32)
 153 elseif(UNIX)
 154     add_definitions(-DGLSLANG_OSINCLUDE_UNIX)
 155 else()
 156     message("unknown platform")
 157 endif()
 158
 159 if(${CMAKE_CXX_COMPILER_ID} MATCHES "GNU")
 160     add_compile_options(-Wall -Wmaybe-uninitialized -Wuninitialized -Wunused -Wunused-local-typedefs
 161                         -Wunused-parameter -Wunused-value  -Wunused-variable -Wunused-but-set-parameter -Wunused-but-set-variable -fno-exceptions)
 162     add_compile_options(-Wno-reorder)  # disable this from -Wall, since it happens all over.
 163     if(NOT ENABLE_RTTI)
 164         add_compile_options(-fno-rtti)
 165     endif()
 166     if(NOT ENABLE_EXCEPTIONS)
 167         add_compile_options(-fno-exceptions)
 168     endif()
 169     if(NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS "9.0.0")
 170         add_compile_options(-Werror=deprecated-copy)
 171     endif()
 172
 173     if(NOT CMAKE_VERSION VERSION_LESS "3.13" AND NOT CMAKE_SYSTEM_NAME STREQUAL "Darwin")
 174         # Error if there's symbols that are not found at link time.
 175         # add_link_options() was added in CMake 3.13 - if using an earlier
 176         # version don't set this - it should be caught by presubmits anyway.
 177         add_link_options("-Wl,--no-undefined")
 178     endif()
 179 elseif(${CMAKE_CXX_COMPILER_ID} MATCHES "Clang" AND NOT MSVC)
 180     add_compile_options(-Wall -Wuninitialized -Wunused -Wunused-local-typedefs
 181                         -Wunused-parameter -Wunused-value  -Wunused-variable)
 182     add_compile_options(-Wno-reorder)  # disable this from -Wall, since it happens all over.
 183     if(NOT ENABLE_RTTI)
 184         add_compile_options(-fno-rtti)
 185     endif()
 186     if(NOT ENABLE_EXCEPTIONS)
 187         add_compile_options(-fno-exceptions)
 188     endif()
 189
 190     if(NOT CMAKE_VERSION VERSION_LESS "3.13")
 191         # Error if there's symbols that are not found at link time.
 192         # add_link_options() was added in CMake 3.13 - if using an earlier
 193         # version don't set this - it should be caught by presubmits anyway.
 194         add_link_options("-Wl,-undefined,error")
 195     endif()
 196 elseif(MSVC)
 197     if(NOT ENABLE_RTTI)
 198         string(FIND "${CMAKE_CXX_FLAGS}" "/GR" MSVC_HAS_GR)
 199         if(MSVC_HAS_GR)
 200             string(REGEX REPLACE "/GR" "/GR-" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
 201         else()
 202             add_compile_options(/GR-) # Disable RTTI
 203         endif()
 204     endif()
 205     if(ENABLE_EXCEPTIONS)
 206         add_compile_options(/EHsc) # Enable Exceptions
 207         else()
 208         string(REGEX REPLACE "/EHsc" "" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}") # Try to remove default /EHsc cxx_flag
 209         add_compile_options(/D_HAS_EXCEPTIONS=0)
 210     endif()
 211 endif()
 212
 213 if(ENABLE_GLSLANG_JS)
 214     if(MSVC)
 215         add_compile_options(/Os /GR-)
 216     else()
 217         add_compile_options(-Os -fno-rtti -fno-exceptions)
 218         if(${CMAKE_CXX_COMPILER_ID} MATCHES "Clang" AND NOT MSVC)
 219             add_compile_options(-Wno-unused-parameter)
 220             add_compile_options(-Wno-unused-variable -Wno-unused-const-variable)
 221         endif()
 222     endif()
 223 endif()
 224
 225 # Request C++11
 226 if(${CMAKE_VERSION} VERSION_LESS 3.1)
 227     # CMake versions before 3.1 do not understand CMAKE_CXX_STANDARD
 228     # remove this block once CMake >=3.1 has fixated in the ecosystem
 229     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
 230 else()
 231     set(CMAKE_CXX_STANDARD 11)
 232     set(CMAKE_CXX_STANDARD_REQUIRED ON)
 233     set(CMAKE_CXX_EXTENSIONS OFF)
 234 endif()
 235
 236 function(glslang_set_link_args TARGET)
 237     # For MinGW compiles, statically link against the GCC and C++ runtimes.
 238     # This avoids the need to ship those runtimes as DLLs.
 239     if(WIN32 AND ${CMAKE_CXX_COMPILER_ID} MATCHES "GNU")
 240         set_target_properties(${TARGET} PROPERTIES
 241                               LINK_FLAGS "-static -static-libgcc -static-libstdc++")
 242     endif()
 243 endfunction(glslang_set_link_args)
 244
 245 if(NOT COMMAND find_host_package)
 246     macro(find_host_package)
 247         find_package(${ARGN})
 248     endmacro()
 249 endif()
 250
 251 # Root directory for build-time generated include files
 252 set(GLSLANG_GENERATED_INCLUDEDIR "${CMAKE_BINARY_DIR}/include")
 253
 254 ################################################################################
 255 # Build version information generation
 256 ################################################################################
 257 include(parse_version.cmake)
 258 set(GLSLANG_CHANGES_FILE      "${CMAKE_CURRENT_SOURCE_DIR}/CHANGES.md")
 259 set(GLSLANG_BUILD_INFO_H_TMPL "${CMAKE_CURRENT_SOURCE_DIR}/build_info.h.tmpl")
 260 set(GLSLANG_BUILD_INFO_H      "${GLSLANG_GENERATED_INCLUDEDIR}/glslang/build_info.h")
 261
 262 parse_version(${GLSLANG_CHANGES_FILE} GLSLANG)
 263
 264 function(configurate_version)
 265     set(major ${GLSLANG_VERSION_MAJOR})
 266     set(minor ${GLSLANG_VERSION_MINOR})
 267     set(patch ${GLSLANG_VERSION_PATCH})
 268     set(flavor ${GLSLANG_VERSION_FLAVOR})
 269     configure_file(${GLSLANG_BUILD_INFO_H_TMPL} ${GLSLANG_BUILD_INFO_H} @ONLY)
 270 endfunction()
 271
 272 configurate_version()
 273
 274 # glslang_add_build_info_dependency() adds the glslang-build-info dependency and
 275 # generated include directories to target.
 276 function(glslang_add_build_info_dependency target)
 277     target_include_directories(${target} PUBLIC $<BUILD_INTERFACE:${GLSLANG_GENERATED_INCLUDEDIR}>)
 278 endfunction()
 279
 280 # glslang_only_export_explicit_symbols() makes the symbol visibility hidden by
 281 # default for <target> when building shared libraries, and sets the
 282 # GLSLANG_IS_SHARED_LIBRARY define, and GLSLANG_EXPORTING to 1 when specifically
 283 # building <target>.
 284 function(glslang_only_export_explicit_symbols target)
 285     if(BUILD_SHARED_LIBS)
 286         target_compile_definitions(${target} PUBLIC "GLSLANG_IS_SHARED_LIBRARY=1")
 287         if(WIN32)
 288             target_compile_definitions(${target} PRIVATE "GLSLANG_EXPORTING=1")
 289         else()
 290             target_compile_options(${target} PRIVATE "-fvisibility=hidden")
 291         endif()
 292     endif()
 293 endfunction()
 294
 295 # glslang_pch() adds precompiled header rules to <target> for the pre-compiled
 296 # header file <pch>. As target_precompile_headers() was added in CMake 3.16,
 297 # this is a no-op if called on earlier versions of CMake.
 298 if(NOT CMAKE_VERSION VERSION_LESS "3.16" AND ENABLE_PCH)
 299     function(glslang_pch target pch)
 300         target_precompile_headers(${target} PRIVATE ${pch})
 301     endfunction()
 302 else()
 303     function(glslang_pch target pch)
 304     endfunction()
 305     if(ENABLE_PCH)
 306         message("Your CMake version is ${CMAKE_VERSION}. Update to at least 3.16 to enable precompiled headers to speed up incremental builds")
 307     endif()
 308 endif()
 309
 310 if(BUILD_EXTERNAL AND IS_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/External)
 311     find_host_package(PythonInterp 3 REQUIRED)
 312
 313     # We depend on these for later projects, so they should come first.
 314     add_subdirectory(External)
 315 endif()
 316
 317 if(NOT TARGET SPIRV-Tools-opt)
 318     set(ENABLE_OPT OFF)
 319 endif()
 320
 321 if(ENABLE_OPT)
 322     message(STATUS "optimizer enabled")
 323     add_definitions(-DENABLE_OPT=1)
 324 else()
 325     if(ENABLE_HLSL)
 326         message(STATUS "spirv-tools not linked - illegal SPIRV may be generated for HLSL")
 327     endif()
 328     add_definitions(-DENABLE_OPT=0)
 329 endif()
 330
 331 add_subdirectory(glslang)
 332 add_subdirectory(OGLCompilersDLL)
 333 if(ENABLE_GLSLANG_BINARIES)
 334     add_subdirectory(StandAlone)
 335 endif()
 336 add_subdirectory(SPIRV)
 337 if(ENABLE_HLSL)
 338     add_subdirectory(hlsl)
 339 endif()
 340 if(ENABLE_CTEST)
 341     add_subdirectory(gtests)
 342 endif()
 343
 344 if(ENABLE_CTEST AND BUILD_TESTING)
 345     # glslang-testsuite runs a bash script on Windows.
 346     # Make sure to use '-o igncr' flag to ignore carriage returns (\r).
 347     set(IGNORE_CR_FLAG "")
 348     if(WIN32)
 349         set(IGNORE_CR_FLAG -o igncr)
 350     endif()
 351
 352     if (CMAKE_CONFIGURATION_TYPES)
 353         set(RESULTS_PATH ${CMAKE_CURRENT_BINARY_DIR}/$<CONFIGURATION>/localResults)
 354         set(VALIDATOR_PATH ${CMAKE_CURRENT_BINARY_DIR}/StandAlone/$<CONFIGURATION>/glslangValidator)
 355         set(REMAP_PATH ${CMAKE_CURRENT_BINARY_DIR}/StandAlone/$<CONFIGURATION>/spirv-remap)
 356     else()
 357         set(RESULTS_PATH ${CMAKE_CURRENT_BINARY_DIR}/localResults)
 358         set(VALIDATOR_PATH ${CMAKE_CURRENT_BINARY_DIR}/StandAlone/glslangValidator)
 359         set(REMAP_PATH ${CMAKE_CURRENT_BINARY_DIR}/StandAlone/spirv-remap)
 360     endif()
 361
 362     add_test(NAME glslang-testsuite
 363         COMMAND bash ${IGNORE_CR_FLAG} runtests ${RESULTS_PATH} ${VALIDATOR_PATH} ${REMAP_PATH}
 364         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/Test/)
 365 endif()