CMakeLists.txt

   1 ##
   2 ## Author: Hank Anderson <hank@statease.com>
   3 ##
   4
   5 cmake_minimum_required(VERSION 2.8.5)
   6 project(OpenBLAS C ASM)
   7 set(OpenBLAS_MAJOR_VERSION 0)
   8 set(OpenBLAS_MINOR_VERSION 3)
   9 set(OpenBLAS_PATCH_VERSION 9.dev)
  10 set(OpenBLAS_VERSION "${OpenBLAS_MAJOR_VERSION}.${OpenBLAS_MINOR_VERSION}.${OpenBLAS_PATCH_VERSION}")
  11
  12 # Adhere to GNU filesystem layout conventions
  13 include(GNUInstallDirs)
  14
  15 include(CMakePackageConfigHelpers)
  16
  17
  18 #######
  19 if(MSVC)
  20 option(BUILD_WITHOUT_LAPACK "Do not build LAPACK and LAPACKE (Only BLAS or CBLAS)" ON)
  21 endif()
  22 option(BUILD_WITHOUT_CBLAS "Do not build the C interface (CBLAS) to the BLAS functions" OFF)
  23 option(DYNAMIC_ARCH "Include support for multiple CPU targets, with automatic selection at runtime (x86/x86_64, aarch64 or ppc only)" OFF)
  24 option(DYNAMIC_OLDER "Include specific support for older x86 cpu models (Penryn,Dunnington,Atom,Nano,Opteron) with DYNAMIC_ARCH" OFF)
  25 option(BUILD_RELAPACK "Build with ReLAPACK (recursive implementation of several LAPACK functions on top of standard LAPACK)" OFF)
  26 if(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
  27 option(NO_AFFINITY "Disable support for CPU affinity masks to avoid binding processes from e.g. R or numpy/scipy to a single core" ON)
  28 else()
  29 set(NO_AFFINITY 1)
  30 endif()
  31
  32 # Add a prefix or suffix to all exported symbol names in the shared library.
  33 # Avoids conflicts with other BLAS libraries, especially when using
  34 # 64 bit integer interfaces in OpenBLAS.
  35
  36 set(SYMBOLPREFIX "" CACHE STRING  "Add a prefix to all exported symbol names in the shared library to avoid conflicts with other BLAS libraries" )
  37 set(SYMBOLSUFFIX "" CACHE STRING  "Add a suffix to all exported symbol names in the shared library, e.g. _64 for INTERFACE64 builds" )
  38 #######
  39 if(BUILD_WITHOUT_LAPACK)
  40 set(NO_LAPACK 1)
  41 set(NO_LAPACKE 1)
  42 endif()
  43
  44 if(BUILD_WITHOUT_CBLAS)
  45 set(NO_CBLAS 1)
  46 endif()
  47
  48 #######
  49
  50 if(MSVC AND MSVC_STATIC_CRT)
  51     set(CompilerFlags
  52             CMAKE_CXX_FLAGS
  53             CMAKE_CXX_FLAGS_DEBUG
  54             CMAKE_CXX_FLAGS_RELEASE
  55             CMAKE_C_FLAGS
  56             CMAKE_C_FLAGS_DEBUG
  57             CMAKE_C_FLAGS_RELEASE
  58             )
  59     foreach(CompilerFlag ${CompilerFlags})
  60       string(REPLACE "/MD" "/MT" ${CompilerFlag} "${${CompilerFlag}}")
  61     endforeach()
  62 endif()
  63
  64 message(WARNING "CMake support is experimental. It does not yet support all build options and may not produce the same Makefiles that OpenBLAS ships with.")
  65
  66 include("${PROJECT_SOURCE_DIR}/cmake/utils.cmake")
  67 include("${PROJECT_SOURCE_DIR}/cmake/system.cmake")
  68
  69 set(OpenBLAS_LIBNAME openblas${SUFFIX64_UNDERSCORE})
  70
  71 set(BLASDIRS interface driver/level2 driver/level3 driver/others)
  72
  73 if (NOT DYNAMIC_ARCH)
  74   list(APPEND BLASDIRS kernel)
  75 endif ()
  76
  77 if (DEFINED SANITY_CHECK)
  78   list(APPEND BLASDIRS reference)
  79 endif ()
  80
  81 set(SUBDIRS     ${BLASDIRS})
  82 if (NOT NO_LAPACK)
  83   if(BUILD_RELAPACK)
  84     list(APPEND SUBDIRS relapack/src)
  85   endif()
  86   list(APPEND SUBDIRS lapack)
  87 endif ()
  88
  89 # set which float types we want to build for
  90 if (NOT DEFINED BUILD_SINGLE AND NOT DEFINED BUILD_DOUBLE AND NOT DEFINED BUILD_COMPLEX AND NOT DEFINED BUILD_COMPLEX16)
  91   # if none are defined, build for all
  92   set(BUILD_SINGLE true)
  93   set(BUILD_DOUBLE true)
  94   set(BUILD_COMPLEX true)
  95   set(BUILD_COMPLEX16 true)
  96 endif ()
  97
  98 if (NOT DEFINED BUILD_MATGEN)
  99   set(BUILD_MATGEN true)
 100 endif()
 101
 102 set(FLOAT_TYPES "")
 103 if (BUILD_SINGLE)
 104   message(STATUS "Building Single Precision")
 105   list(APPEND FLOAT_TYPES "SINGLE") # defines nothing
 106 endif ()
 107
 108 if (BUILD_DOUBLE)
 109   message(STATUS "Building Double Precision")
 110   list(APPEND FLOAT_TYPES "DOUBLE") # defines DOUBLE
 111 endif ()
 112
 113 if (BUILD_COMPLEX)
 114   message(STATUS "Building Complex Precision")
 115   list(APPEND FLOAT_TYPES "COMPLEX") # defines COMPLEX
 116 endif ()
 117
 118 if (BUILD_COMPLEX16)
 119   message(STATUS "Building Double Complex Precision")
 120   list(APPEND FLOAT_TYPES "ZCOMPLEX") # defines COMPLEX and DOUBLE
 121 endif ()
 122
 123 if (NOT DEFINED CORE OR "${CORE}" STREQUAL "UNKNOWN")
 124   message(FATAL_ERROR "Detecting CPU failed. Please set TARGET explicitly, e.g. make TARGET=your_cpu_target. Please read README for details.")
 125 endif ()
 126
 127 #Set default output directory
 128 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
 129 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
 130 if(MSVC)
 131 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG ${PROJECT_BINARY_DIR}/lib/Debug)
 132 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELEASE ${PROJECT_BINARY_DIR}/lib/Release)
 133 endif ()
 134 # get obj vars into format that add_library likes: $<TARGET_OBJS:objlib> (see http://www.cmake.org/cmake/help/v3.0/command/add_library.html)
 135 set(TARGET_OBJS "")
 136 foreach (SUBDIR ${SUBDIRS})
 137   add_subdirectory(${SUBDIR})
 138   string(REPLACE "/" "_" subdir_obj ${SUBDIR})
 139   list(APPEND TARGET_OBJS "$<TARGET_OBJECTS:${subdir_obj}>")
 140 endforeach ()
 141
 142 # netlib:
 143
 144 # Can't just use lapack-netlib's CMake files, since they are set up to search for BLAS, build and install a binary. We just want to build a couple of lib files out of lapack and lapacke.
 145 # Not using add_subdirectory here because lapack-netlib already has its own CMakeLists.txt. Instead include a cmake script with the sources we want.
 146 if (NOT NOFORTRAN AND NOT NO_LAPACK)
 147   include("${PROJECT_SOURCE_DIR}/cmake/lapack.cmake")
 148   if (NOT NO_LAPACKE)
 149     include("${PROJECT_SOURCE_DIR}/cmake/lapacke.cmake")
 150   endif ()
 151 endif ()
 152
 153 # Only generate .def for dll on MSVC and always produce pdb files for debug and release
 154 if(MSVC)
 155   if (${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} VERSION_LESS 3.4)
 156     set(OpenBLAS_DEF_FILE "${PROJECT_BINARY_DIR}/openblas.def")
 157   endif()
 158   set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} /Zi")
 159   set(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE} /DEBUG /OPT:REF /OPT:ICF")
 160 endif()
 161
 162 if (${DYNAMIC_ARCH})
 163   add_subdirectory(kernel)
 164   foreach(TARGET_CORE ${DYNAMIC_CORE})
 165     message("${TARGET_CORE}")
 166     list(APPEND TARGET_OBJS "$<TARGET_OBJECTS:kernel_${TARGET_CORE}>")
 167   endforeach()
 168 endif ()
 169
 170 # add objects to the openblas lib
 171 add_library(${OpenBLAS_LIBNAME} ${LA_SOURCES} ${LAPACKE_SOURCES} ${RELA_SOURCES} ${TARGET_OBJS} ${OpenBLAS_DEF_FILE})
 172 target_include_directories(${OpenBLAS_LIBNAME} INTERFACE $<INSTALL_INTERFACE:include/openblas${SUFFIX64}>)
 173
 174 # Android needs to explicitly link against libm
 175 if(ANDROID)
 176   target_link_libraries(${OpenBLAS_LIBNAME} m)
 177 endif()
 178
 179 # Handle MSVC exports
 180 if(MSVC AND BUILD_SHARED_LIBS)
 181   if (${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} VERSION_LESS 3.4)
 182     include("${PROJECT_SOURCE_DIR}/cmake/export.cmake")
 183   else()
 184     # Creates verbose .def file (51KB vs 18KB)
 185     set_target_properties(${OpenBLAS_LIBNAME} PROPERTIES WINDOWS_EXPORT_ALL_SYMBOLS true)
 186   endif()
 187 endif()
 188
 189 # Set output for libopenblas
 190 set_target_properties( ${OpenBLAS_LIBNAME} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
 191 set_target_properties( ${OpenBLAS_LIBNAME} PROPERTIES LIBRARY_OUTPUT_NAME_DEBUG "${OpenBLAS_LIBNAME}_d")
 192 set_target_properties( ${OpenBLAS_LIBNAME} PROPERTIES EXPORT_NAME "OpenBLAS")
 193
 194 foreach (OUTPUTCONFIG ${CMAKE_CONFIGURATION_TYPES})
 195   string( TOUPPER ${OUTPUTCONFIG} OUTPUTCONFIG )
 196
 197   set_target_properties( ${OpenBLAS_LIBNAME} PROPERTIES RUNTIME_OUTPUT_DIRECTORY_${OUTPUTCONFIG} ${PROJECT_BINARY_DIR}/lib/${OUTPUTCONFIG} )
 198   set_target_properties( ${OpenBLAS_LIBNAME} PROPERTIES LIBRARY_OUTPUT_DIRECTORY_${OUTPUTCONFIG} ${PROJECT_BINARY_DIR}/lib/${OUTPUTCONFIG} )
 199   set_target_properties( ${OpenBLAS_LIBNAME} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY_${OUTPUTCONFIG} ${PROJECT_BINARY_DIR}/lib/${OUTPUTCONFIG} )
 200 endforeach()
 201
 202 enable_testing()
 203
 204 if (USE_THREAD)
 205   # Add threading library to linker
 206   find_package(Threads)
 207   if (THREADS_HAVE_PTHREAD_ARG)
 208     set_property(TARGET ${OpenBLAS_LIBNAME} PROPERTY COMPILE_OPTIONS "-pthread")
 209     set_property(TARGET ${OpenBLAS_LIBNAME} PROPERTY INTERFACE_COMPILE_OPTIONS "-pthread")
 210   endif()
 211   target_link_libraries(${OpenBLAS_LIBNAME} ${CMAKE_THREAD_LIBS_INIT})
 212 endif()
 213
 214 #if (MSVC OR NOT NOFORTRAN)
 215 if (NOT NO_CBLAS)
 216   # Broken without fortran on unix
 217   add_subdirectory(utest)
 218 endif()
 219
 220 if (NOT MSVC AND NOT NOFORTRAN)
 221   # Build test and ctest
 222   add_subdirectory(test)
 223   if(NOT NO_CBLAS)
 224     add_subdirectory(ctest)
 225   endif()
 226 endif()
 227
 228 set_target_properties(${OpenBLAS_LIBNAME} PROPERTIES
 229   VERSION ${OpenBLAS_MAJOR_VERSION}.${OpenBLAS_MINOR_VERSION}
 230   SOVERSION ${OpenBLAS_MAJOR_VERSION}
 231 )
 232
 233 if (BUILD_SHARED_LIBS AND BUILD_RELAPACK)
 234   if (NOT MSVC)
 235     target_link_libraries(${OpenBLAS_LIBNAME} "-Wl,-allow-multiple-definition")
 236   else()
 237     target_link_libraries(${OpenBLAS_LIBNAME} "/FORCE:MULTIPLE")
 238   endif()
 239 endif()
 240
 241 if (BUILD_SHARED_LIBS AND NOT ${SYMBOLPREFIX}${SYMBOLSUFIX} STREQUAL "")
 242 if (NOT DEFINED ARCH)
 243   set(ARCH_IN "x86_64")
 244 else()
 245   set(ARCH_IN ${ARCH})
 246 endif()
 247
 248 if (${CORE} STREQUAL "generic")
 249   set(ARCH_IN "GENERIC")
 250 endif ()
 251
 252 if (NOT DEFINED EXPRECISION)
 253   set(EXPRECISION_IN 0)
 254 else()
 255   set(EXPRECISION_IN ${EXPRECISION})
 256 endif()
 257
 258 if (NOT DEFINED NO_CBLAS)
 259   set(NO_CBLAS_IN 0)
 260 else()
 261   set(NO_CBLAS_IN ${NO_CBLAS})
 262 endif()
 263
 264 if (NOT DEFINED NO_LAPACK)
 265   set(NO_LAPACK_IN 0)
 266 else()
 267   set(NO_LAPACK_IN ${NO_LAPACK})
 268 endif()
 269
 270 if (NOT DEFINED NO_LAPACKE)
 271   set(NO_LAPACKE_IN 0)
 272 else()
 273   set(NO_LAPACKE_IN ${NO_LAPACKE})
 274 endif()
 275
 276 if (NOT DEFINED NEED2UNDERSCORES)
 277   set(NEED2UNDERSCORES_IN 0)
 278 else()
 279   set(NEED2UNDERSCORES_IN ${NEED2UNDERSCORES})
 280 endif()
 281
 282 if (NOT DEFINED ONLY_CBLAS)
 283   set(ONLY_CBLAS_IN 0)
 284 else()
 285   set(ONLY_CBLAS_IN ${ONLY_CBLAS})
 286 endif()
 287
 288 if (NOT DEFINED BU)
 289   set(BU _)
 290 endif()
 291
 292 if (NOT ${SYMBOLPREFIX} STREQUAL "")
 293 message(STATUS "adding prefix ${SYMBOLPREFIX} to names of exported symbols in ${OpenBLAS_LIBNAME}")
 294 endif()
 295 if (NOT ${SYMBOLSUFFIX} STREQUAL "")
 296 message(STATUS "adding suffix ${SYMBOLSUFFIX} to names of exported symbols in ${OpenBLAS_LIBNAME}")
 297 endif()
 298         add_custom_command(TARGET ${OpenBLAS_LIBNAME} POST_BUILD
 299         COMMAND perl  ${PROJECT_SOURCE_DIR}/exports/gensymbol "objcopy" "${ARCH}" "${BU}" "${EXPRECISION_IN}" "${NO_CBLAS_IN}" "${NO_LAPACK_IN}" "${NO_LAPACKE_IN}" "${NEED2UNDERSCORES_IN}" "${ONLY_CBLAS_IN}" \"${SYMBOLPREFIX}\" \"${SYMBOLSUFFIX}\" "${BUILD_LAPACK_DEPRECATED}" > ${PROJECT_BINARY_DIR}/objcopy.def
 300         COMMAND objcopy -v --redefine-syms ${PROJECT_BINARY_DIR}/objcopy.def  ${PROJECT_BINARY_DIR}/lib/lib${OpenBLAS_LIBNAME}.so
 301         COMMENT "renaming symbols"
 302         )
 303 endif()
 304
 305
 306 # Install project
 307
 308 # Install libraries
 309 install(TARGETS ${OpenBLAS_LIBNAME}
 310         EXPORT "OpenBLAS${SUFFIX64}Targets"
 311         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 312         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 313   LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR} )
 314
 315 # Install headers
 316 set(CMAKE_INSTALL_INCLUDEDIR ${CMAKE_INSTALL_INCLUDEDIR}/openblas${SUFFIX64})
 317 set(CMAKE_INSTALL_FULL_INCLUDEDIR ${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_INCLUDEDIR})
 318
 319 message(STATUS "Generating openblas_config.h in ${CMAKE_INSTALL_INCLUDEDIR}")
 320
 321 set(OPENBLAS_CONFIG_H ${CMAKE_BINARY_DIR}/openblas_config.h)
 322 file(WRITE  ${OPENBLAS_CONFIG_H} "#ifndef OPENBLAS_CONFIG_H\n")
 323 file(APPEND ${OPENBLAS_CONFIG_H} "#define OPENBLAS_CONFIG_H\n")
 324 file(STRINGS ${PROJECT_BINARY_DIR}/config.h __lines)
 325 foreach(line ${__lines})
 326   string(REPLACE "#define " "" line ${line})
 327   file(APPEND ${OPENBLAS_CONFIG_H} "#define OPENBLAS_${line}\n")
 328 endforeach()
 329 file(APPEND ${OPENBLAS_CONFIG_H} "#define OPENBLAS_VERSION \"OpenBLAS ${OpenBLAS_VERSION}\"\n")
 330 file(READ   ${CMAKE_CURRENT_SOURCE_DIR}/openblas_config_template.h OPENBLAS_CONFIG_TEMPLATE_H_CONTENTS)
 331 file(APPEND ${OPENBLAS_CONFIG_H} "${OPENBLAS_CONFIG_TEMPLATE_H_CONTENTS}\n")
 332 file(APPEND ${OPENBLAS_CONFIG_H} "#endif /* OPENBLAS_CONFIG_H */\n")
 333 install (FILES ${OPENBLAS_CONFIG_H} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 334
 335 if(NOT NOFORTRAN)
 336   message(STATUS "Generating f77blas.h in ${CMAKE_INSTALL_INCLUDEDIR}")
 337
 338   set(F77BLAS_H ${CMAKE_BINARY_DIR}/generated/f77blas.h)
 339   file(WRITE  ${F77BLAS_H} "#ifndef OPENBLAS_F77BLAS_H\n")
 340   file(APPEND ${F77BLAS_H} "#define OPENBLAS_F77BLAS_H\n")
 341   file(APPEND ${F77BLAS_H} "#include \"openblas_config.h\"\n")
 342   file(READ ${CMAKE_CURRENT_SOURCE_DIR}/common_interface.h COMMON_INTERFACE_H_CONTENTS)
 343   file(APPEND ${F77BLAS_H} "${COMMON_INTERFACE_H_CONTENTS}\n")
 344   file(APPEND ${F77BLAS_H} "#endif")
 345   install (FILES ${F77BLAS_H} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 346 endif()
 347
 348 if(NOT NO_CBLAS)
 349         message (STATUS "Generating cblas.h in ${CMAKE_INSTALL_INCLUDEDIR}")
 350
 351         set(CBLAS_H ${CMAKE_BINARY_DIR}/generated/cblas.h)
 352         file(READ ${CMAKE_CURRENT_SOURCE_DIR}/cblas.h CBLAS_H_CONTENTS)
 353         string(REPLACE "common" "openblas_config" CBLAS_H_CONTENTS_NEW "${CBLAS_H_CONTENTS}")
 354         file(WRITE ${CBLAS_H} "${CBLAS_H_CONTENTS_NEW}")
 355         install (FILES ${CBLAS_H} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 356 endif()
 357
 358 if(NOT NO_LAPACKE)
 359         message (STATUS "Copying LAPACKE header files to ${CMAKE_INSTALL_INCLUDEDIR}")
 360         add_dependencies( ${OpenBLAS_LIBNAME} genlapacke)
 361         FILE(GLOB_RECURSE INCLUDE_FILES "${CMAKE_CURRENT_SOURCE_DIR}/lapack-netlib/LAPACKE/*.h")
 362         install (FILES ${INCLUDE_FILES} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 363
 364         ADD_CUSTOM_TARGET(genlapacke
 365         COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/lapack-netlib/LAPACKE/include/lapacke_mangling_with_flags.h.in "${CMAKE_BINARY_DIR}/lapacke_mangling.h"
 366         )
 367         install (FILES ${CMAKE_BINARY_DIR}/lapacke_mangling.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/openblas${SUFFIX64})
 368 endif()
 369
 370 include(FindPkgConfig QUIET)
 371 if(PKG_CONFIG_FOUND)
 372         configure_file(${PROJECT_SOURCE_DIR}/cmake/openblas.pc.in ${PROJECT_BINARY_DIR}/openblas${SUFFIX64}.pc @ONLY)
 373         install (FILES ${PROJECT_BINARY_DIR}/openblas${SUFFIX64}.pc DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig/)
 374 endif()
 375
 376
 377 # GNUInstallDirs "DATADIR" wrong here; CMake search path wants "share".
 378 set(PN OpenBLAS)
 379 set(CMAKECONFIG_INSTALL_DIR "share/cmake/${PN}${SUFFIX64}")
 380 configure_package_config_file(cmake/${PN}Config.cmake.in
 381                               "${CMAKE_CURRENT_BINARY_DIR}/${PN}${SUFFIX64}Config.cmake"
 382                               INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR})
 383 write_basic_package_version_file(${CMAKE_CURRENT_BINARY_DIR}/${PN}ConfigVersion.cmake
 384                                  VERSION ${${PN}_VERSION}
 385                                  COMPATIBILITY AnyNewerVersion)
 386 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${PN}${SUFFIX64}Config.cmake
 387         DESTINATION ${CMAKECONFIG_INSTALL_DIR})
 388 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${PN}ConfigVersion.cmake
 389         RENAME ${PN}${SUFFIX64}ConfigVersion.cmake
 390         DESTINATION ${CMAKECONFIG_INSTALL_DIR})
 391 install(EXPORT "${PN}${SUFFIX64}Targets"
 392         NAMESPACE "${PN}${SUFFIX64}::"
 393         DESTINATION ${CMAKECONFIG_INSTALL_DIR})
 394