CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 # ----------------------------------------------------------------------------
   8
   9 # Disable in-source builds to prevent source tree corruption.
  10 if(" ${CMAKE_SOURCE_DIR}" STREQUAL " ${CMAKE_BINARY_DIR}")
  11   message(FATAL_ERROR "
  12 FATAL: In-source builds are not allowed.
  13        You should create a separate directory for build files.
  14 ")
  15 endif()
  16
  17
  18 include(cmake/OpenCVMinDepVersions.cmake)
  19
  20 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  21   cmake_minimum_required(VERSION 3.0 FATAL_ERROR)
  22 elseif(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  23   cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
  24   #Required to resolve linker error issues due to incompatibility with CMake v3.0+ policies.
  25   #CMake fails to find _fseeko() which leads to subsequent linker error.
  26   #See details here: http://www.cmake.org/Wiki/CMake/Policies
  27   cmake_policy(VERSION 2.8)
  28 else()
  29   cmake_minimum_required(VERSION "${MIN_VER_CMAKE}" FATAL_ERROR)
  30 endif()
  31
  32 # Following block can break build in case of cross-compilng
  33 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  34 # so we will try to detect cross-compiling by presense of CMAKE_TOOLCHAIN_FILE
  35 if(NOT DEFINED CMAKE_INSTALL_PREFIX)
  36   if(NOT CMAKE_TOOLCHAIN_FILE)
  37     # it _must_ go before project(OpenCV) in order to work
  38     if(WIN32)
  39       set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  40     else()
  41       set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  42     endif()
  43   else(NOT CMAKE_TOOLCHAIN_FILE)
  44     #Android: set output folder to ${CMAKE_BINARY_DIR}
  45     set( LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  46     # any cross-compiling
  47     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  48   endif(NOT CMAKE_TOOLCHAIN_FILE)
  49 endif()
  50
  51 if(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  52   set(WINRT TRUE)
  53 endif(CMAKE_SYSTEM_NAME MATCHES WindowsPhone OR CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  54
  55 if(WINRT)
  56   add_definitions(-DWINRT -DNO_GETENV)
  57
  58   # Making definitions available to other configurations and
  59   # to filter dependency restrictions at compile time.
  60   if(CMAKE_SYSTEM_NAME MATCHES WindowsPhone)
  61     set(WINRT_PHONE TRUE)
  62     add_definitions(-DWINRT_PHONE)
  63   elseif(CMAKE_SYSTEM_NAME MATCHES WindowsStore)
  64     set(WINRT_STORE TRUE)
  65     add_definitions(-DWINRT_STORE)
  66   endif()
  67
  68   if(CMAKE_SYSTEM_VERSION MATCHES 10)
  69     set(WINRT_10 TRUE)
  70     add_definitions(-DWINRT_10)
  71   elseif(CMAKE_SYSTEM_VERSION MATCHES 8.1)
  72     set(WINRT_8_1 TRUE)
  73     add_definitions(-DWINRT_8_1)
  74   elseif(CMAKE_SYSTEM_VERSION MATCHES 8.0)
  75     set(WINRT_8_0 TRUE)
  76     add_definitions(-DWINRT_8_0)
  77   endif()
  78 endif()
  79
  80 if(POLICY CMP0026)
  81   cmake_policy(SET CMP0026 NEW)
  82 endif()
  83
  84 if(POLICY CMP0042)
  85   cmake_policy(SET CMP0042 NEW)
  86 endif()
  87
  88 if(POLICY CMP0046)
  89   cmake_policy(SET CMP0046 NEW)
  90 endif()
  91
  92 if(POLICY CMP0051)
  93   cmake_policy(SET CMP0051 NEW)
  94 endif()
  95
  96 if(POLICY CMP0056)
  97   cmake_policy(SET CMP0056 NEW)
  98 endif()
  99
 100 if(POLICY CMP0067)
 101   cmake_policy(SET CMP0067 NEW)
 102 endif()
 103
 104 include(cmake/OpenCVUtils.cmake)
 105
 106 # must go before the project command
 107 ocv_update(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
 108 if(DEFINED CMAKE_BUILD_TYPE)
 109   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
 110 endif()
 111
 112 enable_testing()
 113
 114 project(OpenCV CXX C)
 115
 116 if(MSVC)
 117   set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
 118 endif()
 119
 120 ocv_cmake_eval(DEBUG_PRE ONCE)
 121
 122 ocv_clear_vars(OpenCVModules_TARGETS)
 123
 124 include(cmake/OpenCVDownload.cmake)
 125
 126 # ----------------------------------------------------------------------------
 127 # Break in case of popular CMake configuration mistakes
 128 # ----------------------------------------------------------------------------
 129 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
 130   message(FATAL_ERROR "CMake fails to determine the bitness of the target platform.
 131   Please check your CMake and compiler installation. If you are cross-compiling then ensure that your CMake toolchain file correctly sets the compiler details.")
 132 endif()
 133
 134 # ----------------------------------------------------------------------------
 135 # Detect compiler and target platform architecture
 136 # ----------------------------------------------------------------------------
 137 OCV_OPTION(ENABLE_CXX11 "Enable C++11 compilation mode" "${OPENCV_CXX11}")
 138 include(cmake/OpenCVDetectCXXCompiler.cmake)
 139
 140 # Add these standard paths to the search paths for FIND_LIBRARY
 141 # to find libraries from these locations first
 142 if(UNIX AND NOT ANDROID)
 143   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
 144     if(EXISTS /lib64)
 145       list(APPEND CMAKE_LIBRARY_PATH /lib64)
 146     else()
 147       list(APPEND CMAKE_LIBRARY_PATH /lib)
 148     endif()
 149     if(EXISTS /usr/lib64)
 150       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
 151     else()
 152       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 153     endif()
 154   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
 155     if(EXISTS /lib32)
 156       list(APPEND CMAKE_LIBRARY_PATH /lib32)
 157     else()
 158       list(APPEND CMAKE_LIBRARY_PATH /lib)
 159     endif()
 160     if(EXISTS /usr/lib32)
 161       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 162     else()
 163       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 164     endif()
 165   endif()
 166 endif()
 167
 168 # Add these standard paths to the search paths for FIND_PATH
 169 # to find include files from these locations first
 170 if(MINGW)
 171   if(EXISTS /mingw)
 172       list(APPEND CMAKE_INCLUDE_PATH /mingw)
 173   endif()
 174   if(EXISTS /mingw32)
 175       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
 176   endif()
 177   if(EXISTS /mingw64)
 178       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 179   endif()
 180 endif()
 181
 182 # ----------------------------------------------------------------------------
 183 # OpenCV cmake options
 184 # ----------------------------------------------------------------------------
 185
 186 OCV_OPTION(OPENCV_ENABLE_NONFREE "Enable non-free algorithms" OFF)
 187
 188 # Optional 3rd party components
 189 # ===================================================
 190 OCV_OPTION(WITH_1394           "Include IEEE1394 support"                    ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 191 OCV_OPTION(WITH_AVFOUNDATION   "Use AVFoundation for Video I/O (iOS/Mac)"    ON   IF APPLE)
 192 OCV_OPTION(WITH_CARBON         "Use Carbon for UI instead of Cocoa"          OFF  IF APPLE )
 193 OCV_OPTION(WITH_CAROTENE       "Use NVidia carotene acceleration library for ARM platform"                   ON  IF (ARM OR AARCH64) AND NOT IOS AND NOT (CMAKE_VERSION VERSION_LESS "2.8.11"))
 194 OCV_OPTION(WITH_CPUFEATURES    "Use cpufeatures Android library"             ON   IF ANDROID)
 195 OCV_OPTION(WITH_VTK            "Include VTK library support (and build opencv_viz module eiher)"             ON  IF (NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT CMAKE_CROSSCOMPILING) )
 196 OCV_OPTION(WITH_CUDA           "Include NVidia Cuda Runtime support"                                         ON  IF (NOT IOS AND NOT WINRT) )
 197 OCV_OPTION(WITH_CUFFT          "Include NVidia Cuda Fast Fourier Transform (FFT) library support"            ON  IF (NOT IOS AND NOT WINRT) )
 198 OCV_OPTION(WITH_CUBLAS         "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" ON IF (NOT IOS AND NOT WINRT) )
 199 OCV_OPTION(WITH_NVCUVID        "Include NVidia Video Decoding library support"                               ON IF (NOT IOS AND NOT APPLE) )
 200 OCV_OPTION(WITH_EIGEN          "Include Eigen2/Eigen3 support"               ON   IF (NOT WINRT) )
 201 OCV_OPTION(WITH_VFW            "Include Video for Windows support"           ON   IF WIN32 )
 202 OCV_OPTION(WITH_FFMPEG         "Include FFMPEG support"                      ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 203 OCV_OPTION(WITH_GSTREAMER      "Include Gstreamer support"                   ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 204 OCV_OPTION(WITH_GSTREAMER_0_10 "Enable Gstreamer 0.10 support (instead of 1.x)"                              OFF )
 205 OCV_OPTION(WITH_GTK            "Include GTK support"                         ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 206 OCV_OPTION(WITH_GTK_2_X        "Use GTK version 2"                           OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 207 OCV_OPTION(WITH_IPP            "Include Intel IPP support"                   NOT MINGW IF (X86_64 OR X86) AND NOT WINRT AND NOT IOS )
 208 OCV_OPTION(WITH_HALIDE         "Include Halide support"                      OFF)
 209 OCV_OPTION(WITH_JASPER         "Include JPEG2K support"                      ON   IF (NOT IOS) )
 210 OCV_OPTION(WITH_JPEG           "Include JPEG support"                        ON)
 211 OCV_OPTION(WITH_WEBP           "Include WebP support"                        ON   IF (NOT WINRT) )
 212 OCV_OPTION(WITH_OPENEXR        "Include ILM support via OpenEXR"             ON   IF (NOT IOS AND NOT WINRT) )
 213 OCV_OPTION(WITH_OPENGL         "Include OpenGL support"                      OFF  IF (NOT ANDROID AND NOT WINRT) )
 214 OCV_OPTION(WITH_OPENVX         "Include OpenVX support"                      OFF)
 215 OCV_OPTION(WITH_OPENNI         "Include OpenNI support"                      OFF  IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 216 OCV_OPTION(WITH_OPENNI2        "Include OpenNI2 support"                     OFF  IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 217 OCV_OPTION(WITH_PNG            "Include PNG support"                         ON)
 218 OCV_OPTION(WITH_GDCM           "Include DICOM support"                       OFF)
 219 OCV_OPTION(WITH_PVAPI          "Include Prosilica GigE support"              OFF   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 220 OCV_OPTION(WITH_GIGEAPI        "Include Smartek GigE support"                OFF   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 221 OCV_OPTION(WITH_ARAVIS         "Include Aravis GigE support"                 OFF   IF (NOT ANDROID AND NOT IOS AND NOT WINRT AND NOT WIN32) )
 222 OCV_OPTION(WITH_QT             "Build with Qt Backend support"               OFF  IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 223 OCV_OPTION(WITH_WIN32UI        "Build with Win32 UI Backend support"         ON   IF WIN32 AND NOT WINRT)
 224 OCV_OPTION(WITH_QUICKTIME      "Use QuickTime for Video I/O"                 OFF  IF APPLE )
 225 OCV_OPTION(WITH_QTKIT          "Use QTKit Video I/O backend"                 OFF  IF APPLE )
 226 OCV_OPTION(WITH_TBB            "Include Intel TBB support"                   OFF  IF (NOT IOS AND NOT WINRT) )
 227 OCV_OPTION(WITH_OPENMP         "Include OpenMP support"                      OFF)
 228 OCV_OPTION(WITH_CSTRIPES       "Include C= support"                          OFF  IF (WIN32 AND NOT WINRT)  )
 229 OCV_OPTION(WITH_PTHREADS_PF    "Use pthreads-based parallel_for"             ON   IF (NOT WIN32 OR MINGW) )
 230 OCV_OPTION(WITH_TIFF           "Include TIFF support"                        ON   IF (NOT IOS) )
 231 OCV_OPTION(WITH_UNICAP         "Include Unicap support (GPL)"                OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 232 OCV_OPTION(WITH_V4L            "Include Video 4 Linux support"               ON   IF (UNIX AND NOT ANDROID AND NOT APPLE) )
 233 OCV_OPTION(WITH_LIBV4L         "Use libv4l for Video 4 Linux support"        OFF  IF (UNIX AND NOT ANDROID AND NOT APPLE) )
 234 OCV_OPTION(WITH_DSHOW          "Build VideoIO with DirectShow support"       ON   IF (WIN32 AND NOT ARM AND NOT WINRT) )
 235 OCV_OPTION(WITH_MSMF           "Build VideoIO with Media Foundation support" OFF  IF WIN32 )
 236 OCV_OPTION(WITH_XIMEA          "Include XIMEA cameras support"               OFF  IF (NOT ANDROID AND NOT WINRT) )
 237 OCV_OPTION(WITH_XINE           "Include Xine support (GPL)"                  OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 238 OCV_OPTION(WITH_CLP            "Include Clp support (EPL)"                   OFF)
 239 OCV_OPTION(WITH_OPENCL         "Include OpenCL Runtime support"              NOT ANDROID IF (NOT IOS AND NOT WINRT) )
 240 OCV_OPTION(WITH_OPENCL_SVM     "Include OpenCL Shared Virtual Memory support" OFF ) # experimental
 241 OCV_OPTION(WITH_OPENCLAMDFFT   "Include AMD OpenCL FFT library support"      ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 242 OCV_OPTION(WITH_OPENCLAMDBLAS  "Include AMD OpenCL BLAS library support"     ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 243 OCV_OPTION(WITH_DIRECTX        "Include DirectX support"                     ON   IF (WIN32 AND NOT WINRT) )
 244 OCV_OPTION(WITH_INTELPERC      "Include Intel Perceptual Computing support"  OFF  IF (WIN32 AND NOT WINRT) )
 245 OCV_OPTION(WITH_MATLAB         "Include Matlab support"                      ON   IF (NOT ANDROID AND NOT IOS AND NOT WINRT))
 246 OCV_OPTION(WITH_VA             "Include VA support"                          OFF  IF (UNIX AND NOT ANDROID) )
 247 OCV_OPTION(WITH_VA_INTEL       "Include Intel VA-API/OpenCL support"         OFF  IF (UNIX AND NOT ANDROID) )
 248 OCV_OPTION(WITH_MFX            "Include Intel Media SDK support"             OFF   IF ((UNIX AND NOT ANDROID) OR (WIN32 AND NOT WINRT AND NOT MINGW)) )
 249 OCV_OPTION(WITH_GDAL           "Include GDAL Support"                        OFF  IF (NOT ANDROID AND NOT IOS AND NOT WINRT) )
 250 OCV_OPTION(WITH_GPHOTO2        "Include gPhoto2 library support"             ON   IF (UNIX AND NOT ANDROID AND NOT IOS) )
 251 OCV_OPTION(WITH_LAPACK         "Include Lapack library support"              ON   IF (NOT ANDROID AND NOT IOS) )
 252 OCV_OPTION(WITH_ITT            "Include Intel ITT support"                   ON   IF (NOT APPLE_FRAMEWORK) )
 253
 254 # OpenCV build components
 255 # ===================================================
 256 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR APPLE_FRAMEWORK) )
 257 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID AND NOT WINRT) IF (NOT APPLE_FRAMEWORK) )
 258 OCV_OPTION(BUILD_opencv_js          "Build JavaScript bindings by Emscripten" OFF )
 259 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 260 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" ON  IF (NOT WINRT OR APPLE_FRAMEWORK))
 261 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 262 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON  IF NOT WINRT)
 263 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     ON  IF (NOT APPLE_FRAMEWORK) )
 264 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           ON  IF (NOT APPLE_FRAMEWORK) )
 265 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into debug libs (not MSCV only)" ON )
 266 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of statically linked CRT for statically linked OpenCV" ON IF MSVC )
 267 OCV_OPTION(BUILD_WITH_DYNAMIC_IPP   "Enables dynamic linking of IPP (only for standalone IPP)" OFF )
 268 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create fat java wrapper containing the whole OpenCV library" ON IF NOT BUILD_SHARED_LIBS AND CMAKE_COMPILER_IS_GNUCXX )
 269 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID )
 270 OCV_OPTION(BUILD_CUDA_STUBS         "Build CUDA modules stubs when no CUDA SDK" OFF  IF (NOT APPLE_FRAMEWORK) )
 271
 272 # 3rd party libs
 273 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             WIN32 OR APPLE )
 274 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          WIN32 OR ANDROID OR APPLE )
 275 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        WIN32 OR ANDROID OR APPLE )
 276 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          WIN32 OR ANDROID OR APPLE )
 277 OCV_OPTION(BUILD_PNG                "Build libpng from source"           WIN32 OR ANDROID OR APPLE )
 278 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          (WIN32 OR ANDROID OR APPLE) AND NOT WINRT)
 279 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" ANDROID )
 280 OCV_OPTION(BUILD_IPP_IW             "Build IPP IW from source"           NOT MINGW IF (X86_64 OR X86) AND NOT WINRT )
 281 OCV_OPTION(BUILD_ITT                "Build Intel ITT from source"        NOT MINGW IF (X86_64 OR X86) AND NOT WINRT AND NOT APPLE_FRAMEWORK )
 282
 283 # OpenCV installation options
 284 # ===================================================
 285 OCV_OPTION(INSTALL_CREATE_DISTRIB   "Change install rules to build the distribution package" OFF )
 286 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 287 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 288 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 289 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT APPLE_FRAMEWORK AND BUILD_SHARED_LIBS) )
 290 OCV_OPTION(INSTALL_TESTS            "Install accuracy and performance test binaries and test data" OFF)
 291
 292 # OpenCV build options
 293 # ===================================================
 294 OCV_OPTION(ENABLE_CCACHE              "Use ccache"                                               (UNIX AND NOT IOS AND (CMAKE_GENERATOR MATCHES "Makefile" OR CMAKE_GENERATOR MATCHES "Ninja")) )
 295 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON IF (NOT IOS AND NOT CMAKE_CROSSCOMPILING) )
 296 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) )
 297 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CMAKE_COMPILER_IS_GNUCXX )
 298 OCV_OPTION(ENABLE_COVERAGE            "Enable coverage collection with  GCov"                    OFF  IF CMAKE_COMPILER_IS_GNUCXX )
 299 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CMAKE_COMPILER_IS_GNUCXX AND NOT (APPLE AND CMAKE_COMPILER_IS_CLANGCXX) )
 300 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CMAKE_COMPILER_IS_GNUCXX AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 301 OCV_OPTION(ENABLE_VSX                 "Enable POWER8 and above VSX (64-bit little-endian)"       ON   IF (CMAKE_COMPILER_IS_GNUCXX AND PPC64LE) )
 302 OCV_OPTION(ENABLE_FAST_MATH           "Enable -ffast-math (not recommended for GCC 4.6.x)"       OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 303 OCV_OPTION(ENABLE_NEON                "Enable NEON instructions"                                 (NEON OR ANDROID_ARM_NEON OR AARCH64) IF CMAKE_COMPILER_IS_GNUCXX AND (ARM OR AARCH64 OR IOS) )
 304 OCV_OPTION(ENABLE_VFPV3               "Enable VFPv3-D32 instructions"                            OFF  IF CMAKE_COMPILER_IS_GNUCXX AND (ARM OR AARCH64 OR IOS) )
 305 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 306 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 307 OCV_OPTION(ANDROID_EXAMPLES_WITH_LIBS "Build binaries of Android examples with native libraries" OFF  IF ANDROID )
 308 OCV_OPTION(ENABLE_IMPL_COLLECTION     "Collect implementation data on function call"             OFF )
 309 OCV_OPTION(ENABLE_INSTRUMENTATION     "Instrument functions to collect calls trace and performance" OFF )
 310 OCV_OPTION(ENABLE_GNU_STL_DEBUG       "Enable GNU STL Debug mode (defines _GLIBCXX_DEBUG)"       OFF IF ((NOT CMAKE_VERSION VERSION_LESS "2.8.11") AND CMAKE_COMPILER_IS_GNUCXX) )
 311 OCV_OPTION(ENABLE_BUILD_HARDENING     "Enable hardening of the resulting binaries (against security attacks, detects memory corruption, etc)" OFF)
 312 OCV_OPTION(GENERATE_ABI_DESCRIPTOR    "Generate XML file for abi_compliance_checker tool" OFF IF UNIX)
 313 OCV_OPTION(CV_ENABLE_INTRINSICS       "Use intrinsic-based optimized code" ON )
 314 OCV_OPTION(CV_DISABLE_OPTIMIZATION    "Disable explicit optimized code (dispatched code/intrinsics/loop unrolling/etc)" OFF )
 315 OCV_OPTION(CV_TRACE                   "Enable OpenCV code trace" ON)
 316
 317 OCV_OPTION(ENABLE_PYLINT              "Add target with Pylint checks"                            (${BUILD_DOCS} OR ${BUILD_EXAMPLES}) )
 318
 319 if(ENABLE_IMPL_COLLECTION)
 320   add_definitions(-DCV_COLLECT_IMPL_DATA)
 321 endif()
 322
 323
 324 # ----------------------------------------------------------------------------
 325 #  Get actual OpenCV version number from sources
 326 # ----------------------------------------------------------------------------
 327 include(cmake/OpenCVVersion.cmake)
 328
 329
 330 # ----------------------------------------------------------------------------
 331 #  Build & install layouts
 332 # ----------------------------------------------------------------------------
 333
 334 # Save libs and executables in the same place
 335 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications")
 336
 337 if(ANDROID)
 338   if(ANDROID_ABI MATCHES "NEON")
 339     set(ENABLE_NEON ON)
 340   endif()
 341   if(ANDROID_ABI MATCHES "VFPV3")
 342     set(ENABLE_VFPV3 ON)
 343   endif()
 344 endif()
 345
 346 if(ANDROID OR WIN32)
 347   ocv_update(OPENCV_DOC_INSTALL_PATH doc)
 348 else()
 349   ocv_update(OPENCV_DOC_INSTALL_PATH share/OpenCV/doc)
 350 endif()
 351
 352 if(WIN32 AND CMAKE_HOST_SYSTEM_NAME MATCHES Windows)
 353   if(DEFINED OpenCV_RUNTIME AND DEFINED OpenCV_ARCH)
 354     ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "${OpenCV_ARCH}/${OpenCV_RUNTIME}/")
 355   else()
 356     message(STATUS "Can't detect runtime and/or arch")
 357     ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "")
 358   endif()
 359 elseif(ANDROID)
 360   ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "sdk/native/")
 361 else()
 362   ocv_update(OpenCV_INSTALL_BINARIES_PREFIX "")
 363 endif()
 364
 365 if(ANDROID)
 366   ocv_update(OPENCV_SAMPLES_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}samples/${ANDROID_NDK_ABI_NAME}")
 367 else()
 368   ocv_update(OPENCV_SAMPLES_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}samples")
 369 endif()
 370
 371 if(ANDROID)
 372   ocv_update(OPENCV_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}bin/${ANDROID_NDK_ABI_NAME}")
 373 else()
 374   ocv_update(OPENCV_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}bin")
 375 endif()
 376
 377 if(NOT OPENCV_TEST_INSTALL_PATH)
 378   ocv_update(OPENCV_TEST_INSTALL_PATH "${OPENCV_BIN_INSTALL_PATH}")
 379 endif()
 380
 381 if (OPENCV_TEST_DATA_PATH)
 382   get_filename_component(OPENCV_TEST_DATA_PATH ${OPENCV_TEST_DATA_PATH} ABSOLUTE)
 383 endif()
 384
 385 if(ANDROID)
 386   ocv_update(OPENCV_TEST_DATA_INSTALL_PATH "sdk/etc/testdata")
 387 elseif(WIN32)
 388   ocv_update(OPENCV_TEST_DATA_INSTALL_PATH "testdata")
 389 else()
 390   ocv_update(OPENCV_TEST_DATA_INSTALL_PATH "share/OpenCV/testdata")
 391 endif()
 392
 393 if(ANDROID)
 394   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 395   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 396   ocv_update(OPENCV_LIB_INSTALL_PATH     sdk/native/libs/${ANDROID_NDK_ABI_NAME})
 397   ocv_update(OPENCV_3P_LIB_INSTALL_PATH  sdk/native/3rdparty/libs/${ANDROID_NDK_ABI_NAME})
 398   ocv_update(OPENCV_CONFIG_INSTALL_PATH  sdk/native/jni)
 399   ocv_update(OPENCV_INCLUDE_INSTALL_PATH sdk/native/jni/include)
 400   ocv_update(OPENCV_SAMPLES_SRC_INSTALL_PATH samples/native)
 401   ocv_update(OPENCV_OTHER_INSTALL_PATH   sdk/etc)
 402 else()
 403   set(LIBRARY_OUTPUT_PATH                "${OpenCV_BINARY_DIR}/lib")
 404   ocv_update(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib${LIB_SUFFIX}")
 405
 406   if(WIN32 AND CMAKE_HOST_SYSTEM_NAME MATCHES Windows)
 407     if(OpenCV_STATIC)
 408       ocv_update(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 409     else()
 410       ocv_update(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}lib${LIB_SUFFIX}")
 411     endif()
 412     ocv_update(OPENCV_3P_LIB_INSTALL_PATH  "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 413     ocv_update(OPENCV_SAMPLES_SRC_INSTALL_PATH    samples/native)
 414     ocv_update(OPENCV_JAR_INSTALL_PATH java)
 415     ocv_update(OPENCV_OTHER_INSTALL_PATH   etc)
 416     ocv_update(OPENCV_CONFIG_INSTALL_PATH  ".")
 417   else()
 418     include(GNUInstallDirs)
 419     ocv_update(OPENCV_LIB_INSTALL_PATH     ${CMAKE_INSTALL_LIBDIR}${LIB_SUFFIX})
 420     ocv_update(OPENCV_3P_LIB_INSTALL_PATH  share/OpenCV/3rdparty/${OPENCV_LIB_INSTALL_PATH})
 421     ocv_update(OPENCV_SAMPLES_SRC_INSTALL_PATH    share/OpenCV/samples)
 422     ocv_update(OPENCV_JAR_INSTALL_PATH share/OpenCV/java)
 423     ocv_update(OPENCV_OTHER_INSTALL_PATH   share/OpenCV)
 424
 425     if(NOT DEFINED OPENCV_CONFIG_INSTALL_PATH)
 426       math(EXPR SIZEOF_VOID_P_BITS "8 * ${CMAKE_SIZEOF_VOID_P}")
 427       if(LIB_SUFFIX AND NOT SIZEOF_VOID_P_BITS EQUAL LIB_SUFFIX)
 428         ocv_update(OPENCV_CONFIG_INSTALL_PATH ${CMAKE_INSTALL_LIBDIR}${LIB_SUFFIX}/cmake/opencv)
 429       else()
 430         ocv_update(OPENCV_CONFIG_INSTALL_PATH share/OpenCV)
 431       endif()
 432     endif()
 433   endif()
 434   ocv_update(OPENCV_INCLUDE_INSTALL_PATH "include")
 435 endif()
 436
 437 ocv_update(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 438 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 439
 440 if(INSTALL_TO_MANGLED_PATHS)
 441   set(OPENCV_INCLUDE_INSTALL_PATH ${OPENCV_INCLUDE_INSTALL_PATH}/opencv-${OPENCV_VERSION})
 442   foreach(v
 443       OPENCV_3P_LIB_INSTALL_PATH
 444       OPENCV_SAMPLES_SRC_INSTALL_PATH
 445       OPENCV_CONFIG_INSTALL_PATH
 446       OPENCV_DOC_INSTALL_PATH
 447       OPENCV_JAR_INSTALL_PATH
 448       OPENCV_TEST_DATA_INSTALL_PATH
 449       OPENCV_OTHER_INSTALL_PATH
 450     )
 451     string(REPLACE "OpenCV" "OpenCV-${OPENCV_VERSION}" ${v} "${${v}}")
 452     string(REPLACE "opencv" "opencv-${OPENCV_VERSION}" ${v} "${${v}}")
 453   endforeach()
 454 endif()
 455
 456
 457 if(WIN32)
 458   # Postfix of DLLs:
 459   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 460   set(OPENCV_DEBUG_POSTFIX d)
 461 else()
 462   # Postfix of so's:
 463   set(OPENCV_DLLVERSION "")
 464   set(OPENCV_DEBUG_POSTFIX "")
 465 endif()
 466
 467 if(DEFINED CMAKE_DEBUG_POSTFIX)
 468   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 469 endif()
 470
 471 if((INSTALL_CREATE_DISTRIB AND BUILD_SHARED_LIBS AND NOT DEFINED BUILD_opencv_world) OR APPLE_FRAMEWORK)
 472   set(BUILD_opencv_world ON CACHE INTERNAL "")
 473 endif()
 474
 475 # ----------------------------------------------------------------------------
 476 #  Path for build/platform -specific headers
 477 # ----------------------------------------------------------------------------
 478 ocv_update(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 479 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 480
 481 # ----------------------------------------------------------------------------
 482 #  Path for additional modules
 483 # ----------------------------------------------------------------------------
 484 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules")
 485
 486 # ----------------------------------------------------------------------------
 487 #  Autodetect if we are in a GIT repository
 488 # ----------------------------------------------------------------------------
 489 find_host_package(Git QUIET)
 490
 491 if(NOT DEFINED OPENCV_VCSVERSION AND GIT_FOUND)
 492   execute_process(COMMAND "${GIT_EXECUTABLE}" describe --tags --always --dirty --match "[0-9].[0-9].[0-9]*"
 493     WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 494     OUTPUT_VARIABLE OPENCV_VCSVERSION
 495     RESULT_VARIABLE GIT_RESULT
 496     ERROR_QUIET
 497     OUTPUT_STRIP_TRAILING_WHITESPACE
 498   )
 499   if(NOT GIT_RESULT EQUAL 0)
 500     set(OPENCV_VCSVERSION "unknown")
 501   endif()
 502 elseif(NOT DEFINED OPENCV_VCSVERSION)
 503   # We don't have git:
 504   set(OPENCV_VCSVERSION "unknown")
 505 endif()
 506
 507
 508 # ----------------------------------------------------------------------------
 509 # OpenCV compiler and linker options
 510 # ----------------------------------------------------------------------------
 511 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 512 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 513   set(CMAKE_BUILD_TYPE Release)
 514 endif()
 515
 516 # --- Python Support ---
 517 include(cmake/OpenCVDetectPython.cmake)
 518
 519 include(cmake/OpenCVCompilerOptions.cmake)
 520
 521
 522 # ----------------------------------------------------------------------------
 523 # Use statically or dynamically linked CRT?
 524 # Default: dynamic
 525 # ----------------------------------------------------------------------------
 526 if(MSVC)
 527   include(cmake/OpenCVCRTLinkage.cmake)
 528 endif(MSVC)
 529
 530 if(WIN32 AND NOT MINGW)
 531   add_definitions(-D_VARIADIC_MAX=10)
 532 endif(WIN32 AND NOT MINGW)
 533
 534
 535 # ----------------------------------------------------------------------------
 536 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 537 # ----------------------------------------------------------------------------
 538 if(UNIX)
 539   if(NOT APPLE_FRAMEWORK)
 540     find_package(PkgConfig QUIET)
 541   endif()
 542   include(CheckFunctionExists)
 543   include(CheckIncludeFile)
 544   include(CheckSymbolExists)
 545
 546   if(NOT APPLE)
 547     CHECK_INCLUDE_FILE(pthread.h HAVE_PTHREAD)
 548     if(ANDROID)
 549       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 550     elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD|NetBSD|DragonFly|OpenBSD|Haiku")
 551       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 552     elseif(EMSCRIPTEN)
 553       # no need to link to system libs with emscripten
 554     else()
 555       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 556     endif()
 557   else()
 558     set(HAVE_PTHREAD 1)
 559   endif()
 560
 561   CHECK_SYMBOL_EXISTS(posix_memalign stdlib.h HAVE_POSIX_MEMALIGN)
 562   CHECK_INCLUDE_FILE(malloc.h HAVE_MALLOC_H)
 563   if(HAVE_MALLOC_H)
 564     CHECK_SYMBOL_EXISTS(memalign malloc.h HAVE_MEMALIGN)
 565   endif()
 566 endif()
 567
 568 include(cmake/OpenCVPCHSupport.cmake)
 569 include(cmake/OpenCVModule.cmake)
 570
 571 # ----------------------------------------------------------------------------
 572 #  Detect endianness of build platform
 573 # ----------------------------------------------------------------------------
 574
 575 if(IOS)
 576   # test_big_endian needs try_compile, which doesn't work for iOS
 577   # http://public.kitware.com/Bug/view.php?id=12288
 578   set(WORDS_BIGENDIAN 0)
 579 else()
 580   include(TestBigEndian)
 581   test_big_endian(WORDS_BIGENDIAN)
 582 endif()
 583
 584 # ----------------------------------------------------------------------------
 585 #  Detect 3rd-party libraries
 586 # ----------------------------------------------------------------------------
 587
 588 if(ANDROID AND WITH_CPUFEATURES)
 589   add_subdirectory(3rdparty/cpufeatures)
 590   set(HAVE_CPUFEATURES 1)
 591 endif()
 592
 593 include(cmake/OpenCVFindLibsGrfmt.cmake)
 594 include(cmake/OpenCVFindLibsGUI.cmake)
 595 include(cmake/OpenCVFindLibsVideo.cmake)
 596 include(cmake/OpenCVFindLibsPerf.cmake)
 597 include(cmake/OpenCVFindLAPACK.cmake)
 598
 599 # ----------------------------------------------------------------------------
 600 #  Detect other 3rd-party libraries/tools
 601 # ----------------------------------------------------------------------------
 602
 603 # --- Doxygen for documentation ---
 604 if(BUILD_DOCS)
 605   find_package(Doxygen)
 606 else()
 607   unset(DOXYGEN_FOUND CACHE)
 608 endif()
 609
 610 # --- Java Support ---
 611 include(cmake/OpenCVDetectApacheAnt.cmake)
 612 if(ANDROID)
 613   include(cmake/OpenCVDetectAndroidSDK.cmake)
 614
 615   if(NOT ANDROID_TOOLS_Pkg_Revision GREATER 13)
 616     message(WARNING "OpenCV requires Android SDK tools revision 14 or newer. Otherwise tests and samples will no be compiled.")
 617   endif()
 618 else()
 619   find_package(JNI)
 620 endif()
 621
 622 if(ENABLE_PYLINT)
 623   include(cmake/OpenCVPylint.cmake)
 624 endif()
 625
 626
 627 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 628   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 629 else()
 630   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 631 endif()
 632
 633 # --- OpenCL ---
 634 if(WITH_OPENCL)
 635   include(cmake/OpenCVDetectOpenCL.cmake)
 636 endif()
 637
 638 # --- Halide ---
 639 if(WITH_HALIDE)
 640   include(cmake/OpenCVDetectHalide.cmake)
 641 endif()
 642
 643 # --- DirectX ---
 644 if(WITH_DIRECTX)
 645   include(cmake/OpenCVDetectDirectX.cmake)
 646 endif()
 647
 648 # --- Matlab/Octave ---
 649 if(WITH_MATLAB)
 650   include(cmake/OpenCVFindMatlab.cmake)
 651 endif()
 652
 653 include(cmake/OpenCVDetectVTK.cmake)
 654
 655 if(WITH_OPENVX)
 656   include(cmake/FindOpenVX.cmake)
 657 endif()
 658
 659 # ----------------------------------------------------------------------------
 660 # OpenCV HAL
 661 # ----------------------------------------------------------------------------
 662 set(_hal_includes "")
 663 macro(ocv_hal_register HAL_LIBRARIES_VAR HAL_HEADERS_VAR HAL_INCLUDE_DIRS_VAR)
 664   # 1. libraries
 665   foreach (l ${${HAL_LIBRARIES_VAR}})
 666     if(NOT TARGET ${l})
 667       get_filename_component(l "${l}" ABSOLUTE)
 668     endif()
 669     list(APPEND OPENCV_HAL_LINKER_LIBS ${l})
 670   endforeach()
 671   # 2. headers
 672   foreach (h ${${HAL_HEADERS_VAR}})
 673     set(_hal_includes "${_hal_includes}\n#include \"${h}\"")
 674   endforeach()
 675   # 3. include paths
 676   ocv_include_directories(${${HAL_INCLUDE_DIRS_VAR}})
 677 endmacro()
 678
 679 if(NOT DEFINED OpenCV_HAL)
 680   set(OpenCV_HAL "OpenCV_HAL")
 681 endif()
 682
 683 if(HAVE_OPENVX)
 684   if(NOT ";${OpenCV_HAL};" MATCHES ";openvx;")
 685     set(OpenCV_HAL "openvx;${OpenCV_HAL}")
 686   endif()
 687 endif()
 688
 689 if(WITH_CAROTENE)
 690   ocv_debug_message(STATUS "Enable carotene acceleration")
 691   if(NOT ";${OpenCV_HAL};" MATCHES ";carotene;")
 692     set(OpenCV_HAL "carotene;${OpenCV_HAL}")
 693   endif()
 694 endif()
 695
 696 foreach(hal ${OpenCV_HAL})
 697   if(hal STREQUAL "carotene")
 698     add_subdirectory(3rdparty/carotene/hal)
 699     ocv_hal_register(CAROTENE_HAL_LIBRARIES CAROTENE_HAL_HEADERS CAROTENE_HAL_INCLUDE_DIRS)
 700     list(APPEND OpenCV_USED_HAL "carotene (ver ${CAROTENE_HAL_VERSION})")
 701   elseif(hal STREQUAL "openvx")
 702     add_subdirectory(3rdparty/openvx)
 703     ocv_hal_register(OPENVX_HAL_LIBRARIES OPENVX_HAL_HEADERS OPENVX_HAL_INCLUDE_DIRS)
 704     list(APPEND OpenCV_USED_HAL "openvx (ver ${OPENVX_HAL_VERSION})")
 705   else()
 706     ocv_debug_message(STATUS "OpenCV HAL: ${hal} ...")
 707     ocv_clear_vars(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 708     find_package(${hal} NO_MODULE QUIET)
 709     if(${hal}_FOUND)
 710       ocv_hal_register(OpenCV_HAL_LIBRARIES OpenCV_HAL_HEADERS OpenCV_HAL_INCLUDE_DIRS)
 711       list(APPEND OpenCV_USED_HAL "${hal} (ver ${${hal}_VERSION})")
 712     endif()
 713   endif()
 714 endforeach()
 715 configure_file("${OpenCV_SOURCE_DIR}/cmake/templates/custom_hal.hpp.in" "${CMAKE_BINARY_DIR}/custom_hal.hpp" @ONLY)
 716 unset(_hal_includes)
 717
 718
 719 # ----------------------------------------------------------------------------
 720 # Add CUDA libraries (needed for apps/tools, samples)
 721 # ----------------------------------------------------------------------------
 722 if(HAVE_CUDA)
 723   set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_LIBRARIES} ${CUDA_npp_LIBRARY})
 724   if(HAVE_CUBLAS)
 725     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cublas_LIBRARY})
 726   endif()
 727   if(HAVE_CUFFT)
 728     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cufft_LIBRARY})
 729   endif()
 730   foreach(p ${CUDA_LIBS_PATH})
 731     if(MSVC AND CMAKE_GENERATOR MATCHES "Ninja|JOM")
 732       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CMAKE_LIBRARY_PATH_FLAG}"${p}")
 733     else()
 734       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CMAKE_LIBRARY_PATH_FLAG}${p})
 735     endif()
 736   endforeach()
 737 endif()
 738
 739
 740 # ----------------------------------------------------------------------------
 741 # Code trace support
 742 # ----------------------------------------------------------------------------
 743 if(CV_TRACE)
 744   include(cmake/OpenCVDetectTrace.cmake)
 745 endif()
 746
 747
 748 # ----------------------------------------------------------------------------
 749 # Solution folders:
 750 # ----------------------------------------------------------------------------
 751 if(ENABLE_SOLUTION_FOLDERS)
 752   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 753   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 754 endif()
 755
 756 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 757 include(cmake/OpenCVExtraTargets.cmake)
 758
 759 # ----------------------------------------------------------------------------
 760 # Process subdirectories
 761 # ----------------------------------------------------------------------------
 762
 763 # opencv.hpp and legacy headers
 764 add_subdirectory(include)
 765
 766 # OpenCV modules
 767 add_subdirectory(modules)
 768
 769 # Generate targets for documentation
 770 add_subdirectory(doc)
 771
 772 # various data that is used by cv libraries and/or demo applications.
 773 add_subdirectory(data)
 774
 775 # extra applications
 776 if(BUILD_opencv_apps)
 777   add_subdirectory(apps)
 778 endif()
 779
 780 # examples
 781 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES)
 782   add_subdirectory(samples)
 783 endif()
 784
 785 if(ANDROID)
 786   add_subdirectory(platforms/android/service)
 787 endif()
 788
 789 # ----------------------------------------------------------------------------
 790 # Finalization: generate configuration-based files
 791 # ----------------------------------------------------------------------------
 792
 793 # Generate platform-dependent and configuration-dependent headers
 794 include(cmake/OpenCVGenHeaders.cmake)
 795
 796 # Generate opencv.pc for pkg-config command
 797 if(NOT OPENCV_SKIP_PKGCONFIG_GENERATION
 798     AND NOT CMAKE_GENERATOR MATCHES "Xcode")
 799   include(cmake/OpenCVGenPkgconfig.cmake)
 800 endif()
 801
 802 # Generate OpenCV.mk for ndk-build (Android build tool)
 803 include(cmake/OpenCVGenAndroidMK.cmake)
 804
 805 # Generate OpenCVConfig.cmake and OpenCVConfig-version.cmake for cmake projects
 806 include(cmake/OpenCVGenConfig.cmake)
 807
 808 # Generate Info.plist for the IOS framework
 809 if(APPLE_FRAMEWORK)
 810   include(cmake/OpenCVGenInfoPlist.cmake)
 811 endif()
 812
 813 # Generate ABI descriptor
 814 include(cmake/OpenCVGenABI.cmake)
 815
 816 # Generate environment setup file
 817 if(INSTALL_TESTS AND OPENCV_TEST_DATA_PATH)
 818   if(ANDROID)
 819     get_filename_component(TEST_PATH ${OPENCV_TEST_INSTALL_PATH} DIRECTORY)
 820     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_android.sh.in"
 821                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 822     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 823             DESTINATION ./ COMPONENT tests)
 824   elseif(WIN32)
 825     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_windows.cmd.in"
 826                    "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd" @ONLY)
 827     install(PROGRAMS "${CMAKE_BINARY_DIR}/win-install/opencv_run_all_tests.cmd"
 828             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 829   elseif(UNIX)
 830     configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmake/templates/opencv_run_all_tests_unix.sh.in"
 831                    "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh" @ONLY)
 832     install(PROGRAMS "${CMAKE_BINARY_DIR}/unix-install/opencv_run_all_tests.sh"
 833             DESTINATION ${OPENCV_TEST_INSTALL_PATH} COMPONENT tests)
 834   endif()
 835 endif()
 836
 837 if(NOT OPENCV_README_FILE)
 838   if(ANDROID)
 839     set(OPENCV_README_FILE ${CMAKE_CURRENT_SOURCE_DIR}/platforms/android/README.android)
 840   endif()
 841 endif()
 842
 843 if(NOT OPENCV_LICENSE_FILE)
 844   set(OPENCV_LICENSE_FILE ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE)
 845 endif()
 846
 847 # for UNIX it does not make sense as LICENSE and readme will be part of the package automatically
 848 if(ANDROID OR NOT UNIX)
 849   install(FILES ${OPENCV_LICENSE_FILE}
 850         PERMISSIONS OWNER_READ GROUP_READ WORLD_READ
 851         DESTINATION ./ COMPONENT libs)
 852   if(OPENCV_README_FILE)
 853     install(FILES ${OPENCV_README_FILE}
 854             PERMISSIONS OWNER_READ GROUP_READ WORLD_READ
 855             DESTINATION ./ COMPONENT libs)
 856   endif()
 857 endif()
 858
 859 if(COMMAND ocv_pylint_finalize)
 860   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/modules/python/test)
 861   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/python)
 862   ocv_pylint_add_directory(${CMAKE_CURRENT_LIST_DIR}/samples/dnn)
 863   ocv_pylint_add_directory_recurse(${CMAKE_CURRENT_LIST_DIR}/samples/python/tutorial_code)
 864   ocv_pylint_finalize()
 865 endif()
 866
 867 # ----------------------------------------------------------------------------
 868 # Summary:
 869 # ----------------------------------------------------------------------------
 870 status("")
 871 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 872 if(OPENCV_VCSVERSION)
 873   status("  Version control:" ${OPENCV_VCSVERSION})
 874 endif()
 875 if(OPENCV_EXTRA_MODULES_PATH AND NOT BUILD_INFO_SKIP_EXTRA_MODULES)
 876   set(__dump_extra_header OFF)
 877   foreach(p ${OPENCV_EXTRA_MODULES_PATH})
 878     if(EXISTS ${p})
 879       if(NOT __dump_extra_header)
 880         set(__dump_extra_header ON)
 881         status("")
 882         status("  Extra modules:")
 883       else()
 884         status("")
 885       endif()
 886       set(EXTRA_MODULES_VCSVERSION "unknown")
 887       if(GIT_FOUND)
 888         execute_process(COMMAND "${GIT_EXECUTABLE}" describe --tags --always --dirty --match "[0-9].[0-9].[0-9]*"
 889           WORKING_DIRECTORY "${p}"
 890           OUTPUT_VARIABLE EXTRA_MODULES_VCSVERSION
 891           RESULT_VARIABLE GIT_RESULT
 892           ERROR_QUIET
 893           OUTPUT_STRIP_TRAILING_WHITESPACE
 894         )
 895         if(NOT GIT_RESULT EQUAL 0)
 896           set(EXTRA_MODULES_VCSVERSION "unknown")
 897         endif()
 898       endif()
 899       status("    Location (extra):" ${p})
 900       status("    Version control (extra):" ${EXTRA_MODULES_VCSVERSION})
 901     endif()
 902   endforeach()
 903   unset(__dump_extra_header)
 904 endif()
 905
 906 # ========================== build platform ==========================
 907 status("")
 908 status("  Platform:")
 909 if(NOT CMAKE_VERSION VERSION_LESS 2.8.11 AND NOT BUILD_INFO_SKIP_TIMESTAMP)
 910   string(TIMESTAMP TIMESTAMP "" UTC)
 911   if(TIMESTAMP)
 912     status("    Timestamp:"    ${TIMESTAMP})
 913   endif()
 914 endif()
 915 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
 916 if(CMAKE_CROSSCOMPILING)
 917   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
 918 endif()
 919 status("    CMake:"            ${CMAKE_VERSION})
 920 status("    CMake generator:"  ${CMAKE_GENERATOR})
 921 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
 922 if(MSVC)
 923   status("    MSVC:"           ${MSVC_VERSION})
 924 endif()
 925 if(CMAKE_GENERATOR MATCHES Xcode)
 926   status("    Xcode:"          ${XCODE_VERSION})
 927 endif()
 928 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
 929   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
 930 endif()
 931
 932
 933 # ========================= CPU code generation mode =========================
 934 status("")
 935 status("  CPU/HW features:")
 936 status("    Baseline:"  "${CPU_BASELINE_FINAL}")
 937 if(NOT CPU_BASELINE STREQUAL CPU_BASELINE_FINAL)
 938   status("      requested:"  "${CPU_BASELINE}")
 939 endif()
 940 if(CPU_BASELINE_REQUIRE)
 941   status("      required:"  "${CPU_BASELINE_REQUIRE}")
 942 endif()
 943 if(CPU_BASELINE_DISABLE)
 944   status("      disabled:"  "${CPU_BASELINE_DISABLE}")
 945 endif()
 946 if(CPU_DISPATCH_FINAL OR CPU_DISPATCH)
 947   status("    Dispatched code generation:"  "${CPU_DISPATCH_FINAL}")
 948   if(NOT CPU_DISPATCH STREQUAL CPU_DISPATCH_FINAL)
 949     status("      requested:"  "${CPU_DISPATCH}")
 950   endif()
 951   if(CPU_DISPATCH_REQUIRE)
 952     status("      required:"  "${CPU_DISPATCH_REQUIRE}")
 953   endif()
 954   foreach(OPT ${CPU_DISPATCH_FINAL})
 955     status("      ${OPT} (${CPU_${OPT}_USAGE_COUNT} files):"  "+ ${CPU_DISPATCH_${OPT}_INCLUDED}")
 956   endforeach()
 957 endif()
 958
 959 # ========================== C/C++ options ==========================
 960 if(CMAKE_CXX_COMPILER_VERSION)
 961   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
 962 else()
 963   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 964 endif()
 965 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
 966
 967 status("")
 968 status("  C/C++:")
 969 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
 970 if(ENABLE_CXX11 OR HAVE_CXX11)
 971 status("    C++11:" HAVE_CXX11 THEN YES ELSE NO)
 972 endif()
 973 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
 974 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
 975 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
 976 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
 977 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
 978 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
 979 if(WIN32)
 980   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
 981   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
 982 else()
 983   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
 984   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
 985 endif()
 986 status("    ccache:"                  CMAKE_COMPILER_IS_CCACHE THEN YES ELSE NO)
 987 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
 988
 989 # ========================== Dependencies ============================
 990 ocv_get_all_libs(deps_modules deps_extra deps_3rdparty)
 991 status("    Extra dependencies:" ${deps_extra})
 992 status("    3rdparty dependencies:" ${deps_3rdparty})
 993
 994 # ========================== OpenCV modules ==========================
 995 status("")
 996 status("  OpenCV modules:")
 997 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD}")
 998 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
 999 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO}")
1000 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
1001 list(SORT OPENCV_MODULES_BUILD_ST)
1002 list(SORT OPENCV_MODULES_DISABLED_USER_ST)
1003 list(SORT OPENCV_MODULES_DISABLED_AUTO_ST)
1004 list(SORT OPENCV_MODULES_DISABLED_FORCE_ST)
1005 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
1006 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
1007 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
1008 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
1009
1010 ocv_build_features_string(apps_status
1011   IF BUILD_TESTS AND HAVE_opencv_ts THEN "tests"
1012   IF BUILD_PERF_TESTS AND HAVE_opencv_ts THEN "perf_tests"
1013   IF BUILD_EXAMPLES THEN "examples"
1014   IF BUILD_opencv_apps THEN "apps"
1015   IF BUILD_ANDROID_SERVICE THEN "android_service"
1016   IF BUILD_ANDROID_EXAMPLES AND CAN_BUILD_ANDROID_PROJECTS THEN "android_examples"
1017   ELSE "-")
1018 status("    Applications:" "${apps_status}")
1019 status("    Documentation:" BUILD_DOCS AND DOXYGEN_FOUND THEN "YES (${DOXYGEN_EXECUTABLE} ${DOXYGEN_VERSION})" ELSE "NO")
1020 status("    Non-free algorithms:" OPENCV_ENABLE_NONFREE THEN "YES" ELSE "NO")
1021
1022 # ========================== Android details ==========================
1023 if(ANDROID)
1024   status("")
1025   status("  Android: ")
1026   status("    Android ABI:" ${ANDROID_ABI})
1027   status("    STL type:" ${ANDROID_STL})
1028   status("    Native API level:" android-${ANDROID_NATIVE_API_LEVEL})
1029   android_get_compatible_target(android_sdk_target_status ${ANDROID_NATIVE_API_LEVEL} ${ANDROID_SDK_TARGET} 11)
1030   status("    SDK target:" "${android_sdk_target_status}")
1031   if(BUILD_WITH_ANDROID_NDK)
1032     status("    Android NDK:" "${ANDROID_NDK} (toolchain: ${ANDROID_TOOLCHAIN_NAME})")
1033   elseif(BUILD_WITH_STANDALONE_TOOLCHAIN)
1034     status("    Android toolchain:" "${ANDROID_STANDALONE_TOOLCHAIN}")
1035   endif()
1036   status("    android tool:"  ANDROID_EXECUTABLE  THEN "${ANDROID_EXECUTABLE} (${ANDROID_TOOLS_Pkg_Desc})" ELSE NO)
1037 endif()
1038
1039 # ================== Windows RT features ==================
1040 if(WIN32)
1041 status("")
1042 status("  Windows RT support:" WINRT THEN YES ELSE NO)
1043   if(WINRT)
1044     status("    Building for Microsoft platform: " ${CMAKE_SYSTEM_NAME})
1045     status("    Building for architectures: " ${CMAKE_VS_EFFECTIVE_PLATFORMS})
1046     status("    Building for version: " ${CMAKE_SYSTEM_VERSION})
1047     if (DEFINED ENABLE_WINRT_MODE_NATIVE)
1048       status("    Building for C++ without CX extensions")
1049     endif()
1050   endif()
1051 endif(WIN32)
1052
1053 # ========================== GUI ==========================
1054 status("")
1055 status("  GUI: ")
1056
1057 if(WITH_QT OR HAVE_QT)
1058   if(HAVE_QT5)
1059     status("    QT:" "YES (ver ${Qt5Core_VERSION_STRING})")
1060     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt5OpenGL_LIBRARIES} ${Qt5OpenGL_VERSION_STRING})" ELSE NO)
1061   elseif(HAVE_QT)
1062     status("    QT:" "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})")
1063     status("      QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
1064   else()
1065     status("    QT:" "NO")
1066   endif()
1067 endif()
1068
1069 if(WITH_WIN32UI)
1070   status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
1071 endif()
1072
1073 if(APPLE)
1074   if(WITH_CARBON)
1075     status("    Carbon:" YES)
1076   else()
1077     status("    Cocoa:"  YES)
1078   endif()
1079 endif()
1080
1081 if(WITH_GTK OR HAVE_GTK)
1082   if(HAVE_GTK3)
1083     status("    GTK+:" "YES (ver ${ALIASOF_gtk+-3.0_VERSION})")
1084   elseif(HAVE_GTK)
1085     status("    GTK+:" "YES (ver ${ALIASOF_gtk+-2.0_VERSION})")
1086   else()
1087     status("    GTK+:" "NO")
1088   endif()
1089   if(HAVE_GTK)
1090     status(  "      GThread :" HAVE_GTHREAD THEN "YES (ver ${ALIASOF_gthread-2.0_VERSION})" ELSE NO)
1091     status(  "      GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${ALIASOF_gtkglext-1.0_VERSION})" ELSE NO)
1092   endif()
1093 endif()
1094
1095 if(WITH_OPENGL OR HAVE_OPENGL)
1096   status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
1097 endif()
1098
1099 if(WITH_VTK OR HAVE_VTK)
1100   status("    VTK support:" HAVE_VTK THEN "YES (ver ${VTK_VERSION})" ELSE NO)
1101 endif()
1102
1103 # ========================== MEDIA IO ==========================
1104 status("")
1105 status("  Media I/O: ")
1106 status("    ZLib:"   ZLIB_FOUND THEN "${ZLIB_LIBRARIES} (ver ${ZLIB_VERSION_STRING})" ELSE "build (ver ${ZLIB_VERSION_STRING})")
1107
1108 if(WITH_JPEG OR HAVE_JPEG)
1109   status("    JPEG:" JPEG_FOUND THEN "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})" ELSE "build (ver ${JPEG_LIB_VERSION})")
1110 endif()
1111
1112 if(WITH_WEBP OR HAVE_WEBP)
1113   status("    WEBP:" WEBP_FOUND THEN "${WEBP_LIBRARY} (ver ${WEBP_VERSION})" ELSE "build (ver ${WEBP_VERSION})")
1114 endif()
1115
1116 if(WITH_PNG OR HAVE_PNG)
1117   status("    PNG:"  PNG_FOUND  THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})" ELSE "build (ver ${PNG_VERSION})")
1118 endif()
1119
1120 if(WITH_TIFF OR HAVE_TIFF)
1121   status("    TIFF:" TIFF_FOUND THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION} / ${TIFF_VERSION_STRING})" ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
1122 endif()
1123
1124 if(WITH_JASPER OR HAVE_JASPER)
1125   status("    JPEG 2000:" JASPER_FOUND THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
1126 endif()
1127
1128 if(WITH_OPENEXR OR HAVE_OPENEXR)
1129   status("    OpenEXR:" OPENEXR_FOUND THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
1130 endif()
1131
1132 if(WITH_GDAL OR HAVE_GDAL)
1133   status("    GDAL:" HAVE_GDAL THEN "YES (${GDAL_LIBRARY})" ELSE "NO")
1134 endif()
1135
1136 if(WITH_GDCM OR HAVE_GDCM)
1137   status("    GDCM:" HAVE_GDCM THEN "YES (ver ${GDCM_VERSION})" ELSE "NO")
1138 endif()
1139
1140 # ========================== VIDEO IO ==========================
1141 status("")
1142 status("  Video I/O:")
1143
1144 if(WITH_VFW OR HAVE_VFW)
1145   status("    Video for Windows:" HAVE_VFW         THEN YES                                        ELSE NO)
1146 endif()
1147
1148 if(WITH_1394 OR HAVE_DC1394)
1149   if (HAVE_DC1394_2)
1150     status("    DC1394:" "YES (ver ${ALIASOF_libdc1394-2_VERSION})")
1151   elseif (HAVE_DC1394)
1152     status("    DC1394:" "YES (ver ${ALIASOF_libdc1394_VERSION})")
1153   else()
1154     status("    DC1394:" "NO")
1155   endif()
1156 endif()
1157
1158 if(WITH_FFMPEG OR HAVE_FFMPEG)
1159   if(WIN32)
1160     status("    FFMPEG:"       HAVE_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
1161   else()
1162     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
1163   endif()
1164   status("      avcodec:"      FFMPEG_libavcodec_FOUND    THEN "YES (ver ${FFMPEG_libavcodec_VERSION})"    ELSE NO)
1165   status("      avformat:"     FFMPEG_libavformat_FOUND   THEN "YES (ver ${FFMPEG_libavformat_VERSION})"   ELSE NO)
1166   status("      avutil:"       FFMPEG_libavutil_FOUND     THEN "YES (ver ${FFMPEG_libavutil_VERSION})"     ELSE NO)
1167   status("      swscale:"      FFMPEG_libswscale_FOUND    THEN "YES (ver ${FFMPEG_libswscale_VERSION})"    ELSE NO)
1168   status("      avresample:"   FFMPEG_libavresample_FOUND THEN "YES (ver ${FFMPEG_libavresample_VERSION})" ELSE NO)
1169 endif()
1170
1171 if(WITH_GSTREAMER OR HAVE_GSTREAMER)
1172   status("    GStreamer:"      HAVE_GSTREAMER      THEN ""                                         ELSE NO)
1173   if(HAVE_GSTREAMER)
1174     status("      base:"       "YES (ver ${GSTREAMER_BASE_VERSION})")
1175     status("      video:"      "YES (ver ${GSTREAMER_VIDEO_VERSION})")
1176     status("      app:"        "YES (ver ${GSTREAMER_APP_VERSION})")
1177     status("      riff:"       "YES (ver ${GSTREAMER_RIFF_VERSION})")
1178     status("      pbutils:"    "YES (ver ${GSTREAMER_PBUTILS_VERSION})")
1179   endif(HAVE_GSTREAMER)
1180 endif()
1181
1182 if(WITH_OPENNI OR HAVE_OPENNI)
1183   status("    OpenNI:"         HAVE_OPENNI         THEN "YES (ver ${OPENNI_VERSION_STRING}, build ${OPENNI_VERSION_BUILD})" ELSE NO)
1184   status("    OpenNI PrimeSensor Modules:" HAVE_OPENNI_PRIME_SENSOR_MODULE THEN "YES (${OPENNI_PRIME_SENSOR_MODULE})"      ELSE NO)
1185 endif()
1186
1187 if(WITH_OPENNI2 OR HAVE_OPENNI2)
1188   status("    OpenNI2:"        HAVE_OPENNI2    THEN "YES (ver ${OPENNI2_VERSION_STRING}, build ${OPENNI2_VERSION_BUILD})" ELSE NO)
1189 endif()
1190
1191 if(WITH_PVAPI OR HAVE_PVAPI)
1192   status("    PvAPI:"          HAVE_PVAPI          THEN YES                                        ELSE NO)
1193 endif()
1194
1195 if(WITH_GIGEAPI OR HAVE_GIGE_API)
1196   status("    GigEVisionSDK:"  HAVE_GIGE_API       THEN YES                                        ELSE NO)
1197 endif()
1198
1199 if(WITH_ARAVIS OR HAVE_ARAVIS_API)
1200   status("    Aravis SDK:"     HAVE_ARAVIS_API     THEN "YES (${ARAVIS_LIBRARIES})"                ELSE NO)
1201 endif()
1202
1203 if(APPLE)
1204   status("    AVFoundation:"   HAVE_AVFOUNDATION   THEN YES                                        ELSE NO)
1205   if(WITH_QUICKTIME OR HAVE_QUICKTIME)
1206     status("    QuickTime:"      HAVE_QUICKTIME      THEN YES                                        ELSE NO)
1207   endif()
1208   if(WITH_QTKIT OR HAVE_QTKIT)
1209     status("    QTKit:"          HAVE_QTKIT          THEN "YES (deprecated)"                         ELSE NO)
1210   endif()
1211 endif()
1212
1213 if(WITH_UNICAP OR HAVE_UNICAP)
1214   status("    UniCap:"         HAVE_UNICAP         THEN "YES (ver ${ALIASOF_libunicap_VERSION})"   ELSE NO)
1215   status("    UniCap ucil:"    HAVE_UNICAP_UCIL    THEN "YES (ver ${ALIASOF_libucil_VERSION})"     ELSE NO)
1216 endif()
1217
1218 if(WITH_V4L OR WITH_LIBV4L OR HAVE_LIBV4L OR HAVE_CAMV4L OR HAVE_CAMV4L2 OR HAVE_VIDEOIO)
1219   status("    libv4l/libv4l2:" HAVE_LIBV4L THEN "${ALIASOF_libv4l1_VERSION} / ${ALIASOF_libv4l2_VERSION}" ELSE "NO")
1220   ocv_build_features_string(v4l_status
1221     IF HAVE_CAMV4L THEN "linux/videodev.h"
1222     IF HAVE_CAMV4L2 THEN "linux/videodev2.h"
1223     IF HAVE_VIDEOIO THEN "sys/videoio.h"
1224     ELSE "NO")
1225   status("    v4l/v4l2:" "${v4l_status}")
1226 endif()
1227
1228 if(WITH_DSHOW OR HAVE_DSHOW)
1229   status("    DirectShow:"     HAVE_DSHOW     THEN YES                                        ELSE NO)
1230 endif()
1231
1232 if(WITH_MSMF OR HAVE_MSMF)
1233   status("    Media Foundation:" HAVE_MSMF    THEN YES                                        ELSE NO)
1234 endif()
1235
1236 if(WITH_XIMEA OR HAVE_XIMEA)
1237   status("    XIMEA:"          HAVE_XIMEA          THEN YES                                        ELSE NO)
1238 endif()
1239
1240 if(WITH_XINE OR HAVE_XINE)
1241   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${ALIASOF_libxine_VERSION})"     ELSE NO)
1242 endif()
1243
1244 if(WITH_INTELPERC OR HAVE_INTELPERC)
1245   status("    Intel PerC:"     HAVE_INTELPERC      THEN "YES"                                 ELSE NO)
1246 endif()
1247
1248 if(WITH_MFX OR HAVE_MFX)
1249   status("    Intel Media SDK:" HAVE_MFX      THEN "YES (${MFX_LIBRARY})" ELSE NO)
1250 endif()
1251
1252 if(WITH_GPHOTO2 OR HAVE_GPHOTO2)
1253   status("    gPhoto2:"        HAVE_GPHOTO2        THEN "YES"                                 ELSE NO)
1254 endif()
1255
1256 # Order is similar to CV_PARALLEL_FRAMEWORK in core/src/parallel.cpp
1257 ocv_build_features_string(parallel_status EXCLUSIVE
1258   IF HAVE_TBB THEN "TBB (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})"
1259   IF HAVE_CSTRIPES THEN "C="
1260   IF HAVE_OPENMP THEN "OpenMP"
1261   IF HAVE_GCD THEN "GCD"
1262   IF WINRT OR HAVE_CONCURRENCY THEN "Concurrency"
1263   IF HAVE_PTHREADS_PF THEN "pthreads"
1264   ELSE "none")
1265 status("")
1266 status("  Parallel framework:" "${parallel_status}")
1267
1268 if(CV_TRACE OR OPENCV_TRACE)
1269   ocv_build_features_string(trace_status EXCLUSIVE
1270     IF HAVE_ITT THEN "with Intel ITT"
1271     ELSE "built-in")
1272   status("")
1273   status("  Trace: " OPENCV_TRACE THEN "YES (${trace_status})" ELSE NO)
1274 endif()
1275
1276 # ========================== Other third-party libraries ==========================
1277 status("")
1278 status("  Other third-party libraries:")
1279
1280 if(WITH_IPP AND HAVE_IPP)
1281   status("    Intel IPP:" "${IPP_VERSION_STR} [${IPP_VERSION_MAJOR}.${IPP_VERSION_MINOR}.${IPP_VERSION_BUILD}]")
1282   status("           at:" "${IPP_ROOT_DIR}")
1283   if(NOT HAVE_IPP_ICV)
1284     status("       linked:" BUILD_WITH_DYNAMIC_IPP THEN "dynamic" ELSE "static")
1285   endif()
1286   if(HAVE_IPP_IW)
1287     if(BUILD_IPP_IW)
1288       status("    Intel IPP IW:" "sources (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1289     else()
1290       status("    Intel IPP IW:" "binaries (${IW_VERSION_MAJOR}.${IW_VERSION_MINOR}.${IW_VERSION_UPDATE})")
1291     endif()
1292     status("              at:" "${IPP_IW_PATH}")
1293   else()
1294     status("    Intel IPP IW:"   NO)
1295   endif()
1296 endif()
1297
1298 if(WITH_VA OR HAVE_VA)
1299   status("    VA:"            HAVE_VA          THEN "YES" ELSE NO)
1300 endif()
1301
1302 if(WITH_VA_INTEL OR HAVE_VA_INTEL)
1303   status("    Intel VA-API/OpenCL:"  HAVE_VA_INTEL       THEN "YES (MSDK: ${VA_INTEL_MSDK_ROOT}  OpenCL: ${VA_INTEL_IOCL_ROOT})" ELSE NO)
1304 endif()
1305
1306 if(WITH_LAPACK OR HAVE_LAPACK)
1307   status("    Lapack:"      HAVE_LAPACK     THEN "YES (${LAPACK_LIBRARIES})" ELSE NO)
1308 endif()
1309
1310 if(WITH_HALIDE OR HAVE_HALIDE)
1311   status("    Halide:"     HAVE_HALIDE      THEN "YES (${HALIDE_LIBRARIES} ${HALIDE_INCLUDE_DIRS})" ELSE NO)
1312 endif()
1313
1314 if(WITH_EIGEN OR HAVE_EIGEN)
1315   status("    Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
1316 endif()
1317
1318 if(WITH_OPENVX OR HAVE_OPENVX)
1319   status("    OpenVX:"     HAVE_OPENVX      THEN "YES (${OPENVX_LIBRARIES})" ELSE "NO")
1320 endif()
1321
1322 status("    Custom HAL:" OpenCV_USED_HAL  THEN "YES (${OpenCV_USED_HAL})" ELSE "NO")
1323
1324 if(WITH_CUDA OR HAVE_CUDA)
1325   ocv_build_features_string(cuda_features
1326     IF HAVE_CUFFT THEN "CUFFT"
1327     IF HAVE_CUBLAS THEN "CUBLAS"
1328     IF HAVE_NVCUVID THEN "NVCUVID"
1329     IF CUDA_FAST_MATH THEN "FAST_MATH"
1330     ELSE "no extra features")
1331   status("")
1332   status("  NVIDIA CUDA:" HAVE_CUDA THEN "YES (ver ${CUDA_VERSION_STRING}, ${cuda_features})" ELSE NO)
1333   if(HAVE_CUDA)
1334     status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
1335     status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
1336   endif()
1337 endif()
1338
1339 if(WITH_OPENCL OR HAVE_OPENCL)
1340   ocv_build_features_string(opencl_features
1341     IF HAVE_OPENCL_SVM THEN "SVM"
1342     IF HAVE_CLAMDFFT THEN "AMDFFT"
1343     IF HAVE_CLAMDBLAS THEN "AMDBLAS"
1344     ELSE "no extra features")
1345   status("")
1346   status("  OpenCL:"     HAVE_OPENCL   THEN   "YES (${opencl_features})" ELSE "NO")
1347   if(HAVE_OPENCL)
1348     status("    Include path:"  OPENCL_INCLUDE_DIRS THEN "${OPENCL_INCLUDE_DIRS}" ELSE "NO")
1349     status("    Link libraries:"       OPENCL_LIBRARIES THEN "${OPENCL_LIBRARIES}" ELSE "Dynamic load")
1350   endif()
1351 endif()
1352
1353 # ========================== python ==========================
1354 if(BUILD_opencv_python2)
1355   status("")
1356   status("  Python 2:")
1357   status("    Interpreter:"     PYTHON2INTERP_FOUND  THEN "${PYTHON2_EXECUTABLE} (ver ${PYTHON2_VERSION_STRING})"       ELSE NO)
1358   if(PYTHON2LIBS_VERSION_STRING)
1359     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES} (ver ${PYTHON2LIBS_VERSION_STRING})"   ELSE NO)
1360   else()
1361     status("    Libraries:"   HAVE_opencv_python2  THEN  "${PYTHON2_LIBRARIES}"                                      ELSE NO)
1362   endif()
1363   status("    numpy:"         PYTHON2_NUMPY_INCLUDE_DIRS THEN "${PYTHON2_NUMPY_INCLUDE_DIRS} (ver ${PYTHON2_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
1364   status("    packages path:" PYTHON2_EXECUTABLE         THEN "${PYTHON2_PACKAGES_PATH}"                                    ELSE "-")
1365 endif()
1366
1367 if(BUILD_opencv_python3)
1368   status("")
1369   status("  Python 3:")
1370   status("    Interpreter:"     PYTHON3INTERP_FOUND  THEN "${PYTHON3_EXECUTABLE} (ver ${PYTHON3_VERSION_STRING})"       ELSE NO)
1371   if(PYTHON3LIBS_VERSION_STRING)
1372     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES} (ver ${PYTHON3LIBS_VERSION_STRING})"   ELSE NO)
1373   else()
1374     status("    Libraries:"   HAVE_opencv_python3  THEN  "${PYTHON3_LIBRARIES}"                                      ELSE NO)
1375   endif()
1376   status("    numpy:"         PYTHON3_NUMPY_INCLUDE_DIRS THEN "${PYTHON3_NUMPY_INCLUDE_DIRS} (ver ${PYTHON3_NUMPY_VERSION})" ELSE "NO (Python3 wrappers can not be generated)")
1377   status("    packages path:" PYTHON3_EXECUTABLE         THEN "${PYTHON3_PACKAGES_PATH}"                                    ELSE "-")
1378 endif()
1379
1380 status("")
1381 status("  Python (for build):"  PYTHON_DEFAULT_AVAILABLE THEN "${PYTHON_DEFAULT_EXECUTABLE}" ELSE NO)
1382 if(PYLINT_FOUND AND PYLINT_EXECUTABLE)
1383   status("    Pylint:"  PYLINT_FOUND THEN "${PYLINT_EXECUTABLE} (ver: ${PYLINT_VERSION}, checks: ${PYLINT_TOTAL_TARGETS})" ELSE NO)
1384 endif()
1385
1386 # ========================== java ==========================
1387 if(BUILD_opencv_java)
1388   status("")
1389   status("  Java:")
1390   status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
1391   if(NOT ANDROID)
1392     status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
1393   endif()
1394   status("    Java wrappers:" HAVE_opencv_java                                                            THEN YES ELSE NO)
1395   status("    Java tests:"    BUILD_TESTS AND opencv_test_java_BINARY_DIR                                 THEN YES ELSE NO)
1396 endif()
1397
1398 # ========================= matlab =========================
1399 if(WITH_MATLAB OR MATLAB_FOUND)
1400   status("")
1401   status("  Matlab:" MATLAB_FOUND THEN "YES" ELSE "NO")
1402   if(MATLAB_FOUND)
1403     status("    mex:"         MATLAB_MEX_SCRIPT  THEN  "${MATLAB_MEX_SCRIPT}"   ELSE NO)
1404     status("    Compiler/generator:" MEX_WORKS   THEN  "Working"                ELSE "Not working (bindings will not be generated)")
1405   endif()
1406 endif()
1407
1408 # ========================== auxiliary ==========================
1409 status("")
1410 status("  Install to:" "${CMAKE_INSTALL_PREFIX}")
1411 status("-----------------------------------------------------------------")
1412 status("")
1413
1414
1415 ocv_finalize_status()
1416
1417 # ----------------------------------------------------------------------------
1418 # CPack stuff
1419 # ----------------------------------------------------------------------------
1420
1421 include(cmake/OpenCVPackaging.cmake)
1422
1423 # This should be the last command
1424 ocv_cmake_dump_vars("" TOFILE "CMakeVars.txt")
1425 ocv_cmake_eval(DEBUG_POST ONCE)