CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.12)
   2 # When using CMake 3.4 and later, don't export symbols from executables unless
   3 # the CMAKE_ENABLE_EXPORTS variable is set.
   4 if(POLICY CMP0065)
   5   cmake_policy(SET CMP0065 NEW)
   6 endif()
   7
   8 if(CMAKE_EXECUTABLE_SUFFIX)
   9   set(CMAKE_EXECUTABLE_SUFFIX_TMP ${CMAKE_EXECUTABLE_SUFFIX})
  10 endif()
  11
  12 project(libjpeg-turbo C)
  13 set(VERSION 3.0.1)
  14 set(COPYRIGHT_YEAR "1991-2023")
  15 string(REPLACE "." ";" VERSION_TRIPLET ${VERSION})
  16 list(GET VERSION_TRIPLET 0 VERSION_MAJOR)
  17 list(GET VERSION_TRIPLET 1 VERSION_MINOR)
  18 list(GET VERSION_TRIPLET 2 VERSION_REVISION)
  19 function(pad_number NUMBER OUTPUT_LEN)
  20   string(LENGTH "${${NUMBER}}" INPUT_LEN)
  21   if(INPUT_LEN LESS OUTPUT_LEN)
  22     math(EXPR ZEROES "${OUTPUT_LEN} - ${INPUT_LEN} - 1")
  23     set(NUM ${${NUMBER}})
  24     foreach(C RANGE ${ZEROES})
  25       set(NUM "0${NUM}")
  26     endforeach()
  27     set(${NUMBER} ${NUM} PARENT_SCOPE)
  28   endif()
  29 endfunction()
  30 pad_number(VERSION_MINOR 3)
  31 pad_number(VERSION_REVISION 3)
  32 set(LIBJPEG_TURBO_VERSION_NUMBER ${VERSION_MAJOR}${VERSION_MINOR}${VERSION_REVISION})
  33
  34 # The libjpeg-turbo build system has never supported and will never support
  35 # being integrated into another build system using add_subdirectory(), because
  36 # doing so would require that we (minimally):
  37 #
  38 # 1. avoid using certain CMake variables, such as CMAKE_SOURCE_DIR,
  39 #    CMAKE_BINARY_DIR, and CMAKE_PROJECT_NAME;
  40 # 2. avoid using implicit include directories and relative paths;
  41 # 3. optionally provide a way to skip the installation of libjpeg-turbo
  42 #    components when the 'install' target is built;
  43 # 4. optionally provide a way to postfix target names, to avoid namespace
  44 #    conflicts;
  45 # 5. restructure the top-level CMakeLists.txt so that it properly sets the
  46 #    PROJECT_VERSION variable; and
  47 # 6. design automated regression tests to ensure that new commits don't break
  48 #    any of the above.
  49 #
  50 # Even if we did all of that, issues would still arise, because it is
  51 # impossible for an upstream build system to anticipate the widely varying
  52 # needs of every downstream build system.  That's why the CMake
  53 # ExternalProject_Add() function exists.  Downstream projects that wish to
  54 # integrate libjpeg-turbo as a subdirectory should either use
  55 # ExternalProject_Add() or make downstream modifications to the libjpeg-turbo
  56 # build system to suit their specific needs.  Please do not file bug reports,
  57 # feature requests, or pull requests regarding this.
  58 if(NOT CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
  59   message(FATAL_ERROR "The libjpeg-turbo build system cannot be integrated into another build system using add_subdirectory().  Use ExternalProject_Add() instead.")
  60 endif()
  61
  62 # CMake 3.14 and later sets CMAKE_MACOSX_BUNDLE to TRUE by default when
  63 # CMAKE_SYSTEM_NAME is iOS, tvOS, or watchOS, which breaks the libjpeg-turbo
  64 # build.  (Specifically, when CMAKE_MACOSX_BUNDLE is TRUE, executables for
  65 # Apple platforms are built as application bundles, which causes CMake to
  66 # complain that our install() directives for executables do not specify a
  67 # BUNDLE DESTINATION.  Even if CMake did not complain, building executables as
  68 # application bundles would break our iOS packages.)
  69 set(CMAKE_MACOSX_BUNDLE FALSE)
  70
  71 get_property(GENERATOR_IS_MULTI_CONFIG GLOBAL PROPERTY
  72   GENERATOR_IS_MULTI_CONFIG)
  73 # If the GENERATOR_IS_MULTI_CONFIG property doesn't exist (CMake < 3.9), then
  74 # set the GENERATOR_IS_MULTI_CONFIG variable manually if the generator is
  75 # Visual Studio or Xcode (the only multi-config generators in CMake < 3.9).
  76 if(NOT GENERATOR_IS_MULTI_CONFIG AND (MSVC_IDE OR XCODE))
  77   set(GENERATOR_IS_MULTI_CONFIG TRUE)
  78 endif()
  79
  80 string(TIMESTAMP DEFAULT_BUILD "%Y%m%d")
  81 set(BUILD ${DEFAULT_BUILD} CACHE STRING "Build string (default: ${DEFAULT_BUILD})")
  82
  83 # NOTE: On Windows, this does nothing except when using MinGW or Cygwin.
  84 # CMAKE_BUILD_TYPE has no meaning in Visual Studio, and it always defaults to
  85 # Debug when using NMake.
  86 if(NOT CMAKE_BUILD_TYPE)
  87   set(CMAKE_BUILD_TYPE Release)
  88 endif()
  89 message(STATUS "CMAKE_BUILD_TYPE = ${CMAKE_BUILD_TYPE}")
  90
  91 message(STATUS "VERSION = ${VERSION}, BUILD = ${BUILD}")
  92
  93 include(cmakescripts/PackageInfo.cmake)
  94
  95 # Detect CPU type and whether we're building 64-bit or 32-bit code
  96 math(EXPR BITS "${CMAKE_SIZEOF_VOID_P} * 8")
  97 string(TOLOWER ${CMAKE_SYSTEM_PROCESSOR} CMAKE_SYSTEM_PROCESSOR_LC)
  98 set(COUNT 1)
  99 foreach(ARCH ${CMAKE_OSX_ARCHITECTURES})
 100   if(COUNT GREATER 1)
 101     message(FATAL_ERROR "libjpeg-turbo contains assembly code, so it cannot be built with multiple values in CMAKE_OSX_ARCHITECTURES.")
 102   endif()
 103   math(EXPR COUNT "${COUNT}+1")
 104 endforeach()
 105 if(CMAKE_SYSTEM_PROCESSOR_LC MATCHES "x86_64" OR
 106   CMAKE_SYSTEM_PROCESSOR_LC MATCHES "amd64" OR
 107   CMAKE_SYSTEM_PROCESSOR_LC MATCHES "i[0-9]86" OR
 108   CMAKE_SYSTEM_PROCESSOR_LC MATCHES "x86" OR
 109   CMAKE_SYSTEM_PROCESSOR_LC MATCHES "ia32")
 110   if(BITS EQUAL 64 OR CMAKE_C_COMPILER_ABI MATCHES "ELF X32")
 111     set(CPU_TYPE x86_64)
 112   else()
 113     set(CPU_TYPE i386)
 114   endif()
 115   if(NOT CMAKE_SYSTEM_PROCESSOR STREQUAL ${CPU_TYPE})
 116     set(CMAKE_SYSTEM_PROCESSOR ${CPU_TYPE})
 117   endif()
 118 elseif(CMAKE_SYSTEM_PROCESSOR_LC STREQUAL "aarch64" OR
 119   CMAKE_SYSTEM_PROCESSOR_LC MATCHES "^arm")
 120   if(BITS EQUAL 64)
 121     set(CPU_TYPE arm64)
 122   else()
 123     set(CPU_TYPE arm)
 124   endif()
 125 elseif(CMAKE_SYSTEM_PROCESSOR_LC MATCHES "^ppc" OR
 126   CMAKE_SYSTEM_PROCESSOR_LC MATCHES "^powerpc")
 127   set(CPU_TYPE powerpc)
 128 else()
 129   set(CPU_TYPE ${CMAKE_SYSTEM_PROCESSOR_LC})
 130 endif()
 131 if(CMAKE_OSX_ARCHITECTURES MATCHES "x86_64" OR
 132   CMAKE_OSX_ARCHITECTURES MATCHES "arm64" OR
 133   CMAKE_OSX_ARCHITECTURES MATCHES "i386")
 134   set(CPU_TYPE ${CMAKE_OSX_ARCHITECTURES})
 135 endif()
 136 if(CMAKE_OSX_ARCHITECTURES MATCHES "ppc")
 137   set(CPU_TYPE powerpc)
 138 endif()
 139 if(MSVC_IDE AND CMAKE_GENERATOR_PLATFORM MATCHES "arm64")
 140   set(CPU_TYPE arm64)
 141 endif()
 142
 143 message(STATUS "${BITS}-bit build (${CPU_TYPE})")
 144
 145
 146 ###############################################################################
 147 # INSTALL DIRECTORIES
 148 ###############################################################################
 149
 150 if(WIN32)
 151   if(MSVC)
 152     set(CMAKE_INSTALL_DEFAULT_PREFIX "c:/${CMAKE_PROJECT_NAME}")
 153   else()
 154     set(CMAKE_INSTALL_DEFAULT_PREFIX "c:/${CMAKE_PROJECT_NAME}-gcc")
 155   endif()
 156   if(BITS EQUAL 64)
 157     set(CMAKE_INSTALL_DEFAULT_PREFIX "${CMAKE_INSTALL_DEFAULT_PREFIX}64")
 158   endif()
 159 else()
 160   if(NOT CMAKE_INSTALL_DEFAULT_PREFIX)
 161     set(CMAKE_INSTALL_DEFAULT_PREFIX /opt/${CMAKE_PROJECT_NAME})
 162   endif()
 163 endif()
 164 if(CMAKE_INSTALL_PREFIX_INITIALIZED_TO_DEFAULT)
 165   set(CMAKE_INSTALL_PREFIX "${CMAKE_INSTALL_DEFAULT_PREFIX}" CACHE PATH
 166     "Directory into which to install ${CMAKE_PROJECT_NAME} (default: ${CMAKE_INSTALL_DEFAULT_PREFIX})"
 167     FORCE)
 168 endif()
 169 message(STATUS "CMAKE_INSTALL_PREFIX = ${CMAKE_INSTALL_PREFIX}")
 170
 171 # When the prefix is /opt/${CMAKE_PROJECT_NAME}, we assume that an "official"
 172 # build is being created, and thus we install things into specific locations.
 173
 174 if(CMAKE_INSTALL_PREFIX STREQUAL "${CMAKE_INSTALL_DEFAULT_PREFIX}")
 175   set(CMAKE_INSTALL_DEFAULT_DATAROOTDIR "")
 176   set(CMAKE_INSTALL_DEFAULT_DOCDIR "<CMAKE_INSTALL_DATAROOTDIR>/doc")
 177   set(CMAKE_INSTALL_DEFAULT_JAVADIR "<CMAKE_INSTALL_DATAROOTDIR>/classes")
 178   if(UNIX AND NOT APPLE)
 179     if(BITS EQUAL 64)
 180       set(CMAKE_INSTALL_DEFAULT_LIBDIR "lib64")
 181     elseif(CMAKE_C_COMPILER_ABI MATCHES "ELF X32")
 182       set(CMAKE_INSTALL_DEFAULT_LIBDIR "libx32")
 183     else()
 184       set(CMAKE_INSTALL_DEFAULT_LIBDIR "lib32")
 185     endif()
 186   endif()
 187 endif()
 188
 189 include(cmakescripts/GNUInstallDirs.cmake)
 190
 191 macro(report_directory var)
 192   if(CMAKE_INSTALL_${var} STREQUAL CMAKE_INSTALL_FULL_${var})
 193     message(STATUS "CMAKE_INSTALL_${var} = ${CMAKE_INSTALL_${var}}")
 194   else()
 195     message(STATUS "CMAKE_INSTALL_${var} = ${CMAKE_INSTALL_${var}} (${CMAKE_INSTALL_FULL_${var}})")
 196   endif()
 197   mark_as_advanced(CLEAR CMAKE_INSTALL_${var})
 198 endmacro()
 199
 200 set(DIRLIST "BINDIR;DATAROOTDIR;DOCDIR;INCLUDEDIR;LIBDIR")
 201 if(UNIX)
 202   list(APPEND DIRLIST "MANDIR")
 203 endif()
 204 foreach(dir ${DIRLIST})
 205   report_directory(${dir})
 206 endforeach()
 207
 208
 209 ###############################################################################
 210 # CONFIGURATION OPTIONS
 211 ###############################################################################
 212
 213 macro(boolean_number var)
 214   if(${var})
 215     set(${var} 1 ${ARGN})
 216   else()
 217     set(${var} 0 ${ARGN})
 218   endif()
 219 endmacro()
 220
 221 option(ENABLE_SHARED "Build shared libraries" TRUE)
 222 boolean_number(ENABLE_SHARED)
 223 option(ENABLE_STATIC "Build static libraries" TRUE)
 224 boolean_number(ENABLE_STATIC)
 225 option(REQUIRE_SIMD "Generate a fatal error if SIMD extensions are not available for this platform (default is to fall back to a non-SIMD build)" FALSE)
 226 boolean_number(REQUIRE_SIMD)
 227 option(WITH_ARITH_DEC "Include arithmetic decoding support when emulating the libjpeg v6b API/ABI" TRUE)
 228 boolean_number(WITH_ARITH_DEC)
 229 option(WITH_ARITH_ENC "Include arithmetic encoding support when emulating the libjpeg v6b API/ABI" TRUE)
 230 boolean_number(WITH_ARITH_ENC)
 231 if(CMAKE_C_COMPILER_ABI MATCHES "ELF X32")
 232   set(WITH_JAVA 0)
 233 else()
 234   option(WITH_JAVA "Build Java wrapper for the TurboJPEG API library (implies ENABLE_SHARED=1)" FALSE)
 235   boolean_number(WITH_JAVA)
 236 endif()
 237 option(WITH_JPEG7 "Emulate libjpeg v7 API/ABI (this makes ${CMAKE_PROJECT_NAME} backward-incompatible with libjpeg v6b)" FALSE)
 238 boolean_number(WITH_JPEG7)
 239 option(WITH_JPEG8 "Emulate libjpeg v8 API/ABI (this makes ${CMAKE_PROJECT_NAME} backward-incompatible with libjpeg v6b)" FALSE)
 240 boolean_number(WITH_JPEG8)
 241 option(WITH_SIMD "Include SIMD extensions, if available for this platform" TRUE)
 242 boolean_number(WITH_SIMD)
 243 option(WITH_TURBOJPEG "Include the TurboJPEG API library and associated test programs" TRUE)
 244 boolean_number(WITH_TURBOJPEG)
 245 option(WITH_FUZZ "Build fuzz targets" FALSE)
 246
 247 macro(report_option var desc)
 248   if(${var})
 249     message(STATUS "${desc} enabled (${var} = ${${var}})")
 250   else()
 251     message(STATUS "${desc} disabled (${var} = ${${var}})")
 252   endif()
 253 endmacro()
 254
 255 if(WITH_JAVA)
 256   set(ENABLE_SHARED 1)
 257 endif()
 258
 259 # Explicitly setting CMAKE_POSITION_INDEPENDENT_CODE=FALSE disables PIC for all
 260 # targets, which will cause the shared library builds to fail.  Thus, if shared
 261 # libraries are enabled and CMAKE_POSITION_INDEPENDENT_CODE is explicitly set
 262 # to FALSE, we need to unset it, thus restoring the default behavior
 263 # (automatically using PIC for shared library targets.)
 264 if(DEFINED CMAKE_POSITION_INDEPENDENT_CODE AND
 265   NOT CMAKE_POSITION_INDEPENDENT_CODE AND ENABLE_SHARED)
 266   unset(CMAKE_POSITION_INDEPENDENT_CODE CACHE)
 267 endif()
 268
 269 report_option(ENABLE_SHARED "Shared libraries")
 270 report_option(ENABLE_STATIC "Static libraries")
 271
 272 if(ENABLE_SHARED)
 273   set(CMAKE_INSTALL_RPATH ${CMAKE_INSTALL_FULL_LIBDIR})
 274 endif()
 275
 276 if(WITH_JPEG8 OR WITH_JPEG7)
 277   set(WITH_ARITH_ENC 1)
 278   set(WITH_ARITH_DEC 1)
 279 endif()
 280
 281 if(WITH_ARITH_DEC)
 282   set(D_ARITH_CODING_SUPPORTED 1)
 283 endif()
 284 report_option(WITH_ARITH_DEC "Arithmetic decoding support")
 285
 286 if(WITH_ARITH_ENC)
 287   set(C_ARITH_CODING_SUPPORTED 1)
 288 endif()
 289 report_option(WITH_ARITH_ENC "Arithmetic encoding support")
 290
 291 report_option(WITH_TURBOJPEG "TurboJPEG API library")
 292 report_option(WITH_JAVA "TurboJPEG Java wrapper")
 293
 294 if(NOT WITH_JPEG8)
 295   set(MEM_SRCDST_FUNCTIONS "global:  jpeg_mem_dest;  jpeg_mem_src;")
 296 endif()
 297
 298 # 0: Original libjpeg v6b/v7/v8 API/ABI
 299 #
 300 # libjpeg v6b/v7 API/ABI emulation:
 301 # 1: + In-memory source/destination managers (libjpeg-turbo 1.3.x)
 302 # 2: + Partial image decompression functions (libjpeg-turbo 1.5.x)
 303 # 3: + ICC functions (libjpeg-turbo 2.0.x)
 304 # 4: + 12-bit-per-component and lossless functions (libjpeg-turbo 2.2.x)
 305 #
 306 # libjpeg v8 API/ABI emulation:
 307 # 1: + Partial image decompression functions (libjpeg-turbo 1.5.x)
 308 # 2: + ICC functions (libjpeg-turbo 2.0.x)
 309 # 3: + 12-bit-per-component and lossless functions (libjpeg-turbo 2.2.x)
 310 set(SO_AGE 3)
 311 if(NOT WITH_JPEG8)
 312   set(SO_AGE 4)
 313 endif()
 314
 315 if(WITH_JPEG8)
 316   set(JPEG_LIB_VERSION 80)
 317 elseif(WITH_JPEG7)
 318   set(JPEG_LIB_VERSION 70)
 319 else()
 320   set(JPEG_LIB_VERSION 62)
 321 endif()
 322
 323 math(EXPR JPEG_LIB_VERSION_DIV10 "${JPEG_LIB_VERSION} / 10")
 324 math(EXPR JPEG_LIB_VERSION_MOD10 "${JPEG_LIB_VERSION} % 10")
 325 if(JPEG_LIB_VERSION STREQUAL "62")
 326   set(DEFAULT_SO_MAJOR_VERSION ${JPEG_LIB_VERSION})
 327 else()
 328   set(DEFAULT_SO_MAJOR_VERSION ${JPEG_LIB_VERSION_DIV10})
 329 endif()
 330 if(JPEG_LIB_VERSION STREQUAL "80")
 331   set(DEFAULT_SO_MINOR_VERSION 2)
 332 else()
 333   set(DEFAULT_SO_MINOR_VERSION 0)
 334 endif()
 335
 336 # This causes SO_MAJOR_VERSION/SO_MINOR_VERSION to reset to defaults if
 337 # WITH_JPEG7 or WITH_JPEG8 has changed.
 338 if((DEFINED WITH_JPEG7_INT AND NOT WITH_JPEG7 EQUAL WITH_JPEG7_INT) OR
 339   (DEFINED WITH_JPEG8_INT AND NOT WITH_JPEG8 EQUAL WITH_JPEG8_INT))
 340   set(FORCE_SO_VERSION "FORCE")
 341 endif()
 342 set(WITH_JPEG7_INT ${WITH_JPEG7} CACHE INTERNAL "")
 343 set(WITH_JPEG8_INT ${WITH_JPEG8} CACHE INTERNAL "")
 344
 345 set(SO_MAJOR_VERSION ${DEFAULT_SO_MAJOR_VERSION} CACHE STRING
 346   "Major version of the libjpeg API shared library (default: ${DEFAULT_SO_MAJOR_VERSION})"
 347   ${FORCE_SO_VERSION})
 348 set(SO_MINOR_VERSION ${DEFAULT_SO_MINOR_VERSION} CACHE STRING
 349   "Minor version of the libjpeg API shared library (default: ${DEFAULT_SO_MINOR_VERSION})"
 350   ${FORCE_SO_VERSION})
 351
 352 set(JPEG_LIB_VERSION_DECIMAL "${JPEG_LIB_VERSION_DIV10}.${JPEG_LIB_VERSION_MOD10}")
 353 message(STATUS "Emulating libjpeg API/ABI v${JPEG_LIB_VERSION_DECIMAL} (WITH_JPEG7 = ${WITH_JPEG7}, WITH_JPEG8 = ${WITH_JPEG8})")
 354 message(STATUS "libjpeg API shared library version = ${SO_MAJOR_VERSION}.${SO_AGE}.${SO_MINOR_VERSION}")
 355
 356 # Because the TurboJPEG API library uses versioned symbols and changes the
 357 # names of functions whenever they are modified in a backward-incompatible
 358 # manner, it is always backward-ABI-compatible with itself, so the major and
 359 # minor SO versions don't change.  However, we increase the middle number (the
 360 # SO "age") whenever functions are added to the API, because adding functions
 361 # affects forward API/ABI compatibility.
 362 set(TURBOJPEG_SO_MAJOR_VERSION 0)
 363 # 0: TurboJPEG 1.3.x API
 364 # 1: TurboJPEG 1.4.x API
 365 #    The TurboJPEG 1.5.x API modified some of the function prototypes, adding
 366 #    the const keyword in front of pointers to unmodified buffers, but that did
 367 #    not affect forward API/ABI compatibility.
 368 # 2: TurboJPEG 2.0.x API
 369 #    The TurboJPEG 2.1.x API modified the behavior of the tjDecompressHeader3()
 370 #    function so that it accepts "abbreviated table specification" (AKA
 371 #    "tables-only") datastreams as well as JPEG images, but that did not affect
 372 #    forward API/ABI compatibility.
 373 # 3: TurboJPEG 3 API
 374 set(TURBOJPEG_SO_AGE 3)
 375 set(TURBOJPEG_SO_VERSION 0.${TURBOJPEG_SO_AGE}.0)
 376
 377
 378 ###############################################################################
 379 # COMPILER SETTINGS
 380 ###############################################################################
 381
 382 if(MSVC)
 383   option(WITH_CRT_DLL
 384     "Link all ${CMAKE_PROJECT_NAME} libraries and executables with the C run-time DLL (msvcr*.dll) instead of the static C run-time library (libcmt*.lib.)  The default is to use the C run-time DLL only with the libraries and executables that need it."
 385     FALSE)
 386   if(NOT WITH_CRT_DLL)
 387     # Use the static C library for all build types
 388     foreach(var CMAKE_C_FLAGS CMAKE_C_FLAGS_DEBUG CMAKE_C_FLAGS_RELEASE
 389       CMAKE_C_FLAGS_MINSIZEREL CMAKE_C_FLAGS_RELWITHDEBINFO)
 390       if(${var} MATCHES "/MD")
 391         string(REGEX REPLACE "/MD" "/MT" ${var} "${${var}}")
 392       endif()
 393     endforeach()
 394   endif()
 395   add_definitions(-D_CRT_NONSTDC_NO_WARNINGS)
 396 endif()
 397
 398 if(CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID STREQUAL "Clang")
 399   # Use the maximum optimization level for release builds
 400   foreach(var CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_RELWITHDEBINFO)
 401     if(${var} MATCHES "-O2")
 402       string(REGEX REPLACE "-O2" "-O3" ${var} "${${var}}")
 403     endif()
 404   endforeach()
 405 endif()
 406
 407 if(CMAKE_SYSTEM_NAME STREQUAL "SunOS")
 408   if(CMAKE_C_COMPILER_ID MATCHES "SunPro")
 409     # Use the maximum optimization level for release builds
 410     foreach(var CMAKE_C_FLAGS_RELEASE CMAKE_C_FLAGS_RELWITHDEBINFO)
 411       if(${var} MATCHES "-xO3")
 412         string(REGEX REPLACE "-xO3" "-xO5" ${var} "${${var}}")
 413       endif()
 414       if(${var} MATCHES "-xO2")
 415         string(REGEX REPLACE "-xO2" "-xO5" ${var} "${${var}}")
 416       endif()
 417     endforeach()
 418   endif()
 419 endif()
 420
 421 string(TOUPPER ${CMAKE_BUILD_TYPE} CMAKE_BUILD_TYPE_UC)
 422
 423 set(EFFECTIVE_C_FLAGS "${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 424 message(STATUS "Compiler flags = ${EFFECTIVE_C_FLAGS}")
 425
 426 set(EFFECTIVE_LD_FLAGS "${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_${CMAKE_BUILD_TYPE_UC}}")
 427 message(STATUS "Linker flags = ${EFFECTIVE_LD_FLAGS}")
 428
 429 include(CheckCSourceCompiles)
 430 include(CheckIncludeFiles)
 431 include(CheckTypeSize)
 432
 433 check_type_size("size_t" SIZE_T)
 434 check_type_size("unsigned long" UNSIGNED_LONG)
 435
 436 if(SIZE_T EQUAL UNSIGNED_LONG)
 437   check_c_source_compiles("int main(int argc, char **argv) { unsigned long a = argc;  return __builtin_ctzl(a); }"
 438     HAVE_BUILTIN_CTZL)
 439 endif()
 440 if(MSVC)
 441   check_include_files("intrin.h" HAVE_INTRIN_H)
 442 endif()
 443
 444 if(UNIX)
 445   if(CMAKE_CROSSCOMPILING)
 446     set(RIGHT_SHIFT_IS_UNSIGNED 0)
 447   else()
 448     include(CheckCSourceRuns)
 449     check_c_source_runs("
 450       #include <stdio.h>
 451       #include <stdlib.h>
 452       int is_shifting_signed (long arg) {
 453         long res = arg >> 4;
 454         if (res == -0x7F7E80CL)
 455           return 1; /* right shift is signed */
 456         /* see if unsigned-shift hack will fix it. */
 457         /* we can't just test exact value since it depends on width of long... */
 458         res |= (~0L) << (32-4);
 459         if (res == -0x7F7E80CL)
 460           return 0; /* right shift is unsigned */
 461         printf(\"Right shift isn't acting as I expect it to.\\\\n\");
 462         printf(\"I fear the JPEG software will not work at all.\\\\n\\\\n\");
 463         return 0; /* try it with unsigned anyway */
 464       }
 465       int main (void) {
 466         exit(is_shifting_signed(-0x7F7E80B1L));
 467       }" RIGHT_SHIFT_IS_UNSIGNED)
 468   endif()
 469 endif()
 470
 471 if(MSVC)
 472   set(INLINE_OPTIONS "__inline;inline")
 473 else()
 474   set(INLINE_OPTIONS "__inline__;inline")
 475 endif()
 476 option(FORCE_INLINE "Force function inlining" TRUE)
 477 boolean_number(FORCE_INLINE)
 478 if(FORCE_INLINE)
 479   if(MSVC)
 480     list(INSERT INLINE_OPTIONS 0 "__forceinline")
 481   else()
 482     list(INSERT INLINE_OPTIONS 0 "inline __attribute__((always_inline))")
 483     list(INSERT INLINE_OPTIONS 0 "__inline__ __attribute__((always_inline))")
 484   endif()
 485 endif()
 486 foreach(inline ${INLINE_OPTIONS})
 487   check_c_source_compiles("${inline} static int foo(void) { return 0; } int main(void) { return foo(); }"
 488     INLINE_WORKS)
 489   if(INLINE_WORKS)
 490     set(INLINE ${inline})
 491     break()
 492   endif()
 493 endforeach()
 494 if(NOT INLINE_WORKS)
 495   message(FATAL_ERROR "Could not determine how to inline functions.")
 496 endif()
 497 message(STATUS "INLINE = ${INLINE} (FORCE_INLINE = ${FORCE_INLINE})")
 498
 499 if(MSVC)
 500   set(THREAD_LOCAL "__declspec(thread)")
 501 else()
 502   set(THREAD_LOCAL "__thread")
 503 endif()
 504 check_c_source_compiles("${THREAD_LOCAL} int i;  int main(void) { i = 0;  return i; }" HAVE_THREAD_LOCAL)
 505 if(HAVE_THREAD_LOCAL)
 506   message(STATUS "THREAD_LOCAL = ${THREAD_LOCAL}")
 507 else()
 508   message(WARNING "Thread-local storage is not available.  The TurboJPEG API library's global error handler will not be thread-safe.")
 509   unset(THREAD_LOCAL)
 510 endif()
 511
 512 if(UNIX AND NOT APPLE)
 513   file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/conftest.map "VERS_1 { global: *; };")
 514   set(CMAKE_REQUIRED_FLAGS
 515     "-Wl,--version-script,${CMAKE_CURRENT_BINARY_DIR}/conftest.map")
 516   check_c_source_compiles("int main(void) { return 0; }" HAVE_VERSION_SCRIPT)
 517   set(CMAKE_REQUIRED_FLAGS)
 518   file(REMOVE ${CMAKE_CURRENT_BINARY_DIR}/conftest.map)
 519   if(HAVE_VERSION_SCRIPT)
 520     message(STATUS "Linker supports GNU-style version scripts")
 521     set(MAPFLAG "-Wl,--version-script,")
 522     set(TJMAPFLAG "-Wl,--version-script,")
 523   else()
 524     message(STATUS "Linker does not support GNU-style version scripts")
 525     if(CMAKE_SYSTEM_NAME STREQUAL "SunOS")
 526       # The Solaris linker doesn't like our version script for the libjpeg API
 527       # library, but the version script for the TurboJPEG API library should
 528       # still work.
 529       file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/conftest.map
 530         "VERS_1 { global: foo;  local: *; }; VERS_2 { global: foo2; } VERS_1;")
 531       set(CMAKE_REQUIRED_FLAGS "-Wl,-M,${CMAKE_CURRENT_BINARY_DIR}/conftest.map -shared")
 532       check_c_source_compiles("int foo() { return 0; } int foo2() { return 2; }"
 533         HAVE_MAPFILE)
 534       set(CMAKE_REQUIRED_FLAGS)
 535       file(REMOVE ${CMAKE_CURRENT_BINARY_DIR}/conftest.map)
 536       if(HAVE_MAPFILE)
 537         message(STATUS "Linker supports mapfiles")
 538         set(TJMAPFLAG "-Wl,-M,")
 539       else()
 540         message(STATUS "Linker does not support mapfiles")
 541       endif()
 542     endif()
 543   endif()
 544 endif()
 545
 546 # Generate files
 547 configure_file(jversion.h.in jversion.h)
 548 if(UNIX)
 549   configure_file(libjpeg.map.in libjpeg.map)
 550 endif()
 551
 552 # Include directories and compiler definitions
 553 include_directories(${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_CURRENT_SOURCE_DIR})
 554
 555
 556 ###############################################################################
 557 # TARGETS
 558 ###############################################################################
 559
 560 if(CMAKE_EXECUTABLE_SUFFIX_TMP)
 561   set(CMAKE_EXECUTABLE_SUFFIX ${CMAKE_EXECUTABLE_SUFFIX_TMP})
 562 endif()
 563 message(STATUS "CMAKE_EXECUTABLE_SUFFIX = ${CMAKE_EXECUTABLE_SUFFIX}")
 564
 565 set(JPEG16_SOURCES jcapistd.c jccolor.c jcdiffct.c jclossls.c jcmainct.c
 566   jcprepct.c jcsample.c jdapistd.c jdcolor.c jddiffct.c jdlossls.c jdmainct.c
 567   jdpostct.c jdsample.c jutils.c)
 568 set(JPEG12_SOURCES ${JPEG16_SOURCES} jccoefct.c jcdctmgr.c jdcoefct.c
 569   jddctmgr.c jdmerge.c jfdctfst.c jfdctint.c jidctflt.c jidctfst.c jidctint.c
 570   jidctred.c jquant1.c jquant2.c)
 571 set(JPEG_SOURCES ${JPEG12_SOURCES} jcapimin.c jchuff.c jcicc.c jcinit.c
 572   jclhuff.c jcmarker.c jcmaster.c jcomapi.c jcparam.c jcphuff.c jctrans.c
 573   jdapimin.c jdatadst.c jdatasrc.c jdhuff.c jdicc.c jdinput.c jdlhuff.c
 574   jdmarker.c jdmaster.c jdphuff.c jdtrans.c jerror.c jfdctflt.c jmemmgr.c
 575   jmemnobs.c)
 576
 577 if(WITH_ARITH_ENC OR WITH_ARITH_DEC)
 578   set(JPEG_SOURCES ${JPEG_SOURCES} jaricom.c)
 579 endif()
 580
 581 if(WITH_ARITH_ENC)
 582   set(JPEG_SOURCES ${JPEG_SOURCES} jcarith.c)
 583 endif()
 584
 585 if(WITH_ARITH_DEC)
 586   set(JPEG_SOURCES ${JPEG_SOURCES} jdarith.c)
 587 endif()
 588
 589 if(WITH_SIMD)
 590   add_subdirectory(simd)
 591   if(NEON_INTRINSICS)
 592     add_definitions(-DNEON_INTRINSICS)
 593   endif()
 594 else()
 595   message(STATUS "SIMD extensions: None (WITH_SIMD = ${WITH_SIMD})")
 596 endif()
 597
 598 # We have to generate these here, because if the build system tries and fails
 599 # to enable the SIMD extensions, the value of WITH_SIMD will have changed.
 600 configure_file(jconfig.h.in jconfig.h)
 601 configure_file(jconfigint.h.in jconfigint.h)
 602
 603 if(WITH_SIMD)
 604   message(STATUS "SIMD extensions: ${CPU_TYPE} (WITH_SIMD = ${WITH_SIMD})")
 605   if(MSVC_IDE OR XCODE)
 606     set_source_files_properties(${SIMD_OBJS} PROPERTIES GENERATED 1)
 607   endif()
 608   set(SIMD_TARGET_OBJECTS $<TARGET_OBJECTS:simd>)
 609 endif()
 610
 611 if(WITH_JAVA)
 612   add_subdirectory(java)
 613 endif()
 614
 615 if(ENABLE_SHARED)
 616   # Compile a separate version of these source files with 12-bit and 16-bit
 617   # data precision.
 618   add_library(jpeg12 OBJECT ${JPEG12_SOURCES})
 619   set_property(TARGET jpeg12 PROPERTY COMPILE_FLAGS "-DBITS_IN_JSAMPLE=12")
 620   set_target_properties(jpeg12 PROPERTIES POSITION_INDEPENDENT_CODE 1)
 621   add_library(jpeg16 OBJECT ${JPEG16_SOURCES})
 622   set_property(TARGET jpeg16 PROPERTY COMPILE_FLAGS "-DBITS_IN_JSAMPLE=16")
 623   set_target_properties(jpeg16 PROPERTIES POSITION_INDEPENDENT_CODE 1)
 624   add_subdirectory(sharedlib)
 625 endif()
 626
 627 if(ENABLE_STATIC)
 628   # Compile a separate version of these source files with 12-bit and 16-bit
 629   # data precision.
 630   add_library(jpeg12-static OBJECT ${JPEG12_SOURCES})
 631   set_property(TARGET jpeg12-static PROPERTY COMPILE_FLAGS
 632     "-DBITS_IN_JSAMPLE=12")
 633   add_library(jpeg16-static OBJECT ${JPEG16_SOURCES})
 634   set_property(TARGET jpeg16-static PROPERTY COMPILE_FLAGS
 635     "-DBITS_IN_JSAMPLE=16")
 636   add_library(jpeg-static STATIC ${JPEG_SOURCES} ${SIMD_TARGET_OBJECTS}
 637     ${SIMD_OBJS} $<TARGET_OBJECTS:jpeg12-static>
 638     $<TARGET_OBJECTS:jpeg16-static>)
 639   if(NOT MSVC)
 640     set_target_properties(jpeg-static PROPERTIES OUTPUT_NAME jpeg)
 641   endif()
 642 endif()
 643
 644 if(WITH_TURBOJPEG)
 645   if(ENABLE_SHARED)
 646     set(TURBOJPEG_SOURCES ${JPEG_SOURCES} ${SIMD_TARGET_OBJECTS} ${SIMD_OBJS}
 647       turbojpeg.c transupp.c jdatadst-tj.c jdatasrc-tj.c rdbmp.c rdppm.c
 648       wrbmp.c wrppm.c $<TARGET_OBJECTS:jpeg12> $<TARGET_OBJECTS:jpeg16>)
 649     set(TJMAPFILE ${CMAKE_CURRENT_SOURCE_DIR}/turbojpeg-mapfile)
 650     if(WITH_JAVA)
 651       set(TURBOJPEG_SOURCES ${TURBOJPEG_SOURCES} turbojpeg-jni.c)
 652       include_directories(${JAVA_INCLUDE_PATH} ${JAVA_INCLUDE_PATH2})
 653       set(TJMAPFILE ${CMAKE_CURRENT_SOURCE_DIR}/turbojpeg-mapfile.jni)
 654     endif()
 655     if(MSVC)
 656       configure_file(${CMAKE_SOURCE_DIR}/win/turbojpeg.rc.in
 657         ${CMAKE_BINARY_DIR}/win/turbojpeg.rc)
 658       set(TURBOJPEG_SOURCES ${TURBOJPEG_SOURCES}
 659         ${CMAKE_BINARY_DIR}/win/turbojpeg.rc)
 660     endif()
 661     add_library(turbojpeg12 OBJECT rdppm.c wrppm.c)
 662     set_property(TARGET turbojpeg12 PROPERTY COMPILE_FLAGS
 663       "-DBITS_IN_JSAMPLE=12 -DPPM_SUPPORTED")
 664     set_target_properties(turbojpeg12 PROPERTIES POSITION_INDEPENDENT_CODE 1)
 665     add_library(turbojpeg16 OBJECT rdppm.c wrppm.c)
 666     set_property(TARGET turbojpeg16 PROPERTY COMPILE_FLAGS
 667       "-DBITS_IN_JSAMPLE=16 -DPPM_SUPPORTED")
 668     set_target_properties(turbojpeg16 PROPERTIES POSITION_INDEPENDENT_CODE 1)
 669     add_library(turbojpeg SHARED ${TURBOJPEG_SOURCES}
 670       $<TARGET_OBJECTS:turbojpeg12> $<TARGET_OBJECTS:turbojpeg16>)
 671     set_property(TARGET turbojpeg PROPERTY COMPILE_FLAGS
 672       "-DBMP_SUPPORTED -DPPM_SUPPORTED")
 673     if(WIN32)
 674       set_target_properties(turbojpeg PROPERTIES DEFINE_SYMBOL DLLDEFINE)
 675     endif()
 676     if(MINGW)
 677       set_target_properties(turbojpeg PROPERTIES LINK_FLAGS -Wl,--kill-at)
 678     endif()
 679     if(APPLE AND (NOT CMAKE_OSX_DEPLOYMENT_TARGET OR
 680                   CMAKE_OSX_DEPLOYMENT_TARGET VERSION_GREATER 10.4))
 681       if(NOT CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG)
 682         set(CMAKE_SHARED_LIBRARY_RUNTIME_C_FLAG "-Wl,-rpath,")
 683       endif()
 684       set_target_properties(turbojpeg PROPERTIES MACOSX_RPATH 1)
 685     endif()
 686     set_target_properties(turbojpeg PROPERTIES
 687       SOVERSION ${TURBOJPEG_SO_MAJOR_VERSION} VERSION ${TURBOJPEG_SO_VERSION})
 688     if(TJMAPFLAG)
 689       set_target_properties(turbojpeg PROPERTIES
 690         LINK_FLAGS "${TJMAPFLAG}${TJMAPFILE}")
 691     endif()
 692
 693     add_executable(tjunittest tjunittest.c tjutil.c md5/md5.c md5/md5hl.c)
 694     target_link_libraries(tjunittest turbojpeg)
 695
 696     add_executable(tjbench tjbench.c tjutil.c)
 697     target_link_libraries(tjbench turbojpeg)
 698     if(UNIX)
 699       target_link_libraries(tjbench m)
 700     endif()
 701
 702     add_executable(tjexample tjexample.c)
 703     target_link_libraries(tjexample turbojpeg)
 704   endif()
 705
 706   if(ENABLE_STATIC)
 707     add_library(turbojpeg12-static OBJECT rdppm.c wrppm.c)
 708     set_property(TARGET turbojpeg12-static PROPERTY COMPILE_FLAGS
 709       "-DBITS_IN_JSAMPLE=12 -DPPM_SUPPORTED")
 710     add_library(turbojpeg16-static OBJECT rdppm.c wrppm.c)
 711     set_property(TARGET turbojpeg16-static PROPERTY COMPILE_FLAGS
 712       "-DBITS_IN_JSAMPLE=16 -DPPM_SUPPORTED")
 713     add_library(turbojpeg-static STATIC ${JPEG_SOURCES} ${SIMD_TARGET_OBJECTS}
 714       ${SIMD_OBJS} turbojpeg.c transupp.c jdatadst-tj.c jdatasrc-tj.c rdbmp.c
 715       rdppm.c wrbmp.c wrppm.c $<TARGET_OBJECTS:jpeg12-static>
 716       $<TARGET_OBJECTS:jpeg16-static> $<TARGET_OBJECTS:turbojpeg12-static>
 717       $<TARGET_OBJECTS:turbojpeg16-static>)
 718     set_property(TARGET turbojpeg-static PROPERTY COMPILE_FLAGS
 719       "-DBMP_SUPPORTED -DPPM_SUPPORTED")
 720     if(NOT MSVC)
 721       set_target_properties(turbojpeg-static PROPERTIES OUTPUT_NAME turbojpeg)
 722     endif()
 723
 724     add_executable(tjunittest-static tjunittest.c tjutil.c md5/md5.c
 725       md5/md5hl.c)
 726     target_link_libraries(tjunittest-static turbojpeg-static)
 727
 728     add_executable(tjbench-static tjbench.c tjutil.c)
 729     target_link_libraries(tjbench-static turbojpeg-static)
 730     if(UNIX)
 731       target_link_libraries(tjbench-static m)
 732     endif()
 733   endif()
 734 endif()
 735
 736 if(WIN32)
 737   set(USE_SETMODE "-DUSE_SETMODE")
 738 endif()
 739 set(CDJPEG_COMPILE_FLAGS
 740   "-DBMP_SUPPORTED -DGIF_SUPPORTED -DPPM_SUPPORTED -DTARGA_SUPPORTED ${USE_SETMODE}")
 741
 742 if(ENABLE_STATIC)
 743   # Compile a separate version of these source files with 12-bit and 16-bit
 744   # data precision.
 745   add_library(cjpeg12-static OBJECT rdgif.c rdppm.c)
 746   set_property(TARGET cjpeg12-static PROPERTY COMPILE_FLAGS
 747     "-DBITS_IN_JSAMPLE=12 -DGIF_SUPPORTED -DPPM_SUPPORTED")
 748   add_library(cjpeg16-static OBJECT rdgif.c rdppm.c)
 749   set_property(TARGET cjpeg16-static PROPERTY COMPILE_FLAGS
 750     "-DBITS_IN_JSAMPLE=16 -DGIF_SUPPORTED -DPPM_SUPPORTED")
 751   add_executable(cjpeg-static cjpeg.c cdjpeg.c rdbmp.c rdgif.c rdppm.c
 752     rdswitch.c rdtarga.c $<TARGET_OBJECTS:cjpeg12-static>
 753     $<TARGET_OBJECTS:cjpeg16-static>)
 754   set_property(TARGET cjpeg-static PROPERTY COMPILE_FLAGS
 755     ${CDJPEG_COMPILE_FLAGS})
 756   target_link_libraries(cjpeg-static jpeg-static)
 757
 758   # Compile a separate version of these source files with 12-bit and 16-bit
 759   # data precision.
 760   add_library(djpeg12-static OBJECT rdcolmap.c wrgif.c wrppm.c)
 761   set_property(TARGET djpeg12-static PROPERTY COMPILE_FLAGS
 762     "-DBITS_IN_JSAMPLE=12 -DGIF_SUPPORTED -DPPM_SUPPORTED")
 763   add_library(djpeg16-static OBJECT wrppm.c)
 764   set_property(TARGET djpeg16-static PROPERTY COMPILE_FLAGS
 765     "-DBITS_IN_JSAMPLE=16 -DPPM_SUPPORTED")
 766   add_executable(djpeg-static djpeg.c cdjpeg.c rdcolmap.c rdswitch.c wrbmp.c
 767     wrgif.c wrppm.c wrtarga.c $<TARGET_OBJECTS:djpeg12-static>
 768     $<TARGET_OBJECTS:djpeg16-static>)
 769   set_property(TARGET djpeg-static PROPERTY COMPILE_FLAGS
 770     ${CDJPEG_COMPILE_FLAGS})
 771   target_link_libraries(djpeg-static jpeg-static)
 772
 773   add_executable(jpegtran-static jpegtran.c cdjpeg.c rdswitch.c transupp.c)
 774   target_link_libraries(jpegtran-static jpeg-static)
 775   set_property(TARGET jpegtran-static PROPERTY COMPILE_FLAGS "${USE_SETMODE}")
 776
 777   add_executable(example-static example.c)
 778   target_link_libraries(example-static jpeg-static)
 779 endif()
 780
 781 add_executable(rdjpgcom rdjpgcom.c)
 782
 783 add_executable(wrjpgcom wrjpgcom.c)
 784
 785
 786 ###############################################################################
 787 # TESTS
 788 ###############################################################################
 789
 790 if(WITH_FUZZ)
 791   add_subdirectory(fuzz)
 792 endif()
 793
 794 add_executable(strtest strtest.c)
 795
 796 add_subdirectory(md5)
 797
 798 if(GENERATOR_IS_MULTI_CONFIG)
 799   set(OBJDIR "\${CTEST_CONFIGURATION_TYPE}/")
 800 else()
 801   set(OBJDIR "")
 802 endif()
 803
 804 enable_testing()
 805
 806 if(WITH_JAVA)
 807   add_test(TJUnitTest
 808     ${Java_JAVA_EXECUTABLE} ${JAVAARGS} -cp java/turbojpeg.jar
 809       -Djava.library.path=${CMAKE_CURRENT_BINARY_DIR}/${OBJDIR}
 810       TJUnitTest)
 811   add_test(TJUnitTest-yuv
 812     ${Java_JAVA_EXECUTABLE} ${JAVAARGS} -cp java/turbojpeg.jar
 813       -Djava.library.path=${CMAKE_CURRENT_BINARY_DIR}/${OBJDIR}
 814       TJUnitTest -yuv)
 815   add_test(TJUnitTest-yuv-nopad
 816     ${Java_JAVA_EXECUTABLE} ${JAVAARGS} -cp java/turbojpeg.jar
 817       -Djava.library.path=${CMAKE_CURRENT_BINARY_DIR}/${OBJDIR}
 818       TJUnitTest -yuv -noyuvpad)
 819   add_test(TJUnitTest-lossless
 820     ${Java_JAVA_EXECUTABLE} ${JAVAARGS} -cp java/turbojpeg.jar
 821       -Djava.library.path=${CMAKE_CURRENT_BINARY_DIR}/${OBJDIR}
 822       TJUnitTest -lossless)
 823   add_test(TJUnitTest-bi
 824     ${Java_JAVA_EXECUTABLE} ${JAVAARGS} -cp java/turbojpeg.jar
 825       -Djava.library.path=${CMAKE_CURRENT_BINARY_DIR}/${OBJDIR}
 826       TJUnitTest -bi)
 827   add_test(TJUnitTest-bi-yuv
 828     ${Java_JAVA_EXECUTABLE} ${JAVAARGS} -cp java/turbojpeg.jar
 829       -Djava.library.path=${CMAKE_CURRENT_BINARY_DIR}/${OBJDIR}
 830       TJUnitTest -bi -yuv)
 831   add_test(TJUnitTest-bi-yuv-nopad
 832     ${Java_JAVA_EXECUTABLE} ${JAVAARGS} -cp java/turbojpeg.jar
 833       -Djava.library.path=${CMAKE_CURRENT_BINARY_DIR}/${OBJDIR}
 834       TJUnitTest -bi -yuv -noyuvpad)
 835   add_test(TJUnitTest-bi-lossless
 836     ${Java_JAVA_EXECUTABLE} ${JAVAARGS} -cp java/turbojpeg.jar
 837       -Djava.library.path=${CMAKE_CURRENT_BINARY_DIR}/${OBJDIR}
 838       TJUnitTest -bi -lossless)
 839   add_test(TJUnitTest12
 840     ${Java_JAVA_EXECUTABLE} ${JAVAARGS} -cp java/turbojpeg.jar
 841       -Djava.library.path=${CMAKE_CURRENT_BINARY_DIR}/${OBJDIR}
 842       TJUnitTest -precision 12)
 843   add_test(TJUnitTest12-lossless
 844     ${Java_JAVA_EXECUTABLE} ${JAVAARGS} -cp java/turbojpeg.jar
 845       -Djava.library.path=${CMAKE_CURRENT_BINARY_DIR}/${OBJDIR}
 846       TJUnitTest -precision 12 -lossless)
 847   add_test(TJUnitTest16-lossless
 848     ${Java_JAVA_EXECUTABLE} ${JAVAARGS} -cp java/turbojpeg.jar
 849       -Djava.library.path=${CMAKE_CURRENT_BINARY_DIR}/${OBJDIR}
 850       TJUnitTest -precision 16)
 851 endif()
 852
 853 set(TEST_LIBTYPES "")
 854 if(ENABLE_SHARED)
 855   set(TEST_LIBTYPES ${TEST_LIBTYPES} shared)
 856 endif()
 857 if(ENABLE_STATIC)
 858   set(TEST_LIBTYPES ${TEST_LIBTYPES} static)
 859 endif()
 860
 861 set(TESTIMAGES ${CMAKE_CURRENT_SOURCE_DIR}/testimages)
 862 set(MD5CMP ${CMAKE_CURRENT_BINARY_DIR}/md5/md5cmp)
 863 if(CMAKE_CROSSCOMPILING)
 864   file(RELATIVE_PATH TESTIMAGES ${CMAKE_CURRENT_BINARY_DIR} ${TESTIMAGES})
 865   file(RELATIVE_PATH MD5CMP ${CMAKE_CURRENT_BINARY_DIR} ${MD5CMP})
 866 endif()
 867
 868 # The output of the floating point DCT/IDCT algorithms differs depending on the
 869 # type of floating point math used, so the FLOATTEST8 and FLOATTEST12 CMake
 870 # variables must be set in order to tell the testing system which floating
 871 # point results it should expect:
 872 #
 873 # sse = validate against the expected results from the libjpeg-turbo SSE SIMD
 874 #       extensions
 875 # no-fp-contract = validate against the expected results from the C code when
 876 #                  floating point expression contraction is disabled (the
 877 #                  default with Clang 13 and earlier, when building for
 878 #                  platforms that lack fused multiply-add [FMA] instructions,
 879 #                  or when passing -ffp-contract=off to GCC or Clang)
 880 # fp-contract = validate against the expected results from the C code when
 881 #               floating point expression contraction is enabled (the default
 882 #               with Clang 14 and later, with GCC when building for platforms
 883 #               that have fused multiply-add [FMA] instructions, or when
 884 #               passing -ffp-contract=fast to GCC or -ffp-contract=on to Clang)
 885 # 387 = validate against the expected results from the C code when the 387 FPU
 886 #       is being used for floating point math (which is generally the default
 887 #       with x86 compilers)
 888 # msvc = validate against the expected results from the C code when compiled
 889 #        with a 32-bit version of Visual C++
 890
 891 if(CPU_TYPE STREQUAL "x86_64" OR CPU_TYPE STREQUAL "i386")
 892   if(WITH_SIMD)
 893     set(DEFAULT_FLOATTEST8 sse)
 894   elseif(CPU_TYPE STREQUAL "x86_64")
 895     set(DEFAULT_FLOATTEST8 no-fp-contract)
 896   endif()
 897 elseif(CPU_TYPE STREQUAL "powerpc" OR CPU_TYPE STREQUAL "arm64")
 898   if(CMAKE_C_COMPILER_ID STREQUAL "Clang")
 899     if(CMAKE_C_COMPILER_VERSION VERSION_EQUAL 14.0.0 OR
 900       CMAKE_C_COMPILER_VERSION VERSION_GREATER 14.0.0)
 901       set(DEFAULT_FLOATTEST8 fp-contract)
 902     else()
 903       set(DEFAULT_FLOATTEST8 no-fp-contract)
 904     endif()
 905   elseif(CMAKE_COMPILER_IS_GNUCC)
 906     set(DEFAULT_FLOATTEST8 fp-contract)
 907   endif()
 908 # else we can't really set an intelligent default for FLOATTEST8.  The
 909 # appropriate value could be no-fp-contract, fp-contract, 387, or msvc,
 910 # depending on the compiler and compiler options.  We leave it to the user to
 911 # set FLOATTEST8 manually.
 912 endif()
 913
 914 # This causes FLOATTEST8 to reset to the default value if WITH_SIMD has
 915 # changed.
 916 if(DEFINED WITH_SIMD_INT AND NOT WITH_SIMD EQUAL WITH_SIMD_INT)
 917   set(FORCE_FLOATTEST8 "FORCE")
 918 endif()
 919 set(WITH_SIMD_INT ${WITH_SIMD} CACHE INTERNAL "")
 920 set(FLOATTEST8 ${DEFAULT_FLOATTEST8} CACHE STRING
 921   "The type of floating point math used by the 8-bit-per-sample floating point DCT/IDCT algorithms.  This tells the testing system which numerical results it should expect from those tests.  [sse = libjpeg-turbo x86/x86-64 SIMD extensions, no-fp-contract = generic FPU with floating point expression contraction disabled, fp-contract = generic FPU with floating point expression contraction enabled, 387 = 387 FPU, msvc = 32-bit Visual Studio] (default = ${DEFAULT_FLOATTEST8})"
 922   ${FORCE_FLOATTEST8})
 923 message(STATUS "FLOATTEST8 = ${FLOATTEST8}")
 924
 925 if(FLOATTEST8)
 926   string(TOUPPER ${FLOATTEST8} FLOATTEST8_UC)
 927   string(REGEX REPLACE "-" "_" FLOATTEST8_UC ${FLOATTEST8_UC})
 928   string(TOLOWER ${FLOATTEST8} FLOATTEST8)
 929   if(NOT FLOATTEST8 STREQUAL "sse" AND
 930     NOT FLOATTEST8 STREQUAL "no-fp-contract" AND
 931     NOT FLOATTEST8 STREQUAL "fp-contract" AND NOT FLOATTEST8 STREQUAL "387" AND
 932     NOT FLOATTEST8 STREQUAL "msvc")
 933     message(FATAL_ERROR "\"${FLOATTEST8}\" is not a valid value for FLOATTEST8.")
 934   endif()
 935 endif()
 936
 937 if(CPU_TYPE STREQUAL "x86_64")
 938   set(DEFAULT_FLOATTEST12 no-fp-contract)
 939 elseif(CPU_TYPE STREQUAL "powerpc" OR CPU_TYPE STREQUAL "arm64")
 940   if(CMAKE_C_COMPILER_ID STREQUAL "Clang")
 941     if(CMAKE_C_COMPILER_VERSION VERSION_EQUAL 14.0.0 OR
 942       CMAKE_C_COMPILER_VERSION VERSION_GREATER 14.0.0)
 943       set(DEFAULT_FLOATTEST12 fp-contract)
 944     else()
 945       set(DEFAULT_FLOATTEST12 no-fp-contract)
 946     endif()
 947   elseif(CMAKE_COMPILER_IS_GNUCC)
 948     set(DEFAULT_FLOATTEST12 fp-contract)
 949   endif()
 950 # else we can't really set an intelligent default for FLOATTEST12.  The
 951 # appropriate value could be no-fp-contract, fp-contract, or something else,
 952 # depending on the compiler and compiler options.  We leave it to the user to
 953 # set FLOATTEST12 manually.
 954 endif()
 955
 956 set(FLOATTEST12 ${DEFAULT_FLOATTEST12} CACHE STRING
 957   "The type of floating point math used by the 12-bit-per-sample floating point DCT/IDCT algorithms.  This tells the testing system which numerical results it should expect from those tests.  [sse = libjpeg-turbo x86/x86-64 SIMD extensions, no-fp-contract = generic FPU with floating point expression contraction disabled, fp-contract = generic FPU with floating point expression contraction enabled, 387 = 387 FPU, msvc = 32-bit Visual Studio] (default = ${DEFAULT_FLOATTEST12})")
 958 message(STATUS "FLOATTEST12 = ${FLOATTEST12}")
 959
 960 if(FLOATTEST12)
 961   string(TOUPPER ${FLOATTEST12} FLOATTEST12_UC)
 962   string(REGEX REPLACE "-" "_" FLOATTEST12_UC ${FLOATTEST12_UC})
 963   string(TOLOWER ${FLOATTEST12} FLOATTEST12)
 964   if(NOT FLOATTEST12 STREQUAL "sse" AND
 965     NOT FLOATTEST12 STREQUAL "no-fp-contract" AND
 966     NOT FLOATTEST12 STREQUAL "fp-contract" AND
 967     NOT FLOATTEST12 STREQUAL "387" AND
 968     NOT FLOATTEST12 STREQUAL "msvc")
 969     message(FATAL_ERROR "\"${FLOATTEST12}\" is not a valid value for FLOATTEST12.")
 970   endif()
 971 endif()
 972
 973 foreach(libtype ${TEST_LIBTYPES})
 974   if(libtype STREQUAL "static")
 975     set(suffix -static)
 976   endif()
 977   if(WITH_TURBOJPEG)
 978     add_test(tjunittest-${libtype}
 979       ${CMAKE_CROSSCOMPILING_EMULATOR} tjunittest${suffix})
 980     add_test(tjunittest-${libtype}-alloc
 981       ${CMAKE_CROSSCOMPILING_EMULATOR} tjunittest${suffix} -alloc)
 982     add_test(tjunittest-${libtype}-yuv
 983       ${CMAKE_CROSSCOMPILING_EMULATOR} tjunittest${suffix} -yuv)
 984     add_test(tjunittest-${libtype}-yuv-alloc
 985       ${CMAKE_CROSSCOMPILING_EMULATOR} tjunittest${suffix} -yuv -alloc)
 986     add_test(tjunittest-${libtype}-yuv-nopad
 987       ${CMAKE_CROSSCOMPILING_EMULATOR} tjunittest${suffix} -yuv -noyuvpad)
 988     add_test(tjunittest-${libtype}-lossless
 989       ${CMAKE_CROSSCOMPILING_EMULATOR} tjunittest${suffix} -lossless)
 990     add_test(tjunittest-${libtype}-lossless-alloc
 991       ${CMAKE_CROSSCOMPILING_EMULATOR} tjunittest${suffix} -lossless -alloc)
 992     add_test(tjunittest-${libtype}-bmp
 993       ${CMAKE_CROSSCOMPILING_EMULATOR} tjunittest${suffix} -bmp)
 994     add_test(tjunittest12-${libtype}
 995       ${CMAKE_CROSSCOMPILING_EMULATOR} tjunittest${suffix} -precision 12)
 996     add_test(tjunittest12-${libtype}-alloc
 997       ${CMAKE_CROSSCOMPILING_EMULATOR} tjunittest${suffix} -precision 12
 998         -alloc)
 999     add_test(tjunittest12-${libtype}-lossless
1000       ${CMAKE_CROSSCOMPILING_EMULATOR} tjunittest${suffix} -precision 12
1001         -lossless)
1002     add_test(tjunittest12-${libtype}-lossless-alloc
1003       ${CMAKE_CROSSCOMPILING_EMULATOR} tjunittest${suffix} -precision 12
1004         -lossless -alloc)
1005     add_test(tjunittest12-${libtype}-bmp
1006       ${CMAKE_CROSSCOMPILING_EMULATOR} tjunittest${suffix} -precision 12 -bmp)
1007     add_test(tjunittest16-${libtype}-lossless
1008       ${CMAKE_CROSSCOMPILING_EMULATOR} tjunittest${suffix} -precision 16)
1009     add_test(tjunittest16-${libtype}-lossless-alloc
1010       ${CMAKE_CROSSCOMPILING_EMULATOR} tjunittest${suffix} -precision 16
1011         -alloc)
1012     add_test(tjunittest16-${libtype}-bmp
1013       ${CMAKE_CROSSCOMPILING_EMULATOR} tjunittest${suffix} -precision 16 -bmp)
1014
1015     foreach(sample_bits 8 12)
1016
1017       if(sample_bits EQUAL 12)
1018         set(tjbench tjbench12)
1019         set(testout testout12${suffix})
1020
1021         set(MD5_PPM_GRAY_TILE 2f799249148b1a9d0e61fa4408f6c397)
1022         set(MD5_PPM_420_8x8_TILE b25684e1af37be504ee3fd137757353f)
1023         set(MD5_PPM_420_16x16_TILE 2c1af444a63d19167eb3f4c1fa7f1b67)
1024         set(MD5_PPM_420_32x32_TILE cce091fe18688f39bc0b5ba29238e1e2)
1025         set(MD5_PPM_420_64x64_TILE f770ec8f710a014606dee662bc88606d)
1026         set(MD5_PPM_420_128x128_TILE a841bc82e9eda34cbdefe53f808b339c)
1027         set(MD5_PPM_420M_8x8_TILE 9de845a8d805affb9ae3a7b2712eaa46)
1028         set(MD5_PPM_420M_TILE 455d273be0e229b9c8aabb16481bce5b)
1029         set(MD5_PPM_422_8x8_TILE 5e9f784a98a7eae2789ea1458ed43748)
1030         set(MD5_PPM_422_16x16_TILE c8df65a792d371a30c8fb7352f320314)
1031         set(MD5_PPM_422_32x32_TILE b523b630237e3305a5c4d353ff4ee19b)
1032         set(MD5_PPM_422_64x64_TILE eb30bdd20337079745b039e24e613bfd)
1033         set(MD5_PPM_422_128x128_TILE 7997458635973b004da46863e2da55ea)
1034         set(MD5_PPM_422M_8x8_TILE f8443fffd32cce7681dd36010ce43c07)
1035         set(MD5_PPM_422M_TILE a0d45368343a63ca2c8ee87cc4ef9ded)
1036         set(MD5_PPM_444_TILE 2f571a032e4dbc8ef40f75219d336b0b)
1037       else()
1038         set(tjbench tjbench)
1039         set(testout testout${suffix})
1040
1041         set(MD5_PPM_GRAY_TILE 2c3b567086e6ca0c5e6d34ad8d6f6fe8)
1042         set(MD5_PPM_420_8x8_TILE efca1bdf0226df01777137778cf986ec)
1043         set(MD5_PPM_420_16x16_TILE 8c92c7453870d9e11c6d1dec3a8c9101)
1044         set(MD5_PPM_420_32x32_TILE 3f7651872a95e469d1c7115f1b11ecef)
1045         set(MD5_PPM_420_64x64_TILE f64c71af03fdea12363b62f1a3096aab)
1046         set(MD5_PPM_420_128x128_TILE 5a5ef57517558c671bf5e75793588d69)
1047         set(MD5_PPM_420M_8x8_TILE 66bd869b315a32a00fef1a025661ce72)
1048         set(MD5_PPM_420M_TILE bf9ec2ab4875abb2efcce8f876fe2c2a)
1049         set(MD5_PPM_422_8x8_TILE c300553ce1b3b90fd414ec96b62fe988)
1050         set(MD5_PPM_422_16x16_TILE 6559ddb1191f5b2d3eb41081b254c4e0)
1051         set(MD5_PPM_422_32x32_TILE 58691797f4584c4c5ed5965a6bb9aec0)
1052         set(MD5_PPM_422_64x64_TILE 7f9e34942ae46af7b784f459ec133f5e)
1053         set(MD5_PPM_422_128x128_TILE 6afcb77580d85dd3eacb04b3c2bc7710)
1054         set(MD5_PPM_422M_8x8_TILE 55df1f96bcfb631aedeb940cf3f011f5)
1055         set(MD5_PPM_422M_TILE 6502031018c2d2f69bc6353347f8df4d)
1056         set(MD5_PPM_444_TILE 87bd58005eec73f0f313c8e38d0d793c)
1057       endif()
1058
1059       # Test compressing from/decompressing to an arbitrary subregion of a larger
1060       # image buffer
1061       add_test(${tjbench}-${libtype}-tile-cp
1062         ${CMAKE_COMMAND} -E copy_if_different ${TESTIMAGES}/testorig.ppm
1063           ${testout}_tile.ppm)
1064       add_test(${tjbench}-${libtype}-tile
1065         ${CMAKE_CROSSCOMPILING_EMULATOR} tjbench${suffix} ${testout}_tile.ppm
1066           95 -precision ${sample_bits} -rgb -quiet -tile -benchtime 0.01
1067           -warmup 0)
1068       set_tests_properties(${tjbench}-${libtype}-tile
1069         PROPERTIES DEPENDS ${tjbench}-${libtype}-tile-cp)
1070
1071       foreach(tile 8 16 32 64 128)
1072         add_test(${tjbench}-${libtype}-tile-gray-${tile}x${tile}-cmp
1073           ${CMAKE_CROSSCOMPILING_EMULATOR} ${MD5CMP} ${MD5_PPM_GRAY_TILE}
1074             ${testout}_tile_GRAY_Q95_${tile}x${tile}.ppm)
1075         foreach(subsamp 420 422)
1076           add_test(${tjbench}-${libtype}-tile-${subsamp}-${tile}x${tile}-cmp
1077             ${CMAKE_CROSSCOMPILING_EMULATOR} ${MD5CMP}
1078               ${MD5_PPM_${subsamp}_${tile}x${tile}_TILE}
1079               ${testout}_tile_${subsamp}_Q95_${tile}x${tile}.ppm)
1080         endforeach()
1081         add_test(${tjbench}-${libtype}-tile-444-${tile}x${tile}-cmp
1082           ${CMAKE_CROSSCOMPILING_EMULATOR} ${MD5CMP} ${MD5_PPM_444_TILE}
1083             ${testout}_tile_444_Q95_${tile}x${tile}.ppm)
1084         foreach(subsamp gray 420 422 444)
1085           set_tests_properties(
1086             ${tjbench}-${libtype}-tile-${subsamp}-${tile}x${tile}-cmp
1087             PROPERTIES DEPENDS ${tjbench}-${libtype}-tile)
1088         endforeach()
1089       endforeach()
1090
1091       add_test(${tjbench}-${libtype}-tilem-cp
1092         ${CMAKE_COMMAND} -E copy_if_different ${TESTIMAGES}/testorig.ppm
1093           ${testout}_tilem.ppm)
1094       add_test(${tjbench}-${libtype}-tilem
1095         ${CMAKE_CROSSCOMPILING_EMULATOR} tjbench${suffix} ${testout}_tilem.ppm
1096           95 -precision ${sample_bits} -rgb -fastupsample -quiet -tile
1097           -benchtime 0.01 -warmup 0)
1098       set_tests_properties(${tjbench}-${libtype}-tilem
1099         PROPERTIES DEPENDS ${tjbench}-${libtype}-tilem-cp)
1100
1101       add_test(${tjbench}-${libtype}-tile-420m-8x8-cmp
1102         ${CMAKE_CROSSCOMPILING_EMULATOR} ${MD5CMP} ${MD5_PPM_420M_8x8_TILE}
1103           ${testout}_tilem_420_Q95_8x8.ppm)
1104       add_test(${tjbench}-${libtype}-tile-422m-8x8-cmp
1105         ${CMAKE_CROSSCOMPILING_EMULATOR} ${MD5CMP} ${MD5_PPM_422M_8x8_TILE}
1106           ${testout}_tilem_422_Q95_8x8.ppm)
1107       foreach(tile 16 32 64 128)
1108         foreach(subsamp 420 422)
1109           add_test(${tjbench}-${libtype}-tile-${subsamp}m-${tile}x${tile}-cmp
1110             ${CMAKE_CROSSCOMPILING_EMULATOR} ${MD5CMP}
1111               ${MD5_PPM_${subsamp}M_TILE}
1112               ${testout}_tilem_${subsamp}_Q95_${tile}x${tile}.ppm)
1113         endforeach()
1114       endforeach()
1115       foreach(tile 8 16 32 64 128)
1116         foreach(subsamp 420 422)
1117           set_tests_properties(
1118             ${tjbench}-${libtype}-tile-${subsamp}m-${tile}x${tile}-cmp
1119             PROPERTIES DEPENDS ${tjbench}-${libtype}-tilem)
1120         endforeach()
1121       endforeach()
1122
1123     endforeach()
1124
1125   endif()
1126
1127   # These tests are carefully crafted to provide full coverage of as many of
1128   # the underlying algorithms as possible (including all of the
1129   # SIMD-accelerated ones.)
1130
1131   macro(add_bittest PROG NAME ARGS OUTFILE INFILE MD5SUM)
1132     if(${PROG} STREQUAL "cjpeg16")
1133       set(ACTUAL_ARGS "${ARGS};-precision;16")
1134     elseif(${PROG} STREQUAL "cjpeg12")
1135       set(ACTUAL_ARGS "${ARGS};-precision;12")
1136     else()
1137       set(ACTUAL_ARGS ${ARGS})
1138     endif()
1139     string(REGEX REPLACE "16" "" ACTUAL_PROG ${PROG})
1140     string(REGEX REPLACE "12" "" ACTUAL_PROG ${ACTUAL_PROG})
1141     add_test(${PROG}-${libtype}-${NAME}
1142       ${CMAKE_CROSSCOMPILING_EMULATOR} ${ACTUAL_PROG}${suffix} ${ACTUAL_ARGS}
1143         -outfile ${OUTFILE} ${INFILE})
1144     add_test(${PROG}-${libtype}-${NAME}-cmp
1145       ${CMAKE_CROSSCOMPILING_EMULATOR} ${MD5CMP} ${MD5SUM} ${OUTFILE})
1146     set_tests_properties(${PROG}-${libtype}-${NAME}-cmp PROPERTIES
1147       DEPENDS ${PROG}-${libtype}-${NAME})
1148     if(${ARGC} GREATER 6)
1149       set(DEPENDS ${ARGN})
1150       set_tests_properties(${PROG}-${libtype}-${NAME} PROPERTIES
1151         DEPENDS ${DEPENDS})
1152     endif()
1153   endmacro()
1154
1155   set(MD5_JPEG_LOSSLESS fe99437df4e9976fe5e841969242b208)
1156   set(MD5_PPM_LOSSLESS 01d9642a2b8723fefebbe9cb074ccd02)
1157
1158   # Lossless (all arguments other than -lossless and -restart should have no
1159   # effect)
1160   add_bittest(cjpeg16 lossless
1161     "-lossless;4;-restart;1;-quality;1;-grayscale;-optimize;-dct;float;-smooth;100;-baseline;-qslots;1,0,0;-sample;1x2,3x4,2x1"
1162     testout16_lossless.jpg ${TESTIMAGES}/testorig.ppm
1163     ${MD5_JPEG_LOSSLESS})
1164   add_bittest(djpeg16 lossless
1165     "-fast;-scale;1/8;-dct;float;-dither;none;-nosmooth;-onepass"
1166     testout16_lossless.ppm testout16_lossless.jpg
1167     ${MD5_PPM_LOSSLESS} cjpeg16-${libtype}-lossless)
1168
1169   foreach(sample_bits 8 12)
1170
1171     if(sample_bits EQUAL 12)
1172       set(cjpeg cjpeg12)
1173       set(djpeg djpeg12)
1174       set(jpegtran jpegtran12)
1175       set(testout testout12${suffix})
1176
1177       set(TESTORIG testorig12.jpg)
1178       set(MD5_JPEG_RGB_ISLOW 9d7369207c520d37f2c1cbfcb82b2964)
1179       set(MD5_JPEG_RGB_ISLOW2 a00bd20d8ae49684640ef7177d2e0b64)
1180       set(MD5_PPM_RGB_ISLOW f3301d2219783b8b3d942b7239fa50c0)
1181       set(MD5_JPEG_422_IFAST_OPT 7322e3bd2f127f7de4b40d4480ce60e4)
1182       set(MD5_PPM_422_IFAST 79807fa552899e66a04708f533e16950)
1183       set(MD5_JPEG_440_ISLOW e25c1912e38367be505a89c410c1c2d2)
1184       set(MD5_PPM_440_ISLOW e7d2e26288870cfcb30f3114ad01e380)
1185       set(MD5_PPM_422M_IFAST 07737bfe8a7c1c87aaa393a0098d16b0)
1186       set(MD5_JPEG_420_IFAST_Q100_PROG 9447cef4803d9b0f74bcf333cc710a29)
1187       set(MD5_PPM_420_Q100_IFAST 1b3730122709f53d007255e8dfd3305e)
1188       set(MD5_PPM_420M_Q100_IFAST 980a1a3c5bf9510022869d30b7d26566)
1189       set(MD5_JPEG_GRAY_ISLOW 235c90707b16e2e069f37c888b2636d9)
1190       set(MD5_PPM_GRAY_ISLOW 7213c10af507ad467da5578ca5ee1fca)
1191       set(MD5_PPM_GRAY_ISLOW_RGB e96ee81c30a6ed422d466338bd3de65d)
1192       set(MD5_JPEG_420S_IFAST_OPT 7af8e60be4d9c227ec63ac9b6630855e)
1193
1194       set(MD5_JPEG_3x2_FLOAT_PROG_SSE a8c17daf77b457725ec929e215b603f8)
1195       set(MD5_PPM_3x2_FLOAT_SSE 42876ab9e5c2f76a87d08db5fbd57956)
1196       set(MD5_JPEG_3x2_FLOAT_PROG_NO_FP_CONTRACT
1197         a8c17daf77b457725ec929e215b603f8)
1198       set(MD5_PPM_3x2_FLOAT_NO_FP_CONTRACT ${MD5_PPM_3x2_FLOAT_SSE})
1199       set(MD5_JPEG_3x2_FLOAT_PROG_FP_CONTRACT
1200         ${MD5_JPEG_3x2_FLOAT_PROG_NO_FP_CONTRACT})
1201       if(CMAKE_C_COMPILER_ID STREQUAL "Clang")
1202         set(MD5_PPM_3x2_FLOAT_FP_CONTRACT 2da9de6ae869e88b8372de815d366b03)
1203       else()
1204         set(MD5_PPM_3x2_FLOAT_FP_CONTRACT ${MD5_PPM_3x2_FLOAT_SSE})
1205       endif()
1206       set(MD5_JPEG_3x2_FLOAT_PROG_387 bc6dbbefac2872f6b9d6c4a0ae60c3c0)
1207       set(MD5_PPM_3x2_FLOAT_387 bcc5723c61560463ac60f772e742d092)
1208       set(MD5_JPEG_3x2_FLOAT_PROG_MSVC e27840755870fa849872e58aa0cd1400)
1209       set(MD5_PPM_3x2_FLOAT_MSVC 6c2880b83bb1aa41dfe330e7a9768690)
1210
1211       set(MD5_JPEG_3x2_IFAST_PROG 1396cc2b7185cfe943d408c9d305339e)
1212       set(MD5_PPM_3x2_IFAST 3975985ef6eeb0a2cdc58daa651ccc00)
1213       set(MD5_PPM_420M_ISLOW_2_1 4ca6be2a6f326ff9eaab63e70a8259c0)
1214       set(MD5_PPM_420M_ISLOW_15_8 12aa9f9534c1b3d7ba047322226365eb)
1215       set(MD5_PPM_420M_ISLOW_13_8 f7e22817c7b25e1393e4ec101e9d4e96)
1216       set(MD5_PPM_420M_ISLOW_11_8 800a16f9f4dc9b293197bfe11be10a82)
1217       set(MD5_PPM_420M_ISLOW_9_8 06b7a92a9bc69f4dc36ec40f1937d55c)
1218       set(MD5_PPM_420M_ISLOW_7_8 3ec444a14a4ab4eab88ffc49c48eca43)
1219       set(MD5_PPM_420M_ISLOW_3_4 3e726b7ea872445b19437d1c1d4f0d93)
1220       set(MD5_PPM_420M_ISLOW_5_8 a8a771abdc94301d20ffac119b2caccd)
1221       set(MD5_PPM_420M_ISLOW_1_2 b419124dd5568b085787234866102866)
1222       set(MD5_PPM_420M_ISLOW_3_8 343d19015531b7bbe746124127244fa8)
1223       set(MD5_PPM_420M_ISLOW_1_4 35fd59d866e44659edfa3c18db2a3edb)
1224       set(MD5_PPM_420M_ISLOW_1_8 ccaed48ac0aedefda5d4abe4013f4ad7)
1225       set(MD5_JPEG_LOSSLESS 8473501f5bb7c826524472c858bf4fcd)
1226       set(MD5_PPM_LOSSLESS 1da3fb2620e5a4e258e0fcb891bc67e8)
1227       set(MD5_PPM_420_ISLOW_SKIP15_31 86664cd9dc956536409e44e244d20a97)
1228       set(MD5_PPM_420_ISLOW_PROG_CROP62x62_71_71
1229         452a21656115a163029cfba5c04fa76a)
1230       set(MD5_PPM_444_ISLOW_SKIP1_6 ef63901f71ef7a75cd78253fc0914f84)
1231       set(MD5_PPM_444_ISLOW_PROG_CROP98x98_13_13
1232         15b173fb5872d9575572fbcc1b05956f)
1233       set(MD5_JPEG_CROP cdb35ff4b4519392690ea040c56ea99c)
1234
1235       set(MD5_JPEG_EXAMPLE_COMPRESS 5e502da0c3c0f957a58c536f31e973dc)
1236       set(MD5_PPM_EXAMPLE_DECOMPRESS 2ff0e8505ee6e0ffaeb24037d5650b57)
1237     else()
1238       set(cjpeg cjpeg)
1239       set(djpeg djpeg)
1240       set(jpegtran jpegtran)
1241       set(testout testout${suffix})
1242
1243       set(TESTORIG testorig.jpg)
1244       set(MD5_JPEG_RGB_ISLOW 1d44a406f61da743b5fd31c0a9abdca3)
1245       set(MD5_JPEG_RGB_ISLOW2 31d121e57b6c2934c890a7fc7763bcd4)
1246       set(MD5_PPM_RGB_ISLOW 00a257f5393fef8821f2b88ac7421291)
1247       set(MD5_BMP_RGB_ISLOW_565 f07d2e75073e4bb10f6c6f4d36e2e3be)
1248       set(MD5_BMP_RGB_ISLOW_565D 4cfa0928ef3e6bb626d7728c924cfda4)
1249       set(MD5_JPEG_422_IFAST_OPT 2540287b79d913f91665e660303ab2c8)
1250       set(MD5_PPM_422_IFAST 35bd6b3f833bad23de82acea847129fa)
1251       set(MD5_JPEG_440_ISLOW 538bc02bd4b4658fd85de6ece6cbeda6)
1252       set(MD5_PPM_440_ISLOW 11e7eab7ef7ef3276934bb7e7b6bb377)
1253       set(MD5_PPM_422M_IFAST 8dbc65323d62cca7c91ba02dd1cfa81d)
1254       set(MD5_BMP_422M_IFAST_565 3294bd4d9a1f2b3d08ea6020d0db7065)
1255       set(MD5_BMP_422M_IFAST_565D da98c9c7b6039511be4a79a878a9abc1)
1256       set(MD5_JPEG_420_IFAST_Q100_PROG 0ba15f9dab81a703505f835f9dbbac6d)
1257       set(MD5_PPM_420_Q100_IFAST 5a732542015c278ff43635e473a8a294)
1258       set(MD5_PPM_420M_Q100_IFAST ff692ee9323a3b424894862557c092f1)
1259       set(MD5_JPEG_GRAY_ISLOW 72b51f894b8f4a10b3ee3066770aa38d)
1260       set(MD5_PPM_GRAY_ISLOW 8d3596c56eace32f205deccc229aa5ed)
1261       set(MD5_PPM_GRAY_ISLOW_RGB 116424ac07b79e5e801f00508eab48ec)
1262       set(MD5_BMP_GRAY_ISLOW_565 12f78118e56a2f48b966f792fedf23cc)
1263       set(MD5_BMP_GRAY_ISLOW_565D bdbbd616441a24354c98553df5dc82db)
1264       set(MD5_JPEG_420S_IFAST_OPT 388708217ac46273ca33086b22827ed8)
1265
1266       set(MD5_JPEG_3x2_FLOAT_PROG_SSE 343e3f8caf8af5986ebaf0bdc13b5c71)
1267       set(MD5_PPM_3x2_FLOAT_SSE 1a75f36e5904d6fc3a85a43da9ad89bb)
1268       set(MD5_JPEG_3x2_FLOAT_PROG_NO_FP_CONTRACT
1269         9bca803d2042bd1eb03819e2bf92b3e5)
1270       set(MD5_PPM_3x2_FLOAT_NO_FP_CONTRACT f6bfab038438ed8f5522fbd33595dcdc)
1271       set(MD5_JPEG_3x2_FLOAT_PROG_FP_CONTRACT
1272         ${MD5_JPEG_3x2_FLOAT_PROG_NO_FP_CONTRACT})
1273       if(CMAKE_C_COMPILER_ID STREQUAL "Clang")
1274         set(MD5_PPM_3x2_FLOAT_FP_CONTRACT ${MD5_PPM_3x2_FLOAT_NO_FP_CONTRACT})
1275       else()
1276         set(MD5_PPM_3x2_FLOAT_FP_CONTRACT 0e917a34193ef976b679a6b069b1be26)
1277       endif()
1278       set(MD5_JPEG_3x2_FLOAT_PROG_387 1657664a410e0822c924b54f6f65e6e9)
1279       set(MD5_PPM_3x2_FLOAT_387 cb0a1f027f3d2917c902b5640214e025)
1280       set(MD5_JPEG_3x2_FLOAT_PROG_MSVC 7999ce9cd0ee9b6c7043b7351ab7639d)
1281       set(MD5_PPM_3x2_FLOAT_MSVC 28cdc448a6b75e97892f0e0f8d4b21f3)
1282
1283       set(MD5_JPEG_3x2_IFAST_PROG 1ee5d2c1a77f2da495f993c8c7cceca5)
1284       set(MD5_PPM_3x2_IFAST fd283664b3b49127984af0a7f118fccd)
1285       set(MD5_JPEG_420_ISLOW_ARI e986fb0a637a8d833d96e8a6d6d84ea1)
1286       set(MD5_JPEG_444_ISLOW_PROGARI 0a8f1c8f66e113c3cf635df0a475a617)
1287       set(MD5_PPM_420M_IFAST_ARI 57251da28a35b46eecb7177d82d10e0e)
1288       set(MD5_JPEG_420_ISLOW 9a68f56bc76e466aa7e52f415d0f4a5f)
1289       set(MD5_PPM_420M_ISLOW_2_1 9f9de8c0612f8d06869b960b05abf9c9)
1290       set(MD5_PPM_420M_ISLOW_15_8 b6875bc070720b899566cc06459b63b7)
1291       set(MD5_PPM_420M_ISLOW_13_8 bc3452573c8152f6ae552939ee19f82f)
1292       set(MD5_PPM_420M_ISLOW_11_8 d8cc73c0aaacd4556569b59437ba00a5)
1293       set(MD5_PPM_420M_ISLOW_9_8 d25e61bc7eac0002f5b393aa223747b6)
1294       set(MD5_PPM_420M_ISLOW_7_8 ddb564b7c74a09494016d6cd7502a946)
1295       set(MD5_PPM_420M_ISLOW_3_4 8ed8e68808c3fbc4ea764fc9d2968646)
1296       set(MD5_PPM_420M_ISLOW_5_8 a3363274999da2366a024efae6d16c9b)
1297       set(MD5_PPM_420M_ISLOW_1_2 e692a315cea26b988c8e8b29a5dbcd81)
1298       set(MD5_PPM_420M_ISLOW_3_8 79eca9175652ced755155c90e785a996)
1299       set(MD5_PPM_420M_ISLOW_1_4 79cd778f8bf1a117690052cacdd54eca)
1300       set(MD5_PPM_420M_ISLOW_1_8 391b3d4aca640c8567d6f8745eb2142f)
1301       set(MD5_BMP_420_ISLOW_256 4980185e3776e89bd931736e1cddeee6)
1302       set(MD5_BMP_420_ISLOW_565 bf9d13e16c4923b92e1faa604d7922cb)
1303       set(MD5_BMP_420_ISLOW_565D 6bde71526acc44bcff76f696df8638d2)
1304       set(MD5_BMP_420M_ISLOW_565 8dc0185245353cfa32ad97027342216f)
1305       set(MD5_BMP_420M_ISLOW_565D ce034037d212bc403330df6f915c161b)
1306       set(MD5_JPEG_LOSSLESS fc777b82d42d835ae1282ba1ee87c209)
1307       set(MD5_PPM_LOSSLESS 64072f1dbdc5b3a187777788604971a5)
1308       set(MD5_PPM_420_ISLOW_SKIP15_31 c4c65c1e43d7275cd50328a61e6534f0)
1309       set(MD5_PPM_420_ISLOW_ARI_SKIP16_139 087c6b123db16ac00cb88c5b590bb74a)
1310       set(MD5_PPM_420_ISLOW_PROG_CROP62x62_71_71
1311         26eb36ccc7d1f0cb80cdabb0ac8b5d99)
1312       set(MD5_PPM_420_ISLOW_ARI_CROP53x53_4_4 886c6775af22370257122f8b16207e6d)
1313       set(MD5_PPM_444_ISLOW_SKIP1_6 5606f86874cf26b8fcee1117a0a436a6)
1314       set(MD5_PPM_444_ISLOW_PROG_CROP98x98_13_13
1315         db87dc7ce26bcdc7a6b56239ce2b9d6c)
1316       set(MD5_PPM_444_ISLOW_ARI_CROP37x37_0_0 cb57b32bd6d03e35432362f7bf184b6d)
1317       set(MD5_JPEG_CROP b4197f377e621c4e9b1d20471432610d)
1318
1319       set(MD5_JPEG_EXAMPLE_COMPRESS 95d4d72e2ef127332654c2599afb47bf)
1320       set(MD5_PPM_EXAMPLE_DECOMPRESS 6fdde7301575bfd711e295b969b6b3de)
1321     endif()
1322
1323     # CC: null  SAMP: fullsize  FDCT: islow  ENT: huff
1324     add_bittest(${cjpeg} rgb-islow "-rgb;-dct;int;-icc;${TESTIMAGES}/test1.icc"
1325       ${testout}_rgb_islow.jpg ${TESTIMAGES}/testorig.ppm
1326       ${MD5_JPEG_RGB_ISLOW})
1327
1328     # CC: null  SAMP: fullsize  IDCT: islow  ENT: huff
1329     add_bittest(${djpeg} rgb-islow
1330       "-dct;int;-ppm;-icc;${testout}_rgb_islow.icc"
1331       ${testout}_rgb_islow.ppm ${testout}_rgb_islow.jpg
1332       ${MD5_PPM_RGB_ISLOW} ${cjpeg}-${libtype}-rgb-islow)
1333
1334     add_test(${djpeg}-${libtype}-rgb-islow-icc-cmp
1335       ${CMAKE_CROSSCOMPILING_EMULATOR} ${MD5CMP}
1336         b06a39d730129122e85c1363ed1bbc9e ${testout}_rgb_islow.icc)
1337     set_tests_properties(${djpeg}-${libtype}-rgb-islow-icc-cmp PROPERTIES
1338       DEPENDS ${djpeg}-${libtype}-rgb-islow)
1339
1340     add_bittest(${jpegtran} icc "-copy;all;-icc;${TESTIMAGES}/test2.icc"
1341       ${testout}_rgb_islow2.jpg ${testout}_rgb_islow.jpg
1342       ${MD5_JPEG_RGB_ISLOW2} ${cjpeg}-${libtype}-rgb-islow)
1343
1344     if(sample_bits EQUAL 8)
1345       # CC: RGB->RGB565  SAMP: fullsize  IDCT: islow  ENT: huff
1346       add_bittest(${djpeg} rgb-islow-565 "-dct;int;-rgb565;-dither;none;-bmp"
1347         ${testout}_rgb_islow_565.bmp ${testout}_rgb_islow.jpg
1348         ${MD5_BMP_RGB_ISLOW_565} ${cjpeg}-${libtype}-rgb-islow)
1349
1350       # CC: RGB->RGB565 (dithered)  SAMP: fullsize  IDCT: islow  ENT: huff
1351       add_bittest(${djpeg} rgb-islow-565D "-dct;int;-rgb565;-bmp"
1352         ${testout}_rgb_islow_565D.bmp ${testout}_rgb_islow.jpg
1353         ${MD5_BMP_RGB_ISLOW_565D} ${cjpeg}-${libtype}-rgb-islow)
1354     endif()
1355
1356     # CC: RGB->YCC  SAMP: fullsize/h2v1  FDCT: ifast  ENT: 2-pass huff
1357     add_bittest(${cjpeg} 422-ifast-opt "-sample;2x1;-dct;fast;-opt"
1358       ${testout}_422_ifast_opt.jpg ${TESTIMAGES}/testorig.ppm
1359       ${MD5_JPEG_422_IFAST_OPT})
1360
1361     # CC: YCC->RGB  SAMP: fullsize/h2v1 fancy  IDCT: ifast  ENT: huff
1362     add_bittest(${djpeg} 422-ifast "-dct;fast"
1363       ${testout}_422_ifast.ppm ${testout}_422_ifast_opt.jpg
1364       ${MD5_PPM_422_IFAST} ${cjpeg}-${libtype}-422-ifast-opt)
1365
1366     # CC: RGB->YCC  SAMP: fullsize/h1v2  FDCT: islow  ENT: huff
1367     add_bittest(${cjpeg} 440-islow "-sample;1x2;-dct;int"
1368       ${testout}_440_islow.jpg ${TESTIMAGES}/testorig.ppm
1369       ${MD5_JPEG_440_ISLOW})
1370
1371     # CC: YCC->RGB  SAMP: fullsize/h1v2 fancy  IDCT: islow  ENT: huff
1372     add_bittest(${djpeg} 440-islow "-dct;int"
1373       ${testout}_440_islow.ppm ${testout}_440_islow.jpg
1374       ${MD5_PPM_440_ISLOW} ${cjpeg}-${libtype}-440-islow)
1375
1376     # CC: YCC->RGB  SAMP: h2v1 merged  IDCT: ifast  ENT: huff
1377     add_bittest(${djpeg} 422m-ifast "-dct;fast;-nosmooth"
1378       ${testout}_422m_ifast.ppm ${testout}_422_ifast_opt.jpg
1379       ${MD5_PPM_422M_IFAST} ${cjpeg}-${libtype}-422-ifast-opt)
1380
1381     if(sample_bits EQUAL 8)
1382       # CC: YCC->RGB565  SAMP: h2v1 merged  IDCT: ifast  ENT: huff
1383       add_bittest(${djpeg} 422m-ifast-565
1384         "-dct;int;-nosmooth;-rgb565;-dither;none;-bmp"
1385         ${testout}_422m_ifast_565.bmp ${testout}_422_ifast_opt.jpg
1386         ${MD5_BMP_422M_IFAST_565} ${cjpeg}-${libtype}-422-ifast-opt)
1387
1388       # CC: YCC->RGB565 (dithered)  SAMP: h2v1 merged  IDCT: ifast  ENT: huff
1389       add_bittest(${djpeg} 422m-ifast-565D "-dct;int;-nosmooth;-rgb565;-bmp"
1390         ${testout}_422m_ifast_565D.bmp ${testout}_422_ifast_opt.jpg
1391         ${MD5_BMP_422M_IFAST_565D} ${cjpeg}-${libtype}-422-ifast-opt)
1392     endif()
1393
1394     # CC: RGB->YCC  SAMP: fullsize/h2v2  FDCT: ifast  ENT: prog huff
1395     add_bittest(${cjpeg} 420-q100-ifast-prog
1396       "-sample;2x2;-quality;100;-dct;fast;-scans;${TESTIMAGES}/test.scan"
1397       ${testout}_420_q100_ifast_prog.jpg ${TESTIMAGES}/testorig.ppm
1398       ${MD5_JPEG_420_IFAST_Q100_PROG})
1399
1400     # CC: YCC->RGB  SAMP: fullsize/h2v2 fancy  IDCT: ifast  ENT: prog huff
1401     add_bittest(${djpeg} 420-q100-ifast-prog "-dct;fast"
1402       ${testout}_420_q100_ifast.ppm ${testout}_420_q100_ifast_prog.jpg
1403       ${MD5_PPM_420_Q100_IFAST} ${cjpeg}-${libtype}-420-q100-ifast-prog)
1404
1405     # CC: YCC->RGB  SAMP: h2v2 merged  IDCT: ifast  ENT: prog huff
1406     add_bittest(${djpeg} 420m-q100-ifast-prog "-dct;fast;-nosmooth"
1407       ${testout}_420m_q100_ifast.ppm ${testout}_420_q100_ifast_prog.jpg
1408       ${MD5_PPM_420M_Q100_IFAST} ${cjpeg}-${libtype}-420-q100-ifast-prog)
1409
1410     # CC: RGB->Gray  SAMP: fullsize  FDCT: islow  ENT: huff
1411     add_bittest(${cjpeg} gray-islow "-gray;-dct;int"
1412       ${testout}_gray_islow.jpg ${TESTIMAGES}/testorig.ppm
1413       ${MD5_JPEG_GRAY_ISLOW})
1414
1415     # CC: Gray->Gray  SAMP: fullsize  IDCT: islow  ENT: huff
1416     add_bittest(${djpeg} gray-islow "-dct;int"
1417       ${testout}_gray_islow.ppm ${testout}_gray_islow.jpg
1418       ${MD5_PPM_GRAY_ISLOW} ${cjpeg}-${libtype}-gray-islow)
1419
1420     # CC: Gray->RGB  SAMP: fullsize  IDCT: islow  ENT: huff
1421     add_bittest(${djpeg} gray-islow-rgb "-dct;int;-rgb"
1422       ${testout}_gray_islow_rgb.ppm ${testout}_gray_islow.jpg
1423       ${MD5_PPM_GRAY_ISLOW_RGB} ${cjpeg}-${libtype}-gray-islow)
1424
1425     if(sample_bits EQUAL 8)
1426       # CC: Gray->RGB565  SAMP: fullsize  IDCT: islow  ENT: huff
1427       add_bittest(${djpeg} gray-islow-565 "-dct;int;-rgb565;-dither;none;-bmp"
1428         ${testout}_gray_islow_565.bmp ${testout}_gray_islow.jpg
1429         ${MD5_BMP_GRAY_ISLOW_565} ${cjpeg}-${libtype}-gray-islow)
1430
1431       # CC: Gray->RGB565 (dithered)  SAMP: fullsize  IDCT: islow  ENT: huff
1432       add_bittest(${djpeg} gray-islow-565D "-dct;int;-rgb565;-bmp"
1433         ${testout}_gray_islow_565D.bmp ${testout}_gray_islow.jpg
1434         ${MD5_BMP_GRAY_ISLOW_565D} ${cjpeg}-${libtype}-gray-islow)
1435     endif()
1436
1437     # CC: RGB->YCC  SAMP: fullsize smooth/h2v2 smooth  FDCT: islow
1438     # ENT: 2-pass huff
1439     add_bittest(${cjpeg} 420s-ifast-opt "-sample;2x2;-smooth;1;-dct;int;-opt"
1440       ${testout}_420s_ifast_opt.jpg ${TESTIMAGES}/testorig.ppm
1441       ${MD5_JPEG_420S_IFAST_OPT})
1442
1443     if(FLOATTEST${sample_bits})
1444       # CC: RGB->YCC  SAMP: fullsize/int  FDCT: float  ENT: prog huff
1445       add_bittest(${cjpeg} 3x2-float-prog "-sample;3x2;-dct;float;-prog"
1446         ${testout}_3x2_float_prog.jpg ${TESTIMAGES}/testorig.ppm
1447         ${MD5_JPEG_3x2_FLOAT_PROG_${FLOATTEST${sample_bits}_UC}})
1448
1449       # CC: YCC->RGB  SAMP: fullsize/int  IDCT: float  ENT: prog huff
1450       add_bittest(${djpeg} 3x2-float-prog "-dct;float"
1451         ${testout}_3x2_float.ppm ${testout}_3x2_float_prog.jpg
1452         ${MD5_PPM_3x2_FLOAT_${FLOATTEST${sample_bits}_UC}}
1453         ${cjpeg}-${libtype}-3x2-float-prog)
1454     endif()
1455
1456     # CC: RGB->YCC  SAMP: fullsize/int  FDCT: ifast  ENT: prog huff
1457     add_bittest(${cjpeg} 3x2-ifast-prog "-sample;3x2;-dct;fast;-prog"
1458       ${testout}_3x2_ifast_prog.jpg ${TESTIMAGES}/testorig.ppm
1459       ${MD5_JPEG_3x2_IFAST_PROG})
1460
1461     # CC: YCC->RGB  SAMP: fullsize/int  IDCT: ifast  ENT: prog huff
1462     add_bittest(${djpeg} 3x2-ifast-prog "-dct;fast"
1463       ${testout}_3x2_ifast.ppm ${testout}_3x2_ifast_prog.jpg
1464       ${MD5_PPM_3x2_IFAST} ${cjpeg}-${libtype}-3x2-ifast-prog)
1465
1466     if(WITH_ARITH_ENC AND sample_bits EQUAL 8)
1467       # CC: YCC->RGB  SAMP: fullsize/h2v2  FDCT: islow  ENT: arith
1468       add_bittest(${cjpeg} 420-islow-ari "-dct;int;-arithmetic"
1469         ${testout}_420_islow_ari.jpg ${TESTIMAGES}/testorig.ppm
1470         ${MD5_JPEG_420_ISLOW_ARI})
1471
1472       add_bittest(${jpegtran} 420-islow-ari "-arithmetic"
1473         ${testout}_420_islow_ari2.jpg ${TESTIMAGES}/testimgint.jpg
1474         ${MD5_JPEG_420_ISLOW_ARI})
1475
1476       # CC: YCC->RGB  SAMP: fullsize  FDCT: islow  ENT: prog arith
1477       add_bittest(${cjpeg} 444-islow-progari
1478         "-sample;1x1;-dct;int;-prog;-arithmetic"
1479         ${testout}_444_islow_progari.jpg ${TESTIMAGES}/testorig.ppm
1480         ${MD5_JPEG_444_ISLOW_PROGARI})
1481     endif()
1482
1483     if(WITH_ARITH_DEC AND sample_bits EQUAL 8)
1484       # CC: RGB->YCC  SAMP: h2v2 merged  IDCT: ifast  ENT: arith
1485       add_bittest(${djpeg} 420m-ifast-ari "-fast;-skip;1,20;-ppm"
1486         ${testout}_420m_ifast_ari.ppm ${TESTIMAGES}/testimgari.jpg
1487         ${MD5_PPM_420M_IFAST_ARI})
1488
1489       add_bittest(${jpegtran} 420-islow ""
1490         ${testout}_420_islow.jpg ${TESTIMAGES}/testimgari.jpg
1491         ${MD5_JPEG_420_ISLOW})
1492     endif()
1493
1494     # 2/1--   CC: YCC->RGB  SAMP: h2v2 merged  IDCT: 16x16 islow  ENT: huff
1495     # 15/8--  CC: YCC->RGB  SAMP: h2v2 merged  IDCT: 15x15 islow  ENT: huff
1496     # 13/8--  CC: YCC->RGB  SAMP: h2v2 merged  IDCT: 13x13 islow  ENT: huff
1497     # 11/8--  CC: YCC->RGB  SAMP: h2v2 merged  IDCT: 11x11 islow  ENT: huff
1498     # 9/8--   CC: YCC->RGB  SAMP: h2v2 merged  IDCT: 9x9 islow  ENT: huff
1499     # 7/8--   CC: YCC->RGB  SAMP: h2v2 merged  IDCT: 7x7 islow/14x14 islow
1500     #         ENT: huff
1501     # 3/4--   CC: YCC->RGB  SAMP: h2v2 merged  IDCT: 6x6 islow/12x12 islow
1502     #         ENT: huff
1503     # 5/8--   CC: YCC->RGB  SAMP: h2v2 merged  IDCT: 5x5 islow/10x10 islow
1504     #         ENT: huff
1505     # 1/2--   CC: YCC->RGB  SAMP: h2v2 merged  IDCT: 4x4 islow/8x8 islow
1506     #         ENT: huff
1507     # 3/8--   CC: YCC->RGB  SAMP: h2v2 merged  IDCT: 3x3 islow/6x6 islow
1508     #         ENT: huff
1509     # 1/4--   CC: YCC->RGB  SAMP: h2v2 merged  IDCT: 2x2 islow/4x4 islow
1510     #         ENT: huff
1511     # 1/8--   CC: YCC->RGB  SAMP: h2v2 merged  IDCT: 1x1 islow/2x2 islow
1512     #         ENT: huff
1513     foreach(scale 2_1 15_8 13_8 11_8 9_8 7_8 3_4 5_8 1_2 3_8 1_4 1_8)
1514       string(REGEX REPLACE "_" "/" scalearg ${scale})
1515       add_bittest(${djpeg} 420m-islow-${scale}
1516         "-dct;int;-scale;${scalearg};-nosmooth;-ppm"
1517         ${testout}_420m_islow_${scale}.ppm ${TESTIMAGES}/${TESTORIG}
1518         ${MD5_PPM_420M_ISLOW_${scale}})
1519     endforeach()
1520
1521     if(sample_bits EQUAL 8)
1522       # CC: YCC->RGB (dithered)  SAMP: h2v2 fancy  IDCT: islow  ENT: huff
1523       add_bittest(${djpeg} 420-islow-256 "-dct;int;-colors;256;-bmp"
1524         ${testout}_420_islow_256.bmp ${TESTIMAGES}/${TESTORIG}
1525         ${MD5_BMP_420_ISLOW_256})
1526
1527       # CC: YCC->RGB565  SAMP: h2v2 fancy  IDCT: islow  ENT: huff
1528       add_bittest(${djpeg} 420-islow-565 "-dct;int;-rgb565;-dither;none;-bmp"
1529         ${testout}_420_islow_565.bmp ${TESTIMAGES}/${TESTORIG}
1530         ${MD5_BMP_420_ISLOW_565})
1531
1532       # CC: YCC->RGB565 (dithered)  SAMP: h2v2 fancy  IDCT: islow  ENT: huff
1533       add_bittest(${djpeg} 420-islow-565D "-dct;int;-rgb565;-bmp"
1534         ${testout}_420_islow_565D.bmp ${TESTIMAGES}/${TESTORIG}
1535         ${MD5_BMP_420_ISLOW_565D})
1536
1537       # CC: YCC->RGB565  SAMP: h2v2 merged  IDCT: islow  ENT: huff
1538       add_bittest(${djpeg} 420m-islow-565
1539         "-dct;int;-nosmooth;-rgb565;-dither;none;-bmp"
1540         ${testout}_420m_islow_565.bmp ${TESTIMAGES}/${TESTORIG}
1541         ${MD5_BMP_420M_ISLOW_565})
1542
1543       # CC: YCC->RGB565 (dithered)  SAMP: h2v2 merged  IDCT: islow  ENT: huff
1544       add_bittest(${djpeg} 420m-islow-565D "-dct;int;-nosmooth;-rgb565;-bmp"
1545         ${testout}_420m_islow_565D.bmp ${TESTIMAGES}/${TESTORIG}
1546         ${MD5_BMP_420M_ISLOW_565D})
1547     endif()
1548
1549     # Lossless (all arguments other than -lossless and -restart should have no
1550     # effect)
1551     add_bittest(${cjpeg} lossless
1552       "-lossless;4;-restart;1;-quality;1;-grayscale;-optimize;-dct;float;-smooth;100;-baseline;-qslots;1,0,0;-sample;1x2,3x4,2x1"
1553       ${testout}_lossless.jpg ${TESTIMAGES}/testorig.ppm
1554       ${MD5_JPEG_LOSSLESS})
1555     add_bittest(${djpeg} lossless
1556       "-fast;-scale;1/8;-dct;float;-dither;none;-nosmooth;-onepass"
1557       ${testout}_lossless.ppm ${testout}_lossless.jpg
1558       ${MD5_PPM_LOSSLESS} ${cjpeg}-${libtype}-lossless)
1559
1560     # Partial decode tests.  These tests are designed to cover all of the
1561     # possible code paths in jpeg_skip_scanlines().
1562
1563     # Context rows: Yes  Intra-iMCU row: Yes  iMCU row prefetch: No
1564     # ENT: huff
1565     add_bittest(${djpeg} 420-islow-skip15_31 "-dct;int;-skip;15,31;-ppm"
1566       ${testout}_420_islow_skip15,31.ppm ${TESTIMAGES}/${TESTORIG}
1567       ${MD5_PPM_420_ISLOW_SKIP15_31})
1568
1569     # Context rows: Yes  Intra-iMCU row: No   iMCU row prefetch: Yes
1570     # ENT: arith
1571     if(WITH_ARITH_DEC AND sample_bits EQUAL 8)
1572       add_bittest(${djpeg} 420-islow-ari-skip16_139
1573         "-dct;int;-skip;16,139;-ppm"
1574         ${testout}_420_islow_ari_skip16,139.ppm ${TESTIMAGES}/testimgari.jpg
1575         ${MD5_PPM_420_ISLOW_ARI_SKIP16_139})
1576     endif()
1577
1578     # Context rows: Yes  Intra-iMCU row: No   iMCU row prefetch: No
1579     # ENT: prog huff
1580     add_test(${cjpeg}-${libtype}-420-islow-prog
1581       ${CMAKE_CROSSCOMPILING_EMULATOR} cjpeg${suffix} -dct int -prog
1582         -precision ${sample_bits} -outfile ${testout}_420_islow_prog.jpg
1583         ${TESTIMAGES}/testorig.ppm)
1584     add_bittest(${djpeg} 420-islow-prog-crop62x62_71_71
1585       "-dct;int;-crop;62x62+71+71;-ppm"
1586       ${testout}_420_islow_prog_crop62x62,71,71.ppm
1587       ${testout}_420_islow_prog.jpg ${MD5_PPM_420_ISLOW_PROG_CROP62x62_71_71}
1588       ${cjpeg}-${libtype}-420-islow-prog)
1589
1590     # Context rows: Yes  Intra-iMCU row: No   iMCU row prefetch: No
1591     # ENT: arith
1592     if(WITH_ARITH_DEC AND sample_bits EQUAL 8)
1593       add_bittest(${djpeg} 420-islow-ari-crop53x53_4_4
1594         "-dct;int;-crop;53x53+4+4;-ppm"
1595         ${testout}_420_islow_ari_crop53x53,4,4.ppm ${TESTIMAGES}/testimgari.jpg
1596         ${MD5_PPM_420_ISLOW_ARI_CROP53x53_4_4})
1597     endif()
1598
1599     # Context rows: No   Intra-iMCU row: Yes  ENT: huff
1600     add_test(${cjpeg}-${libtype}-444-islow
1601       ${CMAKE_CROSSCOMPILING_EMULATOR} cjpeg${suffix} -dct int -sample 1x1
1602         -precision ${sample_bits} -outfile ${testout}_444_islow.jpg
1603         ${TESTIMAGES}/testorig.ppm)
1604     add_bittest(${djpeg} 444-islow-skip1_6 "-dct;int;-skip;1,6;-ppm"
1605       ${testout}_444_islow_skip1,6.ppm ${testout}_444_islow.jpg
1606       ${MD5_PPM_444_ISLOW_SKIP1_6} ${cjpeg}-${libtype}-444-islow)
1607
1608     # Context rows: No   Intra-iMCU row: No   ENT: prog huff
1609     add_test(${cjpeg}-${libtype}-444-islow-prog
1610       ${CMAKE_CROSSCOMPILING_EMULATOR} cjpeg${suffix} -dct int -prog
1611         -precision ${sample_bits} -sample 1x1
1612         -outfile ${testout}_444_islow_prog.jpg ${TESTIMAGES}/testorig.ppm)
1613     add_bittest(${djpeg} 444-islow-prog-crop98x98_13_13
1614       "-dct;int;-crop;98x98+13+13;-ppm"
1615       ${testout}_444_islow_prog_crop98x98,13,13.ppm
1616       ${testout}_444_islow_prog.jpg ${MD5_PPM_444_ISLOW_PROG_CROP98x98_13_13}
1617       ${cjpeg}-${libtype}-444-islow-prog)
1618
1619     # Context rows: No   Intra-iMCU row: No   ENT: arith
1620     if(WITH_ARITH_ENC AND sample_bits EQUAL 8)
1621       add_test(${cjpeg}-${libtype}-444-islow-ari
1622         ${CMAKE_CROSSCOMPILING_EMULATOR} cjpeg${suffix} -dct int -arithmetic
1623           -sample 1x1 -precision ${sample_bits}
1624           -outfile ${testout}_444_islow_ari.jpg ${TESTIMAGES}/testorig.ppm)
1625       if(WITH_ARITH_DEC)
1626         add_bittest(${djpeg} 444-islow-ari-crop37x37_0_0
1627           "-dct;int;-crop;37x37+0+0;-ppm"
1628           ${testout}_444_islow_ari_crop37x37,0,0.ppm
1629           ${testout}_444_islow_ari.jpg ${MD5_PPM_444_ISLOW_ARI_CROP37x37_0_0}
1630           ${cjpeg}-${libtype}-444-islow-ari)
1631       endif()
1632     endif()
1633
1634     add_bittest(${jpegtran} crop "-crop;120x90+20+50;-transpose;-perfect"
1635       ${testout}_crop.jpg ${TESTIMAGES}/${TESTORIG}
1636       ${MD5_JPEG_CROP})
1637
1638     unset(EXAMPLE_12BIT_ARG)
1639     if(sample_bits EQUAL 12)
1640       set(EXAMPLE_12BIT_ARG "-precision;12")
1641     endif()
1642
1643     add_test(example-${sample_bits}bit-${libtype}-compress
1644       ${CMAKE_CROSSCOMPILING_EMULATOR} example${suffix} compress -q 95
1645         ${EXAMPLE_12BIT_ARG} ${testout}-example.jpg)
1646     add_test(example-${sample_bits}bit-${libtype}-compress-cmp
1647       ${CMAKE_CROSSCOMPILING_EMULATOR} ${MD5CMP} ${MD5_JPEG_EXAMPLE_COMPRESS}
1648         ${testout}-example.jpg)
1649     set_tests_properties(example-${sample_bits}bit-${libtype}-compress-cmp
1650       PROPERTIES DEPENDS example-${sample_bits}bit-${libtype}-compress)
1651
1652     add_test(example-${sample_bits}bit-${libtype}-decompress
1653       ${CMAKE_CROSSCOMPILING_EMULATOR} example${suffix} decompress
1654         ${EXAMPLE_12BIT_ARG} ${testout}-example.jpg ${testout}-example.ppm)
1655     set_tests_properties(example-${sample_bits}bit-${libtype}-decompress
1656       PROPERTIES DEPENDS example-${sample_bits}bit-${libtype}-compress)
1657     add_test(example-${sample_bits}bit-${libtype}-decompress-cmp
1658       ${CMAKE_CROSSCOMPILING_EMULATOR} ${MD5CMP} ${MD5_PPM_EXAMPLE_DECOMPRESS}
1659         ${testout}-example.ppm)
1660     set_tests_properties(example-${sample_bits}bit-${libtype}-decompress-cmp
1661       PROPERTIES DEPENDS example-${sample_bits}bit-${libtype}-decompress)
1662
1663   endforeach()
1664
1665 endforeach()
1666
1667 add_custom_target(testclean COMMAND ${CMAKE_COMMAND} -P
1668   ${CMAKE_CURRENT_SOURCE_DIR}/cmakescripts/testclean.cmake)
1669
1670 configure_file(croptest.in croptest @ONLY)
1671 add_custom_target(croptest
1672   COMMAND echo croptest
1673   COMMAND ${BASH} ${CMAKE_CURRENT_BINARY_DIR}/croptest)
1674
1675 if(WITH_TURBOJPEG)
1676   configure_file(tjbenchtest.in tjbenchtest @ONLY)
1677   configure_file(tjexampletest.in tjexampletest @ONLY)
1678   if(WIN32)
1679     set(BASH bash)
1680   endif()
1681   add_custom_target(tjtest COMMAND ${CMAKE_COMMAND} -DWITH_JAVA=${WITH_JAVA}
1682     -DPRECISION=8 -P ${CMAKE_SOURCE_DIR}/cmakescripts/tjbenchtest.cmake
1683     DEPENDS ${CMAKE_SOURCE_DIR}/cmakescripts/tjbenchtest.cmake
1684       ${CMAKE_CURRENT_BINARY_DIR}/tjbenchtest
1685       ${CMAKE_CURRENT_BINARY_DIR}/tjexampletest)
1686   add_custom_target(tjtest12 COMMAND ${CMAKE_COMMAND} -DWITH_JAVA=${WITH_JAVA}
1687     -DPRECISION=12 -P ${CMAKE_SOURCE_DIR}/cmakescripts/tjbenchtest.cmake
1688     DEPENDS ${CMAKE_SOURCE_DIR}/cmakescripts/tjbenchtest.cmake
1689       ${CMAKE_CURRENT_BINARY_DIR}/tjbenchtest
1690       ${CMAKE_CURRENT_BINARY_DIR}/tjexampletest)
1691   add_custom_target(tjtest16 COMMAND ${CMAKE_COMMAND} -DWITH_JAVA=${WITH_JAVA}
1692     -DPRECISION=16 -P ${CMAKE_SOURCE_DIR}/cmakescripts/tjbenchtest.cmake
1693     DEPENDS ${CMAKE_SOURCE_DIR}/cmakescripts/tjbenchtest.cmake
1694       ${CMAKE_CURRENT_BINARY_DIR}/tjbenchtest
1695       ${CMAKE_CURRENT_BINARY_DIR}/tjexampletest)
1696 endif()
1697
1698
1699 ###############################################################################
1700 # INSTALLATION
1701 ###############################################################################
1702
1703 set(EXE ${CMAKE_EXECUTABLE_SUFFIX})
1704
1705 if(WITH_TURBOJPEG)
1706   if(ENABLE_SHARED)
1707     install(TARGETS turbojpeg EXPORT ${CMAKE_PROJECT_NAME}Targets
1708       INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
1709       ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
1710       LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
1711       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
1712     install(TARGETS tjbench
1713       RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
1714     if(NOT CMAKE_VERSION VERSION_LESS "3.1" AND MSVC AND
1715       CMAKE_C_LINKER_SUPPORTS_PDB)
1716       install(FILES "$<TARGET_PDB_FILE:turbojpeg>"
1717         DESTINATION ${CMAKE_INSTALL_BINDIR} OPTIONAL)
1718     endif()
1719   endif()
1720   if(ENABLE_STATIC)
1721     install(TARGETS turbojpeg-static EXPORT ${CMAKE_PROJECT_NAME}Targets
1722       INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
1723       ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR})
1724     if(NOT ENABLE_SHARED)
1725       if(GENERATOR_IS_MULTI_CONFIG)
1726         set(DIR "${CMAKE_CURRENT_BINARY_DIR}/\${CMAKE_INSTALL_CONFIG_NAME}")
1727       else()
1728         set(DIR ${CMAKE_CURRENT_BINARY_DIR})
1729       endif()
1730       install(PROGRAMS ${DIR}/tjbench-static${EXE}
1731         DESTINATION ${CMAKE_INSTALL_BINDIR} RENAME tjbench${EXE})
1732     endif()
1733   endif()
1734   install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/turbojpeg.h
1735     DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
1736 endif()
1737
1738 if(ENABLE_STATIC)
1739   install(TARGETS jpeg-static EXPORT ${CMAKE_PROJECT_NAME}Targets
1740     INCLUDES DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
1741     ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR})
1742   if(NOT ENABLE_SHARED)
1743     if(GENERATOR_IS_MULTI_CONFIG)
1744       set(DIR "${CMAKE_CURRENT_BINARY_DIR}/\${CMAKE_INSTALL_CONFIG_NAME}")
1745     else()
1746       set(DIR ${CMAKE_CURRENT_BINARY_DIR})
1747     endif()
1748     install(PROGRAMS ${DIR}/cjpeg-static${EXE}
1749       DESTINATION ${CMAKE_INSTALL_BINDIR} RENAME cjpeg${EXE})
1750     install(PROGRAMS ${DIR}/djpeg-static${EXE}
1751       DESTINATION ${CMAKE_INSTALL_BINDIR} RENAME djpeg${EXE})
1752     install(PROGRAMS ${DIR}/jpegtran-static${EXE}
1753       DESTINATION ${CMAKE_INSTALL_BINDIR} RENAME jpegtran${EXE})
1754   endif()
1755 endif()
1756
1757 install(TARGETS rdjpgcom wrjpgcom RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR})
1758
1759 install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/README.ijg
1760   ${CMAKE_CURRENT_SOURCE_DIR}/README.md ${CMAKE_CURRENT_SOURCE_DIR}/example.c
1761   ${CMAKE_CURRENT_SOURCE_DIR}/tjexample.c
1762   ${CMAKE_CURRENT_SOURCE_DIR}/libjpeg.txt
1763   ${CMAKE_CURRENT_SOURCE_DIR}/structure.txt
1764   ${CMAKE_CURRENT_SOURCE_DIR}/usage.txt ${CMAKE_CURRENT_SOURCE_DIR}/wizard.txt
1765   ${CMAKE_CURRENT_SOURCE_DIR}/LICENSE.md DESTINATION ${CMAKE_INSTALL_DOCDIR})
1766 if(WITH_JAVA)
1767   install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/java/TJExample.java
1768     DESTINATION ${CMAKE_INSTALL_DOCDIR})
1769 endif()
1770
1771 if(UNIX OR MINGW)
1772   install(FILES ${CMAKE_CURRENT_SOURCE_DIR}/cjpeg.1
1773     ${CMAKE_CURRENT_SOURCE_DIR}/djpeg.1 ${CMAKE_CURRENT_SOURCE_DIR}/jpegtran.1
1774     ${CMAKE_CURRENT_SOURCE_DIR}/rdjpgcom.1
1775     ${CMAKE_CURRENT_SOURCE_DIR}/wrjpgcom.1
1776     DESTINATION ${CMAKE_INSTALL_MANDIR}/man1)
1777 endif()
1778 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/pkgscripts/libjpeg.pc
1779   DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
1780 if(WITH_TURBOJPEG)
1781   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/pkgscripts/libturbojpeg.pc
1782     DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig)
1783 endif()
1784 install(FILES
1785   ${CMAKE_CURRENT_BINARY_DIR}/pkgscripts/${CMAKE_PROJECT_NAME}Config.cmake
1786   ${CMAKE_CURRENT_BINARY_DIR}/pkgscripts/${CMAKE_PROJECT_NAME}ConfigVersion.cmake
1787   DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${CMAKE_PROJECT_NAME})
1788 install(EXPORT ${CMAKE_PROJECT_NAME}Targets
1789   NAMESPACE ${CMAKE_PROJECT_NAME}::
1790   DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${CMAKE_PROJECT_NAME})
1791
1792 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/jconfig.h
1793   ${CMAKE_CURRENT_SOURCE_DIR}/jerror.h ${CMAKE_CURRENT_SOURCE_DIR}/jmorecfg.h
1794   ${CMAKE_CURRENT_SOURCE_DIR}/jpeglib.h
1795   DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
1796
1797 include(cmakescripts/BuildPackages.cmake)
1798
1799 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/cmakescripts/cmake_uninstall.cmake.in"
1800   "cmake_uninstall.cmake" IMMEDIATE @ONLY)
1801
1802 add_custom_target(uninstall COMMAND ${CMAKE_COMMAND} -P cmake_uninstall.cmake)