CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 #
   8 #   - OCT-2008: Initial version <joseluisblancoc@gmail.com>
   9 #
  10 # ----------------------------------------------------------------------------
  11
  12 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  13
  14 # --------------------------------------------------------------
  15 # Indicate CMake 2.7 and above that we don't want to mix relative
  16 #  and absolute paths in linker lib lists.
  17 # Run "cmake --help-policy CMP0003" for more information.
  18 # --------------------------------------------------------------
  19 if(COMMAND cmake_policy)
  20   cmake_policy(SET CMP0003 NEW)
  21 endif()
  22
  23 # Following block can broke build in case of cross-compilng
  24 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  25 # so we will try to detect crosscompiling by presense of CMAKE_TOOLCHAIN_FILE
  26 if(NOT CMAKE_TOOLCHAIN_FILE)
  27   # it _must_ go before project(OpenCV) in order to work
  28   if(WIN32)
  29     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  30   else()
  31     set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  32   endif()
  33
  34   if(MSVC)
  35     set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
  36   endif()
  37 else(NOT CMAKE_TOOLCHAIN_FILE)
  38   #Android: set output folder to ${CMAKE_BINARY_DIR}
  39   set( LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  40   # any crosscompiling
  41   set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  42 endif(NOT CMAKE_TOOLCHAIN_FILE)
  43
  44 # --------------------------------------------------------------
  45 # Top level OpenCV project
  46 # --------------------------------------------------------------
  47 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  48   cmake_minimum_required(VERSION 2.8.8)
  49 elseif(IOS)
  50   cmake_minimum_required(VERSION 2.8.0)
  51 else()
  52   cmake_minimum_required(VERSION 2.6.3)
  53 endif()
  54
  55 # must go before the project command
  56 set(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  57 if(DEFINED CMAKE_BUILD_TYPE AND CMAKE_VERSION VERSION_GREATER "2.8")
  58   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
  59 endif()
  60
  61 project(OpenCV CXX C)
  62
  63 include(cmake/OpenCVUtils.cmake)
  64
  65 # ----------------------------------------------------------------------------
  66 # Break in case of popular CMake configuration mistakes
  67 # ----------------------------------------------------------------------------
  68 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
  69   message(FATAL_ERROR "CMake fails to deterimine the bitness of target platform.
  70   Please check your CMake and compiler installation. If you are crosscompiling then ensure that your CMake toolchain file correctly sets the compiler details.")
  71 endif()
  72
  73 # ----------------------------------------------------------------------------
  74 # Detect compiler and target platform architecture
  75 # ----------------------------------------------------------------------------
  76 include(cmake/OpenCVDetectCXXCompiler.cmake)
  77
  78 # Add these standard paths to the search paths for FIND_LIBRARY
  79 # to find libraries from these locations first
  80 if(UNIX AND NOT ANDROID)
  81   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
  82     if(EXISTS /lib64)
  83       list(APPEND CMAKE_LIBRARY_PATH /lib64)
  84     else()
  85       list(APPEND CMAKE_LIBRARY_PATH /lib)
  86     endif()
  87     if(EXISTS /usr/lib64)
  88       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
  89     else()
  90       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
  91     endif()
  92   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
  93     if(EXISTS /lib32)
  94       list(APPEND CMAKE_LIBRARY_PATH /lib32)
  95     else()
  96       list(APPEND CMAKE_LIBRARY_PATH /lib)
  97     endif()
  98     if(EXISTS /usr/lib32)
  99       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 100     else()
 101       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 102     endif()
 103   endif()
 104 endif()
 105
 106
 107 # ----------------------------------------------------------------------------
 108 # OpenCV cmake options
 109 # ----------------------------------------------------------------------------
 110
 111 # Optional 3rd party components
 112 # ===================================================
 113 OCV_OPTION(WITH_1394           "Include IEEE1394 support"                    ON   IF (UNIX AND NOT ANDROID AND NOT IOS) )
 114 OCV_OPTION(WITH_AVFOUNDATION   "Use AVFoundation for Video I/O"              ON   IF IOS)
 115 OCV_OPTION(WITH_CARBON         "Use Carbon for UI instead of Cocoa"          OFF  IF APPLE )
 116 OCV_OPTION(WITH_CUBLAS         "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" OFF IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 117 OCV_OPTION(WITH_CUDA           "Include NVidia Cuda Runtime support"         ON   IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 118 OCV_OPTION(WITH_CUFFT          "Include NVidia Cuda Fast Fourier Transform (FFT) library support"            ON  IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 119 OCV_OPTION(WITH_EIGEN          "Include Eigen2/Eigen3 support"               ON)
 120 OCV_OPTION(WITH_FFMPEG         "Include FFMPEG support"                      ON   IF (NOT ANDROID AND NOT IOS) )
 121 OCV_OPTION(WITH_GSTREAMER      "Include Gstreamer support"                   ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 122 OCV_OPTION(WITH_GTK            "Include GTK support"                         ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 123 OCV_OPTION(WITH_IMAGEIO        "ImageIO support for OS X"                    OFF  IF APPLE)
 124 OCV_OPTION(WITH_IPP            "Include Intel IPP support"                   OFF  IF (MSVC OR X86 OR X86_64) )
 125 OCV_OPTION(WITH_JASPER         "Include JPEG2K support"                      ON   IF (NOT IOS) )
 126 OCV_OPTION(WITH_JPEG           "Include JPEG support"                        ON   IF (NOT IOS) )
 127 OCV_OPTION(WITH_OPENEXR        "Include ILM support via OpenEXR"             ON   IF (NOT IOS) )
 128 OCV_OPTION(WITH_OPENGL         "Include OpenGL support"                      OFF  IF (NOT ANDROID AND NOT APPLE) )
 129 OCV_OPTION(WITH_OPENNI         "Include OpenNI support"                      OFF  IF (NOT ANDROID AND NOT IOS) )
 130 OCV_OPTION(WITH_PNG            "Include PNG support"                         ON   IF (NOT IOS) )
 131 OCV_OPTION(WITH_PVAPI          "Include Prosilica GigE support"              ON   IF (NOT ANDROID AND NOT IOS) )
 132 OCV_OPTION(WITH_QT             "Build with Qt Backend support"               OFF  IF (NOT ANDROID AND NOT IOS) )
 133 OCV_OPTION(WITH_QUICKTIME      "Use QuickTime for Video I/O insted of QTKit" OFF  IF APPLE )
 134 OCV_OPTION(WITH_TBB            "Include Intel TBB support"                   OFF  IF (NOT IOS) )
 135 OCV_OPTION(WITH_CSTRIPES       "Include C= support"                          OFF  IF WIN32 )
 136 OCV_OPTION(WITH_TIFF           "Include TIFF support"                        ON   IF (NOT IOS) )
 137 OCV_OPTION(WITH_UNICAP         "Include Unicap support (GPL)"                OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 138 OCV_OPTION(WITH_V4L            "Include Video 4 Linux support"               ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 139 OCV_OPTION(WITH_VIDEOINPUT     "Build HighGUI with DirectShow support"       ON   IF WIN32 )
 140 OCV_OPTION(WITH_XIMEA          "Include XIMEA cameras support"               OFF  IF (NOT ANDROID AND NOT APPLE) )
 141 OCV_OPTION(WITH_XINE           "Include Xine support (GPL)"                  OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 142 OCV_OPTION(WITH_CLP            "Include Clp support (EPL)"                   OFF)
 143 OCV_OPTION(WITH_OPENCL         "Include OpenCL Runtime support"              OFF  IF (NOT ANDROID AND NOT IOS) )
 144 OCV_OPTION(WITH_OPENCLAMDFFT   "Include AMD OpenCL FFT library support"      OFF  IF (NOT ANDROID AND NOT IOS) )
 145 OCV_OPTION(WITH_OPENCLAMDBLAS  "Include AMD OpenCL BLAS library support"     OFF  IF (NOT ANDROID AND NOT IOS) )
 146
 147
 148 # OpenCV build components
 149 # ===================================================
 150 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR IOS) )
 151 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 152 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" ON )
 153 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 154 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON )
 155 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     ON  IF (NOT IOS) )
 156 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           ON  IF (NOT IOS) )
 157 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into debug libs (not MSCV only)" ON )
 158 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of staticaly linked CRT for staticaly linked OpenCV" ON IF MSVC )
 159 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create fat java wrapper containing the whole OpenCV library" ON IF ANDROID AND NOT BUILD_SHARED_LIBS AND CMAKE_COMPILER_IS_GNUCXX )
 160 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID AND ANDROID_USE_STLPORT AND ANDROID_SOURCE_TREE )
 161 OCV_OPTION(BUILD_ANDROID_PACKAGE    "Build platform-specific package for Google Play" OFF IF ANDROID )
 162
 163 # 3rd party libs
 164 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"         WIN32 OR APPLE )
 165 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"      WIN32 OR ANDROID OR APPLE )
 166 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"    WIN32 OR ANDROID OR APPLE )
 167 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"      WIN32 OR ANDROID OR APPLE )
 168 OCV_OPTION(BUILD_PNG                "Build libpng from source"       WIN32 OR ANDROID OR APPLE )
 169 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"      WIN32 OR ANDROID OR APPLE )
 170
 171
 172 # OpenCV installation options
 173 # ===================================================
 174 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 175 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 176 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 177 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT IOS AND BUILD_SHARED_LIBS) )
 178
 179
 180 # OpenCV build options
 181 # ===================================================
 182 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON   IF (NOT IOS) )
 183 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) IF (CMAKE_VERSION VERSION_GREATER "2.8.0") )
 184 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CMAKE_COMPILER_IS_GNUCXX )
 185 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CMAKE_COMPILER_IS_GNUCXX )
 186 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CMAKE_COMPILER_IS_GNUCXX AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 187 OCV_OPTION(ENABLE_FAST_MATH           "Enable -ffast-math (not recommended for GCC 4.6.x)"       OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 188 OCV_OPTION(ENABLE_SSE                 "Enable SSE instructions"                                  ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 189 OCV_OPTION(ENABLE_SSE2                "Enable SSE2 instructions"                                 ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 190 OCV_OPTION(ENABLE_SSE3                "Enable SSE3 instructions"                                 ON   IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 191 OCV_OPTION(ENABLE_SSSE3               "Enable SSSE3 instructions"                                OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 192 OCV_OPTION(ENABLE_SSE41               "Enable SSE4.1 instructions"                               OFF  IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 193 OCV_OPTION(ENABLE_SSE42               "Enable SSE4.2 instructions"                               OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 194 OCV_OPTION(ENABLE_AVX                 "Enable AVX instructions"                                  OFF  IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 195 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 196 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 197
 198
 199 # uncategorized options
 200 # ===================================================
 201 OCV_OPTION(CMAKE_VERBOSE "Verbose mode" OFF )
 202
 203 # backward compatibility
 204 # ===================================================
 205 include(cmake/OpenCVLegacyOptions.cmake OPTIONAL)
 206
 207
 208 # ----------------------------------------------------------------------------
 209 #  Get actual OpenCV version number from sources
 210 # ----------------------------------------------------------------------------
 211 include(cmake/OpenCVVersion.cmake)
 212
 213
 214 # ----------------------------------------------------------------------------
 215 #  Build & install layouts
 216 # ----------------------------------------------------------------------------
 217
 218 # Save libs and executables in the same place
 219 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications" )
 220
 221 if(ANDROID OR WIN32)
 222   set(OPENCV_DOC_INSTALL_PATH doc)
 223 elseif(INSTALL_TO_MANGLED_PATHS)
 224   set(OPENCV_DOC_INSTALL_PATH share/OpenCV-${OPENCV_VERSION}/doc)
 225 else()
 226   set(OPENCV_DOC_INSTALL_PATH share/OpenCV/doc)
 227 endif()
 228
 229 if(ANDROID)
 230   set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 231   set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 232   set(OPENCV_LIB_INSTALL_PATH     sdk/native/libs/${ANDROID_NDK_ABI_NAME})
 233   set(OPENCV_3P_LIB_INSTALL_PATH  sdk/native/3rdparty/libs/${ANDROID_NDK_ABI_NAME})
 234   set(OPENCV_CONFIG_INSTALL_PATH  sdk/native/jni)
 235   set(OPENCV_INCLUDE_INSTALL_PATH sdk/native/jni/include)
 236 else()
 237   set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib")
 238   set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib${LIB_SUFFIX}")
 239   set(OPENCV_LIB_INSTALL_PATH     lib${LIB_SUFFIX})
 240   set(OPENCV_3P_LIB_INSTALL_PATH  share/OpenCV/3rdparty/${OPENCV_LIB_INSTALL_PATH})
 241   set(OPENCV_INCLUDE_INSTALL_PATH include)
 242
 243   math(EXPR SIZEOF_VOID_P_BITS "8 * ${CMAKE_SIZEOF_VOID_P}")
 244   if(LIB_SUFFIX AND NOT SIZEOF_VOID_P_BITS EQUAL LIB_SUFFIX)
 245     set(OPENCV_CONFIG_INSTALL_PATH lib${LIB_SUFFIX}/cmake/opencv)
 246   else()
 247     set(OPENCV_CONFIG_INSTALL_PATH share/OpenCV)
 248   endif()
 249 endif()
 250
 251 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 252 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 253
 254 if(INSTALL_TO_MANGLED_PATHS)
 255   set(OPENCV_INCLUDE_INSTALL_PATH ${OPENCV_INCLUDE_INSTALL_PATH}/opencv-${OPENCV_VERSION})
 256 endif()
 257
 258 if(WIN32)
 259   # Postfix of DLLs:
 260   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 261   set(OPENCV_DEBUG_POSTFIX d)
 262 else()
 263   # Postfix of so's:
 264   set(OPENCV_DLLVERSION "")
 265   set(OPENCV_DEBUG_POSTFIX "")
 266 endif()
 267
 268 if(DEFINED CMAKE_DEBUG_POSTFIX)
 269   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 270 endif()
 271
 272 if(CMAKE_VERBOSE)
 273   set(CMAKE_VERBOSE_MAKEFILE 1)
 274 endif()
 275
 276
 277 # ----------------------------------------------------------------------------
 278 #  Path for build/platform -specific headers
 279 # ----------------------------------------------------------------------------
 280 set(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 281 add_definitions(-DHAVE_CVCONFIG_H)
 282 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 283
 284
 285 # ----------------------------------------------------------------------------
 286 #  Autodetect if we are in a GIT repository
 287 # ----------------------------------------------------------------------------
 288
 289 # don't use FindGit because it requires CMake 2.8.2
 290 set(git_names git eg) # eg = easy git
 291 # Prefer .cmd variants on Windows unless running in a Makefile in the MSYS shell
 292 if(CMAKE_HOST_WIN32)
 293   if(NOT CMAKE_GENERATOR MATCHES "MSYS")
 294     set(git_names git.cmd git eg.cmd eg)
 295   endif()
 296 endif()
 297
 298 find_host_program(GIT_EXECUTABLE NAMES ${git_names} PATH_SUFFIXES Git/cmd Git/bin DOC "git command line client")
 299 mark_as_advanced(GIT_EXECUTABLE)
 300
 301 if(GIT_EXECUTABLE)
 302   execute_process(COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
 303     WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 304     OUTPUT_VARIABLE OPENCV_GIT_HASH_SORT
 305     RESULT_VARIABLE GIT_RESULT
 306     ERROR_QUIET
 307     OUTPUT_STRIP_TRAILING_WHITESPACE
 308   )
 309   if(GIT_RESULT EQUAL 0)
 310     set(OPENCV_VCSVERSION "commit:${OPENCV_GIT_HASH_SORT}")
 311   else()
 312     set(OPENCV_VCSVERSION "exported")
 313   endif()
 314 else()
 315   # We don't have git:
 316   set(OPENCV_VCSVERSION "")
 317 endif()
 318
 319
 320 # ----------------------------------------------------------------------------
 321 # OpenCV compiler and linker options
 322 # ----------------------------------------------------------------------------
 323 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 324 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 325   set(CMAKE_BUILD_TYPE Release)
 326 endif()
 327
 328 include(cmake/OpenCVCompilerOptions.cmake)
 329
 330
 331 # ----------------------------------------------------------------------------
 332 # Use statically or dynamically linked CRT?
 333 # Default: dynamic
 334 # ----------------------------------------------------------------------------
 335 if(MSVC)
 336   include(cmake/OpenCVCRTLinkage.cmake)
 337 endif(MSVC)
 338
 339 if(WIN32 AND NOT MINGW)
 340   add_definitions(-D_VARIADIC_MAX=10)
 341 endif(WIN32 AND NOT MINGW)
 342
 343
 344 # ----------------------------------------------------------------------------
 345 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 346 # ----------------------------------------------------------------------------
 347 if(UNIX)
 348   include(cmake/OpenCVFindPkgConfig.cmake OPTIONAL)
 349   include(CheckFunctionExists)
 350   include(CheckIncludeFile)
 351
 352   if(NOT APPLE)
 353     CHECK_INCLUDE_FILE(alloca.h HAVE_ALLOCA_H)
 354     CHECK_FUNCTION_EXISTS(alloca HAVE_ALLOCA)
 355     CHECK_INCLUDE_FILE(unistd.h HAVE_UNISTD_H)
 356     CHECK_INCLUDE_FILE(pthread.h HAVE_LIBPTHREAD)
 357     if(ANDROID)
 358       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 359     elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD|NetBSD|DragonFly")
 360       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 361     else()
 362       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 363     endif()
 364   else()
 365     add_definitions(-DHAVE_ALLOCA -DHAVE_ALLOCA_H -DHAVE_LIBPTHREAD -DHAVE_UNISTD_H)
 366   endif()
 367 endif()
 368
 369 include(cmake/OpenCVPCHSupport.cmake)
 370 include(cmake/OpenCVModule.cmake)
 371
 372 # ----------------------------------------------------------------------------
 373 #  Detect 3rd-party libraries
 374 # ----------------------------------------------------------------------------
 375
 376 include(cmake/OpenCVFindLibsGrfmt.cmake)
 377 include(cmake/OpenCVFindLibsGUI.cmake)
 378 include(cmake/OpenCVFindLibsVideo.cmake)
 379 include(cmake/OpenCVFindLibsPerf.cmake)
 380
 381
 382 # ----------------------------------------------------------------------------
 383 #  Detect other 3rd-party libraries/tools
 384 # ----------------------------------------------------------------------------
 385
 386 # --- LATEX for pdf documentation ---
 387 if(BUILD_DOCS)
 388   include(cmake/OpenCVFindLATEX.cmake)
 389 endif(BUILD_DOCS)
 390
 391 # --- Python Support ---
 392 include(cmake/OpenCVDetectPython.cmake)
 393
 394 # --- Java Support ---
 395 include(cmake/OpenCVDetectApacheAnt.cmake)
 396 if(ANDROID)
 397   include(cmake/OpenCVDetectAndroidSDK.cmake)
 398
 399   if(NOT ANDROID_TOOLS_Pkg_Revision GREATER 13)
 400     message(WARNING "OpenCV requires Android SDK tools revision 14 or newer. Otherwise tests and samples will no be compiled.")
 401   endif()
 402 elseif(ANT_EXECUTABLE)
 403   find_package(JNI)
 404 endif()
 405
 406 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 407   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 408 else()
 409   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 410 endif()
 411
 412 # --- OpenCL ---
 413 if(WITH_OPENCL)
 414   include(cmake/OpenCVDetectOpenCL.cmake)
 415   if(OPENCL_FOUND)
 416     set(HAVE_OPENCL 1)
 417   endif()
 418   if(WITH_OPENCLAMDFFT)
 419     set(HAVE_CLAMDFFT 1)
 420   endif()
 421   if(WITH_OPENCLAMDBLAS)
 422     set(HAVE_CLAMDBLAS 1)
 423   endif()
 424 endif()
 425
 426 # ----------------------------------------------------------------------------
 427 # Solution folders:
 428 # ----------------------------------------------------------------------------
 429 if(ENABLE_SOLUTION_FOLDERS)
 430   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 431   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 432 endif()
 433
 434 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 435 include(cmake/OpenCVExtraTargets.cmake)
 436
 437
 438 # ----------------------------------------------------------------------------
 439 # Process subdirectories
 440 # ----------------------------------------------------------------------------
 441
 442 # opencv.hpp and legacy headers
 443 add_subdirectory(include)
 444
 445 # OpenCV modules
 446 add_subdirectory(modules)
 447
 448 # Generate targets for documentation
 449 add_subdirectory(doc)
 450
 451 # various data that is used by cv libraries and/or demo applications.
 452 add_subdirectory(data)
 453
 454 # extra applications
 455 add_subdirectory(apps)
 456
 457 # examples
 458 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES)
 459   add_subdirectory(samples)
 460 endif()
 461
 462 if(BUILD_ANDROID_SERVICE)
 463   add_subdirectory(android/service)
 464 endif()
 465
 466 if(BUILD_ANDROID_PACKAGE)
 467   add_subdirectory(android/package)
 468 endif()
 469
 470 # ----------------------------------------------------------------------------
 471 # Finalization: generate configuration-based files
 472 # ----------------------------------------------------------------------------
 473 ocv_track_build_dependencies()
 474
 475 # Generate platform-dependent and configuration-dependent headers
 476 include(cmake/OpenCVGenHeaders.cmake)
 477
 478 # Generate opencv.pc for pkg-config command
 479 include(cmake/OpenCVGenPkgconfig.cmake)
 480
 481 # Generate OpenCV.mk for ndk-build (Android build tool)
 482 include(cmake/OpenCVGenAndroidMK.cmake)
 483
 484 # Generate OpenCVСonfig.cmake and OpenCVConfig-version.cmake for cmake projects
 485 include(cmake/OpenCVGenConfig.cmake)
 486
 487
 488 # ----------------------------------------------------------------------------
 489 # Summary:
 490 # ----------------------------------------------------------------------------
 491 status("")
 492 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 493 if(OPENCV_VCSVERSION)
 494   status("  Version control:" ${OPENCV_VCSVERSION})
 495 endif()
 496
 497 # ========================== build platform ==========================
 498 status("")
 499 status("  Platform:")
 500 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
 501 if(CMAKE_CROSSCOMPILING)
 502   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
 503 endif()
 504 status("    CMake:"            ${CMAKE_VERSION})
 505 status("    CMake generator:"  ${CMAKE_GENERATOR})
 506 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
 507 if(MSVC)
 508   status("    MSVC:"           ${MSVC_VERSION})
 509 endif()
 510 if(CMAKE_GENERATOR MATCHES Xcode)
 511   status("    Xcode:"          ${XCODE_VERSION})
 512 endif()
 513 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
 514   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
 515 endif()
 516
 517 # ========================== C/C++ options ==========================
 518 status("")
 519 status("  C/C++:")
 520 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
 521 status("    C++ Compiler:"           CMAKE_COMPILER_IS_GNUCXX THEN "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_GCC_REGEX_VERSION})" ELSE "${CMAKE_CXX_COMPILER}" )
 522 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
 523 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
 524 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
 525 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
 526 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
 527 if(WIN32)
 528   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
 529   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
 530 else()
 531   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
 532   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
 533 endif()
 534 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
 535
 536 # ========================== OpenCV modules ==========================
 537 status("")
 538 status("  OpenCV modules:")
 539 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD}")
 540 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
 541 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
 542 set(OPENCV_MODULES_DISABLED_AUTO_ST "")
 543 foreach(m ${OPENCV_MODULES_DISABLED_AUTO})
 544   set(__mdeps "")
 545   foreach(d ${OPENCV_MODULE_${m}_DEPS})
 546     if(d MATCHES "^opencv_" AND NOT HAVE_${d})
 547       list(APPEND __mdeps ${d})
 548     endif()
 549   endforeach()
 550   list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}(deps: ${__mdeps})")
 551 endforeach()
 552 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO_ST}")
 553
 554 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
 555 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
 556 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
 557 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
 558
 559 # ========================== Android details ==========================
 560 if(ANDROID)
 561   status("")
 562   status("  Android: ")
 563   status("    Android ABI:" ${ANDROID_ABI})
 564   status("    Native API level:" android-${ANDROID_NATIVE_API_LEVEL})
 565   status("    SDK target:" "${ANDROID_SDK_TARGET}")
 566   if(BUILD_WITH_ANDROID_NDK)
 567     status("    Android NDK:" "${ANDROID_NDK} (toolchain: ${ANDROID_TOOLCHAIN_NAME})")
 568   elseif(BUILD_WITH_STANDALONE_TOOLCHAIN)
 569     status("    Android toolchain:" "${ANDROID_STANDALONE_TOOLCHAIN}")
 570   endif()
 571   status("    android tool:"  ANDROID_EXECUTABLE  THEN "${ANDROID_EXECUTABLE} (${ANDROID_TOOLS_Pkg_Desc})" ELSE NO)
 572   status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"            ELSE NO)
 573   status("    Google Play package:" BUILD_ANDROID_PACKAGE THEN YES ELSE NO)
 574 endif()
 575
 576 # ========================== GUI ==========================
 577 status("")
 578 status("  GUI: ")
 579
 580 if(HAVE_QT)
 581   status("    QT 4.x:"            HAVE_QT        THEN "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})" ELSE NO)
 582   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
 583 else()
 584   if(DEFINED WITH_QT)
 585     status("    QT 4.x:" NO)
 586   endif()
 587   if(WIN32)
 588     status("    Win32 UI:" YES)
 589   else()
 590     if(APPLE)
 591       if(WITH_CARBON)
 592         status("    Carbon:" YES)
 593       else()
 594         status("    Cocoa:"  YES)
 595       endif()
 596     else()
 597       status("    GTK+ 2.x:" HAVE_GTK      THEN "YES (ver ${ALIASOF_gtk+-2.0_VERSION})"     ELSE NO)
 598       status("    GThread :" HAVE_GTHREAD  THEN "YES (ver ${ALIASOF_gthread-2.0_VERSION})"  ELSE NO)
 599       status("    GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${ALIASOF_gtkglext-1.0_VERSION})" ELSE NO)
 600     endif()
 601   endif()
 602 endif()
 603
 604 status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
 605
 606 # ========================== MEDIA IO ==========================
 607 status("")
 608 status("  Media I/O: ")
 609 status("    ZLib:"         BUILD_ZLIB    THEN "build (ver ${ZLIB_VERSION_STRING})"               ELSE "${ZLIB_LIBRARY} (ver ${ZLIB_VERSION_STRING})")
 610
 611 if(WITH_JPEG)
 612   status("    JPEG:"       JPEG_FOUND    THEN "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})"        ELSE "build (ver ${JPEG_LIB_VERSION})")
 613 else()
 614   status("    JPEG:"       "NO")
 615 endif()
 616 if(WITH_PNG)
 617   status("    PNG:"        PNG_FOUND     THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})"              ELSE "build (ver ${PNG_VERSION})")
 618 else()
 619   status("    PNG:"        "NO")
 620 endif()
 621 if(WITH_TIFF)
 622   if(TIFF_VERSION_STRING AND TIFF_FOUND)
 623     status("    TIFF:"     "${TIFF_LIBRARY} (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 624   else()
 625     status("    TIFF:"     TIFF_FOUND    THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION})"            ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 626   endif()
 627 else()
 628   status("    TIFF:"       "NO")
 629 endif()
 630 if(WITH_JASPER)
 631   status("    JPEG 2000:"  JASPER_FOUND  THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
 632 else()
 633   status("    JPEG 2000:"  "NO")
 634 endif()
 635 if(WITH_OPENEXR)
 636   status("    OpenEXR:"  OPENEXR_FOUND  THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
 637 else()
 638   status("    OpenEXR:"  "NO")
 639 endif()
 640
 641 # ========================== VIDEO IO ==========================
 642 status("")
 643 status("  Video I/O:")
 644
 645 if(DEFINED WITH_1394)
 646   status("    DC1394 1.x:"     HAVE_DC1394         THEN "YES (ver ${ALIASOF_libdc1394_VERSION})"   ELSE NO)
 647   status("    DC1394 2.x:"     HAVE_DC1394_2       THEN "YES (ver ${ALIASOF_libdc1394-2_VERSION})" ELSE NO)
 648 endif(DEFINED WITH_1394)
 649
 650 if(ANDROID)
 651   if(HAVE_opencv_androidcamera)
 652     status("    AndroidNativeCamera:" BUILD_ANDROID_CAMERA_WRAPPER
 653                                                    THEN "YES, build for Android${ANDROID_VERSION}" ELSE "YES, use prebuilt libraries")
 654   else()
 655     status("    AndroidNativeCamera:" "NO (native camera requires Android API level 8 or higher)")
 656   endif()
 657 endif()
 658
 659 if(DEFINED WITH_AVFOUNDATION)
 660   status("    AVFoundation:"   WITH_AVFOUNDATION   THEN YES                                        ELSE NO)
 661 endif(DEFINED WITH_AVFOUNDATION)
 662
 663 if(DEFINED WITH_FFMPEG)
 664   if(WIN32)
 665     status("    FFMPEG:"       WITH_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
 666   else()
 667     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
 668   endif()
 669   status("      codec:"        HAVE_FFMPEG_CODEC   THEN "YES (ver ${ALIASOF_libavcodec_VERSION})"  ELSE NO)
 670   status("      format:"       HAVE_FFMPEG_FORMAT  THEN "YES (ver ${ALIASOF_libavformat_VERSION})" ELSE NO)
 671   status("      util:"         HAVE_FFMPEG_UTIL    THEN "YES (ver ${ALIASOF_libavutil_VERSION})"   ELSE NO)
 672   status("      swscale:"      HAVE_FFMPEG_SWSCALE THEN "YES (ver ${ALIASOF_libswscale_VERSION})"  ELSE NO)
 673   status("      gentoo-style:" HAVE_GENTOO_FFMPEG  THEN YES                                        ELSE NO)
 674 endif(DEFINED WITH_FFMPEG)
 675
 676 if(DEFINED WITH_GSTREAMER)
 677   status("    GStreamer:"      HAVE_GSTREAMER      THEN ""                                         ELSE NO)
 678   if(HAVE_GSTREAMER)
 679     status("      base:"       "YES (ver ${ALIASOF_gstreamer-base-0.10_VERSION})")
 680     status("      app:"        "YES (ver ${ALIASOF_gstreamer-app-0.10_VERSION})")
 681     status("      video:"      "YES (ver ${ALIASOF_gstreamer-video-0.10_VERSION})")
 682   endif()
 683 endif(DEFINED WITH_GSTREAMER)
 684
 685 if(DEFINED WITH_OPENNI)
 686   status("    OpenNI:"         HAVE_OPENNI         THEN "YES (ver ${OPENNI_VERSION_STRING}, build ${OPENNI_VERSION_BUILD})"
 687                                                                                                    ELSE NO)
 688   status("    OpenNI PrimeSensor Modules:" HAVE_OPENNI_PRIME_SENSOR_MODULE
 689                                                    THEN "YES (${OPENNI_PRIME_SENSOR_MODULE})"      ELSE NO)
 690 endif(DEFINED WITH_OPENNI)
 691
 692 if(DEFINED WITH_PVAPI)
 693   status("    PvAPI:"          HAVE_PVAPI          THEN YES                                        ELSE NO)
 694 endif(DEFINED WITH_PVAPI)
 695
 696 if(DEFINED WITH_QUICKTIME)
 697   status("    QuickTime:"      WITH_QUICKTIME      THEN YES                                        ELSE NO)
 698   status("    QTKit:"          WITH_QUICKTIME      THEN NO                                         ELSE YES)
 699 endif(DEFINED WITH_QUICKTIME)
 700
 701 if(DEFINED WITH_UNICAP)
 702   status("    UniCap:"         HAVE_UNICAP         THEN "YES (ver ${ALIASOF_libunicap_VERSION})"   ELSE NO)
 703   status("    UniCap ucil:"    HAVE_UNICAP_UCIL    THEN "YES (ver ${ALIASOF_libucil_VERSION})"     ELSE NO)
 704 endif(DEFINED WITH_UNICAP)
 705
 706 if(DEFINED WITH_V4L)
 707   if(HAVE_CAMV4L)
 708     set(HAVE_CAMV4L_STR "YES")
 709   else()
 710     set(HAVE_CAMV4L_STR "NO")
 711   endif()
 712   if(HAVE_CAMV4L2)
 713     set(HAVE_CAMV4L2_STR "YES")
 714   else()
 715     set(HAVE_CAMV4L2_STR "NO")
 716   endif()
 717   status("    V4L/V4L2:"       HAVE_LIBV4L         THEN "Using libv4l (ver ${ALIASOF_libv4l1_VERSION})"
 718                                                                                                    ELSE "${HAVE_CAMV4L_STR}/${HAVE_CAMV4L2_STR}")
 719 endif(DEFINED WITH_V4L)
 720
 721 if(DEFINED WITH_VIDEOINPUT)
 722   status("    DirectShow:"     HAVE_VIDEOINPUT     THEN YES                                        ELSE NO)
 723 endif(DEFINED WITH_VIDEOINPUT)
 724
 725 if(DEFINED WITH_XIMEA)
 726   status("    XIMEA:"          HAVE_XIMEA          THEN YES                                        ELSE NO)
 727 endif(DEFINED WITH_XIMEA)
 728
 729 if(DEFINED WITH_XINE)
 730   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${ALIASOF_libxine_VERSION})"     ELSE NO)
 731 endif(DEFINED WITH_XINE)
 732
 733 # ========================== Other third-party libraries ==========================
 734 status("")
 735 status("  Other third-party libraries:")
 736
 737 if(DEFINED WITH_IPP)
 738   if(WITH_IPP AND IPP_FOUND)
 739     status("    Use IPP:" "${IPP_LATEST_VERSION_STR} [${IPP_LATEST_VERSION_MAJOR}.${IPP_LATEST_VERSION_MINOR}.${IPP_LATEST_VERSION_BUILD}]")
 740     status("         at:" "${IPP_ROOT_DIR}")
 741   else()
 742     status("    Use IPP:"   WITH_IPP AND NOT IPP_FOUND THEN "IPP not found" ELSE NO)
 743   endif()
 744 endif(DEFINED WITH_IPP)
 745
 746 if(DEFINED WITH_TBB)
 747   status("    Use TBB:"   HAVE_TBB   THEN "YES (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})" ELSE NO)
 748 endif(DEFINED WITH_TBB)
 749
 750 if(DEFINED WITH_CSTRIPES)
 751   status("    Use C=:"   HAVE_CSTRIPES   THEN YES ELSE NO)
 752 endif(DEFINED WITH_CSTRIPES)
 753
 754 if(DEFINED WITH_CUDA)
 755   status("    Use Cuda:"  HAVE_CUDA  THEN "YES (ver ${CUDA_VERSION_STRING})" ELSE NO)
 756 endif(DEFINED WITH_CUDA)
 757
 758 status("    Use OpenCL:"  HAVE_OPENCL  THEN YES ELSE NO)
 759
 760 status("    Use Eigen:" HAVE_EIGEN THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
 761 status("    Use Clp:"   HAVE_CLP   THEN YES ELSE NO)
 762
 763 if(HAVE_CUDA)
 764   status("")
 765   status("  NVIDIA CUDA")
 766
 767   status("    Use CUFFT:"            HAVE_CUFFT  THEN YES ELSE NO)
 768   status("    Use CUBLAS:"           HAVE_CUBLAS THEN YES ELSE NO)
 769   status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
 770   status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
 771 endif()
 772
 773 # ========================== python ==========================
 774 status("")
 775 status("  Python:")
 776 status("    Interpreter:"   PYTHON_EXECUTABLE     THEN "${PYTHON_EXECUTABLE} (ver ${PYTHON_VERSION_FULL})"         ELSE NO)
 777 if(BUILD_opencv_python)
 778   if(PYTHONLIBS_VERSION_STRING)
 779     status("    Libraries:"   HAVE_opencv_python  THEN  "${PYTHON_LIBRARIES} (ver ${PYTHONLIBS_VERSION_STRING})"   ELSE NO)
 780   else()
 781     status("    Libraries:"   HAVE_opencv_python  THEN  ${PYTHON_LIBRARIES}                                        ELSE NO)
 782   endif()
 783   status("    numpy:"         PYTHON_USE_NUMPY    THEN "${PYTHON_NUMPY_INCLUDE_DIR} (ver ${PYTHON_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
 784   status("    packages path:" PYTHON_EXECUTABLE   THEN "${PYTHON_PACKAGES_PATH}"                                   ELSE "-")
 785 endif()
 786
 787 # ========================== documentation ==========================
 788 if(BUILD_DOCS)
 789   status("")
 790   status("  Documentation:")
 791   if(HAVE_SPHINX)
 792     status("    Build Documentation:" PDFLATEX_COMPILER      THEN YES ELSE "YES (only HTML and without math expressions)")
 793   else()
 794     status("    Build Documentation:" NO)
 795   endif()
 796   status("    Sphinx:"              HAVE_SPHINX              THEN "${SPHINX_BUILD} (ver ${SPHINX_VERSION})" ELSE NO)
 797   status("    PdfLaTeX compiler:"   PDFLATEX_COMPILER        THEN "${PDFLATEX_COMPILER}" ELSE NO)
 798 endif()
 799
 800 # ========================== samples and tests ==========================
 801 status("")
 802 status("  Tests and samples:")
 803 status("    Tests:"             BUILD_TESTS AND HAVE_opencv_ts       THEN YES ELSE NO)
 804 status("    Performance tests:" BUILD_PERF_TESTS AND HAVE_opencv_ts  THEN YES ELSE NO)
 805 status("    Examples:"          BUILD_EXAMPLES                       THEN YES ELSE NO)
 806
 807 if(ANDROID)
 808   status("    Android tests:"    BUILD_TESTS AND CAN_BUILD_ANDROID_PROJECTS            THEN YES ELSE NO)
 809   status("    Android examples:" BUILD_ANDROID_EXAMPLES AND CAN_BUILD_ANDROID_PROJECTS THEN YES ELSE NO)
 810 endif()
 811
 812 # ========================== auxiliary ==========================
 813 status("")
 814 status("  Install path:" "${CMAKE_INSTALL_PREFIX}")
 815 status("")
 816 status("  cvconfig.h is in:" "${OPENCV_CONFIG_FILE_INCLUDE_DIR}")
 817 status("-----------------------------------------------------------------")
 818 status("")
 819
 820 ocv_finalize_status()
 821
 822 # ----------------------------------------------------------------------------
 823 # Warn in the case of in-source build
 824 # ----------------------------------------------------------------------------
 825 if("${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 826   message(WARNING "The source directory is the same as binary directory. \"make clean\" may damage the source tree")
 827 endif()
 828