CMakeLists.txt

   1 # The name of our project is "VULKAN". CMakeLists files in this project can
   2 # refer to the root source directory of the project as ${VULKAN_SOURCE_DIR} and
   3 # to the root binary directory of the project as ${VULKAN_BINARY_DIR}.
   4 cmake_minimum_required(VERSION 2.8.11)
   5
   6 # This must come before the project command.
   7 set(CMAKE_OSX_DEPLOYMENT_TARGET "10.12" CACHE STRING "Minimum OS X deployment version")
   8
   9 project (VULKAN)
  10 # set (CMAKE_VERBOSE_MAKEFILE 1)
  11
  12 # The API_NAME allows renaming builds to avoid conflicts with installed SDKs
  13 # The MAJOR number of the version we're building, used in naming
  14 # <api-name>-<major>.dll (and other files).
  15 set(API_NAME "Vulkan" CACHE STRING "API name to use when building")
  16 set(MAJOR "1")
  17 string(TOLOWER ${API_NAME} API_LOWERCASE)
  18
  19 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  20 find_package(PythonInterp 3 REQUIRED)
  21
  22 option(USE_CCACHE "Use ccache" OFF)
  23 if (USE_CCACHE)
  24     find_program(CCACHE_FOUND ccache)
  25     if(CCACHE_FOUND)
  26         set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
  27         set_property(GLOBAL PROPERTY RULE_LAUNCH_LINK ccache)
  28     endif(CCACHE_FOUND)
  29 endif()
  30
  31 if(APPLE)
  32     # CMake versions 3 or later need CMAKE_MACOSX_RPATH defined.
  33     # This avoids the CMP0042 policy message.
  34     set(CMAKE_MACOSX_RPATH 1)
  35     # The "install" target for MacOS fixes up bundles in place.
  36     set(CMAKE_INSTALL_PREFIX ${CMAKE_BINARY_DIR})
  37 endif()
  38
  39 # Enable cmake folders
  40 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  41 set(LVL_TARGET_FOLDER lvl_cmake_targets)
  42
  43 if(CMAKE_SYSTEM_NAME STREQUAL "Linux" OR CMAKE_SYSTEM_NAME STREQUAL "Darwin")
  44     set(FALLBACK_CONFIG_DIRS "/etc/xdg" CACHE STRING
  45         "Search path to use when XDG_CONFIG_DIRS is unset or empty or the current process is SUID/SGID. Default is freedesktop compliant.")
  46     set(FALLBACK_DATA_DIRS "/usr/local/share:/usr/share" CACHE STRING
  47         "Search path to use when XDG_DATA_DIRS is unset or empty or the current process is SUID/SGID. Default is freedesktop compliant.")
  48 endif()
  49
  50 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
  51     include(FindPkgConfig)
  52     option(BUILD_WSI_XCB_SUPPORT "Build XCB WSI support" ON)
  53     option(BUILD_WSI_XLIB_SUPPORT "Build Xlib WSI support" ON)
  54     option(BUILD_WSI_WAYLAND_SUPPORT "Build Wayland WSI support" ON)
  55     option(BUILD_WSI_MIR_SUPPORT "Build Mir WSI support" OFF)
  56     set(DEMOS_WSI_SELECTION "XCB" CACHE STRING "Select WSI target for demos (XCB, XLIB, WAYLAND, MIR, DISPLAY)")
  57
  58     if (BUILD_WSI_XCB_SUPPORT)
  59         find_package(XCB REQUIRED)
  60     endif()
  61
  62     if (BUILD_WSI_XLIB_SUPPORT)
  63         find_package(X11 REQUIRED)
  64     endif()
  65
  66     if (BUILD_WSI_WAYLAND_SUPPORT)
  67         find_package(Wayland REQUIRED)
  68         include_directories(${WAYLAND_CLIENT_INCLUDE_DIR})
  69     endif()
  70
  71     if (BUILD_WSI_MIR_SUPPORT)
  72         find_package(Mir REQUIRED)
  73     endif()
  74
  75     # This option can be used to suppress the installation of artifacts from the
  76     # Vulkan-LoaderAndValidationLayers repo while running "make install" for the
  77     # VulkanTools and VulkanSamples repos.  This can be used to prevent the
  78     # overwriting of LVL artifacts when installing these downstream repos.
  79     option(INSTALL_LVL_FILES "Install content from LoaderAndValidationLayers repo" ON)
  80 endif()
  81
  82 set(SCRIPTS_DIR "${CMAKE_CURRENT_SOURCE_DIR}/scripts")
  83
  84 # Header file for CMake settings
  85 include_directories("${PROJECT_SOURCE_DIR}/include")
  86
  87 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Clang")
  88     set(COMMON_COMPILE_FLAGS "-Wall -Wextra -Wno-unused-parameter -Wno-missing-field-initializers")
  89     set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -fno-strict-aliasing -fno-builtin-memcmp")
  90
  91     # For GCC version 7.1 or greater, we need to disable the implicit fallthrough warning since
  92     # there's no consistent way to satisfy all compilers until they all accept the C++17 standard
  93     if (CMAKE_COMPILER_IS_GNUCC AND NOT (CMAKE_CXX_COMPILER_VERSION LESS 7.1))
  94         set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -Wimplicit-fallthrough=0")
  95     endif()
  96
  97     if (APPLE)
  98         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${COMMON_COMPILE_FLAGS}")
  99     else()
 100         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=c99 ${COMMON_COMPILE_FLAGS}")
 101     endif()
 102     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${COMMON_COMPILE_FLAGS} -std=c++11 -fno-rtti")
 103     if (UNIX)
 104         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden")
 105         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")
 106     endif()
 107 endif()
 108
 109 if(WIN32)
 110     # Treat warnings as errors
 111     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/WX>")
 112     # Disable RTTI
 113     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/GR->")
 114     # Warn about nested declarations
 115     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34456>")
 116     # Warn about potentially uninitialized variables
 117     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34701>")
 118     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34703>")
 119     # Warn about different indirection types.
 120     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34057>")
 121     # Warn about signed/unsigned mismatch.
 122     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34245>")
 123 endif()
 124
 125 if(NOT WIN32)
 126     set (BUILDTGT_DIR build)
 127     set (BINDATA_DIR Bin)
 128     set (LIBSOURCE_DIR Lib)
 129 else()
 130     # is WIN32
 131     option(DISABLE_BUILD_PATH_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with MSVC build type info" OFF)
 132     option(DISABLE_BUILDTGT_DIR_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with target info" OFF)
 133     option(ENABLE_WIN10_ONECORE "Link the loader with OneCore umbrella libraries" OFF)
 134
 135     # For Windows, since 32-bit and 64-bit items can co-exist, we build each in its own build directory.
 136     # 32-bit target data goes in build32, and 64-bit target data goes into build.  So, include/link the
 137     # appropriate data at build time.
 138     if (DISABLE_BUILDTGT_DIR_DECORATION)
 139         set (BUILDTGT_DIR "")
 140         set (BINDATA_DIR "")
 141         set (LIBSOURCE_DIR "")
 142     elseif (CMAKE_CL_64)
 143         set (BUILDTGT_DIR build)
 144         set (BINDATA_DIR Bin)
 145         set (LIBSOURCE_DIR Lib)
 146     else()
 147         set (BUILDTGT_DIR build32)
 148         set (BINDATA_DIR Bin32)
 149         set (LIBSOURCE_DIR Lib32)
 150     endif()
 151 endif()
 152
 153 option(BUILD_LOADER "Build loader" ON)
 154 option(BUILD_TESTS "Build tests" ON)
 155 option(BUILD_LAYERS "Build layers" ON)
 156 option(BUILD_DEMOS "Build demos" ON)
 157 if (APPLE)
 158     option(BUILD_VKJSON "Build vkjson" OFF)
 159 else()
 160     option(BUILD_VKJSON "Build vkjson" ON)
 161 endif()
 162 option(BUILD_ICD "Build icd" ON)
 163 option(CUSTOM_GLSLANG_BIN_ROOT "Use the user defined GLSLANG_BINARY_ROOT" OFF)
 164 option(CUSTOM_SPIRV_TOOLS_BIN_ROOT "Use the user defined SPIRV_TOOLS*BINARY_ROOT paths" OFF)
 165
 166 #Choose natural default paths for glslang and SPIRV-Tools binaries to support custom definition by the user on the CMake command line or in the GUI
 167 set(GLSLANG_BINARY_ROOT "${CMAKE_BINARY_DIR}/../glslang" CACHE STRING "User defined path to the glslang binaries for this project")
 168 set(SPIRV_TOOLS_BINARY_ROOT "${CMAKE_BINARY_DIR}/../SPIRV-Tools" CACHE STRING "User defined path to the SPIRV-Tools binaries for this project")
 169 set(SPIRV_TOOLS_OPT_BINARY_ROOT "${CMAKE_BINARY_DIR}/../SPIRV-Tools/opt" CACHE STRING "User defined path to the SPIRV-Tools-opt binaries for this project")
 170
 171 # Define a variable for a default root location to the gslang, SPIRV-Tools and other external sources and cache it to allow the user to customize it as needed
 172 set(EXTERNAL_SOURCE_ROOT "${CMAKE_CURRENT_SOURCE_DIR}/external" CACHE STRING "Root path to external sources such as glslang and SPIRV-Tools")
 173
 174
 175 if (WIN32)
 176     if(CUSTOM_GLSLANG_BIN_ROOT)
 177         set(GSLANG_FINAL_BINARY_PATH ${GLSLANG_BINARY_ROOT}/${BUILDTGT_DIR})
 178     else()
 179         set(GSLANG_FINAL_BINARY_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}")
 180     endif()
 181
 182     if(DISABLE_BUILD_PATH_DECORATION)
 183         set (DEBUG_DECORATION "")
 184         set (RELEASE_DECORATION "")
 185     else()
 186         set (DEBUG_DECORATION "Debug")
 187         set (RELEASE_DECORATION "Release")
 188     endif()
 189
 190     # Take some steps to set up a variable pointing to the final glslang binaries given the variety of input options
 191     set (GLSLANG_SEARCH_PATH "${GSLANG_FINAL_BINARY_PATH}/glslang/${RELEASE_DECORATION}"
 192                              "${GSLANG_FINAL_BINARY_PATH}/glslang/OSDependent/Windows/${RELEASE_DECORATION}"
 193                              "${GSLANG_FINAL_BINARY_PATH}/hlsl/${RELEASE_DECORATION}"
 194                              "${GSLANG_FINAL_BINARY_PATH}/OGLCompilersDLL/${RELEASE_DECORATION}"
 195                              "${GSLANG_FINAL_BINARY_PATH}/SPIRV/${RELEASE_DECORATION}" )
 196
 197     set (GLSLANG_DEBUG_SEARCH_PATH "${GSLANG_FINAL_BINARY_PATH}/glslang/${DEBUG_DECORATION}"
 198                                    "${GSLANG_FINAL_BINARY_PATH}/glslang/OSDependent/Windows/${DEBUG_DECORATION}"
 199                                    "${GSLANG_FINAL_BINARY_PATH}/hlsl/${DEBUG_DECORATION}"
 200                                    "${GSLANG_FINAL_BINARY_PATH}/OGLCompilersDLL/${DEBUG_DECORATION}"
 201                                    "${GSLANG_FINAL_BINARY_PATH}/SPIRV/${DEBUG_DECORATION}")
 202
 203     if(CUSTOM_SPIRV_TOOLS_BIN_ROOT)
 204         set (SPIRV_TOOLS_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/${BUILDTGT_DIR}/source/${RELEASE_DECORATION}")
 205         set (SPIRV_TOOLS_DEBUG_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/${BUILDTGT_DIR}/source/${DEBUG_DECORATION}")
 206         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${SPIRV_TOOLS_OPT_BINARY_ROOT}/${BUILDTGT_DIR}/source/opt/${RELEASE_DECORATION}")
 207         set (SPIRV_TOOLS_OPT_DEBUG_SEARCH_PATH "${SPIRV_TOOLS_OPT_BINARY_ROOT}/${BUILDTGT_DIR}/source/opt/${DEBUG_DECORATION}")
 208     else()
 209         set (SPIRV_TOOLS_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source/${RELEASE_DECORATION}")
 210         set (SPIRV_TOOLS_DEBUG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source/${DEBUG_DECORATION}")
 211         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source/opt/${RELEASE_DECORATION}")
 212         set (SPIRV_TOOLS_OPT_DEBUG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source/opt/${DEBUG_DECORATION}")
 213     endif()
 214 else()
 215     # not WIN32
 216     if(CUSTOM_GLSLANG_BIN_ROOT)
 217         set (GLSLANG_SEARCH_PATH "${GLSLANG_BINARY_ROOT}/install/lib"
 218                                  "${GLSLANG_BINARY_ROOT}/glslang"
 219                                  "${GLSLANG_BINARY_ROOT}/glslang/OSDependent/Unix"
 220                                  "${GLSLANG_BINARY_ROOT}/OGLCompilersDLL"
 221                                  "${GLSLANG_BINARY_ROOT}/SPIRV"
 222                                  "${GLSLANG_BINARY_ROOT}/hlsl"
 223                                  "${GLSLANG_BINARY_ROOT}/StandAlone")
 224     else()
 225         set (GLSLANG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/install/lib" "${CMAKE_SOURCE_DIR}/../x86_64/lib/glslang" )
 226     endif()
 227
 228     if(CUSTOM_SPIRV_TOOLS_BIN_ROOT)
 229         set (SPIRV_TOOLS_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/source" )
 230         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${SPIRV_TOOLS_OPT_BINARY_ROOT}/source/opt" )
 231     else()
 232         set (SPIRV_TOOLS_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source" "${CMAKE_SOURCE_DIR}/../x86_64/lib/spirv-tools" )
 233         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source/opt" "${CMAKE_SOURCE_DIR}/../x86_64/lib/spirv-tools" )
 234     endif()
 235 endif()
 236
 237 find_program(GLSLANG_VALIDATOR NAMES glslangValidator
 238              HINTS "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/install/bin"
 239                    "${GLSLANG_BINARY_ROOT}/StandAlone"
 240                    "${PROJECT_SOURCE_DIR}/external/${BINDATA_DIR}")
 241
 242 find_path(GLSLANG_SPIRV_INCLUDE_DIR SPIRV/spirv.hpp HINTS "${EXTERNAL_SOURCE_ROOT}/glslang"
 243                                                     "${CMAKE_SOURCE_DIR}/../glslang"
 244                                               DOC "Path to SPIRV/spirv.hpp")
 245
 246 find_path(SPIRV_TOOLS_INCLUDE_DIR spirv-tools/libspirv.h HINTS "${EXTERNAL_SOURCE_ROOT}/glslang/External/spirv-tools/include"
 247                                                    "${CMAKE_SOURCE_DIR}/../glslang/External/spirv-tools/include"
 248                                              DOC "Path to spirv-tools/libspirv.h")
 249
 250 find_library(GLSLANG_LIB NAMES glslang
 251              HINTS ${GLSLANG_SEARCH_PATH} )
 252
 253 find_library(OGLCompiler_LIB NAMES OGLCompiler
 254              HINTS ${GLSLANG_SEARCH_PATH} )
 255
 256 find_library(OSDependent_LIB NAMES OSDependent
 257              HINTS ${GLSLANG_SEARCH_PATH} )
 258
 259 find_library(HLSL_LIB NAMES HLSL
 260              HINTS ${GLSLANG_SEARCH_PATH} )
 261
 262 find_library(SPIRV_LIB NAMES SPIRV
 263              HINTS ${GLSLANG_SEARCH_PATH} )
 264
 265 find_library(SPIRV_REMAPPER_LIB NAMES SPVRemapper
 266              HINTS ${GLSLANG_SEARCH_PATH} )
 267
 268 find_library(SPIRV_TOOLS_LIB NAMES SPIRV-Tools
 269              HINTS ${SPIRV_TOOLS_SEARCH_PATH} )
 270
 271 find_library(SPIRV_TOOLS_OPT_LIB NAMES SPIRV-Tools-opt
 272              HINTS ${SPIRV_TOOLS_OPT_SEARCH_PATH} )
 273
 274 if (WIN32)
 275     add_library(glslang         STATIC IMPORTED)
 276     add_library(OGLCompiler     STATIC IMPORTED)
 277     add_library(OSDependent     STATIC IMPORTED)
 278     add_library(HLSL            STATIC IMPORTED)
 279     add_library(SPIRV           STATIC IMPORTED)
 280     add_library(SPVRemapper     STATIC IMPORTED)
 281     add_library(Loader          STATIC IMPORTED)
 282     add_library(SPIRV-Tools-opt STATIC IMPORTED)
 283     add_library(SPIRV-Tools     STATIC IMPORTED)
 284
 285     find_library(GLSLANG_DLIB NAMES glslangd
 286                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 287     find_library(OGLCompiler_DLIB NAMES OGLCompilerd
 288                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 289     find_library(OSDependent_DLIB NAMES OSDependentd
 290                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 291     find_library(HLSL_DLIB NAMES HLSLd
 292                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 293     find_library(SPIRV_DLIB NAMES SPIRVd
 294                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 295     find_library(SPIRV_REMAPPER_DLIB NAMES SPVRemapperd
 296                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 297     find_library(SPIRV_TOOLS_DLIB NAMES SPIRV-Toolsd
 298                  HINTS ${SPIRV_TOOLS_DEBUG_SEARCH_PATH} )
 299     find_library(SPIRV_TOOLS_OPT_DLIB NAMES SPIRV-Tools-optd
 300                  HINTS ${SPIRV_TOOLS_OPT_DEBUG_SEARCH_PATH} )
 301
 302     set_target_properties(glslang PROPERTIES
 303                          IMPORTED_LOCATION       "${GLSLANG_LIB}"
 304                          IMPORTED_LOCATION_DEBUG "${GLSLANG_DLIB}")
 305     set_target_properties(OGLCompiler PROPERTIES
 306                          IMPORTED_LOCATION       "${OGLCompiler_LIB}"
 307                          IMPORTED_LOCATION_DEBUG "${OGLCompiler_DLIB}")
 308     set_target_properties(OSDependent PROPERTIES
 309                          IMPORTED_LOCATION       "${OSDependent_LIB}"
 310                          IMPORTED_LOCATION_DEBUG "${OSDependent_DLIB}")
 311     set_target_properties(HLSL PROPERTIES
 312                          IMPORTED_LOCATION       "${HLSL_LIB}"
 313                          IMPORTED_LOCATION_DEBUG "${HLSL_DLIB}")
 314     set_target_properties(SPIRV PROPERTIES
 315                          IMPORTED_LOCATION       "${SPIRV_LIB}"
 316                          IMPORTED_LOCATION_DEBUG "${SPIRV_DLIB}")
 317     set_target_properties(SPVRemapper PROPERTIES
 318                          IMPORTED_LOCATION       "${SPIRV_REMAPPER_LIB}"
 319                          IMPORTED_LOCATION_DEBUG "${SPIRV_REMAPPER_DLIB}")
 320     set_target_properties(SPIRV-Tools PROPERTIES
 321                          IMPORTED_LOCATION       "${SPIRV_TOOLS_LIB}"
 322                          IMPORTED_LOCATION_DEBUG "${SPIRV_TOOLS_DLIB}")
 323     set_target_properties(SPIRV-Tools-opt PROPERTIES
 324                          IMPORTED_LOCATION       "${SPIRV_TOOLS_OPT_LIB}"
 325                          IMPORTED_LOCATION_DEBUG "${SPIRV_TOOLS_OPT_DLIB}")
 326
 327     set (SPIRV_TOOLS_LIBRARIES SPIRV-Tools-opt SPIRV-Tools)
 328     set (GLSLANG_LIBRARIES glslang OGLCompiler OSDependent HLSL SPIRV SPVRemapper ${SPIRV_TOOLS_LIBRARIES})
 329 else ()
 330     # not WIN32
 331     set (SPIRV_TOOLS_LIBRARIES ${SPIRV_TOOLS_OPT_LIB} ${SPIRV_TOOLS_LIB})
 332     set (GLSLANG_LIBRARIES ${GLSLANG_LIB} ${OGLCompiler_LIB} ${OSDependent_LIB} ${HLSL_LIB} ${SPIRV_LIB} ${SPIRV_REMAPPER_LIB} ${SPIRV_TOOLS_LIBRARIES})
 333 endif()
 334
 335 set (PYTHON_CMD ${PYTHON_EXECUTABLE})
 336
 337 # Define macro used for building vkxml generated files
 338 macro(run_vk_xml_generate dependency output)
 339     add_custom_command(OUTPUT ${output}
 340     COMMAND ${PYTHON_CMD} ${SCRIPTS_DIR}/lvl_genvk.py -registry ${SCRIPTS_DIR}/vk.xml ${output}
 341     DEPENDS ${SCRIPTS_DIR}/vk.xml ${SCRIPTS_DIR}/generator.py ${SCRIPTS_DIR}/${dependency} ${SCRIPTS_DIR}/lvl_genvk.py ${SCRIPTS_DIR}/reg.py
 342     )
 343 endmacro()
 344
 345 # Define macro used for generating header files containing commit IDs for external dependencies
 346 macro(run_external_revision_generate source_dir symbol_name output)
 347     add_custom_command(OUTPUT ${output}
 348     # NOTE: If you modify this call to use --rev_file instead of --git_dir (to read the commit ID from a file instead of
 349     # parsing from a Git repository), you probably also want to add the revision file to the list of DEPENDS on the
 350     # subsequent line (to ensure that the script is re-run when the revision file is modified).
 351     COMMAND ${PYTHON_CMD} ${SCRIPTS_DIR}/external_revision_generator.py --git_dir ${source_dir} -s ${symbol_name} -o ${output}
 352     DEPENDS ${SCRIPTS_DIR}/external_revision_generator.py ${source_dir}/.git/HEAD ${source_dir}/.git/index
 353     )
 354 endmacro()
 355
 356 # Custom target for generated vulkan helper file dependencies
 357 set(generate_helper_files_DEPENDS)
 358 if(BUILD_LAYERS)
 359     LIST(APPEND generate_helper_files_DEPENDS spirv_tools_commit_id.h)
 360 endif()
 361 add_custom_target(generate_helper_files DEPENDS
 362     vk_enum_string_helper.h
 363     vk_safe_struct.h
 364     vk_safe_struct.cpp
 365     vk_object_types.h
 366     vk_layer_dispatch_table.h
 367     vk_dispatch_table_helper.h
 368     vk_extension_helper.h
 369     vk_typemap_helper.h
 370     ${generate_helper_files_DEPENDS}
 371     )
 372 set_target_properties(generate_helper_files PROPERTIES FOLDER ${LVL_TARGET_FOLDER})
 373
 374 # Rules to build generated helper files
 375 run_vk_xml_generate(loader_extension_generator.py vk_layer_dispatch_table.h)
 376 run_vk_xml_generate(dispatch_table_helper_generator.py vk_dispatch_table_helper.h)
 377 run_vk_xml_generate(helper_file_generator.py vk_safe_struct.h)
 378 run_vk_xml_generate(helper_file_generator.py vk_safe_struct.cpp)
 379 run_vk_xml_generate(helper_file_generator.py vk_enum_string_helper.h)
 380 run_vk_xml_generate(helper_file_generator.py vk_object_types.h)
 381 run_vk_xml_generate(helper_file_generator.py vk_extension_helper.h)
 382 run_vk_xml_generate(helper_file_generator.py vk_typemap_helper.h)
 383 if(BUILD_LAYERS)
 384     run_external_revision_generate(${EXTERNAL_SOURCE_ROOT}/glslang/External/spirv-tools SPIRV_TOOLS_COMMIT_ID spirv_tools_commit_id.h)
 385 endif()
 386
 387
 388
 389 if(NOT WIN32)
 390     include(GNUInstallDirs)
 391
 392     add_definitions(-DFALLBACK_CONFIG_DIRS="${FALLBACK_CONFIG_DIRS}")
 393     add_definitions(-DFALLBACK_DATA_DIRS="${FALLBACK_DATA_DIRS}")
 394     add_definitions(-DSYSCONFDIR="${CMAKE_INSTALL_FULL_SYSCONFDIR}")
 395
 396     # Make sure /etc is searched by the loader
 397     if(NOT (CMAKE_INSTALL_FULL_SYSCONFDIR STREQUAL "/etc"))
 398         add_definitions(-DEXTRASYSCONFDIR="/etc")
 399     endif()
 400 endif()
 401
 402 if(UNIX)
 403     if(INSTALL_LVL_FILES)
 404         install(DIRECTORY "${PROJECT_SOURCE_DIR}/include/vulkan" DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 405         install(FILES "${CMAKE_CURRENT_BINARY_DIR}/vk_layer_dispatch_table.h" DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/vulkan")
 406     endif()
 407
 408 # uninstall target
 409 configure_file(
 410     "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 411     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 412     IMMEDIATE @ONLY)
 413
 414 add_custom_target(uninstall
 415     COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)
 416 endif()
 417
 418 # Layer Utils Library
 419 # For Windows, we use a static lib because the Windows loader has a fairly restrictive loader search
 420 # path that can't be easily modified to point it to the same directory that contains the layers.
 421 set(VKLAYER_UTILS_VLF_SOURCES
 422     layers/vk_layer_config.cpp
 423     layers/vk_layer_extension_utils.cpp
 424     layers/vk_layer_utils.cpp
 425     layers/vk_format_utils.cpp
 426     )
 427 if (WIN32)
 428     add_library(VkLayer_utils STATIC ${VKLAYER_UTILS_VLF_SOURCES})
 429     target_compile_definitions(VkLayer_utils PUBLIC _CRT_SECURE_NO_WARNINGS)
 430 else()
 431     add_library(VkLayer_utils SHARED ${VKLAYER_UTILS_VLF_SOURCES})
 432     if(INSTALL_LVL_FILES)
 433         install(TARGETS VkLayer_utils DESTINATION ${CMAKE_INSTALL_LIBDIR})
 434     endif()
 435 endif()
 436 add_dependencies(VkLayer_utils generate_helper_files)
 437 target_include_directories(
 438     VkLayer_utils PUBLIC
 439     ${CMAKE_CURRENT_SOURCE_DIR}/loader
 440     ${CMAKE_CURRENT_SOURCE_DIR}/include/vulkan
 441     ${CMAKE_CURRENT_BINARY_DIR}
 442     )
 443
 444 add_definitions(-DAPI_NAME="${API_NAME}")
 445
 446 # loader: Generic VULKAN ICD loader
 447 # tests: VULKAN tests
 448 if(BUILD_LOADER)
 449     add_subdirectory(loader)
 450 endif()
 451
 452 if(BUILD_TESTS)
 453     add_subdirectory(tests)
 454 endif()
 455
 456 if(BUILD_LAYERS)
 457     add_subdirectory(layers)
 458 endif()
 459
 460 if(BUILD_DEMOS)
 461     add_subdirectory(demos)
 462 endif()
 463
 464 if(BUILD_VKJSON)
 465     add_subdirectory(libs/vkjson)
 466 endif()
 467
 468 if(BUILD_ICD)
 469     add_subdirectory(icd)
 470 endif()