CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 #
   8 #   - OCT-2008: Initial version <joseluisblancoc@gmail.com>
   9 #
  10 # ----------------------------------------------------------------------------
  11
  12 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  13
  14 # --------------------------------------------------------------
  15 # Indicate CMake 2.7 and above that we don't want to mix relative
  16 #  and absolute paths in linker lib lists.
  17 # Run "cmake --help-policy CMP0003" for more information.
  18 # --------------------------------------------------------------
  19 if(COMMAND cmake_policy)
  20   cmake_policy(SET CMP0003 NEW)
  21 endif()
  22
  23 # Following block can broke build in case of cross-compilng
  24 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  25 # so we will try to detect crosscompiling by presense of CMAKE_TOOLCHAIN_FILE
  26 if(NOT CMAKE_TOOLCHAIN_FILE)
  27   # it _must_ go before project(OpenCV) in order to work
  28   if(WIN32)
  29     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  30   else()
  31     set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  32   endif()
  33
  34   if(MSVC)
  35     set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
  36   endif()
  37 else(NOT CMAKE_TOOLCHAIN_FILE)
  38   #Android: set output folder to ${CMAKE_BINARY_DIR}
  39   set( LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  40   # any crosscompiling
  41   set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  42 endif(NOT CMAKE_TOOLCHAIN_FILE)
  43
  44 # --------------------------------------------------------------
  45 # Top level OpenCV project
  46 # --------------------------------------------------------------
  47 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  48   cmake_minimum_required(VERSION 2.8.8)
  49 elseif(IOS)
  50   cmake_minimum_required(VERSION 2.8.0)
  51 else()
  52   cmake_minimum_required(VERSION 2.6.3)
  53 endif()
  54
  55 # must go before the project command
  56 set(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  57 if(DEFINED CMAKE_BUILD_TYPE AND CMAKE_VERSION VERSION_GREATER "2.8")
  58   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
  59 endif()
  60
  61 project(OpenCV CXX C)
  62
  63 include(cmake/OpenCVUtils.cmake)
  64
  65 # ----------------------------------------------------------------------------
  66 # Break in case of popular CMake configuration mistakes
  67 # ----------------------------------------------------------------------------
  68 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
  69   message(FATAL_ERROR "CMake fails to deterimine the bitness of target platform.
  70   Please check your CMake and compiler installation. If you are crosscompiling then ensure that your CMake toolchain file correctly sets the compiler details.")
  71 endif()
  72
  73 # ----------------------------------------------------------------------------
  74 # Detect compiler and target platform architecture
  75 # ----------------------------------------------------------------------------
  76 include(cmake/OpenCVDetectCXXCompiler.cmake)
  77
  78 # Add these standard paths to the search paths for FIND_LIBRARY
  79 # to find libraries from these locations first
  80 if(UNIX AND NOT ANDROID)
  81   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
  82     if(EXISTS /lib64)
  83       list(APPEND CMAKE_LIBRARY_PATH /lib64)
  84     else()
  85       list(APPEND CMAKE_LIBRARY_PATH /lib)
  86     endif()
  87     if(EXISTS /usr/lib64)
  88       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
  89     else()
  90       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
  91     endif()
  92   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
  93     if(EXISTS /lib32)
  94       list(APPEND CMAKE_LIBRARY_PATH /lib32)
  95     else()
  96       list(APPEND CMAKE_LIBRARY_PATH /lib)
  97     endif()
  98     if(EXISTS /usr/lib32)
  99       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 100     else()
 101       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 102     endif()
 103   endif()
 104 endif()
 105
 106
 107 # ----------------------------------------------------------------------------
 108 # OpenCV cmake options
 109 # ----------------------------------------------------------------------------
 110
 111 # Optional 3rd party components
 112 # ===================================================
 113 OCV_OPTION(WITH_1394           "Include IEEE1394 support"                    ON   IF (UNIX AND NOT ANDROID AND NOT IOS) )
 114 OCV_OPTION(WITH_AVFOUNDATION   "Use AVFoundation for Video I/O"              ON   IF IOS)
 115 OCV_OPTION(WITH_CARBON         "Use Carbon for UI instead of Cocoa"          OFF  IF APPLE )
 116 OCV_OPTION(WITH_CUDA           "Include NVidia Cuda Runtime support"         ON   IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 117 OCV_OPTION(WITH_CUFFT          "Include NVidia Cuda Fast Fourier Transform (FFT) library support"            ON  IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 118 OCV_OPTION(WITH_CUBLAS         "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" OFF IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 119 OCV_OPTION(WITH_NVCUVID        "Include NVidia Video Decoding library support"                               OFF IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS AND NOT APPLE) )
 120 OCV_OPTION(WITH_EIGEN          "Include Eigen2/Eigen3 support"               ON)
 121 OCV_OPTION(WITH_FFMPEG         "Include FFMPEG support"                      ON   IF (NOT ANDROID AND NOT IOS))
 122 OCV_OPTION(WITH_GSTREAMER      "Include Gstreamer support"                   ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 123 OCV_OPTION(WITH_GTK            "Include GTK support"                         ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 124 OCV_OPTION(WITH_IPP            "Include Intel IPP support"                   OFF  IF (MSVC OR X86 OR X86_64) )
 125 OCV_OPTION(WITH_JASPER         "Include JPEG2K support"                      ON   IF (NOT IOS) )
 126 OCV_OPTION(WITH_JPEG           "Include JPEG support"                        ON   IF (NOT IOS) )
 127 OCV_OPTION(WITH_WEBP           "Include WebP support"                        ON   IF (NOT IOS) )
 128 OCV_OPTION(WITH_OPENEXR        "Include ILM support via OpenEXR"             ON   IF (NOT IOS) )
 129 OCV_OPTION(WITH_OPENGL         "Include OpenGL support"                      OFF  IF (NOT ANDROID AND NOT APPLE) )
 130 OCV_OPTION(WITH_OPENNI         "Include OpenNI support"                      OFF  IF (NOT ANDROID AND NOT IOS) )
 131 OCV_OPTION(WITH_PNG            "Include PNG support"                         ON   IF (NOT IOS) )
 132 OCV_OPTION(WITH_PVAPI          "Include Prosilica GigE support"              ON   IF (NOT ANDROID AND NOT IOS) )
 133 OCV_OPTION(WITH_GIGEAPI        "Include Smartek GigE support"                ON   IF (NOT ANDROID AND NOT IOS) )
 134 OCV_OPTION(WITH_QT             "Build with Qt Backend support"               OFF  IF (NOT ANDROID AND NOT IOS) )
 135 OCV_OPTION(WITH_QUICKTIME      "Use QuickTime for Video I/O insted of QTKit" OFF  IF APPLE )
 136 OCV_OPTION(WITH_TBB            "Include Intel TBB support"                   OFF  IF (NOT IOS) )
 137 OCV_OPTION(WITH_CSTRIPES       "Include C= support"                          OFF  IF WIN32 )
 138 OCV_OPTION(WITH_TIFF           "Include TIFF support"                        ON   IF (NOT IOS) )
 139 OCV_OPTION(WITH_UNICAP         "Include Unicap support (GPL)"                OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 140 OCV_OPTION(WITH_V4L            "Include Video 4 Linux support"               ON   IF (UNIX AND NOT ANDROID) )
 141 OCV_OPTION(WITH_VIDEOINPUT     "Build HighGUI with DirectShow support"       ON   IF WIN32 )
 142 OCV_OPTION(WITH_XIMEA          "Include XIMEA cameras support"               OFF  IF (NOT ANDROID AND NOT APPLE) )
 143 OCV_OPTION(WITH_XINE           "Include Xine support (GPL)"                  OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 144 OCV_OPTION(WITH_CLP            "Include Clp support (EPL)"                   OFF)
 145 OCV_OPTION(WITH_OPENCL         "Include OpenCL Runtime support"              OFF  IF (NOT ANDROID AND NOT IOS) )
 146 OCV_OPTION(WITH_OPENCLAMDFFT   "Include AMD OpenCL FFT library support"      OFF  IF (NOT ANDROID AND NOT IOS) )
 147 OCV_OPTION(WITH_OPENCLAMDBLAS  "Include AMD OpenCL BLAS library support"     OFF  IF (NOT ANDROID AND NOT IOS) )
 148
 149
 150 # OpenCV build components
 151 # ===================================================
 152 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR IOS) )
 153 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID) IF (NOT IOS) )
 154 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 155 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" ON )
 156 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 157 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON )
 158 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     ON  IF (NOT IOS) )
 159 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           ON  IF (NOT IOS) )
 160 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into debug libs (not MSCV only)" ON )
 161 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of staticaly linked CRT for staticaly linked OpenCV" ON IF MSVC )
 162 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create fat java wrapper containing the whole OpenCV library" ON IF NOT BUILD_SHARED_LIBS AND CMAKE_COMPILER_IS_GNUCXX )
 163 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID AND ANDROID_SOURCE_TREE )
 164 OCV_OPTION(BUILD_ANDROID_PACKAGE    "Build platform-specific package for Google Play" OFF IF ANDROID )
 165
 166 # 3rd party libs
 167 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             WIN32 OR APPLE )
 168 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          WIN32 OR ANDROID OR APPLE )
 169 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        WIN32 OR ANDROID OR APPLE )
 170 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          WIN32 OR ANDROID OR APPLE )
 171 OCV_OPTION(BUILD_PNG                "Build libpng from source"           WIN32 OR ANDROID OR APPLE )
 172 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          WIN32 OR ANDROID OR APPLE )
 173 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" ANDROID IF CMAKE_COMPILER_IS_GNUCXX )
 174
 175 # OpenCV installation options
 176 # ===================================================
 177 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 178 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 179 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 180 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT IOS AND BUILD_SHARED_LIBS) )
 181
 182
 183 # OpenCV build options
 184 # ===================================================
 185 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON   IF (NOT IOS) )
 186 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) IF (CMAKE_VERSION VERSION_GREATER "2.8.0") )
 187 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CMAKE_COMPILER_IS_GNUCXX )
 188 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CMAKE_COMPILER_IS_GNUCXX AND NOT (APPLE AND CMAKE_COMPILER_IS_CLANGCXX) )
 189 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CMAKE_COMPILER_IS_GNUCXX AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 190 OCV_OPTION(ENABLE_FAST_MATH           "Enable -ffast-math (not recommended for GCC 4.6.x)"       OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 191 OCV_OPTION(ENABLE_SSE                 "Enable SSE instructions"                                  ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 192 OCV_OPTION(ENABLE_SSE2                "Enable SSE2 instructions"                                 ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 193 OCV_OPTION(ENABLE_SSE3                "Enable SSE3 instructions"                                 ON   IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 194 OCV_OPTION(ENABLE_SSSE3               "Enable SSSE3 instructions"                                OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 195 OCV_OPTION(ENABLE_SSE41               "Enable SSE4.1 instructions"                               OFF  IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 196 OCV_OPTION(ENABLE_SSE42               "Enable SSE4.2 instructions"                               OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 197 OCV_OPTION(ENABLE_AVX                 "Enable AVX instructions"                                  OFF  IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 198 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 199 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 200
 201
 202 # uncategorized options
 203 # ===================================================
 204 OCV_OPTION(CMAKE_VERBOSE "Verbose mode" OFF )
 205
 206 # backward compatibility
 207 # ===================================================
 208 include(cmake/OpenCVLegacyOptions.cmake OPTIONAL)
 209
 210
 211 # ----------------------------------------------------------------------------
 212 #  Get actual OpenCV version number from sources
 213 # ----------------------------------------------------------------------------
 214 include(cmake/OpenCVVersion.cmake)
 215
 216
 217 # ----------------------------------------------------------------------------
 218 #  Build & install layouts
 219 # ----------------------------------------------------------------------------
 220
 221 # Save libs and executables in the same place
 222 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications" )
 223
 224 if(ANDROID OR WIN32)
 225   set(OPENCV_DOC_INSTALL_PATH doc)
 226 elseif(INSTALL_TO_MANGLED_PATHS)
 227   set(OPENCV_DOC_INSTALL_PATH share/OpenCV-${OPENCV_VERSION}/doc)
 228 else()
 229   set(OPENCV_DOC_INSTALL_PATH share/OpenCV/doc)
 230 endif()
 231
 232 if(ANDROID)
 233   set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 234   set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 235   set(OPENCV_LIB_INSTALL_PATH     sdk/native/libs/${ANDROID_NDK_ABI_NAME})
 236   set(OPENCV_3P_LIB_INSTALL_PATH  sdk/native/3rdparty/libs/${ANDROID_NDK_ABI_NAME})
 237   set(OPENCV_CONFIG_INSTALL_PATH  sdk/native/jni)
 238   set(OPENCV_INCLUDE_INSTALL_PATH sdk/native/jni/include)
 239 else()
 240   set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib")
 241   set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib${LIB_SUFFIX}")
 242   set(OPENCV_LIB_INSTALL_PATH     lib${LIB_SUFFIX})
 243   set(OPENCV_3P_LIB_INSTALL_PATH  share/OpenCV/3rdparty/${OPENCV_LIB_INSTALL_PATH})
 244   set(OPENCV_INCLUDE_INSTALL_PATH include)
 245
 246   math(EXPR SIZEOF_VOID_P_BITS "8 * ${CMAKE_SIZEOF_VOID_P}")
 247   if(LIB_SUFFIX AND NOT SIZEOF_VOID_P_BITS EQUAL LIB_SUFFIX)
 248     set(OPENCV_CONFIG_INSTALL_PATH lib${LIB_SUFFIX}/cmake/opencv)
 249   else()
 250     set(OPENCV_CONFIG_INSTALL_PATH share/OpenCV)
 251   endif()
 252 endif()
 253
 254 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 255 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 256
 257 if(INSTALL_TO_MANGLED_PATHS)
 258   set(OPENCV_INCLUDE_INSTALL_PATH ${OPENCV_INCLUDE_INSTALL_PATH}/opencv-${OPENCV_VERSION})
 259 endif()
 260
 261 if(WIN32)
 262   # Postfix of DLLs:
 263   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 264   set(OPENCV_DEBUG_POSTFIX d)
 265 else()
 266   # Postfix of so's:
 267   set(OPENCV_DLLVERSION "")
 268   set(OPENCV_DEBUG_POSTFIX "")
 269 endif()
 270
 271 if(DEFINED CMAKE_DEBUG_POSTFIX)
 272   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 273 endif()
 274
 275 if(CMAKE_VERBOSE)
 276   set(CMAKE_VERBOSE_MAKEFILE 1)
 277 endif()
 278
 279
 280 # ----------------------------------------------------------------------------
 281 #  Path for build/platform -specific headers
 282 # ----------------------------------------------------------------------------
 283 set(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 284 add_definitions(-DHAVE_CVCONFIG_H)
 285 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 286
 287
 288 # ----------------------------------------------------------------------------
 289 #  Autodetect if we are in a GIT repository
 290 # ----------------------------------------------------------------------------
 291
 292 # don't use FindGit because it requires CMake 2.8.2
 293 set(git_names git eg) # eg = easy git
 294 # Prefer .cmd variants on Windows unless running in a Makefile in the MSYS shell
 295 if(CMAKE_HOST_WIN32)
 296   if(NOT CMAKE_GENERATOR MATCHES "MSYS")
 297     set(git_names git.cmd git eg.cmd eg)
 298   endif()
 299 endif()
 300
 301 find_host_program(GIT_EXECUTABLE NAMES ${git_names} PATH_SUFFIXES Git/cmd Git/bin DOC "git command line client")
 302 mark_as_advanced(GIT_EXECUTABLE)
 303
 304 if(GIT_EXECUTABLE)
 305   execute_process(COMMAND ${GIT_EXECUTABLE} describe --tags --always --dirty --match "2.[0-9].[0-9]*"
 306     WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 307     OUTPUT_VARIABLE OPENCV_VCSVERSION
 308     RESULT_VARIABLE GIT_RESULT
 309     ERROR_QUIET
 310     OUTPUT_STRIP_TRAILING_WHITESPACE
 311   )
 312   if(NOT GIT_RESULT EQUAL 0)
 313     set(OPENCV_VCSVERSION "unknown")
 314   endif()
 315 else()
 316   # We don't have git:
 317   set(OPENCV_VCSVERSION "unknown")
 318 endif()
 319
 320
 321 # ----------------------------------------------------------------------------
 322 # OpenCV compiler and linker options
 323 # ----------------------------------------------------------------------------
 324 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 325 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 326   set(CMAKE_BUILD_TYPE Release)
 327 endif()
 328
 329 include(cmake/OpenCVCompilerOptions.cmake)
 330
 331
 332 # ----------------------------------------------------------------------------
 333 # Use statically or dynamically linked CRT?
 334 # Default: dynamic
 335 # ----------------------------------------------------------------------------
 336 if(MSVC)
 337   include(cmake/OpenCVCRTLinkage.cmake)
 338 endif(MSVC)
 339
 340 if(WIN32 AND NOT MINGW)
 341   add_definitions(-D_VARIADIC_MAX=10)
 342 endif(WIN32 AND NOT MINGW)
 343
 344
 345 # ----------------------------------------------------------------------------
 346 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 347 # ----------------------------------------------------------------------------
 348 if(UNIX)
 349   include(cmake/OpenCVFindPkgConfig.cmake OPTIONAL)
 350   include(CheckFunctionExists)
 351   include(CheckIncludeFile)
 352
 353   if(NOT APPLE)
 354     CHECK_INCLUDE_FILE(alloca.h HAVE_ALLOCA_H)
 355     CHECK_FUNCTION_EXISTS(alloca HAVE_ALLOCA)
 356     CHECK_INCLUDE_FILE(unistd.h HAVE_UNISTD_H)
 357     CHECK_INCLUDE_FILE(pthread.h HAVE_LIBPTHREAD)
 358     if(ANDROID)
 359       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 360     elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD|NetBSD|DragonFly")
 361       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 362     else()
 363       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 364     endif()
 365   else()
 366     add_definitions(-DHAVE_ALLOCA -DHAVE_ALLOCA_H -DHAVE_LIBPTHREAD -DHAVE_UNISTD_H)
 367   endif()
 368 endif()
 369
 370 include(cmake/OpenCVPCHSupport.cmake)
 371 include(cmake/OpenCVModule.cmake)
 372
 373 # ----------------------------------------------------------------------------
 374 #  Detect 3rd-party libraries
 375 # ----------------------------------------------------------------------------
 376
 377 include(cmake/OpenCVFindLibsGrfmt.cmake)
 378 include(cmake/OpenCVFindLibsGUI.cmake)
 379 include(cmake/OpenCVFindLibsVideo.cmake)
 380 include(cmake/OpenCVFindLibsPerf.cmake)
 381
 382
 383 # ----------------------------------------------------------------------------
 384 #  Detect other 3rd-party libraries/tools
 385 # ----------------------------------------------------------------------------
 386
 387 # --- LATEX for pdf documentation ---
 388 if(BUILD_DOCS)
 389   include(cmake/OpenCVFindLATEX.cmake)
 390 endif(BUILD_DOCS)
 391
 392 # --- Python Support ---
 393 include(cmake/OpenCVDetectPython.cmake)
 394
 395 # --- Java Support ---
 396 include(cmake/OpenCVDetectApacheAnt.cmake)
 397 if(ANDROID)
 398   include(cmake/OpenCVDetectAndroidSDK.cmake)
 399
 400   if(NOT ANDROID_TOOLS_Pkg_Revision GREATER 13)
 401     message(WARNING "OpenCV requires Android SDK tools revision 14 or newer. Otherwise tests and samples will no be compiled.")
 402   endif()
 403 elseif(ANT_EXECUTABLE)
 404   find_package(JNI)
 405 endif()
 406
 407 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 408   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 409 else()
 410   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 411 endif()
 412
 413 # --- OpenCL ---
 414 if(WITH_OPENCL)
 415   include(cmake/OpenCVDetectOpenCL.cmake)
 416 endif()
 417
 418 # ----------------------------------------------------------------------------
 419 # Solution folders:
 420 # ----------------------------------------------------------------------------
 421 if(ENABLE_SOLUTION_FOLDERS)
 422   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 423   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 424 endif()
 425
 426 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 427 include(cmake/OpenCVExtraTargets.cmake)
 428
 429
 430 # ----------------------------------------------------------------------------
 431 # Process subdirectories
 432 # ----------------------------------------------------------------------------
 433
 434 # opencv.hpp and legacy headers
 435 add_subdirectory(include)
 436
 437 # OpenCV modules
 438 add_subdirectory(modules)
 439
 440 # Generate targets for documentation
 441 add_subdirectory(doc)
 442
 443 # various data that is used by cv libraries and/or demo applications.
 444 add_subdirectory(data)
 445
 446 # extra applications
 447 if(BUILD_opencv_apps)
 448   add_subdirectory(apps)
 449 endif()
 450
 451 # examples
 452 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES)
 453   add_subdirectory(samples)
 454 endif()
 455
 456 if(ANDROID)
 457   add_subdirectory(android/service)
 458 endif()
 459
 460 if(BUILD_ANDROID_PACKAGE)
 461   add_subdirectory(android/package)
 462 endif()
 463
 464 if (ANDROID)
 465   add_subdirectory(android/libinfo)
 466 endif()
 467
 468 # ----------------------------------------------------------------------------
 469 # Finalization: generate configuration-based files
 470 # ----------------------------------------------------------------------------
 471 ocv_track_build_dependencies()
 472
 473 # Generate platform-dependent and configuration-dependent headers
 474 include(cmake/OpenCVGenHeaders.cmake)
 475
 476 # Generate opencv.pc for pkg-config command
 477 include(cmake/OpenCVGenPkgconfig.cmake)
 478
 479 # Generate OpenCV.mk for ndk-build (Android build tool)
 480 include(cmake/OpenCVGenAndroidMK.cmake)
 481
 482 # Generate OpenCVСonfig.cmake and OpenCVConfig-version.cmake for cmake projects
 483 include(cmake/OpenCVGenConfig.cmake)
 484
 485
 486 # ----------------------------------------------------------------------------
 487 # Summary:
 488 # ----------------------------------------------------------------------------
 489 status("")
 490 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 491 if(OPENCV_VCSVERSION)
 492   status("  Version control:" ${OPENCV_VCSVERSION})
 493 endif()
 494
 495 # ========================== build platform ==========================
 496 status("")
 497 status("  Platform:")
 498 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
 499 if(CMAKE_CROSSCOMPILING)
 500   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
 501 endif()
 502 status("    CMake:"            ${CMAKE_VERSION})
 503 status("    CMake generator:"  ${CMAKE_GENERATOR})
 504 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
 505 if(MSVC)
 506   status("    MSVC:"           ${MSVC_VERSION})
 507 endif()
 508 if(CMAKE_GENERATOR MATCHES Xcode)
 509   status("    Xcode:"          ${XCODE_VERSION})
 510 endif()
 511 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
 512   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
 513 endif()
 514
 515 # ========================== C/C++ options ==========================
 516 if(CMAKE_CXX_COMPILER_VERSION)
 517   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
 518 elseif(CMAKE_COMPILER_IS_CLANGCXX)
 519   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CLANG_REGEX_VERSION})")
 520 elseif(CMAKE_COMPILER_IS_GNUCXX)
 521   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_GCC_REGEX_VERSION})")
 522 else()
 523   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 524 endif()
 525 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
 526
 527 status("")
 528 status("  C/C++:")
 529 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
 530 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
 531 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
 532 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
 533 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
 534 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
 535 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
 536 if(WIN32)
 537   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
 538   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
 539 else()
 540   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
 541   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
 542 endif()
 543 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
 544
 545 # ========================== OpenCV modules ==========================
 546 status("")
 547 status("  OpenCV modules:")
 548 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD}")
 549 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
 550 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
 551 set(OPENCV_MODULES_DISABLED_AUTO_ST "")
 552 foreach(m ${OPENCV_MODULES_DISABLED_AUTO})
 553   set(__mdeps "")
 554   foreach(d ${OPENCV_MODULE_${m}_DEPS})
 555     if(d MATCHES "^opencv_" AND NOT HAVE_${d})
 556       list(APPEND __mdeps ${d})
 557     endif()
 558   endforeach()
 559   if(__mdeps)
 560     list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}(deps: ${__mdeps})")
 561   else()
 562     list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}")
 563   endif()
 564 endforeach()
 565 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO_ST}")
 566
 567 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
 568 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
 569 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
 570 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
 571
 572 # ========================== Android details ==========================
 573 if(ANDROID)
 574   status("")
 575   status("  Android: ")
 576   status("    Android ABI:" ${ANDROID_ABI})
 577   status("    STL type:" ${ANDROID_STL})
 578   status("    Native API level:" android-${ANDROID_NATIVE_API_LEVEL})
 579   android_get_compatible_target(android_sdk_target_status ${ANDROID_NATIVE_API_LEVEL} ${ANDROID_SDK_TARGET} 11)
 580   status("    SDK target:" "${android_sdk_target_status}")
 581   if(BUILD_WITH_ANDROID_NDK)
 582     status("    Android NDK:" "${ANDROID_NDK} (toolchain: ${ANDROID_TOOLCHAIN_NAME})")
 583   elseif(BUILD_WITH_STANDALONE_TOOLCHAIN)
 584     status("    Android toolchain:" "${ANDROID_STANDALONE_TOOLCHAIN}")
 585   endif()
 586   status("    android tool:"  ANDROID_EXECUTABLE  THEN "${ANDROID_EXECUTABLE} (${ANDROID_TOOLS_Pkg_Desc})" ELSE NO)
 587   status("    Google Play package:" BUILD_ANDROID_PACKAGE                                         THEN YES ELSE NO)
 588   status("    Android examples:"    BUILD_ANDROID_EXAMPLES AND CAN_BUILD_ANDROID_PROJECTS         THEN YES ELSE NO)
 589 endif()
 590
 591 # ========================== GUI ==========================
 592 status("")
 593 status("  GUI: ")
 594
 595 if(HAVE_QT)
 596   status("    QT 4.x:"            HAVE_QT        THEN "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})" ELSE NO)
 597   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
 598 else()
 599   if(DEFINED WITH_QT)
 600     status("    QT 4.x:" NO)
 601   endif()
 602   if(WIN32)
 603     status("    Win32 UI:" YES)
 604   else()
 605     if(APPLE)
 606       if(WITH_CARBON)
 607         status("    Carbon:" YES)
 608       else()
 609         status("    Cocoa:"  YES)
 610       endif()
 611     else()
 612       status("    GTK+ 2.x:" HAVE_GTK      THEN "YES (ver ${ALIASOF_gtk+-2.0_VERSION})"     ELSE NO)
 613       status("    GThread :" HAVE_GTHREAD  THEN "YES (ver ${ALIASOF_gthread-2.0_VERSION})"  ELSE NO)
 614       status("    GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${ALIASOF_gtkglext-1.0_VERSION})" ELSE NO)
 615     endif()
 616   endif()
 617 endif()
 618
 619 status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
 620
 621 # ========================== MEDIA IO ==========================
 622 status("")
 623 status("  Media I/O: ")
 624 status("    ZLib:"         BUILD_ZLIB    THEN "build (ver ${ZLIB_VERSION_STRING})"               ELSE "${ZLIB_LIBRARY} (ver ${ZLIB_VERSION_STRING})")
 625
 626 if(WITH_JPEG)
 627   status("    JPEG:"       JPEG_FOUND    THEN "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})"        ELSE "build (ver ${JPEG_LIB_VERSION})")
 628 else()
 629   status("    JPEG:"       "NO")
 630 endif()
 631
 632 if(WITH_WEBP)
 633   status("    WEBP:"       WEBP_FOUND    THEN "${WEBP_LIBRARY} (ver ${WEBP_VERSION})"        ELSE "build (ver ${WEBP_VERSION})")
 634 else()
 635   status("    WEBP:"       "NO")
 636 endif()
 637
 638 if(WITH_PNG)
 639   status("    PNG:"        PNG_FOUND     THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})"              ELSE "build (ver ${PNG_VERSION})")
 640 else()
 641   status("    PNG:"        "NO")
 642 endif()
 643 if(WITH_TIFF)
 644   if(TIFF_VERSION_STRING AND TIFF_FOUND)
 645     status("    TIFF:"     "${TIFF_LIBRARY} (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 646   else()
 647     status("    TIFF:"     TIFF_FOUND    THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION})"            ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 648   endif()
 649 else()
 650   status("    TIFF:"       "NO")
 651 endif()
 652 if(WITH_JASPER)
 653   status("    JPEG 2000:"  JASPER_FOUND  THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
 654 else()
 655   status("    JPEG 2000:"  "NO")
 656 endif()
 657 if(WITH_OPENEXR)
 658   status("    OpenEXR:"  OPENEXR_FOUND  THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
 659 else()
 660   status("    OpenEXR:"  "NO")
 661 endif()
 662
 663 # ========================== VIDEO IO ==========================
 664 status("")
 665 status("  Video I/O:")
 666
 667 if(DEFINED WITH_1394)
 668   status("    DC1394 1.x:"     HAVE_DC1394         THEN "YES (ver ${ALIASOF_libdc1394_VERSION})"   ELSE NO)
 669   status("    DC1394 2.x:"     HAVE_DC1394_2       THEN "YES (ver ${ALIASOF_libdc1394-2_VERSION})" ELSE NO)
 670 endif(DEFINED WITH_1394)
 671
 672 if(ANDROID)
 673   if(HAVE_opencv_androidcamera)
 674     status("    AndroidNativeCamera:" BUILD_ANDROID_CAMERA_WRAPPER
 675                                                    THEN "YES, build for Android${ANDROID_VERSION}" ELSE "YES, use prebuilt libraries")
 676   else()
 677     status("    AndroidNativeCamera:" "NO (native camera requires Android API level 8 or higher)")
 678   endif()
 679 endif()
 680
 681 if(DEFINED WITH_AVFOUNDATION)
 682   status("    AVFoundation:"   WITH_AVFOUNDATION   THEN YES                                        ELSE NO)
 683 endif(DEFINED WITH_AVFOUNDATION)
 684
 685 if(DEFINED WITH_FFMPEG)
 686   if(WIN32)
 687     status("    FFMPEG:"       WITH_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
 688   else()
 689     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
 690   endif()
 691   status("      codec:"        HAVE_FFMPEG_CODEC   THEN "YES (ver ${ALIASOF_libavcodec_VERSION})"  ELSE NO)
 692   status("      format:"       HAVE_FFMPEG_FORMAT  THEN "YES (ver ${ALIASOF_libavformat_VERSION})" ELSE NO)
 693   status("      util:"         HAVE_FFMPEG_UTIL    THEN "YES (ver ${ALIASOF_libavutil_VERSION})"   ELSE NO)
 694   status("      swscale:"      HAVE_FFMPEG_SWSCALE THEN "YES (ver ${ALIASOF_libswscale_VERSION})"  ELSE NO)
 695   status("      gentoo-style:" HAVE_GENTOO_FFMPEG  THEN YES                                        ELSE NO)
 696 endif(DEFINED WITH_FFMPEG)
 697
 698 if(DEFINED WITH_GSTREAMER)
 699   status("    GStreamer:"      HAVE_GSTREAMER      THEN ""                                         ELSE NO)
 700   if(HAVE_GSTREAMER)
 701     status("      base:"       "YES (ver ${ALIASOF_gstreamer-base-0.10_VERSION})")
 702     status("      app:"        "YES (ver ${ALIASOF_gstreamer-app-0.10_VERSION})")
 703     status("      video:"      "YES (ver ${ALIASOF_gstreamer-video-0.10_VERSION})")
 704   endif()
 705 endif(DEFINED WITH_GSTREAMER)
 706
 707 if(DEFINED WITH_OPENNI)
 708   status("    OpenNI:"         HAVE_OPENNI         THEN "YES (ver ${OPENNI_VERSION_STRING}, build ${OPENNI_VERSION_BUILD})"
 709                                                                                                    ELSE NO)
 710   status("    OpenNI PrimeSensor Modules:" HAVE_OPENNI_PRIME_SENSOR_MODULE
 711                                                    THEN "YES (${OPENNI_PRIME_SENSOR_MODULE})"      ELSE NO)
 712 endif(DEFINED WITH_OPENNI)
 713
 714 if(DEFINED WITH_PVAPI)
 715   status("    PvAPI:"          HAVE_PVAPI          THEN YES                                        ELSE NO)
 716 endif(DEFINED WITH_PVAPI)
 717
 718 if(DEFINED WITH_GIGEAPI)
 719   status("    GigEVisionSDK:"  HAVE_GIGE_API       THEN YES                                        ELSE NO)
 720 endif(DEFINED WITH_GIGEAPI)
 721
 722 if(DEFINED WITH_QUICKTIME)
 723   status("    QuickTime:"      WITH_QUICKTIME      THEN YES                                        ELSE NO)
 724   status("    QTKit:"          WITH_QUICKTIME      THEN NO                                         ELSE YES)
 725 endif(DEFINED WITH_QUICKTIME)
 726
 727 if(DEFINED WITH_UNICAP)
 728   status("    UniCap:"         HAVE_UNICAP         THEN "YES (ver ${ALIASOF_libunicap_VERSION})"   ELSE NO)
 729   status("    UniCap ucil:"    HAVE_UNICAP_UCIL    THEN "YES (ver ${ALIASOF_libucil_VERSION})"     ELSE NO)
 730 endif(DEFINED WITH_UNICAP)
 731
 732 if(DEFINED WITH_V4L)
 733   if(HAVE_CAMV4L)
 734     set(HAVE_CAMV4L_STR "YES")
 735   else()
 736     set(HAVE_CAMV4L_STR "NO")
 737   endif()
 738   if(HAVE_CAMV4L2)
 739     set(HAVE_CAMV4L2_STR "YES")
 740   elseif(HAVE_VIDEOIO)
 741     set(HAVE_CAMV4L2_STR "YES(videoio)")
 742   else()
 743     set(HAVE_CAMV4L2_STR "NO")
 744   endif()
 745   status("    V4L/V4L2:"       HAVE_LIBV4L         THEN "Using libv4l (ver ${ALIASOF_libv4l1_VERSION})"
 746                                                    ELSE "${HAVE_CAMV4L_STR}/${HAVE_CAMV4L2_STR}")
 747 endif(DEFINED WITH_V4L)
 748
 749 if(DEFINED WITH_VIDEOINPUT)
 750   status("    DirectShow:"     HAVE_VIDEOINPUT     THEN YES                                        ELSE NO)
 751 endif(DEFINED WITH_VIDEOINPUT)
 752
 753 if(DEFINED WITH_XIMEA)
 754   status("    XIMEA:"          HAVE_XIMEA          THEN YES                                        ELSE NO)
 755 endif(DEFINED WITH_XIMEA)
 756
 757 if(DEFINED WITH_XINE)
 758   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${ALIASOF_libxine_VERSION})"     ELSE NO)
 759 endif(DEFINED WITH_XINE)
 760
 761 # ========================== Other third-party libraries ==========================
 762 status("")
 763 status("  Other third-party libraries:")
 764
 765 if(WITH_IPP AND IPP_FOUND)
 766   status("    Use IPP:" "${IPP_LATEST_VERSION_STR} [${IPP_LATEST_VERSION_MAJOR}.${IPP_LATEST_VERSION_MINOR}.${IPP_LATEST_VERSION_BUILD}]")
 767   status("         at:" "${IPP_ROOT_DIR}")
 768 else()
 769   status("    Use IPP:"   WITH_IPP AND NOT IPP_FOUND THEN "IPP not found" ELSE NO)
 770 endif()
 771
 772 status("    Use Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
 773 status("    Use TBB:"        HAVE_TBB         THEN "YES (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})" ELSE NO)
 774 status("    Use OpenMP:"     HAVE_OPENMP      THEN YES ELSE NO)
 775 status("    Use GCD"         HAVE_GCD         THEN YES ELSE NO)
 776 status("    Use Concurrency" HAVE_CONCURRENCY THEN YES ELSE NO)
 777 status("    Use C=:"         HAVE_CSTRIPES    THEN YES ELSE NO)
 778 status("    Use Cuda:"       HAVE_CUDA        THEN "YES (ver ${CUDA_VERSION_STRING})" ELSE NO)
 779 status("    Use OpenCL:"     HAVE_OPENCL      THEN YES ELSE NO)
 780
 781 if(HAVE_CUDA)
 782   status("")
 783   status("  NVIDIA CUDA")
 784
 785   status("    Use CUFFT:"            HAVE_CUFFT   THEN YES ELSE NO)
 786   status("    Use CUBLAS:"           HAVE_CUBLAS  THEN YES ELSE NO)
 787   status("    USE NVCUVID:"          HAVE_NVCUVID THEN YES ELSE NO)
 788   status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
 789   status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
 790   status("    Use fast math:"        CUDA_FAST_MATH THEN YES ELSE NO)
 791 endif()
 792
 793 if(HAVE_OPENCL)
 794   status("")
 795   status("  OpenCL")
 796   if(OPENCL_INCLUDE_DIR)
 797     status("    Include path:"       ${OPENCL_INCLUDE_DIRS})
 798   endif()
 799   if(OPENCL_LIBRARIES)
 800     status("    libraries:"          ${OPENCL_LIBRARIES})
 801   endif()
 802   status("    Use AMDFFT:"           HAVE_CLAMDFFT  THEN YES ELSE NO)
 803   status("    Use AMDBLAS:"          HAVE_CLAMDBLAS THEN YES ELSE NO)
 804 endif()
 805
 806 # ========================== python ==========================
 807 status("")
 808 status("  Python:")
 809 status("    Interpreter:"     PYTHON_EXECUTABLE   THEN "${PYTHON_EXECUTABLE} (ver ${PYTHON_VERSION_FULL})"         ELSE NO)
 810 if(BUILD_opencv_python)
 811   if(PYTHONLIBS_VERSION_STRING)
 812     status("    Libraries:"   HAVE_opencv_python  THEN  "${PYTHON_LIBRARIES} (ver ${PYTHONLIBS_VERSION_STRING})"   ELSE NO)
 813   else()
 814     status("    Libraries:"   HAVE_opencv_python  THEN  ${PYTHON_LIBRARIES}                                        ELSE NO)
 815   endif()
 816   status("    numpy:"         PYTHON_USE_NUMPY    THEN "${PYTHON_NUMPY_INCLUDE_DIR} (ver ${PYTHON_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
 817   status("    packages path:" PYTHON_EXECUTABLE   THEN "${PYTHON_PACKAGES_PATH}"                                   ELSE "-")
 818 endif()
 819
 820 # ========================== java ==========================
 821 status("")
 822 status("  Java:")
 823 status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
 824 if(NOT ANDROID)
 825   status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
 826 endif()
 827 status("    Java tests:"    BUILD_TESTS AND (NOT ANDROID OR CAN_BUILD_ANDROID_PROJECTS)                 THEN YES ELSE NO)
 828
 829 # ========================== documentation ==========================
 830 if(BUILD_DOCS)
 831   status("")
 832   status("  Documentation:")
 833   if(HAVE_SPHINX)
 834     status("    Build Documentation:" PDFLATEX_COMPILER      THEN YES ELSE "YES (only HTML and without math expressions)")
 835   else()
 836     status("    Build Documentation:" NO)
 837   endif()
 838   status("    Sphinx:"              HAVE_SPHINX              THEN "${SPHINX_BUILD} (ver ${SPHINX_VERSION})" ELSE NO)
 839   status("    PdfLaTeX compiler:"   PDFLATEX_COMPILER        THEN "${PDFLATEX_COMPILER}" ELSE NO)
 840 endif()
 841
 842 # ========================== samples and tests ==========================
 843 status("")
 844 status("  Tests and samples:")
 845 status("    Tests:"             BUILD_TESTS AND HAVE_opencv_ts       THEN YES ELSE NO)
 846 status("    Performance tests:" BUILD_PERF_TESTS AND HAVE_opencv_ts  THEN YES ELSE NO)
 847 status("    C/C++ Examples:"    BUILD_EXAMPLES                       THEN YES ELSE NO)
 848
 849 # ========================== auxiliary ==========================
 850 status("")
 851 status("  Install path:" "${CMAKE_INSTALL_PREFIX}")
 852 status("")
 853 status("  cvconfig.h is in:" "${OPENCV_CONFIG_FILE_INCLUDE_DIR}")
 854 status("-----------------------------------------------------------------")
 855 status("")
 856
 857 ocv_finalize_status()
 858
 859 # ----------------------------------------------------------------------------
 860 # Warn in the case of in-source build
 861 # ----------------------------------------------------------------------------
 862 if("${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 863   message(WARNING "The source directory is the same as binary directory. \"make clean\" may damage the source tree")
 864 endif()
 865