CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 #
   8 #   - OCT-2008: Initial version <joseluisblancoc@gmail.com>
   9 #
  10 # ----------------------------------------------------------------------------
  11
  12 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  13
  14 # --------------------------------------------------------------
  15 # Indicate CMake 2.7 and above that we don't want to mix relative
  16 #  and absolute paths in linker lib lists.
  17 # Run "cmake --help-policy CMP0003" for more information.
  18 # --------------------------------------------------------------
  19 if(COMMAND cmake_policy)
  20   cmake_policy(SET CMP0003 NEW)
  21 endif()
  22
  23 # Following block can broke build in case of cross-compilng
  24 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  25 # so we will try to detect crosscompiling by presense of CMAKE_TOOLCHAIN_FILE
  26 if(NOT CMAKE_TOOLCHAIN_FILE)
  27   # it _must_ go before project(OpenCV) in order to work
  28   if(WIN32)
  29     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  30   else()
  31     set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  32   endif()
  33
  34   if(MSVC)
  35     set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
  36   endif()
  37 else(NOT CMAKE_TOOLCHAIN_FILE)
  38   #Android: set output folder to ${CMAKE_BINARY_DIR}
  39   set( LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  40   # any crosscompiling
  41   set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  42 endif(NOT CMAKE_TOOLCHAIN_FILE)
  43
  44 # --------------------------------------------------------------
  45 # Top level OpenCV project
  46 # --------------------------------------------------------------
  47 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  48   cmake_minimum_required(VERSION 2.8.8)
  49 elseif(IOS)
  50   cmake_minimum_required(VERSION 2.8.0)
  51 else()
  52   cmake_minimum_required(VERSION 2.6.3)
  53 endif()
  54
  55 # must go before the project command
  56 set(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  57 if(DEFINED CMAKE_BUILD_TYPE AND CMAKE_VERSION VERSION_GREATER "2.8")
  58   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
  59 endif()
  60
  61 project(OpenCV CXX C)
  62
  63 include(cmake/OpenCVUtils.cmake REQUIRED)
  64
  65 # ----------------------------------------------------------------------------
  66 # Break in case of popular CMake configuration mistakes
  67 # ----------------------------------------------------------------------------
  68 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
  69   message(FATAL_ERROR "CMake fails to deterimine the bitness of target platform.
  70   Please check your CMake and compiler installation. If you are crosscompiling then ensure that your CMake toolchain file correctly sets the compiler details.")
  71 endif()
  72
  73 # ----------------------------------------------------------------------------
  74 # Detect compiler and target platform architecture
  75 # ----------------------------------------------------------------------------
  76 include(cmake/OpenCVDetectCXXCompiler.cmake REQUIRED)
  77
  78 # Add these standard paths to the search paths for FIND_LIBRARY
  79 # to find libraries from these locations first
  80 if(UNIX AND NOT ANDROID)
  81   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
  82     if(EXISTS /lib64)
  83       list(APPEND CMAKE_LIBRARY_PATH /lib64)
  84     else()
  85       list(APPEND CMAKE_LIBRARY_PATH /lib)
  86     endif()
  87     if(EXISTS /usr/lib64)
  88       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
  89     else()
  90       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
  91     endif()
  92   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
  93     if(EXISTS /lib32)
  94       list(APPEND CMAKE_LIBRARY_PATH /lib32)
  95     else()
  96       list(APPEND CMAKE_LIBRARY_PATH /lib)
  97     endif()
  98     if(EXISTS /usr/lib32)
  99       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 100     else()
 101       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 102     endif()
 103   endif()
 104 endif()
 105
 106
 107 # ----------------------------------------------------------------------------
 108 # OpenCV cmake options
 109 # ----------------------------------------------------------------------------
 110
 111 # Optional 3rd party components
 112 # ===================================================
 113 OCV_OPTION(WITH_1394           "Include IEEE1394 support"                    ON   IF (UNIX AND NOT ANDROID AND NOT IOS) )
 114 OCV_OPTION(WITH_AVFOUNDATION   "Use AVFoundation for Video I/O"              ON   IF IOS)
 115 OCV_OPTION(WITH_CARBON         "Use Carbon for UI instead of Cocoa"          OFF  IF APPLE )
 116 OCV_OPTION(WITH_CUBLAS         "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" OFF IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 117 OCV_OPTION(WITH_CUDA           "Include NVidia Cuda Runtime support"         ON   IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 118 OCV_OPTION(WITH_CUFFT          "Include NVidia Cuda Fast Fourier Transform (FFT) library support"            ON  IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 119 OCV_OPTION(WITH_EIGEN          "Include Eigen2/Eigen3 support"               ON)
 120 OCV_OPTION(WITH_FFMPEG         "Include FFMPEG support"                      ON   IF (NOT ANDROID AND NOT IOS) )
 121 OCV_OPTION(WITH_GSTREAMER      "Include Gstreamer support"                   ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 122 OCV_OPTION(WITH_GTK            "Include GTK support"                         ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 123 OCV_OPTION(WITH_IMAGEIO        "ImageIO support for OS X"                    OFF  IF APPLE)
 124 OCV_OPTION(WITH_IPP            "Include Intel IPP support"                   OFF  IF (MSVC OR X86 OR X86_64) )
 125 OCV_OPTION(WITH_JASPER         "Include JPEG2K support"                      ON   IF (NOT IOS) )
 126 OCV_OPTION(WITH_JPEG           "Include JPEG support"                        ON   IF (NOT IOS) )
 127 OCV_OPTION(WITH_OPENEXR        "Include ILM support via OpenEXR"             ON   IF (NOT IOS) )
 128 OCV_OPTION(WITH_OPENGL         "Include OpenGL support"                      OFF  IF (NOT ANDROID AND NOT APPLE) )
 129 OCV_OPTION(WITH_OPENNI         "Include OpenNI support"                      OFF  IF (NOT ANDROID AND NOT IOS) )
 130 OCV_OPTION(WITH_PNG            "Include PNG support"                         ON   IF (NOT IOS) )
 131 OCV_OPTION(WITH_PVAPI          "Include Prosilica GigE support"              ON   IF (NOT ANDROID AND NOT IOS) )
 132 OCV_OPTION(WITH_QT             "Build with Qt Backend support"               OFF  IF (NOT ANDROID AND NOT IOS) )
 133 OCV_OPTION(WITH_QUICKTIME      "Use QuickTime for Video I/O insted of QTKit" OFF  IF APPLE )
 134 OCV_OPTION(WITH_TBB            "Include Intel TBB support"                   OFF  IF (NOT IOS) )
 135 OCV_OPTION(WITH_TIFF           "Include TIFF support"                        ON   IF (NOT IOS) )
 136 OCV_OPTION(WITH_UNICAP         "Include Unicap support (GPL)"                OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 137 OCV_OPTION(WITH_V4L            "Include Video 4 Linux support"               ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 138 OCV_OPTION(WITH_VIDEOINPUT     "Build HighGUI with DirectShow support"       ON   IF WIN32 )
 139 OCV_OPTION(WITH_XIMEA          "Include XIMEA cameras support"               OFF  IF (NOT ANDROID AND NOT APPLE) )
 140 OCV_OPTION(WITH_XINE           "Include Xine support (GPL)"                  OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 141 OCV_OPTION(WITH_CLP            "Include Clp support (EPL)"                   OFF)
 142 OCV_OPTION(WITH_OPENCL         "Include OpenCL Runtime support"              OFF  IF (NOT ANDROID AND NOT IOS) )
 143 OCV_OPTION(WITH_OPENCLAMDFFT   "Include AMD OpenCL FFT library support"      OFF  IF (NOT ANDROID AND NOT IOS) )
 144 OCV_OPTION(WITH_OPENCLAMDBLAS  "Include AMD OpenCL BLAS library support"     OFF  IF (NOT ANDROID AND NOT IOS) )
 145
 146
 147 # OpenCV build components
 148 # ===================================================
 149 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR IOS) )
 150 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 151 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" ON )
 152 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 153 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON )
 154 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     ON  IF (NOT IOS) )
 155 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           ON  IF (NOT IOS) )
 156 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into debug libs (not MSCV only)" ON )
 157 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of staticaly linked CRT for staticaly linked OpenCV" ON IF MSVC )
 158 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create fat java wrapper containing the whole OpenCV library" ON IF ANDROID AND NOT BUILD_SHARED_LIBS AND CMAKE_COMPILER_IS_GNUCXX )
 159 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID AND ANDROID_USE_STLPORT AND ANDROID_SOURCE_TREE )
 160 OCV_OPTION(BUILD_ANDROID_PACKAGE    "Build platform-specific package for Google Play" OFF IF ANDROID )
 161
 162
 163 # 3rd party libs
 164 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"         WIN32 OR IOS OR APPLE )
 165 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"      WIN32 OR IOS OR ANDROID OR APPLE )
 166 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"    WIN32 OR IOS OR ANDROID OR APPLE )
 167 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"      WIN32 OR IOS OR ANDROID OR APPLE )
 168 OCV_OPTION(BUILD_PNG                "Build libpng from source"       WIN32 OR IOS OR ANDROID OR APPLE )
 169
 170 # OpenCV installation options
 171 # ===================================================
 172 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 173 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 174 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF  IF ANDROID )
 175 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT IOS AND BUILD_SHARED_LIBS) )
 176
 177
 178 if(MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode)
 179   set(ENABLE_SOLUTION_FOLDERS0 ON)
 180 else()
 181   set(ENABLE_SOLUTION_FOLDERS0 OFF)
 182 endif()
 183
 184 # OpenCV build options
 185 # ===================================================
 186 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON   IF (NOT IOS) )
 187 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        ${ENABLE_SOLUTION_FOLDERS0} IF (CMAKE_VERSION VERSION_GREATER "2.8.0") )
 188 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CMAKE_COMPILER_IS_GNUCXX )
 189 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CMAKE_COMPILER_IS_GNUCXX )
 190 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CMAKE_COMPILER_IS_GNUCXX AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 191 OCV_OPTION(ENABLE_FAST_MATH           "Enable -ffast-math (not recommended for GCC 4.6.x)"       OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 192 OCV_OPTION(ENABLE_SSE                 "Enable SSE instructions"                                  ON   IF (MSVC OR CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 193 OCV_OPTION(ENABLE_SSE2                "Enable SSE2 instructions"                                 ON   IF (MSVC OR CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 194 OCV_OPTION(ENABLE_SSE3                "Enable SSE3 instructions"                                 OFF  IF (CV_ICC OR CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 195 OCV_OPTION(ENABLE_SSSE3               "Enable SSSE3 instructions"                                OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 196 OCV_OPTION(ENABLE_SSE41               "Enable SSE4.1 instructions"                               OFF  IF (CV_ICC OR CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 197 OCV_OPTION(ENABLE_SSE42               "Enable SSE4.2 instructions"                               OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 198 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 199 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 200
 201 # uncategorized options
 202 # ===================================================
 203 OCV_OPTION(CMAKE_VERBOSE "Verbose mode" OFF )
 204
 205 # backward compatibility
 206 # ===================================================
 207 include(cmake/OpenCVLegacyOptions.cmake OPTIONAL)
 208
 209
 210 # ----------------------------------------------------------------------------
 211 #  Get actual OpenCV version number from sources
 212 # ----------------------------------------------------------------------------
 213 include(cmake/OpenCVVersion.cmake REQUIRED)
 214
 215
 216 # ----------------------------------------------------------------------------
 217 #  Build & install layouts
 218 # ----------------------------------------------------------------------------
 219
 220 # Save libs and executables in the same place
 221 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications" )
 222
 223 if(ANDROID OR WIN32)
 224     set(OPENCV_DOC_INSTALL_PATH doc)
 225 elseif(INSTALL_TO_MANGLED_PATHS)
 226     set(OPENCV_DOC_INSTALL_PATH share/OpenCV-${OPENCV_VERSION}/doc)
 227 else()
 228     set(OPENCV_DOC_INSTALL_PATH share/OpenCV/doc)
 229 endif()
 230
 231 if(ANDROID)
 232     set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 233     set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 234     set(OPENCV_LIB_INSTALL_PATH     sdk/native/libs/${ANDROID_NDK_ABI_NAME})
 235     set(OPENCV_3P_LIB_INSTALL_PATH  sdk/native/3rdparty/libs/${ANDROID_NDK_ABI_NAME})
 236     set(OPENCV_CONFIG_INSTALL_PATH  sdk/native/jni)
 237     set(OPENCV_INCLUDE_INSTALL_PATH sdk/native/jni/include)
 238 else()
 239     set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib")
 240     set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib${LIB_SUFFIX}")
 241     set(OPENCV_LIB_INSTALL_PATH     lib${LIB_SUFFIX})
 242     set(OPENCV_3P_LIB_INSTALL_PATH  share/OpenCV/3rdparty/${OPENCV_LIB_INSTALL_PATH})
 243     set(OPENCV_INCLUDE_INSTALL_PATH include)
 244
 245     math(EXPR SIZEOF_VOID_P_BITS "8 * ${CMAKE_SIZEOF_VOID_P}")
 246     if(LIB_SUFFIX AND NOT SIZEOF_VOID_P_BITS EQUAL LIB_SUFFIX)
 247       set(OPENCV_CONFIG_INSTALL_PATH lib${LIB_SUFFIX}/cmake/opencv)
 248     else()
 249       set(OPENCV_CONFIG_INSTALL_PATH share/OpenCV)
 250     endif()
 251 endif()
 252
 253 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 254 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 255
 256 if(INSTALL_TO_MANGLED_PATHS)
 257   set(OPENCV_INCLUDE_INSTALL_PATH ${OPENCV_INCLUDE_INSTALL_PATH}/opencv-${OPENCV_VERSION})
 258 endif()
 259
 260 if(WIN32)
 261   # Postfix of DLLs:
 262   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 263   set(OPENCV_DEBUG_POSTFIX d)
 264 else()
 265   # Postfix of so's:
 266   set(OPENCV_DLLVERSION "")
 267   set(OPENCV_DEBUG_POSTFIX "")
 268 endif()
 269
 270 if(DEFINED CMAKE_DEBUG_POSTFIX)
 271   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 272 endif()
 273
 274 if(CMAKE_VERBOSE)
 275   set(CMAKE_VERBOSE_MAKEFILE 1)
 276 endif()
 277
 278
 279 # ----------------------------------------------------------------------------
 280 #  Path for build/platform -specific headers
 281 # ----------------------------------------------------------------------------
 282 set(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 283 add_definitions(-DHAVE_CVCONFIG_H)
 284 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 285
 286
 287 # ----------------------------------------------------------------------------
 288 #  Autodetect if we are in a GIT repository
 289 # ----------------------------------------------------------------------------
 290
 291 # don't use FindGit because it requires CMake 2.8.2
 292 set(git_names git eg) # eg = easy git
 293 # Prefer .cmd variants on Windows unless running in a Makefile in the MSYS shell
 294 if(WIN32)
 295   if(NOT CMAKE_GENERATOR MATCHES "MSYS")
 296     set(git_names git.cmd git eg.cmd eg)
 297   endif()
 298 endif()
 299
 300 find_host_program(GIT_EXECUTABLE NAMES ${git_names} PATH_SUFFIXES Git/cmd Git/bin DOC "git command line client")
 301 mark_as_advanced(GIT_EXECUTABLE)
 302
 303 if(GIT_EXECUTABLE)
 304   execute_process(COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
 305     WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 306     OUTPUT_VARIABLE OPENCV_GIT_HASH_SORT
 307     RESULT_VARIABLE GIT_RESULT
 308     ERROR_QUIET
 309     OUTPUT_STRIP_TRAILING_WHITESPACE
 310   )
 311   if(GIT_RESULT EQUAL 0)
 312     set(OPENCV_VCSVERSION "commit:${OPENCV_GIT_HASH_SORT}")
 313   else()
 314     set(OPENCV_VCSVERSION "exported")
 315   endif()
 316 else()
 317   # We don't have git:
 318   set(OPENCV_VCSVERSION "")
 319 endif()
 320
 321
 322 # ----------------------------------------------------------------------------
 323 # OpenCV compiler and linker options
 324 # ----------------------------------------------------------------------------
 325 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 326 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 327   set(CMAKE_BUILD_TYPE Release)
 328 endif()
 329
 330 include(cmake/OpenCVCompilerOptions.cmake REQUIRED)
 331
 332
 333 # ----------------------------------------------------------------------------
 334 # Use statically or dynamically linked CRT?
 335 # Default: dynamic
 336 # ----------------------------------------------------------------------------
 337 if(MSVC)
 338   include(cmake/OpenCVCRTLinkage.cmake REQUIRED)
 339 endif(MSVC)
 340
 341
 342 # ----------------------------------------------------------------------------
 343 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 344 # ----------------------------------------------------------------------------
 345 if(UNIX)
 346   include(cmake/OpenCVFindPkgConfig.cmake OPTIONAL)
 347   include(CheckFunctionExists)
 348   include(CheckIncludeFile)
 349
 350   if(NOT APPLE)
 351     CHECK_INCLUDE_FILE(alloca.h HAVE_ALLOCA_H)
 352     CHECK_FUNCTION_EXISTS(alloca HAVE_ALLOCA)
 353     CHECK_INCLUDE_FILE(unistd.h HAVE_UNISTD_H)
 354     CHECK_INCLUDE_FILE(pthread.h HAVE_LIBPTHREAD)
 355     if(ANDROID)
 356       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 357     elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD|NetBSD|DragonFly")
 358       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 359     else()
 360       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 361     endif()
 362   else()
 363     add_definitions(-DHAVE_ALLOCA -DHAVE_ALLOCA_H -DHAVE_LIBPTHREAD -DHAVE_UNISTD_H)
 364   endif()
 365 endif()
 366
 367 include(cmake/OpenCVPCHSupport.cmake REQUIRED)
 368 include(cmake/OpenCVModule.cmake REQUIRED)
 369
 370 # ----------------------------------------------------------------------------
 371 #  Detect 3rd-party libraries
 372 # ----------------------------------------------------------------------------
 373
 374 include(cmake/OpenCVFindLibsGrfmt.cmake REQUIRED)
 375 include(cmake/OpenCVFindLibsGUI.cmake   REQUIRED)
 376 include(cmake/OpenCVFindLibsVideo.cmake REQUIRED)
 377 include(cmake/OpenCVFindLibsPerf.cmake  REQUIRED)
 378
 379
 380 # ----------------------------------------------------------------------------
 381 #  Detect other 3rd-party libraries/tools
 382 # ----------------------------------------------------------------------------
 383
 384 # --- LATEX for pdf documentation ---
 385 if(BUILD_DOCS)
 386   include(cmake/OpenCVFindLATEX.cmake REQUIRED)
 387 endif(BUILD_DOCS)
 388
 389 # --- Python Support ---
 390 include(cmake/OpenCVDetectPython.cmake REQUIRED)
 391
 392 # --- Java Support ---
 393 if(ANDROID)
 394   include(cmake/OpenCVDetectApacheAnt.cmake REQUIRED)
 395   include(cmake/OpenCVDetectAndroidSDK.cmake REQUIRED)
 396
 397   if(NOT ANDROID_TOOLS_Pkg_Revision GREATER 13)
 398     message(WARNING "OpenCV requires Android SDK tools revision 14 or newer. Otherwise tests and samples will no be compiled.")
 399   endif()
 400 endif(ANDROID)
 401
 402 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 403   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 404 else()
 405   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 406 endif()
 407
 408 # --- OpenCL ---
 409 if(WITH_OPENCL)
 410   include(cmake/OpenCVDetectOpenCL.cmake REQUIRED)
 411   if(OPENCL_FOUND)
 412     set(HAVE_OPENCL 1)
 413   endif()
 414   if(WITH_OPENCLAMDFFT)
 415     set(HAVE_CLAMDFFT 1)
 416   endif()
 417   if(WITH_OPENCLAMDBLAS)
 418     set(HAVE_CLAMDBLAS 1)
 419   endif()
 420 endif()
 421
 422 # ----------------------------------------------------------------------------
 423 # Solution folders:
 424 # ----------------------------------------------------------------------------
 425 if(ENABLE_SOLUTION_FOLDERS)
 426   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 427   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 428 endif()
 429
 430 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 431 include(cmake/OpenCVExtraTargets.cmake REQUIRED)
 432
 433
 434 # ----------------------------------------------------------------------------
 435 # Process subdirectories
 436 # ----------------------------------------------------------------------------
 437
 438 # opencv.hpp and legacy headers
 439 add_subdirectory(include)
 440
 441 # OpenCV modules
 442 add_subdirectory(modules)
 443
 444 # Generate targets for documentation
 445 add_subdirectory(doc)
 446
 447 # various data that is used by cv libraries and/or demo applications.
 448 add_subdirectory(data)
 449
 450 # extra applications
 451 add_subdirectory(apps)
 452
 453 # examples
 454 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES)
 455   add_subdirectory(samples)
 456 endif()
 457
 458 if(BUILD_ANDROID_SERVICE)
 459   add_subdirectory(android/service)
 460 endif()
 461
 462 if(BUILD_ANDROID_PACKAGE)
 463   add_subdirectory(android/package)
 464 endif()
 465
 466 # ----------------------------------------------------------------------------
 467 # Finalization: generate configuration-based files
 468 # ----------------------------------------------------------------------------
 469 ocv_track_build_dependencies()
 470
 471 # Generate platform-dependent and configuration-dependent headers
 472 include(cmake/OpenCVGenHeaders.cmake REQUIRED)
 473
 474 # Generate opencv.pc for pkg-config command
 475 include(cmake/OpenCVGenPkgconfig.cmake REQUIRED)
 476
 477 # Generate OpenCV.mk for ndk-build (Android build tool)
 478 include(cmake/OpenCVGenAndroidMK.cmake REQUIRED)
 479
 480 # Generate OpenCVСonfig.cmake and OpenCVConfig-version.cmake for cmake projects
 481 include(cmake/OpenCVGenConfig.cmake REQUIRED)
 482
 483
 484 # ----------------------------------------------------------------------------
 485 # Summary:
 486 # ----------------------------------------------------------------------------
 487 status("")
 488 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 489 if(OPENCV_VCSVERSION)
 490   status("  Version control:" ${OPENCV_VCSVERSION})
 491 endif()
 492
 493 # ========================== build platform ==========================
 494 status("")
 495 status("  Platform:")
 496 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
 497 if(CMAKE_CROSSCOMPILING)
 498   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
 499 endif()
 500 status("    CMake:"            ${CMAKE_VERSION})
 501 status("    CMake generator:"  ${CMAKE_GENERATOR})
 502 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
 503 if(MSVC)
 504   status("    MSVC:"           ${MSVC_VERSION})
 505 endif()
 506 if(CMAKE_GENERATOR MATCHES Xcode)
 507   status("    Xcode:"          ${XCODE_VERSION})
 508 endif()
 509 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
 510   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
 511 endif()
 512
 513 # ========================== C/C++ options ==========================
 514 status("")
 515 status("  C/C++:")
 516 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
 517 status("    C++ Compiler:"           CMAKE_COMPILER_IS_GNUCXX THEN "${CMAKE_CXX_COMPILER} (ver ${CMAKE_GCC_REGEX_VERSION})" ELSE "${CMAKE_CXX_COMPILER}" )
 518 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
 519 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
 520 status("    C Compiler:"             ${CMAKE_C_COMPILER})
 521 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
 522 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
 523 if(WIN32)
 524   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
 525   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
 526 else()
 527   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
 528   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
 529 endif()
 530 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
 531
 532 # ========================== OpenCV modules ==========================
 533 status("")
 534 status("  OpenCV modules:")
 535 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD}")
 536 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
 537 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
 538 set(OPENCV_MODULES_DISABLED_AUTO_ST "")
 539 foreach(m ${OPENCV_MODULES_DISABLED_AUTO})
 540   set(__mdeps "")
 541   foreach(d ${OPENCV_MODULE_${m}_DEPS})
 542     if(d MATCHES "^opencv_" AND NOT HAVE_${d})
 543       list(APPEND __mdeps ${d})
 544     endif()
 545   endforeach()
 546   list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}(deps: ${__mdeps})")
 547 endforeach()
 548 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO_ST}")
 549
 550 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
 551 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
 552 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
 553 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
 554
 555 # ========================== Android details ==========================
 556 if(ANDROID)
 557   status("")
 558   status("  Android: ")
 559   status("    Android ABI:" ${ANDROID_ABI})
 560   status("    Native API level:" android-${ANDROID_NATIVE_API_LEVEL})
 561   status("    SDK target:" "${ANDROID_SDK_TARGET}")
 562   if(BUILD_WITH_ANDROID_NDK)
 563     status("    Android NDK:" "${ANDROID_NDK} (toolchain: ${ANDROID_TOOLCHAIN_NAME})")
 564   elseif(BUILD_WITH_STANDALONE_TOOLCHAIN)
 565     status("    Android toolchain:" "${ANDROID_STANDALONE_TOOLCHAIN}")
 566   endif()
 567   status("    android tool:"  ANDROID_EXECUTABLE  THEN "${ANDROID_EXECUTABLE} (${ANDROID_TOOLS_Pkg_Desc})" ELSE NO)
 568   status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"            ELSE NO)
 569   status("    Google Play package:" BUILD_ANDROID_PACKAGE THEN YES ELSE NO)
 570 endif()
 571
 572 # ========================== GUI ==========================
 573 status("")
 574 status("  GUI: ")
 575
 576 if(HAVE_QT)
 577   status("    QT 4.x:"            HAVE_QT        THEN "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})" ELSE NO)
 578   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
 579 else()
 580   if(DEFINED WITH_QT)
 581     status("    QT 4.x:" NO)
 582   endif()
 583   if(WIN32)
 584     status("    Win32 UI:" YES)
 585   else()
 586     if(APPLE)
 587       if(WITH_CARBON)
 588         status("    Carbon:" YES)
 589       else()
 590         status("    Cocoa:"  YES)
 591       endif()
 592     else()
 593       status("    GTK+ 2.x:" HAVE_GTK      THEN "YES (ver ${ALIASOF_gtk+-2.0_VERSION})"     ELSE NO)
 594       status("    GThread :" HAVE_GTHREAD  THEN "YES (ver ${ALIASOF_gthread-2.0_VERSION})"  ELSE NO)
 595       status("    GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${ALIASOF_gtkglext-1.0_VERSION})" ELSE NO)
 596     endif()
 597   endif()
 598 endif()
 599
 600 status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
 601
 602 # ========================== MEDIA IO ==========================
 603 status("")
 604 status("  Media I/O: ")
 605 status("    ZLib:"         BUILD_ZLIB    THEN "build (ver ${ZLIB_VERSION_STRING})"               ELSE "${ZLIB_LIBRARY} (ver ${ZLIB_VERSION_STRING})")
 606
 607 if(WITH_JPEG)
 608   status("    JPEG:"       JPEG_FOUND    THEN "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})"        ELSE "build (ver ${JPEG_LIB_VERSION})")
 609 else()
 610   status("    JPEG:"       "NO")
 611 endif()
 612 if(WITH_PNG)
 613   status("    PNG:"        PNG_FOUND     THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})"              ELSE "build (ver ${PNG_VERSION})")
 614 else()
 615   status("    PNG:"        "NO")
 616 endif()
 617 if(WITH_TIFF)
 618   if(TIFF_VERSION_STRING AND TIFF_FOUND)
 619     status("    TIFF:"     "${TIFF_LIBRARY} (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 620   else()
 621     status("    TIFF:"     TIFF_FOUND    THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION})"            ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 622   endif()
 623 else()
 624   status("    TIFF:"       "NO")
 625 endif()
 626 if(WITH_JASPER)
 627   status("    JPEG 2000:"  JASPER_FOUND  THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
 628 else()
 629   status("    JPEG 2000:"  "NO")
 630 endif()
 631
 632 status("    OpenEXR:"   WITH_OPENEXR AND OPENEXR_FOUND     THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})"                     ELSE NO)
 633
 634 # ========================== VIDEO IO ==========================
 635 status("")
 636 status("  Video I/O:")
 637
 638 if(DEFINED WITH_1394)
 639   status("    DC1394 1.x:"     HAVE_DC1394         THEN "YES (ver ${ALIASOF_libdc1394_VERSION})"   ELSE NO)
 640   status("    DC1394 2.x:"     HAVE_DC1394_2       THEN "YES (ver ${ALIASOF_libdc1394-2_VERSION})" ELSE NO)
 641 endif(DEFINED WITH_1394)
 642
 643 if(ANDROID)
 644   if(HAVE_opencv_androidcamera)
 645     status("    AndroidNativeCamera:" BUILD_ANDROID_CAMERA_WRAPPER
 646                                                    THEN "YES, build for Android${ANDROID_VERSION}" ELSE "YES, use prebuilt libraries")
 647   else()
 648     status("    AndroidNativeCamera:" "NO (native camera requires Android API level 8 or higher)")
 649   endif()
 650 endif()
 651
 652 if(DEFINED WITH_AVFOUNDATION)
 653   status("    AVFoundation:"   WITH_AVFOUNDATION   THEN YES                                        ELSE NO)
 654 endif(DEFINED WITH_AVFOUNDATION)
 655
 656 if(DEFINED WITH_FFMPEG)
 657   if(WIN32)
 658     status("    FFMPEG:"       WITH_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
 659   else()
 660     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
 661   endif()
 662   status("      codec:"        HAVE_FFMPEG_CODEC   THEN "YES (ver ${ALIASOF_libavcodec_VERSION})"  ELSE NO)
 663   status("      format:"       HAVE_FFMPEG_FORMAT  THEN "YES (ver ${ALIASOF_libavformat_VERSION})" ELSE NO)
 664   status("      util:"         HAVE_FFMPEG_UTIL    THEN "YES (ver ${ALIASOF_libavutil_VERSION})"   ELSE NO)
 665   status("      swscale:"      HAVE_FFMPEG_SWSCALE THEN "YES (ver ${ALIASOF_libswscale_VERSION})"  ELSE NO)
 666   status("      gentoo-style:" HAVE_GENTOO_FFMPEG  THEN YES                                        ELSE NO)
 667 endif(DEFINED WITH_FFMPEG)
 668
 669 if(DEFINED WITH_GSTREAMER)
 670   status("    GStreamer:"      HAVE_GSTREAMER      THEN ""                                         ELSE NO)
 671   if(HAVE_GSTREAMER)
 672     status("      base:"       "YES (ver ${ALIASOF_gstreamer-base-0.10_VERSION})")
 673     status("      app:"        "YES (ver ${ALIASOF_gstreamer-app-0.10_VERSION})")
 674     status("      video:"      "YES (ver ${ALIASOF_gstreamer-video-0.10_VERSION})")
 675   endif()
 676 endif(DEFINED WITH_GSTREAMER)
 677
 678 if(DEFINED WITH_OPENNI)
 679   status("    OpenNI:"         HAVE_OPENNI         THEN "YES (ver ${OPENNI_VERSION_STRING}, build ${OPENNI_VERSION_BUILD})"
 680                                                                                                    ELSE NO)
 681   status("    OpenNI PrimeSensor Modules:" HAVE_OPENNI_PRIME_SENSOR_MODULE
 682                                                    THEN "YES (${OPENNI_PRIME_SENSOR_MODULE})"      ELSE NO)
 683 endif(DEFINED WITH_OPENNI)
 684
 685 if(DEFINED WITH_PVAPI)
 686   status("    PvAPI:"          HAVE_PVAPI          THEN YES                                        ELSE NO)
 687 endif(DEFINED WITH_PVAPI)
 688
 689 if(DEFINED WITH_QUICKTIME)
 690   status("    QuickTime:"      WITH_QUICKTIME      THEN YES                                        ELSE NO)
 691   status("    QTKit:"          WITH_QUICKTIME      THEN NO                                         ELSE YES)
 692 endif(DEFINED WITH_QUICKTIME)
 693
 694 if(DEFINED WITH_UNICAP)
 695   status("    UniCap:"         HAVE_UNICAP         THEN "YES (ver ${ALIASOF_libunicap_VERSION})"   ELSE NO)
 696   status("    UniCap ucil:"    HAVE_UNICAP_UCIL    THEN "YES (ver ${ALIASOF_libucil_VERSION})"     ELSE NO)
 697 endif(DEFINED WITH_UNICAP)
 698
 699 if(DEFINED WITH_V4L)
 700   if(HAVE_CAMV4L)
 701     set(HAVE_CAMV4L_STR "YES")
 702   else()
 703     set(HAVE_CAMV4L_STR "NO")
 704   endif()
 705   if(HAVE_CAMV4L2)
 706     set(HAVE_CAMV4L2_STR "YES")
 707   else()
 708     set(HAVE_CAMV4L2_STR "NO")
 709   endif()
 710   status("    V4L/V4L2:"       HAVE_LIBV4L         THEN "Using libv4l (ver ${ALIASOF_libv4l1_VERSION})"
 711                                                                                                    ELSE "${HAVE_CAMV4L_STR}/${HAVE_CAMV4L2_STR}")
 712 endif(DEFINED WITH_V4L)
 713
 714 if(DEFINED WITH_VIDEOINPUT)
 715   status("    DirectShow:"     HAVE_VIDEOINPUT     THEN YES                                        ELSE NO)
 716 endif(DEFINED WITH_VIDEOINPUT)
 717
 718 if(DEFINED WITH_XIMEA)
 719   status("    XIMEA:"          HAVE_XIMEA          THEN YES                                        ELSE NO)
 720 endif(DEFINED WITH_XIMEA)
 721
 722 if(DEFINED WITH_XINE)
 723   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${ALIASOF_libxine_VERSION})"     ELSE NO)
 724 endif(DEFINED WITH_XINE)
 725
 726 # ========================== Other third-party libraries ==========================
 727 status("")
 728 status("  Other third-party libraries:")
 729
 730 if(DEFINED WITH_IPP)
 731   if(WITH_IPP AND IPP_FOUND)
 732     status("    Use IPP:" "${IPP_LATEST_VERSION_STR} [${IPP_LATEST_VERSION_MAJOR}.${IPP_LATEST_VERSION_MINOR}.${IPP_LATEST_VERSION_BUILD}]")
 733     status("         at:" "${IPP_ROOT_DIR}")
 734   else()
 735     status("    Use IPP:"   WITH_IPP AND NOT IPP_FOUND THEN "IPP not found" ELSE NO)
 736   endif()
 737 endif(DEFINED WITH_IPP)
 738
 739 if(DEFINED WITH_TBB)
 740   status("    Use TBB:"   HAVE_TBB   THEN "YES (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})" ELSE NO)
 741 endif(DEFINED WITH_TBB)
 742
 743 if(DEFINED WITH_CUDA)
 744   status("    Use Cuda:"  HAVE_CUDA  THEN "YES (ver ${CUDA_VERSION_STRING})" ELSE NO)
 745 endif(DEFINED WITH_CUDA)
 746
 747 status("    Use OpenCL:"  HAVE_OPENCL  THEN YES ELSE NO)
 748
 749 status("    Use Eigen:" HAVE_EIGEN THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
 750 status("    Use Clp:"   HAVE_CLP   THEN YES ELSE NO)
 751
 752 if(HAVE_CUDA)
 753   status("")
 754   status("  NVIDIA CUDA:"            "(ver ${CUDA_VERSION_STRING})")
 755
 756   status("    Use CUFFT:"            HAVE_CUFFT  THEN YES ELSE NO)
 757   status("    Use CUBLAS:"           HAVE_CUBLAS THEN YES ELSE NO)
 758   status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
 759   status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_BIN})
 760   status("    NVIDIA GPU features:"  ${OPENCV_CUDA_ARCH_FEATURES})
 761 endif()
 762
 763 # ========================== python ==========================
 764 status("")
 765 status("  Python:")
 766 status("    Interpreter:"   PYTHON_EXECUTABLE     THEN "${PYTHON_EXECUTABLE} (ver ${PYTHON_VERSION_FULL})"         ELSE NO)
 767 if(BUILD_opencv_python)
 768   if(PYTHONLIBS_VERSION_STRING)
 769     status("    Libraries:"     HAVE_opencv_python  THEN  "${PYTHON_LIBRARIES} (ver ${PYTHONLIBS_VERSION_STRING})" ELSE NO)
 770   else()
 771     status("    Libraries:"     HAVE_opencv_python  THEN  ${PYTHON_LIBRARIES}                                      ELSE NO)
 772   endif()
 773   status("    numpy:"         PYTHON_USE_NUMPY    THEN "${PYTHON_NUMPY_INCLUDE_DIR} (ver ${PYTHON_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
 774   status("    packages path:" PYTHON_EXECUTABLE   THEN "${PYTHON_PACKAGES_PATH}"                                   ELSE "-")
 775 endif()
 776
 777 # ========================== documentation ==========================
 778 if(BUILD_DOCS)
 779   status("")
 780   status("  Documentation:")
 781   if(HAVE_SPHINX)
 782     status("    Build Documentation:" PDFLATEX_COMPILER      THEN YES ELSE "YES (only HTML and without math expressions)")
 783   else()
 784     status("    Build Documentation:" NO)
 785   endif()
 786   status("    Sphinx:"              HAVE_SPHINX              THEN "${SPHINX_BUILD} (ver ${SPHINX_VERSION})" ELSE NO)
 787   status("    PdfLaTeX compiler:"   PDFLATEX_COMPILER        THEN "${PDFLATEX_COMPILER}" ELSE NO)
 788 endif()
 789
 790 # ========================== samples and tests ==========================
 791 status("")
 792 status("  Tests and samples:")
 793 status("    Tests:"             BUILD_TESTS AND HAVE_opencv_ts       THEN YES ELSE NO)
 794 status("    Performance tests:" BUILD_PERF_TESTS AND HAVE_opencv_ts  THEN YES ELSE NO)
 795 status("    Examples:"          BUILD_EXAMPLES                       THEN YES ELSE NO)
 796
 797 if(ANDROID)
 798   status("    Android tests:"    BUILD_TESTS AND CAN_BUILD_ANDROID_PROJECTS            THEN YES ELSE NO)
 799   status("    Android examples:" BUILD_ANDROID_EXAMPLES AND CAN_BUILD_ANDROID_PROJECTS THEN YES ELSE NO)
 800 endif()
 801
 802 # ========================== auxiliary ==========================
 803 status("")
 804 status("  Install path:" "${CMAKE_INSTALL_PREFIX}")
 805 status("")
 806 status("  cvconfig.h is in:" "${OPENCV_CONFIG_FILE_INCLUDE_DIR}")
 807 status("-----------------------------------------------------------------")
 808 status("")
 809
 810 ocv_finalize_status()
 811
 812 # ----------------------------------------------------------------------------
 813 # Warn in the case of in-source build
 814 # ----------------------------------------------------------------------------
 815 if("${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 816   message(WARNING "The source directory is the same as binary directory. \"make clean\" may damage the source tree")
 817 endif()
 818