CMakeLists.txt

   1 PROJECT (libsolv)
   2
   3 CMAKE_MINIMUM_REQUIRED (VERSION 2.4)
   4
   5 OPTION (ENABLE_STATIC "Build a static version of the libraries?" OFF)
   6 OPTION (DISABLE_SHARED "Do not build a shared version of the libraries?" OFF)
   7
   8 OPTION (ENABLE_PERL "Build the perl bindings?" OFF)
   9 OPTION (ENABLE_PYTHON "Build the python bindings?" OFF)
  10 OPTION (ENABLE_RUBY "Build the ruby bindings?" OFF)
  11
  12 OPTION (USE_VENDORDIRS "Install the bindings in vendor directories?" OFF)
  13
  14 OPTION (ENABLE_RPMDB "Build with rpm database support?" OFF)
  15 OPTION (ENABLE_RPMDB_PUBKEY "Build with rpmdb pubkey support?" OFF)
  16 OPTION (ENABLE_RPMDB_BYRPMHEADER "Build with rpmdb Header support?" OFF)
  17 OPTION (ENABLE_RPMMD "Build with rpmmd repository support?" OFF)
  18 OPTION (ENABLE_SUSEREPO "Build with suse repository support?" OFF)
  19 OPTION (ENABLE_COMPS "Build with fedora comps support?" OFF)
  20 OPTION (ENABLE_HELIXREPO "Build with helix repository support?" OFF)
  21 OPTION (ENABLE_DEBIAN "Build with debian database/repository support?" OFF)
  22 OPTION (ENABLE_MDKREPO "Build with mandriva/mageia repository support?" OFF)
  23 OPTION (ENABLE_ARCHREPO "Build with archlinux repository support?" OFF)
  24 OPTION (ENABLE_CUDFREPO "Build with cudf repository support?" OFF)
  25 OPTION (ENABLE_HAIKU "Build with Haiku package support?" OFF)
  26
  27 OPTION (ENABLE_LZMA_COMPRESSION "Build with lzma/xz compression support?" OFF)
  28 OPTION (ENABLE_BZIP2_COMPRESSION "Build with bzip2 compression support?" OFF)
  29
  30 #IF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERISION} GREATER 2.4)
  31 #ENDIF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERISION} GREATER 2.4)
  32
  33 IF (COMMAND cmake_policy)
  34   # escape preprocessor, see -DVERSION below
  35   CMAKE_POLICY (SET CMP0005 OLD)
  36 ENDIF (COMMAND cmake_policy)
  37
  38 # Library
  39 IF (DEFINED LIB)
  40   SET (LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${LIB}")
  41 ELSE (DEFINED  LIB)
  42   IF (CMAKE_SIZEOF_VOID_P MATCHES "8")
  43     SET (LIB_SUFFIX "64")
  44   ENDIF (CMAKE_SIZEOF_VOID_P MATCHES "8")
  45   SET (LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX}")
  46 ENDIF (DEFINED  LIB)
  47 MESSAGE (STATUS "Libraries will be installed in ${LIB_INSTALL_DIR}")
  48 SET (BIN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/bin")
  49
  50 ####################################################################
  51 # CONFIGURATION                                                    #
  52 ####################################################################
  53
  54 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
  55 SET (CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  56 INSTALL( FILES ${CMAKE_MODULE_PATH}/FindLibSolv.cmake DESTINATION ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules )
  57
  58 INCLUDE (${CMAKE_SOURCE_DIR}/VERSION.cmake)
  59
  60 SET (have_system x)
  61
  62 IF (FEDORA)
  63 MESSAGE(STATUS "Building for Fedora")
  64 ADD_DEFINITIONS (-DFEDORA)
  65 SET (ENABLE_RPMDB ON)
  66 SET (ENABLE_RPMMD ON)
  67 SET (have_system ${have_system}x)
  68 ENDIF (FEDORA)
  69
  70 IF (DEBIAN)
  71 MESSAGE (STATUS "Building for Debian")
  72 ADD_DEFINITIONS (-DDEBIAN)
  73 SET (ENABLE_DEBIAN ON)
  74 SET (have_system ${have_system}x)
  75 ENDIF (DEBIAN)
  76
  77 IF (SUSE)
  78 MESSAGE (STATUS "Building for SUSE")
  79 ADD_DEFINITIONS (-DSUSE)
  80 SET (ENABLE_RPMDB ON)
  81 SET (ENABLE_RPMDB_PUBKEY ON)
  82 SET (ENABLE_RPMDB_BYRPMHEADER ON)
  83 SET (ENABLE_RPMMD ON)
  84 SET (ENABLE_SUSEREPO ON)
  85 SET (ENABLE_HELIXREPO ON)
  86 SET (have_system ${have_system}x)
  87 ENDIF (SUSE)
  88
  89 IF (ARCHLINUX)
  90 MESSAGE (STATUS "Building for Archlinux")
  91 ADD_DEFINITIONS (-DARCHLINUX)
  92 SET (ENABLE_ARCHREPO ON)
  93 SET (have_system ${have_system}x)
  94 ENDIF (ARCHLINUX)
  95
  96 IF (MANDRIVA)
  97 MESSAGE (STATUS "Building for Mandriva/Mageia")
  98 ADD_DEFINITIONS (-DMANDRIVA)
  99 SET (ENABLE_MDKREPO ON)
 100 SET (ENABLE_RPMDB ON)
 101 SET (have_system ${have_system}x)
 102 ENDIF (MANDRIVA)
 103
 104 IF (HAIKU)
 105 MESSAGE(STATUS "Building for Haiku")
 106 FIND_LIBRARY(HAIKU_BE_LIBRARY NAMES be)
 107 FIND_LIBRARY(HAIKU_NETWORK_LIBRARY NAMES network)
 108 FIND_LIBRARY(HAIKU_PACKAGE_LIBRARY NAMES package)
 109 SET (HAIKU_SYSTEM_LIBRARIES
 110     ${HAIKU_BE_LIBRARY} ${HAIKU_NETWORK_LIBRARY} ${HAIKU_PACKAGE_LIBRARY})
 111 ADD_DEFINITIONS (-DHAIKU)
 112 SET (ENABLE_HAIKU ON)
 113 SET (have_system ${have_system}x)
 114 ENDIF (HAIKU)
 115
 116 IF (${have_system} STREQUAL x)
 117     MESSAGE (STATUS "Building for no system")
 118     ADD_DEFINITIONS (-DNOSYSTEM)
 119 ENDIF (${have_system} STREQUAL x)
 120 IF (${have_system} STRGREATER xx)
 121     MESSAGE (FATAL_ERROR "Can only compile for one system type.")
 122 ENDIF (${have_system} STRGREATER xx)
 123
 124 IF (ENABLE_ARCHREPO)
 125 SET (ENABLE_LZMA_COMPRESSION ON)
 126 ENDIF (ENABLE_ARCHREPO)
 127
 128 FIND_PACKAGE (EXPAT REQUIRED)
 129 FIND_PACKAGE (ZLIB REQUIRED)
 130 IF (ENABLE_LZMA_COMPRESSION)
 131 FIND_PACKAGE (LZMA REQUIRED)
 132 ENDIF (ENABLE_LZMA_COMPRESSION)
 133 IF (ENABLE_BZIP2_COMPRESSION)
 134 FIND_PACKAGE (BZip2 REQUIRED)
 135 ENDIF (ENABLE_BZIP2_COMPRESSION)
 136
 137 IF (RPM5)
 138 MESSAGE (STATUS "Enabling RPM 5 support")
 139 ADD_DEFINITIONS (-DRPM5)
 140 SET (ENABLE_RPMDB ON)
 141 SET (ENABLE_RPMMD ON)
 142 FIND_PACKAGE (PkgConfig REQUIRED)
 143 PKG_CHECK_MODULES (RPM REQUIRED rpm)
 144 INCLUDE_DIRECTORIES (${RPM_INCLUDE_DIRS})
 145 ENDIF (RPM5)
 146
 147 IF (MULTI_SEMANTICS)
 148 MESSAGE (STATUS "Enabling multi dist support")
 149 ADD_DEFINITIONS (-DMULTI_SEMANTICS)
 150 ENDIF (MULTI_SEMANTICS)
 151
 152 INCLUDE (CheckIncludeFile)
 153 IF (ENABLE_RPMDB)
 154   FIND_LIBRARY (RPMDB_LIBRARY NAMES rpmdb)
 155
 156   IF (NOT RPMDB_LIBRARY)
 157     FIND_LIBRARY (RPMDB_LIBRARY NAMES rpm)
 158   ENDIF (NOT RPMDB_LIBRARY)
 159
 160   FIND_LIBRARY (RPMIO_LIBRARY NAMES rpmio)
 161   IF (RPMIO_LIBRARY)
 162     SET(RPMDB_LIBRARY ${RPMIO_LIBRARY} ${RPMDB_LIBRARY})
 163   ENDIF (RPMIO_LIBRARY)
 164
 165   IF (RPM5)
 166     FIND_LIBRARY (RPMMISC_LIBRARY NAMES rpmmisc)
 167     IF (RPMMISC_LIBRARY)
 168       SET (RPMDB_LIBRARY ${RPMMISC_LIBRARY} ${RPMDB_LIBRARY})
 169     ENDIF (RPMMISC_LIBRARY)
 170   ENDIF (RPM5)
 171
 172   IF (RPM5 OR FEDORA)
 173     FIND_LIBRARY (DB_LIBRARY NAMES db)
 174     IF (DB_LIBRARY)
 175       SET (RPMDB_LIBRARY ${DB_LIBRARY} ${RPMDB_LIBRARY})
 176     ENDIF (DB_LIBRARY)
 177   ENDIF (RPM5 OR FEDORA)
 178   CHECK_INCLUDE_FILE(rpm/db.h HAVE_RPM_DB_H)
 179   INCLUDE (CheckLibraryExists)
 180   CHECK_LIBRARY_EXISTS(rpmio pgpDigGetParams "" HAVE_PGPDIGGETPARAMS)
 181 ENDIF (ENABLE_RPMDB)
 182
 183 INCLUDE (CheckFunctionExists)
 184 INCLUDE (TestBigEndian)
 185
 186 CHECK_FUNCTION_EXISTS (strchrnul HAVE_STRCHRNUL)
 187 CHECK_FUNCTION_EXISTS (fopencookie HAVE_FOPENCOOKIE)
 188 CHECK_FUNCTION_EXISTS (funopen HAVE_FUNOPEN)
 189 TEST_BIG_ENDIAN (WORDS_BIGENDIAN)
 190
 191 # should create config.h with #cmakedefine instead...
 192 FOREACH (VAR HAVE_STRCHRNUL HAVE_FOPENCOOKIE HAVE_FUNOPEN WORDS_BIGENDIAN
 193   HAVE_RPM_DB_H HAVE_PGPDIGGETPARAMS
 194   ENABLE_RPMDB ENABLE_RPMDB_PUBKEY ENABLE_RPMMD ENABLE_SUSEREPO ENABLE_COMPS
 195   ENABLE_HELIXREPO ENABLE_MDKREPO ENABLE_ARCHREPO ENABLE_DEBIAN ENABLE_HAIKU
 196   ENABLE_LZMA_COMPRESSION ENABLE_BZIP2_COMPRESSION)
 197   IF(${VAR})
 198     ADD_DEFINITIONS (-D${VAR}=1)
 199     SET (SWIG_FLAGS ${SWIG_FLAGS} -D${VAR})
 200   ENDIF (${VAR})
 201 ENDFOREACH (VAR)
 202
 203 SET (PACKAGE "libsolv")
 204 SET (VERSION "${LIBSOLV_MAJOR}.${LIBSOLV_MINOR}.${LIBSOLV_PATCH}")
 205
 206 ADD_DEFINITIONS (-D_FILE_OFFSET_BITS=64)
 207 ADD_DEFINITIONS (-DVERSION=\\\"${VERSION}\\\")
 208 CONFIGURE_FILE (src/solvversion.h.in src/solvversion.h)
 209
 210 SET (CPACK_PACKAGE_DESCRIPTION_SUMMARY "Package dependency solver library")
 211 SET (CPACK_PACKAGE_VENDOR "SUSE")
 212 SET (CPACK_PACKAGE_VERSION_MAJOR ${LIBSOLV_MAJOR})
 213 SET (CPACK_PACKAGE_VERSION_MINOR ${LIBSOLV_MINOR})
 214 SET (CPACK_PACKAGE_VERSION_PATCH ${LIBSOLV_PATCH})
 215 SET (CPACK_GENERATOR "TBZ2")
 216 SET (CPACK_SOURCE_GENERATOR "TBZ2")
 217 SET (CPACK_SOURCE_PACKAGE_FILE_NAME "${PACKAGE}-${VERSION}")
 218 SET (CPACK_SOURCE_TOPLEVEL_TAG "Linux-Source:")
 219 SET (CPACK_TOPLEVEL_TAG "Linux-Source:")
 220
 221 # The following components are regex's to match anywhere (unless anchored)
 222 # in absolute path + filename to find files or directories to be excluded
 223 # from source tarball.
 224 SET (CPACK_SOURCE_IGNORE_FILES
 225 # temporary files
 226 "\\\\.swp$"
 227 # backup files
 228 "~$"
 229 # eclipse files
 230 "\\\\.cdtproject$"
 231 "\\\\.cproject$"
 232 "\\\\.project$"
 233 "\\\\.settings/"
 234 # others
 235 "\\\\.#"
 236 "/#"
 237 "/build/"
 238 "/_build/"
 239 "/\\\\.git/"
 240 # used before
 241 "/\\\\.libs/"
 242 "/\\\\.deps/"
 243 "\\\\.o$"
 244 "\\\\.lo$"
 245 "\\\\.la$"
 246 "Makefile$"
 247 "Makefile\\\\.in$"
 248 # cmake cache files
 249 "DartConfiguration.tcl$"
 250 "CMakeCache.txt"
 251 "CMakeFiles"
 252 "cmake_install.cmake$"
 253 "CMakeLists.txt.auto$"
 254 "CTestTestfile.cmake"
 255 "CPackConfig.cmake$"
 256 "CPackSourceConfig.cmake$"
 257 "libsolv.spec$"
 258 )
 259
 260 INCLUDE(CPack)
 261
 262 ####################################################################
 263 # INCLUDES                                                         #
 264 ####################################################################
 265
 266 #SET (CMAKE_INCLUDE_DIRECTORIES_BEFORE ON)
 267 INCLUDE_DIRECTORIES (${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_SOURCE_DIR} ${CMAKE_SOURCE_DIR}/src ${CMAKE_SOURCE_DIR}/ext ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_BINARY_DIR}/src SYSTEM )
 268
 269 ####################################################################
 270
 271 MESSAGE (STATUS "Looking for modules in ${CMAKE_MODULE_PATH}")
 272
 273 set (CMAKE_C_FLAGS     "${CMAKE_C_FLAGS} -Wall")
 274 set (CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS} -O3")
 275 set (CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS} -g -O3")
 276 set (CMAKE_C_FLAGS_DEBUG     "${CMAKE_C_FLAGS} -g3 -O0")
 277
 278 SET (SYSTEM_LIBRARIES "-Wl,--as-needed" ${EXPAT_LIBRARY} ${ZLIB_LIBRARY})
 279 IF (ENABLE_LZMA_COMPRESSION)
 280 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${LZMA_LIBRARY})
 281 ENDIF (ENABLE_LZMA_COMPRESSION)
 282 IF (ENABLE_BZIP2_COMPRESSION)
 283 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${BZIP2_LIBRARIES})
 284 ENDIF (ENABLE_BZIP2_COMPRESSION)
 285 IF (ENABLE_RPMDB)
 286 SET (SYSTEM_LIBRARIES ${RPMDB_LIBRARY} ${SYSTEM_LIBRARIES})
 287 ENDIF (ENABLE_RPMDB)
 288 IF (ENABLE_HAIKU)
 289 SET (SYSTEM_LIBRARIES ${HAIKU_SYSTEM_LIBRARIES} ${SYSTEM_LIBRARIES})
 290 ENDIF (ENABLE_HAIKU)
 291
 292 ADD_SUBDIRECTORY (src)
 293 ADD_SUBDIRECTORY (ext)
 294 ADD_SUBDIRECTORY (tools)
 295 IF (ENABLE_PERL OR ENABLE_PYTHON OR ENABLE_RUBY)
 296     ADD_SUBDIRECTORY (bindings)
 297 ENDIF (ENABLE_PERL OR ENABLE_PYTHON OR ENABLE_RUBY)
 298 ADD_SUBDIRECTORY (examples)
 299
 300 MESSAGE (STATUS "Version: ${VERSION}")
 301
 302 ####################################################################
 303 # RPM SPEC                                                         #
 304 ####################################################################
 305
 306 MACRO (SPECFILE)
 307   MESSAGE (STATUS "Writing spec file...")
 308   CONFIGURE_FILE (${CMAKE_SOURCE_DIR}/package/libsolv.spec.in ${CMAKE_BINARY_DIR}/package/libsolv.spec @ONLY)
 309 ENDMACRO (SPECFILE)
 310
 311 SPECFILE ()
 312
 313 SET (AUTOBUILD_COMMAND
 314   COMMAND ${CMAKE_COMMAND} -E remove ${CMAKE_BINARY_DIR}/package/*.tar.bz2
 315   COMMAND mkdir -p _CPack_Packages/${CPACK_TOPLEVEL_TAG}
 316   COMMAND ${CMAKE_MAKE_PROGRAM} package_source
 317   COMMAND ${CMAKE_COMMAND} -E copy ${CPACK_SOURCE_PACKAGE_FILE_NAME}.tar.bz2 ${CMAKE_BINARY_DIR}/package
 318   COMMAND ${CMAKE_COMMAND} -E remove ${CPACK_SOURCE_PACKAGE_FILE_NAME}.tar.bz2
 319   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_SOURCE_DIR}/package/libsolv.changes" "${CMAKE_BINARY_DIR}/package/libsolv.changes"
 320 )
 321
 322 ADD_CUSTOM_TARGET (srcpackage
 323   ${AUTOBUILD_COMMAND}
 324 )
 325
 326 ADD_CUSTOM_TARGET (srcpackage_local
 327   ${AUTOBUILD_COMMAND}
 328 )
 329
 330 ENABLE_TESTING()
 331 ADD_SUBDIRECTORY (test)