CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 #
   8 #   - OCT-2008: Initial version <joseluisblancoc@gmail.com>
   9 #
  10 # ----------------------------------------------------------------------------
  11
  12 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  13
  14 # --------------------------------------------------------------
  15 # Indicate CMake 2.7 and above that we don't want to mix relative
  16 #  and absolute paths in linker lib lists.
  17 # Run "cmake --help-policy CMP0003" for more information.
  18 # --------------------------------------------------------------
  19 if(COMMAND cmake_policy)
  20   cmake_policy(SET CMP0003 NEW)
  21 endif()
  22
  23 # Following block can broke build in case of cross-compilng
  24 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  25 # so we will try to detect crosscompiling by presense of CMAKE_TOOLCHAIN_FILE
  26 if(NOT CMAKE_TOOLCHAIN_FILE)
  27   # it _must_ go before project(OpenCV) in order to work
  28   if(WIN32)
  29     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  30   else()
  31     set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  32   endif()
  33
  34   if(MSVC)
  35     set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
  36   endif()
  37 else(NOT CMAKE_TOOLCHAIN_FILE)
  38   #Android: set output folder to ${CMAKE_BINARY_DIR}
  39   set( LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  40   # any crosscompiling
  41   set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  42 endif(NOT CMAKE_TOOLCHAIN_FILE)
  43
  44 # --------------------------------------------------------------
  45 # Top level OpenCV project
  46 # --------------------------------------------------------------
  47 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  48   cmake_minimum_required(VERSION 2.8.8)
  49 elseif(IOS)
  50   cmake_minimum_required(VERSION 2.8.0)
  51 else()
  52   cmake_minimum_required(VERSION 2.6.3)
  53 endif()
  54
  55 # must go before the project command
  56 set(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  57 if(DEFINED CMAKE_BUILD_TYPE AND CMAKE_VERSION VERSION_GREATER "2.8")
  58   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
  59 endif()
  60
  61 project(OpenCV CXX C)
  62
  63 include(cmake/OpenCVUtils.cmake REQUIRED)
  64
  65 # ----------------------------------------------------------------------------
  66 # Break in case of popular CMake configuration mistakes
  67 # ----------------------------------------------------------------------------
  68 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
  69   message(FATAL_ERROR "CMake fails to deterimine the bitness of target platform.
  70   Please check your CMake and compiler installation. If you are crosscompiling then ensure that your CMake toolchain file correctly sets the compiler details.")
  71 endif()
  72
  73 # ----------------------------------------------------------------------------
  74 # Detect compiler and target platform architecture
  75 # ----------------------------------------------------------------------------
  76 include(cmake/OpenCVDetectCXXCompiler.cmake REQUIRED)
  77
  78 # Add these standard paths to the search paths for FIND_LIBRARY
  79 # to find libraries from these locations first
  80 if(UNIX AND NOT ANDROID)
  81   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
  82     if(EXISTS /lib64)
  83       list(APPEND CMAKE_LIBRARY_PATH /lib64)
  84     else()
  85       list(APPEND CMAKE_LIBRARY_PATH /lib)
  86     endif()
  87     if(EXISTS /usr/lib64)
  88       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
  89     else()
  90       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
  91     endif()
  92   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
  93     if(EXISTS /lib32)
  94       list(APPEND CMAKE_LIBRARY_PATH /lib32)
  95     else()
  96       list(APPEND CMAKE_LIBRARY_PATH /lib)
  97     endif()
  98     if(EXISTS /usr/lib32)
  99       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 100     else()
 101       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 102     endif()
 103   endif()
 104 endif()
 105
 106
 107 # ----------------------------------------------------------------------------
 108 # OpenCV cmake options
 109 # ----------------------------------------------------------------------------
 110
 111 # Optional 3rd party components
 112 # ===================================================
 113 OCV_OPTION(WITH_1394           "Include IEEE1394 support"                    ON   IF (UNIX AND NOT ANDROID AND NOT IOS) )
 114 OCV_OPTION(WITH_AVFOUNDATION   "Use AVFoundation for Video I/O"              ON   IF IOS)
 115 OCV_OPTION(WITH_CARBON         "Use Carbon for UI instead of Cocoa"          OFF  IF APPLE )
 116 OCV_OPTION(WITH_CUBLAS         "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" OFF IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 117 OCV_OPTION(WITH_CUDA           "Include NVidia Cuda Runtime support"         ON   IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 118 OCV_OPTION(WITH_CUFFT          "Include NVidia Cuda Fast Fourier Transform (FFT) library support"            ON  IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 119 OCV_OPTION(WITH_EIGEN          "Include Eigen2/Eigen3 support"               ON)
 120 OCV_OPTION(WITH_FFMPEG         "Include FFMPEG support"                      ON   IF (NOT ANDROID AND NOT IOS) )
 121 OCV_OPTION(WITH_GSTREAMER      "Include Gstreamer support"                   ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 122 OCV_OPTION(WITH_GTK            "Include GTK support"                         ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 123 OCV_OPTION(WITH_IMAGEIO        "ImageIO support for OS X"                    OFF  IF APPLE)
 124 OCV_OPTION(WITH_IPP            "Include Intel IPP support"                   OFF  IF (MSVC OR X86 OR X86_64) )
 125 OCV_OPTION(WITH_JASPER         "Include JPEG2K support"                      ON   IF (NOT IOS) )
 126 OCV_OPTION(WITH_JPEG           "Include JPEG support"                        ON   IF (NOT IOS) )
 127 OCV_OPTION(WITH_OPENEXR        "Include ILM support via OpenEXR"             ON   IF (NOT IOS) )
 128 OCV_OPTION(WITH_OPENGL         "Include OpenGL support"                      OFF  IF (NOT ANDROID AND NOT APPLE) )
 129 OCV_OPTION(WITH_OPENNI         "Include OpenNI support"                      OFF  IF (NOT ANDROID AND NOT IOS) )
 130 OCV_OPTION(WITH_PNG            "Include PNG support"                         ON   IF (NOT IOS) )
 131 OCV_OPTION(WITH_PVAPI          "Include Prosilica GigE support"              ON   IF (NOT ANDROID AND NOT IOS) )
 132 OCV_OPTION(WITH_QT             "Build with Qt Backend support"               OFF  IF (NOT ANDROID AND NOT IOS) )
 133 OCV_OPTION(WITH_QUICKTIME      "Use QuickTime for Video I/O insted of QTKit" OFF  IF APPLE )
 134 OCV_OPTION(WITH_TBB            "Include Intel TBB support"                   OFF  IF (NOT IOS) )
 135 OCV_OPTION(WITH_TIFF           "Include TIFF support"                        ON   IF (NOT IOS) )
 136 OCV_OPTION(WITH_UNICAP         "Include Unicap support (GPL)"                OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 137 OCV_OPTION(WITH_V4L            "Include Video 4 Linux support"               ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 138 OCV_OPTION(WITH_VIDEOINPUT     "Build HighGUI with DirectShow support"       ON   IF WIN32 )
 139 OCV_OPTION(WITH_XIMEA          "Include XIMEA cameras support"               OFF  IF (NOT ANDROID AND NOT APPLE) )
 140 OCV_OPTION(WITH_XINE           "Include Xine support (GPL)"                  OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 141 OCV_OPTION(WITH_CLP            "Include Clp support (EPL)"                   OFF)
 142 OCV_OPTION(WITH_OPENCL         "Include OpenCL Runtime support"              OFF  IF (NOT ANDROID AND NOT IOS) )
 143 OCV_OPTION(WITH_OPENCLAMDFFT   "Include AMD OpenCL FFT library support"      OFF  IF (NOT ANDROID AND NOT IOS) )
 144 OCV_OPTION(WITH_OPENCLAMDBLAS  "Include AMD OpenCL BLAS library support"     OFF  IF (NOT ANDROID AND NOT IOS) )
 145
 146
 147 # OpenCV build components
 148 # ===================================================
 149 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR IOS) )
 150 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 151 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" ON )
 152 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 153 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON )
 154 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     ON  IF (NOT IOS) )
 155 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           ON  IF (NOT IOS) )
 156 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into debug libs (not MSCV only)" ON )
 157 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of staticaly linked CRT for staticaly linked OpenCV" ON IF MSVC )
 158 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create fat java wrapper containing the whole OpenCV library" ON IF ANDROID AND NOT BUILD_SHARED_LIBS AND CMAKE_COMPILER_IS_GNUCXX )
 159 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID AND ANDROID_USE_STLPORT AND ANDROID_SOURCE_TREE )
 160 OCV_OPTION(BUILD_ANDROID_PACKAGE    "Build platform-specific package for Google Play" OFF IF ANDROID )
 161
 162
 163 # 3rd party libs
 164 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"         WIN32 OR IOS OR APPLE )
 165 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"      WIN32 OR IOS OR ANDROID OR APPLE )
 166 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"    WIN32 OR IOS OR ANDROID OR APPLE )
 167 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"      WIN32 OR IOS OR ANDROID OR APPLE )
 168 OCV_OPTION(BUILD_PNG                "Build libpng from source"       WIN32 OR IOS OR ANDROID OR APPLE )
 169
 170 # OpenCV installation options
 171 # ===================================================
 172 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 173 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 174 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF  IF ANDROID )
 175 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT IOS AND BUILD_SHARED_LIBS) )
 176
 177
 178 if(MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode)
 179   set(ENABLE_SOLUTION_FOLDERS0 ON)
 180 else()
 181   set(ENABLE_SOLUTION_FOLDERS0 OFF)
 182 endif()
 183
 184 # OpenCV build options
 185 # ===================================================
 186 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON   IF (NOT IOS) )
 187 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        ${ENABLE_SOLUTION_FOLDERS0} IF (CMAKE_VERSION VERSION_GREATER "2.8.0") )
 188 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CMAKE_COMPILER_IS_GNUCXX )
 189 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CMAKE_COMPILER_IS_GNUCXX )
 190 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CMAKE_COMPILER_IS_GNUCXX AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 191 OCV_OPTION(ENABLE_FAST_MATH           "Enable -ffast-math (not recommended for GCC 4.6.x)"       OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 192 OCV_OPTION(ENABLE_SSE                 "Enable SSE instructions"                                  ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 193 OCV_OPTION(ENABLE_SSE2                "Enable SSE2 instructions"                                 ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 194 OCV_OPTION(ENABLE_SSE3                "Enable SSE3 instructions"                                 ON   IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 195 OCV_OPTION(ENABLE_SSSE3               "Enable SSSE3 instructions"                                OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 196 OCV_OPTION(ENABLE_SSE41               "Enable SSE4.1 instructions"                               OFF  IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 197 OCV_OPTION(ENABLE_SSE42               "Enable SSE4.2 instructions"                               OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 198 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 199 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 200 OCV_OPTION(ENABLE_MULTI_PROCESSOR_COMPILATION "Enabling multi-processory compilation"            OFF IF MSVC)
 201
 202
 203 # uncategorized options
 204 # ===================================================
 205 OCV_OPTION(CMAKE_VERBOSE "Verbose mode" OFF )
 206
 207 # backward compatibility
 208 # ===================================================
 209 include(cmake/OpenCVLegacyOptions.cmake OPTIONAL)
 210
 211
 212 # ----------------------------------------------------------------------------
 213 #  Get actual OpenCV version number from sources
 214 # ----------------------------------------------------------------------------
 215 include(cmake/OpenCVVersion.cmake REQUIRED)
 216
 217
 218 # ----------------------------------------------------------------------------
 219 #  Build & install layouts
 220 # ----------------------------------------------------------------------------
 221
 222 # Save libs and executables in the same place
 223 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications" )
 224
 225 if(ANDROID OR WIN32)
 226     set(OPENCV_DOC_INSTALL_PATH doc)
 227 elseif(INSTALL_TO_MANGLED_PATHS)
 228     set(OPENCV_DOC_INSTALL_PATH share/OpenCV-${OPENCV_VERSION}/doc)
 229 else()
 230     set(OPENCV_DOC_INSTALL_PATH share/OpenCV/doc)
 231 endif()
 232
 233 if(ANDROID)
 234     set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 235     set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 236     set(OPENCV_LIB_INSTALL_PATH     sdk/native/libs/${ANDROID_NDK_ABI_NAME})
 237     set(OPENCV_3P_LIB_INSTALL_PATH  sdk/native/3rdparty/libs/${ANDROID_NDK_ABI_NAME})
 238     set(OPENCV_CONFIG_INSTALL_PATH  sdk/native/jni)
 239     set(OPENCV_INCLUDE_INSTALL_PATH sdk/native/jni/include)
 240 else()
 241     set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib")
 242     set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib${LIB_SUFFIX}")
 243     set(OPENCV_LIB_INSTALL_PATH     lib${LIB_SUFFIX})
 244     set(OPENCV_3P_LIB_INSTALL_PATH  share/OpenCV/3rdparty/${OPENCV_LIB_INSTALL_PATH})
 245     set(OPENCV_INCLUDE_INSTALL_PATH include)
 246
 247     math(EXPR SIZEOF_VOID_P_BITS "8 * ${CMAKE_SIZEOF_VOID_P}")
 248     if(LIB_SUFFIX AND NOT SIZEOF_VOID_P_BITS EQUAL LIB_SUFFIX)
 249       set(OPENCV_CONFIG_INSTALL_PATH lib${LIB_SUFFIX}/cmake/opencv)
 250     else()
 251       set(OPENCV_CONFIG_INSTALL_PATH share/OpenCV)
 252     endif()
 253 endif()
 254
 255 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 256 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 257
 258 if(INSTALL_TO_MANGLED_PATHS)
 259   set(OPENCV_INCLUDE_INSTALL_PATH ${OPENCV_INCLUDE_INSTALL_PATH}/opencv-${OPENCV_VERSION})
 260 endif()
 261
 262 if(WIN32)
 263   # Postfix of DLLs:
 264   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 265   set(OPENCV_DEBUG_POSTFIX d)
 266 else()
 267   # Postfix of so's:
 268   set(OPENCV_DLLVERSION "")
 269   set(OPENCV_DEBUG_POSTFIX "")
 270 endif()
 271
 272 if(DEFINED CMAKE_DEBUG_POSTFIX)
 273   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 274 endif()
 275
 276 if(CMAKE_VERBOSE)
 277   set(CMAKE_VERBOSE_MAKEFILE 1)
 278 endif()
 279
 280
 281 # ----------------------------------------------------------------------------
 282 #  Path for build/platform -specific headers
 283 # ----------------------------------------------------------------------------
 284 set(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 285 add_definitions(-DHAVE_CVCONFIG_H)
 286 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 287
 288
 289 # ----------------------------------------------------------------------------
 290 #  Autodetect if we are in a GIT repository
 291 # ----------------------------------------------------------------------------
 292
 293 # don't use FindGit because it requires CMake 2.8.2
 294 set(git_names git eg) # eg = easy git
 295 # Prefer .cmd variants on Windows unless running in a Makefile in the MSYS shell
 296 if(WIN32)
 297   if(NOT CMAKE_GENERATOR MATCHES "MSYS")
 298     set(git_names git.cmd git eg.cmd eg)
 299   endif()
 300 endif()
 301
 302 find_host_program(GIT_EXECUTABLE NAMES ${git_names} PATH_SUFFIXES Git/cmd Git/bin DOC "git command line client")
 303 mark_as_advanced(GIT_EXECUTABLE)
 304
 305 if(GIT_EXECUTABLE)
 306   execute_process(COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
 307     WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 308     OUTPUT_VARIABLE OPENCV_GIT_HASH_SORT
 309     RESULT_VARIABLE GIT_RESULT
 310     ERROR_QUIET
 311     OUTPUT_STRIP_TRAILING_WHITESPACE
 312   )
 313   if(GIT_RESULT EQUAL 0)
 314     set(OPENCV_VCSVERSION "commit:${OPENCV_GIT_HASH_SORT}")
 315   else()
 316     set(OPENCV_VCSVERSION "exported")
 317   endif()
 318 else()
 319   # We don't have git:
 320   set(OPENCV_VCSVERSION "")
 321 endif()
 322
 323
 324 # ----------------------------------------------------------------------------
 325 # OpenCV compiler and linker options
 326 # ----------------------------------------------------------------------------
 327 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 328 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 329   set(CMAKE_BUILD_TYPE Release)
 330 endif()
 331
 332 include(cmake/OpenCVCompilerOptions.cmake REQUIRED)
 333
 334
 335 # ----------------------------------------------------------------------------
 336 # Use statically or dynamically linked CRT?
 337 # Default: dynamic
 338 # ----------------------------------------------------------------------------
 339 if(MSVC)
 340   include(cmake/OpenCVCRTLinkage.cmake REQUIRED)
 341   add_definitions(-D_VARIADIC_MAX=10)
 342 endif(MSVC)
 343
 344
 345 # ----------------------------------------------------------------------------
 346 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 347 # ----------------------------------------------------------------------------
 348 if(UNIX)
 349   include(cmake/OpenCVFindPkgConfig.cmake OPTIONAL)
 350   include(CheckFunctionExists)
 351   include(CheckIncludeFile)
 352
 353   if(NOT APPLE)
 354     CHECK_INCLUDE_FILE(alloca.h HAVE_ALLOCA_H)
 355     CHECK_FUNCTION_EXISTS(alloca HAVE_ALLOCA)
 356     CHECK_INCLUDE_FILE(unistd.h HAVE_UNISTD_H)
 357     CHECK_INCLUDE_FILE(pthread.h HAVE_LIBPTHREAD)
 358     if(ANDROID)
 359       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 360     elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD|NetBSD|DragonFly")
 361       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 362     else()
 363       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 364     endif()
 365   else()
 366     add_definitions(-DHAVE_ALLOCA -DHAVE_ALLOCA_H -DHAVE_LIBPTHREAD -DHAVE_UNISTD_H)
 367   endif()
 368 endif()
 369
 370 include(cmake/OpenCVPCHSupport.cmake REQUIRED)
 371 include(cmake/OpenCVModule.cmake REQUIRED)
 372
 373 # ----------------------------------------------------------------------------
 374 #  Detect 3rd-party libraries
 375 # ----------------------------------------------------------------------------
 376
 377 include(cmake/OpenCVFindLibsGrfmt.cmake REQUIRED)
 378 include(cmake/OpenCVFindLibsGUI.cmake   REQUIRED)
 379 include(cmake/OpenCVFindLibsVideo.cmake REQUIRED)
 380 include(cmake/OpenCVFindLibsPerf.cmake  REQUIRED)
 381
 382
 383 # ----------------------------------------------------------------------------
 384 #  Detect other 3rd-party libraries/tools
 385 # ----------------------------------------------------------------------------
 386
 387 # --- LATEX for pdf documentation ---
 388 if(BUILD_DOCS)
 389   include(cmake/OpenCVFindLATEX.cmake REQUIRED)
 390 endif(BUILD_DOCS)
 391
 392 # --- Python Support ---
 393 include(cmake/OpenCVDetectPython.cmake REQUIRED)
 394
 395 # --- Java Support ---
 396 if(ANDROID)
 397   include(cmake/OpenCVDetectApacheAnt.cmake REQUIRED)
 398   include(cmake/OpenCVDetectAndroidSDK.cmake REQUIRED)
 399
 400   if(NOT ANDROID_TOOLS_Pkg_Revision GREATER 13)
 401     message(WARNING "OpenCV requires Android SDK tools revision 14 or newer. Otherwise tests and samples will no be compiled.")
 402   endif()
 403 endif(ANDROID)
 404
 405 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 406   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 407 else()
 408   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 409 endif()
 410
 411 # --- OpenCL ---
 412 if(WITH_OPENCL)
 413   include(cmake/OpenCVDetectOpenCL.cmake REQUIRED)
 414   if(OPENCL_FOUND)
 415     set(HAVE_OPENCL 1)
 416   endif()
 417   if(WITH_OPENCLAMDFFT)
 418     set(HAVE_CLAMDFFT 1)
 419   endif()
 420   if(WITH_OPENCLAMDBLAS)
 421     set(HAVE_CLAMDBLAS 1)
 422   endif()
 423 endif()
 424
 425 # ----------------------------------------------------------------------------
 426 # Solution folders:
 427 # ----------------------------------------------------------------------------
 428 if(ENABLE_SOLUTION_FOLDERS)
 429   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 430   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 431 endif()
 432
 433 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 434 include(cmake/OpenCVExtraTargets.cmake REQUIRED)
 435
 436
 437 # ----------------------------------------------------------------------------
 438 # Process subdirectories
 439 # ----------------------------------------------------------------------------
 440
 441 # opencv.hpp and legacy headers
 442 add_subdirectory(include)
 443
 444 # OpenCV modules
 445 add_subdirectory(modules)
 446
 447 # Generate targets for documentation
 448 add_subdirectory(doc)
 449
 450 # various data that is used by cv libraries and/or demo applications.
 451 add_subdirectory(data)
 452
 453 # extra applications
 454 add_subdirectory(apps)
 455
 456 # examples
 457 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES)
 458   add_subdirectory(samples)
 459 endif()
 460
 461 if(BUILD_ANDROID_SERVICE)
 462   add_subdirectory(android/service)
 463 endif()
 464
 465 if(BUILD_ANDROID_PACKAGE)
 466   add_subdirectory(android/package)
 467 endif()
 468
 469 # ----------------------------------------------------------------------------
 470 # Finalization: generate configuration-based files
 471 # ----------------------------------------------------------------------------
 472 ocv_track_build_dependencies()
 473
 474 # Generate platform-dependent and configuration-dependent headers
 475 include(cmake/OpenCVGenHeaders.cmake REQUIRED)
 476
 477 # Generate opencv.pc for pkg-config command
 478 include(cmake/OpenCVGenPkgconfig.cmake REQUIRED)
 479
 480 # Generate OpenCV.mk for ndk-build (Android build tool)
 481 include(cmake/OpenCVGenAndroidMK.cmake REQUIRED)
 482
 483 # Generate OpenCVСonfig.cmake and OpenCVConfig-version.cmake for cmake projects
 484 include(cmake/OpenCVGenConfig.cmake REQUIRED)
 485
 486
 487 # ----------------------------------------------------------------------------
 488 # Summary:
 489 # ----------------------------------------------------------------------------
 490 status("")
 491 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 492 if(OPENCV_VCSVERSION)
 493   status("  Version control:" ${OPENCV_VCSVERSION})
 494 endif()
 495
 496 # ========================== build platform ==========================
 497 status("")
 498 status("  Platform:")
 499 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
 500 if(CMAKE_CROSSCOMPILING)
 501   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
 502 endif()
 503 status("    CMake:"            ${CMAKE_VERSION})
 504 status("    CMake generator:"  ${CMAKE_GENERATOR})
 505 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
 506 if(MSVC)
 507   status("    MSVC:"           ${MSVC_VERSION})
 508 endif()
 509 if(CMAKE_GENERATOR MATCHES Xcode)
 510   status("    Xcode:"          ${XCODE_VERSION})
 511 endif()
 512 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
 513   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
 514 endif()
 515
 516 # ========================== C/C++ options ==========================
 517 status("")
 518 status("  C/C++:")
 519 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
 520 status("    C++ Compiler:"           CMAKE_COMPILER_IS_GNUCXX THEN "${CMAKE_CXX_COMPILER} (ver ${CMAKE_GCC_REGEX_VERSION})" ELSE "${CMAKE_CXX_COMPILER}" )
 521 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
 522 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
 523 status("    C Compiler:"             ${CMAKE_C_COMPILER})
 524 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
 525 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
 526 if(WIN32)
 527   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
 528   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
 529 else()
 530   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
 531   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
 532 endif()
 533 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
 534
 535 # ========================== OpenCV modules ==========================
 536 status("")
 537 status("  OpenCV modules:")
 538 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD}")
 539 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
 540 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
 541 set(OPENCV_MODULES_DISABLED_AUTO_ST "")
 542 foreach(m ${OPENCV_MODULES_DISABLED_AUTO})
 543   set(__mdeps "")
 544   foreach(d ${OPENCV_MODULE_${m}_DEPS})
 545     if(d MATCHES "^opencv_" AND NOT HAVE_${d})
 546       list(APPEND __mdeps ${d})
 547     endif()
 548   endforeach()
 549   list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}(deps: ${__mdeps})")
 550 endforeach()
 551 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO_ST}")
 552
 553 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
 554 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
 555 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
 556 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
 557
 558 # ========================== Android details ==========================
 559 if(ANDROID)
 560   status("")
 561   status("  Android: ")
 562   status("    Android ABI:" ${ANDROID_ABI})
 563   status("    Native API level:" android-${ANDROID_NATIVE_API_LEVEL})
 564   status("    SDK target:" "${ANDROID_SDK_TARGET}")
 565   if(BUILD_WITH_ANDROID_NDK)
 566     status("    Android NDK:" "${ANDROID_NDK} (toolchain: ${ANDROID_TOOLCHAIN_NAME})")
 567   elseif(BUILD_WITH_STANDALONE_TOOLCHAIN)
 568     status("    Android toolchain:" "${ANDROID_STANDALONE_TOOLCHAIN}")
 569   endif()
 570   status("    android tool:"  ANDROID_EXECUTABLE  THEN "${ANDROID_EXECUTABLE} (${ANDROID_TOOLS_Pkg_Desc})" ELSE NO)
 571   status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"            ELSE NO)
 572   status("    Google Play package:" BUILD_ANDROID_PACKAGE THEN YES ELSE NO)
 573 endif()
 574
 575 # ========================== GUI ==========================
 576 status("")
 577 status("  GUI: ")
 578
 579 if(HAVE_QT)
 580   status("    QT 4.x:"            HAVE_QT        THEN "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})" ELSE NO)
 581   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
 582 else()
 583   if(DEFINED WITH_QT)
 584     status("    QT 4.x:" NO)
 585   endif()
 586   if(WIN32)
 587     status("    Win32 UI:" YES)
 588   else()
 589     if(APPLE)
 590       if(WITH_CARBON)
 591         status("    Carbon:" YES)
 592       else()
 593         status("    Cocoa:"  YES)
 594       endif()
 595     else()
 596       status("    GTK+ 2.x:" HAVE_GTK      THEN "YES (ver ${ALIASOF_gtk+-2.0_VERSION})"     ELSE NO)
 597       status("    GThread :" HAVE_GTHREAD  THEN "YES (ver ${ALIASOF_gthread-2.0_VERSION})"  ELSE NO)
 598       status("    GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${ALIASOF_gtkglext-1.0_VERSION})" ELSE NO)
 599     endif()
 600   endif()
 601 endif()
 602
 603 status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
 604
 605 # ========================== MEDIA IO ==========================
 606 status("")
 607 status("  Media I/O: ")
 608 status("    ZLib:"         BUILD_ZLIB    THEN "build (ver ${ZLIB_VERSION_STRING})"               ELSE "${ZLIB_LIBRARY} (ver ${ZLIB_VERSION_STRING})")
 609
 610 if(WITH_JPEG)
 611   status("    JPEG:"       JPEG_FOUND    THEN "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})"        ELSE "build (ver ${JPEG_LIB_VERSION})")
 612 else()
 613   status("    JPEG:"       "NO")
 614 endif()
 615 if(WITH_PNG)
 616   status("    PNG:"        PNG_FOUND     THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})"              ELSE "build (ver ${PNG_VERSION})")
 617 else()
 618   status("    PNG:"        "NO")
 619 endif()
 620 if(WITH_TIFF)
 621   if(TIFF_VERSION_STRING AND TIFF_FOUND)
 622     status("    TIFF:"     "${TIFF_LIBRARY} (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 623   else()
 624     status("    TIFF:"     TIFF_FOUND    THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION})"            ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 625   endif()
 626 else()
 627   status("    TIFF:"       "NO")
 628 endif()
 629 if(WITH_JASPER)
 630   status("    JPEG 2000:"  JASPER_FOUND  THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
 631 else()
 632   status("    JPEG 2000:"  "NO")
 633 endif()
 634
 635 status("    OpenEXR:"   WITH_OPENEXR AND OPENEXR_FOUND     THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})"                     ELSE NO)
 636
 637 # ========================== VIDEO IO ==========================
 638 status("")
 639 status("  Video I/O:")
 640
 641 if(DEFINED WITH_1394)
 642   status("    DC1394 1.x:"     HAVE_DC1394         THEN "YES (ver ${ALIASOF_libdc1394_VERSION})"   ELSE NO)
 643   status("    DC1394 2.x:"     HAVE_DC1394_2       THEN "YES (ver ${ALIASOF_libdc1394-2_VERSION})" ELSE NO)
 644 endif(DEFINED WITH_1394)
 645
 646 if(ANDROID)
 647   if(HAVE_opencv_androidcamera)
 648     status("    AndroidNativeCamera:" BUILD_ANDROID_CAMERA_WRAPPER
 649                                                    THEN "YES, build for Android${ANDROID_VERSION}" ELSE "YES, use prebuilt libraries")
 650   else()
 651     status("    AndroidNativeCamera:" "NO (native camera requires Android API level 8 or higher)")
 652   endif()
 653 endif()
 654
 655 if(DEFINED WITH_AVFOUNDATION)
 656   status("    AVFoundation:"   WITH_AVFOUNDATION   THEN YES                                        ELSE NO)
 657 endif(DEFINED WITH_AVFOUNDATION)
 658
 659 if(DEFINED WITH_FFMPEG)
 660   if(WIN32)
 661     status("    FFMPEG:"       WITH_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
 662   else()
 663     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
 664   endif()
 665   status("      codec:"        HAVE_FFMPEG_CODEC   THEN "YES (ver ${ALIASOF_libavcodec_VERSION})"  ELSE NO)
 666   status("      format:"       HAVE_FFMPEG_FORMAT  THEN "YES (ver ${ALIASOF_libavformat_VERSION})" ELSE NO)
 667   status("      util:"         HAVE_FFMPEG_UTIL    THEN "YES (ver ${ALIASOF_libavutil_VERSION})"   ELSE NO)
 668   status("      swscale:"      HAVE_FFMPEG_SWSCALE THEN "YES (ver ${ALIASOF_libswscale_VERSION})"  ELSE NO)
 669   status("      gentoo-style:" HAVE_GENTOO_FFMPEG  THEN YES                                        ELSE NO)
 670 endif(DEFINED WITH_FFMPEG)
 671
 672 if(DEFINED WITH_GSTREAMER)
 673   status("    GStreamer:"      HAVE_GSTREAMER      THEN ""                                         ELSE NO)
 674   if(HAVE_GSTREAMER)
 675     status("      base:"       "YES (ver ${ALIASOF_gstreamer-base-0.10_VERSION})")
 676     status("      app:"        "YES (ver ${ALIASOF_gstreamer-app-0.10_VERSION})")
 677     status("      video:"      "YES (ver ${ALIASOF_gstreamer-video-0.10_VERSION})")
 678   endif()
 679 endif(DEFINED WITH_GSTREAMER)
 680
 681 if(DEFINED WITH_OPENNI)
 682   status("    OpenNI:"         HAVE_OPENNI         THEN "YES (ver ${OPENNI_VERSION_STRING}, build ${OPENNI_VERSION_BUILD})"
 683                                                                                                    ELSE NO)
 684   status("    OpenNI PrimeSensor Modules:" HAVE_OPENNI_PRIME_SENSOR_MODULE
 685                                                    THEN "YES (${OPENNI_PRIME_SENSOR_MODULE})"      ELSE NO)
 686 endif(DEFINED WITH_OPENNI)
 687
 688 if(DEFINED WITH_PVAPI)
 689   status("    PvAPI:"          HAVE_PVAPI          THEN YES                                        ELSE NO)
 690 endif(DEFINED WITH_PVAPI)
 691
 692 if(DEFINED WITH_QUICKTIME)
 693   status("    QuickTime:"      WITH_QUICKTIME      THEN YES                                        ELSE NO)
 694   status("    QTKit:"          WITH_QUICKTIME      THEN NO                                         ELSE YES)
 695 endif(DEFINED WITH_QUICKTIME)
 696
 697 if(DEFINED WITH_UNICAP)
 698   status("    UniCap:"         HAVE_UNICAP         THEN "YES (ver ${ALIASOF_libunicap_VERSION})"   ELSE NO)
 699   status("    UniCap ucil:"    HAVE_UNICAP_UCIL    THEN "YES (ver ${ALIASOF_libucil_VERSION})"     ELSE NO)
 700 endif(DEFINED WITH_UNICAP)
 701
 702 if(DEFINED WITH_V4L)
 703   if(HAVE_CAMV4L)
 704     set(HAVE_CAMV4L_STR "YES")
 705   else()
 706     set(HAVE_CAMV4L_STR "NO")
 707   endif()
 708   if(HAVE_CAMV4L2)
 709     set(HAVE_CAMV4L2_STR "YES")
 710   else()
 711     set(HAVE_CAMV4L2_STR "NO")
 712   endif()
 713   status("    V4L/V4L2:"       HAVE_LIBV4L         THEN "Using libv4l (ver ${ALIASOF_libv4l1_VERSION})"
 714                                                                                                    ELSE "${HAVE_CAMV4L_STR}/${HAVE_CAMV4L2_STR}")
 715 endif(DEFINED WITH_V4L)
 716
 717 if(DEFINED WITH_VIDEOINPUT)
 718   status("    DirectShow:"     HAVE_VIDEOINPUT     THEN YES                                        ELSE NO)
 719 endif(DEFINED WITH_VIDEOINPUT)
 720
 721 if(DEFINED WITH_XIMEA)
 722   status("    XIMEA:"          HAVE_XIMEA          THEN YES                                        ELSE NO)
 723 endif(DEFINED WITH_XIMEA)
 724
 725 if(DEFINED WITH_XINE)
 726   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${ALIASOF_libxine_VERSION})"     ELSE NO)
 727 endif(DEFINED WITH_XINE)
 728
 729 # ========================== Other third-party libraries ==========================
 730 status("")
 731 status("  Other third-party libraries:")
 732
 733 if(DEFINED WITH_IPP)
 734   if(WITH_IPP AND IPP_FOUND)
 735     status("    Use IPP:" "${IPP_LATEST_VERSION_STR} [${IPP_LATEST_VERSION_MAJOR}.${IPP_LATEST_VERSION_MINOR}.${IPP_LATEST_VERSION_BUILD}]")
 736     status("         at:" "${IPP_ROOT_DIR}")
 737   else()
 738     status("    Use IPP:"   WITH_IPP AND NOT IPP_FOUND THEN "IPP not found" ELSE NO)
 739   endif()
 740 endif(DEFINED WITH_IPP)
 741
 742 if(DEFINED WITH_TBB)
 743   status("    Use TBB:"   HAVE_TBB   THEN "YES (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})" ELSE NO)
 744 endif(DEFINED WITH_TBB)
 745
 746 if(DEFINED WITH_CUDA)
 747   status("    Use Cuda:"  HAVE_CUDA  THEN "YES (ver ${CUDA_VERSION_STRING})" ELSE NO)
 748 endif(DEFINED WITH_CUDA)
 749
 750 status("    Use OpenCL:"  HAVE_OPENCL  THEN YES ELSE NO)
 751
 752 status("    Use Eigen:" HAVE_EIGEN THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
 753 status("    Use Clp:"   HAVE_CLP   THEN YES ELSE NO)
 754
 755 if(HAVE_CUDA)
 756   status("")
 757   status("  NVIDIA CUDA:"            "(ver ${CUDA_VERSION_STRING})")
 758
 759   status("    Use CUFFT:"            HAVE_CUFFT  THEN YES ELSE NO)
 760   status("    Use CUBLAS:"           HAVE_CUBLAS THEN YES ELSE NO)
 761   status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
 762   status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_BIN})
 763 endif()
 764
 765 # ========================== python ==========================
 766 status("")
 767 status("  Python:")
 768 status("    Interpreter:"   PYTHON_EXECUTABLE     THEN "${PYTHON_EXECUTABLE} (ver ${PYTHON_VERSION_FULL})"         ELSE NO)
 769 if(BUILD_opencv_python)
 770   if(PYTHONLIBS_VERSION_STRING)
 771     status("    Libraries:"     HAVE_opencv_python  THEN  "${PYTHON_LIBRARIES} (ver ${PYTHONLIBS_VERSION_STRING})" ELSE NO)
 772   else()
 773     status("    Libraries:"     HAVE_opencv_python  THEN  ${PYTHON_LIBRARIES}                                      ELSE NO)
 774   endif()
 775   status("    numpy:"         PYTHON_USE_NUMPY    THEN "${PYTHON_NUMPY_INCLUDE_DIR} (ver ${PYTHON_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
 776   status("    packages path:" PYTHON_EXECUTABLE   THEN "${PYTHON_PACKAGES_PATH}"                                   ELSE "-")
 777 endif()
 778
 779 # ========================== documentation ==========================
 780 if(BUILD_DOCS)
 781   status("")
 782   status("  Documentation:")
 783   if(HAVE_SPHINX)
 784     status("    Build Documentation:" PDFLATEX_COMPILER      THEN YES ELSE "YES (only HTML and without math expressions)")
 785   else()
 786     status("    Build Documentation:" NO)
 787   endif()
 788   status("    Sphinx:"              HAVE_SPHINX              THEN "${SPHINX_BUILD} (ver ${SPHINX_VERSION})" ELSE NO)
 789   status("    PdfLaTeX compiler:"   PDFLATEX_COMPILER        THEN "${PDFLATEX_COMPILER}" ELSE NO)
 790 endif()
 791
 792 # ========================== samples and tests ==========================
 793 status("")
 794 status("  Tests and samples:")
 795 status("    Tests:"             BUILD_TESTS AND HAVE_opencv_ts       THEN YES ELSE NO)
 796 status("    Performance tests:" BUILD_PERF_TESTS AND HAVE_opencv_ts  THEN YES ELSE NO)
 797 status("    Examples:"          BUILD_EXAMPLES                       THEN YES ELSE NO)
 798
 799 if(ANDROID)
 800   status("    Android tests:"    BUILD_TESTS AND CAN_BUILD_ANDROID_PROJECTS            THEN YES ELSE NO)
 801   status("    Android examples:" BUILD_ANDROID_EXAMPLES AND CAN_BUILD_ANDROID_PROJECTS THEN YES ELSE NO)
 802 endif()
 803
 804 # ========================== auxiliary ==========================
 805 status("")
 806 status("  Install path:" "${CMAKE_INSTALL_PREFIX}")
 807 status("")
 808 status("  cvconfig.h is in:" "${OPENCV_CONFIG_FILE_INCLUDE_DIR}")
 809 status("-----------------------------------------------------------------")
 810 status("")
 811
 812 ocv_finalize_status()
 813
 814 # ----------------------------------------------------------------------------
 815 # Warn in the case of in-source build
 816 # ----------------------------------------------------------------------------
 817 if("${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 818   message(WARNING "The source directory is the same as binary directory. \"make clean\" may damage the source tree")
 819 endif()
 820