CMakeLists.txt

   1 PROJECT (libsolv)
   2
   3 CMAKE_MINIMUM_REQUIRED (VERSION 2.4)
   4
   5 OPTION (ENABLE_STATIC "Build a static version of the libraries?" OFF)
   6 OPTION (DISABLE_SHARED "Do not build a shared version of the libraries?" OFF)
   7
   8 OPTION (ENABLE_PERL "Build the perl bindings?" OFF)
   9 OPTION (ENABLE_PYTHON "Build the python bindings?" OFF)
  10 OPTION (ENABLE_RUBY "Build the ruby bindings?" OFF)
  11 OPTION (ENABLE_TCL "Build the Tcl bindings?" OFF)
  12
  13 OPTION (USE_VENDORDIRS "Install the bindings in vendor directories?" OFF)
  14
  15 OPTION (ENABLE_RPMDB "Build with rpm database support?" OFF)
  16 OPTION (ENABLE_RPMPKG "Build with rpm package support?" OFF)
  17 OPTION (ENABLE_PUBKEY "Build with pubkey support?" OFF)
  18 OPTION (ENABLE_RPMDB_BYRPMHEADER "Build with rpmdb Header support?" OFF)
  19 OPTION (ENABLE_RPMMD "Build with rpmmd repository support?" OFF)
  20 OPTION (ENABLE_SUSEREPO "Build with suse repository support?" OFF)
  21 OPTION (ENABLE_COMPS "Build with fedora comps support?" OFF)
  22 OPTION (ENABLE_HELIXREPO "Build with helix repository support?" OFF)
  23 OPTION (ENABLE_DEBIAN "Build with debian database/repository support?" OFF)
  24 OPTION (ENABLE_MDKREPO "Build with mandriva/mageia repository support?" OFF)
  25 OPTION (ENABLE_ARCHREPO "Build with archlinux repository support?" OFF)
  26 OPTION (ENABLE_CUDFREPO "Build with cudf repository support?" OFF)
  27 OPTION (ENABLE_HAIKU "Build with Haiku package support?" OFF)
  28 OPTION (ENABLE_APPDATA "Build with AppStream appdata support?" OFF)
  29
  30 OPTION (MULTI_SEMANTICS "Build with support for multiple distribution types?" OFF)
  31
  32 OPTION (ENABLE_LZMA_COMPRESSION "Build with lzma/xz compression support?" OFF)
  33 OPTION (ENABLE_BZIP2_COMPRESSION "Build with bzip2 compression support?" OFF)
  34
  35 #IF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERISION} GREATER 2.4)
  36 #ENDIF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERISION} GREATER 2.4)
  37
  38 IF (COMMAND cmake_policy)
  39   # escape preprocessor, see -DVERSION below
  40   CMAKE_POLICY (SET CMP0005 OLD)
  41 ENDIF (COMMAND cmake_policy)
  42
  43 # Library
  44 IF (DEFINED LIB)
  45   SET (LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${LIB}")
  46 ELSE (DEFINED  LIB)
  47   IF (CMAKE_SIZEOF_VOID_P MATCHES "8")
  48     SET (LIB_SUFFIX "64")
  49   ENDIF (CMAKE_SIZEOF_VOID_P MATCHES "8")
  50   SET (LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX}")
  51 ENDIF (DEFINED  LIB)
  52 MESSAGE (STATUS "Libraries will be installed in ${LIB_INSTALL_DIR}")
  53 # Library
  54 IF (DEFINED INCLUDE)
  55   SET (INCLUDE_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${INCLUDE}")
  56 else (DEFINED INCLUDE)
  57   SET (INCLUDE_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/include")
  58 ENDIF (DEFINED  INCLUDE)
  59 MESSAGE (STATUS "Header files will be installed in ${INCLUDE_INSTALL_DIR}")
  60 SET (BIN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/bin")
  61 SET (MAN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/share/man")
  62 IF (IS_DIRECTORY "${CMAKE_INSTALL_PREFIX}/man"  AND NOT IS_DIRECTORY "${CMAKE_INSTALL_PREFIX}/share/man")
  63   SET (MAN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/man")
  64 ENDIF (IS_DIRECTORY "${CMAKE_INSTALL_PREFIX}/man"  AND NOT IS_DIRECTORY "${CMAKE_INSTALL_PREFIX}/share/man")
  65 MESSAGE(STATUS "Man pages will be installed in ${MAN_INSTALL_DIR}")
  66
  67 ####################################################################
  68 # CONFIGURATION                                                    #
  69 ####################################################################
  70
  71 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
  72 SET (CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  73 INSTALL( FILES ${CMAKE_MODULE_PATH}/FindLibSolv.cmake DESTINATION ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules )
  74
  75 INCLUDE (${CMAKE_SOURCE_DIR}/VERSION.cmake)
  76
  77 SET (have_system x)
  78
  79 IF (FEDORA)
  80 MESSAGE(STATUS "Building for Fedora")
  81 ADD_DEFINITIONS (-DFEDORA)
  82 SET (ENABLE_RPMDB ON)
  83 SET (ENABLE_RPMMD ON)
  84 SET (have_system ${have_system}x)
  85 ENDIF (FEDORA)
  86
  87 IF (DEBIAN)
  88 MESSAGE (STATUS "Building for Debian")
  89 ADD_DEFINITIONS (-DDEBIAN)
  90 SET (ENABLE_DEBIAN ON)
  91 SET (have_system ${have_system}x)
  92 ENDIF (DEBIAN)
  93
  94 IF (SUSE)
  95 MESSAGE (STATUS "Building for SUSE")
  96 ADD_DEFINITIONS (-DSUSE)
  97 SET (ENABLE_RPMDB ON)
  98 SET (ENABLE_PUBKEY ON)
  99 SET (ENABLE_RPMDB_BYRPMHEADER ON)
 100 SET (ENABLE_RPMMD ON)
 101 SET (ENABLE_SUSEREPO ON)
 102 SET (ENABLE_HELIXREPO ON)
 103 SET (ENABLE_LINKED_PKGS ON)
 104 SET (have_system ${have_system}x)
 105 ENDIF (SUSE)
 106
 107 IF (ARCHLINUX)
 108 MESSAGE (STATUS "Building for Archlinux")
 109 ADD_DEFINITIONS (-DARCHLINUX)
 110 SET (ENABLE_ARCHREPO ON)
 111 SET (have_system ${have_system}x)
 112 ENDIF (ARCHLINUX)
 113
 114 IF (MANDRIVA)
 115 MESSAGE (STATUS "Building for Mandriva")
 116 ADD_DEFINITIONS (-DMANDRIVA)
 117 SET (ENABLE_MDKREPO ON)
 118 SET (ENABLE_RPMDB ON)
 119 SET (have_system ${have_system}x)
 120 ENDIF (MANDRIVA)
 121
 122 IF (MAGEIA)
 123 MESSAGE (STATUS "Building for Mageia")
 124 ADD_DEFINITIONS (-DMAGEIA)
 125 SET (ENABLE_MDKREPO ON)
 126 SET (ENABLE_RPMDB ON)
 127 SET (ENABLE_RPMMD ON)
 128 SET (ENABLE_LZMA_COMPRESSION ON)
 129 SET (have_system ${have_system}x)
 130 ENDIF (MAGEIA)
 131
 132 IF (HAIKU)
 133 MESSAGE(STATUS "Building for Haiku")
 134 FIND_LIBRARY(HAIKU_BE_LIBRARY NAMES be)
 135 FIND_LIBRARY(HAIKU_NETWORK_LIBRARY NAMES network)
 136 FIND_LIBRARY(HAIKU_PACKAGE_LIBRARY NAMES package)
 137 SET (HAIKU_SYSTEM_LIBRARIES
 138     ${HAIKU_BE_LIBRARY} ${HAIKU_NETWORK_LIBRARY} ${HAIKU_PACKAGE_LIBRARY})
 139 ADD_DEFINITIONS (-DHAIKU)
 140 SET (ENABLE_HAIKU ON)
 141 SET (have_system ${have_system}x)
 142 ENDIF (HAIKU)
 143
 144 IF (${have_system} STREQUAL x)
 145     MESSAGE (STATUS "Building for no system")
 146 ENDIF (${have_system} STREQUAL x)
 147 IF (${have_system} STRGREATER xx)
 148     MESSAGE (FATAL_ERROR "Can only compile for one system type.")
 149 ENDIF (${have_system} STRGREATER xx)
 150
 151 IF (ENABLE_ARCHREPO)
 152 SET (ENABLE_LZMA_COMPRESSION ON)
 153 ENDIF (ENABLE_ARCHREPO)
 154
 155 FIND_PACKAGE (EXPAT REQUIRED)
 156 FIND_PACKAGE (ZLIB REQUIRED)
 157 IF (ENABLE_LZMA_COMPRESSION)
 158 FIND_PACKAGE (LZMA REQUIRED)
 159 ENDIF (ENABLE_LZMA_COMPRESSION)
 160 IF (ENABLE_BZIP2_COMPRESSION)
 161 FIND_PACKAGE (BZip2 REQUIRED)
 162 ENDIF (ENABLE_BZIP2_COMPRESSION)
 163
 164 IF (RPM5)
 165 MESSAGE (STATUS "Enabling RPM 5 support")
 166 ADD_DEFINITIONS (-DRPM5)
 167 SET (ENABLE_RPMDB ON)
 168 SET (ENABLE_RPMMD ON)
 169 FIND_PACKAGE (PkgConfig REQUIRED)
 170 PKG_CHECK_MODULES (RPM REQUIRED rpm)
 171 INCLUDE_DIRECTORIES (${RPM_INCLUDE_DIRS})
 172 ENDIF (RPM5)
 173
 174 IF (MULTI_SEMANTICS)
 175 MESSAGE (STATUS "Enabling multi dist support")
 176 ENDIF (MULTI_SEMANTICS)
 177
 178 IF (ENABLE_RPMDB)
 179 SET (ENABLE_RPMPKG ON)
 180 ENDIF (ENABLE_RPMDB)
 181
 182 INCLUDE (CheckIncludeFile)
 183 IF (ENABLE_RPMDB)
 184   FIND_LIBRARY (RPMDB_LIBRARY NAMES rpmdb)
 185
 186   IF (NOT RPMDB_LIBRARY)
 187     FIND_LIBRARY (RPMDB_LIBRARY NAMES rpm)
 188   ENDIF (NOT RPMDB_LIBRARY)
 189
 190   FIND_LIBRARY (RPMIO_LIBRARY NAMES rpmio)
 191   IF (RPMIO_LIBRARY)
 192     SET(RPMDB_LIBRARY ${RPMIO_LIBRARY} ${RPMDB_LIBRARY})
 193   ENDIF (RPMIO_LIBRARY)
 194
 195   IF (RPM5)
 196     FIND_LIBRARY (RPMMISC_LIBRARY NAMES rpmmisc)
 197     IF (RPMMISC_LIBRARY)
 198       SET (RPMDB_LIBRARY ${RPMMISC_LIBRARY} ${RPMDB_LIBRARY})
 199     ENDIF (RPMMISC_LIBRARY)
 200   ENDIF (RPM5)
 201
 202   # check if rpm contains a bundled berkeley db
 203   CHECK_INCLUDE_FILE(rpm/db.h HAVE_RPM_DB_H)
 204   IF (NOT HAVE_RPM_DB_H)
 205     FIND_LIBRARY (DB_LIBRARY NAMES db)
 206     IF (DB_LIBRARY)
 207       SET (RPMDB_LIBRARY ${DB_LIBRARY} ${RPMDB_LIBRARY})
 208     ENDIF (DB_LIBRARY)
 209   ENDIF (NOT HAVE_RPM_DB_H)
 210   INCLUDE (CheckLibraryExists)
 211   CHECK_LIBRARY_EXISTS(rpmio pgpDigGetParams "" HAVE_PGPDIGGETPARAMS)
 212 ENDIF (ENABLE_RPMDB)
 213
 214 IF (ENABLE_PUBKEY)
 215   SET (ENABLE_PGPVRFY ON)
 216 ENDIF (ENABLE_PUBKEY)
 217
 218 INCLUDE (CheckFunctionExists)
 219 INCLUDE (TestBigEndian)
 220
 221 CHECK_FUNCTION_EXISTS (strchrnul HAVE_STRCHRNUL)
 222 CHECK_FUNCTION_EXISTS (fopencookie HAVE_FOPENCOOKIE)
 223 CHECK_FUNCTION_EXISTS (funopen HAVE_FUNOPEN)
 224 TEST_BIG_ENDIAN (WORDS_BIGENDIAN)
 225
 226 IF (${CMAKE_MAJOR_VERSION} GREATER 2)
 227 INCLUDE (CMakePushCheckState)
 228 INCLUDE (CheckCCompilerFlag)
 229 MACRO (check_linker_flag FLAG VAR)
 230         CMAKE_PUSH_CHECK_STATE (RESET)
 231         SET (CMAKE_REQUIRED_FLAGS "${FLAG}")
 232         CHECK_C_COMPILER_FLAG ("" "${VAR}")
 233         CMAKE_POP_CHECK_STATE ()
 234 ENDMACRO (check_linker_flag)
 235 check_linker_flag("-Wl,--as-needed" HAVE_LINKER_AS_NEEDED)
 236 check_linker_flag("-Wl,--version-script=${CMAKE_SOURCE_DIR}/src/libsolv.ver" HAVE_LINKER_VERSION_SCRIPT)
 237 ELSE (${CMAKE_MAJOR_VERSION} GREATER 2)
 238 SET (HAVE_LINKER_AS_NEEDED 1)
 239 SET (HAVE_LINKER_VERSION_SCRIPT 1)
 240 ENDIF (${CMAKE_MAJOR_VERSION} GREATER 2)
 241
 242 # should create config.h with #cmakedefine instead...
 243 FOREACH (VAR HAVE_STRCHRNUL HAVE_FOPENCOOKIE HAVE_FUNOPEN WORDS_BIGENDIAN
 244   HAVE_RPM_DB_H HAVE_PGPDIGGETPARAMS)
 245   IF(${VAR})
 246     ADD_DEFINITIONS (-D${VAR}=1)
 247     SET (SWIG_FLAGS ${SWIG_FLAGS} -D${VAR})
 248   ENDIF (${VAR})
 249 ENDFOREACH (VAR)
 250
 251 FOREACH (VAR
 252   ENABLE_LINKED_PKGS ENABLE_COMPLEX_DEPS MULTI_SEMANTICS)
 253   IF(${VAR})
 254     ADD_DEFINITIONS (-D${VAR}=1)
 255     SET (SWIG_FLAGS ${SWIG_FLAGS} -D${VAR})
 256     STRING(REPLACE ENABLE_ "" VARX ${VAR})
 257     SET (LIBSOLV_FEATURE_${VARX} 1)
 258   ENDIF (${VAR})
 259 ENDFOREACH (VAR)
 260
 261 FOREACH (VAR
 262   ENABLE_RPMDB ENABLE_RPMPKG ENABLE_PUBKEY ENABLE_RPMMD ENABLE_RPMDB_BYRPMHEADER
 263   ENABLE_SUSEREPO ENABLE_COMPS
 264   ENABLE_HELIXREPO ENABLE_MDKREPO ENABLE_ARCHREPO ENABLE_DEBIAN ENABLE_HAIKU
 265   ENABLE_LZMA_COMPRESSION ENABLE_BZIP2_COMPRESSION ENABLE_PGPVRFY ENABLE_APPDATA)
 266   IF(${VAR})
 267     ADD_DEFINITIONS (-D${VAR}=1)
 268     SET (SWIG_FLAGS ${SWIG_FLAGS} -D${VAR})
 269     STRING(REPLACE ENABLE_ "" VARX ${VAR})
 270     SET (LIBSOLVEXT_FEATURE_${VARX} 1)
 271   ENDIF (${VAR})
 272 ENDFOREACH (VAR)
 273
 274 SET (PACKAGE "libsolv")
 275 SET (VERSION "${LIBSOLV_MAJOR}.${LIBSOLV_MINOR}.${LIBSOLV_PATCH}")
 276
 277 ADD_DEFINITIONS (-D_FILE_OFFSET_BITS=64)
 278 ADD_DEFINITIONS (-DVERSION=\\\"${VERSION}\\\")
 279 CONFIGURE_FILE (src/solvversion.h.in src/solvversion.h)
 280
 281 SET (CPACK_PACKAGE_DESCRIPTION_SUMMARY "Package dependency solver library")
 282 SET (CPACK_PACKAGE_VENDOR "SUSE")
 283 SET (CPACK_PACKAGE_VERSION_MAJOR ${LIBSOLV_MAJOR})
 284 SET (CPACK_PACKAGE_VERSION_MINOR ${LIBSOLV_MINOR})
 285 SET (CPACK_PACKAGE_VERSION_PATCH ${LIBSOLV_PATCH})
 286 SET (CPACK_GENERATOR "TBZ2")
 287 SET (CPACK_SOURCE_GENERATOR "TBZ2")
 288 SET (CPACK_SOURCE_PACKAGE_FILE_NAME "${PACKAGE}-${VERSION}")
 289 SET (CPACK_SOURCE_TOPLEVEL_TAG "Linux-Source:")
 290 SET (CPACK_TOPLEVEL_TAG "Linux-Source:")
 291
 292 # The following components are regex's to match anywhere (unless anchored)
 293 # in absolute path + filename to find files or directories to be excluded
 294 # from source tarball.
 295 SET (CPACK_SOURCE_IGNORE_FILES
 296 # temporary files
 297 "\\\\.swp$"
 298 # backup files
 299 "~$"
 300 # eclipse files
 301 "\\\\.cdtproject$"
 302 "\\\\.cproject$"
 303 "\\\\.project$"
 304 "\\\\.settings/"
 305 # others
 306 "\\\\.#"
 307 "/#"
 308 "/build/"
 309 "/_build/"
 310 "/\\\\.git/"
 311 # used before
 312 "/\\\\.libs/"
 313 "/\\\\.deps/"
 314 "\\\\.o$"
 315 "\\\\.lo$"
 316 "\\\\.la$"
 317 "Makefile$"
 318 "Makefile\\\\.in$"
 319 # cmake cache files
 320 "DartConfiguration.tcl$"
 321 "CMakeCache.txt"
 322 "CMakeFiles"
 323 "cmake_install.cmake$"
 324 "CMakeLists.txt.auto$"
 325 "CTestTestfile.cmake"
 326 "CPackConfig.cmake$"
 327 "CPackSourceConfig.cmake$"
 328 "libsolv.spec$"
 329 )
 330
 331 INCLUDE(CPack)
 332
 333 ####################################################################
 334 # INCLUDES                                                         #
 335 ####################################################################
 336
 337 #SET (CMAKE_INCLUDE_DIRECTORIES_BEFORE ON)
 338 INCLUDE_DIRECTORIES (${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_SOURCE_DIR} ${CMAKE_SOURCE_DIR}/src ${CMAKE_SOURCE_DIR}/ext ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_BINARY_DIR}/src SYSTEM )
 339
 340 ####################################################################
 341
 342 MESSAGE (STATUS "Looking for modules in ${CMAKE_MODULE_PATH}")
 343
 344 set (CMAKE_C_FLAGS     "${CMAKE_C_FLAGS} -Wall")
 345 set (CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS} -O3")
 346 set (CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS} -g -O3")
 347 set (CMAKE_C_FLAGS_DEBUG     "${CMAKE_C_FLAGS} -g3 -O0")
 348
 349 SET (SYSTEM_LIBRARIES ${EXPAT_LIBRARY} ${ZLIB_LIBRARY})
 350 IF (ENABLE_LZMA_COMPRESSION)
 351 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${LZMA_LIBRARY})
 352 ENDIF (ENABLE_LZMA_COMPRESSION)
 353 IF (ENABLE_BZIP2_COMPRESSION)
 354 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${BZIP2_LIBRARIES})
 355 ENDIF (ENABLE_BZIP2_COMPRESSION)
 356 IF (ENABLE_RPMDB)
 357 SET (SYSTEM_LIBRARIES ${RPMDB_LIBRARY} ${SYSTEM_LIBRARIES})
 358 ENDIF (ENABLE_RPMDB)
 359 IF (ENABLE_HAIKU)
 360 SET (SYSTEM_LIBRARIES ${HAIKU_SYSTEM_LIBRARIES} ${SYSTEM_LIBRARIES})
 361 ENDIF (ENABLE_HAIKU)
 362 IF (HAVE_LINKER_AS_NEEDED)
 363 SET (SYSTEM_LIBRARIES "-Wl,--as-needed" ${SYSTEM_LIBRARIES})
 364 ENDIF (HAVE_LINKER_AS_NEEDED)
 365
 366 ADD_SUBDIRECTORY (src)
 367 ADD_SUBDIRECTORY (ext)
 368 ADD_SUBDIRECTORY (tools)
 369 IF (ENABLE_PERL OR ENABLE_PYTHON OR ENABLE_RUBY OR ENABLE_TCL)
 370     ADD_SUBDIRECTORY (bindings)
 371 ENDIF (ENABLE_PERL OR ENABLE_PYTHON OR ENABLE_RUBY OR ENABLE_TCL)
 372 ADD_SUBDIRECTORY (examples)
 373 ADD_SUBDIRECTORY (doc)
 374
 375 MESSAGE (STATUS "Version: ${VERSION}")
 376
 377 ####################################################################
 378 # RPM SPEC                                                         #
 379 ####################################################################
 380
 381 MACRO (SPECFILE)
 382   MESSAGE (STATUS "Writing spec file...")
 383   CONFIGURE_FILE (${CMAKE_SOURCE_DIR}/package/libsolv.spec.in ${CMAKE_BINARY_DIR}/package/libsolv.spec @ONLY)
 384 ENDMACRO (SPECFILE)
 385
 386 MACRO (PCFILE)
 387   MESSAGE (STATUS "Writing pkg-config file...")
 388   CONFIGURE_FILE (${CMAKE_SOURCE_DIR}/libsolv.pc.in ${CMAKE_BINARY_DIR}/libsolv.pc @ONLY)
 389   INSTALL( FILES ${CMAKE_BINARY_DIR}/libsolv.pc DESTINATION ${LIB_INSTALL_DIR}/pkgconfig )
 390 ENDMACRO (PCFILE)
 391
 392 SPECFILE ()
 393 PCFILE ()
 394
 395 SET (AUTOBUILD_COMMAND
 396   COMMAND ${CMAKE_COMMAND} -E remove ${CMAKE_BINARY_DIR}/package/*.tar.bz2
 397   COMMAND mkdir -p _CPack_Packages/${CPACK_TOPLEVEL_TAG}
 398   COMMAND ${CMAKE_MAKE_PROGRAM} package_source
 399   COMMAND ${CMAKE_COMMAND} -E copy ${CPACK_SOURCE_PACKAGE_FILE_NAME}.tar.bz2 ${CMAKE_BINARY_DIR}/package
 400   COMMAND ${CMAKE_COMMAND} -E remove ${CPACK_SOURCE_PACKAGE_FILE_NAME}.tar.bz2
 401   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_SOURCE_DIR}/package/libsolv.changes" "${CMAKE_BINARY_DIR}/package/libsolv.changes"
 402 )
 403
 404 ADD_CUSTOM_TARGET (srcpackage
 405   ${AUTOBUILD_COMMAND}
 406 )
 407
 408 ADD_CUSTOM_TARGET (srcpackage_local
 409   ${AUTOBUILD_COMMAND}
 410 )
 411
 412 ENABLE_TESTING()
 413 ADD_SUBDIRECTORY (test)