CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2
   3 if(NOT DEFINED CMAKE_BUILD_TYPE)
   4         set(CMAKE_BUILD_TYPE Release CACHE STRING "Build type")
   5 endif()
   6
   7 project(libwebsockets C)
   8
   9 set(PACKAGE "libwebsockets")
  10 set(CPACK_PACKAGE_NAME "${PACKAGE}")
  11 set(CPACK_PACKAGE_VERSION_MAJOR "1")
  12 set(CPACK_PACKAGE_VERSION_MINOR "5")
  13 set(CPACK_PACKAGE_VERSION "${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}")
  14 set(CPACK_PACKAGE_VENDOR "andy@warmcat.com")
  15 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY "${PACKAGE} ${PACKAGE_VERSION}")
  16 set(SOVERSION "5")
  17 set(CPACK_SOURCE_GENERATOR "TGZ")
  18 set(CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
  19 set(VERSION "${CPACK_PACKAGE_VERSION}")
  20
  21 set(LWS_LIBRARY_VERSION ${CPACK_PACKAGE_VERSION})
  22 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${PROJECT_SOURCE_DIR}/cmake/")
  23
  24 message(STATUS "CMAKE_TOOLCHAIN_FILE='${CMAKE_TOOLCHAIN_FILE}'")
  25
  26 # Try to find the current Git hash.
  27 find_package(Git)
  28 if(GIT_EXECUTABLE)
  29         execute_process(
  30     WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
  31     COMMAND "${GIT_EXECUTABLE}" log -n 1 --pretty=%h
  32     OUTPUT_VARIABLE GIT_HASH
  33     OUTPUT_STRIP_TRAILING_WHITESPACE
  34     )
  35
  36     set(LWS_BUILD_HASH ${GIT_HASH})
  37     message("Git commit hash: ${LWS_BUILD_HASH}")
  38 endif()
  39
  40 set(LWS_USE_BUNDLED_ZLIB_DEFAULT OFF)
  41 if(WIN32)
  42         set(LWS_USE_BUNDLED_ZLIB_DEFAULT ON)
  43 endif()
  44
  45 option(LWS_WITH_STATIC "Build the static version of the library" ON)
  46 option(LWS_WITH_SHARED "Build the shared version of the library" ON)
  47 option(LWS_WITH_SSL "Include SSL support (default OpenSSL, wolfSSL if LWS_USE_WOLFSSL is set)" ON)
  48 option(LWS_USE_CYASSL "Use CyaSSL replacement for OpenSSL. When setting this, you also need to specify LWS_CYASSL_LIBRARIES and LWS_CYASSL_INCLUDE_DIRS" OFF)
  49 option(LWS_USE_WOLFSSL "Use wolfSSL replacement for OpenSSL. When setting this, you also need to specify LWS_WOLFSSL_LIBRARIES and LWS_WOLFSSL_INCLUDE_DIRS" OFF)
  50 option(LWS_WITH_ZLIB "Include zlib support (required for extensions)" ON)
  51 option(LWS_WITH_LIBEV "Compile with support for libev" OFF)
  52 option(LWS_USE_BUNDLED_ZLIB "Use bundled zlib version (Windows only)" ${LWS_USE_BUNDLED_ZLIB_DEFAULT})
  53 option(LWS_SSL_CLIENT_USE_OS_CA_CERTS "SSL support should make use of the OS-installed CA root certs" ON)
  54 option(LWS_WITHOUT_BUILTIN_GETIFADDRS "Don't use the BSD getifaddrs implementation from libwebsockets if it is missing (this will result in a compilation error) ... The default is to assume that your libc provides it. On some systems such as uclibc it doesn't exist." OFF)
  55 option(LWS_WITHOUT_BUILTIN_SHA1 "Don't build the lws sha-1 (eg, because openssl will provide it" OFF)
  56 option(LWS_WITHOUT_CLIENT "Don't build the client part of the library" OFF)
  57 option(LWS_WITHOUT_SERVER "Don't build the server part of the library" OFF)
  58 option(LWS_LINK_TESTAPPS_DYNAMIC "Link the test apps to the shared version of the library. Default is to link statically" OFF)
  59 option(LWS_WITHOUT_TESTAPPS "Don't build the libwebsocket-test-apps" OFF)
  60 option(LWS_WITHOUT_TEST_SERVER "Don't build the test server" OFF)
  61 option(LWS_WITHOUT_TEST_SERVER_EXTPOLL "Don't build the test server version that uses external poll" OFF)
  62 option(LWS_WITHOUT_TEST_PING "Don't build the ping test application" OFF)
  63 option(LWS_WITHOUT_TEST_CLIENT "Don't build the client test application" OFF)
  64 option(LWS_WITHOUT_TEST_FRAGGLE "Don't build the ping test application" OFF)
  65 option(LWS_WITHOUT_EXTENSIONS "Don't compile with extensions" OFF)
  66 option(LWS_WITH_LATENCY "Build latency measuring code into the library" OFF)
  67 option(LWS_WITHOUT_DAEMONIZE "Don't build the daemonization api" ON)
  68 option(LWS_IPV6 "Compile with support for ipv6" OFF)
  69 option(LWS_WITH_HTTP2 "Compile with support for http2" OFF)
  70 option(LWS_MBED3 "Platform is MBED3" OFF)
  71
  72 if (DEFINED YOTTA_WEBSOCKETS_VERSION_STRING)
  73
  74 set(LWS_WITH_SHARED OFF)
  75 set(LWS_WITH_SSL OFF)
  76 set(LWS_WITH_ZLIB OFF)
  77 set(LWS_WITHOUT_CLIENT ON)
  78 set(LWS_WITHOUT_TESTAPPS ON)
  79 set(LWS_WITHOUT_EXTENSIONS ON)
  80 set(LWS_MBED3 ON)
  81
  82 endif()
  83
  84 if (DEFINED YOTTA_WEBSOCKETS_VERSION_STRING)
  85
  86 set(LWS_WITH_SHARED OFF)
  87 set(LWS_WITH_SSL OFF)
  88 set(LWS_WITH_ZLIB OFF)
  89 set(LWS_WITHOUT_CLIENT ON)
  90 set(LWS_WITHOUT_TESTAPPS ON)
  91 set(LWS_WITHOUT_EXTENSIONS ON)
  92 set(LWS_MBED3 ON)
  93
  94 endif()
  95
  96
  97 # Allow the user to override installation directories.
  98 set(LWS_INSTALL_LIB_DIR       lib CACHE PATH "Installation directory for libraries")
  99 set(LWS_INSTALL_BIN_DIR       bin CACHE PATH "Installation directory for executables")
 100 set(LWS_INSTALL_INCLUDE_DIR   include CACHE PATH "Installation directory for header files")
 101 set(LWS_INSTALL_EXAMPLES_DIR  bin CACHE PATH "Installation directory for example files")
 102
 103 # Allow the user to use the old CyaSSL options/library in stead of wolfSSL
 104 if (LWS_USE_CYASSL AND LWS_USE_WOLFSSL)
 105         message(FATAL_ERROR "LWS_USE_CYASSL and LWS_USE_WOLFSSL are mutually exclusive!")
 106 endif()
 107 if (LWS_USE_CYASSL)
 108         # Copy CyaSSL options to the wolfSSL options
 109         set(LWS_USE_WOLFSSL ${LWS_USE_CYASSL} CACHE BOOL "Use wolfSSL/CyaSSL instead of OpenSSL" FORCE)
 110         set(LWS_WOLFSSL_LIBRARIES ${LWS_CYASSL_LIBRARIES} CACHE PATH "Path to wolfSSL/CyaSSL libraries" FORCE)
 111         set(LWS_WOLFSSL_INCLUDE_DIRS ${LWS_CYASSL_INCLUDE_DIRS} CACHE PATH "Path to wolfSSL/CyaSSL header files" FORCE)
 112 endif()
 113
 114 if (LWS_WITHOUT_CLIENT AND LWS_WITHOUT_SERVER)
 115         message(FATAL_ERROR "Makes no sense to compile with neither client nor server.")
 116 endif()
 117
 118 if (NOT (LWS_WITH_STATIC OR LWS_WITH_SHARED))
 119         message(FATAL_ERROR "Makes no sense to compile with neither static nor shared libraries.")
 120 endif()
 121
 122 if (NOT LWS_WITHOUT_EXTENSIONS)
 123         if (NOT LWS_WITH_ZLIB)
 124                 message(FATAL_ERROR "zlib is required for extensions.")
 125         endif()
 126 endif()
 127
 128 set(LWS_ZLIB_LIBRARIES CACHE PATH "Path to the zlib library")
 129 set(LWS_ZLIB_INCLUDE_DIRS CACHE PATH "Path to the zlib include directory")
 130 set(LWS_OPENSSL_LIBRARIES CACHE PATH "Path to the OpenSSL library")
 131 set(LWS_OPENSSL_INCLUDE_DIRS CACHE PATH "Path to the OpenSSL include directory")
 132 set(LWS_WOLFSSL_LIBRARIES CACHE PATH "Path to the wolfSSL library")
 133 set(LWS_WOLFSSL_INCLUDE_DIRS CACHE PATH "Path to the wolfSSL include directory")
 134 set(LWS_LIBEV_LIBRARIES CACHE PATH "Path to the libev library")
 135 set(LWS_LIBEV_INCLUDE_DIRS CACHE PATH "Path to the libev include directory")
 136
 137 if (NOT LWS_WITH_SSL)
 138         set(LWS_WITHOUT_BUILTIN_SHA1 OFF)
 139 endif()
 140
 141 if (LWS_WITH_SSL AND NOT LWS_USE_WOLFSSL)
 142         if ("${LWS_OPENSSL_LIBRARIES}" STREQUAL "" OR "${LWS_OPENSSL_INCLUDE_DIRS}" STREQUAL "")
 143         else()
 144                 set(OPENSSL_LIBRARIES ${LWS_OPENSSL_LIBRARIES})
 145                 set(OPENSSL_INCLUDE_DIRS ${LWS_OPENSSL_INCLUDE_DIRS})
 146                 set(OPENSSL_FOUND 1)
 147         endif()
 148 endif()
 149
 150 if (LWS_WITH_SSL AND LWS_USE_WOLFSSL)
 151         if ("${LWS_WOLFSSL_LIBRARIES}" STREQUAL "" OR "${LWS_WOLFSSL_INCLUDE_DIRS}" STREQUAL "")
 152                 if (NOT WOLFSSL_FOUND)
 153                         if (LWS_USE_CYASSL)
 154                                 message(FATAL_ERROR "You must set LWS_CYASSL_LIBRARIES and LWS_CYASSL_INCLUDE_DIRS when LWS_USE_CYASSL is turned on.")
 155                         else()
 156                                 message(FATAL_ERROR "You must set LWS_WOLFSSL_LIBRARIES and LWS_WOLFSSL_INCLUDE_DIRS when LWS_USE_WOLFSSL is turned on.")
 157                         endif()
 158                 endif()
 159         else()
 160                 set(WOLFSSL_LIBRARIES ${LWS_WOLFSSL_LIBRARIES})
 161                 set(WOLFSSL_INCLUDE_DIRS ${LWS_WOLFSSL_INCLUDE_DIRS})
 162                 set(WOLFSSL_FOUND 1)
 163         endif()
 164         set(USE_WOLFSSL 1)
 165         if (LWS_USE_CYASSL)
 166                 set(USE_OLD_CYASSL 1)
 167         endif()
 168 endif()
 169
 170 if (LWS_WITH_ZLIB AND NOT LWS_USE_BUNDLED_ZLIB)
 171         if ("${LWS_ZLIB_LIBRARIES}" STREQUAL "" OR "${LWS_ZLIB_INCLUDE_DIRS}" STREQUAL "")
 172         else()
 173                 set(ZLIB_LIBRARIES ${LWS_ZLIB_LIBRARIES})
 174                 set(ZLIB_INCLUDE_DIRS ${LWS_ZLIB_INCLUDE_DIRS})
 175                 set(ZLIB_FOUND 1)
 176         endif()
 177 endif()
 178
 179 if (LWS_WITH_LIBEV)
 180         if ("${LWS_LIBEV_LIBRARIES}" STREQUAL "" OR "${LWS_LIBEV_INCLUDE_DIRS}" STREQUAL "")
 181         else()
 182                 set(LIBEV_LIBRARIES ${LWS_LIBEV_LIBRARIES})
 183                 set(LIBEV_INCLUDE_DIRS ${LWS_LIBEV_INCLUDE_DIRS})
 184                 set(LIBEV_FOUND 1)
 185         endif()
 186 endif()
 187
 188 # FIXME: This must be runtime-only option.
 189 # The base dir where the test-apps look for the SSL certs.
 190 set(LWS_OPENSSL_CLIENT_CERTS ../share CACHE PATH "Server SSL certificate directory")
 191 if (WIN32)
 192         set(LWS_OPENSSL_CLIENT_CERTS . CACHE PATH "Client SSL certificate directory")
 193
 194         if (LWS_IPV6)
 195                 set(LWS_IPV6 OFF)
 196                 message(WARNING "IPv6 does not currently work on Windows!")
 197         endif()
 198 else()
 199         set(LWS_OPENSSL_CLIENT_CERTS /etc/pki/tls/certs/ CACHE PATH "Client SSL certificate directory")
 200 endif()
 201
 202 if (LWS_WITHOUT_EXTENSIONS)
 203         set(LWS_NO_EXTENSIONS 1)
 204 endif()
 205
 206 if (LWS_WITH_SSL)
 207         set(LWS_OPENSSL_SUPPORT 1)
 208 endif()
 209
 210 if (LWS_SSL_CLIENT_USE_OS_CA_CERTS)
 211         set(LWS_SSL_CLIENT_USE_OS_CA_CERTS 1)
 212 endif()
 213
 214 if (LWS_WITH_LATENCY)
 215         set(LWS_LATENCY 1)
 216 endif()
 217
 218 if (LWS_WITHOUT_DAEMONIZE OR WIN32)
 219         set(LWS_NO_DAEMONIZE 1)
 220 endif()
 221
 222 if (LWS_WITHOUT_SERVER)
 223         set(LWS_NO_SERVER 1)
 224 endif()
 225
 226 if (LWS_WITHOUT_CLIENT)
 227         set(LWS_NO_CLIENT 1)
 228 endif()
 229
 230 if (LWS_WITH_LIBEV)
 231         set(LWS_USE_LIBEV 1)
 232 endif()
 233
 234 if (LWS_IPV6)
 235         set(LWS_USE_IPV6 1)
 236 endif()
 237
 238 if (LWS_WITH_HTTP2)
 239         set(LWS_USE_HTTP2 1)
 240 endif()
 241
 242 if (LWS_MBED3)
 243         set(CMAKE_C_FLAGS "-D_DEBUG ${CMAKE_C_FLAGS}")
 244 endif()
 245
 246 if (MINGW)
 247         set(LWS_MINGW_SUPPORT 1)
 248         set(CMAKE_C_FLAGS "-D__USE_MINGW_ANSI_STDIO ${CMAKE_C_FLAGS}")
 249 endif()
 250
 251 include_directories("${PROJECT_BINARY_DIR}")
 252
 253 include(CheckCSourceCompiles)
 254
 255 # Check for different inline keyword versions.
 256 foreach(KEYWORD "inline" "__inline__" "__inline")
 257         set(CMAKE_REQUIRED_DEFINITIONS "-DKEYWORD=${KEYWORD}")
 258         CHECK_C_SOURCE_COMPILES(
 259                 "
 260                 #include <stdio.h>
 261                 static KEYWORD void a() {}
 262                 int main(int argc, char **argv) { a(); return 0; }
 263                 " LWS_HAVE_${KEYWORD})
 264 endforeach()
 265
 266 if (NOT LWS_HAVE_inline)
 267         if (LWS_HAVE___inline__)
 268                 set(inline __inline__)
 269         elseif(LWS_HAVE___inline)
 270                 set(inline __inline)
 271         endif()
 272 endif()
 273
 274 # Put the libaries and binaries that get built into directories at the
 275 # top of the build tree rather than in hard-to-find leaf directories.
 276 SET(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/bin")
 277 SET(CMAKE_LIBRARY_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/lib")
 278 SET(CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${PROJECT_BINARY_DIR}/lib")
 279
 280 # Put absolute path of dynamic libraries into the object code. Some
 281 # architectures, notably Mac OS X, need this.
 282 SET(CMAKE_INSTALL_NAME_DIR "${CMAKE_INSTALL_PREFIX}/${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}")
 283
 284 include(CheckFunctionExists)
 285 include(CheckIncludeFile)
 286 include(CheckIncludeFiles)
 287 include(CheckLibraryExists)
 288 include(CheckTypeSize)
 289
 290 if (LWS_WITHOUT_BUILTIN_SHA1)
 291         set(LWS_SHA1_USE_OPENSSL_NAME 1)
 292 endif()
 293
 294 CHECK_FUNCTION_EXISTS(bzero LWS_HAVE_BZERO)
 295 CHECK_FUNCTION_EXISTS(fork LWS_HAVE_FORK)
 296 CHECK_FUNCTION_EXISTS(getenv LWS_HAVE_GETENV)
 297 CHECK_FUNCTION_EXISTS(malloc LWS_HAVE_MALLOC)
 298 CHECK_FUNCTION_EXISTS(memset LWS_HAVE_MEMSET)
 299 CHECK_FUNCTION_EXISTS(realloc LWS_HAVE_REALLOC)
 300 CHECK_FUNCTION_EXISTS(socket LWS_HAVE_SOCKET)
 301 CHECK_FUNCTION_EXISTS(strerror LWS_HAVE_STRERROR)
 302 CHECK_FUNCTION_EXISTS(vfork LWS_HAVE_VFORK)
 303 CHECK_FUNCTION_EXISTS(getifaddrs LWS_HAVE_GETIFADDRS)
 304
 305 if (NOT LWS_HAVE_GETIFADDRS)
 306         if (LWS_WITHOUT_BUILTIN_GETIFADDRS)
 307                 message(FATAL_ERROR "No getifaddrs was found on the system. Turn off the LWS_WITHOUT_BUILTIN_GETIFADDRS compile option to use the supplied BSD version.")
 308         endif()
 309         set(LWS_BUILTIN_GETIFADDRS 1)
 310 endif()
 311
 312 CHECK_INCLUDE_FILE(dlfcn.h LWS_HAVE_DLFCN_H)
 313 CHECK_INCLUDE_FILE(fcntl.h LWS_HAVE_FCNTL_H)
 314 CHECK_INCLUDE_FILE(in6addr.h LWS_HAVE_IN6ADDR_H)
 315 CHECK_INCLUDE_FILE(inttypes.h LWS_HAVE_INTTYPES_H)
 316 CHECK_INCLUDE_FILE(memory.h LWS_HAVE_MEMORY_H)
 317 CHECK_INCLUDE_FILE(netinet/in.h LWS_HAVE_NETINET_IN_H)
 318 CHECK_INCLUDE_FILE(stdint.h LWS_HAVE_STDINT_H)
 319 CHECK_INCLUDE_FILE(stdlib.h LWS_HAVE_STDLIB_H)
 320 CHECK_INCLUDE_FILE(strings.h LWS_HAVE_STRINGS_H)
 321 CHECK_INCLUDE_FILE(string.h LWS_HAVE_STRING_H)
 322 CHECK_INCLUDE_FILE(sys/prctl.h LWS_HAVE_SYS_PRCTL_H)
 323 CHECK_INCLUDE_FILE(sys/socket.h LWS_HAVE_SYS_SOCKET_H)
 324 CHECK_INCLUDE_FILE(sys/stat.h LWS_HAVE_SYS_STAT_H)
 325 CHECK_INCLUDE_FILE(sys/types.h LWS_HAVE_SYS_TYPES_H)
 326 CHECK_INCLUDE_FILE(unistd.h LWS_HAVE_UNISTD_H)
 327 CHECK_INCLUDE_FILE(vfork.h LWS_HAVE_VFORK_H)
 328
 329 if (LWS_WITH_ZLIB AND NOT LWS_USE_BUNDLED_ZLIB)
 330         CHECK_INCLUDE_FILE(zlib.h LWS_HAVE_ZLIB_H)
 331 endif()
 332
 333 # TODO: These can also be tested to see whether they actually work...
 334 set(LWS_HAVE_WORKING_FORK LWS_HAVE_FORK)
 335 set(LWS_HAVE_WORKING_VFORK LWS_HAVE_VFORK)
 336
 337 CHECK_INCLUDE_FILES("stdlib.h;stdarg.h;string.h;float.h" STDC_HEADERS)
 338
 339 # These don't work Cross...
 340 #CHECK_TYPE_SIZE(pid_t PID_T_SIZE)
 341 #CHECK_TYPE_SIZE(size_t SIZE_T_SIZE)
 342 #CHECK_TYPE_SIZE("void *" LWS_SIZEOFPTR LANGUAGE C)
 343
 344 if (NOT PID_T_SIZE)
 345         set(pid_t int)
 346 endif()
 347
 348 if (NOT SIZE_T_SIZE)
 349         set(size_t "unsigned int")
 350 endif()
 351
 352 if (NOT LWS_HAVE_MALLOC)
 353         set(malloc rpl_malloc)
 354 endif()
 355
 356 if (NOT LWS_HAVE_REALLOC)
 357         set(realloc rpl_realloc)
 358 endif()
 359
 360 # Generate the lws_config.h that includes all the public compilation settings.
 361 configure_file(
 362        "${PROJECT_SOURCE_DIR}/lws_config.h.in"
 363        "${PROJECT_BINARY_DIR}/lws_config.h")
 364
 365 # Generate the lws_config.h that includes all the private compilation settings.
 366 configure_file(
 367        "${PROJECT_SOURCE_DIR}/lws_config_private.h.in"
 368        "${PROJECT_BINARY_DIR}/lws_config_private.h")
 369
 370 if (MSVC)
 371         # Turn off stupid microsoft security warnings.
 372         add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
 373 endif(MSVC)
 374
 375 include_directories("${PROJECT_SOURCE_DIR}/lib")
 376
 377 # Group headers and sources.
 378 # Some IDEs use this for nicer file structure.
 379 set(HDR_PRIVATE
 380         lib/private-libwebsockets.h)
 381
 382 set(HDR_PUBLIC
 383         "${PROJECT_SOURCE_DIR}/lib/libwebsockets.h"
 384         "${PROJECT_BINARY_DIR}/lws_config.h")
 385
 386 set(SOURCES
 387         lib/base64-decode.c
 388         lib/handshake.c
 389         lib/libwebsockets.c
 390         lib/service.c
 391         lib/pollfd.c
 392         lib/output.c
 393         lib/parsers.c
 394         lib/context.c
 395         lib/alloc.c
 396         lib/header.c)
 397
 398 if (NOT LWS_WITHOUT_CLIENT)
 399         list(APPEND SOURCES
 400                 lib/client.c
 401                 lib/client-handshake.c
 402                 lib/client-parser.c)
 403 endif()
 404
 405 if (LWS_WITH_SSL)
 406         list(APPEND SOURCES
 407                 lib/ssl.c)
 408 endif()
 409
 410 if (NOT LWS_WITHOUT_BUILTIN_SHA1)
 411         list(APPEND SOURCES
 412                 lib/sha-1.c)
 413 endif()
 414
 415 if (LWS_WITH_HTTP2)
 416         list(APPEND SOURCES
 417                 lib/http2.c
 418                 lib/hpack.c
 419                 lib/ssl-http2.c)
 420 endif()
 421 # select the active platform files
 422
 423 if (WIN32)
 424         list(APPEND SOURCES
 425                 lib/lws-plat-win.c)
 426 else()
 427         if (LWS_MBED3)
 428                 list(APPEND SOURCES
 429                         lib/lws-plat-mbed3.cpp
 430                         lib/lws-plat-mbed3.c)
 431         else()
 432                 list(APPEND SOURCES
 433                         lib/lws-plat-unix.c)
 434         endif()
 435 endif()
 436
 437 if (NOT LWS_WITHOUT_SERVER)
 438         list(APPEND SOURCES
 439                 lib/server.c
 440                 lib/server-handshake.c)
 441 endif()
 442
 443 if (NOT LWS_WITHOUT_EXTENSIONS)
 444         list(APPEND HDR_PRIVATE
 445                 lib/extension-deflate-frame.h
 446                 lib/extension-deflate-stream.h)
 447         list(APPEND SOURCES
 448                 lib/extension.c
 449                 lib/extension-deflate-frame.c
 450                 lib/extension-deflate-stream.c)
 451 endif()
 452
 453 if (LWS_WITH_LIBEV)
 454         list(APPEND SOURCES
 455                 lib/libev.c)
 456 endif(LWS_WITH_LIBEV)
 457
 458 # Add helper files for Windows.
 459 if (WIN32)
 460         set(WIN32_HELPERS_PATH win32port/win32helpers)
 461         include_directories(${WIN32_HELPERS_PATH})
 462 else()
 463         # Unix.
 464         if (NOT LWS_WITHOUT_DAEMONIZE)
 465                 list(APPEND SOURCES
 466                         lib/daemonize.c)
 467         endif()
 468 endif()
 469
 470 if (UNIX)
 471         if (NOT LWS_HAVE_GETIFADDRS)
 472                 list(APPEND HDR_PRIVATE lib/getifaddrs.h)
 473                 list(APPEND SOURCES lib/getifaddrs.c)
 474         endif()
 475 endif()
 476
 477 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
 478     include (CheckCCompilerFlag)
 479     CHECK_C_COMPILER_FLAG(-fvisibility=hidden LWS_HAVE_VISIBILITY)
 480     if (LWS_HAVE_VISIBILITY)
 481                 set(VISIBILITY_FLAG -fvisibility=hidden)
 482     endif()
 483     if (UNIX)
 484                set(CMAKE_C_FLAGS "-Wall -Werror ${VISIBILITY_FLAG} ${CMAKE_C_FLAGS}" )
 485     else(UNIX)
 486                set(CMAKE_C_FLAGS "-Wall ${VISIBILITY_FLAG} ${CMAKE_C_FLAGS}" )
 487     endif(UNIX)
 488 endif ()
 489
 490 source_group("Headers Private"  FILES ${HDR_PRIVATE})
 491 source_group("Headers Public"   FILES ${HDR_PUBLIC})
 492 source_group("Sources"          FILES ${SOURCES})
 493
 494 #
 495 # Create the lib.
 496 #
 497 set(LWS_LIBRARIES)
 498
 499 if (LWS_WITH_STATIC)
 500         add_library(websockets STATIC
 501                                 ${HDR_PRIVATE}
 502                                 ${HDR_PUBLIC}
 503                                 ${SOURCES})
 504         list(APPEND LWS_LIBRARIES websockets)
 505
 506         if (WIN32)
 507                 # Windows uses the same .lib ending for static libraries and shared
 508                 # library linker files, so rename the static library.
 509                 set_target_properties(websockets
 510                         PROPERTIES
 511                         OUTPUT_NAME websockets_static)
 512         endif()
 513 endif()
 514
 515 if (LWS_WITH_SHARED)
 516         add_library(websockets_shared SHARED
 517                                 ${HDR_PRIVATE}
 518                                 ${HDR_PUBLIC}
 519                                 ${SOURCES})
 520         list(APPEND LWS_LIBRARIES websockets_shared)
 521
 522         # We want the shared lib to be named "libwebsockets"
 523         # not "libwebsocket_shared".
 524         set_target_properties(websockets_shared
 525                 PROPERTIES
 526                 OUTPUT_NAME websockets)
 527
 528         if (WIN32)
 529                 # Compile as DLL (export function declarations)
 530                 set_property(
 531                         TARGET websockets_shared
 532                         PROPERTY COMPILE_DEFINITIONS
 533                         LWS_DLL
 534                         LWS_INTERNAL)
 535         endif()
 536
 537         if (APPLE)
 538                 set_property(TARGET websockets_shared PROPERTY MACOSX_RPATH YES)
 539         endif()
 540 endif()
 541
 542 # Set the so version of the lib.
 543 # Equivalent to LDFLAGS=-version-info x:x:x
 544 if(CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
 545         foreach(lib ${LWS_LIBRARIES})
 546                 set_target_properties(${lib}
 547                         PROPERTIES
 548                         SOVERSION ${SOVERSION})
 549         endforeach()
 550 endif()
 551
 552 set(LIB_LIST)
 553
 554 #
 555 # Find libraries.
 556 #
 557
 558 #
 559 # ZLIB (Only needed for deflate extensions).
 560 #
 561 if (LWS_WITH_ZLIB)
 562         if (LWS_USE_BUNDLED_ZLIB)
 563                 if (WIN32)
 564                         set(WIN32_ZLIB_PATH "win32port/zlib")
 565                         set(ZLIB_SRCS
 566                                 ${WIN32_ZLIB_PATH}/adler32.c
 567                                 ${WIN32_ZLIB_PATH}/compress.c
 568                                 ${WIN32_ZLIB_PATH}/crc32.c
 569                                 ${WIN32_ZLIB_PATH}/deflate.c
 570                                 ${WIN32_ZLIB_PATH}/gzclose.c
 571                                 ${WIN32_ZLIB_PATH}/gzio.c
 572                                 ${WIN32_ZLIB_PATH}/gzlib.c
 573                                 ${WIN32_ZLIB_PATH}/gzread.c
 574                                 ${WIN32_ZLIB_PATH}/gzwrite.c
 575                                 ${WIN32_ZLIB_PATH}/infback.c
 576                                 ${WIN32_ZLIB_PATH}/inffast.c
 577                                 ${WIN32_ZLIB_PATH}/inflate.c
 578                                 ${WIN32_ZLIB_PATH}/inftrees.c
 579                                 ${WIN32_ZLIB_PATH}/trees.c
 580                                 ${WIN32_ZLIB_PATH}/uncompr.c
 581                                 ${WIN32_ZLIB_PATH}/zutil.c)
 582                         add_library(zlib_internal STATIC ${ZLIB_SRCS})
 583                         set(ZLIB_INCLUDE_DIRS ${WIN32_ZLIB_PATH})
 584                         get_property(ZLIB_LIBRARIES TARGET zlib_internal PROPERTY LOCATION)
 585                         set(ZLIB_FOUND 1)
 586                         # Make sure zlib_internal is compiled before the libs.
 587                         foreach (lib ${LWS_LIBRARIES})
 588                                 add_dependencies(${lib} zlib_internal)
 589                         endforeach()
 590                 else()
 591                         message(FATAL_ERROR "Don't have bundled zlib for that platform")
 592                 endif()
 593         elseif (NOT ZLIB_FOUND)
 594                 find_package(ZLIB REQUIRED)
 595         endif()
 596         message("zlib include dirs: ${ZLIB_INCLUDE_DIRS}")
 597         message("zlib libraries: ${ZLIB_LIBRARIES}")
 598         include_directories(${ZLIB_INCLUDE_DIRS})
 599         list(APPEND LIB_LIST ${ZLIB_LIBRARIES})
 600 endif()
 601
 602 #
 603 # OpenSSL
 604 #
 605 if (LWS_WITH_SSL)
 606         message("Compiling with SSL support")
 607
 608         if (LWS_USE_WOLFSSL)
 609                 # Use wolfSSL as OpenSSL replacement.
 610                 # TODO: Add a find_package command for this also.
 611                 message("wolfSSL include dir: ${WOLFSSL_INCLUDE_DIRS}")
 612                 message("wolfSSL libraries: ${WOLFSSL_LIBRARIES}")
 613
 614                 # Additional to the root directory we need to include
 615                 # the wolfssl/ subdirectory which contains the OpenSSL
 616                 # compatability layer headers.
 617
 618                 if (LWS_USE_CYASSL)
 619                         foreach(inc ${WOLFSSL_INCLUDE_DIRS})
 620                                 include_directories("${inc}" "${inc}/cyassl")
 621                         endforeach()
 622                 else()
 623                         foreach(inc ${WOLFSSL_INCLUDE_DIRS})
 624                                 include_directories("${inc}" "${inc}/wolfssl")
 625                         endforeach()
 626                 endif()
 627
 628                 list(APPEND LIB_LIST "${WOLFSSL_LIBRARIES}")
 629         else()
 630                 if (NOT OPENSSL_FOUND)
 631                         # TODO: Add support for STATIC also.
 632                         find_package(OpenSSL REQUIRED)
 633                         set(OPENSSL_INCLUDE_DIRS "${OPENSSL_INCLUDE_DIR}")
 634                 endif()
 635
 636                 message("OpenSSL include dir: ${OPENSSL_INCLUDE_DIRS}")
 637                 message("OpenSSL libraries: ${OPENSSL_LIBRARIES}")
 638
 639                 include_directories("${OPENSSL_INCLUDE_DIRS}")
 640                 list(APPEND LIB_LIST ${OPENSSL_LIBRARIES})
 641         endif()
 642 endif(LWS_WITH_SSL)
 643
 644 if (LWS_WITH_LIBEV)
 645         if (NOT LIBEV_FOUND)
 646                 find_path(LIBEV_INCLUDE_DIRS NAMES ev.h)
 647                 find_library(LIBEV_LIBRARIES NAMES ev)
 648                 if(LIBEV_INCLUDE_DIRS AND LIBEV_LIBRARIES)
 649                         set(LIBEV_FOUND 1)
 650                 endif()
 651         endif()
 652         message("libev include dir: ${LIBEV_INCLUDE_DIRS}")
 653         message("libev libraries: ${LIBEV_LIBRARIES}")
 654         include_directories("${LIBEV_INCLUDE_DIRS}")
 655         list(APPEND LIB_LIST ${LIBEV_LIBRARIES})
 656 endif(LWS_WITH_LIBEV)
 657
 658 #
 659 # Platform specific libs.
 660 #
 661 if (WINCE)
 662         list(APPEND LIB_LIST ws2.lib)
 663 elseif (WIN32)
 664         list(APPEND LIB_LIST ws2_32.lib)
 665 endif()
 666
 667 if (UNIX)
 668         list(APPEND LIB_LIST m)
 669 endif()
 670
 671 # Setup the linking for all libs.
 672 foreach (lib ${LWS_LIBRARIES})
 673         target_link_libraries(${lib} ${LIB_LIST})
 674 endforeach()
 675
 676 #
 677 # Test applications
 678 #
 679 set(TEST_APP_LIST)
 680 if (NOT LWS_WITHOUT_TESTAPPS)
 681         #
 682         # Helper function for adding a test app.
 683         #
 684         macro(create_test_app TEST_NAME MAIN_SRC S2 S3 S4)
 685
 686                 set(TEST_SRCS ${MAIN_SRC})
 687                 set(TEST_HDR)
 688                 if ("${S2}" STREQUAL "")
 689                 else()
 690                         list(APPEND TEST_SRCS ${S2})
 691                 endif()
 692                 if ("${S3}" STREQUAL "")
 693                 else()
 694                         list(APPEND TEST_SRCS ${S3})
 695                 endif()
 696                 if ("${S4}" STREQUAL "")
 697                 else()
 698                         list(APPEND TEST_SRCS ${S4})
 699                 endif()
 700                 if (WIN32)
 701                         list(APPEND TEST_SRCS
 702                                 ${WIN32_HELPERS_PATH}/getopt.c
 703                                 ${WIN32_HELPERS_PATH}/getopt_long.c
 704                                 ${WIN32_HELPERS_PATH}/gettimeofday.c
 705                         )
 706
 707                         list(APPEND TEST_HDR
 708                                 ${WIN32_HELPERS_PATH}/getopt.h
 709                                 ${WIN32_HELPERS_PATH}/gettimeofday.h
 710                         )
 711                 endif(WIN32)
 712
 713                 source_group("Headers Private"   FILES ${TEST_HDR})
 714                 source_group("Sources"   FILES ${TEST_SRCS})
 715                 add_executable(${TEST_NAME} ${TEST_SRCS} ${TEST_HDR})
 716
 717                 if (LWS_LINK_TESTAPPS_DYNAMIC)
 718                         if (NOT LWS_WITH_SHARED)
 719                                 message(FATAL_ERROR "Build of the shared library is disabled. LWS_LINK_TESTAPPS_DYNAMIC must be combined with LWS_WITH_SHARED.")
 720                         endif()
 721                         target_link_libraries(${TEST_NAME} websockets_shared)
 722                         add_dependencies(${TEST_NAME} websockets_shared)
 723                 else()
 724                         if (NOT LWS_WITH_STATIC)
 725                                 message(FATAL_ERROR "Build of the static library is disabled. Disabled LWS_LINK_TESTAPPS_DYNAMIC must be combined with LWS_WITH_STATIC.")
 726                         endif()
 727                         target_link_libraries(${TEST_NAME} websockets)
 728                         add_dependencies(${TEST_NAME} websockets)
 729                 endif()
 730
 731                 # Set test app specific defines.
 732                 set_property(TARGET ${TEST_NAME}
 733                                         PROPERTY COMPILE_DEFINITIONS
 734                                                 INSTALL_DATADIR="${CMAKE_INSTALL_PREFIX}/share"
 735                                         )
 736
 737                 # Prefix the binary names with libwebsockets.
 738                 set_target_properties(${TEST_NAME}
 739                         PROPERTIES
 740                         OUTPUT_NAME libwebsockets-${TEST_NAME})
 741
 742                 # Add to the list of tests.
 743                 list(APPEND TEST_APP_LIST ${TEST_NAME})
 744         endmacro()
 745
 746         if (LWS_WITH_SSL AND NOT LWS_USE_WOLFSSL)
 747                 message("Searching for OpenSSL executable and dlls")
 748                 find_package(OpenSSLbins)
 749                 message("OpenSSL executable: ${OPENSSL_EXECUTABLE}")
 750         endif()
 751
 752         if (NOT LWS_WITHOUT_SERVER)
 753                 #
 754                 # test-server
 755                 #
 756                 if (NOT LWS_WITHOUT_TEST_SERVER)
 757                         create_test_app(test-server "test-server/test-server.c" "test-server/test-server-http.c" "test-server/test-server-dumb-increment.c" "test-server/test-server-mirror.c")
 758                 endif()
 759
 760                 #
 761                 # test-server-extpoll
 762                 #
 763                 if (NOT LWS_WITHOUT_TEST_SERVER_EXTPOLL)
 764                         create_test_app(test-server-extpoll "test-server/test-server.c" "test-server/test-server-http.c" "test-server/test-server-dumb-increment.c" "test-server/test-server-mirror.c")
 765                         # Set defines for this executable only.
 766                         set_property(
 767                                 TARGET test-server-extpoll
 768                                 PROPERTY COMPILE_DEFINITIONS
 769                                         EXTERNAL_POLL
 770                                         INSTALL_DATADIR="${CMAKE_INSTALL_PREFIX}/share"
 771                                 )
 772
 773                         # We need to link against winsock code.
 774                         if (WIN32)
 775                                 target_link_libraries(test-server-extpoll ws2_32.lib)
 776                         endif(WIN32)
 777                 endif()
 778
 779                 # Data files for running the test server.
 780                 set(TEST_SERVER_DATA
 781                         "${PROJECT_SOURCE_DIR}/test-server/favicon.ico"
 782                         "${PROJECT_SOURCE_DIR}/test-server/leaf.jpg"
 783                         "${PROJECT_SOURCE_DIR}/test-server/libwebsockets.org-logo.png"
 784                         "${PROJECT_SOURCE_DIR}/test-server/test.html")
 785
 786                 # Generate self-signed SSL certs for the test-server.
 787                 if (LWS_WITH_SSL AND OPENSSL_EXECUTABLE AND NOT LWS_WITHOUT_TEST_SERVER)
 788                         message("Generating SSL Certificates for the test-server...")
 789
 790                         set(TEST_SERVER_SSL_KEY "${PROJECT_BINARY_DIR}/libwebsockets-test-server.key.pem")
 791                         set(TEST_SERVER_SSL_CERT "${PROJECT_BINARY_DIR}/libwebsockets-test-server.pem")
 792
 793                         if (WIN32)
 794                                 if (MINGW)
 795                                         message("cmd = \"${OPENSSL_EXECUTABLE}\" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -subj \"/C=GB/ST=Erewhon/L=All around/O=libwebsockets-test/CN=localhost\" -keyout \"${TEST_SERVER_SSL_KEY}\" -out \"${TEST_SERVER_SSL_CERT}\"")
 796                                         execute_process(
 797                                                 COMMAND "${OPENSSL_EXECUTABLE}" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -subj "/C=GB/ST=Erewhon/L=All around/O=libwebsockets-test/CN=localhost" -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 798                                                 RESULT_VARIABLE OPENSSL_RETURN_CODE)
 799                                 else()
 800                                         file(WRITE "${PROJECT_BINARY_DIR}/openssl_input.txt"
 801                                                 "GB\n"
 802                                                 "Erewhon\n"
 803                                                 "All around\n"
 804                                                 "libwebsockets-test\n"
 805                                                 "localhost\n"
 806                                                 "none@invalid.org\n\n"
 807                                                 )
 808
 809                                         # The "type" command is a bit picky with paths.
 810                                         file(TO_NATIVE_PATH "${PROJECT_BINARY_DIR}/openssl_input.txt" OPENSSL_INPUT_WIN_PATH)
 811                                         message("OPENSSL_INPUT_WIN_PATH = ${OPENSSL_INPUT_WIN_PATH}")
 812                                         message("cmd = \"${OPENSSL_EXECUTABLE}\" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout \"${TEST_SERVER_SSL_KEY}\" -out \"${TEST_SERVER_SSL_CERT}\"")
 813
 814                                         execute_process(
 815                                                 COMMAND cmd /c type "${OPENSSL_INPUT_WIN_PATH}"
 816                                                 COMMAND "${OPENSSL_EXECUTABLE}" req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 817                                                 RESULT_VARIABLE OPENSSL_RETURN_CODE
 818                                                 OUTPUT_QUIET ERROR_QUIET)
 819
 820                                         message("\n")
 821                                 endif()
 822
 823                                 if (OPENSSL_RETURN_CODE)
 824                                         message(WARNING "!!! Failed to generate SSL certificate for Test Server using cmd.exe !!!:\nOpenSSL return code = ${OPENSSL_RETURN_CODE}")
 825                                 else()
 826                                         message("SUCCSESFULLY generated SSL certificate")
 827                                 endif()
 828                         else()
 829                                 # Unix.
 830                                 execute_process(
 831                                         COMMAND printf "GB\\nErewhon\\nAll around\\nlibwebsockets-test\\n\\nlocalhost\\nnone@invalid.org\\n"
 832                                         COMMAND "${OPENSSL_EXECUTABLE}"
 833                                                 req -new -newkey rsa:1024 -days 10000 -nodes -x509 -keyout "${TEST_SERVER_SSL_KEY}" -out "${TEST_SERVER_SSL_CERT}"
 834                                         RESULT_VARIABLE OPENSSL_RETURN_CODE
 835                                         OUTPUT_QUIET ERROR_QUIET)
 836
 837                                 if (OPENSSL_RETURN_CODE)
 838                                         message(WARNING "!!! Failed to generate SSL certificate for Test Server!!!:\nOpenSSL return code = ${OPENSSL_RETURN_CODE}")
 839                                 else()
 840                                         message("SUCCESSFULLY generated SSL certificate")
 841                                 endif()
 842                         endif()
 843
 844                         list(APPEND TEST_SERVER_DATA
 845                                 "${TEST_SERVER_SSL_KEY}"
 846                                 "${TEST_SERVER_SSL_CERT}")
 847                 endif()
 848
 849                 add_custom_command(TARGET test-server
 850                                                 POST_BUILD
 851                                                 COMMAND "${CMAKE_COMMAND}" -E make_directory "$<TARGET_FILE_DIR:test-server>/../share/libwebsockets-test-server")
 852
 853                 # Copy the file needed to run the server so that the test apps can
 854                 # reach them from their default output location
 855                 foreach (TEST_FILE ${TEST_SERVER_DATA})
 856                         if (EXISTS ${TEST_FILE})
 857                                 add_custom_command(TARGET test-server
 858                                                         POST_BUILD
 859                                                         COMMAND "${CMAKE_COMMAND}" -E copy "${TEST_FILE}" "$<TARGET_FILE_DIR:test-server>/../share/libwebsockets-test-server" VERBATIM)
 860                         endif()
 861                 endforeach()
 862         endif(NOT LWS_WITHOUT_SERVER)
 863
 864         if (NOT LWS_WITHOUT_CLIENT)
 865                 #
 866                 # test-client
 867                 #
 868                 if (NOT LWS_WITHOUT_TEST_CLIENT)
 869                         create_test_app(test-client "test-server/test-client.c" "" "" "")
 870                 endif()
 871
 872                 #
 873                 # test-fraggle
 874                 #
 875                 if (NOT LWS_WITHOUT_TEST_FRAGGLE)
 876                         create_test_app(test-fraggle "test-server/test-fraggle.c" "" "" "")
 877                 endif()
 878
 879                 #
 880                 # test-ping
 881                 #
 882                 if (NOT LWS_WITHOUT_TEST_PING)
 883                         create_test_app(test-ping "test-server/test-ping.c" "" "" "")
 884                 endif()
 885                 #
 886                 # test-echo
 887                 #
 888                 if (NOT WITHOUT_TEST_ECHO)
 889                         create_test_app(test-echo "test-server/test-echo.c" "" "" "")
 890                 endif()
 891
 892         endif(NOT LWS_WITHOUT_CLIENT)
 893
 894         #
 895         # Copy OpenSSL dlls to the output directory on Windows.
 896         # (Otherwise we'll get an error when trying to run)
 897         #
 898         if (WIN32 AND LWS_WITH_SSL AND NOT LWS_USE_WOLFSSL)
 899                 if(OPENSSL_BIN_FOUND)
 900                         message("OpenSSL dlls found:")
 901                         message("  Libeay: ${LIBEAY_BIN}")
 902                         message("  SSLeay: ${SSLEAY_BIN}")
 903
 904                         foreach(TARGET_BIN ${TEST_APP_LIST})
 905                                 add_custom_command(TARGET ${TARGET_BIN}
 906                                         POST_BUILD
 907                                         COMMAND "${CMAKE_COMMAND}" -E copy "${LIBEAY_BIN}" "$<TARGET_FILE_DIR:${TARGET_BIN}>" VERBATIM)
 908                                 add_custom_command(TARGET ${TARGET_BIN}
 909                                         POST_BUILD
 910                                         COMMAND "${CMAKE_COMMAND}" -E copy "${SSLEAY_BIN}" "$<TARGET_FILE_DIR:${TARGET_BIN}>" VERBATIM)
 911                         endforeach()
 912                 endif()
 913         endif()
 914 endif(NOT LWS_WITHOUT_TESTAPPS)
 915
 916 if (UNIX)
 917         # Generate documentation.
 918         # TODO: Fix this on Windows.
 919         message("Generating API documentation")
 920         file(GLOB C_FILES "${PROJECT_SOURCE_DIR}/lib/*.c")
 921         execute_process(COMMAND "${CMAKE_COMMAND}" -E make_directory "${PROJECT_BINARY_DIR}/doc/")
 922
 923         execute_process(
 924                 COMMAND "${PROJECT_SOURCE_DIR}/scripts/kernel-doc" -html ${C_FILES} ${HDR_PUBLIC}
 925                 OUTPUT_FILE "${PROJECT_BINARY_DIR}/doc/libwebsockets-api-doc.html"
 926                 ERROR_QUIET)
 927
 928         execute_process(
 929                 COMMAND "${PROJECT_SOURCE_DIR}/scripts/kernel-doc" -text ${C_FILES} ${HDR_PUBLIC}
 930                 OUTPUT_FILE "${PROJECT_BINARY_DIR}/doc/libwebsockets-api-doc.txt"
 931                 ERROR_QUIET)
 932
 933 # Generate and install pkgconfig.
 934 # (This is not indented, because the tabs will be part of the output)
 935 file(WRITE "${PROJECT_BINARY_DIR}/libwebsockets.pc"
 936 "prefix=\"${CMAKE_INSTALL_PREFIX}\"
 937 exec_prefix=\${prefix}
 938 libdir=\${exec_prefix}/lib${LIB_SUFFIX}
 939 includedir=\${prefix}/include
 940
 941 Name: libwebsockets
 942 Description: Websockets server and client library
 943 Version: ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}
 944
 945 Libs: -L\${libdir} -lwebsockets
 946 Cflags: -I\${includedir}"
 947 )
 948
 949         install(FILES "${PROJECT_BINARY_DIR}/libwebsockets.pc"
 950                 DESTINATION lib${LIB_SUFFIX}/pkgconfig)
 951 endif(UNIX)
 952
 953 #
 954 # Installation preparations.
 955 #
 956
 957 if(WIN32 AND NOT CYGWIN)
 958   set(DEF_INSTALL_CMAKE_DIR cmake)
 959 else()
 960   set(DEF_INSTALL_CMAKE_DIR lib/cmake/libwebsockets)
 961 endif()
 962
 963 set(LWS_INSTALL_CMAKE_DIR ${DEF_INSTALL_CMAKE_DIR} CACHE PATH "Installation directory for CMake files")
 964
 965 # Export targets (This is used for other CMake projects to easily find the libraries and include files).
 966 export(TARGETS ${LWS_LIBRARIES}
 967         FILE "${PROJECT_BINARY_DIR}/LibwebsocketsTargets.cmake")
 968 export(PACKAGE libwebsockets)
 969
 970 # Generate the config file for the build-tree.
 971 set(LWS__INCLUDE_DIRS
 972     "${PROJECT_SOURCE_DIR}/lib"
 973     "${PROJECT_BINARY_DIR}")
 974 set(LIBWEBSOCKETS_INCLUDE_DIRS ${LWS__INCLUDE_DIRS} CACHE PATH "Libwebsockets include directories")
 975 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfig.cmake.in
 976                 ${PROJECT_BINARY_DIR}/LibwebsocketsConfig.cmake
 977                 @ONLY)
 978
 979 # Generate the config file for the installation tree.
 980 get_filename_component(LWS_ABSOLUTE_INSTALL_CMAKE_DIR ${LWS_INSTALL_CMAKE_DIR} ABSOLUTE)
 981 get_filename_component(LWS_ABSOLUTE_INSTALL_INCLUDE_DIR ${LWS_INSTALL_INCLUDE_DIR} ABSOLUTE)
 982 file(RELATIVE_PATH
 983     REL_INCLUDE_DIR
 984     "${LWS_ABSOLUTE_INSTALL_CMAKE_DIR}"
 985     "${LWS_ABSOLUTE_INSTALL_INCLUDE_DIR}") # Calculate the relative directory from the cmake dir.
 986
 987 # Note the EVENT_CMAKE_DIR is defined in JanssonConfig.cmake.in,
 988 # we escape it here so it's evaluated when it is included instead
 989 # so that the include dirs are given relative to where the
 990 # config file is located.
 991 set(LWS__INCLUDE_DIRS
 992     "\${LWS_CMAKE_DIR}/${REL_INCLUDE_DIR}")
 993 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfig.cmake.in
 994                 ${PROJECT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/LibwebsocketsConfig.cmake
 995                 @ONLY)
 996
 997 # Generate version info for both build-tree and install-tree.
 998 configure_file(${PROJECT_SOURCE_DIR}/cmake/LibwebsocketsConfigVersion.cmake.in
 999                 ${PROJECT_BINARY_DIR}/LibwebsocketsConfigVersion.cmake
1000                 @ONLY)
1001
1002                         set_target_properties(${LWS_LIBRARIES}
1003                                         PROPERTIES PUBLIC_HEADER "${HDR_PUBLIC}")
1004
1005 #
1006 # Installation.
1007 #
1008
1009 # Install libs and headers.
1010 install(TARGETS ${LWS_LIBRARIES}
1011                 EXPORT LibwebsocketsTargets
1012                 LIBRARY DESTINATION "${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}" COMPONENT libraries
1013                 ARCHIVE DESTINATION "${LWS_INSTALL_LIB_DIR}${LIB_SUFFIX}" COMPONENT libraries
1014                 RUNTIME DESTINATION "${LWS_INSTALL_BIN_DIR}" COMPONENT libraries # Windows DLLs
1015                 PUBLIC_HEADER DESTINATION "${LWS_INSTALL_INCLUDE_DIR}" COMPONENT dev)
1016 set(CPACK_COMPONENT_LIBRARIES_DISPLAY_NAME "Libraries")
1017 set(CPACK_COMPONENT_DEV_DISPLAY_NAME "Development files")
1018
1019 # Install test apps.
1020 if (NOT LWS_WITHOUT_TESTAPPS AND NOT LWS_WITHOUT_CLIENT)
1021         install(TARGETS test-client ${TEST_APP_LIST}
1022                         RUNTIME DESTINATION ${LWS_INSTALL_EXAMPLES_DIR}
1023                         COMPONENT examples)
1024         set(CPACK_COMPONENT_EXAMPLES_DISPLAY_NAME "Example files")
1025 endif()
1026
1027 # Programs shared files used by the test-server.
1028 if (NOT LWS_WITHOUT_TESTAPPS AND NOT LWS_WITHOUT_SERVER)
1029         install(FILES ${TEST_SERVER_DATA}
1030                         DESTINATION share/libwebsockets-test-server
1031                         COMPONENT examples)
1032 endif()
1033
1034 # build subdir is not part of sources
1035 set(CPACK_SOURCE_IGNORE_FILES $(CPACK_SOURCE_IGNORE_FILES) ".git" "build" "tgz" "tar.gz")
1036
1037 # Most people are more used to "make dist" compared to "make package_source"
1038 add_custom_target(dist COMMAND "${CMAKE_MAKE_PROGRAM}" package_source)
1039
1040 include(UseRPMTools)
1041 if (RPMTools_FOUND)
1042         RPMTools_ADD_RPM_TARGETS(libwebsockets libwebsockets.spec)
1043 endif()
1044
1045 message("---------------------------------------------------------------------")
1046 message("  Settings:  (For more help do cmake -LH <srcpath>)")
1047 message("---------------------------------------------------------------------")
1048 message(" LWS_WITH_STATIC = ${LWS_WITH_STATIC}")
1049 message(" LWS_WITH_SHARED = ${LWS_WITH_SHARED}")
1050 message(" LWS_WITH_SSL = ${LWS_WITH_SSL} (SSL Support)")
1051 message(" LWS_SSL_CLIENT_USE_OS_CA_CERTS = ${LWS_SSL_CLIENT_USE_OS_CA_CERTS}")
1052 message(" LWS_USE_WOLFSSL = ${LWS_USE_WOLFSSL} (wolfSSL/CyaSSL replacement for OpenSSL)")
1053 if (LWS_USE_WOLFSSL)
1054         message("   LWS_WOLFSSL_LIBRARIES = ${LWS_WOLFSSL_LIBRARIES}")
1055         message("   LWS_WOLFSSL_INCLUDE_DIRS = ${LWS_WOLFSSL_INCLUDE_DIRS}")
1056 endif()
1057 message(" LWS_WITHOUT_BUILTIN_SHA1 = ${LWS_WITHOUT_BUILTIN_SHA1}")
1058 message(" LWS_WITHOUT_BUILTIN_GETIFADDRS = ${LWS_WITHOUT_BUILTIN_GETIFADDRS}")
1059 message(" LWS_WITHOUT_CLIENT = ${LWS_WITHOUT_CLIENT}")
1060 message(" LWS_WITHOUT_SERVER = ${LWS_WITHOUT_SERVER}")
1061 message(" LWS_LINK_TESTAPPS_DYNAMIC = ${LWS_LINK_TESTAPPS_DYNAMIC}")
1062 message(" LWS_WITHOUT_TESTAPPS = ${LWS_WITHOUT_TESTAPPS}")
1063 message(" LWS_WITHOUT_TEST_SERVER = ${LWS_WITHOUT_TEST_SERVER}")
1064 message(" LWS_WITHOUT_TEST_SERVER_EXTPOLL = ${LWS_WITHOUT_TEST_SERVER_EXTPOLL}")
1065 message(" LWS_WITHOUT_TEST_PING = ${LWS_WITHOUT_TEST_PING}")
1066 message(" LWS_WITHOUT_TEST_CLIENT = ${LWS_WITHOUT_TEST_CLIENT}")
1067 message(" LWS_WITHOUT_TEST_FRAGGLE = ${LWS_WITHOUT_TEST_FRAGGLE}")
1068 message(" LWS_WITHOUT_EXTENSIONS = ${LWS_WITHOUT_EXTENSIONS}")
1069 message(" LWS_WITH_LATENCY = ${LWS_WITH_LATENCY}")
1070 message(" LWS_WITHOUT_DAEMONIZE = ${LWS_WITHOUT_DAEMONIZE}")
1071 message(" LWS_USE_LIBEV = ${LWS_USE_LIBEV}")
1072 message(" LWS_IPV6 = ${LWS_IPV6}")
1073 message(" LWS_WITH_HTTP2 = ${LWS_WITH_HTTP2}")
1074 message(" LWS_MBED3 = ${LWS_MBED3}")
1075 message("---------------------------------------------------------------------")
1076
1077 # These will be available to parent projects including libwebsockets using add_subdirectory()
1078 set(LIBWEBSOCKETS_LIBRARIES ${LWS_LIBRARIES} CACHE STRING "Libwebsocket libraries")
1079 if (LWS_WITH_STATIC)
1080         set(LIBWEBSOCKETS_LIBRARIES_STATIC websocket CACHE STRING "Libwebsocket static library")
1081 endif()
1082 if (LWS_WITH_SHARED)
1083         set(LIBWEBSOCKETS_LIBRARIES_SHARED websockets_shared CACHE STRING "Libwebsocket shared library")
1084 endif()
1085
1086 # This must always be last!
1087 include(CPack)