CMakeLists.txt

   1 if (CMAKE_VERSION VERSION_LESS "2.8.12")
   2     cmake_minimum_required(VERSION 2.8.9)
   3     set(HEAPTRACK_BUILD_GUI OFF)
   4 else()
   5     cmake_minimum_required(VERSION 2.8.12)
   6 endif()
   7
   8 project(heaptrack)
   9 enable_testing()
  10
  11 if(NOT CMAKE_BUILD_TYPE)
  12   message(STATUS "Setting build type to 'RelWithDebInfo' as none was specified.")
  13   set(CMAKE_BUILD_TYPE RelWithDebInfo CACHE STRING "Choose the type of build." FORCE)
  14 endif()
  15
  16 set(HEAPTRACK_VERSION_MAJOR 1)
  17 set(HEAPTRACK_VERSION_MINOR 1)
  18 set(HEAPTRACK_VERSION_PATCH 0)
  19 set(HEAPTRACK_LIB_VERSION 1.0.0)
  20 set(HEAPTRACK_LIB_SOVERSION 1)
  21 set(HEAPTRACK_FILE_FORMAT_VERSION 2)
  22
  23 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  24
  25 find_package(Libunwind REQUIRED)
  26 find_package(Boost 1.41.0 REQUIRED COMPONENTS iostreams program_options)
  27 find_package(Threads REQUIRED)
  28 find_package(ZLIB REQUIRED)
  29 include(FeatureSummary)
  30
  31 option(
  32   HEAPTRACK_BUILD_GUI
  33   "Disable this option to skip building the Qt5 / KF5 based GUI for heaptrack."
  34   On
  35 )
  36
  37 if(HEAPTRACK_BUILD_GUI)
  38     find_package(Qt5 5.2.0 NO_MODULE OPTIONAL_COMPONENTS Widgets)
  39     find_package(ECM 1.0.0 NO_MODULE)
  40     if(Qt5_FOUND AND ECM_FOUND)
  41         set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${ECM_MODULE_PATH} ${ECM_KDE_MODULE_DIR})
  42             find_package(KF5 COMPONENTS CoreAddons I18n ItemModels ThreadWeaver ConfigWidgets KIO)
  43             find_package(KChart "2.6.0")
  44             set_package_properties(KChart PROPERTIES TYPE RECOMMENDED PURPOSE "Required for the heaptrack_gui executable. Get it from the kdiagram module.")
  45     endif()
  46 endif()
  47
  48 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  49
  50 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11 -Wall -Wpedantic")
  51
  52 include (CheckCXXSourceCompiles)
  53 check_cxx_source_compiles(
  54     "#include <unordered_map>
  55     #include <atomic>
  56     thread_local int tls;
  57     int main() { return 0; }"
  58     HAVE_CXX11_SUPPORT)
  59
  60 if (NOT HAVE_CXX11_SUPPORT)
  61     message(FATAL_ERROR "Your compiler is too old and does not support the required C++11 features.")
  62 endif()
  63
  64 check_cxx_source_compiles(
  65     "#include <stdio_ext.h>
  66     #include <fcntl.h>
  67     #include <dlfcn.h>
  68     #include <link.h>
  69     int main() { return 0; }"
  70     HAVE_LINUX_HEADERS)
  71
  72 if (NOT HAVE_LINUX_HEADERS)
  73     message(FATAL_ERROR "You are missing some Linux headers required to compile heaptrack.")
  74 endif()
  75
  76 check_cxx_source_compiles(
  77     "#include <future>
  78     std::future<int> f;
  79     int main() { return 0; }"
  80     HAVE_FUTURE_SUPPORT)
  81
  82 # cfree() does not exist in glibc 2.26+.
  83 # See: https://bugs.kde.org/show_bug.cgi?id=383889
  84 include(CheckSymbolExists)
  85 check_symbol_exists(cfree malloc.h HAVE_CFREE)
  86
  87 set(BIN_INSTALL_DIR "bin")
  88 set(LIB_SUFFIX "" CACHE STRING "Define suffix of directory name (32/64)")
  89 set(LIB_INSTALL_DIR "lib${LIB_SUFFIX}")
  90 set(LIBEXEC_INSTALL_DIR "${LIB_INSTALL_DIR}/heaptrack/libexec")
  91
  92 file(RELATIVE_PATH LIBEXEC_REL_PATH
  93     "${CMAKE_INSTALL_PREFIX}/${BIN_INSTALL_DIR}"
  94     "${CMAKE_INSTALL_PREFIX}/${LIBEXEC_INSTALL_DIR}")
  95
  96 file(RELATIVE_PATH LIB_REL_PATH
  97     "${CMAKE_INSTALL_PREFIX}/${BIN_INSTALL_DIR}"
  98     "${CMAKE_INSTALL_PREFIX}/${LIB_INSTALL_DIR}/heaptrack")
  99
 100 add_subdirectory(3rdparty)
 101 add_subdirectory(src)
 102 add_subdirectory(tests)
 103
 104 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)