CMakeLists.txt

   1 ##
   2 ## Author: Hank Anderson <hank@statease.com>
   3 ##
   4
   5 cmake_minimum_required(VERSION 2.8.5)
   6 project(OpenBLAS C ASM)
   7 set(OpenBLAS_MAJOR_VERSION 0)
   8 set(OpenBLAS_MINOR_VERSION 3)
   9 set(OpenBLAS_PATCH_VERSION 6.dev)
  10 set(OpenBLAS_VERSION "${OpenBLAS_MAJOR_VERSION}.${OpenBLAS_MINOR_VERSION}.${OpenBLAS_PATCH_VERSION}")
  11
  12 # Adhere to GNU filesystem layout conventions
  13 include(GNUInstallDirs)
  14
  15 include(CMakePackageConfigHelpers)
  16
  17
  18 #######
  19 if(MSVC)
  20 option(BUILD_WITHOUT_LAPACK "Do not build LAPACK and LAPACKE (Only BLAS or CBLAS)" ON)
  21 endif()
  22 option(BUILD_WITHOUT_CBLAS "Do not build the C interface (CBLAS) to the BLAS functions" OFF)
  23 option(DYNAMIC_ARCH "Include support for multiple CPU targets, with automatic selection at runtime (x86/x86_64 only)" OFF)
  24 option(DYNAMIC_OLDER "Include specific support for older cpu models (Penryn,Dunnington,Atom,Nano,Opteron) with DYNAMIC_ARCH" OFF)
  25 option(BUILD_RELAPACK "Build with ReLAPACK (recursive implementation of several LAPACK functions on top of standard LAPACK)" OFF)
  26
  27 # Add a prefix or suffix to all exported symbol names in the shared library.
  28 # Avoids conflicts with other BLAS libraries, especially when using
  29 # 64 bit integer interfaces in OpenBLAS.
  30
  31 set(SYMBOLPREFIX "" CACHE STRING  "Add a prefix to all exported symbol names in the shared library to avoid conflicts with other BLAS libraries" )
  32 set(SYMBOLSUFFIX "" CACHE STRING  "Add a suffix to all exported symbol names in the shared library, e.g. _64 for INTERFACE64 builds" )
  33 #######
  34 if(BUILD_WITHOUT_LAPACK)
  35 set(NO_LAPACK 1)
  36 set(NO_LAPACKE 1)
  37 endif()
  38
  39 if(BUILD_WITHOUT_CBLAS)
  40 set(NO_CBLAS 1)
  41 endif()
  42
  43 #######
  44
  45 if(MSVC AND MSVC_STATIC_CRT)
  46     set(CompilerFlags
  47             CMAKE_CXX_FLAGS
  48             CMAKE_CXX_FLAGS_DEBUG
  49             CMAKE_CXX_FLAGS_RELEASE
  50             CMAKE_C_FLAGS
  51             CMAKE_C_FLAGS_DEBUG
  52             CMAKE_C_FLAGS_RELEASE
  53             )
  54     foreach(CompilerFlag ${CompilerFlags})
  55       string(REPLACE "/MD" "/MT" ${CompilerFlag} "${${CompilerFlag}}")
  56     endforeach()
  57 endif()
  58
  59 message(WARNING "CMake support is experimental. It does not yet support all build options and may not produce the same Makefiles that OpenBLAS ships with.")
  60
  61 include("${PROJECT_SOURCE_DIR}/cmake/utils.cmake")
  62 include("${PROJECT_SOURCE_DIR}/cmake/system.cmake")
  63
  64 set(OpenBLAS_LIBNAME openblas${SUFFIX64_UNDERSCORE})
  65
  66 set(BLASDIRS interface driver/level2 driver/level3 driver/others)
  67
  68 if (NOT DYNAMIC_ARCH)
  69   list(APPEND BLASDIRS kernel)
  70 endif ()
  71
  72 if (DEFINED SANITY_CHECK)
  73   list(APPEND BLASDIRS reference)
  74 endif ()
  75
  76 set(SUBDIRS     ${BLASDIRS})
  77 if (NOT NO_LAPACK)
  78   if(BUILD_RELAPACK)
  79     list(APPEND SUBDIRS relapack/src)
  80   endif()
  81   list(APPEND SUBDIRS lapack)
  82 endif ()
  83
  84 # set which float types we want to build for
  85 if (NOT DEFINED BUILD_SINGLE AND NOT DEFINED BUILD_DOUBLE AND NOT DEFINED BUILD_COMPLEX AND NOT DEFINED BUILD_COMPLEX16)
  86   # if none are defined, build for all
  87   set(BUILD_SINGLE true)
  88   set(BUILD_DOUBLE true)
  89   set(BUILD_COMPLEX true)
  90   set(BUILD_COMPLEX16 true)
  91 endif ()
  92
  93 if (NOT DEFINED BUILD_MATGEN)
  94   set(BUILD_MATGEN true)
  95 endif()
  96
  97 set(FLOAT_TYPES "")
  98 if (BUILD_SINGLE)
  99   message(STATUS "Building Single Precision")
 100   list(APPEND FLOAT_TYPES "SINGLE") # defines nothing
 101 endif ()
 102
 103 if (BUILD_DOUBLE)
 104   message(STATUS "Building Double Precision")
 105   list(APPEND FLOAT_TYPES "DOUBLE") # defines DOUBLE
 106 endif ()
 107
 108 if (BUILD_COMPLEX)
 109   message(STATUS "Building Complex Precision")
 110   list(APPEND FLOAT_TYPES "COMPLEX") # defines COMPLEX
 111 endif ()
 112
 113 if (BUILD_COMPLEX16)
 114   message(STATUS "Building Double Complex Precision")
 115   list(APPEND FLOAT_TYPES "ZCOMPLEX") # defines COMPLEX and DOUBLE
 116 endif ()
 117
 118 if (NOT DEFINED CORE OR "${CORE}" STREQUAL "UNKNOWN")
 119   message(FATAL_ERROR "Detecting CPU failed. Please set TARGET explicitly, e.g. make TARGET=your_cpu_target. Please read README for details.")
 120 endif ()
 121
 122 #Set default output directory
 123 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
 124 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
 125 if(MSVC)
 126 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG ${PROJECT_BINARY_DIR}/lib/Debug)
 127 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELEASE ${PROJECT_BINARY_DIR}/lib/Release)
 128 endif ()
 129 # get obj vars into format that add_library likes: $<TARGET_OBJS:objlib> (see http://www.cmake.org/cmake/help/v3.0/command/add_library.html)
 130 set(TARGET_OBJS "")
 131 foreach (SUBDIR ${SUBDIRS})
 132   add_subdirectory(${SUBDIR})
 133   string(REPLACE "/" "_" subdir_obj ${SUBDIR})
 134   list(APPEND TARGET_OBJS "$<TARGET_OBJECTS:${subdir_obj}>")
 135 endforeach ()
 136
 137 # netlib:
 138
 139 # Can't just use lapack-netlib's CMake files, since they are set up to search for BLAS, build and install a binary. We just want to build a couple of lib files out of lapack and lapacke.
 140 # Not using add_subdirectory here because lapack-netlib already has its own CMakeLists.txt. Instead include a cmake script with the sources we want.
 141 if (NOT NOFORTRAN AND NOT NO_LAPACK)
 142   include("${PROJECT_SOURCE_DIR}/cmake/lapack.cmake")
 143   if (NOT NO_LAPACKE)
 144     include("${PROJECT_SOURCE_DIR}/cmake/lapacke.cmake")
 145   endif ()
 146 endif ()
 147
 148 # Only generate .def for dll on MSVC and always produce pdb files for debug and release
 149 if(MSVC)
 150   if (${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} VERSION_LESS 3.4)
 151     set(OpenBLAS_DEF_FILE "${PROJECT_BINARY_DIR}/openblas.def")
 152   endif()
 153   set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} /Zi")
 154   set(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE} /DEBUG /OPT:REF /OPT:ICF")
 155 endif()
 156
 157 if (${DYNAMIC_ARCH})
 158   add_subdirectory(kernel)
 159   foreach(TARGET_CORE ${DYNAMIC_CORE})
 160     message("${TARGET_CORE}")
 161     list(APPEND TARGET_OBJS "$<TARGET_OBJECTS:kernel_${TARGET_CORE}>")
 162   endforeach()
 163 endif ()
 164
 165 # add objects to the openblas lib
 166 add_library(${OpenBLAS_LIBNAME} ${LA_SOURCES} ${LAPACKE_SOURCES} ${RELA_SOURCES} ${TARGET_OBJS} ${OpenBLAS_DEF_FILE})
 167 target_include_directories(${OpenBLAS_LIBNAME} INTERFACE $<INSTALL_INTERFACE:include/openblas${SUFFIX64}>)
 168
 169 # Android needs to explicitly link against libm
 170 if(ANDROID)
 171   target_link_libraries(${OpenBLAS_LIBNAME} m)
 172 endif()
 173
 174 # Handle MSVC exports
 175 if(MSVC AND BUILD_SHARED_LIBS)
 176   if (${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} VERSION_LESS 3.4)
 177     include("${PROJECT_SOURCE_DIR}/cmake/export.cmake")
 178   else()
 179     # Creates verbose .def file (51KB vs 18KB)
 180     set_target_properties(${OpenBLAS_LIBNAME} PROPERTIES WINDOWS_EXPORT_ALL_SYMBOLS true)
 181   endif()
 182 endif()
 183
 184 # Set output for libopenblas
 185 set_target_properties( ${OpenBLAS_LIBNAME} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
 186 set_target_properties( ${OpenBLAS_LIBNAME} PROPERTIES LIBRARY_OUTPUT_NAME_DEBUG "${OpenBLAS_LIBNAME}_d")
 187 set_target_properties( ${OpenBLAS_LIBNAME} PROPERTIES EXPORT_NAME "OpenBLAS")
 188
 189 foreach (OUTPUTCONFIG ${CMAKE_CONFIGURATION_TYPES})
 190   string( TOUPPER ${OUTPUTCONFIG} OUTPUTCONFIG )
 191
 192   set_target_properties( ${OpenBLAS_LIBNAME} PROPERTIES RUNTIME_OUTPUT_DIRECTORY_${OUTPUTCONFIG} ${PROJECT_BINARY_DIR}/lib/${OUTPUTCONFIG} )
 193   set_target_properties( ${OpenBLAS_LIBNAME} PROPERTIES LIBRARY_OUTPUT_DIRECTORY_${OUTPUTCONFIG} ${PROJECT_BINARY_DIR}/lib/${OUTPUTCONFIG} )
 194   set_target_properties( ${OpenBLAS_LIBNAME} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY_${OUTPUTCONFIG} ${PROJECT_BINARY_DIR}/lib/${OUTPUTCONFIG} )
 195 endforeach()
 196
 197 enable_testing()
 198
 199 if (USE_THREAD)
 200   # Add threading library to linker
 201   find_package(Threads)
 202   if (THREADS_HAVE_PTHREAD_ARG)
 203     set_property(TARGET ${OpenBLAS_LIBNAME} PROPERTY COMPILE_OPTIONS "-pthread")
 204     set_property(TARGET ${OpenBLAS_LIBNAME} PROPERTY INTERFACE_COMPILE_OPTIONS "-pthread")
 205   endif()
 206   target_link_libraries(${OpenBLAS_LIBNAME} ${CMAKE_THREAD_LIBS_INIT})
 207 endif()
 208
 209 if (MSVC OR NOT NOFORTRAN)
 210   # Broken without fortran on unix
 211   add_subdirectory(utest)
 212 endif()
 213
 214 if (NOT MSVC AND NOT NOFORTRAN)
 215   # Build test and ctest
 216   add_subdirectory(test)
 217   if(NOT NO_CBLAS)
 218     add_subdirectory(ctest)
 219   endif()
 220 endif()
 221
 222 set_target_properties(${OpenBLAS_LIBNAME} PROPERTIES
 223   VERSION ${OpenBLAS_MAJOR_VERSION}.${OpenBLAS_MINOR_VERSION}
 224   SOVERSION ${OpenBLAS_MAJOR_VERSION}
 225 )
 226
 227 if (BUILD_SHARED_LIBS AND BUILD_RELAPACK)
 228   if (NOT MSVC)
 229     target_link_libraries(${OpenBLAS_LIBNAME} "-Wl,-allow-multiple-definition")
 230   else()
 231     target_link_libraries(${OpenBLAS_LIBNAME} "/FORCE:MULTIPLE")
 232   endif()
 233 endif()
 234
 235 if (BUILD_SHARED_LIBS AND NOT ${SYMBOLPREFIX}${SYMBOLSUFIX} STREQUAL "")
 236 if (NOT DEFINED ARCH)
 237   set(ARCH_IN "x86_64")
 238 else()
 239   set(ARCH_IN ${ARCH})
 240 endif()
 241
 242 if (${CORE} STREQUAL "generic")
 243   set(ARCH_IN "GENERIC")
 244 endif ()
 245
 246 if (NOT DEFINED EXPRECISION)
 247   set(EXPRECISION_IN 0)
 248 else()
 249   set(EXPRECISION_IN ${EXPRECISION})
 250 endif()
 251
 252 if (NOT DEFINED NO_CBLAS)
 253   set(NO_CBLAS_IN 0)
 254 else()
 255   set(NO_CBLAS_IN ${NO_CBLAS})
 256 endif()
 257
 258 if (NOT DEFINED NO_LAPACK)
 259   set(NO_LAPACK_IN 0)
 260 else()
 261   set(NO_LAPACK_IN ${NO_LAPACK})
 262 endif()
 263
 264 if (NOT DEFINED NO_LAPACKE)
 265   set(NO_LAPACKE_IN 0)
 266 else()
 267   set(NO_LAPACKE_IN ${NO_LAPACKE})
 268 endif()
 269
 270 if (NOT DEFINED NEED2UNDERSCORES)
 271   set(NEED2UNDERSCORES_IN 0)
 272 else()
 273   set(NEED2UNDERSCORES_IN ${NEED2UNDERSCORES})
 274 endif()
 275
 276 if (NOT DEFINED ONLY_CBLAS)
 277   set(ONLY_CBLAS_IN 0)
 278 else()
 279   set(ONLY_CBLAS_IN ${ONLY_CBLAS})
 280 endif()
 281
 282 if (NOT DEFINED BU)
 283   set(BU _)
 284 endif()
 285
 286 if (NOT ${SYMBOLPREFIX} STREQUAL "")
 287 message(STATUS "adding prefix ${SYMBOLPREFIX} to names of exported symbols in ${OpenBLAS_LIBNAME}")
 288 endif()
 289 if (NOT ${SYMBOLSUFFIX} STREQUAL "")
 290 message(STATUS "adding suffix ${SYMBOLSUFFIX} to names of exported symbols in ${OpenBLAS_LIBNAME}")
 291 endif()
 292         add_custom_command(TARGET ${OpenBLAS_LIBNAME} POST_BUILD
 293         COMMAND perl  ${PROJECT_SOURCE_DIR}/exports/gensymbol "objcopy" "${ARCH}" "${BU}" "${EXPRECISION_IN}" "${NO_CBLAS_IN}" "${NO_LAPACK_IN}" "${NO_LAPACKE_IN}" "${NEED2UNDERSCORES_IN}" "${ONLY_CBLAS_IN}" \"${SYMBOLPREFIX}\" \"${SYMBOLSUFFIX}\" "${BUILD_LAPACK_DEPRECATED}" > ${PROJECT_BINARY_DIR}/objcopy.def
 294         COMMAND objcopy -v --redefine-syms ${PROJECT_BINARY_DIR}/objcopy.def  ${PROJECT_BINARY_DIR}/lib/lib${OpenBLAS_LIBNAME}.so
 295         COMMENT "renaming symbols"
 296         )
 297 endif()
 298
 299
 300 # Install project
 301
 302 # Install libraries
 303 install(TARGETS ${OpenBLAS_LIBNAME}
 304         EXPORT "OpenBLAS${SUFFIX64}Targets"
 305         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 306         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 307   LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR} )
 308
 309 # Install headers
 310 set(CMAKE_INSTALL_INCLUDEDIR ${CMAKE_INSTALL_INCLUDEDIR}/openblas${SUFFIX64})
 311 set(CMAKE_INSTALL_FULL_INCLUDEDIR ${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_INCLUDEDIR})
 312
 313 message(STATUS "Generating openblas_config.h in ${CMAKE_INSTALL_INCLUDEDIR}")
 314
 315 set(OPENBLAS_CONFIG_H ${CMAKE_BINARY_DIR}/openblas_config.h)
 316 file(WRITE  ${OPENBLAS_CONFIG_H} "#ifndef OPENBLAS_CONFIG_H\n")
 317 file(APPEND ${OPENBLAS_CONFIG_H} "#define OPENBLAS_CONFIG_H\n")
 318 file(STRINGS ${PROJECT_BINARY_DIR}/config.h __lines)
 319 foreach(line ${__lines})
 320   string(REPLACE "#define " "" line ${line})
 321   file(APPEND ${OPENBLAS_CONFIG_H} "#define OPENBLAS_${line}\n")
 322 endforeach()
 323 file(APPEND ${OPENBLAS_CONFIG_H} "#define OPENBLAS_VERSION \"OpenBLAS ${OpenBLAS_VERSION}\"\n")
 324 file(READ   ${CMAKE_CURRENT_SOURCE_DIR}/openblas_config_template.h OPENBLAS_CONFIG_TEMPLATE_H_CONTENTS)
 325 file(APPEND ${OPENBLAS_CONFIG_H} "${OPENBLAS_CONFIG_TEMPLATE_H_CONTENTS}\n")
 326 file(APPEND ${OPENBLAS_CONFIG_H} "#endif /* OPENBLAS_CONFIG_H */\n")
 327 install (FILES ${OPENBLAS_CONFIG_H} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 328
 329 if(NOT NOFORTRAN)
 330   message(STATUS "Generating f77blas.h in ${CMAKE_INSTALL_INCLUDEDIR}")
 331
 332   set(F77BLAS_H ${CMAKE_BINARY_DIR}/generated/f77blas.h)
 333   file(WRITE  ${F77BLAS_H} "#ifndef OPENBLAS_F77BLAS_H\n")
 334   file(APPEND ${F77BLAS_H} "#define OPENBLAS_F77BLAS_H\n")
 335   file(APPEND ${F77BLAS_H} "#include \"openblas_config.h\"\n")
 336   file(READ ${CMAKE_CURRENT_SOURCE_DIR}/common_interface.h COMMON_INTERFACE_H_CONTENTS)
 337   file(APPEND ${F77BLAS_H} "${COMMON_INTERFACE_H_CONTENTS}\n")
 338   file(APPEND ${F77BLAS_H} "#endif")
 339   install (FILES ${F77BLAS_H} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 340 endif()
 341
 342 if(NOT NO_CBLAS)
 343         message (STATUS "Generating cblas.h in ${CMAKE_INSTALL_INCLUDEDIR}")
 344
 345         set(CBLAS_H ${CMAKE_BINARY_DIR}/generated/cblas.h)
 346         file(READ ${CMAKE_CURRENT_SOURCE_DIR}/cblas.h CBLAS_H_CONTENTS)
 347         string(REPLACE "common" "openblas_config" CBLAS_H_CONTENTS_NEW "${CBLAS_H_CONTENTS}")
 348         file(WRITE ${CBLAS_H} "${CBLAS_H_CONTENTS_NEW}")
 349         install (FILES ${CBLAS_H} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 350 endif()
 351
 352 if(NOT NO_LAPACKE)
 353         message (STATUS "Copying LAPACKE header files to ${CMAKE_INSTALL_INCLUDEDIR}")
 354         add_dependencies( ${OpenBLAS_LIBNAME} genlapacke)
 355         FILE(GLOB_RECURSE INCLUDE_FILES "${CMAKE_CURRENT_SOURCE_DIR}/lapack-netlib/LAPACKE/*.h")
 356         install (FILES ${INCLUDE_FILES} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 357
 358         ADD_CUSTOM_TARGET(genlapacke
 359         COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/lapack-netlib/LAPACKE/include/lapacke_mangling_with_flags.h.in "${CMAKE_BINARY_DIR}/lapacke_mangling.h"
 360         )
 361         install (FILES ${CMAKE_BINARY_DIR}/lapacke_mangling.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/openblas${SUFFIX64})
 362 endif()
 363
 364 include(FindPkgConfig QUIET)
 365 if(PKG_CONFIG_FOUND)
 366         configure_file(${PROJECT_SOURCE_DIR}/cmake/openblas.pc.in ${PROJECT_BINARY_DIR}/openblas${SUFFIX64}.pc @ONLY)
 367         install (FILES ${PROJECT_BINARY_DIR}/openblas${SUFFIX64}.pc DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig/)
 368 endif()
 369
 370
 371 # GNUInstallDirs "DATADIR" wrong here; CMake search path wants "share".
 372 set(PN OpenBLAS)
 373 set(CMAKECONFIG_INSTALL_DIR "share/cmake/${PN}${SUFFIX64}")
 374 configure_package_config_file(cmake/${PN}Config.cmake.in
 375                               "${CMAKE_CURRENT_BINARY_DIR}/${PN}${SUFFIX64}Config.cmake"
 376                               INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR})
 377 write_basic_package_version_file(${CMAKE_CURRENT_BINARY_DIR}/${PN}ConfigVersion.cmake
 378                                  VERSION ${${PN}_VERSION}
 379                                  COMPATIBILITY AnyNewerVersion)
 380 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${PN}${SUFFIX64}Config.cmake
 381         DESTINATION ${CMAKECONFIG_INSTALL_DIR})
 382 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${PN}ConfigVersion.cmake
 383         RENAME ${PN}${SUFFIX64}ConfigVersion.cmake
 384         DESTINATION ${CMAKECONFIG_INSTALL_DIR})
 385 install(EXPORT "${PN}${SUFFIX64}Targets"
 386         NAMESPACE "${PN}${SUFFIX64}::"
 387         DESTINATION ${CMAKECONFIG_INSTALL_DIR})
 388