CMakeLists.txt

   1 # The name of our project is "VULKAN". CMakeLists files in this project can
   2 # refer to the root source directory of the project as ${VULKAN_SOURCE_DIR} and
   3 # to the root binary directory of the project as ${VULKAN_BINARY_DIR}.
   4 cmake_minimum_required(VERSION 2.8.11)
   5 project (VULKAN)
   6 # set (CMAKE_VERBOSE_MAKEFILE 1)
   7
   8 # The API_NAME allows renaming builds to avoid conflicts with installed SDKs
   9 # The MAJOR number of the version we're building, used in naming
  10 # <api-name>-<major>.dll (and other files).
  11 set(API_NAME "Vulkan" CACHE STRING "API name to use when building")
  12 set(MAJOR "1")
  13 string(TOLOWER ${API_NAME} API_LOWERCASE)
  14
  15 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  16 find_package(PythonInterp 3 REQUIRED)
  17
  18 option(USE_CCACHE "Use ccache" OFF)
  19 if (USE_CCACHE)
  20     find_program(CCACHE_FOUND ccache)
  21     if(CCACHE_FOUND)
  22         set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
  23         set_property(GLOBAL PROPERTY RULE_LAUNCH_LINK ccache)
  24     endif(CCACHE_FOUND)
  25 endif()
  26
  27 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
  28     set(FALLBACK_CONFIG_DIRS "/etc/xdg" CACHE STRING
  29         "Search path to use when XDG_CONFIG_DIRS is unset or empty or the current process is SUID/SGID. Default is freedesktop compliant.")
  30     set(FALLBACK_DATA_DIRS "/usr/local/share:/usr/share" CACHE STRING
  31         "Search path to use when XDG_DATA_DIRS is unset or empty or the current process is SUID/SGID. Default is freedesktop compliant.")
  32
  33     include(FindPkgConfig)
  34     option(BUILD_WSI_XCB_SUPPORT "Build XCB WSI support" ON)
  35     option(BUILD_WSI_XLIB_SUPPORT "Build Xlib WSI support" ON)
  36     option(BUILD_WSI_WAYLAND_SUPPORT "Build Wayland WSI support" ON)
  37     option(BUILD_WSI_MIR_SUPPORT "Build Mir WSI support" OFF)
  38     set(DEMOS_WSI_SELECTION "XCB" CACHE STRING "Select WSI target for demos (XCB, XLIB, WAYLAND, MIR, DISPLAY)")
  39
  40     if (BUILD_WSI_XCB_SUPPORT)
  41         find_package(XCB REQUIRED)
  42     endif()
  43
  44     if (BUILD_WSI_XLIB_SUPPORT)
  45         find_package(X11 REQUIRED)
  46     endif()
  47
  48     if (BUILD_WSI_WAYLAND_SUPPORT)
  49         find_package(Wayland REQUIRED)
  50         include_directories(${WAYLAND_CLIENT_INCLUDE_DIR})
  51     endif()
  52
  53     if (BUILD_WSI_MIR_SUPPORT)
  54         find_package(Mir REQUIRED)
  55     endif()
  56
  57     # This option can be used to suppress the installation of artifacts from the
  58     # Vulkan-LoaderAndValidationLayers repo while running "make install" for the
  59     # VulkanTools and VulkanSamples repos.  This can be used to prevent the
  60     # overwriting of LVL artifacts when installing these downstream repos.
  61     option(INSTALL_LVL_FILES "Install content from LoaderAndValidationLayers repo" ON)
  62 endif()
  63
  64 set(SCRIPTS_DIR "${CMAKE_CURRENT_SOURCE_DIR}/scripts")
  65
  66 # Header file for CMake settings
  67 include_directories("${PROJECT_SOURCE_DIR}/include")
  68
  69 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Clang")
  70     set(COMMON_COMPILE_FLAGS "-Wall -Wextra -Wno-unused-parameter -Wno-missing-field-initializers")
  71     set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -fno-strict-aliasing -fno-builtin-memcmp")
  72
  73     # For GCC version 7.1 or greater, we need to disable the implicit fallthrough warning since
  74     # there's no consistent way to satisfy all compilers until they all accept the C++17 standard
  75     if (CMAKE_COMPILER_IS_GNUCC AND NOT (CMAKE_CXX_COMPILER_VERSION LESS 7.1))
  76         set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -Wimplicit-fallthrough=0")
  77     endif()
  78
  79     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=c99 ${COMMON_COMPILE_FLAGS}")
  80     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${COMMON_COMPILE_FLAGS} -std=c++11 -fno-rtti")
  81     if (UNIX)
  82         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden")
  83         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")
  84     endif()
  85 endif()
  86
  87 if(WIN32)
  88     # Treat warnings as errors
  89     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/WX>")
  90     # Disable RTTI
  91     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/GR->")
  92     # Warn about nested declarations
  93     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34456>")
  94     # Warn about potentially uninitialized variables
  95     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34701>")
  96     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34703>")
  97     # Warn about different indirection types.
  98     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34057>")
  99     # Warn about signed/unsigned mismatch.
 100     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34245>")
 101 endif()
 102
 103 if(NOT WIN32)
 104     set (BUILDTGT_DIR build)
 105     set (BINDATA_DIR Bin)
 106     set (LIBSOURCE_DIR Lib)
 107 else()
 108     # is WIN32
 109     option(DISABLE_BUILD_PATH_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with MSVC build type info" OFF)
 110     option(DISABLE_BUILDTGT_DIR_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with target info" OFF)
 111
 112     # For Windows, since 32-bit and 64-bit items can co-exist, we build each in its own build directory.
 113     # 32-bit target data goes in build32, and 64-bit target data goes into build.  So, include/link the
 114     # appropriate data at build time.
 115     if (DISABLE_BUILDTGT_DIR_DECORATION)
 116         set (BUILDTGT_DIR "")
 117         set (BINDATA_DIR "")
 118         set (LIBSOURCE_DIR "")
 119     elseif (CMAKE_CL_64)
 120         set (BUILDTGT_DIR build)
 121         set (BINDATA_DIR Bin)
 122         set (LIBSOURCE_DIR Lib)
 123     else()
 124         set (BUILDTGT_DIR build32)
 125         set (BINDATA_DIR Bin32)
 126         set (LIBSOURCE_DIR Lib32)
 127     endif()
 128 endif()
 129
 130 option(BUILD_LOADER "Build loader" ON)
 131 option(BUILD_TESTS "Build tests" ON)
 132 option(BUILD_LAYERS "Build layers" ON)
 133 option(BUILD_DEMOS "Build demos" ON)
 134 option(BUILD_VKJSON "Build vkjson" ON)
 135 option(BUILD_ICD "Build icd" ON)
 136 option(CUSTOM_GLSLANG_BIN_ROOT "Use the user defined GLSLANG_BINARY_ROOT" OFF)
 137 option(CUSTOM_SPIRV_TOOLS_BIN_ROOT "Use the user defined SPIRV_TOOLS*BINARY_ROOT paths" OFF)
 138
 139 #Choose natural default paths for glslang and SPIRV-Tools binaries to support custom definition by the user on the CMake command line or in the GUI
 140 set(GLSLANG_BINARY_ROOT "${CMAKE_BINARY_DIR}/../glslang" CACHE STRING "User defined path to the glslang binaries for this project")
 141 set(SPIRV_TOOLS_BINARY_ROOT "${CMAKE_BINARY_DIR}/../SPIRV-Tools" CACHE STRING "User defined path to the SPIRV-Tools binaries for this project")
 142 set(SPIRV_TOOLS_OPT_BINARY_ROOT "${CMAKE_BINARY_DIR}/../SPIRV-Tools/opt" CACHE STRING "User defined path to the SPIRV-Tools-opt binaries for this project")
 143
 144 # Define a variable for a default root location to the gslang, SPIRV-Tools and other external sources and cache it to allow the user to customize it as needed
 145 set(EXTERNAL_SOURCE_ROOT "${CMAKE_CURRENT_SOURCE_DIR}/external" CACHE STRING "Root path to external sources such as glslang and SPIRV-Tools")
 146
 147
 148 if (WIN32)
 149     if(CUSTOM_GLSLANG_BIN_ROOT)
 150         set(GSLANG_FINAL_BINARY_PATH ${GLSLANG_BINARY_ROOT}/${BUILDTGT_DIR})
 151     else()
 152         set(GSLANG_FINAL_BINARY_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}")
 153     endif()
 154
 155     if(DISABLE_BUILD_PATH_DECORATION)
 156         set (DEBUG_DECORATION "")
 157         set (RELEASE_DECORATION "")
 158     else()
 159         set (DEBUG_DECORATION "Debug")
 160         set (RELEASE_DECORATION "Release")
 161     endif()
 162
 163     # Take some steps to set up a variable pointing to the final glslang binaries given the variety of input options
 164     set (GLSLANG_SEARCH_PATH "${GSLANG_FINAL_BINARY_PATH}/glslang/${RELEASE_DECORATION}"
 165                              "${GSLANG_FINAL_BINARY_PATH}/glslang/OSDependent/Windows/${RELEASE_DECORATION}"
 166                              "${GSLANG_FINAL_BINARY_PATH}/hlsl/${RELEASE_DECORATION}"
 167                              "${GSLANG_FINAL_BINARY_PATH}/OGLCompilersDLL/${RELEASE_DECORATION}"
 168                              "${GSLANG_FINAL_BINARY_PATH}/SPIRV/${RELEASE_DECORATION}" )
 169
 170     set (GLSLANG_DEBUG_SEARCH_PATH "${GSLANG_FINAL_BINARY_PATH}/glslang/${DEBUG_DECORATION}"
 171                                    "${GSLANG_FINAL_BINARY_PATH}/glslang/OSDependent/Windows/${DEBUG_DECORATION}"
 172                                    "${GSLANG_FINAL_BINARY_PATH}/hlsl/${DEBUG_DECORATION}"
 173                                    "${GSLANG_FINAL_BINARY_PATH}/OGLCompilersDLL/${DEBUG_DECORATION}"
 174                                    "${GSLANG_FINAL_BINARY_PATH}/SPIRV/${DEBUG_DECORATION}")
 175
 176     if(CUSTOM_SPIRV_TOOLS_BIN_ROOT)
 177         set (SPIRV_TOOLS_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/${BUILDTGT_DIR}/source/${RELEASE_DECORATION}")
 178         set (SPIRV_TOOLS_DEBUG_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/${BUILDTGT_DIR}/source/${DEBUG_DECORATION}")
 179         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${SPIRV_TOOLS_OPT_BINARY_ROOT}/${BUILDTGT_DIR}/source/opt/${RELEASE_DECORATION}")
 180         set (SPIRV_TOOLS_OPT_DEBUG_SEARCH_PATH "${SPIRV_TOOLS_OPT_BINARY_ROOT}/${BUILDTGT_DIR}/source/opt/${DEBUG_DECORATION}")
 181     else()
 182         set (SPIRV_TOOLS_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source/${RELEASE_DECORATION}")
 183         set (SPIRV_TOOLS_DEBUG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source/${DEBUG_DECORATION}")
 184         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source/opt/${RELEASE_DECORATION}")
 185         set (SPIRV_TOOLS_OPT_DEBUG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source/opt/${DEBUG_DECORATION}")
 186     endif()
 187 else()
 188     # not WIN32
 189     if(CUSTOM_GLSLANG_BIN_ROOT)
 190         set (GLSLANG_SEARCH_PATH "${GLSLANG_BINARY_ROOT}/install/lib"
 191                                  "${GLSLANG_BINARY_ROOT}/glslang"
 192                                  "${GLSLANG_BINARY_ROOT}/glslang/OSDependent/Unix"
 193                                  "${GLSLANG_BINARY_ROOT}/OGLCompilersDLL"
 194                                  "${GLSLANG_BINARY_ROOT}/SPIRV"
 195                                  "${GLSLANG_BINARY_ROOT}/hlsl"
 196                                  "${GLSLANG_BINARY_ROOT}/StandAlone")
 197     else()
 198         set (GLSLANG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/install/lib" "${CMAKE_SOURCE_DIR}/../x86_64/lib/glslang" )
 199     endif()
 200
 201     if(CUSTOM_SPIRV_TOOLS_BIN_ROOT)
 202         set (SPIRV_TOOLS_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/source" )
 203         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${SPIRV_TOOLS_OPT_BINARY_ROOT}/source/opt" )
 204     else()
 205         set (SPIRV_TOOLS_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source" "${CMAKE_SOURCE_DIR}/../x86_64/lib/spirv-tools" )
 206         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source/opt" "${CMAKE_SOURCE_DIR}/../x86_64/lib/spirv-tools" )
 207     endif()
 208 endif()
 209
 210 find_program(GLSLANG_VALIDATOR NAMES glslangValidator
 211              HINTS "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/install/bin"
 212                    "${GLSLANG_BINARY_ROOT}/StandAlone"
 213                    "${PROJECT_SOURCE_DIR}/external/${BINDATA_DIR}")
 214
 215 find_path(GLSLANG_SPIRV_INCLUDE_DIR SPIRV/spirv.hpp HINTS "${EXTERNAL_SOURCE_ROOT}/glslang"
 216                                                     "${CMAKE_SOURCE_DIR}/../glslang"
 217                                               DOC "Path to SPIRV/spirv.hpp")
 218
 219 find_path(SPIRV_TOOLS_INCLUDE_DIR spirv-tools/libspirv.h HINTS "${EXTERNAL_SOURCE_ROOT}/glslang/External/spirv-tools/include"
 220                                                    "${CMAKE_SOURCE_DIR}/../glslang/External/spirv-tools/include"
 221                                              DOC "Path to spirv-tools/libspirv.h")
 222
 223 find_library(GLSLANG_LIB NAMES glslang
 224              HINTS ${GLSLANG_SEARCH_PATH} )
 225
 226 find_library(OGLCompiler_LIB NAMES OGLCompiler
 227              HINTS ${GLSLANG_SEARCH_PATH} )
 228
 229 find_library(OSDependent_LIB NAMES OSDependent
 230              HINTS ${GLSLANG_SEARCH_PATH} )
 231
 232 find_library(HLSL_LIB NAMES HLSL
 233              HINTS ${GLSLANG_SEARCH_PATH} )
 234
 235 find_library(SPIRV_LIB NAMES SPIRV
 236              HINTS ${GLSLANG_SEARCH_PATH} )
 237
 238 find_library(SPIRV_REMAPPER_LIB NAMES SPVRemapper
 239              HINTS ${GLSLANG_SEARCH_PATH} )
 240
 241 find_library(SPIRV_TOOLS_LIB NAMES SPIRV-Tools
 242              HINTS ${SPIRV_TOOLS_SEARCH_PATH} )
 243
 244 find_library(SPIRV_TOOLS_OPT_LIB NAMES SPIRV-Tools-opt
 245              HINTS ${SPIRV_TOOLS_OPT_SEARCH_PATH} )
 246
 247 if (WIN32)
 248     add_library(glslang         STATIC IMPORTED)
 249     add_library(OGLCompiler     STATIC IMPORTED)
 250     add_library(OSDependent     STATIC IMPORTED)
 251     add_library(HLSL            STATIC IMPORTED)
 252     add_library(SPIRV           STATIC IMPORTED)
 253     add_library(SPVRemapper     STATIC IMPORTED)
 254     add_library(Loader          STATIC IMPORTED)
 255     add_library(SPIRV-Tools-opt STATIC IMPORTED)
 256     add_library(SPIRV-Tools     STATIC IMPORTED)
 257
 258     find_library(GLSLANG_DLIB NAMES glslangd
 259                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 260     find_library(OGLCompiler_DLIB NAMES OGLCompilerd
 261                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 262     find_library(OSDependent_DLIB NAMES OSDependentd
 263                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 264     find_library(HLSL_DLIB NAMES HLSLd
 265                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 266     find_library(SPIRV_DLIB NAMES SPIRVd
 267                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 268     find_library(SPIRV_REMAPPER_DLIB NAMES SPVRemapperd
 269                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 270     find_library(SPIRV_TOOLS_DLIB NAMES SPIRV-Toolsd
 271                  HINTS ${SPIRV_TOOLS_DEBUG_SEARCH_PATH} )
 272     find_library(SPIRV_TOOLS_OPT_DLIB NAMES SPIRV-Tools-optd
 273                  HINTS ${SPIRV_TOOLS_OPT_DEBUG_SEARCH_PATH} )
 274
 275     set_target_properties(glslang PROPERTIES
 276                          IMPORTED_LOCATION       "${GLSLANG_LIB}"
 277                          IMPORTED_LOCATION_DEBUG "${GLSLANG_DLIB}")
 278     set_target_properties(OGLCompiler PROPERTIES
 279                          IMPORTED_LOCATION       "${OGLCompiler_LIB}"
 280                          IMPORTED_LOCATION_DEBUG "${OGLCompiler_DLIB}")
 281     set_target_properties(OSDependent PROPERTIES
 282                          IMPORTED_LOCATION       "${OSDependent_LIB}"
 283                          IMPORTED_LOCATION_DEBUG "${OSDependent_DLIB}")
 284     set_target_properties(HLSL PROPERTIES
 285                          IMPORTED_LOCATION       "${HLSL_LIB}"
 286                          IMPORTED_LOCATION_DEBUG "${HLSL_DLIB}")
 287     set_target_properties(SPIRV PROPERTIES
 288                          IMPORTED_LOCATION       "${SPIRV_LIB}"
 289                          IMPORTED_LOCATION_DEBUG "${SPIRV_DLIB}")
 290     set_target_properties(SPVRemapper PROPERTIES
 291                          IMPORTED_LOCATION       "${SPIRV_REMAPPER_LIB}"
 292                          IMPORTED_LOCATION_DEBUG "${SPIRV_REMAPPER_DLIB}")
 293     set_target_properties(SPIRV-Tools PROPERTIES
 294                          IMPORTED_LOCATION       "${SPIRV_TOOLS_LIB}"
 295                          IMPORTED_LOCATION_DEBUG "${SPIRV_TOOLS_DLIB}")
 296     set_target_properties(SPIRV-Tools-opt PROPERTIES
 297                          IMPORTED_LOCATION       "${SPIRV_TOOLS_OPT_LIB}"
 298                          IMPORTED_LOCATION_DEBUG "${SPIRV_TOOLS_OPT_DLIB}")
 299
 300     set (SPIRV_TOOLS_LIBRARIES SPIRV-Tools-opt SPIRV-Tools)
 301     set (GLSLANG_LIBRARIES glslang OGLCompiler OSDependent HLSL SPIRV SPVRemapper ${SPIRV_TOOLS_LIBRARIES})
 302 else ()
 303     # not WIN32
 304     set (SPIRV_TOOLS_LIBRARIES ${SPIRV_TOOLS_OPT_LIB} ${SPIRV_TOOLS_LIB})
 305     set (GLSLANG_LIBRARIES ${GLSLANG_LIB} ${OGLCompiler_LIB} ${OSDependent_LIB} ${HLSL_LIB} ${SPIRV_LIB} ${SPIRV_REMAPPER_LIB} ${SPIRV_TOOLS_LIBRARIES})
 306 endif()
 307
 308 set (PYTHON_CMD ${PYTHON_EXECUTABLE})
 309
 310 # Define macro used for building vkxml generated files
 311 macro(run_vk_xml_generate dependency output)
 312     add_custom_command(OUTPUT ${output}
 313     COMMAND ${PYTHON_CMD} ${SCRIPTS_DIR}/lvl_genvk.py -registry ${SCRIPTS_DIR}/vk.xml ${output}
 314     DEPENDS ${SCRIPTS_DIR}/vk.xml ${SCRIPTS_DIR}/generator.py ${SCRIPTS_DIR}/${dependency} ${SCRIPTS_DIR}/lvl_genvk.py ${SCRIPTS_DIR}/reg.py
 315     )
 316 endmacro()
 317
 318 # Define macro used for generating header files containing commit IDs for external dependencies
 319 macro(run_external_revision_generate source_dir symbol_name output)
 320     add_custom_command(OUTPUT ${output}
 321     COMMAND ${PYTHON_CMD} ${SCRIPTS_DIR}/external_revision_generator.py ${source_dir} ${symbol_name} ${output}
 322     DEPENDS ${SCRIPTS_DIR}/external_revision_generator.py ${source_dir}/.git/HEAD ${source_dir}/.git/index
 323     )
 324 endmacro()
 325
 326 # Custom target for generated vulkan helper file dependencies
 327 add_custom_target(generate_helper_files DEPENDS
 328     vk_enum_string_helper.h
 329     vk_struct_size_helper.h
 330     vk_struct_size_helper.c
 331     vk_safe_struct.h
 332     vk_safe_struct.cpp
 333     vk_object_types.h
 334     vk_layer_dispatch_table.h
 335     vk_dispatch_table_helper.h
 336     vk_extension_helper.h
 337     vk_typemap_helper.h
 338     spirv_tools_commit_id.h
 339     )
 340
 341 # Rules to build generated helper files
 342 run_vk_xml_generate(loader_extension_generator.py vk_layer_dispatch_table.h)
 343 run_vk_xml_generate(dispatch_table_helper_generator.py vk_dispatch_table_helper.h)
 344 run_vk_xml_generate(helper_file_generator.py vk_safe_struct.h)
 345 run_vk_xml_generate(helper_file_generator.py vk_safe_struct.cpp)
 346 run_vk_xml_generate(helper_file_generator.py vk_struct_size_helper.h)
 347 run_vk_xml_generate(helper_file_generator.py vk_struct_size_helper.c)
 348 run_vk_xml_generate(helper_file_generator.py vk_enum_string_helper.h)
 349 run_vk_xml_generate(helper_file_generator.py vk_object_types.h)
 350 run_vk_xml_generate(helper_file_generator.py vk_extension_helper.h)
 351 run_vk_xml_generate(helper_file_generator.py vk_typemap_helper.h)
 352 run_external_revision_generate(${EXTERNAL_SOURCE_ROOT}/glslang/External/spirv-tools SPIRV_TOOLS_COMMIT_ID spirv_tools_commit_id.h)
 353
 354 if(NOT WIN32)
 355     include(GNUInstallDirs)
 356
 357     add_definitions(-DFALLBACK_CONFIG_DIRS="${FALLBACK_CONFIG_DIRS}")
 358     add_definitions(-DFALLBACK_DATA_DIRS="${FALLBACK_DATA_DIRS}")
 359     add_definitions(-DSYSCONFDIR="${CMAKE_INSTALL_FULL_SYSCONFDIR}")
 360
 361     # Make sure /etc is searched by the loader
 362     if(NOT (CMAKE_INSTALL_FULL_SYSCONFDIR STREQUAL "/etc"))
 363         add_definitions(-DEXTRASYSCONFDIR="/etc")
 364     endif()
 365 endif()
 366
 367 if(UNIX)
 368     if(INSTALL_LVL_FILES)
 369         install(DIRECTORY "${PROJECT_SOURCE_DIR}/include/vulkan" DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 370         install(FILES "${CMAKE_CURRENT_BINARY_DIR}/vk_layer_dispatch_table.h" DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/vulkan")
 371     endif()
 372
 373 # uninstall target
 374 configure_file(
 375     "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 376     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 377     IMMEDIATE @ONLY)
 378
 379 add_custom_target(uninstall
 380     COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)
 381 endif()
 382
 383 add_definitions(-DAPI_NAME="${API_NAME}")
 384
 385 # loader: Generic VULKAN ICD loader
 386 # tests: VULKAN tests
 387 if(BUILD_LOADER)
 388     add_subdirectory(loader)
 389 endif()
 390
 391 if(BUILD_TESTS)
 392     add_subdirectory(tests)
 393 endif()
 394
 395 if(BUILD_LAYERS)
 396     add_subdirectory(layers)
 397 endif()
 398
 399 if(BUILD_DEMOS)
 400     add_subdirectory(demos)
 401 endif()
 402
 403 if(BUILD_VKJSON)
 404     add_subdirectory(libs/vkjson)
 405 endif()
 406
 407 if(BUILD_ICD)
 408     add_subdirectory(icd)
 409 endif()