CMakeLists.txt

   1 # Require at least version 2.8.12 of CMake
   2 cmake_minimum_required(VERSION 2.8.12)
   3
   4 if(CMAKE_VERSION VERSION_EQUAL 3.0 OR CMAKE_VERSION VERSION_GREATER 3.0)
   5     cmake_policy(SET CMP0042 NEW)
   6 endif()
   7
   8 # Set the project name
   9 project(CoreCLR)
  10
  11 # Include cmake functions
  12 include(functions.cmake)
  13
  14 # Set commonly used directory names
  15 set(CLR_DIR ${CMAKE_CURRENT_SOURCE_DIR})
  16 set(VM_DIR ${CMAKE_CURRENT_SOURCE_DIR}/src/vm)
  17 set(GENERATED_INCLUDE_DIR ${CMAKE_CURRENT_BINARY_DIR}/src/inc)
  18 set(VERSION_FILE_PATH "${CMAKE_BINARY_DIR}/version.cpp")
  19
  20 set(CORECLR_SET_RPATH ON)
  21 if(CORECLR_SET_RPATH)
  22     # Enable @rpath support for shared libraries.
  23     set(MACOSX_RPATH ON)
  24 endif(CORECLR_SET_RPATH)
  25
  26 OPTION(CMAKE_ENABLE_CODE_COVERAGE "Enable code coverage" OFF)
  27
  28 # Ensure that python is present
  29 find_program(PYTHON python)
  30 if (PYTHON STREQUAL "PYTHON-NOTFOUND")
  31     message(FATAL_ERROR "PYTHON not found: Please install Python 2.7.9 or later from https://www.python.org/downloads/")
  32 endif()
  33
  34 # Ensure other tools are present
  35 if (WIN32)
  36     enable_language(ASM_MASM)
  37
  38     # Ensure that MC is present
  39     find_program(MC mc)
  40     if (MC STREQUAL "MC-NOTFOUND")
  41         message(FATAL_ERROR "MC not found")
  42     endif()
  43
  44     if (CLR_CMAKE_HOST_ARCH STREQUAL arm64)
  45       # CMAKE_CXX_COMPILER will default to the compiler installed with
  46       # Visual studio. Overwrite it to the compiler on the path.
  47       # TODO, remove when cmake generator supports Arm64 as a target.
  48       find_program(PATH_CXX_COMPILER cl)
  49       set(CMAKE_CXX_COMPILER ${PATH_CXX_COMPILER})
  50       message("Overwriting the CMAKE_CXX_COMPILER.")
  51       message(CMAKE_CXX_COMPILER found:${CMAKE_CXX_COMPILER})
  52     endif()
  53
  54 else (WIN32)
  55     enable_language(ASM)
  56
  57     # Ensure that awk is present
  58     find_program(AWK awk)
  59     if (AWK STREQUAL "AWK-NOTFOUND")
  60         message(FATAL_ERROR "AWK not found")
  61     endif()
  62
  63     if (CMAKE_SYSTEM_NAME STREQUAL Darwin)
  64
  65       # Ensure that dsymutil and strip are present
  66       find_program(DSYMUTIL dsymutil)
  67       if (DSYMUTIL STREQUAL "DSYMUTIL-NOTFOUND")
  68           message(FATAL_ERROR "dsymutil not found")
  69       endif()
  70
  71       find_program(STRIP strip)
  72       if (STRIP STREQUAL "STRIP-NOTFOUND")
  73           message(FATAL_ERROR "strip not found")
  74       endif()
  75
  76     else (CMAKE_SYSTEM_NAME STREQUAL Darwin)
  77
  78       # Ensure that objcopy is present
  79       if (DEFINED ENV{CROSSCOMPILE})
  80         if (CMAKE_SYSTEM_PROCESSOR STREQUAL armv7l OR CMAKE_SYSTEM_PROCESSOR STREQUAL aarch64)
  81           find_program(OBJCOPY ${TOOLCHAIN}-objcopy)
  82         else()
  83           clr_unknown_arch()
  84         endif()
  85       else()
  86         find_program(OBJCOPY objcopy)
  87       endif()
  88
  89       if (OBJCOPY STREQUAL "OBJCOPY-NOTFOUND")
  90           message(FATAL_ERROR "objcopy not found")
  91       endif()
  92
  93     endif (CMAKE_SYSTEM_NAME STREQUAL Darwin)
  94 endif(WIN32)
  95
  96 #----------------------------------------
  97 # Detect and set platform variable names
  98 #     - for non-windows build platform & architecture is detected using inbuilt CMAKE variables
  99 #     - for windows we use the passed in parameter to CMAKE to determine build arch
 100 #----------------------------------------
 101 if(CMAKE_SYSTEM_NAME STREQUAL Linux)
 102     set(CLR_CMAKE_PLATFORM_UNIX 1)
 103     # CMAKE_SYSTEM_PROCESSOR returns the value of `uname -p`.
 104     # For the AMD/Intel 64bit architecure two different strings are common.
 105     # Linux and Darwin identify it as "x86_64" while FreeBSD and netbsd uses the
 106     # "amd64" string. Accept either of the two here.
 107     if(CMAKE_SYSTEM_PROCESSOR STREQUAL x86_64 OR CMAKE_SYSTEM_PROCESSOR STREQUAL amd64)
 108         set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 109     elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL armv7l)
 110         set(CLR_CMAKE_PLATFORM_UNIX_ARM 1)
 111     elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL aarch64)
 112         set(CLR_CMAKE_PLATFORM_UNIX_ARM64 1)
 113     else()
 114         clr_unknown_arch()
 115     endif()
 116     set(CLR_CMAKE_PLATFORM_LINUX 1)
 117 endif(CMAKE_SYSTEM_NAME STREQUAL Linux)
 118
 119 if(CMAKE_SYSTEM_NAME STREQUAL Darwin)
 120   set(CLR_CMAKE_PLATFORM_UNIX 1)
 121   set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 122   set(CLR_CMAKE_PLATFORM_DARWIN 1)
 123   if(CMAKE_VERSION VERSION_LESS "3.4.0")
 124     set(CMAKE_ASM_COMPILE_OBJECT "${CMAKE_C_COMPILER} <FLAGS> <DEFINES> -o <OBJECT> -c <SOURCE>")
 125   else()
 126     set(CMAKE_ASM_COMPILE_OBJECT "${CMAKE_C_COMPILER} <FLAGS> <DEFINES> <INCLUDES> -o <OBJECT> -c <SOURCE>")
 127   endif(CMAKE_VERSION VERSION_LESS "3.4.0")
 128 endif(CMAKE_SYSTEM_NAME STREQUAL Darwin)
 129
 130 if(CMAKE_SYSTEM_NAME STREQUAL FreeBSD)
 131   set(CLR_CMAKE_PLATFORM_UNIX 1)
 132   set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 133   set(CLR_CMAKE_PLATFORM_FREEBSD 1)
 134 endif(CMAKE_SYSTEM_NAME STREQUAL FreeBSD)
 135
 136 if(CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
 137   set(CLR_CMAKE_PLATFORM_UNIX 1)
 138   set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 139   set(CLR_CMAKE_PLATFORM_OPENBSD 1)
 140 endif(CMAKE_SYSTEM_NAME STREQUAL OpenBSD)
 141
 142 if(CMAKE_SYSTEM_NAME STREQUAL NetBSD)
 143   set(CLR_CMAKE_PLATFORM_UNIX 1)
 144   set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 145   set(CLR_CMAKE_PLATFORM_NETBSD 1)
 146 endif(CMAKE_SYSTEM_NAME STREQUAL NetBSD)
 147
 148 if(CMAKE_SYSTEM_NAME STREQUAL SunOS)
 149   set(CLR_CMAKE_PLATFORM_UNIX 1)
 150   EXECUTE_PROCESS(
 151     COMMAND isainfo -n
 152     OUTPUT_VARIABLE SUNOS_NATIVE_INSTRUCTION_SET
 153     )
 154   if(SUNOS_NATIVE_INSTRUCTION_SET MATCHES "amd64")
 155     set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 156     set(CMAKE_SYSTEM_PROCESSOR "amd64")
 157   else()
 158     clr_unknown_arch()
 159   endif()
 160   set(CLR_CMAKE_PLATFORM_SUNOS 1)
 161 endif(CMAKE_SYSTEM_NAME STREQUAL SunOS)
 162
 163 #--------------------------------------------
 164 # This repo builds two set of binaries
 165 # 1. binaries which execute on target arch machine
 166 #        - for such binaries host architecture & target architecture are same
 167 #        - eg. coreclr.dll
 168 # 2. binaries which execute on host machine but target another architecture
 169 #        - host architecture is different from target architecture
 170 #        - eg. crossgen.exe - runs on x64 machine and generates nis targeting arm64
 171 #        - for complete list of such binaries refer to file crosscomponents.cmake
 172 #-------------------------------------------------------------
 173 # Set HOST architecture variables
 174 if(CLR_CMAKE_PLATFORM_UNIX_ARM)
 175   set(CLR_CMAKE_PLATFORM_ARCH_ARM 1)
 176   set(CLR_CMAKE_HOST_ARCH "arm")
 177 elseif(CLR_CMAKE_PLATFORM_UNIX_ARM64)
 178   set(CLR_CMAKE_PLATFORM_ARCH_ARM64 1)
 179   set(CLR_CMAKE_HOST_ARCH "arm64")
 180 elseif(CLR_CMAKE_PLATFORM_UNIX_AMD64)
 181   set(CLR_CMAKE_PLATFORM_ARCH_AMD64 1)
 182   set(CLR_CMAKE_HOST_ARCH "x64")
 183 elseif(WIN32)
 184   # CLR_CMAKE_HOST_ARCH is passed in as param to cmake
 185   if (CLR_CMAKE_HOST_ARCH STREQUAL x64)
 186     set(CLR_CMAKE_PLATFORM_ARCH_AMD64 1)
 187   elseif(CLR_CMAKE_HOST_ARCH STREQUAL x86)
 188     set(CLR_CMAKE_PLATFORM_ARCH_I386 1)
 189   elseif(CLR_CMAKE_HOST_ARCH STREQUAL arm64)
 190     set(CLR_CMAKE_PLATFORM_ARCH_ARM64 1)
 191   else()
 192     clr_unknown_arch()
 193   endif()
 194 endif()
 195
 196 # Set TARGET architecture variables
 197 # Target arch will be a cmake param (optional) for both windows as well as non-windows build
 198 # if target arch is not specified then host & target are same
 199 if(NOT DEFINED CLR_CMAKE_TARGET_ARCH OR CLR_CMAKE_TARGET_ARCH STREQUAL "" )
 200   set(CLR_CMAKE_TARGET_ARCH ${CLR_CMAKE_HOST_ARCH})
 201 endif()
 202
 203 # Set target architecture variables
 204 if (CLR_CMAKE_TARGET_ARCH STREQUAL x64)
 205     set(CLR_CMAKE_TARGET_ARCH_AMD64 1)
 206   elseif(CLR_CMAKE_TARGET_ARCH STREQUAL x86)
 207     set(CLR_CMAKE_TARGET_ARCH_I386 1)
 208   elseif(CLR_CMAKE_TARGET_ARCH STREQUAL arm64)
 209     set(CLR_CMAKE_TARGET_ARCH_ARM64 1)
 210   elseif(CLR_CMAKE_TARGET_ARCH STREQUAL arm)
 211     set(CLR_CMAKE_TARGET_ARCH_ARM 1)
 212   else()
 213     clr_unknown_arch()
 214 endif()
 215
 216 # check if host & target arch combination are valid
 217 if(NOT(CLR_CMAKE_TARGET_ARCH STREQUAL CLR_CMAKE_HOST_ARCH))
 218   if(NOT((CLR_CMAKE_PLATFORM_ARCH_AMD64 AND CLR_CMAKE_TARGET_ARCH_ARM64) OR (CLR_CMAKE_PLATFORM_ARCH_I386 AND CLR_CMAKE_TARGET_ARCH_ARM)))
 219     message(FATAL_ERROR "Invalid host and target arch combination")
 220   endif()
 221 endif()
 222
 223 #-----------------------------------------------------
 224 # Initialize Cmake compiler flags and other variables
 225 #-----------------------------------------------------
 226
 227 if (CMAKE_CONFIGURATION_TYPES) # multi-configuration generator?
 228     set(CMAKE_CONFIGURATION_TYPES "Debug;Checked;Release;RelWithDebInfo" CACHE STRING "" FORCE)
 229 endif (CMAKE_CONFIGURATION_TYPES)
 230
 231 set(CMAKE_C_FLAGS_CHECKED ${CLR_C_FLAGS_CHECKED_INIT} CACHE STRING "Flags used by the compiler during checked builds.")
 232 set(CMAKE_CXX_FLAGS_CHECKED ${CLR_CXX_FLAGS_CHECKED_INIT} CACHE STRING "Flags used by the compiler during checked builds.")
 233 set(CMAKE_EXE_LINKER_FLAGS_CHECKED "")
 234 set(CMAKE_SHARED_LINKER_FLAGS_CHECKED "")
 235
 236 # Disable the following line for UNIX altjit on Windows
 237 set(CMAKE_CXX_STANDARD_LIBRARIES "") # do not link against standard win32 libs i.e. kernel32, uuid, user32, etc.
 238
 239 if (WIN32)
 240   # For multi-configuration toolset (as Visual Studio)
 241   # set the different configuration defines.
 242   foreach (Config DEBUG CHECKED RELEASE RELWITHDEBINFO)
 243     foreach (Definition IN LISTS CLR_DEFINES_${Config}_INIT)
 244       set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS $<$<CONFIG:${Config}>:${Definition}>)
 245     endforeach (Definition)
 246   endforeach (Config)
 247
 248   if(NOT CLR_CMAKE_PLATFORM_ARCH_ARM64)
 249     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /guard:cf")
 250     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /guard:cf")
 251   endif (NOT CLR_CMAKE_PLATFORM_ARCH_ARM64)
 252
 253   # Incremental linking with CFG is broken until next VS release.
 254   # This needs to be appended to the last for each build type to override the default flag.
 255   set(NO_INCREMENTAL_LINKER_FLAGS "/INCREMENTAL:NO")
 256
 257   # Linker flags
 258   #
 259   # Disable the following line for UNIX altjit on Windows
 260   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /MANIFEST:NO") #Do not create Side-by-Side Assembly Manifest
 261   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /SUBSYSTEM:WINDOWS,6.00") #windows subsystem
 262   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /LARGEADDRESSAWARE") # can handle addresses larger than 2 gigabytes
 263   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /RELEASE") #sets the checksum in the header
 264   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /NXCOMPAT") #Compatible with Data Execution Prevention
 265   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /DYNAMICBASE") #Use address space layout randomization
 266   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /DEBUGTYPE:cv,fixup") #debugging format
 267   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /PDBCOMPRESS") #shrink pdb size
 268   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /DEBUG")
 269   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /IGNORE:4197,4013,4254,4070,4221")
 270
 271   set(CMAKE_STATIC_LINKER_FLAGS "${CMAKE_STATIC_LINKER_FLAGS} /IGNORE:4221")
 272
 273   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /DEBUG /PDBCOMPRESS")
 274   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /STACK:1572864")
 275
 276   # Debug build specific flags
 277   set(CMAKE_SHARED_LINKER_FLAGS_DEBUG "/NOVCFEATURE ${NO_INCREMENTAL_LINKER_FLAGS}")
 278   set(CMAKE_EXE_LINKER_FLAGS_DEBUG "${NO_INCREMENTAL_LINKER_FLAGS}")
 279
 280   # Checked build specific flags
 281   set(CMAKE_SHARED_LINKER_FLAGS_CHECKED "${CMAKE_SHARED_LINKER_FLAGS_CHECKED} /OPT:REF /OPT:NOICF /NOVCFEATURE ${NO_INCREMENTAL_LINKER_FLAGS}")
 282   set(CMAKE_STATIC_LINKER_FLAGS_CHECKED "${CMAKE_STATIC_LINKER_FLAGS_CHECKED}")
 283   set(CMAKE_EXE_LINKER_FLAGS_CHECKED "${CMAKE_EXE_LINKER_FLAGS_CHECKED} /OPT:REF /OPT:NOICF ${NO_INCREMENTAL_LINKER_FLAGS}")
 284
 285   # Release build specific flags
 286   set(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE} /LTCG /OPT:REF /OPT:ICF ${NO_INCREMENTAL_LINKER_FLAGS}")
 287   set(CMAKE_STATIC_LINKER_FLAGS_RELEASE "${CMAKE_STATIC_LINKER_FLAGS_RELEASE} /LTCG")
 288   set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} /LTCG /OPT:REF /OPT:ICF ${NO_INCREMENTAL_LINKER_FLAGS}")
 289
 290   # ReleaseWithDebugInfo build specific flags
 291   set(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO} /LTCG /OPT:REF /OPT:ICF ${NO_INCREMENTAL_LINKER_FLAGS}")
 292   set(CMAKE_STATIC_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_STATIC_LINKER_FLAGS_RELWITHDEBINFO} /LTCG")
 293   set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO} /LTCG /OPT:REF /OPT:ICF ${NO_INCREMENTAL_LINKER_FLAGS}")
 294
 295   # Temporary until cmake has VS generators for arm64
 296   if(CLR_CMAKE_PLATFORM_ARCH_ARM64)
 297     set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /machine:arm64")
 298     set(CMAKE_STATIC_LINKER_FLAGS "${CMAKE_STATIC_LINKER_FLAGS} /machine:arm64")
 299     set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /machine:arm64")
 300   endif(CLR_CMAKE_PLATFORM_ARCH_ARM64)
 301
 302   # Force uCRT to be dynamically linked for Release build
 303   set(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE} /NODEFAULTLIB:libucrt.lib /DEFAULTLIB:ucrt.lib")
 304   set(CMAKE_EXE_LINKER_FLAGS_RELEASE "${CMAKE_EXE_LINKER_FLAGS_RELEASE} /NODEFAULTLIB:libucrt.lib /DEFAULTLIB:ucrt.lib")
 305   set(CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_SHARED_LINKER_FLAGS_RELWITHDEBINFO} /NODEFAULTLIB:libucrt.lib /DEFAULTLIB:ucrt.lib")
 306   set(CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO "${CMAKE_EXE_LINKER_FLAGS_RELWITHDEBINFO} /NODEFAULTLIB:libucrt.lib /DEFAULTLIB:ucrt.lib")
 307
 308 elseif (CLR_CMAKE_PLATFORM_UNIX)
 309   # Set the values to display when interactively configuring CMAKE_BUILD_TYPE
 310   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "DEBUG;CHECKED;RELEASE;RELWITHDEBINFO")
 311
 312   # Use uppercase CMAKE_BUILD_TYPE for the string comparisons below
 313   string(TOUPPER ${CMAKE_BUILD_TYPE} UPPERCASE_CMAKE_BUILD_TYPE)
 314
 315   # For single-configuration toolset
 316   # set the different configuration defines.
 317   if (UPPERCASE_CMAKE_BUILD_TYPE STREQUAL DEBUG)
 318     # First DEBUG
 319     set_property(DIRECTORY  PROPERTY COMPILE_DEFINITIONS ${CLR_DEFINES_DEBUG_INIT})
 320   elseif (UPPERCASE_CMAKE_BUILD_TYPE STREQUAL CHECKED)
 321     # Then CHECKED
 322     set_property(DIRECTORY PROPERTY COMPILE_DEFINITIONS ${CLR_DEFINES_CHECKED_INIT})
 323   elseif (UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELEASE)
 324     # Then RELEASE
 325     set_property(DIRECTORY PROPERTY COMPILE_DEFINITIONS ${CLR_DEFINES_RELEASE_INIT})
 326   elseif (UPPERCASE_CMAKE_BUILD_TYPE STREQUAL RELWITHDEBINFO)
 327     # And then RELWITHDEBINFO
 328     set_property(DIRECTORY APPEND PROPERTY COMPILE_DEFINITIONS ${CLR_DEFINES_RELWITHDEBINFO_INIT})
 329   else ()
 330     message(FATAL_ERROR "Unknown build type! Set CMAKE_BUILD_TYPE to DEBUG, CHECKED, RELEASE, or RELWITHDEBINFO!")
 331   endif ()
 332
 333   # set the CLANG sanitizer flags for debug build
 334   if(UPPERCASE_CMAKE_BUILD_TYPE STREQUAL DEBUG OR UPPERCASE_CMAKE_BUILD_TYPE STREQUAL CHECKED)
 335     # obtain settings from running enablesanitizers.sh
 336     string(FIND "$ENV{DEBUG_SANITIZERS}" "asan" __ASAN_POS)
 337     string(FIND "$ENV{DEBUG_SANITIZERS}" "ubsan" __UBSAN_POS)
 338     if ((${__ASAN_POS} GREATER -1) OR (${__UBSAN_POS} GREATER -1))
 339       set(CLR_SANITIZE_CXX_FLAGS "${CLR_SANITIZE_CXX_FLAGS} -fsanitize-blacklist=${CMAKE_CURRENT_SOURCE_DIR}/sanitizerblacklist.txt -fsanitize=")
 340       set(CLR_SANITIZE_LINK_FLAGS "${CLR_SANITIZE_LINK_FLAGS} -fsanitize=")
 341       if (${__ASAN_POS} GREATER -1)
 342         set(CLR_SANITIZE_CXX_FLAGS "${CLR_SANITIZE_CXX_FLAGS}address,")
 343         set(CLR_SANITIZE_LINK_FLAGS "${CLR_SANITIZE_LINK_FLAGS}address,")
 344         message("Address Sanitizer (asan) enabled")
 345       endif ()
 346       if (${__UBSAN_POS} GREATER -1)
 347         # all sanitizier flags are enabled except alignment (due to heavy use of __unaligned modifier)
 348         set(CLR_SANITIZE_CXX_FLAGS "${CLR_SANITIZE_CXX_FLAGS}bool,bounds,enum,float-cast-overflow,float-divide-by-zero,function,integer,nonnull-attribute,null,object-size,return,returns-nonnull-attribute,shift,unreachable,vla-bound,vptr")
 349         set(CLR_SANITIZE_LINK_FLAGS "${CLR_SANITIZE_LINK_FLAGS}undefined")
 350         message("Undefined Behavior Sanitizer (ubsan) enabled")
 351       endif ()
 352
 353       # -fdata-sections -ffunction-sections: each function has own section instead of one per .o file (needed for --gc-sections)
 354       # -fPIC: enable Position Independent Code normally just for shared libraries but required when linking with address sanitizer
 355       # -O1: optimization level used instead of -O0 to avoid compile error "invalid operand for inline asm constraint"
 356       set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} ${CLR_SANITIZE_CXX_FLAGS} -fdata-sections -ffunction-sections -fPIC -O1")
 357       set(CMAKE_CXX_FLAGS_CHECKED "${CMAKE_CXX_FLAGS_CHECKED} ${CLR_SANITIZE_CXX_FLAGS} -fdata-sections -ffunction-sections -fPIC -O1")
 358
 359       set(CMAKE_EXE_LINKER_FLAGS_DEBUG "${CMAKE_EXE_LINKER_FLAGS_DEBUG} ${CLR_SANITIZE_LINK_FLAGS}")
 360       set(CMAKE_EXE_LINKER_FLAGS_CHECKED "${CMAKE_EXE_LINKER_FLAGS_CHECKED} ${CLR_SANITIZE_LINK_FLAGS}")
 361
 362       # -Wl and --gc-sections: drop unused sections\functions (similar to Windows /Gy function-level-linking)
 363       set(CMAKE_SHARED_LINKER_FLAGS_DEBUG "${CMAKE_SHARED_LINKER_FLAGS_DEBUG} ${CLR_SANITIZE_LINK_FLAGS} -Wl,--gc-sections")
 364       set(CMAKE_SHARED_LINKER_FLAGS_CHECKED "${CMAKE_SHARED_LINKER_FLAGS_CHECKED} ${CLR_SANITIZE_LINK_FLAGS} -Wl,--gc-sections")
 365     endif ()
 366   endif(UPPERCASE_CMAKE_BUILD_TYPE STREQUAL DEBUG OR UPPERCASE_CMAKE_BUILD_TYPE STREQUAL CHECKED)
 367 endif(WIN32)
 368
 369 if(CLR_CMAKE_PLATFORM_LINUX)
 370   set(CMAKE_ASM_FLAGS "${CMAKE_ASM_FLAGS} -Wa,--noexecstack")
 371   set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--build-id=sha1")
 372   set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,--build-id=sha1")
 373 endif(CLR_CMAKE_PLATFORM_LINUX)
 374
 375 #------------------------------------
 376 # Definitions (for platform)
 377 #-----------------------------------
 378 if (CLR_CMAKE_PLATFORM_ARCH_AMD64)
 379   add_definitions(-D_AMD64_)
 380   add_definitions(-D_WIN64)
 381   add_definitions(-DAMD64)
 382   add_definitions(-DBIT64=1)
 383 elseif (CLR_CMAKE_PLATFORM_ARCH_I386)
 384   add_definitions(-D_X86_)
 385 elseif (CLR_CMAKE_PLATFORM_ARCH_ARM)
 386   add_definitions(-D_ARM_)
 387   add_definitions(-DARM)
 388 elseif (CLR_CMAKE_PLATFORM_ARCH_ARM64)
 389   add_definitions(-D_ARM64_)
 390   add_definitions(-DARM64)
 391   add_definitions(-D_WIN64)
 392   add_definitions(-DBIT64=1)
 393 else ()
 394   clr_unknown_arch()
 395 endif ()
 396
 397 if (CLR_CMAKE_PLATFORM_UNIX)
 398   if(CLR_CMAKE_PLATFORM_LINUX)
 399     if(CLR_CMAKE_PLATFORM_UNIX_AMD64)
 400       message("Detected Linux x86_64")
 401       add_definitions(-DLINUX64)
 402     elseif(CLR_CMAKE_PLATFORM_UNIX_ARM)
 403       message("Detected Linux ARM")
 404       add_definitions(-DLINUX32)
 405     elseif(CLR_CMAKE_PLATFORM_UNIX_ARM64)
 406       message("Detected Linux ARM64")
 407       add_definitions(-DLINUX64)
 408     else()
 409       clr_unknown_arch()
 410     endif()
 411   endif(CLR_CMAKE_PLATFORM_LINUX)
 412 endif(CLR_CMAKE_PLATFORM_UNIX)
 413
 414 if (CLR_CMAKE_PLATFORM_UNIX)
 415   add_definitions(-DPLATFORM_UNIX=1)
 416
 417   if(CLR_CMAKE_PLATFORM_DARWIN)
 418     message("Detected OSX x86_64")
 419   endif(CLR_CMAKE_PLATFORM_DARWIN)
 420
 421   if(CLR_CMAKE_PLATFORM_FREEBSD)
 422     message("Detected FreeBSD amd64")
 423   endif(CLR_CMAKE_PLATFORM_FREEBSD)
 424
 425   if(CLR_CMAKE_PLATFORM_NETBSD)
 426     message("Detected NetBSD amd64")
 427   endif(CLR_CMAKE_PLATFORM_NETBSD)
 428 endif(CLR_CMAKE_PLATFORM_UNIX)
 429
 430 if (WIN32)
 431   # Define the CRT lib references that link into Desktop imports
 432   set(STATIC_MT_CRT_LIB  "libcmt$<$<OR:$<CONFIG:Debug>,$<CONFIG:Checked>>:d>.lib")
 433   set(STATIC_MT_VCRT_LIB  "libvcruntime$<$<OR:$<CONFIG:Debug>,$<CONFIG:Checked>>:d>.lib")
 434   set(STATIC_MT_CPP_LIB  "libcpmt$<$<OR:$<CONFIG:Debug>,$<CONFIG:Checked>>:d>.lib")
 435
 436   # Define the uCRT lib reference
 437   set(STATIC_UCRT_LIB  "libucrt$<$<OR:$<CONFIG:Debug>,$<CONFIG:Checked>>:d>.lib")
 438   set(DYNAMIC_UCRT_LIB  "ucrt$<$<OR:$<CONFIG:Debug>,$<CONFIG:Checked>>:d>.lib")
 439 endif(WIN32)
 440
 441 # Architecture specific files folder name
 442 if (CLR_CMAKE_TARGET_ARCH_AMD64)
 443     set(ARCH_SOURCES_DIR amd64)
 444 elseif (CLR_CMAKE_TARGET_ARCH_ARM64)
 445     set(ARCH_SOURCES_DIR arm64)
 446 elseif (CLR_CMAKE_TARGET_ARCH_ARM)
 447     set(ARCH_SOURCES_DIR arm)
 448 elseif (CLR_CMAKE_TARGET_ARCH_I386)
 449     set(ARCH_SOURCES_DIR i386)
 450 else ()
 451     clr_unknown_arch()
 452 endif ()
 453
 454 # Enable for UNIX altjit on Windows - set(CLR_CMAKE_PLATFORM_UNIX_AMD64 1)
 455 # Enable for UNIX altjit on Windows - add_definitions(-DCLR_CMAKE_PLATFORM_UNIX=1)
 456
 457 #--------------------------------------
 458 # Compile Options
 459 #--------------------------------------
 460 include(compileoptions.cmake)
 461
 462 #----------------------------------------------------
 463 # Cross target Component build specific configuration
 464 #----------------------------------------------------
 465 if(CLR_CROSS_COMPONENTS_BUILD)
 466   include(crosscomponents.cmake)
 467 endif(CLR_CROSS_COMPONENTS_BUILD)
 468
 469 #-----------------------------------------
 470 # Add Projects
 471 #     - project which require platform header not clr's
 472 #     - do not depend on clr's compile definitions
 473 #-----------------------------------------
 474 if(CLR_CMAKE_PLATFORM_UNIX)
 475   add_subdirectory(src/corefx)
 476 endif(CLR_CMAKE_PLATFORM_UNIX)
 477
 478 if(CLR_CMAKE_PLATFORM_UNIX)
 479   add_subdirectory(src/ToolBox/SOS/lldbplugin)
 480   if(NOT DEFINED CLR_CROSS_COMPONENTS_BUILD)
 481     add_subdirectory(src/pal)
 482   endif(NOT DEFINED CLR_CROSS_COMPONENTS_BUILD)
 483   add_subdirectory(src/coreclr/hosts)
 484   add_subdirectory(src/ildasm/unixcoreclrloader)
 485 endif(CLR_CMAKE_PLATFORM_UNIX)
 486
 487 # Add this subdir. We install the headers for the jit.
 488 add_subdirectory(src/pal/prebuilt/inc)
 489
 490 add_subdirectory(src/debug/debug-pal)
 491
 492 if(WIN32)
 493   add_subdirectory(src/gc/sample)
 494 endif()
 495
 496 # Above projects do not build with these compile options
 497 # All of the compiler options are specified in file compileoptions.cmake
 498 # Do not add any new options here. They shoul be added in compileoptions.cmake
 499 if(WIN32)
 500   add_compile_options(/FIWarningControl.h) # force include of WarningControl.h
 501   add_compile_options(/Zl) # omit default library name in .OBJ
 502 endif(WIN32)
 503
 504 #-------------------------------------
 505 # Include directory directives
 506 #-------------------------------------
 507 # Include the basic prebuilt headers - required for getting fileversion resource details.
 508 include_directories("src/pal/prebuilt/inc")
 509 include_directories("bin/obj")
 510
 511 if (CLR_CMAKE_PLATFORM_UNIX)
 512   include_directories("src/pal/inc")
 513   include_directories("src/pal/inc/rt")
 514   include_directories("src/pal/src/safecrt")
 515 endif (CLR_CMAKE_PLATFORM_UNIX)
 516
 517 #--------------------------------
 518 # Definition directives
 519 #  - all clr specific compile definitions should be included in this file
 520 #  - all clr specific feature variable should also be added in this file
 521 #----------------------------------
 522 include(clrdefinitions.cmake)
 523
 524 # Microsoft.Dotnet.BuildTools.Coreclr version
 525 set(BuildToolsVersion "1.0.4-prerelease")
 526 set(BuildToolsDir "${CLR_DIR}/packages/Microsoft.DotNet.BuildTools.CoreCLR/${BuildToolsVersion}")
 527
 528 #------------------------------
 529 # Add Product Directory
 530 #------------------------------
 531 add_subdirectory(src)
 532
 533 #------------------------------
 534 # Add Test Directory
 535 #------------------------------
 536 if(CLR_CMAKE_BUILD_TESTS)
 537   # remove some definitions for test build
 538   remove_definitions(-D_SECURE_SCL=0)
 539   remove_definitions(-DUNICODE)
 540   remove_definitions(-D_UNICODE)
 541
 542   add_subdirectory(tests)
 543 endif(CLR_CMAKE_BUILD_TESTS)
 544
 545 include(definitionsconsistencycheck.cmake)