CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2
   3 if(NOT DEFINED CMAKE_BUILD_TYPE)
   4         set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type")
   5 endif()
   6
   7 project(libwebsockets C)
   8
   9 set(PACKAGE "libwebsockets")
  10 set(CPACK_PACKAGE_NAME "${PACKAGE}")
  11 set(CPACK_PACKAGE_VERSION_MAJOR "1")
  12 set(CPACK_PACKAGE_VERSION_MINOR "5")
  13 set(CPACK_PACKAGE_VERSION "${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}")
  14 set(CPACK_PACKAGE_VENDOR "andy@warmcat.com")
  15 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "${PACKAGE} ${PACKAGE_VERSION}")
  16 set(SOVERSION "5")
  17 set(CPACK_SOURCE_GENERATOR "TGZ")
  18 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
  19 set(VERSION "${CPACK_PACKAGE_VERSION}")
  20
  21 set(LWS_LIBRARY_VERSION ${CPACK_PACKAGE_VERSION})
  22 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${PROJECT_SOURCE_DIR}/cmake/")
  23
  24 message(STATUS "CMAKE_TOOLCHAIN_FILE='${CMAKE_TOOLCHAIN_FILE}'")
  25
  26 # Try to find the current Git hash.
  27 find_package(Git)
  28 if(GIT_EXECUTABLE)
  29         execute_process(
  30     WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
  31     COMMAND "${GIT_EXECUTABLE}" log -n 1 --pretty=%h
  32     OUTPUT_VARIABLE GIT_HASH
  33     OUTPUT_STRIP_TRAILING_WHITESPACE
  34     )
  35
  36     set(LWS_BUILD_HASH ${GIT_HASH})
  37     message("Git commit hash: ${LWS_BUILD_HASH}")
  38 endif()
  39
  40 set(LWS_USE_BUNDLED_ZLIB_DEFAULT OFF)
  41 if(WIN32)
  42         set(LWS_USE_BUNDLED_ZLIB_DEFAULT ON)
  43 endif()
  44
  45 option(LWS_WITH_STATIC "Build the static version of the library" ON)
  46 option(LWS_WITH_SHARED "Build the shared version of the library" ON)
  47 option(LWS_WITH_SSL "Include SSL support (default OpenSSL, wolfSSL if LWS_USE_WOLFSSL is set)" ON)
  48 option(LWS_USE_CYASSL "Use CyaSSL replacement for OpenSSL. When setting this, you also need to specify LWS_CYASSL_LIBRARIES and LWS_CYASSL_INCLUDE_DIRS" OFF)
  49 option(LWS_USE_WOLFSSL "Use wolfSSL replacement for OpenSSL. When setting this, you also need to specify LWS_WOLFSSL_LIBRARIES and LWS_WOLFSSL_INCLUDE_DIRS" OFF)
  50 option(LWS_WITH_ZLIB "Include zlib support (required for extensions)" ON)
  51 option(LWS_WITH_LIBEV "Compile with support for libev" OFF)
  52 option(LWS_USE_BUNDLED_ZLIB "Use bundled zlib version (Windows only)" ${LWS_USE_BUNDLED_ZLIB_DEFAULT})
  53 option(LWS_SSL_CLIENT_USE_OS_CA_CERTS "SSL support should make use of the OS-installed CA root certs" ON)
  54 option(LWS_WITHOUT_BUILTIN_GETIFADDRS "Don't use the BSD getifaddrs implementation from libwebsockets if it is missing (this will result in a compilation error) ... The default is to assume that your libc provides it. On some systems such as uclibc it doesn't exist." OFF)
  55 option(LWS_WITHOUT_BUILTIN_SHA1 "Don't build the lws sha-1 (eg, because openssl will provide it" OFF)
  56 option(LWS_WITHOUT_CLIENT "Don't build the client part of the library" OFF)
  57 option(LWS_WITHOUT_SERVER "Don't build the server part of the library" OFF)
  58 option(LWS_LINK_TESTAPPS_DYNAMIC "Link the test apps to the shared version of the library. Default is to link statically" OFF)
  59 option(LWS_WITHOUT_TESTAPPS "Don't build the libwebsocket-test-apps" OFF)
  60 option(LWS_WITHOUT_TEST_SERVER "Don't build the test server" OFF)
  61 option(LWS_WITHOUT_TEST_SERVER_EXTPOLL "Don't build the test server version that uses external poll" OFF)
  62 option(LWS_WITHOUT_TEST_PING "Don't build the ping test application" OFF)
  63 option(LWS_WITHOUT_TEST_CLIENT "Don't build the client test application" OFF)
  64 option(LWS_WITHOUT_TEST_FRAGGLE "Don't build the ping test application" OFF)
  65 option(LWS_WITHOUT_EXTENSIONS "Don't compile with extensions" OFF)
  66 option(LWS_WITH_LATENCY "Build latency measuring code into the library" OFF)
  67 option(LWS_WITHOUT_DAEMONIZE "Don't build the daemonization api" ON)
  68 option(LWS_IPV6 "Compile with support for ipv6" OFF)
  69 option(LWS_WITH_HTTP2 "Compile with support for http2" OFF)
  70 option(LWS_MBED3 "Platform is MBED3" OFF)
  71
  72 if (DEFINED YOTTA_WEBSOCKETS_VERSION_STRING)
  73
  74 set(LWS_WITH_SHARED OFF)
  75 set(LWS_WITH_SSL OFF)
  76 set(LWS_WITH_ZLIB OFF)
  77 set(LWS_WITHOUT_CLIENT ON)
  78 set(LWS_WITHOUT_TESTAPPS ON)
  79 set(LWS_WITHOUT_EXTENSIONS ON)
  80 set(LWS_MBED3 ON)
  81
  82 endif()
  83
  84 if (DEFINED YOTTA_WEBSOCKETS_VERSION_STRING)
  85
  86 set(LWS_WITH_SHARED OFF)
  87 set(LWS_WITH_SSL OFF)
  88 set(LWS_WITH_ZLIB OFF)
  89 set(LWS_WITHOUT_CLIENT ON)
  90 set(LWS_WITHOUT_TESTAPPS ON)
  91 set(LWS_WITHOUT_EXTENSIONS ON)
  92 set(LWS_MBED3 ON)
  93
  94 endif()
  95
  96
  97 # Allow the user to override installation directories.
  98 set(LWS_INSTALL_LIB_DIR       lib CACHE PATH "Installation directory for libraries")
  99 set(LWS_INSTALL_BIN_DIR       bin CACHE PATH "Installation directory for executables")
 100 set(LWS_INSTALL_INCLUDE_DIR   include CACHE PATH "Installation directory for header files")
 101 set(LWS_INSTALL_EXAMPLES_DIR  bin CACHE PATH "Installation directory for example files")
 102
 103 # Allow the user to use the old CyaSSL options/library in stead of wolfSSL
 104 if (LWS_USE_CYASSL AND LWS_USE_WOLFSSL)
 105         message(FATAL_ERROR "LWS_USE_CYASSL and LWS_USE_WOLFSSL are mutually exclusive!")
 106 endif()
 107 if (LWS_USE_CYASSL)
 108         # Copy CyaSSL options to the wolfSSL options
 109         set(LWS_USE_WOLFSSL ${LWS_USE_CYASSL} CACHE BOOL "Use wolfSSL/CyaSSL instead of OpenSSL" FORCE)
 110         set(LWS_WOLFSSL_LIBRARIES ${LWS_CYASSL_LIBRARIES} CACHE PATH "Path to wolfSSL/CyaSSL libraries" FORCE)
 111         set(LWS_WOLFSSL_INCLUDE_DIRS ${LWS_CYASSL_INCLUDE_DIRS} CACHE PATH "Path to wolfSSL/CyaSSL header files" FORCE)
 112 endif()
 113
 114 if (LWS_WITHOUT_CLIENT AND LWS_WITHOUT_SERVER)
 115         message(FATAL_ERROR "Makes no sense to compile with neither client nor server.")
 116 endif()
 117
 118 if (NOT (LWS_WITH_STATIC OR LWS_WITH_SHARED))
 119         message(FATAL_ERROR "Makes no sense to compile with neither static nor shared libraries.")
 120 endif()
 121
 122 if (NOT LWS_WITHOUT_EXTENSIONS)
 123         if (NOT LWS_WITH_ZLIB)
 124                 message(FATAL_ERROR "zlib is required for extensions.")
 125         endif()
 126 endif()
 127
 128 set(LWS_ZLIB_LIBRARIES CACHE PATH "Path to the zlib library")
 129 set(LWS_ZLIB_INCLUDE_DIRS CACHE PATH "Path to the zlib include directory")
 130 set(LWS_OPENSSL_LIBRARIES CACHE PATH "Path to the OpenSSL library")
 131 set(LWS_OPENSSL_INCLUDE_DIRS CACHE PATH "Path to the OpenSSL include directory")
 132 set(LWS_WOLFSSL_LIBRARIES CACHE PATH "Path to the wolfSSL library")
 133 set(LWS_WOLFSSL_INCLUDE_DIRS CACHE PATH "Path to the wolfSSL include directory")
 134 set(LWS_LIBEV_LIBRARIES CACHE PATH "Path to the libev library")
 135 set(LWS_LIBEV_INCLUDE_DIRS CACHE PATH "Path to the libev include directory")
 136
 137 if (NOT LWS_WITH_SSL)
 138         set(LWS_WITHOUT_BUILTIN_SHA1 OFF)
 139 endif()
 140
 141 if (LWS_WITH_SSL AND NOT LWS_USE_WOLFSSL)
 142         if ("${LWS_OPENSSL_LIBRARIES}" STREQUAL "" OR "${LWS_OPENSSL_INCLUDE_DIRS}" STREQUAL "")
 143         else()
 144                 set(OPENSSL_LIBRARIES ${LWS_OPENSSL_LIBRARIES})
 145                 set(OPENSSL_INCLUDE_DIRS ${LWS_OPENSSL_INCLUDE_DIRS})
 146                 set(OPENSSL_FOUND 1)
 147         endif()
 148 endif()
 149
 150 if (LWS_WITH_SSL AND LWS_USE_WOLFSSL)
 151         if ("${LWS_WOLFSSL_LIBRARIES}" STREQUAL "" OR "${LWS_WOLFSSL_INCLUDE_DIRS}" STREQUAL "")
 152                 if (NOT WOLFSSL_FOUND)
 153                         if (LWS_USE_CYASSL)
 154                                 message(FATAL_ERROR "You must set LWS_CYASSL_LIBRARIES and LWS_CYASSL_INCLUDE_DIRS when LWS_USE_CYASSL is turned on.")
 155                         else()
 156                                 message(FATAL_ERROR "You must set LWS_WOLFSSL_LIBRARIES and LWS_WOLFSSL_INCLUDE_DIRS when LWS_USE_WOLFSSL is turned on.")
 157                         endif()
 158                 endif()
 159         else()
 160                 set(WOLFSSL_LIBRARIES ${LWS_WOLFSSL_LIBRARIES})
 161                 set(WOLFSSL_INCLUDE_DIRS ${LWS_WOLFSSL_INCLUDE_DIRS})
 162                 set(WOLFSSL_FOUND 1)
 163         endif()
 164         set(USE_WOLFSSL 1)
 165         if (LWS_USE_CYASSL)
 166                 set(USE_OLD_CYASSL 1)
 167         endif()
 168 endif()
 169
 170 if (LWS_WITH_ZLIB AND NOT LWS_USE_BUNDLED_ZLIB)
 171         if ("${LWS_ZLIB_LIBRARIES}" STREQUAL "" OR "${LWS_ZLIB_INCLUDE_DIRS}" STREQUAL "")
 172         else()
 173                 set(ZLIB_LIBRARIES ${LWS_ZLIB_LIBRARIES})
 174                 set(ZLIB_INCLUDE_DIRS ${LWS_ZLIB_INCLUDE_DIRS})
 175                 set(ZLIB_FOUND 1)
 176         endif()
 177 endif()
 178
 179 if (LWS_WITH_LIBEV)
 180         if ("${LWS_LIBEV_LIBRARIES}" STREQUAL "" OR "${LWS_LIBEV_INCLUDE_DIRS}" STREQUAL "")
 181         else()
 182                 set(LIBEV_LIBRARIES ${LWS_LIBEV_LIBRARIES})
 183                 set(LIBEV_INCLUDE_DIRS ${LWS_LIBEV_INCLUDE_DIRS})
 184                 set(LIBEV_FOUND 1)
 185         endif()
 186 endif()
 187
 188 # FIXME: This must be runtime-only option.
 189 # The base dir where the test-apps look for the SSL certs.
 190 set(LWS_OPENSSL_CLIENT_CERTS ../share CACHE PATH "Server SSL certificate directory")
 191 if (WIN32)
 192         set(LWS_OPENSSL_CLIENT_CERTS . CACHE PATH "Client SSL certificate directory")
 193
 194         if (LWS_IPV6)
 195                 set(LWS_IPV6 OFF)
 196                 message(WARNING "IPv6 does not currently work on Windows!")
 197         endif()
 198 else()
 199         set(LWS_OPENSSL_CLIENT_CERTS /etc/pki/tls/certs/ CACHE PATH "Client SSL certificate directory")
 200 endif()
 201
 202 if (LWS_WITHOUT_EXTENSIONS)
 203         set(LWS_NO_EXTENSIONS 1)
 204 endif()
 205
 206 if (LWS_WITH_SSL)
 207         set(LWS_OPENSSL_SUPPORT 1)
 208 endif()
 209
 210 if (LWS_SSL_CLIENT_USE_OS_CA_CERTS)
 211         set(LWS_SSL_CLIENT_USE_OS_CA_CERTS 1)
 212 endif()
 213
 214 if (LWS_WITH_LATENCY)
 215         set(LWS_LATENCY 1)
 216 endif()
 217
 218 if (LWS_WITHOUT_DAEMONIZE OR WIN32)
 219         set(LWS_NO_DAEMONIZE 1)
 220 endif()
 221
 222 if (LWS_WITHOUT_SERVER)
 223         set(LWS_NO_SERVER 1)
 224 endif()
 225
 226 if (LWS_WITHOUT_CLIENT)
 227         set(LWS_NO_CLIENT 1)
 228 endif()
 229
 230 if (LWS_WITH_LIBEV)
 231         set(LWS_USE_LIBEV 1)
 232 endif()
 233
 234 if (LWS_IPV6)
 235         set(LWS_USE_IPV6 1)
 236 endif()
 237
 238 if (LWS_WITH_HTTP2)
 239         set(LWS_USE_HTTP2 1)
 240 endif()
 241
 242 if (LWS_MBED3)
 243         set(CMAKE_C_FLAGS "-D_DEBUG ${CMAKE_C_FLAGS}")
 244 endif()
 245
 246 if (MINGW)
 247         set(LWS_MINGW_SUPPORT 1)
 248         set(CMAKE_C_FLAGS "-D__USE_MINGW_ANSI_STDIO ${CMAKE_C_FLAGS}")
 249 endif()
 250
 251 include_directories("${PROJECT_BINARY_DIR}")
 252
 253 include(CheckCSourceCompiles)
 254
 255 # Check for different inline keyword versions.
 256 foreach(KEYWORD "inline" "__inline__" "__inline")
 257         set(CMAKE_REQUIRED_DEFINITIONS "-DKEYWORD=${KEYWORD}")
 258         CHECK_C_SOURCE_COMPILES(
 259                 "
 260                 #include <stdio.h>
 261                 static KEYWORD void a() {}
 262                 int main(int argc, char **argv) { a(); return 0; }
 263                 " LWS_HAVE_${KEYWORD})
 264 endforeach()
 265
 266 if (NOT LWS_HAVE_inline)
 267         if (LWS_HAVE___inline__)
 268                 set(inline __inline__)
 269         elseif(LWS_HAVE___inline)
 270                 set(inline __inline)
 271         endif()
 272 endif()
 273
 274 # Put the libaries and binaries that get built into directories at the
 275 # top of the build tree rather than in hard-to-find leaf directories.
 276 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin")
 277 SET(CMAKE_LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/lib")
 278 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/lib")
 279
 280 # Put absolute path of dynamic libraries into the object code. Some
 281 # architectures, notably Mac OS X, need this.
 282 SET(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}")
 283
 284 include(CheckFunctionExists)
 285 include(CheckIncludeFile)
 286 include(CheckIncludeFiles)
 287 include(CheckLibraryExists)
 288 include(CheckTypeSize)
 289
 290 if (LWS_WITHOUT_BUILTIN_SHA1)
 291         set(LWS_SHA1_USE_OPENSSL_NAME 1)
 292 endif()
 293
 294 CHECK_FUNCTION_EXISTS(bzero LWS_HAVE_BZERO)
 295 CHECK_FUNCTION_EXISTS(fork LWS_HAVE_FORK)
 296 CHECK_FUNCTION_EXISTS(getenv LWS_HAVE_GETENV)
 297 CHECK_FUNCTION_EXISTS(malloc LWS_HAVE_MALLOC)
 298 CHECK_FUNCTION_EXISTS(memset LWS_HAVE_MEMSET)
 299 CHECK_FUNCTION_EXISTS(realloc LWS_HAVE_REALLOC)
 300 CHECK_FUNCTION_EXISTS(socket LWS_HAVE_SOCKET)
 301 CHECK_FUNCTION_EXISTS(strerror LWS_HAVE_STRERROR)
 302 CHECK_FUNCTION_EXISTS(vfork LWS_HAVE_VFORK)
 303 CHECK_FUNCTION_EXISTS(getifaddrs LWS_HAVE_GETIFADDRS)
 304
 305 if (NOT LWS_HAVE_GETIFADDRS)
 306         if (LWS_WITHOUT_BUILTIN_GETIFADDRS)
 307                 message(FATAL_ERROR "No getifaddrs was found on the system. Turn off the LWS_WITHOUT_BUILTIN_GETIFADDRS compile option to use the supplied BSD version.")
 308         endif()
 309         set(LWS_BUILTIN_GETIFADDRS 1)
 310 endif()
 311
 312 CHECK_INCLUDE_FILE(dlfcn.h LWS_HAVE_DLFCN_H)
 313 CHECK_INCLUDE_FILE(fcntl.h LWS_HAVE_FCNTL_H)
 314 CHECK_INCLUDE_FILE(in6addr.h LWS_HAVE_IN6ADDR_H)
 315 CHECK_INCLUDE_FILE(inttypes.h LWS_HAVE_INTTYPES_H)
 316 CHECK_INCLUDE_FILE(memory.h LWS_HAVE_MEMORY_H)
 317 CHECK_INCLUDE_FILE(netinet/in.h LWS_HAVE_NETINET_IN_H)
 318 CHECK_INCLUDE_FILE(stdint.h LWS_HAVE_STDINT_H)
 319 CHECK_INCLUDE_FILE(stdlib.h LWS_HAVE_STDLIB_H)
 320 CHECK_INCLUDE_FILE(strings.h LWS_HAVE_STRINGS_H)
 321 CHECK_INCLUDE_FILE(string.h LWS_HAVE_STRING_H)
 322 CHECK_INCLUDE_FILE(sys/prctl.h LWS_HAVE_SYS_PRCTL_H)
 323 CHECK_INCLUDE_FILE(sys/socket.h LWS_HAVE_SYS_SOCKET_H)
 324 CHECK_INCLUDE_FILE(sys/stat.h LWS_HAVE_SYS_STAT_H)
 325 CHECK_INCLUDE_FILE(sys/types.h LWS_HAVE_SYS_TYPES_H)
 326 CHECK_INCLUDE_FILE(unistd.h LWS_HAVE_UNISTD_H)
 327 CHECK_INCLUDE_FILE(vfork.h LWS_HAVE_VFORK_H)
 328
 329 if (LWS_WITH_ZLIB AND NOT LWS_USE_BUNDLED_ZLIB)
 330         CHECK_INCLUDE_FILE(zlib.h LWS_HAVE_ZLIB_H)
 331 endif()
 332
 333 # TODO: These can also be tested to see whether they actually work...
 334 set(LWS_HAVE_WORKING_FORK LWS_HAVE_FORK)
 335 set(LWS_HAVE_WORKING_VFORK LWS_HAVE_VFORK)
 336
 337 CHECK_INCLUDE_FILES("stdlib.h;stdarg.h;string.h;float.h" STDC_HEADERS)
 338
 339 # These don't work Cross...
 340 #CHECK_TYPE_SIZE(pid_t PID_T_SIZE)
 341 #CHECK_TYPE_SIZE(size_t SIZE_T_SIZE)
 342 #CHECK_TYPE_SIZE("void *" LWS_SIZEOFPTR LANGUAGE C)
 343
 344 if (NOT PID_T_SIZE)
 345         set(pid_t int)
 346 endif()
 347
 348 if (NOT SIZE_T_SIZE)
 349         set(size_t "unsigned int")
 350 endif()
 351
 352 if (NOT LWS_HAVE_MALLOC)
 353         set(malloc rpl_malloc)
 354 endif()
 355
 356 if (NOT LWS_HAVE_REALLOC)
 357         set(realloc rpl_realloc)
 358 endif()
 359
 360 # Generate the lws_config.h that includes all the public compilation settings.
 361 configure_file(
 362        "${PROJECT_SOURCE_DIR}/lws_config.h.in"
 363        "${PROJECT_BINARY_DIR}/lws_config.h")
 364
 365 # Generate the lws_config.h that includes all the private compilation settings.
 366 configure_file(
 367        "${PROJECT_SOURCE_DIR}/lws_config_private.h.in"
 368        "${PROJECT_BINARY_DIR}/lws_config_private.h")
 369
 370 if (MSVC)
 371         # Turn off stupid microsoft security warnings.
 372         add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
 373 endif(MSVC)
 374
 375 include_directories("${PROJECT_SOURCE_DIR}/lib")
 376
 377 # Group headers and sources.
 378 # Some IDEs use this for nicer file structure.
 379 set(HDR_PRIVATE
 380         lib/private-libwebsockets.h)
 381
 382 set(HDR_PUBLIC
 383         "${PROJECT_SOURCE_DIR}/lib/libwebsockets.h"
 384         "${PROJECT_BINARY_DIR}/lws_config.h")
 385
 386 set(SOURCES
 387         lib/base64-decode.c
 388         lib/handshake.c
 389         lib/libwebsockets.c
 390         lib/service.c
 391         lib/pollfd.c
 392         lib/output.c
 393         lib/parsers.c
 394         lib/context.c
 395         lib/alloc.c
 396         lib/header.c)
 397
 398 if (NOT LWS_WITHOUT_CLIENT)
 399         list(APPEND SOURCES
 400                 lib/client.c
 401                 lib/client-handshake.c
 402                 lib/client-parser.c)
 403 endif()
 404
 405 if (LWS_WITH_SSL)
 406         list(APPEND SOURCES
 407                 lib/ssl.c)
 408 endif()
 409
 410 if (NOT LWS_WITHOUT_BUILTIN_SHA1)
 411         list(APPEND SOURCES
 412                 lib/sha-1.c)
 413 endif()
 414
 415 if (LWS_WITH_HTTP2)
 416         list(APPEND SOURCES
 417                 lib/http2.c
 418                 lib/hpack.c
 419                 lib/ssl-http2.c)
 420 endif()
 421 # select the active platform files
 422
 423 if (WIN32)
 424         list(APPEND SOURCES
 425                 lib/lws-plat-win.c)
 426 else()
 427         if (LWS_MBED3)
 428                 list(APPEND SOURCES
 429                         lib/lws-plat-mbed3.cpp
 430                         lib/lws-plat-mbed3.c)
 431         else()
 432                 list(APPEND SOURCES
 433                         lib/lws-plat-unix.c)
 434         endif()
 435 endif()
 436
 437 if (NOT LWS_WITHOUT_SERVER)
 438         list(APPEND SOURCES
 439                 lib/server.c
 440                 lib/server-handshake.c)
 441 endif()
 442
 443 if (NOT LWS_WITHOUT_EXTENSIONS)
 444         list(APPEND HDR_PRIVATE
 445                 lib/extension-deflate-frame.h
 446                 lib/extension-deflate-stream.h)
 447         list(APPEND SOURCES
 448                 lib/extension.c
 449                 lib/extension-deflate-frame.c
 450                 lib/extension-deflate-stream.c)
 451 endif()
 452
 453 if (LWS_WITH_LIBEV)
 454         list(APPEND SOURCES
 455                 lib/libev.c)
 456 endif(LWS_WITH_LIBEV)
 457
 458 # Add helper files for Windows.
 459 if (WIN32)
 460         set(WIN32_HELPERS_PATH win32port/win32helpers)
 461         include_directories(${WIN32_HELPERS_PATH})
 462 else()
 463         # Unix.
 464         if (NOT LWS_WITHOUT_DAEMONIZE)
 465                 list(APPEND SOURCES
 466                         lib/daemonize.c)
 467         endif()
 468 endif()
 469
 470 if (UNIX)
 471         if (NOT LWS_HAVE_GETIFADDRS)
 472                 list(APPEND HDR_PRIVATE lib/getifaddrs.h)
 473                 list(APPEND SOURCES lib/getifaddrs.c)
 474         endif()
 475 endif()
 476
 477 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
 478     include (CheckCCompilerFlag)
 479     CHECK_C_COMPILER_FLAG(-fvisibility=hidden LWS_HAVE_VISIBILITY)
 480     if (LWS_HAVE_VISIBILITY)
 481                 set(VISIBILITY_FLAG -fvisibility=hidden)
 482     endif()
 483     if (UNIX)
 484                set(CMAKE_C_FLAGS "-Wall -Werror ${VISIBILITY_FLAG} ${CMAKE_C_FLAGS}" )
 485     else(UNIX)
 486                set(CMAKE_C_FLAGS "-Wall ${VISIBILITY_FLAG} ${CMAKE_C_FLAGS}" )
 487     endif(UNIX)
 488 endif ()
 489
 490 source_group("Headers Private"  FILES ${HDR_PRIVATE})
 491 source_group("Headers Public"   FILES ${HDR_PUBLIC})
 492 source_group("Sources"          FILES ${SOURCES})
 493
 494 #
 495 # Create the lib.
 496 #
 497 set(LWS_LIBRARIES)
 498
 499 if (LWS_WITH_STATIC)
 500         add_library(websockets STATIC
 501                                 ${HDR_PRIVATE}
 502                                 ${HDR_PUBLIC}
 503                                 ${SOURCES})
 504         list(APPEND LWS_LIBRARIES websockets)
 505
 506         if (WIN32)
 507                 # Windows uses the same .lib ending for static libraries and shared
 508                 # library linker files, so rename the static library.
 509                 set_target_properties(websockets
 510                         PROPERTIES
 511                         OUTPUT_NAME websockets_static)
 512         endif()
 513 endif()
 514
 515 if (LWS_WITH_SHARED)
 516         add_library(websockets_shared SHARED
 517                                 ${HDR_PRIVATE}
 518                                 ${HDR_PUBLIC}
 519                                 ${SOURCES})
 520         list(APPEND LWS_LIBRARIES websockets_shared)
 521
 522         # We want the shared lib to be named "libwebsockets"
 523         # not "libwebsocket_shared".
 524         set_target_properties(websockets_shared
 525                 PROPERTIES
 526                 OUTPUT_NAME websockets)
 527
 528         if (WIN32)
 529                 # Compile as DLL (export function declarations)
 530                 set_property(
 531                         TARGET websockets_shared
 532                         PROPERTY COMPILE_DEFINITIONS
 533                         LWS_DLL
 534                         LWS_INTERNAL)
 535         endif()
 536
 537         if (APPLE)
 538                 set_property(TARGET websockets_shared PROPERTY MACOSX_RPATH YES)
 539         endif()
 540 endif()
 541
 542 # Set the so version of the lib.
 543 # Equivalent to LDFLAGS=-version-info x:x:x
 544 if(CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
 545         foreach(lib ${LWS_LIBRARIES})
 546                 set_target_properties(${lib}
 547                         PROPERTIES
 548                         SOVERSION ${SOVERSION})
 549         endforeach()
 550 endif()
 551
 552 set(LIB_LIST)
 553
 554 #
 555 # Find libraries.
 556 #
 557
 558 #
 559 # ZLIB (Only needed for deflate extensions).
 560 #
 561 if (LWS_WITH_ZLIB)
 562         if (LWS_USE_BUNDLED_ZLIB)
 563                 if (WIN32)
 564                         set(WIN32_ZLIB_PATH "win32port/zlib")
 565                         set(ZLIB_SRCS
 566                                 ${WIN32_ZLIB_PATH}/adler32.c
 567                                 ${WIN32_ZLIB_PATH}/compress.c
 568                                 ${WIN32_ZLIB_PATH}/crc32.c
 569                                 ${WIN32_ZLIB_PATH}/deflate.c
 570                                 ${WIN32_ZLIB_PATH}/gzclose.c
 571                                 ${WIN32_ZLIB_PATH}/gzio.c
 572                                 ${WIN32_ZLIB_PATH}/gzlib.c
 573                                 ${WIN32_ZLIB_PATH}/gzread.c
 574                                 ${WIN32_ZLIB_PATH}/gzwrite.c
 575                                 ${WIN32_ZLIB_PATH}/infback.c
 576                                 ${WIN32_ZLIB_PATH}/inffast.c
 577                                 ${WIN32_ZLIB_PATH}/inflate.c
 578                                 ${WIN32_ZLIB_PATH}/inftrees.c
 579                                 ${WIN32_ZLIB_PATH}/trees.c
 580                                 ${WIN32_ZLIB_PATH}/uncompr.c
 581                                 ${WIN32_ZLIB_PATH}/zutil.c)
 582                         add_library(zlib_internal STATIC ${ZLIB_SRCS})
 583                         set(ZLIB_INCLUDE_DIRS ${WIN32_ZLIB_PATH})
 584                         get_property(ZLIB_LIBRARIES TARGET zlib_internal PROPERTY LOCATION)
 585                         set(ZLIB_FOUND 1)
 586                         # Make sure zlib_internal is compiled before the libs.
 587                         foreach (lib ${LWS_LIBRARIES})
 588                                 add_dependencies(${lib} zlib_internal)
 589                         endforeach()
 590                 else()
 591                         message(FATAL_ERROR "Don't have bundled zlib for that platform")
 592                 endif()
 593         elseif (NOT ZLIB_FOUND)
 594                 find_package(ZLIB REQUIRED)
 595         endif()
 596         message("zlib include dirs: ${ZLIB_INCLUDE_DIRS}")
 597         message("zlib libraries: ${ZLIB_LIBRARIES}")
 598         include_directories(${ZLIB_INCLUDE_DIRS})
 599         list(APPEND LIB_LIST ${ZLIB_LIBRARIES})
 600 endif()
 601
 602 #
 603 # OpenSSL
 604 #
 605 if (LWS_WITH_SSL)
 606         message("Compiling with SSL support")
 607
 608         if (LWS_USE_WOLFSSL)
 609                 # Use wolfSSL as OpenSSL replacement.
 610                 # TODO: Add a find_package command for this also.
 611                 message("wolfSSL include dir: ${WOLFSSL_INCLUDE_DIRS}")
 612                 message("wolfSSL libraries: ${WOLFSSL_LIBRARIES}")
 613
 614                 # Additional to the root directory we need to include
 615                 # the wolfssl/ subdirectory which contains the OpenSSL
 616                 # compatability layer headers.
 617
 618                 if (LWS_USE_CYASSL)
 619                         foreach(inc ${WOLFSSL_INCLUDE_DIRS})
 620                                 include_directories("${inc}" "${inc}/cyassl")
 621                         endforeach()
 622                 else()
 623                         foreach(inc ${WOLFSSL_INCLUDE_DIRS})
 624                                 include_directories("${inc}" "${inc}/wolfssl")
 625                         endforeach()
 626                 endif()
 627
 628                 list(APPEND LIB_LIST "${WOLFSSL_LIBRARIES}")
 629         else()
 630                 if (NOT OPENSSL_FOUND)
 631                         # TODO: Add support for STATIC also.
 632                         find_package(OpenSSL REQUIRED)
 633                         set(OPENSSL_INCLUDE_DIRS "${OPENSSL_INCLUDE_DIR}")
 634                 endif()
 635
 636                 message("OpenSSL include dir: ${OPENSSL_INCLUDE_DIRS}")
 637                 message("OpenSSL libraries: ${OPENSSL_LIBRARIES}")
 638
 639                 include_directories("${OPENSSL_INCLUDE_DIRS}")
 640                 list(APPEND LIB_LIST ${OPENSSL_LIBRARIES})
 641         endif()
 642 endif(LWS_WITH_SSL)
 643
 644 if (LWS_WITH_LIBEV)
 645         if (NOT LIBEV_FOUND)
 646                 find_path(LIBEV_INCLUDE_DIRS NAMES ev.h)
 647                 find_library(LIBEV_LIBRARIES NAMES ev)
 648                 if(LIBEV_INCLUDE_DIRS AND LIBEV_LIBRARIES)
 649                         set(LIBEV_FOUND 1)
 650                 endif()
 651         endif()
 652         message("libev include dir: ${LIBEV_INCLUDE_DIRS}")
 653         message("libev libraries: ${LIBEV_LIBRARIES}")
 654         include_directories("${LIBEV_INCLUDE_DIRS}")
 655         list(APPEND LIB_LIST ${LIBEV_LIBRARIES})
 656 endif(LWS_WITH_LIBEV)
 657
 658 #
 659 # Platform specific libs.
 660 #
 661 if (WINCE)
 662         list(APPEND LIB_LIST ws2.lib)
 663 elseif (WIN32)
 664         list(APPEND LIB_LIST ws2_32.lib)
 665 endif()
 666
 667 if (UNIX)
 668         list(APPEND LIB_LIST m)
 669 endif()
 670
 671 # Setup the linking for all libs.
 672 foreach (lib ${LWS_LIBRARIES})
 673         target_link_libraries(${lib} ${LIB_LIST})
 674 endforeach()
 675
 676 #
 677 # Test applications
 678 #
 679 set(TEST_APP_LIST)
 680 if (NOT LWS_WITHOUT_TESTAPPS)
 681         #
 682         # Helper function for adding a test app.
 683         #
 684         macro(create_test_app TEST_NAME MAIN_SRC)
 685
 686                 set(TEST_SRCS ${MAIN_SRC})
 687                 set(TEST_HDR)
 688
 689                 if (WIN32)
 690                         list(APPEND TEST_SRCS
 691                                 ${WIN32_HELPERS_PATH}/getopt.c
 692                                 ${WIN32_HELPERS_PATH}/getopt_long.c
 693                                 ${WIN32_HELPERS_PATH}/gettimeofday.c
 694                         )
 695
 696                         list(APPEND TEST_HDR
 697                                 ${WIN32_HELPERS_PATH}/getopt.h
 698                                 ${WIN32_HELPERS_PATH}/gettimeofday.h
 699                         )
 700                 endif(WIN32)
 701
 702                 source_group("Headers Private"   FILES ${TEST_HDR})
 703                 source_group("Sources"   FILES ${TEST_SRCS})
 704                 add_executable(${TEST_NAME} ${TEST_SRCS} ${TEST_HDR})
 705
 706                 if (LWS_LINK_TESTAPPS_DYNAMIC)
 707                         if (NOT LWS_WITH_SHARED)
 708                                 message(FATAL_ERROR "Build of the shared library is disabled. LWS_LINK_TESTAPPS_DYNAMIC must be combined with LWS_WITH_SHARED.")
 709                         endif()
 710                         target_link_libraries(${TEST_NAME} websockets_shared)
 711                         add_dependencies(${TEST_NAME} websockets_shared)
 712                 else()
 713                         if (NOT LWS_WITH_STATIC)
 714                                 message(FATAL_ERROR "Build of the static library is disabled. Disabled LWS_LINK_TESTAPPS_DYNAMIC must be combined with LWS_WITH_STATIC.")
 715                         endif()
 716                         target_link_libraries(${TEST_NAME} websockets)
 717                         add_dependencies(${TEST_NAME} websockets)
 718                 endif()
 719
 720                 # Set test app specific defines.
 721                 set_property(TARGET ${TEST_NAME}
 722                                         PROPERTY COMPILE_DEFINITIONS
 723                                                 INSTALL_DATADIR="${CMAKE_INSTALL_PREFIX}/share"
 724                                         )
 725
 726                 # Prefix the binary names with libwebsockets.
 727                 set_target_properties(${TEST_NAME}
 728                         PROPERTIES
 729                         OUTPUT_NAME libwebsockets-${TEST_NAME})
 730
 731                 # Add to the list of tests.
 732                 list(APPEND TEST_APP_LIST ${TEST_NAME})
 733         endmacro()
 734
 735         if (LWS_WITH_SSL AND NOT LWS_USE_WOLFSSL)
 736                 message("Searching for OpenSSL executable and dlls")
 737                 find_package(OpenSSLbins)
 738                 message("OpenSSL executable: ${OPENSSL_EXECUTABLE}")
 739         endif()
 740
 741         if (NOT LWS_WITHOUT_SERVER)
 742                 #
 743                 # test-server
 744                 #
 745                 if (NOT LWS_WITHOUT_TEST_SERVER)
 746                         create_test_app(test-server "test-server/test-server.c")
 747                 endif()
 748
 749                 #
 750                 # test-server-extpoll
 751                 #
 752                 if (NOT LWS_WITHOUT_TEST_SERVER_EXTPOLL)
 753                         create_test_app(test-server-extpoll "test-server/test-server.c")
 754                         # Set defines for this executable only.
 755                         set_property(
 756                                 TARGET test-server-extpoll
 757                                 PROPERTY COMPILE_DEFINITIONS
 758                                         EXTERNAL_POLL
 759                                         INSTALL_DATADIR="${CMAKE_INSTALL_PREFIX}/share"
 760                                 )
 761
 762                         # We need to link against winsock code.
 763                         if (WIN32)
 764                                 target_link_libraries(test-server-extpoll ws2_32.lib)
 765                         endif(WIN32)
 766                 endif()
 767
 768                 # Data files for running the test server.
 769                 set(TEST_SERVER_DATA
 770                         "${PROJECT_SOURCE_DIR}/test-server/favicon.ico"
 771                         "${PROJECT_SOURCE_DIR}/test-server/leaf.jpg"
 772                         "${PROJECT_SOURCE_DIR}/test-server/libwebsockets.org-logo.png"
 773                         "${PROJECT_SOURCE_DIR}/test-server/test.html")
 774
 775                 # Generate self-signed SSL certs for the test-server.
 776                 if (LWS_WITH_SSL AND OPENSSL_EXECUTABLE AND NOT LWS_WITHOUT_TEST_SERVER)
 777                         message("Generating SSL Certificates for the test-server...")
 778
 779                         set(TEST_SERVER_SSL_KEY "${PROJECT_BINARY_DIR}/libwebsockets-test-server.key.pem")
 780                         set(TEST_SERVER_SSL_CERT "${PROJECT_BINARY_DIR}/libwebsockets-test-server.pem")
 781
 782                         if (WIN32)
 783                                 if (MINGW)
 784                                         message("cmd = \"${OPENSSL_EXECUTABLE}\" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -subj \"/C=GB/ST=Erewhon/L=All around/O=libwebsockets-test/CN=localhost\" -keyout \"${TEST_SERVER_SSL_KEY}\" -out \"${TEST_SERVER_SSL_CERT}\"")
 785                                         execute_process(
 786                                                 COMMAND "${OPENSSL_EXECUTABLE}" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -subj "/C=GB/ST=Erewhon/L=All around/O=libwebsockets-test/CN=localhost" -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 787                                                 RESULT_VARIABLE OPENSSL_RETURN_CODE)
 788                                 else()
 789                                         file(WRITE "${PROJECT_BINARY_DIR}/openssl_input.txt"
 790                                                 "GB\n"
 791                                                 "Erewhon\n"
 792                                                 "All around\n"
 793                                                 "libwebsockets-test\n"
 794                                                 "localhost\n"
 795                                                 "none@invalid.org\n\n"
 796                                                 )
 797
 798                                         # The "type" command is a bit picky with paths.
 799                                         file(TO_NATIVE_PATH "${PROJECT_BINARY_DIR}/openssl_input.txt" OPENSSL_INPUT_WIN_PATH)
 800                                         message("OPENSSL_INPUT_WIN_PATH = ${OPENSSL_INPUT_WIN_PATH}")
 801                                         message("cmd = \"${OPENSSL_EXECUTABLE}\" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout \"${TEST_SERVER_SSL_KEY}\" -out \"${TEST_SERVER_SSL_CERT}\"")
 802
 803                                         execute_process(
 804                                                 COMMAND cmd /c type "${OPENSSL_INPUT_WIN_PATH}"
 805                                                 COMMAND "${OPENSSL_EXECUTABLE}" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 806                                                 RESULT_VARIABLE OPENSSL_RETURN_CODE
 807                                                 OUTPUT_QUIET ERROR_QUIET)
 808
 809                                         message("\n")
 810                                 endif()
 811
 812                                 if (OPENSSL_RETURN_CODE)
 813                                         message(WARNING "!!! Failed to generate SSL certificate for Test Server using cmd.exe !!!:\nOpenSSL return code = ${OPENSSL_RETURN_CODE}")
 814                                 else()
 815                                         message("SUCCSESFULLY generated SSL certificate")
 816                                 endif()
 817                         else()
 818                                 # Unix.
 819                                 execute_process(
 820                                         COMMAND printf "GB\\nErewhon\\nAll around\\nlibwebsockets-test\\n\\nlocalhost\\nnone@invalid.org\\n"
 821                                         COMMAND "${OPENSSL_EXECUTABLE}"
 822                                                 req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 823                                         RESULT_VARIABLE OPENSSL_RETURN_CODE
 824                                         OUTPUT_QUIET ERROR_QUIET)
 825
 826                                 if (OPENSSL_RETURN_CODE)
 827                                         message(WARNING "!!! Failed to generate SSL certificate for Test Server!!!:\nOpenSSL return code = ${OPENSSL_RETURN_CODE}")
 828                                 else()
 829                                         message("SUCCESSFULLY generated SSL certificate")
 830                                 endif()
 831                         endif()
 832
 833                         list(APPEND TEST_SERVER_DATA
 834                                 "${TEST_SERVER_SSL_KEY}"
 835                                 "${TEST_SERVER_SSL_CERT}")
 836                 endif()
 837
 838                 add_custom_command(TARGET test-server
 839                                                 POST_BUILD
 840                                                 COMMAND "${CMAKE_COMMAND}" -E make_directory "$<TARGET_FILE_DIR:test-server>/../share/libwebsockets-test-server")
 841
 842                 # Copy the file needed to run the server so that the test apps can
 843                 # reach them from their default output location
 844                 foreach (TEST_FILE ${TEST_SERVER_DATA})
 845                         if (EXISTS ${TEST_FILE})
 846                                 add_custom_command(TARGET test-server
 847                                                         POST_BUILD
 848                                                         COMMAND "${CMAKE_COMMAND}" -E copy "${TEST_FILE}" "$<TARGET_FILE_DIR:test-server>/../share/libwebsockets-test-server" VERBATIM)
 849                         endif()
 850                 endforeach()
 851         endif(NOT LWS_WITHOUT_SERVER)
 852
 853         if (NOT LWS_WITHOUT_CLIENT)
 854                 #
 855                 # test-client
 856                 #
 857                 if (NOT LWS_WITHOUT_TEST_CLIENT)
 858                         create_test_app(test-client "test-server/test-client.c")
 859                 endif()
 860
 861                 #
 862                 # test-fraggle
 863                 #
 864                 if (NOT LWS_WITHOUT_TEST_FRAGGLE)
 865                         create_test_app(test-fraggle "test-server/test-fraggle.c")
 866                 endif()
 867
 868                 #
 869                 # test-ping
 870                 #
 871                 if (NOT LWS_WITHOUT_TEST_PING)
 872                         create_test_app(test-ping "test-server/test-ping.c")
 873                 endif()
 874                 #
 875                 # test-echo
 876                 #
 877                 if (NOT WITHOUT_TEST_ECHO)
 878                         create_test_app(test-echo "test-server/test-echo.c")
 879                 endif()
 880
 881         endif(NOT LWS_WITHOUT_CLIENT)
 882
 883         #
 884         # Copy OpenSSL dlls to the output directory on Windows.
 885         # (Otherwise we'll get an error when trying to run)
 886         #
 887         if (WIN32 AND LWS_WITH_SSL AND NOT LWS_USE_WOLFSSL)
 888                 if(OPENSSL_BIN_FOUND)
 889                         message("OpenSSL dlls found:")
 890                         message("  Libeay: ${LIBEAY_BIN}")
 891                         message("  SSLeay: ${SSLEAY_BIN}")
 892
 893                         foreach(TARGET_BIN ${TEST_APP_LIST})
 894                                 add_custom_command(TARGET ${TARGET_BIN}
 895                                         POST_BUILD
 896                                         COMMAND "${CMAKE_COMMAND}" -E copy "${LIBEAY_BIN}" "$<TARGET_FILE_DIR:${TARGET_BIN}>" VERBATIM)
 897                                 add_custom_command(TARGET ${TARGET_BIN}
 898                                         POST_BUILD
 899                                         COMMAND "${CMAKE_COMMAND}" -E copy "${SSLEAY_BIN}" "$<TARGET_FILE_DIR:${TARGET_BIN}>" VERBATIM)
 900                         endforeach()
 901                 endif()
 902         endif()
 903 endif(NOT LWS_WITHOUT_TESTAPPS)
 904
 905 if (UNIX)
 906         # Generate documentation.
 907         # TODO: Fix this on Windows.
 908         message("Generating API documentation")
 909         file(GLOB C_FILES "${PROJECT_SOURCE_DIR}/lib/*.c")
 910         execute_process(COMMAND "${CMAKE_COMMAND}" -E make_directory "${PROJECT_BINARY_DIR}/doc/")
 911
 912         execute_process(
 913                 COMMAND "${PROJECT_SOURCE_DIR}/scripts/kernel-doc" -html ${C_FILES} ${HDR_PUBLIC}
 914                 OUTPUT_FILE "${PROJECT_BINARY_DIR}/doc/libwebsockets-api-doc.html"
 915                 ERROR_QUIET)
 916
 917         execute_process(
 918                 COMMAND "${PROJECT_SOURCE_DIR}/scripts/kernel-doc" -text ${C_FILES} ${HDR_PUBLIC}
 919                 OUTPUT_FILE "${PROJECT_BINARY_DIR}/doc/libwebsockets-api-doc.txt"
 920                 ERROR_QUIET)
 921
 922 # Generate and install pkgconfig.
 923 # (This is not indented, because the tabs will be part of the output)
 924 file(WRITE "${PROJECT_BINARY_DIR}/libwebsockets.pc"
 925 "prefix=\"${CMAKE_INSTALL_PREFIX}\"
 926 exec_prefix=\${prefix}
 927 libdir=\${exec_prefix}/lib${LIB_SUFFIX}
 928 includedir=\${prefix}/include
 929
 930 Name: libwebsockets
 931 Description: Websockets server and client library
 932 Version: ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}
 933
 934 Libs: -L\${libdir} -lwebsockets
 935 Cflags: -I\${includedir}"
 936 )
 937
 938         install(FILES "${PROJECT_BINARY_DIR}/libwebsockets.pc"
 939                 DESTINATION lib${LIB_SUFFIX}/pkgconfig)
 940 endif(UNIX)
 941
 942 #
 943 # Installation preparations.
 944 #
 945
 946 if(WIN32 AND NOT CYGWIN)
 947   set(DEF_INSTALL_CMAKE_DIR cmake)
 948 else()
 949   set(DEF_INSTALL_CMAKE_DIR lib/cmake/libwebsockets)
 950 endif()
 951
 952 set(LWS_INSTALL_CMAKE_DIR ${DEF_INSTALL_CMAKE_DIR} CACHE PATH "Installation directory for CMake files")
 953
 954 # Export targets (This is used for other CMake projects to easily find the libraries and include files).
 955 export(TARGETS ${LWS_LIBRARIES}
 956         FILE "${PROJECT_BINARY_DIR}/LibwebsocketsTargets.cmake")
 957 export(PACKAGE libwebsockets)
 958
 959 # Generate the config file for the build-tree.
 960 set(LWS__INCLUDE_DIRS
 961     "${PROJECT_SOURCE_DIR}/lib"
 962     "${PROJECT_BINARY_DIR}")
 963 set(LIBWEBSOCKETS_INCLUDE_DIRS ${LWS__INCLUDE_DIRS} CACHE PATH "Libwebsockets include directories")
 964 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfig.cmake.in
 965                 ${PROJECT_BINARY_DIR}/LibwebsocketsConfig.cmake
 966                 @ONLY)
 967
 968 # Generate the config file for the installation tree.
 969 get_filename_component(LWS_ABSOLUTE_INSTALL_CMAKE_DIR ${LWS_INSTALL_CMAKE_DIR} ABSOLUTE)
 970 get_filename_component(LWS_ABSOLUTE_INSTALL_INCLUDE_DIR ${LWS_INSTALL_INCLUDE_DIR} ABSOLUTE)
 971 file(RELATIVE_PATH
 972     REL_INCLUDE_DIR
 973     "${LWS_ABSOLUTE_INSTALL_CMAKE_DIR}"
 974     "${LWS_ABSOLUTE_INSTALL_INCLUDE_DIR}") # Calculate the relative directory from the cmake dir.
 975
 976 # Note the EVENT_CMAKE_DIR is defined in JanssonConfig.cmake.in,
 977 # we escape it here so it's evaluated when it is included instead
 978 # so that the include dirs are given relative to where the
 979 # config file is located.
 980 set(LWS__INCLUDE_DIRS
 981     "\${LWS_CMAKE_DIR}/${REL_INCLUDE_DIR}")
 982 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfig.cmake.in
 983                 ${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/LibwebsocketsConfig.cmake
 984                 @ONLY)
 985
 986 # Generate version info for both build-tree and install-tree.
 987 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfigVersion.cmake.in
 988                 ${PROJECT_BINARY_DIR}/LibwebsocketsConfigVersion.cmake
 989                 @ONLY)
 990
 991                         set_target_properties(${LWS_LIBRARIES}
 992                                         PROPERTIES PUBLIC_HEADER "${HDR_PUBLIC}")
 993
 994 #
 995 # Installation.
 996 #
 997
 998 # Install libs and headers.
 999 install(TARGETS ${LWS_LIBRARIES}
1000                 EXPORT LibwebsocketsTargets
1001                 LIBRARY DESTINATION "${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}" COMPONENT libraries
1002                 ARCHIVE DESTINATION "${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}" COMPONENT libraries
1003                 RUNTIME DESTINATION "${LWS_INSTALL_BIN_DIR}" COMPONENT libraries # Windows DLLs
1004                 PUBLIC_HEADER DESTINATION "${LWS_INSTALL_INCLUDE_DIR}" COMPONENT dev)
1005 set(CPACK_COMPONENT_LIBRARIES_DISPLAY_NAME "Libraries")
1006 set(CPACK_COMPONENT_DEV_DISPLAY_NAME "Development files")
1007
1008 # Install test apps.
1009 if (NOT LWS_WITHOUT_TESTAPPS AND NOT LWS_WITHOUT_CLIENT)
1010         install(TARGETS test-client ${TEST_APP_LIST}
1011                         RUNTIME DESTINATION ${LWS_INSTALL_EXAMPLES_DIR}
1012                         COMPONENT examples)
1013         set(CPACK_COMPONENT_EXAMPLES_DISPLAY_NAME "Example files")
1014 endif()
1015
1016 # Programs shared files used by the test-server.
1017 if (NOT LWS_WITHOUT_TESTAPPS AND NOT LWS_WITHOUT_SERVER)
1018         install(FILES ${TEST_SERVER_DATA}
1019                         DESTINATION share/libwebsockets-test-server
1020                         COMPONENT examples)
1021 endif()
1022
1023 # build subdir is not part of sources
1024 set(CPACK_SOURCE_IGNORE_FILES $(CPACK_SOURCE_IGNORE_FILES) ".git" "build" "tgz" "tar.gz")
1025
1026 # Most people are more used to "make dist" compared to "make package_source"
1027 add_custom_target(dist COMMAND "${CMAKE_MAKE_PROGRAM}" package_source)
1028
1029 include(UseRPMTools)
1030 if (RPMTools_FOUND)
1031         RPMTools_ADD_RPM_TARGETS(libwebsockets libwebsockets.spec)
1032 endif()
1033
1034 message("---------------------------------------------------------------------")
1035 message("  Settings:  (For more help do cmake -LH <srcpath>)")
1036 message("---------------------------------------------------------------------")
1037 message(" LWS_WITH_STATIC = ${LWS_WITH_STATIC}")
1038 message(" LWS_WITH_SHARED = ${LWS_WITH_SHARED}")
1039 message(" LWS_WITH_SSL = ${LWS_WITH_SSL} (SSL Support)")
1040 message(" LWS_SSL_CLIENT_USE_OS_CA_CERTS = ${LWS_SSL_CLIENT_USE_OS_CA_CERTS}")
1041 message(" LWS_USE_WOLFSSL = ${LWS_USE_WOLFSSL} (wolfSSL/CyaSSL replacement for OpenSSL)")
1042 if (LWS_USE_WOLFSSL)
1043         message("   LWS_WOLFSSL_LIBRARIES = ${LWS_WOLFSSL_LIBRARIES}")
1044         message("   LWS_WOLFSSL_INCLUDE_DIRS = ${LWS_WOLFSSL_INCLUDE_DIRS}")
1045 endif()
1046 message(" LWS_WITHOUT_BUILTIN_SHA1 = ${LWS_WITHOUT_BUILTIN_SHA1}")
1047 message(" LWS_WITHOUT_BUILTIN_GETIFADDRS = ${LWS_WITHOUT_BUILTIN_GETIFADDRS}")
1048 message(" LWS_WITHOUT_CLIENT = ${LWS_WITHOUT_CLIENT}")
1049 message(" LWS_WITHOUT_SERVER = ${LWS_WITHOUT_SERVER}")
1050 message(" LWS_LINK_TESTAPPS_DYNAMIC = ${LWS_LINK_TESTAPPS_DYNAMIC}")
1051 message(" LWS_WITHOUT_TESTAPPS = ${LWS_WITHOUT_TESTAPPS}")
1052 message(" LWS_WITHOUT_TEST_SERVER = ${LWS_WITHOUT_TEST_SERVER}")
1053 message(" LWS_WITHOUT_TEST_SERVER_EXTPOLL = ${LWS_WITHOUT_TEST_SERVER_EXTPOLL}")
1054 message(" LWS_WITHOUT_TEST_PING = ${LWS_WITHOUT_TEST_PING}")
1055 message(" LWS_WITHOUT_TEST_CLIENT = ${LWS_WITHOUT_TEST_CLIENT}")
1056 message(" LWS_WITHOUT_TEST_FRAGGLE = ${LWS_WITHOUT_TEST_FRAGGLE}")
1057 message(" LWS_WITHOUT_EXTENSIONS = ${LWS_WITHOUT_EXTENSIONS}")
1058 message(" LWS_WITH_LATENCY = ${LWS_WITH_LATENCY}")
1059 message(" LWS_WITHOUT_DAEMONIZE = ${LWS_WITHOUT_DAEMONIZE}")
1060 message(" LWS_USE_LIBEV = ${LWS_USE_LIBEV}")
1061 message(" LWS_IPV6 = ${LWS_IPV6}")
1062 message(" LWS_WITH_HTTP2 = ${LWS_WITH_HTTP2}")
1063 message(" LWS_MBED3 = ${LWS_MBED3}")
1064 message("---------------------------------------------------------------------")
1065
1066 # These will be available to parent projects including libwebsockets using add_subdirectory()
1067 set(LIBWEBSOCKETS_LIBRARIES ${LWS_LIBRARIES} CACHE STRING "Libwebsocket libraries")
1068 if (LWS_WITH_STATIC)
1069         set(LIBWEBSOCKETS_LIBRARIES_STATIC websocket CACHE STRING "Libwebsocket static library")
1070 endif()
1071 if (LWS_WITH_SHARED)
1072         set(LIBWEBSOCKETS_LIBRARIES_SHARED websockets_shared CACHE STRING "Libwebsocket shared library")
1073 endif()
1074
1075 # This must always be last!
1076 include(CPack)