CMakeLists.txt

   1 # dEQP cmake file
   2
   3 # Module FindGit requires cmake >= 2.8.2
   4 cmake_minimum_required(VERSION 2.8.2)
   5
   6 find_package(Git)
   7 find_package(PythonInterp 2)
   8
   9 # dEQP Target.
  10 set(DEQP_TARGET "default" CACHE STRING "dEQP Target (default, android...)")
  11
  12 if (DEFINED DEQP_TARGET_TOOLCHAIN)
  13         # \note Toolchain must be included before project() command
  14         include(targets/${DEQP_TARGET}/${DEQP_TARGET_TOOLCHAIN}.cmake NO_POLICY_SCOPE)
  15 endif ()
  16
  17 project(dEQP-Core-${DEQP_TARGET})
  18
  19 include(framework/delibs/cmake/Defs.cmake NO_POLICY_SCOPE)
  20 include(framework/delibs/cmake/CFlags.cmake)
  21
  22 add_definitions(-DDE_ASSERT_FAILURE_CALLBACK)
  23
  24 # dEQP-specific configuration. Target file should override these.
  25 set(DEQP_TARGET_NAME            "UNKNOWN")              # Target name
  26
  27 set(DEQP_GLES2_LIBRARIES        )                               # GLESv2 libraries. If empty, run-time linking is used
  28 set(DEQP_GLES3_LIBRARIES        )                               # GLESv3 libraries. If empty, run-time linking is used
  29 set(DEQP_EGL_LIBRARIES          )                               # EGL libraries
  30
  31 # Legacy APIs that don't use run-time loading
  32 set(DEQP_SUPPORT_GLES1          OFF)                    # Is GLESv1 supported
  33 set(DEQP_GLES1_LIBRARIES        )                               # GLESv1 libraries
  34 set(DEQP_SUPPORT_VG                     OFF)                    # Is OpenVG supported
  35 set(DEQP_VG_LIBRARIES           )                               # VG libraries
  36
  37 set(DEQP_SUPPORT_WGL            OFF)
  38 set(DEQP_SUPPORT_GLX            OFF)                    # Is GLX supported \todo [2016-10-12 pyry] X11 specific - move to framework/platform/
  39
  40 set(DEQP_PLATFORM_LIBRARIES     )                               # Other platform libraries
  41
  42 set(DEQP_PLATFORM_COPY_LIBRARIES        )               # Libraries / binaries that need to be copied to binary directory
  43
  44 # Delibs include directories
  45 include_directories(
  46         framework/delibs/debase
  47         framework/delibs/decpp
  48         framework/delibs/depool
  49         framework/delibs/dethread
  50         framework/delibs/deutil
  51         framework/delibs/destream
  52         )
  53
  54 # Include target-specific definitions
  55 include(targets/${DEQP_TARGET}/${DEQP_TARGET}.cmake)
  56
  57 # zlib
  58 find_path(ZLIB_INCLUDE_PATH     zlib.h)
  59 find_library(ZLIB_LIBRARY       z)
  60
  61 if (NOT ZLIB_INCLUDE_PATH OR NOT ZLIB_LIBRARY)
  62         message(STATUS "System version of zlib not found, using external/zlib")
  63         add_subdirectory(external/zlib)
  64         # \note ZLIB_LIBRARY and ZLIB_INCLUDE_PATH are promoted from external/zlib/CMakeLists.txt
  65 endif ()
  66
  67 include_directories(${ZLIB_INCLUDE_PATH})
  68
  69 # libpng
  70 #
  71 # The FindPNG module defines PNG_INCLUDE_DIRS and PNG_LIBRARIES. But dEQP's
  72 # CMake files expect the non-standard PNG_INCLUDE_PATH and PNG_LIBRARY. Set the
  73 # non-standard variables here to retain compatibility with dEQP's existing
  74 # CMake files.
  75 include(FindPNG)
  76 set(PNG_INCLUDE_PATH ${PNG_INCLUDE_DIRS})
  77 set(PNG_LIBRARY ${PNG_LIBRARIES})
  78
  79 if (NOT PNG_INCLUDE_PATH OR NOT PNG_LIBRARY)
  80         message(STATUS "System version of libpng not found, using external/libpng")
  81         add_subdirectory(external/libpng)
  82         # \note PNG_LIBRARY and PNG_INCLUDE_PATH are promoted from external/libpng/CMakeLists.txt
  83 endif ()
  84
  85 # glslang
  86 add_subdirectory(external/glslang)
  87
  88 # spirv-tools
  89 add_subdirectory(external/spirv-tools)
  90
  91 # VkRunner
  92 add_subdirectory(external/vkrunner)
  93 include_directories(external/vkrunner/src)
  94
  95 # spirv-headers
  96 set(SPIRV_INCLUDE_PATH "${PROJECT_SOURCE_DIR}/external/spirv-headers/src/include")
  97 if (NOT EXISTS ${SPIRV_INCLUDE_PATH})
  98         message(FATAL_ERROR "SPIR-V headers not found, please run external/fetch_sources.py")
  99 endif()
 100 include_directories(${SPIRV_INCLUDE_PATH})
 101
 102 # Amber
 103 add_subdirectory(external/amber)
 104 include_directories(external/amber)
 105
 106 # RenderDoc API
 107 include_directories(external/renderdoc/src)
 108
 109 include_directories(${PNG_INCLUDE_PATH})
 110
 111 message(STATUS "DEQP_TARGET_NAME        = ${DEQP_TARGET_NAME}")
 112 message(STATUS "DEQP_SUPPORT_GLES1      = ${DEQP_SUPPORT_GLES1}")
 113 message(STATUS "DEQP_GLES1_LIBRARIES    = ${DEQP_GLES1_LIBRARIES}")
 114 message(STATUS "DEQP_GLES2_LIBRARIES    = ${DEQP_GLES2_LIBRARIES}")
 115 message(STATUS "DEQP_GLES3_LIBRARIES    = ${DEQP_GLES3_LIBRARIES}")
 116 message(STATUS "DEQP_GLES31_LIBRARIES   = ${DEQP_GLES31_LIBRARIES}")
 117 message(STATUS "DEQP_GLES32_LIBRARIES   = ${DEQP_GLES32_LIBRARIES}")
 118 message(STATUS "DEQP_SUPPORT_VG         = ${DEQP_SUPPORT_VG}")
 119 message(STATUS "DEQP_VG_LIBRARIES       = ${DEQP_VG_LIBRARIES}")
 120 message(STATUS "DEQP_EGL_LIBRARIES      = ${DEQP_EGL_LIBRARIES}")
 121 message(STATUS "DEQP_PLATFORM_LIBRARIES = ${DEQP_PLATFORM_LIBRARIES}")
 122
 123 # Defines
 124 add_definitions(-DDEQP_TARGET_NAME="${DEQP_TARGET_NAME}")
 125
 126 # Entry points loaded directly by linking to libGL*?
 127 if (DEFINED DEQP_GLES2_LIBRARIES)
 128         add_definitions(-DDEQP_GLES2_DIRECT_LINK=1)
 129 endif ()
 130
 131 if (DEFINED DEQP_GLES3_LIBRARIES)
 132         add_definitions(-DDEQP_GLES3_DIRECT_LINK=1)
 133 endif ()
 134
 135 if (DEFINED DEQP_GLES31_LIBRARIES)
 136         add_definitions(-DDEQP_GLES31_DIRECT_LINK=1)
 137 endif ()
 138
 139 if (DEFINED DEQP_GLES32_LIBRARIES)
 140         add_definitions(-DDEQP_GLES32_DIRECT_LINK=1)
 141 endif ()
 142
 143 if (DEFINED DEQP_EGL_LIBRARIES)
 144         add_definitions(-DDEQP_EGL_DIRECT_LINK=1)
 145 endif ()
 146
 147 # Legacy APIs that don't support run-time loading
 148 if (DEQP_SUPPORT_GLES1)
 149         add_definitions(-DDEQP_SUPPORT_GLES1=1)
 150
 151         if (NOT DEFINED DEQP_GLES1_LIBRARIES)
 152                 message(FATAL_ERROR "Run-time loading of GLES1 is not supported (DEQP_GLES1_LIBRARIES is not set)")
 153         endif ()
 154 endif ()
 155
 156 if (DEQP_SUPPORT_VG)
 157         add_definitions(-DDEQP_SUPPORT_VG=1)
 158
 159         if (NOT DEFINED DEQP_VG_LIBRARIES)
 160                 message(FATAL_ERROR "Run-time loading of VG is not supported (DEQP_VG_LIBRARIES is not set)")
 161         endif ()
 162 endif ()
 163
 164 if (DE_COMPILER_IS_MSC)
 165         # Don't nag about std::copy for example
 166         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -D_SCL_SECURE_NO_WARNINGS")
 167 endif ()
 168
 169 # Precompiled header macro. Parameters are source file list and filename for pch cpp file.
 170 macro(PCH SRCS PCHCPP)
 171   if(MSVC AND CMAKE_GENERATOR MATCHES "^Visual Studio")
 172     set(PCH_NAME "$(IntDir)\\pch.pch")
 173     # make source files use/depend on PCH_NAME
 174     set_source_files_properties(${${SRCS}} PROPERTIES COMPILE_FLAGS "/Yupch.h /FIpch.h /Fp${PCH_NAME}" OBJECT_DEPENDS "${PCH_NAME}")
 175     # make PCHCPP file compile and generate PCH_NAME
 176     set_source_files_properties(${PCHCPP} PROPERTIES COMPILE_FLAGS "/Ycpch.h /Fp${PCH_NAME}" OBJECT_OUTPUTS "${PCH_NAME}")
 177     list(APPEND ${SRCS} "${PCHCPP}")
 178   endif()
 179 endmacro(PCH)
 180
 181 # delibs projects
 182 add_subdirectory(framework/delibs/debase)
 183 add_subdirectory(framework/delibs/depool)
 184 add_subdirectory(framework/delibs/dethread)
 185 add_subdirectory(framework/delibs/destream)
 186 add_subdirectory(framework/delibs/deutil)
 187 add_subdirectory(framework/delibs/decpp)
 188
 189 # ExecServer
 190 add_subdirectory(execserver)
 191
 192 # Executor framework and tools
 193 if (IS_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/executor)
 194         add_subdirectory(executor)
 195 endif ()
 196
 197 # Test framework include directories
 198 include_directories(
 199         framework/common
 200         framework/qphelper
 201         framework/opengl
 202         framework/opengl/wrapper
 203         framework/referencerenderer
 204         framework/opengl/simplereference
 205         framework/randomshaders
 206         framework/egl
 207         framework/egl/wrapper
 208         external/vulkancts/framework/vulkan
 209         )
 210
 211 if (DE_OS_IS_ANDROID OR DE_OS_IS_IOS)
 212         # On Android deqp modules are compiled as libraries and linked into final .so
 213         set(DEQP_MODULE_LIBRARIES )
 214         set(DEQP_MODULE_ENTRY_POINTS )
 215 endif ()
 216
 217 # Macro for adding targets for copying binaries (usually target libraries) to the target destination dir
 218 macro (target_copy_files target dep_name files)
 219         if (NOT "${files}" STREQUAL "")
 220                 set(COPY_TARGETS )
 221                 foreach (SRCNAME ${files})
 222                         get_filename_component(BASENAME ${SRCNAME} NAME)
 223                         set(DSTNAME "${CMAKE_CURRENT_BINARY_DIR}/${BASENAME}")
 224                         add_custom_command(OUTPUT ${DSTNAME}
 225                                                            COMMAND ${CMAKE_COMMAND} -E copy_if_different ${SRCNAME} ${DSTNAME})
 226                         set(COPY_TARGETS ${COPY_TARGETS} ${DSTNAME})
 227                 endforeach ()
 228
 229                 add_custom_target(${dep_name} ALL DEPENDS ${COPY_TARGETS})
 230                 add_dependencies(${target} ${dep_name})
 231         endif ()
 232 endmacro (target_copy_files)
 233
 234 set(MODULE_LIB_TARGET_POSTFIX   "-package")
 235 set(MODULE_DATA_TARGET_POSTFIX  "-data")
 236
 237 # Macro for adding dEQP module
 238 # This adds 3 targets:
 239 #       ${MODULE_NAME}-package:         Static library that contains all SRCS and links to LIBS
 240 #       ${MODULE_NAME}-data:            Custom target that is used for data file copies
 241 #       ${MODULE_NAME}:                         Executable binary (if supported by the platform)
 242 macro (add_deqp_module MODULE_NAME SRCS LIBS ENTRY)
 243
 244         # Library target
 245         add_library("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" STATIC ${SRCS})
 246         target_link_libraries("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" ${LIBS})
 247
 248         set(DEQP_MODULE_LIBRARIES               ${DEQP_MODULE_LIBRARIES} "${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}")
 249         set(DEQP_MODULE_ENTRY_POINTS    ${DEQP_MODULE_ENTRY_POINTS} "${CMAKE_CURRENT_SOURCE_DIR}/${ENTRY}")
 250
 251         # Forward to parent scope
 252         set(DEQP_MODULE_LIBRARIES               ${DEQP_MODULE_LIBRARIES} PARENT_SCOPE)
 253         set(DEQP_MODULE_ENTRY_POINTS    ${DEQP_MODULE_ENTRY_POINTS} PARENT_SCOPE)
 254
 255         if (NOT DE_OS_IS_ANDROID AND NOT DE_OS_IS_IOS)
 256                 # Executable target
 257                 add_executable(${MODULE_NAME} ${PROJECT_SOURCE_DIR}/framework/platform/tcuMain.cpp ${ENTRY})
 258                 target_link_libraries(${MODULE_NAME} tcutil-platform "${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}")
 259                 target_copy_files(${MODULE_NAME} platform-libs-${MODULE_NAME} "${DEQP_PLATFORM_COPY_LIBRARIES}")
 260         endif ()
 261
 262         # Data file target
 263         add_custom_target("${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}")
 264         add_dependencies("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}")
 265 endmacro (add_deqp_module)
 266
 267 # Macro for adding data dirs to module
 268 macro (add_data_dir MODULE_NAME SRC_DIR DST_DIR)
 269         if (DE_OS_IS_WIN32 OR DE_OS_IS_UNIX OR DE_OS_IS_OSX OR DE_OS_IS_QNX)
 270                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_CURRENT_BINARY_DIR}/${DST_DIR})
 271
 272         elseif (DE_OS_IS_ANDROID)
 273                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_BINARY_DIR}/assets/${DST_DIR})
 274
 275         elseif (DE_OS_IS_IOS)
 276                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_BINARY_DIR}/\${CONFIGURATION}\${EFFECTIVE_PLATFORM_NAME}/deqp.app/${DST_DIR})
 277         endif ()
 278 endmacro (add_data_dir)
 279
 280 # Macro for adding individual data files to module
 281 macro (add_data_file MODULE_NAME SRC_FILE DST_FILE)
 282         if (DE_OS_IS_WIN32 OR DE_OS_IS_UNIX OR DE_OS_IS_OSX OR DE_OS_IS_QNX)
 283                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_CURRENT_BINARY_DIR}/${DST_FILE})
 284
 285         elseif (DE_OS_IS_ANDROID)
 286                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_BINARY_DIR}/assets/${DST_FILE})
 287
 288         elseif (DE_OS_IS_IOS)
 289                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_BINARY_DIR}/\${CONFIGURATION}\${EFFECTIVE_PLATFORM_NAME}/deqp.app/${DST_FILE})
 290         endif ()
 291 endmacro (add_data_file)
 292
 293 add_subdirectory(framework)
 294 add_subdirectory(external/vulkancts/framework/vulkan)
 295
 296 if (DE_COMPILER_IS_MSC)
 297         add_compile_options(/bigobj) # Required by glsBuiltinPrecisionTests.cpp
 298 endif ()
 299
 300 add_subdirectory(modules)
 301 add_subdirectory(external/vulkancts/modules/vulkan)
 302 add_subdirectory(external/openglcts)
 303
 304 # Single-binary targets
 305 if (DE_OS_IS_ANDROID)
 306         include_directories(executor)
 307
 308         set(DEQP_SRCS
 309                 framework/platform/android/tcuAndroidMain.cpp
 310                 framework/platform/android/tcuAndroidJNI.cpp
 311                 framework/platform/android/tcuAndroidPlatformCapabilityQueryJNI.cpp
 312                 framework/platform/android/tcuTestLogParserJNI.cpp
 313                 ${DEQP_MODULE_ENTRY_POINTS}
 314                 )
 315
 316         set(DEQP_LIBS
 317                 tcutil-platform
 318                 xecore
 319                 ${DEQP_MODULE_LIBRARIES}
 320                 )
 321
 322         add_library(deqp SHARED ${DEQP_SRCS})
 323         target_link_libraries(deqp ${DEQP_LIBS})
 324
 325         # Separate out the debug information because it's enormous
 326         add_custom_command(TARGET deqp POST_BUILD
 327                 COMMAND ${CMAKE_STRIP} --only-keep-debug -o $<TARGET_FILE:deqp>.debug $<TARGET_FILE:deqp>
 328                 COMMAND ${CMAKE_STRIP} -g $<TARGET_FILE:deqp>)
 329
 330         # Needed by OpenGL CTS that defines its own activity but depends on
 331         # common Android support code.
 332         target_include_directories(deqp PRIVATE framework/platform/android)
 333
 334 elseif (DE_OS_IS_IOS)
 335         # Code sign identity
 336         set(DEQP_IOS_CODE_SIGN_IDENTITY "drawElements" CACHE STRING "Code sign identity for iOS build")
 337
 338         set(MACOSX_BUNDLE_PRODUCT_NAME "\${PRODUCT_NAME}")
 339         set(MACOSX_BUNDLE_GUI_IDENTIFIER "com.drawelements.\${PRODUCT_NAME:identifier}")
 340
 341         include_directories(framework/platform/ios)
 342         set(TESTERCORE_SRC_FILES
 343                 framework/platform/ios/tcuEAGLView.h
 344                 framework/platform/ios/tcuEAGLView.m
 345                 framework/platform/ios/tcuIOSAppDelegate.h
 346                 framework/platform/ios/tcuIOSAppDelegate.m
 347                 framework/platform/ios/tcuIOSViewController.h
 348                 framework/platform/ios/tcuIOSViewController.m
 349                 framework/platform/ios/tcuIOSMain.m
 350                 )
 351         set_source_files_properties(${TESTERCORE_SRC_FILES} COMPILE_FLAGS "-std=c99")
 352
 353         add_executable(deqp MACOSX_BUNDLE ${TESTERCORE_SRC_FILES} ${DEQP_MODULE_ENTRY_POINTS})
 354         target_link_libraries(deqp tcutil-platform xscore ${DEQP_MODULE_LIBRARIES})
 355         set_target_properties(deqp PROPERTIES XCODE_ATTRIBUTE_TARGETED_DEVICE_FAMILY "1,2")
 356         set_target_properties(deqp PROPERTIES XCODE_ATTRIBUTE_CODE_SIGN_IDENTITY "iPhone Developer: ${DEQP_IOS_CODE_SIGN_IDENTITY}")
 357 endif ()