CMakeLists.txt

   1 # dEQP cmake file
   2
   3 # Module FindGit requires cmake >= 2.8.2
   4 cmake_minimum_required(VERSION 2.8.2)
   5
   6 find_package(Git)
   7 find_package(PythonInterp 2)
   8
   9 # dEQP Target.
  10 set(DEQP_TARGET "default" CACHE STRING "dEQP Target (default, android...)")
  11
  12 if (DEFINED DEQP_TARGET_TOOLCHAIN)
  13         # \note Toolchain must be included before project() command
  14         include(targets/${DEQP_TARGET}/${DEQP_TARGET_TOOLCHAIN}.cmake NO_POLICY_SCOPE)
  15 endif ()
  16
  17 project(dEQP-Core-${DEQP_TARGET})
  18
  19 include(framework/delibs/cmake/Defs.cmake NO_POLICY_SCOPE)
  20 include(framework/delibs/cmake/CFlags.cmake)
  21
  22 add_definitions(-DDE_ASSERT_FAILURE_CALLBACK)
  23
  24 # dEQP-specific configuration. Target file should override these.
  25 set(DEQP_TARGET_NAME            "UNKNOWN")              # Target name
  26
  27 set(DEQP_GLES2_LIBRARIES        )                               # GLESv2 libraries. If empty, run-time linking is used
  28 set(DEQP_GLES3_LIBRARIES        )                               # GLESv3 libraries. If empty, run-time linking is used
  29 set(DEQP_EGL_LIBRARIES          )                               # EGL libraries
  30
  31 # Legacy APIs that don't use run-time loading
  32 set(DEQP_SUPPORT_GLES1          OFF)                    # Is GLESv1 supported
  33 set(DEQP_GLES1_LIBRARIES        )                               # GLESv1 libraries
  34 set(DEQP_SUPPORT_VG                     OFF)                    # Is OpenVG supported
  35 set(DEQP_VG_LIBRARIES           )                               # VG libraries
  36
  37 set(DEQP_SUPPORT_WGL            OFF)
  38 set(DEQP_SUPPORT_GLX            OFF)                    # Is GLX supported \todo [2016-10-12 pyry] X11 specific - move to framework/platform/
  39
  40 set(DEQP_PLATFORM_LIBRARIES     )                               # Other platform libraries
  41
  42 set(DEQP_PLATFORM_COPY_LIBRARIES        )               # Libraries / binaries that need to be copied to binary directory
  43
  44 # Delibs include directories
  45 include_directories(
  46         framework/delibs/debase
  47         framework/delibs/decpp
  48         framework/delibs/depool
  49         framework/delibs/dethread
  50         framework/delibs/deutil
  51         framework/delibs/destream
  52         )
  53
  54 # Include target-specific definitions
  55 include(targets/${DEQP_TARGET}/${DEQP_TARGET}.cmake)
  56
  57 # zlib
  58 find_path(ZLIB_INCLUDE_PATH     zlib.h)
  59 find_library(ZLIB_LIBRARY       z)
  60
  61 if (NOT ZLIB_INCLUDE_PATH OR NOT ZLIB_LIBRARY)
  62         message(STATUS "System version of zlib not found, using external/zlib")
  63         add_subdirectory(external/zlib)
  64         # \note ZLIB_LIBRARY and ZLIB_INCLUDE_PATH are promoted from external/zlib/CMakeLists.txt
  65 endif ()
  66
  67 include_directories(${ZLIB_INCLUDE_PATH})
  68
  69 # libpng
  70 #
  71 # The FindPNG module defines PNG_INCLUDE_DIRS and PNG_LIBRARIES. But dEQP's
  72 # CMake files expect the non-standard PNG_INCLUDE_PATH and PNG_LIBRARY. Set the
  73 # non-standard variables here to retain compatibility with dEQP's existing
  74 # CMake files.
  75 include(FindPNG)
  76 set(PNG_INCLUDE_PATH ${PNG_INCLUDE_DIRS})
  77 set(PNG_LIBRARY ${PNG_LIBRARIES})
  78
  79 if (NOT PNG_INCLUDE_PATH OR NOT PNG_LIBRARY)
  80         message(STATUS "System version of libpng not found, using external/libpng")
  81         add_subdirectory(external/libpng)
  82         # \note PNG_LIBRARY and PNG_INCLUDE_PATH are promoted from external/libpng/CMakeLists.txt
  83 endif ()
  84
  85 # glslang
  86 add_subdirectory(external/glslang)
  87
  88 # spirv-tools
  89 add_subdirectory(external/spirv-tools)
  90
  91 include_directories(${PNG_INCLUDE_PATH})
  92
  93 message(STATUS "DEQP_TARGET_NAME        = ${DEQP_TARGET_NAME}")
  94 message(STATUS "DEQP_SUPPORT_GLES1      = ${DEQP_SUPPORT_GLES1}")
  95 message(STATUS "DEQP_GLES1_LIBRARIES    = ${DEQP_GLES1_LIBRARIES}")
  96 message(STATUS "DEQP_GLES2_LIBRARIES    = ${DEQP_GLES2_LIBRARIES}")
  97 message(STATUS "DEQP_GLES3_LIBRARIES    = ${DEQP_GLES3_LIBRARIES}")
  98 message(STATUS "DEQP_GLES31_LIBRARIES   = ${DEQP_GLES31_LIBRARIES}")
  99 message(STATUS "DEQP_GLES32_LIBRARIES   = ${DEQP_GLES32_LIBRARIES}")
 100 message(STATUS "DEQP_SUPPORT_VG         = ${DEQP_SUPPORT_VG}")
 101 message(STATUS "DEQP_VG_LIBRARIES       = ${DEQP_VG_LIBRARIES}")
 102 message(STATUS "DEQP_EGL_LIBRARIES      = ${DEQP_EGL_LIBRARIES}")
 103 message(STATUS "DEQP_PLATFORM_LIBRARIES = ${DEQP_PLATFORM_LIBRARIES}")
 104
 105 # Defines
 106 add_definitions(-DDEQP_TARGET_NAME="${DEQP_TARGET_NAME}")
 107
 108 # Entry points loaded directly by linking to libGL*?
 109 if (DEFINED DEQP_GLES2_LIBRARIES)
 110         add_definitions(-DDEQP_GLES2_DIRECT_LINK=1)
 111 endif ()
 112
 113 if (DEFINED DEQP_GLES3_LIBRARIES)
 114         add_definitions(-DDEQP_GLES3_DIRECT_LINK=1)
 115 endif ()
 116
 117 if (DEFINED DEQP_GLES31_LIBRARIES)
 118         add_definitions(-DDEQP_GLES31_DIRECT_LINK=1)
 119 endif ()
 120
 121 if (DEFINED DEQP_GLES32_LIBRARIES)
 122         add_definitions(-DDEQP_GLES32_DIRECT_LINK=1)
 123 endif ()
 124
 125 if (DEFINED DEQP_EGL_LIBRARIES)
 126         add_definitions(-DDEQP_EGL_DIRECT_LINK=1)
 127 endif ()
 128
 129 # Legacy APIs that don't support run-time loading
 130 if (DEQP_SUPPORT_GLES1)
 131         add_definitions(-DDEQP_SUPPORT_GLES1=1)
 132
 133         if (NOT DEFINED DEQP_GLES1_LIBRARIES)
 134                 message(FATAL_ERROR "Run-time loading of GLES1 is not supported (DEQP_GLES1_LIBRARIES is not set)")
 135         endif ()
 136 endif ()
 137
 138 if (DEQP_SUPPORT_VG)
 139         add_definitions(-DDEQP_SUPPORT_VG=1)
 140
 141         if (NOT DEFINED DEQP_VG_LIBRARIES)
 142                 message(FATAL_ERROR "Run-time loading of VG is not supported (DEQP_VG_LIBRARIES is not set)")
 143         endif ()
 144 endif ()
 145
 146 if (DE_COMPILER_IS_MSC)
 147         # Don't nag about std::copy for example
 148         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -D_SCL_SECURE_NO_WARNINGS")
 149 endif ()
 150
 151 # delibs projects
 152 add_subdirectory(framework/delibs/debase)
 153 add_subdirectory(framework/delibs/depool)
 154 add_subdirectory(framework/delibs/dethread)
 155 add_subdirectory(framework/delibs/destream)
 156 add_subdirectory(framework/delibs/deutil)
 157 add_subdirectory(framework/delibs/decpp)
 158
 159 # ExecServer
 160 add_subdirectory(execserver)
 161
 162 # Executor framework and tools
 163 if (IS_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/executor)
 164         add_subdirectory(executor)
 165 endif ()
 166
 167 # Test framework include directories
 168 include_directories(
 169         framework/common
 170         framework/qphelper
 171         framework/opengl
 172         framework/opengl/wrapper
 173         framework/referencerenderer
 174         framework/opengl/simplereference
 175         framework/randomshaders
 176         framework/egl
 177         framework/egl/wrapper
 178         external/vulkancts/framework/vulkan
 179         )
 180
 181 if (DE_OS_IS_ANDROID OR DE_OS_IS_IOS)
 182         # On Android deqp modules are compiled as libraries and linked into final .so
 183         set(DEQP_MODULE_LIBRARIES )
 184         set(DEQP_MODULE_ENTRY_POINTS )
 185 endif ()
 186
 187 # Macro for adding targets for copying binaries (usually target libraries) to the target destination dir
 188 macro (target_copy_files target dep_name files)
 189         if (NOT "${files}" STREQUAL "")
 190                 set(COPY_TARGETS )
 191                 foreach (SRCNAME ${files})
 192                         get_filename_component(BASENAME ${SRCNAME} NAME)
 193                         set(DSTNAME "${CMAKE_CURRENT_BINARY_DIR}/${BASENAME}")
 194                         add_custom_command(OUTPUT ${DSTNAME}
 195                                                            COMMAND ${CMAKE_COMMAND} -E copy_if_different ${SRCNAME} ${DSTNAME})
 196                         set(COPY_TARGETS ${COPY_TARGETS} ${DSTNAME})
 197                 endforeach ()
 198
 199                 add_custom_target(${dep_name} ALL DEPENDS ${COPY_TARGETS})
 200                 add_dependencies(${target} ${dep_name})
 201         endif ()
 202 endmacro (target_copy_files)
 203
 204 set(MODULE_LIB_TARGET_POSTFIX   "-package")
 205 set(MODULE_DATA_TARGET_POSTFIX  "-data")
 206
 207 # Macro for adding dEQP module
 208 # This adds 3 targets:
 209 #       ${MODULE_NAME}-package:         Static library that contains all SRCS and links to LIBS
 210 #       ${MODULE_NAME}-data:            Custom target that is used for data file copies
 211 #       ${MODULE_NAME}:                         Executable binary (if supported by the platform)
 212 macro (add_deqp_module MODULE_NAME SRCS LIBS ENTRY)
 213
 214         # Library target
 215         add_library("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" STATIC ${SRCS})
 216         target_link_libraries("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" ${LIBS})
 217
 218         set(DEQP_MODULE_LIBRARIES               ${DEQP_MODULE_LIBRARIES} "${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}")
 219         set(DEQP_MODULE_ENTRY_POINTS    ${DEQP_MODULE_ENTRY_POINTS} "${CMAKE_CURRENT_SOURCE_DIR}/${ENTRY}")
 220
 221         # Forward to parent scope
 222         set(DEQP_MODULE_LIBRARIES               ${DEQP_MODULE_LIBRARIES} PARENT_SCOPE)
 223         set(DEQP_MODULE_ENTRY_POINTS    ${DEQP_MODULE_ENTRY_POINTS} PARENT_SCOPE)
 224
 225         if (NOT DE_OS_IS_ANDROID AND NOT DE_OS_IS_IOS)
 226                 # Executable target
 227                 add_executable(${MODULE_NAME} ${PROJECT_SOURCE_DIR}/framework/platform/tcuMain.cpp ${ENTRY})
 228                 target_link_libraries(${MODULE_NAME} tcutil-platform "${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}")
 229                 target_copy_files(${MODULE_NAME} platform-libs-${MODULE_NAME} "${DEQP_PLATFORM_COPY_LIBRARIES}")
 230         endif ()
 231
 232         # Data file target
 233         add_custom_target("${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}")
 234         add_dependencies("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}")
 235 endmacro (add_deqp_module)
 236
 237 # Macro for adding data dirs to module
 238 macro (add_data_dir MODULE_NAME SRC_DIR DST_DIR)
 239         if (DE_OS_IS_WIN32 OR DE_OS_IS_UNIX OR DE_OS_IS_OSX OR DE_OS_IS_QNX)
 240                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_CURRENT_BINARY_DIR}/${DST_DIR})
 241
 242         elseif (DE_OS_IS_ANDROID)
 243                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_BINARY_DIR}/assets/${DST_DIR})
 244
 245         elseif (DE_OS_IS_IOS)
 246                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_BINARY_DIR}/\${CONFIGURATION}\${EFFECTIVE_PLATFORM_NAME}/deqp.app/${DST_DIR})
 247         endif ()
 248 endmacro (add_data_dir)
 249
 250 # Macro for adding individual data files to module
 251 macro (add_data_file MODULE_NAME SRC_FILE DST_FILE)
 252         if (DE_OS_IS_WIN32 OR DE_OS_IS_UNIX OR DE_OS_IS_OSX OR DE_OS_IS_QNX)
 253                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_CURRENT_BINARY_DIR}/${DST_FILE})
 254
 255         elseif (DE_OS_IS_ANDROID)
 256                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_BINARY_DIR}/assets/${DST_FILE})
 257
 258         elseif (DE_OS_IS_IOS)
 259                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_BINARY_DIR}/\${CONFIGURATION}\${EFFECTIVE_PLATFORM_NAME}/deqp.app/${DST_FILE})
 260         endif ()
 261 endmacro (add_data_file)
 262
 263 add_subdirectory(framework)
 264 add_subdirectory(external/vulkancts/framework/vulkan)
 265
 266 if (DE_COMPILER_IS_MSC)
 267         add_compile_options(/bigobj) # Required by glsBuiltinPrecisionTests.cpp
 268 endif ()
 269
 270 add_subdirectory(modules)
 271 add_subdirectory(external/vulkancts/modules/vulkan)
 272 add_subdirectory(external/openglcts)
 273
 274 # Single-binary targets
 275 if (DE_OS_IS_ANDROID)
 276         include_directories(executor)
 277
 278         set(DEQP_SRCS
 279                 framework/platform/android/tcuAndroidMain.cpp
 280                 framework/platform/android/tcuAndroidJNI.cpp
 281                 framework/platform/android/tcuAndroidPlatformCapabilityQueryJNI.cpp
 282                 framework/platform/android/tcuTestLogParserJNI.cpp
 283                 ${DEQP_MODULE_ENTRY_POINTS}
 284                 )
 285
 286         set(DEQP_LIBS
 287                 tcutil-platform
 288                 xecore
 289                 ${DEQP_MODULE_LIBRARIES}
 290                 )
 291
 292         add_library(deqp SHARED ${DEQP_SRCS})
 293         target_link_libraries(deqp ${DEQP_LIBS})
 294
 295         # Needed by OpenGL CTS that defines its own activity but depends on
 296         # common Android support code.
 297         target_include_directories(deqp PRIVATE framework/platform/android)
 298
 299 elseif (DE_OS_IS_IOS)
 300         # Code sign identity
 301         set(DEQP_IOS_CODE_SIGN_IDENTITY "drawElements" CACHE STRING "Code sign identity for iOS build")
 302
 303         set(MACOSX_BUNDLE_PRODUCT_NAME "\${PRODUCT_NAME}")
 304         set(MACOSX_BUNDLE_GUI_IDENTIFIER "com.drawelements.\${PRODUCT_NAME:identifier}")
 305
 306         include_directories(framework/platform/ios)
 307         set(TESTERCORE_SRC_FILES
 308                 framework/platform/ios/tcuEAGLView.h
 309                 framework/platform/ios/tcuEAGLView.m
 310                 framework/platform/ios/tcuIOSAppDelegate.h
 311                 framework/platform/ios/tcuIOSAppDelegate.m
 312                 framework/platform/ios/tcuIOSViewController.h
 313                 framework/platform/ios/tcuIOSViewController.m
 314                 framework/platform/ios/tcuIOSMain.m
 315                 )
 316         set_source_files_properties(${TESTERCORE_SRC_FILES} COMPILE_FLAGS "-std=c99")
 317
 318         add_executable(deqp MACOSX_BUNDLE ${TESTERCORE_SRC_FILES} ${DEQP_MODULE_ENTRY_POINTS})
 319         target_link_libraries(deqp tcutil-platform xscore ${DEQP_MODULE_LIBRARIES})
 320         set_target_properties(deqp PROPERTIES XCODE_ATTRIBUTE_TARGETED_DEVICE_FAMILY "1,2")
 321         set_target_properties(deqp PROPERTIES XCODE_ATTRIBUTE_CODE_SIGN_IDENTITY "iPhone Developer: ${DEQP_IOS_CODE_SIGN_IDENTITY}")
 322 endif ()