CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 # ----------------------------------------------------------------------------
   8
   9 include(cmake/OpenCVMinDepVersions.cmake)
  10
  11 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  12   cmake_minimum_required(VERSION 2.8.8 FATAL_ERROR)
  13 else()
  14   cmake_minimum_required(VERSION "${MIN_VER_CMAKE}" FATAL_ERROR)
  15 endif()
  16
  17 # Following block can broke build in case of cross-compilng
  18 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  19 # so we will try to detect crosscompiling by presense of CMAKE_TOOLCHAIN_FILE
  20 if(NOT CMAKE_TOOLCHAIN_FILE)
  21   # it _must_ go before project(OpenCV) in order to work
  22   if(WIN32)
  23     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  24   else()
  25     set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  26   endif()
  27 else(NOT CMAKE_TOOLCHAIN_FILE)
  28   #Android: set output folder to ${CMAKE_BINARY_DIR}
  29   set( LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  30   # any crosscompiling
  31   set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  32 endif(NOT CMAKE_TOOLCHAIN_FILE)
  33
  34
  35 # must go before the project command
  36 set(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  37 if(DEFINED CMAKE_BUILD_TYPE)
  38   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
  39 endif()
  40
  41 project(OpenCV CXX C)
  42
  43 if(MSVC)
  44   set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
  45 endif()
  46
  47 include(cmake/OpenCVUtils.cmake)
  48
  49 ocv_clear_vars(OpenCVModules_TARGETS)
  50
  51 # ----------------------------------------------------------------------------
  52 # Break in case of popular CMake configuration mistakes
  53 # ----------------------------------------------------------------------------
  54 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
  55   message(FATAL_ERROR "CMake fails to deterimine the bitness of target platform.
  56   Please check your CMake and compiler installation. If you are crosscompiling then ensure that your CMake toolchain file correctly sets the compiler details.")
  57 endif()
  58
  59 # ----------------------------------------------------------------------------
  60 # Detect compiler and target platform architecture
  61 # ----------------------------------------------------------------------------
  62 include(cmake/OpenCVDetectCXXCompiler.cmake)
  63
  64 # Add these standard paths to the search paths for FIND_LIBRARY
  65 # to find libraries from these locations first
  66 if(UNIX AND NOT ANDROID)
  67   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
  68     if(EXISTS /lib64)
  69       list(APPEND CMAKE_LIBRARY_PATH /lib64)
  70     else()
  71       list(APPEND CMAKE_LIBRARY_PATH /lib)
  72     endif()
  73     if(EXISTS /usr/lib64)
  74       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
  75     else()
  76       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
  77     endif()
  78   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
  79     if(EXISTS /lib32)
  80       list(APPEND CMAKE_LIBRARY_PATH /lib32)
  81     else()
  82       list(APPEND CMAKE_LIBRARY_PATH /lib)
  83     endif()
  84     if(EXISTS /usr/lib32)
  85       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
  86     else()
  87       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
  88     endif()
  89   endif()
  90 endif()
  91
  92 # Add these standard paths to the search paths for FIND_PATH
  93 # to find include files from these locations first
  94 if(MINGW)
  95   if(EXISTS /mingw)
  96       list(APPEND CMAKE_INCLUDE_PATH /mingw)
  97   endif()
  98   if(EXISTS /mingw32)
  99       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
 100   endif()
 101   if(EXISTS /mingw64)
 102       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 103   endif()
 104 endif()
 105
 106 # ----------------------------------------------------------------------------
 107 # OpenCV cmake options
 108 # ----------------------------------------------------------------------------
 109
 110 # Optional 3rd party components
 111 # ===================================================
 112 OCV_OPTION(WITH_1394           "Include IEEE1394 support"                    ON   IF (NOT ANDROID AND NOT IOS) )
 113 OCV_OPTION(WITH_AVFOUNDATION   "Use AVFoundation for Video I/O"              ON   IF IOS)
 114 OCV_OPTION(WITH_CARBON         "Use Carbon for UI instead of Cocoa"          OFF  IF APPLE )
 115 OCV_OPTION(WITH_CUDA           "Include NVidia Cuda Runtime support"                                         ON  IF (NOT ANDROID AND NOT IOS) )
 116 OCV_OPTION(WITH_CUFFT          "Include NVidia Cuda Fast Fourier Transform (FFT) library support"            ON  IF (NOT ANDROID AND NOT IOS) )
 117 OCV_OPTION(WITH_CUBLAS         "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" OFF IF (NOT ANDROID AND NOT IOS) )
 118 OCV_OPTION(WITH_NVCUVID        "Include NVidia Video Decoding library support"                               OFF IF (NOT ANDROID AND NOT IOS AND NOT APPLE) )
 119 OCV_OPTION(WITH_EIGEN          "Include Eigen2/Eigen3 support"               ON)
 120 OCV_OPTION(WITH_VFW            "Include Video for Windows support"           ON   IF WIN32 )
 121 OCV_OPTION(WITH_FFMPEG         "Include FFMPEG support"                      ON   IF (NOT ANDROID AND NOT IOS))
 122 OCV_OPTION(WITH_GSTREAMER      "Include Gstreamer support"                   ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 123 OCV_OPTION(WITH_GSTREAMER_1_X  "Include Gstreamer 1.x support"               OFF)
 124 OCV_OPTION(WITH_GTK            "Include GTK support"                         ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 125 OCV_OPTION(WITH_IPP            "Include Intel IPP support"                   OFF  IF (MSVC OR X86 OR X86_64) )
 126 OCV_OPTION(WITH_JASPER         "Include JPEG2K support"                      ON   IF (NOT IOS) )
 127 OCV_OPTION(WITH_JPEG           "Include JPEG support"                        ON)
 128 OCV_OPTION(WITH_WEBP           "Include WebP support"                        ON   IF (NOT IOS) )
 129 OCV_OPTION(WITH_OPENEXR        "Include ILM support via OpenEXR"             ON   IF (NOT IOS) )
 130 OCV_OPTION(WITH_OPENGL         "Include OpenGL support"                      OFF  IF (NOT ANDROID AND NOT APPLE) )
 131 OCV_OPTION(WITH_OPENNI         "Include OpenNI support"                      OFF  IF (NOT ANDROID AND NOT IOS) )
 132 OCV_OPTION(WITH_PNG            "Include PNG support"                         ON)
 133 OCV_OPTION(WITH_PVAPI          "Include Prosilica GigE support"              ON   IF (NOT ANDROID AND NOT IOS) )
 134 OCV_OPTION(WITH_GIGEAPI        "Include Smartek GigE support"                ON   IF (NOT ANDROID AND NOT IOS) )
 135 OCV_OPTION(WITH_QT             "Build with Qt Backend support"               OFF  IF (NOT ANDROID AND NOT IOS) )
 136 OCV_OPTION(WITH_WIN32UI        "Build with Win32 UI Backend support"         ON   IF WIN32 )
 137 OCV_OPTION(WITH_QUICKTIME      "Use QuickTime for Video I/O insted of QTKit" OFF  IF APPLE )
 138 OCV_OPTION(WITH_TBB            "Include Intel TBB support"                   OFF  IF (NOT IOS) )
 139 OCV_OPTION(WITH_CSTRIPES       "Include C= support"                          OFF  IF WIN32 )
 140 OCV_OPTION(WITH_TIFF           "Include TIFF support"                        ON   IF (NOT IOS) )
 141 OCV_OPTION(WITH_UNICAP         "Include Unicap support (GPL)"                OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 142 OCV_OPTION(WITH_V4L            "Include Video 4 Linux support"               ON   IF (UNIX AND NOT ANDROID) )
 143 OCV_OPTION(WITH_LIBV4L         "Use libv4l for Video 4 Linux support"        ON   IF (UNIX AND NOT ANDROID) )
 144 OCV_OPTION(WITH_DSHOW          "Build HighGUI with DirectShow support"       ON   IF (WIN32 AND NOT ARM) )
 145 OCV_OPTION(WITH_MSMF           "Build HighGUI with Media Foundation support" OFF  IF WIN32 )
 146 OCV_OPTION(WITH_XIMEA          "Include XIMEA cameras support"               OFF  IF (NOT ANDROID AND NOT APPLE) )
 147 OCV_OPTION(WITH_XINE           "Include Xine support (GPL)"                  OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 148 OCV_OPTION(WITH_CLP            "Include Clp support (EPL)"                   OFF)
 149 OCV_OPTION(WITH_OPENCL         "Include OpenCL Runtime support"              ON  IF (NOT ANDROID AND NOT IOS) )
 150 OCV_OPTION(WITH_OPENCLAMDFFT   "Include AMD OpenCL FFT library support"      ON  IF (NOT ANDROID AND NOT IOS) )
 151 OCV_OPTION(WITH_OPENCLAMDBLAS  "Include AMD OpenCL BLAS library support"     ON  IF (NOT ANDROID AND NOT IOS) )
 152
 153
 154 # OpenCV build components
 155 # ===================================================
 156 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR IOS) )
 157 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID) IF (NOT IOS) )
 158 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 159 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" ON )
 160 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 161 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON )
 162 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     ON  IF (NOT IOS) )
 163 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           ON  IF (NOT IOS) )
 164 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into debug libs (not MSCV only)" ON )
 165 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of staticaly linked CRT for staticaly linked OpenCV" ON IF MSVC )
 166 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create fat java wrapper containing the whole OpenCV library" ON IF NOT BUILD_SHARED_LIBS AND CMAKE_COMPILER_IS_GNUCXX )
 167 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID AND ANDROID_SOURCE_TREE )
 168 OCV_OPTION(BUILD_ANDROID_PACKAGE    "Build platform-specific package for Google Play" OFF IF ANDROID )
 169
 170 # 3rd party libs
 171 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             WIN32 OR APPLE )
 172 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          WIN32 OR ANDROID OR APPLE )
 173 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        WIN32 OR ANDROID OR APPLE )
 174 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          WIN32 OR ANDROID OR APPLE )
 175 OCV_OPTION(BUILD_PNG                "Build libpng from source"           WIN32 OR ANDROID OR APPLE )
 176 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          WIN32 OR ANDROID OR APPLE )
 177 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" ANDROID )
 178
 179 # OpenCV installation options
 180 # ===================================================
 181 OCV_OPTION(INSTALL_CREATE_DISTRIB   "Change install rules to build the distribution package" OFF )
 182 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 183 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 184 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 185 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT IOS AND BUILD_SHARED_LIBS) )
 186
 187
 188 # OpenCV build options
 189 # ===================================================
 190 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON   IF (NOT IOS) )
 191 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) )
 192 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CMAKE_COMPILER_IS_GNUCXX )
 193 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CMAKE_COMPILER_IS_GNUCXX AND NOT (APPLE AND CMAKE_COMPILER_IS_CLANGCXX) )
 194 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CMAKE_COMPILER_IS_GNUCXX AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 195 OCV_OPTION(ENABLE_FAST_MATH           "Enable -ffast-math (not recommended for GCC 4.6.x)"       OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 196 OCV_OPTION(ENABLE_SSE                 "Enable SSE instructions"                                  ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 197 OCV_OPTION(ENABLE_SSE2                "Enable SSE2 instructions"                                 ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 198 OCV_OPTION(ENABLE_SSE3                "Enable SSE3 instructions"                                 ON   IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 199 OCV_OPTION(ENABLE_SSSE3               "Enable SSSE3 instructions"                                OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 200 OCV_OPTION(ENABLE_SSE41               "Enable SSE4.1 instructions"                               OFF  IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 201 OCV_OPTION(ENABLE_SSE42               "Enable SSE4.2 instructions"                               OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 202 OCV_OPTION(ENABLE_AVX                 "Enable AVX instructions"                                  OFF  IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 203 OCV_OPTION(ENABLE_NEON                "Enable NEON instructions"                                 OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND ARM) )
 204 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 205 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 206 OCV_OPTION(ENABLE_WINRT_MODE          "Build with Windows Runtime support"                       OFF  IF WIN32 )
 207
 208
 209 # ----------------------------------------------------------------------------
 210 #  Get actual OpenCV version number from sources
 211 # ----------------------------------------------------------------------------
 212 include(cmake/OpenCVVersion.cmake)
 213
 214
 215 # ----------------------------------------------------------------------------
 216 #  Build & install layouts
 217 # ----------------------------------------------------------------------------
 218
 219 # Save libs and executables in the same place
 220 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications" )
 221
 222 if(ANDROID OR WIN32)
 223   set(OPENCV_DOC_INSTALL_PATH doc)
 224 elseif(INSTALL_TO_MANGLED_PATHS)
 225   set(OPENCV_DOC_INSTALL_PATH share/OpenCV-${OPENCV_VERSION}/doc)
 226 else()
 227   set(OPENCV_DOC_INSTALL_PATH share/OpenCV/doc)
 228 endif()
 229
 230 if(WIN32)
 231   if(DEFINED OpenCV_RUNTIME AND DEFINED OpenCV_ARCH)
 232     set(OpenCV_INSTALL_BINARIES_PREFIX "${OpenCV_ARCH}/${OpenCV_RUNTIME}/")
 233   else()
 234     message(STATUS "Can't detect runtime and/or arch")
 235     set(OpenCV_INSTALL_BINARIES_PREFIX "")
 236   endif()
 237 else()
 238   set(OpenCV_INSTALL_BINARIES_PREFIX "")
 239 endif()
 240
 241 set(OPENCV_SAMPLES_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}samples")
 242
 243 set(OPENCV_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}bin")
 244
 245 if(ANDROID)
 246   set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 247   set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 248   set(OPENCV_LIB_INSTALL_PATH     sdk/native/libs/${ANDROID_NDK_ABI_NAME})
 249   set(OPENCV_3P_LIB_INSTALL_PATH  sdk/native/3rdparty/libs/${ANDROID_NDK_ABI_NAME})
 250   set(OPENCV_CONFIG_INSTALL_PATH  sdk/native/jni)
 251   set(OPENCV_INCLUDE_INSTALL_PATH sdk/native/jni/include)
 252 else()
 253   set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib")
 254   set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib${LIB_SUFFIX}")
 255   if(WIN32)
 256     if(OpenCV_STATIC)
 257       set(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 258     else()
 259       set(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}lib${LIB_SUFFIX}")
 260     endif()
 261     set(OPENCV_3P_LIB_INSTALL_PATH  "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 262   else()
 263     set(OPENCV_LIB_INSTALL_PATH     lib${LIB_SUFFIX})
 264     set(OPENCV_3P_LIB_INSTALL_PATH  share/OpenCV/3rdparty/${OPENCV_LIB_INSTALL_PATH})
 265   endif()
 266   set(OPENCV_INCLUDE_INSTALL_PATH "include")
 267
 268   math(EXPR SIZEOF_VOID_P_BITS "8 * ${CMAKE_SIZEOF_VOID_P}")
 269   if(LIB_SUFFIX AND NOT SIZEOF_VOID_P_BITS EQUAL LIB_SUFFIX)
 270     set(OPENCV_CONFIG_INSTALL_PATH lib${LIB_SUFFIX}/cmake/opencv)
 271   else()
 272     set(OPENCV_CONFIG_INSTALL_PATH share/OpenCV)
 273   endif()
 274 endif()
 275
 276 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 277 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 278
 279 if(INSTALL_TO_MANGLED_PATHS)
 280   set(OPENCV_INCLUDE_INSTALL_PATH ${OPENCV_INCLUDE_INSTALL_PATH}/opencv-${OPENCV_VERSION})
 281 endif()
 282
 283 if(WIN32)
 284   # Postfix of DLLs:
 285   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 286   set(OPENCV_DEBUG_POSTFIX d)
 287 else()
 288   # Postfix of so's:
 289   set(OPENCV_DLLVERSION "")
 290   set(OPENCV_DEBUG_POSTFIX "")
 291 endif()
 292
 293 if(DEFINED CMAKE_DEBUG_POSTFIX)
 294   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 295 endif()
 296
 297
 298 # ----------------------------------------------------------------------------
 299 #  Path for build/platform -specific headers
 300 # ----------------------------------------------------------------------------
 301 set(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 302 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 303
 304 # ----------------------------------------------------------------------------
 305 #  Path for additional modules
 306 # ----------------------------------------------------------------------------
 307 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules")
 308
 309 # ----------------------------------------------------------------------------
 310 #  Autodetect if we are in a GIT repository
 311 # ----------------------------------------------------------------------------
 312 find_host_package(Git QUIET)
 313
 314 if(GIT_FOUND)
 315   execute_process(COMMAND "${GIT_EXECUTABLE}" describe --tags --always --dirty --match "2.[0-9].[0-9]*"
 316     WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 317     OUTPUT_VARIABLE OPENCV_VCSVERSION
 318     RESULT_VARIABLE GIT_RESULT
 319     ERROR_QUIET
 320     OUTPUT_STRIP_TRAILING_WHITESPACE
 321   )
 322   if(NOT GIT_RESULT EQUAL 0)
 323     set(OPENCV_VCSVERSION "unknown")
 324   endif()
 325 else()
 326   # We don't have git:
 327   set(OPENCV_VCSVERSION "unknown")
 328 endif()
 329
 330
 331 # ----------------------------------------------------------------------------
 332 # OpenCV compiler and linker options
 333 # ----------------------------------------------------------------------------
 334 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 335 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 336   set(CMAKE_BUILD_TYPE Release)
 337 endif()
 338
 339 include(cmake/OpenCVCompilerOptions.cmake)
 340
 341
 342 # ----------------------------------------------------------------------------
 343 # Use statically or dynamically linked CRT?
 344 # Default: dynamic
 345 # ----------------------------------------------------------------------------
 346 if(MSVC)
 347   include(cmake/OpenCVCRTLinkage.cmake)
 348 endif(MSVC)
 349
 350 if(WIN32 AND NOT MINGW)
 351   add_definitions(-D_VARIADIC_MAX=10)
 352 endif(WIN32 AND NOT MINGW)
 353
 354
 355 # ----------------------------------------------------------------------------
 356 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 357 # ----------------------------------------------------------------------------
 358 if(UNIX)
 359   find_package(PkgConfig QUIET)
 360   include(CheckFunctionExists)
 361   include(CheckIncludeFile)
 362
 363   if(NOT APPLE)
 364     CHECK_INCLUDE_FILE(pthread.h HAVE_LIBPTHREAD)
 365     if(ANDROID)
 366       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 367     elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD|NetBSD|DragonFly")
 368       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 369     else()
 370       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 371     endif()
 372   else()
 373     set(HAVE_LIBPTHREAD YES)
 374   endif()
 375 endif()
 376
 377 include(cmake/OpenCVPCHSupport.cmake)
 378 include(cmake/OpenCVModule.cmake)
 379
 380 # ----------------------------------------------------------------------------
 381 #  Detect 3rd-party libraries
 382 # ----------------------------------------------------------------------------
 383
 384 include(cmake/OpenCVFindLibsGrfmt.cmake)
 385 include(cmake/OpenCVFindLibsGUI.cmake)
 386 include(cmake/OpenCVFindLibsVideo.cmake)
 387 include(cmake/OpenCVFindLibsPerf.cmake)
 388
 389
 390 # ----------------------------------------------------------------------------
 391 #  Detect other 3rd-party libraries/tools
 392 # ----------------------------------------------------------------------------
 393
 394 # --- LATEX for pdf documentation ---
 395 if(BUILD_DOCS)
 396   include(cmake/OpenCVFindLATEX.cmake)
 397 endif(BUILD_DOCS)
 398
 399 # --- Python Support ---
 400 include(cmake/OpenCVDetectPython.cmake)
 401
 402 # --- Java Support ---
 403 include(cmake/OpenCVDetectApacheAnt.cmake)
 404 if(ANDROID)
 405   include(cmake/OpenCVDetectAndroidSDK.cmake)
 406
 407   if(NOT ANDROID_TOOLS_Pkg_Revision GREATER 13)
 408     message(WARNING "OpenCV requires Android SDK tools revision 14 or newer. Otherwise tests and samples will no be compiled.")
 409   endif()
 410 else()
 411   find_package(JNI)
 412 endif()
 413
 414 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 415   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 416 else()
 417   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 418 endif()
 419
 420 # --- OpenCL ---
 421 if(WITH_OPENCL)
 422   include(cmake/OpenCVDetectOpenCL.cmake)
 423 endif()
 424
 425 # --- Matlab/Octave ---
 426 include(cmake/OpenCVFindMatlab.cmake)
 427
 428 # ----------------------------------------------------------------------------
 429 # Add CUDA libraries (needed for apps/tools, samples)
 430 # ----------------------------------------------------------------------------
 431 if(HAVE_CUDA)
 432   set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_LIBRARIES} ${CUDA_npp_LIBRARY})
 433   if(HAVE_CUBLAS)
 434     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cublas_LIBRARY})
 435   endif()
 436   if(HAVE_CUFFT)
 437     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cufft_LIBRARY})
 438   endif()
 439 endif()
 440 # ----------------------------------------------------------------------------
 441 # Solution folders:
 442 # ----------------------------------------------------------------------------
 443 if(ENABLE_SOLUTION_FOLDERS)
 444   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 445   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 446 endif()
 447
 448 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 449 include(cmake/OpenCVExtraTargets.cmake)
 450
 451
 452 # ----------------------------------------------------------------------------
 453 # Process subdirectories
 454 # ----------------------------------------------------------------------------
 455
 456 # opencv.hpp and legacy headers
 457 add_subdirectory(include)
 458
 459 # OpenCV modules
 460 add_subdirectory(modules)
 461
 462 # Generate targets for documentation
 463 add_subdirectory(doc)
 464
 465 # various data that is used by cv libraries and/or demo applications.
 466 add_subdirectory(data)
 467
 468 # extra applications
 469 if(BUILD_opencv_apps)
 470   add_subdirectory(apps)
 471 endif()
 472
 473 # examples
 474 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES)
 475   add_subdirectory(samples)
 476 endif()
 477
 478 if(ANDROID)
 479   add_subdirectory(platforms/android/service)
 480 endif()
 481
 482 if(BUILD_ANDROID_PACKAGE)
 483   add_subdirectory(platforms/android/package)
 484 endif()
 485
 486 if (ANDROID)
 487   add_subdirectory(platforms/android/libinfo)
 488 endif()
 489
 490 # ----------------------------------------------------------------------------
 491 # Finalization: generate configuration-based files
 492 # ----------------------------------------------------------------------------
 493 ocv_track_build_dependencies()
 494
 495 # Generate platform-dependent and configuration-dependent headers
 496 include(cmake/OpenCVGenHeaders.cmake)
 497
 498 # Generate opencv.pc for pkg-config command
 499 include(cmake/OpenCVGenPkgconfig.cmake)
 500
 501 # Generate OpenCV.mk for ndk-build (Android build tool)
 502 include(cmake/OpenCVGenAndroidMK.cmake)
 503
 504 # Generate OpenCVСonfig.cmake and OpenCVConfig-version.cmake for cmake projects
 505 include(cmake/OpenCVGenConfig.cmake)
 506
 507 # Generate Info.plist for the IOS framework
 508 include(cmake/OpenCVGenInfoPlist.cmake)
 509
 510 # ----------------------------------------------------------------------------
 511 # Summary:
 512 # ----------------------------------------------------------------------------
 513 status("")
 514 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 515 if(OPENCV_VCSVERSION)
 516   status("  Version control:" ${OPENCV_VCSVERSION})
 517 endif()
 518
 519 # ========================== build platform ==========================
 520 status("")
 521 status("  Platform:")
 522 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
 523 if(CMAKE_CROSSCOMPILING)
 524   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
 525 endif()
 526 status("    CMake:"            ${CMAKE_VERSION})
 527 status("    CMake generator:"  ${CMAKE_GENERATOR})
 528 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
 529 if(MSVC)
 530   status("    MSVC:"           ${MSVC_VERSION})
 531 endif()
 532 if(CMAKE_GENERATOR MATCHES Xcode)
 533   status("    Xcode:"          ${XCODE_VERSION})
 534 endif()
 535 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
 536   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
 537 endif()
 538
 539 # ========================== C/C++ options ==========================
 540 if(CMAKE_CXX_COMPILER_VERSION)
 541   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
 542 elseif(CMAKE_COMPILER_IS_CLANGCXX)
 543   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CLANG_REGEX_VERSION})")
 544 elseif(CMAKE_COMPILER_IS_GNUCXX)
 545   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_GCC_REGEX_VERSION})")
 546 else()
 547   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 548 endif()
 549 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
 550
 551 status("")
 552 status("  C/C++:")
 553 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
 554 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
 555 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
 556 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
 557 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
 558 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
 559 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
 560 if(WIN32)
 561   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
 562   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
 563 else()
 564   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
 565   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
 566 endif()
 567 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
 568
 569 # ========================== OpenCV modules ==========================
 570 status("")
 571 status("  OpenCV modules:")
 572 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD}")
 573 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
 574 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
 575 set(OPENCV_MODULES_DISABLED_AUTO_ST "")
 576 foreach(m ${OPENCV_MODULES_DISABLED_AUTO})
 577   set(__mdeps "")
 578   foreach(d ${OPENCV_MODULE_${m}_DEPS})
 579     if(d MATCHES "^opencv_" AND NOT HAVE_${d})
 580       list(APPEND __mdeps ${d})
 581     endif()
 582   endforeach()
 583   if(__mdeps)
 584     list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}(deps: ${__mdeps})")
 585   else()
 586     list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}")
 587   endif()
 588 endforeach()
 589 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO_ST}")
 590
 591 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
 592 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
 593 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
 594 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
 595
 596 # ========================== Android details ==========================
 597 if(ANDROID)
 598   status("")
 599   status("  Android: ")
 600   status("    Android ABI:" ${ANDROID_ABI})
 601   status("    STL type:" ${ANDROID_STL})
 602   status("    Native API level:" android-${ANDROID_NATIVE_API_LEVEL})
 603   android_get_compatible_target(android_sdk_target_status ${ANDROID_NATIVE_API_LEVEL} ${ANDROID_SDK_TARGET} 11)
 604   status("    SDK target:" "${android_sdk_target_status}")
 605   if(BUILD_WITH_ANDROID_NDK)
 606     status("    Android NDK:" "${ANDROID_NDK} (toolchain: ${ANDROID_TOOLCHAIN_NAME})")
 607   elseif(BUILD_WITH_STANDALONE_TOOLCHAIN)
 608     status("    Android toolchain:" "${ANDROID_STANDALONE_TOOLCHAIN}")
 609   endif()
 610   status("    android tool:"  ANDROID_EXECUTABLE  THEN "${ANDROID_EXECUTABLE} (${ANDROID_TOOLS_Pkg_Desc})" ELSE NO)
 611   status("    Google Play package:" BUILD_ANDROID_PACKAGE                                         THEN YES ELSE NO)
 612   status("    Android examples:"    BUILD_ANDROID_EXAMPLES AND CAN_BUILD_ANDROID_PROJECTS         THEN YES ELSE NO)
 613 endif()
 614
 615 # ================== Windows RT features ==================
 616 if(WIN32)
 617 status("")
 618     status("  Windows RT support:" HAVE_WINRT THEN YES ELSE NO)
 619     if (ENABLE_WINRT_MODE)
 620       status("    Windows SDK v8.0:" ${WINDOWS_SDK_PATH})
 621       status("    Visual Studio 2012:" ${VISUAL_STUDIO_PATH})
 622     endif()
 623 endif(WIN32)
 624
 625 # ========================== GUI ==========================
 626 status("")
 627 status("  GUI: ")
 628
 629 if(HAVE_QT5)
 630   status("    QT 5.x:"            HAVE_QT        THEN "YES (ver ${Qt5Core_VERSION_STRING})" ELSE NO)
 631   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt5OpenGL_LIBRARIES} ${Qt5OpenGL_VERSION_STRING})" ELSE NO)
 632 elseif(HAVE_QT)
 633   status("    QT 4.x:"            HAVE_QT        THEN "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})" ELSE NO)
 634   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
 635 else()
 636   if(DEFINED WITH_QT)
 637     status("    QT:" NO)
 638   endif()
 639   if(DEFINED WITH_WIN32UI)
 640     status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
 641   else()
 642     if(APPLE)
 643       if(WITH_CARBON)
 644         status("    Carbon:" YES)
 645       else()
 646         status("    Cocoa:"  YES)
 647       endif()
 648     else()
 649       status("    GTK+ 2.x:" HAVE_GTK      THEN "YES (ver ${ALIASOF_gtk+-2.0_VERSION})"     ELSE NO)
 650       status("    GThread :" HAVE_GTHREAD  THEN "YES (ver ${ALIASOF_gthread-2.0_VERSION})"  ELSE NO)
 651       status("    GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${ALIASOF_gtkglext-1.0_VERSION})" ELSE NO)
 652     endif()
 653   endif()
 654 endif()
 655
 656 status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
 657
 658 # ========================== MEDIA IO ==========================
 659 status("")
 660 status("  Media I/O: ")
 661 status("    ZLib:"         BUILD_ZLIB    THEN "build (ver ${ZLIB_VERSION_STRING})"               ELSE "${ZLIB_LIBRARIES} (ver ${ZLIB_VERSION_STRING})")
 662
 663 if(WITH_JPEG)
 664   status("    JPEG:"       JPEG_FOUND    THEN "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})"        ELSE "build (ver ${JPEG_LIB_VERSION})")
 665 else()
 666   status("    JPEG:"       "NO")
 667 endif()
 668
 669 if(WITH_WEBP)
 670   status("    WEBP:"       WEBP_FOUND    THEN "${WEBP_LIBRARY} (ver ${WEBP_VERSION})"        ELSE "build (ver ${WEBP_VERSION})")
 671 else()
 672   status("    WEBP:"       "NO")
 673 endif()
 674
 675 if(WITH_PNG)
 676   status("    PNG:"        PNG_FOUND     THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})"              ELSE "build (ver ${PNG_VERSION})")
 677 else()
 678   status("    PNG:"        "NO")
 679 endif()
 680 if(WITH_TIFF)
 681   if(TIFF_VERSION_STRING AND TIFF_FOUND)
 682     status("    TIFF:"     "${TIFF_LIBRARY} (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 683   else()
 684     status("    TIFF:"     TIFF_FOUND    THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION})"            ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 685   endif()
 686 else()
 687   status("    TIFF:"       "NO")
 688 endif()
 689 if(WITH_JASPER)
 690   status("    JPEG 2000:"  JASPER_FOUND  THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
 691 else()
 692   status("    JPEG 2000:"  "NO")
 693 endif()
 694 if(WITH_OPENEXR)
 695   status("    OpenEXR:"  OPENEXR_FOUND  THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
 696 else()
 697   status("    OpenEXR:"  "NO")
 698 endif()
 699
 700 # ========================== VIDEO IO ==========================
 701 status("")
 702 status("  Video I/O:")
 703
 704 if (DEFINED WITH_VFW)
 705   status("    Video for Windows:" HAVE_VFW         THEN YES                                        ELSE NO)
 706 endif(DEFINED WITH_VFW)
 707
 708 if(DEFINED WITH_1394)
 709   status("    DC1394 1.x:"     HAVE_DC1394         THEN "YES (ver ${ALIASOF_libdc1394_VERSION})"   ELSE NO)
 710   status("    DC1394 2.x:"     HAVE_DC1394_2       THEN "YES (ver ${ALIASOF_libdc1394-2_VERSION})" ELSE NO)
 711 endif(DEFINED WITH_1394)
 712
 713 if(ANDROID)
 714   if(HAVE_opencv_androidcamera)
 715     status("    AndroidNativeCamera:" BUILD_ANDROID_CAMERA_WRAPPER
 716                                                    THEN "YES, build for Android${ANDROID_VERSION}" ELSE "YES, use prebuilt libraries")
 717   else()
 718     status("    AndroidNativeCamera:" "NO (native camera requires Android API level 8 or higher)")
 719   endif()
 720 endif()
 721
 722 if(DEFINED WITH_AVFOUNDATION)
 723   status("    AVFoundation:"   WITH_AVFOUNDATION   THEN YES                                        ELSE NO)
 724 endif(DEFINED WITH_AVFOUNDATION)
 725
 726 if(DEFINED WITH_FFMPEG)
 727   if(WIN32)
 728     status("    FFMPEG:"       WITH_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
 729   else()
 730     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
 731   endif()
 732   status("      codec:"        HAVE_FFMPEG_CODEC   THEN "YES (ver ${ALIASOF_libavcodec_VERSION})"  ELSE NO)
 733   status("      format:"       HAVE_FFMPEG_FORMAT  THEN "YES (ver ${ALIASOF_libavformat_VERSION})" ELSE NO)
 734   status("      util:"         HAVE_FFMPEG_UTIL    THEN "YES (ver ${ALIASOF_libavutil_VERSION})"   ELSE NO)
 735   status("      swscale:"      HAVE_FFMPEG_SWSCALE THEN "YES (ver ${ALIASOF_libswscale_VERSION})"  ELSE NO)
 736   status("      gentoo-style:" HAVE_GENTOO_FFMPEG  THEN YES                                        ELSE NO)
 737 endif(DEFINED WITH_FFMPEG)
 738
 739 if(DEFINED WITH_GSTREAMER)
 740   status("    GStreamer:"      HAVE_GSTREAMER      THEN ""                                         ELSE NO)
 741   if(HAVE_GSTREAMER)
 742     status("      base:"       "YES (ver ${GSTREAMER_BASE_VERSION})")
 743     status("      video:"      "YES (ver ${GSTREAMER_VIDEO_VERSION})")
 744     status("      app:"        "YES (ver ${GSTREAMER_APP_VERSION})")
 745     status("      riff:"       "YES (ver ${GSTREAMER_RIFF_VERSION})")
 746     status("      pbutils:"    "YES (ver ${GSTREAMER_PBUTILS_VERSION})")
 747   endif(HAVE_GSTREAMER)
 748 endif(DEFINED WITH_GSTREAMER)
 749
 750 if(DEFINED WITH_OPENNI)
 751   status("    OpenNI:"         HAVE_OPENNI         THEN "YES (ver ${OPENNI_VERSION_STRING}, build ${OPENNI_VERSION_BUILD})"
 752                                                                                                    ELSE NO)
 753   status("    OpenNI PrimeSensor Modules:" HAVE_OPENNI_PRIME_SENSOR_MODULE
 754                                                    THEN "YES (${OPENNI_PRIME_SENSOR_MODULE})"      ELSE NO)
 755 endif(DEFINED WITH_OPENNI)
 756
 757 if(DEFINED WITH_PVAPI)
 758   status("    PvAPI:"          HAVE_PVAPI          THEN YES                                        ELSE NO)
 759 endif(DEFINED WITH_PVAPI)
 760
 761 if(DEFINED WITH_GIGEAPI)
 762   status("    GigEVisionSDK:"  HAVE_GIGE_API       THEN YES                                        ELSE NO)
 763 endif(DEFINED WITH_GIGEAPI)
 764
 765 if(DEFINED WITH_QUICKTIME)
 766   status("    QuickTime:"      HAVE_QUICKTIME      THEN YES                                        ELSE NO)
 767   status("    QTKit:"          HAVE_QTKIT          THEN YES                                        ELSE NO)
 768 endif(DEFINED WITH_QUICKTIME)
 769
 770 if(DEFINED WITH_UNICAP)
 771   status("    UniCap:"         HAVE_UNICAP         THEN "YES (ver ${ALIASOF_libunicap_VERSION})"   ELSE NO)
 772   status("    UniCap ucil:"    HAVE_UNICAP_UCIL    THEN "YES (ver ${ALIASOF_libucil_VERSION})"     ELSE NO)
 773 endif(DEFINED WITH_UNICAP)
 774
 775 if(DEFINED WITH_V4L)
 776   if(HAVE_CAMV4L)
 777     set(HAVE_CAMV4L_STR "YES")
 778   else()
 779     set(HAVE_CAMV4L_STR "NO")
 780   endif()
 781   if(HAVE_CAMV4L2)
 782     set(HAVE_CAMV4L2_STR "YES")
 783   elseif(HAVE_VIDEOIO)
 784     set(HAVE_CAMV4L2_STR "YES(videoio)")
 785   else()
 786     set(HAVE_CAMV4L2_STR "NO")
 787   endif()
 788   status("    V4L/V4L2:"       HAVE_LIBV4L         THEN "Using libv4l (ver ${ALIASOF_libv4l1_VERSION})"
 789                                                    ELSE "${HAVE_CAMV4L_STR}/${HAVE_CAMV4L2_STR}")
 790 endif(DEFINED WITH_V4L)
 791
 792 if(DEFINED WITH_DSHOW)
 793   status("    DirectShow:"     HAVE_DSHOW     THEN YES                                        ELSE NO)
 794 endif(DEFINED WITH_DSHOW)
 795
 796 if(DEFINED WITH_MSMF)
 797   status("    Media Foundation:" HAVE_MSMF    THEN YES                                        ELSE NO)
 798 endif(DEFINED WITH_MSMF)
 799
 800 if(DEFINED WITH_XIMEA)
 801   status("    XIMEA:"          HAVE_XIMEA          THEN YES                                        ELSE NO)
 802 endif(DEFINED WITH_XIMEA)
 803
 804 if(DEFINED WITH_XINE)
 805   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${ALIASOF_libxine_VERSION})"     ELSE NO)
 806 endif(DEFINED WITH_XINE)
 807
 808 # ========================== Other third-party libraries ==========================
 809 status("")
 810 status("  Other third-party libraries:")
 811
 812 if(WITH_IPP AND IPP_FOUND)
 813   status("    Use IPP:" "${IPP_LATEST_VERSION_STR} [${IPP_LATEST_VERSION_MAJOR}.${IPP_LATEST_VERSION_MINOR}.${IPP_LATEST_VERSION_BUILD}]")
 814   status("         at:" "${IPP_ROOT_DIR}")
 815 else()
 816   status("    Use IPP:"   WITH_IPP AND NOT IPP_FOUND THEN "IPP not found" ELSE NO)
 817 endif()
 818
 819 status("    Use Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
 820 status("    Use TBB:"        HAVE_TBB         THEN "YES (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})" ELSE NO)
 821 status("    Use OpenMP:"     HAVE_OPENMP      THEN YES ELSE NO)
 822 status("    Use GCD"         HAVE_GCD         THEN YES ELSE NO)
 823 status("    Use Concurrency" HAVE_CONCURRENCY THEN YES ELSE NO)
 824 status("    Use C=:"         HAVE_CSTRIPES    THEN YES ELSE NO)
 825 status("    Use Cuda:"       HAVE_CUDA        THEN "YES (ver ${CUDA_VERSION_STRING})" ELSE NO)
 826 status("    Use OpenCL:"     HAVE_OPENCL      THEN YES ELSE NO)
 827
 828 if(HAVE_CUDA)
 829   status("")
 830   status("  NVIDIA CUDA")
 831
 832   status("    Use CUFFT:"            HAVE_CUFFT   THEN YES ELSE NO)
 833   status("    Use CUBLAS:"           HAVE_CUBLAS  THEN YES ELSE NO)
 834   status("    USE NVCUVID:"          HAVE_NVCUVID THEN YES ELSE NO)
 835   status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
 836   status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
 837   status("    Use fast math:"        CUDA_FAST_MATH THEN YES ELSE NO)
 838 endif()
 839
 840 if(HAVE_OPENCL)
 841   status("")
 842   status("  OpenCL:")
 843   if(HAVE_OPENCL_STATIC)
 844     set(__opencl_ver "static")
 845   else()
 846     set(__opencl_ver "dynamic")
 847   endif()
 848   status("    Version:"       ${__opencl_ver})
 849   if(OPENCL_INCLUDE_DIR)
 850     status("    Include path:"       ${OPENCL_INCLUDE_DIRS})
 851   endif()
 852   if(OPENCL_LIBRARIES)
 853     set(__libs "")
 854     foreach(l ${OPENCL_LIBRARIES})
 855       if(TARGET ${l})
 856         get_target_property(p ${l} LOCATION)
 857         if(p MATCHES NOTFOUND)
 858           list(APPEND __libs "${l}")
 859         else()
 860           list(APPEND __libs "${p}")
 861         endif()
 862       else()
 863         list(APPEND __libs "${l}")
 864       endif()
 865     endforeach()
 866     status("    libraries:"          ${__libs})
 867   endif()
 868   status("    Use AMDFFT:"           HAVE_CLAMDFFT  THEN YES ELSE NO)
 869   status("    Use AMDBLAS:"          HAVE_CLAMDBLAS THEN YES ELSE NO)
 870 endif()
 871
 872 # ========================== python ==========================
 873 status("")
 874 status("  Python:")
 875 status("    Interpreter:"     PYTHONINTERP_FOUND  THEN "${PYTHON_EXECUTABLE} (ver ${PYTHON_VERSION_STRING})"       ELSE NO)
 876 if(BUILD_opencv_python)
 877   if(PYTHONLIBS_VERSION_STRING)
 878     status("    Libraries:"   HAVE_opencv_python  THEN  "${PYTHON_LIBRARIES} (ver ${PYTHONLIBS_VERSION_STRING})"   ELSE NO)
 879   else()
 880     status("    Libraries:"   HAVE_opencv_python  THEN  "${PYTHON_LIBRARIES}"                                      ELSE NO)
 881   endif()
 882   status("    numpy:"         PYTHON_NUMPY_INCLUDE_DIRS THEN "${PYTHON_NUMPY_INCLUDE_DIRS} (ver ${PYTHON_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
 883   status("    packages path:" PYTHON_EXECUTABLE         THEN "${PYTHON_PACKAGES_PATH}"                                    ELSE "-")
 884 endif()
 885
 886 # ========================== java ==========================
 887 status("")
 888 status("  Java:")
 889 status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
 890 if(NOT ANDROID)
 891   status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
 892 endif()
 893 status("    Java tests:"    BUILD_TESTS AND (CAN_BUILD_ANDROID_PROJECTS OR HAVE_opencv_java)            THEN YES ELSE NO)
 894
 895 # ========================= matlab =========================
 896 status("")
 897 status("  Matlab:")
 898 status("    mex:"         MATLAB_MEX_SCRIPT  THEN  "${MATLAB_MEX_SCRIPT}"   ELSE NO)
 899 if (MATLAB_FOUND)
 900   status("    Compiler/generator:" MEX_WORKS    THEN  "Working"                ELSE "Not working (bindings will not be generated)")
 901 endif()
 902
 903 # ========================== documentation ==========================
 904 if(BUILD_DOCS)
 905   status("")
 906   status("  Documentation:")
 907   if(HAVE_SPHINX)
 908     status("    Build Documentation:" PDFLATEX_COMPILER      THEN YES ELSE "YES (only HTML and without math expressions)")
 909   else()
 910     status("    Build Documentation:" NO)
 911   endif()
 912   status("    Sphinx:"              HAVE_SPHINX              THEN "${SPHINX_BUILD} (ver ${SPHINX_VERSION})" ELSE NO)
 913   status("    PdfLaTeX compiler:"   PDFLATEX_COMPILER        THEN "${PDFLATEX_COMPILER}" ELSE NO)
 914   status("    PlantUML:"            PLANTUML                 THEN "${PLANTUML}" ELSE NO)
 915 endif()
 916
 917 # ========================== samples and tests ==========================
 918 status("")
 919 status("  Tests and samples:")
 920 status("    Tests:"             BUILD_TESTS AND HAVE_opencv_ts       THEN YES ELSE NO)
 921 status("    Performance tests:" BUILD_PERF_TESTS AND HAVE_opencv_ts  THEN YES ELSE NO)
 922 status("    C/C++ Examples:"    BUILD_EXAMPLES                       THEN YES ELSE NO)
 923
 924 # ========================== auxiliary ==========================
 925 status("")
 926 status("  Install path:" "${CMAKE_INSTALL_PREFIX}")
 927 status("")
 928 status("  cvconfig.h is in:" "${OPENCV_CONFIG_FILE_INCLUDE_DIR}")
 929 status("-----------------------------------------------------------------")
 930 status("")
 931
 932 ocv_finalize_status()
 933
 934 # ----------------------------------------------------------------------------
 935 # Warn in the case of in-source build
 936 # ----------------------------------------------------------------------------
 937 if("${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 938   message(WARNING "The source directory is the same as binary directory. \"make clean\" may damage the source tree")
 939 endif()