CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.0.2)
   2
   3 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
   4 if (${CMAKE_VERSION} VERSION_LESS "3.17.0")
   5   list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake-compat)
   6 endif()
   7
   8 project(libzip
   9   VERSION 1.8.0
  10   LANGUAGES C)
  11
  12 option(ENABLE_COMMONCRYPTO "Enable use of CommonCrypto" ON)
  13 option(ENABLE_GNUTLS "Enable use of GnuTLS" ON)
  14 option(ENABLE_MBEDTLS "Enable use of mbed TLS" ON)
  15 option(ENABLE_OPENSSL "Enable use of OpenSSL" ON)
  16 option(ENABLE_WINDOWS_CRYPTO "Enable use of Windows cryptography libraries" ON)
  17
  18 option(ENABLE_BZIP2 "Enable use of BZip2" ON)
  19 option(ENABLE_LZMA "Enable use of LZMA" ON)
  20 option(ENABLE_ZSTD "Enable use of Zstandard" ON)
  21
  22 option(BUILD_TOOLS "Build tools in the src directory (zipcmp, zipmerge, ziptool)" ON)
  23 option(BUILD_REGRESS "Build regression tests" ON)
  24 option(BUILD_EXAMPLES "Build examples" ON)
  25 option(BUILD_DOC "Build documentation" ON)
  26
  27 include(CheckFunctionExists)
  28 include(CheckIncludeFiles)
  29 include(CheckLibraryExists)
  30 include(CheckSymbolExists)
  31 include(CheckTypeSize)
  32 include(CheckCSourceRuns)
  33 include(CheckCSourceCompiles)
  34 include(CheckStructHasMember)
  35 include(TestBigEndian)
  36 include(GNUInstallDirs)
  37
  38 if(ENABLE_COMMONCRYPTO)
  39   check_include_files(CommonCrypto/CommonCrypto.h COMMONCRYPTO_FOUND)
  40 endif()
  41 if(ENABLE_GNUTLS)
  42   find_package(Nettle 3.0)
  43   find_package(GnuTLS)
  44 endif()
  45 if(ENABLE_MBEDTLS)
  46   find_package(MbedTLS 1.0)
  47 endif()
  48 if(ENABLE_OPENSSL)
  49   find_package(OpenSSL)
  50 endif()
  51 if(WIN32)
  52   if(ENABLE_WINDOWS_CRYPTO)
  53     set(WINDOWS_CRYPTO_FOUND TRUE)
  54   endif()
  55 endif()
  56
  57 option(BUILD_SHARED_LIBS "Build shared libraries" ON)
  58 option(LIBZIP_DO_INSTALL "Install libzip and the related files" ON)
  59
  60 option(SHARED_LIB_VERSIONNING "Add SO version in .so build" ON)
  61
  62 find_program(MDOCTOOL NAMES mandoc groff)
  63 if (MDOCTOOL)
  64   set(DOCUMENTATION_FORMAT "mdoc" CACHE STRING "Documentation format")
  65 else()
  66   find_program(MANTOOL NAMES nroff)
  67   if (MANTOOL)
  68     set(DOCUMENTATION_FORMAT "man" CACHE STRING "Documentation format")
  69   else()
  70     set(DOCUMENTATION_FORMAT "html" CACHE STRING "Documentation format")
  71   endif()
  72 endif()
  73
  74 include(Dist)
  75 Dist(${CMAKE_PROJECT_NAME}-${CMAKE_PROJECT_VERSION})
  76
  77 #ADD_CUSTOM_TARGET(uninstall
  78 #  COMMAND cat ${PROJECT_BINARY_DIR}/install_manifest.txt | xargs rm
  79 #  WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  80 #  )
  81
  82 if(BUILD_SHARED_LIBS)
  83   set(HAVE_SHARED TRUE)
  84 else()
  85   set(ZIP_STATIC TRUE)
  86 endif()
  87
  88 # Checks
  89
  90 check_function_exists(_close HAVE__CLOSE)
  91 check_function_exists(_dup HAVE__DUP)
  92 check_function_exists(_fdopen HAVE__FDOPEN)
  93 check_function_exists(_fileno HAVE__FILENO)
  94 check_function_exists(_setmode HAVE__SETMODE)
  95 check_symbol_exists(_snprintf stdio.h HAVE__SNPRINTF)
  96 check_function_exists(_strdup HAVE__STRDUP)
  97 check_symbol_exists(_stricmp string.h HAVE__STRICMP)
  98 check_function_exists(_strtoi64 HAVE__STRTOI64)
  99 check_function_exists(_strtoui64 HAVE__STRTOUI64)
 100 check_function_exists(_unlink HAVE__UNLINK)
 101 check_function_exists(arc4random HAVE_ARC4RANDOM)
 102 check_function_exists(clonefile HAVE_CLONEFILE)
 103 check_function_exists(explicit_bzero HAVE_EXPLICIT_BZERO)
 104 check_function_exists(explicit_memset HAVE_EXPLICIT_MEMSET)
 105 check_function_exists(fileno HAVE_FILENO)
 106 check_function_exists(fseeko HAVE_FSEEKO)
 107 check_function_exists(ftello HAVE_FTELLO)
 108 check_function_exists(getprogname HAVE_GETPROGNAME)
 109 check_function_exists(localtime_r HAVE_LOCALTIME_R)
 110 check_function_exists(setmode HAVE_SETMODE)
 111 check_symbol_exists(snprintf stdio.h HAVE_SNPRINTF)
 112 check_symbol_exists(strcasecmp strings.h HAVE_STRCASECMP)
 113 check_function_exists(strdup HAVE_STRDUP)
 114 check_function_exists(stricmp HAVE_STRICMP)
 115 check_function_exists(strtoll HAVE_STRTOLL)
 116 check_function_exists(strtoull HAVE_STRTOULL)
 117
 118 check_include_files("sys/types.h;sys/stat.h;fts.h" HAVE_FTS_H)
 119 # fts functions may be in external library
 120 if(HAVE_FTS_H)
 121   check_function_exists(fts_open HAVE_FTS_OPEN)
 122   if(NOT HAVE_FTS_OPEN)
 123     check_library_exists(fts fts_open "" HAVE_LIB_FTS)
 124   else(NOT HAVE_FTS_OPEN)
 125     set(HAVE_LIB_FTS "" CACHE INTERNAL "")
 126   endif(NOT HAVE_FTS_OPEN)
 127 else(HAVE_FTS_H)
 128   set(HAVE_LIB_FTS "" CACHE INTERNAL "")
 129 endif(HAVE_FTS_H)
 130
 131 if(HAVE_LIB_FTS)
 132   set(FTS_LIB fts CACHE INTERNAL "")
 133 else()
 134   set(FTS_LIB "" CACHE INTERNAL "")
 135 endif()
 136
 137 check_include_files(stdbool.h HAVE_STDBOOL_H)
 138 check_include_files(strings.h HAVE_STRINGS_H)
 139 check_include_files(unistd.h HAVE_UNISTD_H)
 140
 141 check_include_files(inttypes.h HAVE_INTTYPES_H_LIBZIP)
 142 check_include_files(stdint.h HAVE_STDINT_H_LIBZIP)
 143 check_include_files(sys/types.h HAVE_SYS_TYPES_H_LIBZIP)
 144
 145 # TODO: fix test
 146 # this test does not find __progname even when it exists
 147 #check_symbol_exists(__progname stdlib.h HAVE___PROGNAME)
 148
 149 check_type_size(__int8 __INT8_LIBZIP)
 150 check_type_size(int8_t INT8_T_LIBZIP)
 151 check_type_size(uint8_t UINT8_T_LIBZIP)
 152 check_type_size(__int16 __INT16_LIBZIP)
 153 check_type_size(int16_t INT16_T_LIBZIP)
 154 check_type_size(uint16_t UINT16_T_LIBZIP)
 155 check_type_size(__int32 __INT32_LIBZIP)
 156 check_type_size(int32_t INT32_T_LIBZIP)
 157 check_type_size(uint32_t UINT32_T_LIBZIP)
 158 check_type_size(__int64 __INT64_LIBZIP)
 159 check_type_size(int64_t INT64_T_LIBZIP)
 160 check_type_size(uint64_t UINT64_T_LIBZIP)
 161 check_type_size("short" SHORT_LIBZIP)
 162 check_type_size("int" INT_LIBZIP)
 163 check_type_size("long" LONG_LIBZIP)
 164 check_type_size("long long" LONG_LONG_LIBZIP)
 165 check_type_size("off_t" SIZEOF_OFF_T)
 166 check_type_size("size_t" SIZEOF_SIZE_T)
 167
 168 check_c_source_compiles("#include <sys/ioctl.h>
 169 #include <linux/fs.h>
 170 int main(int argc, char *argv[]) { unsigned long x = FICLONERANGE; }" HAVE_FICLONERANGE)
 171
 172 check_c_source_compiles("
 173 int foo(char * _Nullable bar);
 174 int main(int argc, char *argv[]) { }" HAVE_NULLABLE)
 175
 176 test_big_endian(WORDS_BIGENDIAN)
 177
 178 find_package(ZLIB 1.1.2 REQUIRED)
 179
 180 if(ENABLE_BZIP2)
 181   find_package(BZip2)
 182   if(BZIP2_FOUND)
 183     set(HAVE_LIBBZ2 1)
 184   else()
 185     message(WARNING "-- bzip2 library not found; bzip2 support disabled")
 186   endif(BZIP2_FOUND)
 187 endif(ENABLE_BZIP2)
 188
 189 if(ENABLE_LZMA)
 190   find_package(LibLZMA 5.2)
 191   if(LIBLZMA_FOUND)
 192     set(HAVE_LIBLZMA 1)
 193   else()
 194     message(WARNING "-- lzma library not found; lzma/xz support disabled")
 195   endif(LIBLZMA_FOUND)
 196 endif(ENABLE_LZMA)
 197
 198 if(ENABLE_ZSTD)
 199   find_package(Zstd)
 200   if(Zstd_FOUND)
 201     set(HAVE_LIBZSTD 1)
 202   else()
 203     message(WARNING "-- zstd library not found; zstandard support disabled")
 204   endif(Zstd_FOUND)
 205 endif(ENABLE_ZSTD)
 206
 207 if (COMMONCRYPTO_FOUND)
 208   set(HAVE_CRYPTO 1)
 209   set(HAVE_COMMONCRYPTO 1)
 210 elseif (WINDOWS_CRYPTO_FOUND)
 211   set(HAVE_CRYPTO 1)
 212   set(HAVE_WINDOWS_CRYPTO 1)
 213 elseif (GNUTLS_FOUND AND NETTLE_FOUND)
 214   set(HAVE_CRYPTO 1)
 215   set(HAVE_GNUTLS 1)
 216 elseif (OPENSSL_FOUND)
 217   set(HAVE_CRYPTO 1)
 218   set(HAVE_OPENSSL 1)
 219 elseif (MBEDTLS_FOUND)
 220   set(HAVE_CRYPTO 1)
 221   set(HAVE_MBEDTLS 1)
 222 endif()
 223
 224 if (NOT HAVE_CRYPTO)
 225   message(WARNING "-- neither Common Crypto, GnuTLS, mbed TLS, OpenSSL, nor Windows Cryptography found; AES support disabled")
 226 endif()
 227
 228 if(MSVC)
 229   add_compile_definitions(_CRT_SECURE_NO_WARNINGS)
 230   add_compile_definitions(_CRT_NONSTDC_NO_DEPRECATE)
 231 endif(MSVC)
 232
 233 if(WIN32)
 234   if(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
 235     add_compile_definitions(MS_UWP)
 236   endif(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
 237 endif(WIN32)
 238
 239 # rpath handling: use rpath in installed binaries
 240 if(NOT CMAKE_SYSTEM_NAME MATCHES Linux)
 241   set(CMAKE_INSTALL_RPATH ${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_LIBDIR})
 242   set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 243 endif()
 244
 245 # for code completion frameworks
 246 set(CMAKE_EXPORT_COMPILE_COMMANDS ON)
 247
 248 # Testing
 249 ENABLE_TESTING()
 250
 251 # Targets
 252 ADD_SUBDIRECTORY(lib)
 253
 254 if(BUILD_DOC)
 255   ADD_SUBDIRECTORY(man)
 256 endif()
 257
 258 if(BUILD_TOOLS)
 259   ADD_SUBDIRECTORY(src)
 260 else(BUILD_TOOLS)
 261   if(BUILD_REGRESS)
 262     message(WARNING "-- tools build has been disabled, but they are needed for regression tests; regression testing disabled")
 263     set(BUILD_REGRESS OFF)
 264   endif(BUILD_REGRESS)
 265 endif()
 266
 267 include(FindPerl)
 268
 269 if(NOT PERL_FOUND)
 270   message(WARNING "-- perl not found, regression testing disabled")
 271   set(BUILD_REGRESS OFF)
 272 endif()
 273
 274 if(BUILD_REGRESS)
 275   add_subdirectory(regress)
 276 endif()
 277
 278 if(BUILD_EXAMPLES)
 279   add_subdirectory(examples)
 280 endif()
 281
 282
 283 # pkgconfig file
 284 set(prefix ${CMAKE_INSTALL_PREFIX})
 285 set(exec_prefix \${prefix})
 286 SET(bindir ${CMAKE_INSTALL_FULL_BINDIR})
 287 SET(libdir ${CMAKE_INSTALL_FULL_LIBDIR})
 288 SET(includedir ${CMAKE_INSTALL_FULL_INCLUDEDIR})
 289 if(CMAKE_SYSTEM_NAME MATCHES BSD)
 290   set(PKG_CONFIG_RPATH "-Wl,-R\${libdir}")
 291 endif(CMAKE_SYSTEM_NAME MATCHES BSD)
 292 get_target_property(LIBS_PRIVATE zip LINK_LIBRARIES)
 293 foreach(LIB ${LIBS_PRIVATE})
 294   if(LIB MATCHES "^/")
 295     get_filename_component(LIB ${LIB} NAME_WE)
 296     string(REGEX REPLACE "^lib" "" LIB ${LIB})
 297   endif()
 298   set(LIBS "${LIBS} -l${LIB}")
 299 endforeach()
 300 string(REGEX REPLACE "-lBZip2::BZip2" "-lbz2" LIBS ${LIBS})
 301 string(REGEX REPLACE "-lLibLZMA::LibLZMA" "-llzma" LIBS ${LIBS})
 302 string(REGEX REPLACE "-lOpenSSL::Crypto" "-lssl -lcrypto" LIBS ${LIBS})
 303 string(REGEX REPLACE "-lZLIB::ZLIB" "-lz" LIBS ${LIBS})
 304 string(REGEX REPLACE "-lGnuTLS::GnuTLS" "-lgnutls" LIBS ${LIBS})
 305 string(REGEX REPLACE "-lNettle::Nettle" "-lnettle" LIBS ${LIBS})
 306 configure_file(libzip.pc.in libzip.pc @ONLY)
 307 if(LIBZIP_DO_INSTALL)
 308   install(FILES ${PROJECT_BINARY_DIR}/libzip.pc DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
 309 endif()
 310
 311 # fixed size integral types
 312
 313 if(HAVE_INTTYPES_H_LIBZIP)
 314   set(LIBZIP_TYPES_INCLUDE "#if !defined(__STDC_FORMAT_MACROS)
 315 #define __STDC_FORMAT_MACROS 1
 316 #endif
 317 #include <inttypes.h>")
 318 elseif(HAVE_STDINT_H_LIBZIP)
 319   set(LIBZIP_TYPES_INCLUDE "#include <stdint.h>")
 320 elseif(HAVE_SYS_TYPES_H_LIBZIP)
 321   set(LIBZIP_TYPES_INCLUDE "#include <sys/types.h>")
 322 endif()
 323
 324 if(HAVE_INT8_T_LIBZIP)
 325   set(ZIP_INT8_T int8_t)
 326 elseif(HAVE___INT8_LIBZIP)
 327   set(ZIP_INT8_T __int8)
 328 else()
 329   set(ZIP_INT8_T "signed char")
 330 endif()
 331
 332 if(HAVE_UINT8_T_LIBZIP)
 333   set(ZIP_UINT8_T uint8_t)
 334 elseif(HAVE___INT8_LIBZIP)
 335   set(ZIP_UINT8_T "unsigned __int8")
 336 else()
 337   set(ZIP_UINT8_T "unsigned char")
 338 endif()
 339
 340 if(HAVE_INT16_T_LIBZIP)
 341   set(ZIP_INT16_T int16_t)
 342 elseif(HAVE___INT16_LIBZIP)
 343   set(INT16_T_LIBZIP __int16)
 344 elseif(SHORT_LIBZIP EQUAL 2)
 345   set(INT16_T_LIBZIP short)
 346 endif()
 347
 348 if(HAVE_UINT16_T_LIBZIP)
 349   set(ZIP_UINT16_T uint16_t)
 350 elseif(HAVE___INT16_LIBZIP)
 351   set(UINT16_T_LIBZIP "unsigned __int16")
 352 elseif(SHORT_LIBZIP EQUAL 2)
 353   set(UINT16_T_LIBZIP "unsigned short")
 354 endif()
 355
 356 if(HAVE_INT32_T_LIBZIP)
 357   set(ZIP_INT32_T int32_t)
 358 elseif(HAVE___INT32_LIBZIP)
 359   set(ZIP_INT32_T __int32)
 360 elseif(INT_LIBZIP EQUAL 4)
 361   set(ZIP_INT32_T int)
 362 elseif(LONG_LIBZIP EQUAL 4)
 363   set(ZIP_INT32_T long)
 364 endif()
 365
 366 if(HAVE_UINT32_T_LIBZIP)
 367   set(ZIP_UINT32_T uint32_t)
 368 elseif(HAVE___INT32_LIBZIP)
 369   set(ZIP_UINT32_T "unsigned __int32")
 370 elseif(INT_LIBZIP EQUAL 4)
 371   set(ZIP_UINT32_T "unsigned int")
 372 elseif(LONG_LIBZIP EQUAL 4)
 373   set(ZIP_UINT32_T "unsigned long")
 374 endif()
 375
 376 if(HAVE_INT64_T_LIBZIP)
 377   set(ZIP_INT64_T int64_t)
 378 elseif(HAVE___INT64_LIBZIP)
 379   set(ZIP_INT64_T __int64)
 380 elseif(LONG_LIBZIP EQUAL 8)
 381   set(ZIP_INT64_T long)
 382 elseif(LONG_LONG_LIBZIP EQUAL 8)
 383   set(ZIP_INT64_T "long long")
 384 endif()
 385
 386 if(HAVE_UINT64_T_LIBZIP)
 387   set(ZIP_UINT64_T uint64_t)
 388 elseif(HAVE___INT64_LIBZIP)
 389   set(ZIP_UINT64_T "unsigned __int64")
 390 elseif(LONG_LIBZIP EQUAL 8)
 391   set(ZIP_UINT64_T "unsigned long")
 392 elseif(LONG_LONG_LIBZIP EQUAL 8)
 393   set(ZIP_UINT64_T "unsigned long long")
 394 endif()
 395
 396 if(HAVE_NULLABLE)
 397   set(ZIP_NULLABLE_DEFINES)
 398 else()
 399   set(ZIP_NULLABLE_DEFINES "#define _Nullable
 400 #define _Nonnull")
 401 endif()
 402
 403 # write out config file
 404 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/cmake-config.h.in ${PROJECT_BINARY_DIR}/config.h)
 405 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/cmake-zipconf.h.in ${PROJECT_BINARY_DIR}/zipconf.h)
 406
 407 # for tests
 408
 409 set(srcdir ${CMAKE_CURRENT_SOURCE_DIR}/regress)
 410 set(abs_srcdir ${CMAKE_CURRENT_SOURCE_DIR}/regress)
 411 set(top_builddir ${PROJECT_BINARY_DIR}) # used to find config.h
 412
 413 configure_file(regress/nihtest.conf.in ${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/nihtest.conf @ONLY)
 414 file(COPY ${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/nihtest.conf
 415   DESTINATION ${PROJECT_BINARY_DIR}/regress
 416   FILE_PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 417
 418 configure_file(regress/runtest.in ${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/runtest @ONLY)
 419 file(COPY ${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/runtest
 420   DESTINATION ${PROJECT_BINARY_DIR}/regress
 421   FILE_PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE
 422   )
 423
 424 # create package config file
 425 include(CMakePackageConfigHelpers)
 426 write_basic_package_version_file("${PROJECT_BINARY_DIR}/${PROJECT_NAME}-config-version.cmake"
 427   COMPATIBILITY AnyNewerVersion)
 428
 429 configure_package_config_file("${PROJECT_NAME}-config.cmake.in" "${PROJECT_BINARY_DIR}/${PROJECT_NAME}-config.cmake"
 430   INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/libzip)
 431
 432 if(LIBZIP_DO_INSTALL)
 433   # Add targets to the build-tree export set
 434   export(TARGETS zip
 435     FILE "${PROJECT_BINARY_DIR}/${PROJECT_NAME}-targets.cmake")
 436
 437   # installation
 438   install(FILES ${PROJECT_BINARY_DIR}/zipconf.h DESTINATION include)
 439   install(FILES ${PROJECT_BINARY_DIR}/${PROJECT_NAME}-config.cmake ${PROJECT_BINARY_DIR}/${PROJECT_NAME}-config-version.cmake
 440     DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}
 441     )
 442   install(EXPORT ${PROJECT_NAME}-targets NAMESPACE libzip:: FILE ${PROJECT_NAME}-targets.cmake
 443     DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}
 444     )
 445 endif()
 446