CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2
   3 if(NOT DEFINED CMAKE_BUILD_TYPE)
   4         set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type")
   5 endif()
   6
   7 project(libwebsockets C)
   8
   9 set(PACKAGE "libwebsockets")
  10 set(CPACK_PACKAGE_NAME "${PACKAGE}")
  11 set(CPACK_PACKAGE_VERSION_MAJOR "1")
  12 set(CPACK_PACKAGE_VERSION_MINOR "6")
  13 set(CPACK_PACKAGE_VERSION_PATCH "0")
  14 set(CPACK_PACKAGE_VERSION "${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
  15 set(CPACK_PACKAGE_VENDOR "andy@warmcat.com")
  16 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "${PACKAGE} ${PACKAGE_VERSION}")
  17 set(SOVERSION "6")
  18 set(CPACK_SOURCE_GENERATOR "TGZ")
  19 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
  20 set(VERSION "${CPACK_PACKAGE_VERSION}")
  21
  22 set(LWS_LIBRARY_VERSION ${CPACK_PACKAGE_VERSION})
  23 set(LWS_LIBRARY_VERSION_MAJOR ${CPACK_PACKAGE_VERSION_MAJOR})
  24 set(LWS_LIBRARY_VERSION_MINOR ${CPACK_PACKAGE_VERSION_MINOR})
  25 set(LWS_LIBRARY_VERSION_PATCH ${CPACK_PACKAGE_VERSION_PATCH})
  26
  27 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${PROJECT_SOURCE_DIR}/cmake/")
  28
  29 message(STATUS "CMAKE_TOOLCHAIN_FILE='${CMAKE_TOOLCHAIN_FILE}'")
  30
  31 # Try to find the current Git hash.
  32 find_package(Git)
  33 if(GIT_EXECUTABLE)
  34         execute_process(
  35     WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
  36     COMMAND "${GIT_EXECUTABLE}" log -n 1 --pretty=%h
  37     OUTPUT_VARIABLE GIT_HASH
  38     OUTPUT_STRIP_TRAILING_WHITESPACE
  39     )
  40
  41     set(LWS_BUILD_HASH ${GIT_HASH})
  42     message("Git commit hash: ${LWS_BUILD_HASH}")
  43 endif()
  44
  45 set(LWS_USE_BUNDLED_ZLIB_DEFAULT OFF)
  46 if(WIN32)
  47         set(LWS_USE_BUNDLED_ZLIB_DEFAULT ON)
  48 endif()
  49
  50 option(LWS_WITH_STATIC "Build the static version of the library" ON)
  51 option(LWS_WITH_SHARED "Build the shared version of the library" ON)
  52 option(LWS_WITH_SSL "Include SSL support (default OpenSSL, wolfSSL if LWS_USE_WOLFSSL is set)" ON)
  53 option(LWS_USE_CYASSL "Use CyaSSL replacement for OpenSSL. When setting this, you also need to specify LWS_CYASSL_LIBRARIES and LWS_CYASSL_INCLUDE_DIRS" OFF)
  54 option(LWS_USE_WOLFSSL "Use wolfSSL replacement for OpenSSL. When setting this, you also need to specify LWS_WOLFSSL_LIBRARIES and LWS_WOLFSSL_INCLUDE_DIRS" OFF)
  55 option(LWS_WITH_ZLIB "Include zlib support (required for extensions)" ON)
  56 option(LWS_WITH_LIBEV "Compile with support for libev" OFF)
  57 option(LWS_WITH_LIBUV "Compile with support for libuv" OFF)
  58 option(LWS_USE_BUNDLED_ZLIB "Use bundled zlib version (Windows only)" ${LWS_USE_BUNDLED_ZLIB_DEFAULT})
  59 option(LWS_SSL_CLIENT_USE_OS_CA_CERTS "SSL support should make use of the OS-installed CA root certs" ON)
  60 option(LWS_WITHOUT_BUILTIN_GETIFADDRS "Don't use the BSD getifaddrs implementation from libwebsockets if it is missing (this will result in a compilation error) ... The default is to assume that your libc provides it. On some systems such as uclibc it doesn't exist." OFF)
  61 option(LWS_WITHOUT_BUILTIN_SHA1 "Don't build the lws sha-1 (eg, because openssl will provide it" OFF)
  62 option(LWS_WITHOUT_CLIENT "Don't build the client part of the library" OFF)
  63 option(LWS_WITHOUT_SERVER "Don't build the server part of the library" OFF)
  64 option(LWS_LINK_TESTAPPS_DYNAMIC "Link the test apps to the shared version of the library. Default is to link statically" OFF)
  65 option(LWS_WITHOUT_TESTAPPS "Don't build the libwebsocket-test-apps" OFF)
  66 option(LWS_WITHOUT_TEST_SERVER "Don't build the test server" OFF)
  67 option(LWS_WITHOUT_TEST_SERVER_EXTPOLL "Don't build the test server version that uses external poll" OFF)
  68 option(LWS_WITHOUT_TEST_PING "Don't build the ping test application" OFF)
  69 option(LWS_WITHOUT_TEST_ECHO "Don't build the echo test application" OFF)
  70 option(LWS_WITHOUT_TEST_CLIENT "Don't build the client test application" OFF)
  71 option(LWS_WITHOUT_TEST_FRAGGLE "Don't build the ping test application" OFF)
  72 option(LWS_WITHOUT_EXTENSIONS "Don't compile with extensions" OFF)
  73 option(LWS_WITH_LATENCY "Build latency measuring code into the library" OFF)
  74 option(LWS_WITHOUT_DAEMONIZE "Don't build the daemonization api" ON)
  75 option(LWS_IPV6 "Compile with support for ipv6" OFF)
  76 option(LWS_WITH_HTTP2 "Compile with support for http2" OFF)
  77 option(LWS_MBED3 "Platform is MBED3" OFF)
  78 option(LWS_SSL_SERVER_WITH_ECDH_CERT "Include SSL server use ECDH certificate" OFF)
  79
  80 if (DEFINED YOTTA_WEBSOCKETS_VERSION_STRING)
  81
  82 set(LWS_WITH_SHARED OFF)
  83 set(LWS_WITH_SSL OFF)
  84 set(LWS_WITH_ZLIB OFF)
  85 set(LWS_WITHOUT_CLIENT ON)
  86 set(LWS_WITHOUT_TESTAPPS ON)
  87 set(LWS_WITHOUT_EXTENSIONS ON)
  88 set(LWS_MBED3 ON)
  89 # this implies no pthreads in the lib
  90 set(LWS_MAX_SMP 1)
  91
  92 endif()
  93
  94 if (WIN32)
  95 # this implies no pthreads in the lib
  96 set(LWS_MAX_SMP 1)
  97 endif()
  98
  99
 100 # Allow the user to override installation directories.
 101 set(LWS_INSTALL_LIB_DIR       lib CACHE PATH "Installation directory for libraries")
 102 set(LWS_INSTALL_BIN_DIR       bin CACHE PATH "Installation directory for executables")
 103 set(LWS_INSTALL_INCLUDE_DIR   include CACHE PATH "Installation directory for header files")
 104 set(LWS_INSTALL_EXAMPLES_DIR  bin CACHE PATH "Installation directory for example files")
 105
 106 # Allow the user to use the old CyaSSL options/library in stead of wolfSSL
 107 if (LWS_USE_CYASSL AND LWS_USE_WOLFSSL)
 108         message(FATAL_ERROR "LWS_USE_CYASSL and LWS_USE_WOLFSSL are mutually exclusive!")
 109 endif()
 110 if (LWS_USE_CYASSL)
 111         # Copy CyaSSL options to the wolfSSL options
 112         set(LWS_USE_WOLFSSL ${LWS_USE_CYASSL} CACHE BOOL "Use wolfSSL/CyaSSL instead of OpenSSL" FORCE)
 113         set(LWS_WOLFSSL_LIBRARIES ${LWS_CYASSL_LIBRARIES} CACHE PATH "Path to wolfSSL/CyaSSL libraries" FORCE)
 114         set(LWS_WOLFSSL_INCLUDE_DIRS ${LWS_CYASSL_INCLUDE_DIRS} CACHE PATH "Path to wolfSSL/CyaSSL header files" FORCE)
 115 endif()
 116
 117 if (LWS_WITHOUT_CLIENT AND LWS_WITHOUT_SERVER)
 118         message(FATAL_ERROR "Makes no sense to compile with neither client nor server.")
 119 endif()
 120
 121 if (NOT (LWS_WITH_STATIC OR LWS_WITH_SHARED))
 122         message(FATAL_ERROR "Makes no sense to compile with neither static nor shared libraries.")
 123 endif()
 124
 125 if (NOT LWS_WITHOUT_EXTENSIONS)
 126         if (NOT LWS_WITH_ZLIB)
 127                 message(FATAL_ERROR "zlib is required for extensions.")
 128         endif()
 129 endif()
 130
 131 set(LWS_ZLIB_LIBRARIES CACHE PATH "Path to the zlib library")
 132 set(LWS_ZLIB_INCLUDE_DIRS CACHE PATH "Path to the zlib include directory")
 133 set(LWS_OPENSSL_LIBRARIES CACHE PATH "Path to the OpenSSL library")
 134 set(LWS_OPENSSL_INCLUDE_DIRS CACHE PATH "Path to the OpenSSL include directory")
 135 set(LWS_WOLFSSL_LIBRARIES CACHE PATH "Path to the wolfSSL library")
 136 set(LWS_WOLFSSL_INCLUDE_DIRS CACHE PATH "Path to the wolfSSL include directory")
 137 set(LWS_LIBEV_LIBRARIES CACHE PATH "Path to the libev library")
 138 set(LWS_LIBEV_INCLUDE_DIRS CACHE PATH "Path to the libev include directory")
 139 set(LWS_LIBUV_LIBRARIES CACHE PATH "Path to the libuv library")
 140 set(LWS_LIBUV_INCLUDE_DIRS CACHE PATH "Path to the libuv include directory")
 141
 142 if (NOT LWS_WITH_SSL)
 143         set(LWS_WITHOUT_BUILTIN_SHA1 OFF)
 144 endif()
 145
 146 if (LWS_WITH_SSL AND NOT LWS_USE_WOLFSSL)
 147         if ("${LWS_OPENSSL_LIBRARIES}" STREQUAL "" OR "${LWS_OPENSSL_INCLUDE_DIRS}" STREQUAL "")
 148         else()
 149                 set(OPENSSL_LIBRARIES ${LWS_OPENSSL_LIBRARIES})
 150                 set(OPENSSL_INCLUDE_DIRS ${LWS_OPENSSL_INCLUDE_DIRS})
 151                 set(OPENSSL_FOUND 1)
 152         endif()
 153 endif()
 154
 155 if (LWS_WITH_SSL AND LWS_USE_WOLFSSL)
 156         if ("${LWS_WOLFSSL_LIBRARIES}" STREQUAL "" OR "${LWS_WOLFSSL_INCLUDE_DIRS}" STREQUAL "")
 157                 if (NOT WOLFSSL_FOUND)
 158                         if (LWS_USE_CYASSL)
 159                                 message(FATAL_ERROR "You must set LWS_CYASSL_LIBRARIES and LWS_CYASSL_INCLUDE_DIRS when LWS_USE_CYASSL is turned on.")
 160                         else()
 161                                 message(FATAL_ERROR "You must set LWS_WOLFSSL_LIBRARIES and LWS_WOLFSSL_INCLUDE_DIRS when LWS_USE_WOLFSSL is turned on.")
 162                         endif()
 163                 endif()
 164         else()
 165                 set(WOLFSSL_LIBRARIES ${LWS_WOLFSSL_LIBRARIES})
 166                 set(WOLFSSL_INCLUDE_DIRS ${LWS_WOLFSSL_INCLUDE_DIRS})
 167                 set(WOLFSSL_FOUND 1)
 168         endif()
 169         set(USE_WOLFSSL 1)
 170         if (LWS_USE_CYASSL)
 171                 set(USE_OLD_CYASSL 1)
 172         endif()
 173 endif()
 174
 175 if (LWS_WITH_ZLIB AND NOT LWS_USE_BUNDLED_ZLIB)
 176         if ("${LWS_ZLIB_LIBRARIES}" STREQUAL "" OR "${LWS_ZLIB_INCLUDE_DIRS}" STREQUAL "")
 177         else()
 178                 set(ZLIB_LIBRARIES ${LWS_ZLIB_LIBRARIES})
 179                 set(ZLIB_INCLUDE_DIRS ${LWS_ZLIB_INCLUDE_DIRS})
 180                 set(ZLIB_FOUND 1)
 181         endif()
 182 endif()
 183
 184 if (LWS_WITH_LIBEV)
 185         if ("${LWS_LIBEV_LIBRARIES}" STREQUAL "" OR "${LWS_LIBEV_INCLUDE_DIRS}" STREQUAL "")
 186         else()
 187                 set(LIBEV_LIBRARIES ${LWS_LIBEV_LIBRARIES})
 188                 set(LIBEV_INCLUDE_DIRS ${LWS_LIBEV_INCLUDE_DIRS})
 189                 set(LIBEV_FOUND 1)
 190         endif()
 191 endif()
 192
 193 if (LWS_WITH_LIBUV)
 194         if ("${LWS_LIBUV_LIBRARIES}" STREQUAL "" OR "${LWS_LIBUV_INCLUDE_DIRS}" STREQUAL "")
 195         else()
 196                 set(LIBUV_LIBRARIES ${LWS_LIBUV_LIBRARIES})
 197                 set(LIBUV_INCLUDE_DIRS ${LWS_LIBUV_INCLUDE_DIRS})
 198                 set(LIBUV_FOUND 1)
 199         endif()
 200 endif()
 201
 202 # FIXME: This must be runtime-only option.
 203 # The base dir where the test-apps look for the SSL certs.
 204 set(LWS_OPENSSL_CLIENT_CERTS ../share CACHE PATH "Server SSL certificate directory")
 205 if (WIN32)
 206         set(LWS_OPENSSL_CLIENT_CERTS . CACHE PATH "Client SSL certificate directory")
 207
 208         if (LWS_IPV6)
 209                 set(LWS_IPV6 OFF)
 210                 message(WARNING "IPv6 does not currently work on Windows!")
 211         endif()
 212 else()
 213         set(LWS_OPENSSL_CLIENT_CERTS /etc/pki/tls/certs/ CACHE PATH "Client SSL certificate directory")
 214 endif()
 215
 216 if (LWS_WITHOUT_EXTENSIONS)
 217         set(LWS_NO_EXTENSIONS 1)
 218 endif()
 219
 220 if (LWS_WITH_SSL)
 221         set(LWS_OPENSSL_SUPPORT 1)
 222 endif()
 223
 224 if (LWS_SSL_CLIENT_USE_OS_CA_CERTS)
 225         set(LWS_SSL_CLIENT_USE_OS_CA_CERTS 1)
 226 endif()
 227
 228 if (LWS_WITH_LATENCY)
 229         set(LWS_LATENCY 1)
 230 endif()
 231
 232 if (LWS_WITHOUT_DAEMONIZE OR WIN32)
 233         set(LWS_NO_DAEMONIZE 1)
 234 endif()
 235
 236 if (LWS_WITHOUT_SERVER)
 237         set(LWS_NO_SERVER 1)
 238 endif()
 239
 240 if (LWS_WITHOUT_CLIENT)
 241         set(LWS_NO_CLIENT 1)
 242 endif()
 243
 244 if (LWS_WITH_LIBEV)
 245         set(LWS_USE_LIBEV 1)
 246 endif()
 247
 248 if (LWS_WITH_LIBUV)
 249         set(LWS_USE_LIBUV 1)
 250 endif()
 251
 252 if (LWS_IPV6)
 253         set(LWS_USE_IPV6 1)
 254 endif()
 255
 256 if (LWS_WITH_HTTP2)
 257         set(LWS_USE_HTTP2 1)
 258 endif()
 259
 260 if ("${LWS_MAX_SMP}" STREQUAL "")
 261         set(LWS_MAX_SMP 32)
 262 endif()
 263
 264 #if (LWS_MBED3)
 265 #       set(CMAKE_C_FLAGS "-D_DEBUG ${CMAKE_C_FLAGS}")
 266 #endif()
 267
 268 if (MINGW)
 269         set(LWS_MINGW_SUPPORT 1)
 270         set(CMAKE_C_FLAGS "-D__USE_MINGW_ANSI_STDIO ${CMAKE_C_FLAGS}")
 271 endif()
 272
 273 if (LWS_SSL_SERVER_WITH_ECDH_CERT)
 274         set(LWS_SSL_SERVER_WITH_ECDH_CERT 1)
 275 endif()
 276
 277 include_directories("${PROJECT_BINARY_DIR}")
 278
 279 include(CheckCSourceCompiles)
 280
 281 # Check for different inline keyword versions.
 282 foreach(KEYWORD "inline" "__inline__" "__inline")
 283         set(CMAKE_REQUIRED_DEFINITIONS "-DKEYWORD=${KEYWORD}")
 284         CHECK_C_SOURCE_COMPILES(
 285                 "
 286                 #include <stdio.h>
 287                 static KEYWORD void a() {}
 288                 int main(int argc, char **argv) { a(); return 0; }
 289                 " LWS_HAVE_${KEYWORD})
 290 endforeach()
 291
 292 if (NOT LWS_HAVE_inline)
 293         if (LWS_HAVE___inline__)
 294                 set(inline __inline__)
 295         elseif(LWS_HAVE___inline)
 296                 set(inline __inline)
 297         endif()
 298 endif()
 299
 300 # Put the libaries and binaries that get built into directories at the
 301 # top of the build tree rather than in hard-to-find leaf directories.
 302 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin")
 303 SET(CMAKE_LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/lib")
 304 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/lib")
 305
 306 # Put absolute path of dynamic libraries into the object code. Some
 307 # architectures, notably Mac OS X, need this.
 308 SET(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}")
 309
 310 include(CheckFunctionExists)
 311 include(CheckIncludeFile)
 312 include(CheckIncludeFiles)
 313 include(CheckLibraryExists)
 314 include(CheckTypeSize)
 315
 316 if (LWS_WITHOUT_BUILTIN_SHA1)
 317         set(LWS_SHA1_USE_OPENSSL_NAME 1)
 318 endif()
 319
 320 CHECK_FUNCTION_EXISTS(bzero LWS_HAVE_BZERO)
 321 CHECK_FUNCTION_EXISTS(fork LWS_HAVE_FORK)
 322 CHECK_FUNCTION_EXISTS(getenv LWS_HAVE_GETENV)
 323 CHECK_FUNCTION_EXISTS(malloc LWS_HAVE_MALLOC)
 324 CHECK_FUNCTION_EXISTS(memset LWS_HAVE_MEMSET)
 325 CHECK_FUNCTION_EXISTS(realloc LWS_HAVE_REALLOC)
 326 CHECK_FUNCTION_EXISTS(socket LWS_HAVE_SOCKET)
 327 CHECK_FUNCTION_EXISTS(strerror LWS_HAVE_STRERROR)
 328 CHECK_FUNCTION_EXISTS(vfork LWS_HAVE_VFORK)
 329 CHECK_FUNCTION_EXISTS(getifaddrs LWS_HAVE_GETIFADDRS)
 330
 331 if (NOT LWS_HAVE_GETIFADDRS)
 332         if (LWS_WITHOUT_BUILTIN_GETIFADDRS)
 333                 message(FATAL_ERROR "No getifaddrs was found on the system. Turn off the LWS_WITHOUT_BUILTIN_GETIFADDRS compile option to use the supplied BSD version.")
 334         endif()
 335         set(LWS_BUILTIN_GETIFADDRS 1)
 336 endif()
 337
 338 CHECK_INCLUDE_FILE(dlfcn.h LWS_HAVE_DLFCN_H)
 339 CHECK_INCLUDE_FILE(fcntl.h LWS_HAVE_FCNTL_H)
 340 CHECK_INCLUDE_FILE(in6addr.h LWS_HAVE_IN6ADDR_H)
 341 CHECK_INCLUDE_FILE(inttypes.h LWS_HAVE_INTTYPES_H)
 342 CHECK_INCLUDE_FILE(memory.h LWS_HAVE_MEMORY_H)
 343 CHECK_INCLUDE_FILE(netinet/in.h LWS_HAVE_NETINET_IN_H)
 344 CHECK_INCLUDE_FILE(stdint.h LWS_HAVE_STDINT_H)
 345 CHECK_INCLUDE_FILE(stdlib.h LWS_HAVE_STDLIB_H)
 346 CHECK_INCLUDE_FILE(strings.h LWS_HAVE_STRINGS_H)
 347 CHECK_INCLUDE_FILE(string.h LWS_HAVE_STRING_H)
 348 CHECK_INCLUDE_FILE(sys/prctl.h LWS_HAVE_SYS_PRCTL_H)
 349 CHECK_INCLUDE_FILE(sys/socket.h LWS_HAVE_SYS_SOCKET_H)
 350 CHECK_INCLUDE_FILE(sys/stat.h LWS_HAVE_SYS_STAT_H)
 351 CHECK_INCLUDE_FILE(sys/types.h LWS_HAVE_SYS_TYPES_H)
 352 CHECK_INCLUDE_FILE(unistd.h LWS_HAVE_UNISTD_H)
 353 CHECK_INCLUDE_FILE(vfork.h LWS_HAVE_VFORK_H)
 354
 355 if (LWS_WITH_ZLIB AND NOT LWS_USE_BUNDLED_ZLIB)
 356         CHECK_INCLUDE_FILE(zlib.h LWS_HAVE_ZLIB_H)
 357 endif()
 358
 359 # TODO: These can also be tested to see whether they actually work...
 360 set(LWS_HAVE_WORKING_FORK LWS_HAVE_FORK)
 361 set(LWS_HAVE_WORKING_VFORK LWS_HAVE_VFORK)
 362
 363 CHECK_INCLUDE_FILES("stdlib.h;stdarg.h;string.h;float.h" STDC_HEADERS)
 364
 365 # These don't work Cross...
 366 #CHECK_TYPE_SIZE(pid_t PID_T_SIZE)
 367 #CHECK_TYPE_SIZE(size_t SIZE_T_SIZE)
 368 #CHECK_TYPE_SIZE("void *" LWS_SIZEOFPTR LANGUAGE C)
 369
 370 if (NOT PID_T_SIZE)
 371         set(pid_t int)
 372 endif()
 373
 374 if (NOT SIZE_T_SIZE)
 375         set(size_t "unsigned int")
 376 endif()
 377
 378 if (NOT LWS_HAVE_MALLOC)
 379         set(malloc rpl_malloc)
 380 endif()
 381
 382 if (NOT LWS_HAVE_REALLOC)
 383         set(realloc rpl_realloc)
 384 endif()
 385
 386 # Generate the lws_config.h that includes all the public compilation settings.
 387 configure_file(
 388        "${PROJECT_SOURCE_DIR}/lws_config.h.in"
 389        "${PROJECT_BINARY_DIR}/lws_config.h")
 390
 391 # Generate the lws_config.h that includes all the private compilation settings.
 392 configure_file(
 393        "${PROJECT_SOURCE_DIR}/lws_config_private.h.in"
 394        "${PROJECT_BINARY_DIR}/lws_config_private.h")
 395
 396 if (MSVC)
 397         # Turn off stupid microsoft security warnings.
 398         add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
 399 endif(MSVC)
 400
 401 include_directories("${PROJECT_SOURCE_DIR}/lib")
 402
 403 # Group headers and sources.
 404 # Some IDEs use this for nicer file structure.
 405 set(HDR_PRIVATE
 406         lib/private-libwebsockets.h)
 407
 408 set(HDR_PUBLIC
 409         "${PROJECT_SOURCE_DIR}/lib/libwebsockets.h"
 410         "${PROJECT_BINARY_DIR}/lws_config.h")
 411
 412 set(SOURCES
 413         lib/base64-decode.c
 414         lib/handshake.c
 415         lib/libwebsockets.c
 416         lib/service.c
 417         lib/pollfd.c
 418         lib/output.c
 419         lib/parsers.c
 420         lib/context.c
 421         lib/alloc.c
 422         lib/header.c)
 423
 424 if (NOT LWS_WITHOUT_CLIENT)
 425         list(APPEND SOURCES
 426                 lib/client.c
 427                 lib/client-handshake.c
 428                 lib/client-parser.c)
 429 endif()
 430
 431 if (LWS_WITH_SSL)
 432         list(APPEND SOURCES
 433                 lib/ssl.c)
 434 endif()
 435
 436 if (NOT LWS_WITHOUT_BUILTIN_SHA1)
 437         list(APPEND SOURCES
 438                 lib/sha-1.c)
 439 endif()
 440
 441 if (LWS_WITH_HTTP2)
 442         list(APPEND SOURCES
 443                 lib/http2.c
 444                 lib/hpack.c
 445                 lib/ssl-http2.c)
 446 endif()
 447 # select the active platform files
 448
 449 if (WIN32)
 450         list(APPEND SOURCES
 451                 lib/lws-plat-win.c)
 452 else()
 453         if (LWS_MBED3)
 454                 list(APPEND SOURCES
 455                         lib/lws-plat-mbed3.cpp
 456                         lib/lws-plat-mbed3.c)
 457         else()
 458                 list(APPEND SOURCES
 459                         lib/lws-plat-unix.c)
 460         endif()
 461 endif()
 462
 463 if (NOT LWS_WITHOUT_SERVER)
 464         list(APPEND SOURCES
 465                 lib/server.c
 466                 lib/server-handshake.c)
 467 endif()
 468
 469 if (NOT LWS_WITHOUT_EXTENSIONS)
 470         list(APPEND HDR_PRIVATE
 471                 lib/extension-permessage-deflate.h)
 472         list(APPEND SOURCES
 473                 lib/extension.c
 474                 lib/extension-permessage-deflate.c)
 475 endif()
 476
 477 if (LWS_WITH_LIBEV)
 478         list(APPEND SOURCES
 479                 lib/libev.c)
 480 endif()
 481
 482 if (LWS_WITH_LIBUV)
 483         list(APPEND SOURCES
 484                 lib/libuv.c)
 485 endif()
 486
 487 # Add helper files for Windows.
 488 if (WIN32)
 489         set(WIN32_HELPERS_PATH win32port/win32helpers)
 490         include_directories(${WIN32_HELPERS_PATH})
 491 else()
 492         # Unix.
 493         if (NOT LWS_WITHOUT_DAEMONIZE)
 494                 list(APPEND SOURCES
 495                         lib/daemonize.c)
 496         endif()
 497 endif()
 498
 499 if (UNIX)
 500         if (NOT LWS_HAVE_GETIFADDRS)
 501                 list(APPEND HDR_PRIVATE lib/getifaddrs.h)
 502                 list(APPEND SOURCES lib/getifaddrs.c)
 503         endif()
 504 endif()
 505
 506 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX OR (CMAKE_C_COMPILER_ID MATCHES "Clang") OR (CMAKE_CXX_COMPILER_ID MATCHES "Clang"))
 507     include (CheckCCompilerFlag)
 508     CHECK_C_COMPILER_FLAG(-fvisibility=hidden LWS_HAVE_VISIBILITY)
 509     if (LWS_HAVE_VISIBILITY)
 510                 set(VISIBILITY_FLAG -fvisibility=hidden)
 511     endif()
 512     if (UNIX)
 513                set(CMAKE_C_FLAGS "-Wall -Werror ${VISIBILITY_FLAG} ${CMAKE_C_FLAGS}" )
 514     else(UNIX)
 515                set(CMAKE_C_FLAGS "-Wall ${VISIBILITY_FLAG} ${CMAKE_C_FLAGS}" )
 516     endif(UNIX)
 517 endif ()
 518
 519 if ((CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX) AND NOT LWS_WITHOUT_TESTAPPS)
 520     if (UNIX)
 521         # jeez clang understands -pthread but dies if he sees it at link time!
 522         # http://stackoverflow.com/questions/2391194/what-is-gs-pthread-equiv-in-clang
 523         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -pthread" )
 524     endif()
 525 endif()
 526
 527 if ((CMAKE_C_COMPILER_ID MATCHES "Clang") OR (CMAKE_CXX_COMPILER_ID MATCHES "Clang"))
 528         # otherwise osx blows a bunch of openssl deprecated api errors
 529         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-deprecated-declarations" )
 530 endif()
 531
 532 source_group("Headers Private"  FILES ${HDR_PRIVATE})
 533 source_group("Headers Public"   FILES ${HDR_PUBLIC})
 534 source_group("Sources"          FILES ${SOURCES})
 535
 536 #
 537 # Create the lib.
 538 #
 539 set(LWS_LIBRARIES)
 540
 541 if (LWS_WITH_STATIC)
 542         add_library(websockets STATIC
 543                                 ${HDR_PRIVATE}
 544                                 ${HDR_PUBLIC}
 545                                 ${SOURCES})
 546         list(APPEND LWS_LIBRARIES websockets)
 547
 548         if (WIN32)
 549                 # Windows uses the same .lib ending for static libraries and shared
 550                 # library linker files, so rename the static library.
 551                 set_target_properties(websockets
 552                         PROPERTIES
 553                         OUTPUT_NAME websockets_static)
 554         endif()
 555 endif()
 556
 557 if (LWS_WITH_SHARED)
 558         add_library(websockets_shared SHARED
 559                                 ${HDR_PRIVATE}
 560                                 ${HDR_PUBLIC}
 561                                 ${SOURCES})
 562         list(APPEND LWS_LIBRARIES websockets_shared)
 563
 564         # We want the shared lib to be named "libwebsockets"
 565         # not "libwebsocket_shared".
 566         set_target_properties(websockets_shared
 567                 PROPERTIES
 568                 OUTPUT_NAME websockets)
 569
 570         if (WIN32)
 571                 # Compile as DLL (export function declarations)
 572                 set_property(
 573                         TARGET websockets_shared
 574                         PROPERTY COMPILE_DEFINITIONS
 575                         LWS_DLL
 576                         LWS_INTERNAL)
 577         endif()
 578
 579         if (APPLE)
 580                 set_property(TARGET websockets_shared PROPERTY MACOSX_RPATH YES)
 581         endif()
 582 endif()
 583
 584 # Set the so version of the lib.
 585 # Equivalent to LDFLAGS=-version-info x:x:x
 586 if(CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX OR (CMAKE_C_COMPILER_ID MATCHES "Clang") OR (CMAKE_CXX_COMPILER_ID MATCHES "Clang"))
 587         foreach(lib ${LWS_LIBRARIES})
 588                 set_target_properties(${lib}
 589                         PROPERTIES
 590                         SOVERSION ${SOVERSION})
 591         endforeach()
 592 endif()
 593
 594 set(LIB_LIST)
 595
 596 #
 597 # Find libraries.
 598 #
 599
 600 #
 601 # ZLIB (Only needed for deflate extensions).
 602 #
 603 if (LWS_WITH_ZLIB)
 604         if (LWS_USE_BUNDLED_ZLIB)
 605                 if (WIN32)
 606                         set(WIN32_ZLIB_PATH "win32port/zlib")
 607                         set(ZLIB_SRCS
 608                                 ${WIN32_ZLIB_PATH}/adler32.c
 609                                 ${WIN32_ZLIB_PATH}/compress.c
 610                                 ${WIN32_ZLIB_PATH}/crc32.c
 611                                 ${WIN32_ZLIB_PATH}/deflate.c
 612                                 ${WIN32_ZLIB_PATH}/gzclose.c
 613                                 ${WIN32_ZLIB_PATH}/gzio.c
 614                                 ${WIN32_ZLIB_PATH}/gzlib.c
 615                                 ${WIN32_ZLIB_PATH}/gzread.c
 616                                 ${WIN32_ZLIB_PATH}/gzwrite.c
 617                                 ${WIN32_ZLIB_PATH}/infback.c
 618                                 ${WIN32_ZLIB_PATH}/inffast.c
 619                                 ${WIN32_ZLIB_PATH}/inflate.c
 620                                 ${WIN32_ZLIB_PATH}/inftrees.c
 621                                 ${WIN32_ZLIB_PATH}/trees.c
 622                                 ${WIN32_ZLIB_PATH}/uncompr.c
 623                                 ${WIN32_ZLIB_PATH}/zutil.c)
 624                         add_library(zlib_internal STATIC ${ZLIB_SRCS})
 625                         set(ZLIB_INCLUDE_DIRS ${WIN32_ZLIB_PATH})
 626                         get_property(ZLIB_LIBRARIES TARGET zlib_internal PROPERTY LOCATION)
 627                         set(ZLIB_FOUND 1)
 628                         # Make sure zlib_internal is compiled before the libs.
 629                         foreach (lib ${LWS_LIBRARIES})
 630                                 add_dependencies(${lib} zlib_internal)
 631                         endforeach()
 632                 else()
 633                         message(FATAL_ERROR "Don't have bundled zlib for that platform")
 634                 endif()
 635         elseif (NOT ZLIB_FOUND)
 636                 find_package(ZLIB REQUIRED)
 637         endif()
 638         message("zlib include dirs: ${ZLIB_INCLUDE_DIRS}")
 639         message("zlib libraries: ${ZLIB_LIBRARIES}")
 640         include_directories(${ZLIB_INCLUDE_DIRS})
 641         list(APPEND LIB_LIST ${ZLIB_LIBRARIES})
 642 endif()
 643
 644 #
 645 # OpenSSL
 646 #
 647 if (LWS_WITH_SSL)
 648         message("Compiling with SSL support")
 649
 650         if (LWS_USE_WOLFSSL)
 651                 # Use wolfSSL as OpenSSL replacement.
 652                 # TODO: Add a find_package command for this also.
 653                 message("wolfSSL include dir: ${WOLFSSL_INCLUDE_DIRS}")
 654                 message("wolfSSL libraries: ${WOLFSSL_LIBRARIES}")
 655
 656                 # Additional to the root directory we need to include
 657                 # the wolfssl/ subdirectory which contains the OpenSSL
 658                 # compatibility layer headers.
 659
 660                 if (LWS_USE_CYASSL)
 661                         foreach(inc ${WOLFSSL_INCLUDE_DIRS})
 662                                 include_directories("${inc}" "${inc}/cyassl")
 663                         endforeach()
 664                 else()
 665                         foreach(inc ${WOLFSSL_INCLUDE_DIRS})
 666                                 include_directories("${inc}" "${inc}/wolfssl")
 667                         endforeach()
 668                 endif()
 669
 670                 list(APPEND LIB_LIST "${WOLFSSL_LIBRARIES}")
 671         else()
 672                 if (NOT OPENSSL_FOUND)
 673                         # TODO: Add support for STATIC also.
 674                         find_package(OpenSSL REQUIRED)
 675                         set(OPENSSL_INCLUDE_DIRS "${OPENSSL_INCLUDE_DIR}")
 676                 endif()
 677
 678                 message("OpenSSL include dir: ${OPENSSL_INCLUDE_DIRS}")
 679                 message("OpenSSL libraries: ${OPENSSL_LIBRARIES}")
 680
 681                 include_directories("${OPENSSL_INCLUDE_DIRS}")
 682                 list(APPEND LIB_LIST ${OPENSSL_LIBRARIES})
 683         endif()
 684 endif(LWS_WITH_SSL)
 685
 686 if (LWS_WITH_LIBEV)
 687         if (NOT LIBEV_FOUND)
 688                 find_path(LIBEV_INCLUDE_DIRS NAMES ev.h)
 689                 find_library(LIBEV_LIBRARIES NAMES ev)
 690                 if(LIBEV_INCLUDE_DIRS AND LIBEV_LIBRARIES)
 691                         set(LIBEV_FOUND 1)
 692                 endif()
 693         endif()
 694         message("libev include dir: ${LIBEV_INCLUDE_DIRS}")
 695         message("libev libraries: ${LIBEV_LIBRARIES}")
 696         include_directories("${LIBEV_INCLUDE_DIRS}")
 697         list(APPEND LIB_LIST ${LIBEV_LIBRARIES})
 698 endif(LWS_WITH_LIBEV)
 699
 700 if (LWS_WITH_LIBUV)
 701         if (NOT LIBUV_FOUND)
 702                 find_path(LIBUV_INCLUDE_DIRS NAMES uv.h)
 703                 find_library(LIBUV_LIBRARIES NAMES uv)
 704                 if(LIBUV_INCLUDE_DIRS AND LIBUV_LIBRARIES)
 705                         set(LIBUV_FOUND 1)
 706                 endif()
 707         endif()
 708         message("libuv include dir: ${LIBUV_INCLUDE_DIRS}")
 709         message("libuv libraries: ${LIBUV_LIBRARIES}")
 710         include_directories("${LIBUV_INCLUDE_DIRS}")
 711         list(APPEND LIB_LIST ${LIBUV_LIBRARIES})
 712 endif()
 713
 714 #
 715 # Platform specific libs.
 716 #
 717 if (WINCE)
 718         list(APPEND LIB_LIST ws2.lib)
 719 elseif (WIN32)
 720         list(APPEND LIB_LIST ws2_32.lib)
 721 endif()
 722
 723 if (UNIX)
 724         list(APPEND LIB_LIST m)
 725 endif()
 726
 727 # Setup the linking for all libs.
 728 foreach (lib ${LWS_LIBRARIES})
 729         target_link_libraries(${lib} ${LIB_LIST})
 730 endforeach()
 731
 732 #
 733 # Test applications
 734 #
 735 set(TEST_APP_LIST)
 736 if (NOT LWS_WITHOUT_TESTAPPS)
 737         #
 738         # Helper function for adding a test app.
 739         #
 740         macro(create_test_app TEST_NAME MAIN_SRC S2 S3 S4 S5)
 741
 742                 set(TEST_SRCS ${MAIN_SRC})
 743                 set(TEST_HDR)
 744                 if ("${S2}" STREQUAL "")
 745                 else()
 746                         list(APPEND TEST_SRCS ${S2})
 747                 endif()
 748                 if ("${S3}" STREQUAL "")
 749                 else()
 750                         list(APPEND TEST_SRCS ${S3})
 751                 endif()
 752                 if ("${S4}" STREQUAL "")
 753                 else()
 754                         list(APPEND TEST_SRCS ${S4})
 755                 endif()
 756                 if ("${S5}" STREQUAL "")
 757                 else()
 758                         list(APPEND TEST_SRCS ${S5})
 759                 endif()
 760                 if (WIN32)
 761                         list(APPEND TEST_SRCS
 762                                 ${WIN32_HELPERS_PATH}/getopt.c
 763                                 ${WIN32_HELPERS_PATH}/getopt_long.c
 764                                 ${WIN32_HELPERS_PATH}/gettimeofday.c
 765                         )
 766
 767                         list(APPEND TEST_HDR
 768                                 ${WIN32_HELPERS_PATH}/getopt.h
 769                                 ${WIN32_HELPERS_PATH}/gettimeofday.h
 770                         )
 771                 endif(WIN32)
 772
 773                 source_group("Headers Private"   FILES ${TEST_HDR})
 774                 source_group("Sources"   FILES ${TEST_SRCS})
 775                 add_executable(${TEST_NAME} ${TEST_SRCS} ${TEST_HDR})
 776
 777                 if (LWS_LINK_TESTAPPS_DYNAMIC)
 778                         if (NOT LWS_WITH_SHARED)
 779                                 message(FATAL_ERROR "Build of the shared library is disabled. LWS_LINK_TESTAPPS_DYNAMIC must be combined with LWS_WITH_SHARED.")
 780                         endif()
 781                         target_link_libraries(${TEST_NAME} websockets_shared)
 782                         add_dependencies(${TEST_NAME} websockets_shared)
 783                 else()
 784                         if (NOT LWS_WITH_STATIC)
 785                                 message(FATAL_ERROR "Build of the static library is disabled. Disabled LWS_LINK_TESTAPPS_DYNAMIC must be combined with LWS_WITH_STATIC.")
 786                         endif()
 787                         target_link_libraries(${TEST_NAME} websockets)
 788                         add_dependencies(${TEST_NAME} websockets)
 789                 endif()
 790
 791                 # Set test app specific defines.
 792                 set_property(TARGET ${TEST_NAME}
 793                                         PROPERTY COMPILE_DEFINITIONS
 794                                                 INSTALL_DATADIR="${CMAKE_INSTALL_PREFIX}/share"
 795                                         )
 796
 797                 # Prefix the binary names with libwebsockets.
 798                 set_target_properties(${TEST_NAME}
 799                         PROPERTIES
 800                         OUTPUT_NAME libwebsockets-${TEST_NAME})
 801
 802                 # Add to the list of tests.
 803                 list(APPEND TEST_APP_LIST ${TEST_NAME})
 804         endmacro()
 805
 806         if (LWS_WITH_SSL AND NOT LWS_USE_WOLFSSL)
 807                 message("Searching for OpenSSL executable and dlls")
 808                 find_package(OpenSSLbins)
 809                 message("OpenSSL executable: ${OPENSSL_EXECUTABLE}")
 810         endif()
 811
 812         if (NOT LWS_WITHOUT_SERVER)
 813                 #
 814                 # test-server
 815                 #
 816                 if (NOT LWS_WITHOUT_TEST_SERVER)
 817                         create_test_app(test-server "test-server/test-server.c"
 818                                 "test-server/test-server-http.c"
 819                                 "test-server/test-server-dumb-increment.c"
 820                                 "test-server/test-server-mirror.c"
 821                                 "test-server/test-server-echogen.c")
 822                         if (UNIX)
 823                                 create_test_app(test-fuzxy "test-server/fuzxy.c"
 824                                         ""
 825                                         ""
 826                                         ""
 827                                         "")
 828                         endif()
 829                         if (UNIX AND NOT ((CMAKE_C_COMPILER_ID MATCHES "Clang") OR (CMAKE_CXX_COMPILER_ID MATCHES "Clang")))
 830                                 create_test_app(test-server-pthreads
 831                                         "test-server/test-server-pthreads.c"
 832                                         "test-server/test-server-http.c"
 833                                         "test-server/test-server-dumb-increment.c"
 834                                         "test-server/test-server-mirror.c"
 835                                         "test-server/test-server-echogen.c")
 836                         endif()
 837                         if (UNIX AND NOT ((CMAKE_C_COMPILER_ID MATCHES "Clang") OR (CMAKE_CXX_COMPILER_ID MATCHES "Clang"))
 838                                 AND LWS_WITH_LIBEV)
 839                                 create_test_app(test-server-libev
 840                                         "test-server/test-server-libev.c"
 841                                         "test-server/test-server-http.c"
 842                                         "test-server/test-server-dumb-increment.c"
 843                                         "test-server/test-server-mirror.c"
 844                                         "test-server/test-server-echogen.c")
 845                         endif()
 846                         if (UNIX AND NOT ((CMAKE_C_COMPILER_ID MATCHES "Clang") OR (CMAKE_CXX_COMPILER_ID MATCHES "Clang"))
 847                                 AND LWS_WITH_LIBUV)
 848                                 create_test_app(test-server-libuv
 849                                         "test-server/test-server-libuv.c"
 850                                         "test-server/test-server-http.c"
 851                                         "test-server/test-server-dumb-increment.c"
 852                                         "test-server/test-server-mirror.c"
 853                                         "test-server/test-server-echogen.c")
 854                         endif()
 855                 endif()
 856
 857                 #
 858                 # test-server-extpoll
 859                 #
 860                 if (NOT LWS_WITHOUT_TEST_SERVER_EXTPOLL)
 861                         create_test_app(test-server-extpoll "test-server/test-server.c"
 862                                 "test-server/test-server-http.c"
 863                                 "test-server/test-server-dumb-increment.c"
 864                                 "test-server/test-server-mirror.c"
 865                                 "test-server/test-server-echogen.c")
 866                         # Set defines for this executable only.
 867                         set_property(
 868                                 TARGET test-server-extpoll
 869                                 PROPERTY COMPILE_DEFINITIONS
 870                                         EXTERNAL_POLL
 871                                         INSTALL_DATADIR="${CMAKE_INSTALL_PREFIX}/share"
 872                                 )
 873
 874                         # We need to link against winsock code.
 875                         if (WIN32)
 876                                 target_link_libraries(test-server-extpoll ws2_32.lib)
 877                         endif(WIN32)
 878                 endif()
 879
 880                 # Data files for running the test server.
 881                 set(TEST_SERVER_DATA
 882                         "${PROJECT_SOURCE_DIR}/test-server/favicon.ico"
 883                         "${PROJECT_SOURCE_DIR}/test-server/leaf.jpg"
 884                         "${PROJECT_SOURCE_DIR}/test-server/libwebsockets.org-logo.png"
 885                         "${PROJECT_SOURCE_DIR}/test-server/test.html")
 886
 887                 # Generate self-signed SSL certs for the test-server.
 888                 if (LWS_WITH_SSL AND OPENSSL_EXECUTABLE AND NOT LWS_WITHOUT_TEST_SERVER)
 889                         message("Generating SSL Certificates for the test-server...")
 890
 891                         set(TEST_SERVER_SSL_KEY "${PROJECT_BINARY_DIR}/libwebsockets-test-server.key.pem")
 892                         set(TEST_SERVER_SSL_CERT "${PROJECT_BINARY_DIR}/libwebsockets-test-server.pem")
 893
 894                         if (WIN32)
 895                                 if (MINGW)
 896                                         message("cmd = \"${OPENSSL_EXECUTABLE}\" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -subj \"/C=GB/ST=Erewhon/L=All around/O=libwebsockets-test/CN=localhost\" -keyout \"${TEST_SERVER_SSL_KEY}\" -out \"${TEST_SERVER_SSL_CERT}\"")
 897                                         execute_process(
 898                                                 COMMAND "${OPENSSL_EXECUTABLE}" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -subj "/C=GB/ST=Erewhon/L=All around/O=libwebsockets-test/CN=localhost" -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 899                                                 RESULT_VARIABLE OPENSSL_RETURN_CODE)
 900                                 else()
 901                                         file(WRITE "${PROJECT_BINARY_DIR}/openssl_input.txt"
 902                                                 "GB\n"
 903                                                 "Erewhon\n"
 904                                                 "All around\n"
 905                                                 "libwebsockets-test\n"
 906                                                 "localhost\n"
 907                                                 "none@invalid.org\n\n"
 908                                                 )
 909
 910                                         # The "type" command is a bit picky with paths.
 911                                         file(TO_NATIVE_PATH "${PROJECT_BINARY_DIR}/openssl_input.txt" OPENSSL_INPUT_WIN_PATH)
 912                                         message("OPENSSL_INPUT_WIN_PATH = ${OPENSSL_INPUT_WIN_PATH}")
 913                                         message("cmd = \"${OPENSSL_EXECUTABLE}\" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout \"${TEST_SERVER_SSL_KEY}\" -out \"${TEST_SERVER_SSL_CERT}\"")
 914
 915                                         execute_process(
 916                                                 COMMAND cmd /c type "${OPENSSL_INPUT_WIN_PATH}"
 917                                                 COMMAND "${OPENSSL_EXECUTABLE}" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 918                                                 RESULT_VARIABLE OPENSSL_RETURN_CODE
 919                                                 OUTPUT_QUIET ERROR_QUIET)
 920
 921                                         message("\n")
 922                                 endif()
 923
 924                                 if (OPENSSL_RETURN_CODE)
 925                                         message(WARNING "!!! Failed to generate SSL certificate for Test Server using cmd.exe !!!:\nOpenSSL return code = ${OPENSSL_RETURN_CODE}")
 926                                 else()
 927                                         message("SUCCSESFULLY generated SSL certificate")
 928                                 endif()
 929                         else()
 930                                 # Unix.
 931                                 execute_process(
 932                                         COMMAND printf "GB\\nErewhon\\nAll around\\nlibwebsockets-test\\n\\nlocalhost\\nnone@invalid.org\\n"
 933                                         COMMAND "${OPENSSL_EXECUTABLE}"
 934                                                 req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 935                                         RESULT_VARIABLE OPENSSL_RETURN_CODE
 936                                         OUTPUT_QUIET ERROR_QUIET)
 937
 938                                 if (OPENSSL_RETURN_CODE)
 939                                         message(WARNING "!!! Failed to generate SSL certificate for Test Server!!!:\nOpenSSL return code = ${OPENSSL_RETURN_CODE}")
 940                                 else()
 941                                         message("SUCCESSFULLY generated SSL certificate")
 942                                 endif()
 943                         endif()
 944
 945                         list(APPEND TEST_SERVER_DATA
 946                                 "${TEST_SERVER_SSL_KEY}"
 947                                 "${TEST_SERVER_SSL_CERT}")
 948                 endif()
 949
 950                 add_custom_command(TARGET test-server
 951                                                 POST_BUILD
 952                                                 COMMAND "${CMAKE_COMMAND}" -E make_directory "$<TARGET_FILE_DIR:test-server>/../share/libwebsockets-test-server")
 953
 954                 # Copy the file needed to run the server so that the test apps can
 955                 # reach them from their default output location
 956                 foreach (TEST_FILE ${TEST_SERVER_DATA})
 957                         if (EXISTS ${TEST_FILE})
 958                                 add_custom_command(TARGET test-server
 959                                                         POST_BUILD
 960                                                         COMMAND "${CMAKE_COMMAND}" -E copy "${TEST_FILE}" "$<TARGET_FILE_DIR:test-server>/../share/libwebsockets-test-server" VERBATIM)
 961                         endif()
 962                 endforeach()
 963         endif(NOT LWS_WITHOUT_SERVER)
 964
 965         if (NOT LWS_WITHOUT_CLIENT)
 966                 #
 967                 # test-client
 968                 #
 969                 if (NOT LWS_WITHOUT_TEST_CLIENT)
 970                         create_test_app(test-client "test-server/test-client.c" "" "" "" "")
 971                 endif()
 972
 973                 #
 974                 # test-fraggle
 975                 #
 976                 if (NOT LWS_WITHOUT_TEST_FRAGGLE)
 977                         create_test_app(test-fraggle "test-server/test-fraggle.c" "" "" "" "")
 978                 endif()
 979
 980                 #
 981                 # test-ping
 982                 #
 983                 if (NOT LWS_WITHOUT_TEST_PING)
 984                         create_test_app(test-ping "test-server/test-ping.c" "" "" "" "")
 985                 endif()
 986                 #
 987                 # test-echo
 988                 #
 989                 if (NOT LWS_WITHOUT_TEST_ECHO)
 990                         create_test_app(test-echo "test-server/test-echo.c" "" "" "" "")
 991                 endif()
 992
 993         endif(NOT LWS_WITHOUT_CLIENT)
 994
 995         #
 996         # Copy OpenSSL dlls to the output directory on Windows.
 997         # (Otherwise we'll get an error when trying to run)
 998         #
 999         if (WIN32 AND LWS_WITH_SSL AND NOT LWS_USE_WOLFSSL)
1000                 if(OPENSSL_BIN_FOUND)
1001                         message("OpenSSL dlls found:")
1002                         message("  Libeay: ${LIBEAY_BIN}")
1003                         message("  SSLeay: ${SSLEAY_BIN}")
1004
1005                         foreach(TARGET_BIN ${TEST_APP_LIST})
1006                                 add_custom_command(TARGET ${TARGET_BIN}
1007                                         POST_BUILD
1008                                         COMMAND "${CMAKE_COMMAND}" -E copy "${LIBEAY_BIN}" "$<TARGET_FILE_DIR:${TARGET_BIN}>" VERBATIM)
1009                                 add_custom_command(TARGET ${TARGET_BIN}
1010                                         POST_BUILD
1011                                         COMMAND "${CMAKE_COMMAND}" -E copy "${SSLEAY_BIN}" "$<TARGET_FILE_DIR:${TARGET_BIN}>" VERBATIM)
1012                         endforeach()
1013                 endif()
1014         endif()
1015 endif(NOT LWS_WITHOUT_TESTAPPS)
1016
1017 if (UNIX)
1018         # Generate documentation.
1019         # TODO: Fix this on Windows.
1020         message("Generating API documentation")
1021         file(GLOB C_FILES "${PROJECT_SOURCE_DIR}/lib/*.c")
1022         list(SORT C_FILES)
1023         execute_process(COMMAND "${CMAKE_COMMAND}" -E make_directory "${PROJECT_BINARY_DIR}/doc/")
1024
1025         execute_process(
1026                 COMMAND "${PROJECT_SOURCE_DIR}/scripts/kernel-doc" -html ${C_FILES} ${HDR_PUBLIC}
1027                 OUTPUT_FILE "${PROJECT_BINARY_DIR}/doc/libwebsockets-api-doc.html"
1028                 ERROR_QUIET)
1029
1030         execute_process(
1031                 COMMAND "${PROJECT_SOURCE_DIR}/scripts/kernel-doc" -text ${C_FILES} ${HDR_PUBLIC}
1032                 OUTPUT_FILE "${PROJECT_BINARY_DIR}/doc/libwebsockets-api-doc.txt"
1033                 ERROR_QUIET)
1034
1035 # Generate and install pkgconfig.
1036 # (This is not indented, because the tabs will be part of the output)
1037 file(WRITE "${PROJECT_BINARY_DIR}/libwebsockets.pc"
1038 "prefix=\"${CMAKE_INSTALL_PREFIX}\"
1039 exec_prefix=\${prefix}
1040 libdir=\${exec_prefix}/lib${LIB_SUFFIX}
1041 includedir=\${prefix}/include
1042
1043 Name: libwebsockets
1044 Description: Websockets server and client library
1045 Version: ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}
1046
1047 Libs: -L\${libdir} -lwebsockets
1048 Cflags: -I\${includedir}"
1049 )
1050
1051         install(FILES "${PROJECT_BINARY_DIR}/libwebsockets.pc"
1052                 DESTINATION lib${LIB_SUFFIX}/pkgconfig)
1053 endif(UNIX)
1054
1055 #
1056 # Installation preparations.
1057 #
1058
1059 if(WIN32 AND NOT CYGWIN)
1060   set(DEF_INSTALL_CMAKE_DIR cmake)
1061 else()
1062   set(DEF_INSTALL_CMAKE_DIR lib${LIB_SUFFIX}/cmake/libwebsockets)
1063 endif()
1064
1065 set(LWS_INSTALL_CMAKE_DIR ${DEF_INSTALL_CMAKE_DIR} CACHE PATH "Installation directory for CMake files")
1066
1067 # Export targets (This is used for other CMake projects to easily find the libraries and include files).
1068 export(TARGETS ${LWS_LIBRARIES}
1069         FILE "${PROJECT_BINARY_DIR}/LibwebsocketsTargets.cmake")
1070 export(PACKAGE libwebsockets)
1071
1072 # Generate the config file for the build-tree.
1073 set(LWS__INCLUDE_DIRS
1074     "${PROJECT_SOURCE_DIR}/lib"
1075     "${PROJECT_BINARY_DIR}")
1076 set(LIBWEBSOCKETS_INCLUDE_DIRS ${LWS__INCLUDE_DIRS} CACHE PATH "Libwebsockets include directories")
1077 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfig.cmake.in
1078                 ${PROJECT_BINARY_DIR}/LibwebsocketsConfig.cmake
1079                 @ONLY)
1080
1081 # Generate the config file for the installation tree.
1082 get_filename_component(LWS_ABSOLUTE_INSTALL_CMAKE_DIR ${LWS_INSTALL_CMAKE_DIR} ABSOLUTE)
1083 get_filename_component(LWS_ABSOLUTE_INSTALL_INCLUDE_DIR ${LWS_INSTALL_INCLUDE_DIR} ABSOLUTE)
1084 file(RELATIVE_PATH
1085     REL_INCLUDE_DIR
1086     "${LWS_ABSOLUTE_INSTALL_CMAKE_DIR}"
1087     "${LWS_ABSOLUTE_INSTALL_INCLUDE_DIR}") # Calculate the relative directory from the cmake dir.
1088
1089 # Note the EVENT_CMAKE_DIR is defined in JanssonConfig.cmake.in,
1090 # we escape it here so it's evaluated when it is included instead
1091 # so that the include dirs are given relative to where the
1092 # config file is located.
1093 set(LWS__INCLUDE_DIRS
1094     "\${LWS_CMAKE_DIR}/${REL_INCLUDE_DIR}")
1095 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfig.cmake.in
1096                 ${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/LibwebsocketsConfig.cmake
1097                 @ONLY)
1098
1099 # Generate version info for both build-tree and install-tree.
1100 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfigVersion.cmake.in
1101                 ${PROJECT_BINARY_DIR}/LibwebsocketsConfigVersion.cmake
1102                 @ONLY)
1103
1104                         set_target_properties(${LWS_LIBRARIES}
1105                                         PROPERTIES PUBLIC_HEADER "${HDR_PUBLIC}")
1106
1107 #
1108 # Installation.
1109 #
1110
1111 # Install libs and headers.
1112 install(TARGETS ${LWS_LIBRARIES}
1113                 EXPORT LibwebsocketsTargets
1114                 LIBRARY DESTINATION "${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}" COMPONENT libraries
1115                 ARCHIVE DESTINATION "${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}" COMPONENT libraries
1116                 RUNTIME DESTINATION "${LWS_INSTALL_BIN_DIR}" COMPONENT libraries # Windows DLLs
1117                 PUBLIC_HEADER DESTINATION "${LWS_INSTALL_INCLUDE_DIR}" COMPONENT dev)
1118 set(CPACK_COMPONENT_LIBRARIES_DISPLAY_NAME "Libraries")
1119 set(CPACK_COMPONENT_DEV_DISPLAY_NAME "Development files")
1120
1121 # Install test apps.
1122 if (NOT LWS_WITHOUT_TESTAPPS AND NOT LWS_WITHOUT_CLIENT)
1123         install(TARGETS test-client ${TEST_APP_LIST}
1124                         RUNTIME DESTINATION ${LWS_INSTALL_EXAMPLES_DIR}
1125                         COMPONENT examples)
1126         set(CPACK_COMPONENT_EXAMPLES_DISPLAY_NAME "Example files")
1127 endif()
1128
1129 # Programs shared files used by the test-server.
1130 if (NOT LWS_WITHOUT_TESTAPPS AND NOT LWS_WITHOUT_SERVER)
1131         install(FILES ${TEST_SERVER_DATA}
1132                         DESTINATION share/libwebsockets-test-server
1133                         COMPONENT examples)
1134 endif()
1135
1136 # Install the LibwebsocketsConfig.cmake and LibwebsocketsConfigVersion.cmake
1137 install(FILES
1138                "${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/LibwebsocketsConfig.cmake"
1139                "${PROJECT_BINARY_DIR}/LibwebsocketsConfigVersion.cmake"
1140                DESTINATION "${LWS_INSTALL_CMAKE_DIR}" COMPONENT dev)
1141
1142 # build subdir is not part of sources
1143 set(CPACK_SOURCE_IGNORE_FILES $(CPACK_SOURCE_IGNORE_FILES) ".git" "build" "tgz" "tar.gz")
1144
1145 # Most people are more used to "make dist" compared to "make package_source"
1146 add_custom_target(dist COMMAND "${CMAKE_MAKE_PROGRAM}" package_source)
1147
1148 include(UseRPMTools)
1149 if (RPMTools_FOUND)
1150         RPMTools_ADD_RPM_TARGETS(libwebsockets libwebsockets.spec)
1151 endif()
1152
1153 message("---------------------------------------------------------------------")
1154 message("  Settings:  (For more help do cmake -LH <srcpath>)")
1155 message("---------------------------------------------------------------------")
1156 message(" LWS_WITH_STATIC = ${LWS_WITH_STATIC}")
1157 message(" LWS_WITH_SHARED = ${LWS_WITH_SHARED}")
1158 message(" LWS_WITH_SSL = ${LWS_WITH_SSL} (SSL Support)")
1159 message(" LWS_SSL_CLIENT_USE_OS_CA_CERTS = ${LWS_SSL_CLIENT_USE_OS_CA_CERTS}")
1160 message(" LWS_USE_WOLFSSL = ${LWS_USE_WOLFSSL} (wolfSSL/CyaSSL replacement for OpenSSL)")
1161 if (LWS_USE_WOLFSSL)
1162         message("   LWS_WOLFSSL_LIBRARIES = ${LWS_WOLFSSL_LIBRARIES}")
1163         message("   LWS_WOLFSSL_INCLUDE_DIRS = ${LWS_WOLFSSL_INCLUDE_DIRS}")
1164 endif()
1165 message(" LWS_WITHOUT_BUILTIN_SHA1 = ${LWS_WITHOUT_BUILTIN_SHA1}")
1166 message(" LWS_WITHOUT_BUILTIN_GETIFADDRS = ${LWS_WITHOUT_BUILTIN_GETIFADDRS}")
1167 message(" LWS_WITHOUT_CLIENT = ${LWS_WITHOUT_CLIENT}")
1168 message(" LWS_WITHOUT_SERVER = ${LWS_WITHOUT_SERVER}")
1169 message(" LWS_LINK_TESTAPPS_DYNAMIC = ${LWS_LINK_TESTAPPS_DYNAMIC}")
1170 message(" LWS_WITHOUT_TESTAPPS = ${LWS_WITHOUT_TESTAPPS}")
1171 message(" LWS_WITHOUT_TEST_SERVER = ${LWS_WITHOUT_TEST_SERVER}")
1172 message(" LWS_WITHOUT_TEST_SERVER_EXTPOLL = ${LWS_WITHOUT_TEST_SERVER_EXTPOLL}")
1173 message(" LWS_WITHOUT_TEST_PING = ${LWS_WITHOUT_TEST_PING}")
1174 message(" LWS_WITHOUT_TEST_ECHO = ${LWS_WITHOUT_TEST_ECHO}")
1175 message(" LWS_WITHOUT_TEST_CLIENT = ${LWS_WITHOUT_TEST_CLIENT}")
1176 message(" LWS_WITHOUT_TEST_FRAGGLE = ${LWS_WITHOUT_TEST_FRAGGLE}")
1177 message(" LWS_WITHOUT_EXTENSIONS = ${LWS_WITHOUT_EXTENSIONS}")
1178 message(" LWS_WITH_LATENCY = ${LWS_WITH_LATENCY}")
1179 message(" LWS_WITHOUT_DAEMONIZE = ${LWS_WITHOUT_DAEMONIZE}")
1180 message(" LWS_USE_LIBEV = ${LWS_USE_LIBEV}")
1181 message(" LWS_USE_LIBUV = ${LWS_USE_LIBUV}")
1182 message(" LWS_IPV6 = ${LWS_IPV6}")
1183 message(" LWS_WITH_HTTP2 = ${LWS_WITH_HTTP2}")
1184 message(" LWS_MBED3 = ${LWS_MBED3}")
1185 message(" LWS_SSL_SERVER_WITH_ECDH_CERT = ${LWS_SSL_SERVER_WITH_ECDH_CERT}")
1186 message(" LWS_MAX_SMP = ${LWS_MAX_SMP}")
1187 message("---------------------------------------------------------------------")
1188
1189 # These will be available to parent projects including libwebsockets using add_subdirectory()
1190 set(LIBWEBSOCKETS_LIBRARIES ${LWS_LIBRARIES} CACHE STRING "Libwebsocket libraries")
1191 if (LWS_WITH_STATIC)
1192         set(LIBWEBSOCKETS_LIBRARIES_STATIC websocket CACHE STRING "Libwebsocket static library")
1193 endif()
1194 if (LWS_WITH_SHARED)
1195         set(LIBWEBSOCKETS_LIBRARIES_SHARED websockets_shared CACHE STRING "Libwebsocket shared library")
1196 endif()
1197
1198 # This must always be last!
1199 include(CPack)