CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 # ----------------------------------------------------------------------------
   8
   9 include(cmake/OpenCVMinDepVersions.cmake)
  10
  11 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  12   cmake_minimum_required(VERSION 2.8.8 FATAL_ERROR)
  13 else()
  14   cmake_minimum_required(VERSION "${MIN_VER_CMAKE}" FATAL_ERROR)
  15 endif()
  16
  17 # Following block can broke build in case of cross-compilng
  18 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  19 # so we will try to detect crosscompiling by presense of CMAKE_TOOLCHAIN_FILE
  20 if(NOT CMAKE_TOOLCHAIN_FILE)
  21   # it _must_ go before project(OpenCV) in order to work
  22   if(WIN32)
  23     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  24   else()
  25     set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  26   endif()
  27 else(NOT CMAKE_TOOLCHAIN_FILE)
  28   #Android: set output folder to ${CMAKE_BINARY_DIR}
  29   set( LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  30   # any crosscompiling
  31   set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  32 endif(NOT CMAKE_TOOLCHAIN_FILE)
  33
  34
  35 if(POLICY CMP0022)
  36   cmake_policy(SET CMP0022 OLD)
  37 endif()
  38
  39 # must go before the project command
  40 set(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  41 if(DEFINED CMAKE_BUILD_TYPE)
  42   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
  43 endif()
  44
  45 project(OpenCV CXX C)
  46
  47 if(MSVC)
  48   set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
  49 endif()
  50
  51 include(cmake/OpenCVUtils.cmake)
  52
  53 ocv_clear_vars(OpenCVModules_TARGETS)
  54
  55 # ----------------------------------------------------------------------------
  56 # Break in case of popular CMake configuration mistakes
  57 # ----------------------------------------------------------------------------
  58 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
  59   message(FATAL_ERROR "CMake fails to deterimine the bitness of target platform.
  60   Please check your CMake and compiler installation. If you are crosscompiling then ensure that your CMake toolchain file correctly sets the compiler details.")
  61 endif()
  62
  63 # ----------------------------------------------------------------------------
  64 # Detect compiler and target platform architecture
  65 # ----------------------------------------------------------------------------
  66 include(cmake/OpenCVDetectCXXCompiler.cmake)
  67
  68 # Add these standard paths to the search paths for FIND_LIBRARY
  69 # to find libraries from these locations first
  70 if(UNIX AND NOT ANDROID)
  71   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
  72     if(EXISTS /lib64)
  73       list(APPEND CMAKE_LIBRARY_PATH /lib64)
  74     else()
  75       list(APPEND CMAKE_LIBRARY_PATH /lib)
  76     endif()
  77     if(EXISTS /usr/lib64)
  78       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
  79     else()
  80       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
  81     endif()
  82   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
  83     if(EXISTS /lib32)
  84       list(APPEND CMAKE_LIBRARY_PATH /lib32)
  85     else()
  86       list(APPEND CMAKE_LIBRARY_PATH /lib)
  87     endif()
  88     if(EXISTS /usr/lib32)
  89       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
  90     else()
  91       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
  92     endif()
  93   endif()
  94 endif()
  95
  96 # Add these standard paths to the search paths for FIND_PATH
  97 # to find include files from these locations first
  98 if(MINGW)
  99   if(EXISTS /mingw)
 100       list(APPEND CMAKE_INCLUDE_PATH /mingw)
 101   endif()
 102   if(EXISTS /mingw32)
 103       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
 104   endif()
 105   if(EXISTS /mingw64)
 106       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 107   endif()
 108 endif()
 109
 110 # ----------------------------------------------------------------------------
 111 # OpenCV cmake options
 112 # ----------------------------------------------------------------------------
 113
 114 # Optional 3rd party components
 115 # ===================================================
 116 OCV_OPTION(WITH_1394           "Include IEEE1394 support"                    ON   IF (NOT ANDROID AND NOT IOS) )
 117 OCV_OPTION(WITH_AVFOUNDATION   "Use AVFoundation for Video I/O"              ON   IF IOS)
 118 OCV_OPTION(WITH_CARBON         "Use Carbon for UI instead of Cocoa"          OFF  IF APPLE )
 119 OCV_OPTION(WITH_VTK            "Include VTK library support (and build opencv_viz module eiher)"             OFF IF (NOT ANDROID AND NOT IOS) )
 120 OCV_OPTION(WITH_CUDA           "Include NVidia Cuda Runtime support"                                         ON  IF (NOT IOS) )
 121 OCV_OPTION(WITH_CUFFT          "Include NVidia Cuda Fast Fourier Transform (FFT) library support"            ON  IF (NOT IOS) )
 122 OCV_OPTION(WITH_CUBLAS         "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" OFF IF (NOT IOS) )
 123 OCV_OPTION(WITH_NVCUVID        "Include NVidia Video Decoding library support"                               OFF IF (NOT IOS AND NOT APPLE) )
 124 OCV_OPTION(WITH_EIGEN          "Include Eigen2/Eigen3 support"               ON)
 125 OCV_OPTION(WITH_VFW            "Include Video for Windows support"           ON   IF WIN32 )
 126 OCV_OPTION(WITH_FFMPEG         "Include FFMPEG support"                      ON   IF (NOT ANDROID AND NOT IOS))
 127 OCV_OPTION(WITH_GSTREAMER      "Include Gstreamer support"                   ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 128 OCV_OPTION(WITH_GSTREAMER_0_10 "Enable Gstreamer 0.10 support (instead of 1.x)"                              OFF )
 129 OCV_OPTION(WITH_GTK            "Include GTK support"                         ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 130 OCV_OPTION(WITH_IPP            "Include Intel IPP support"                   OFF  IF (MSVC OR X86 OR X86_64) )
 131 OCV_OPTION(WITH_JASPER         "Include JPEG2K support"                      ON   IF (NOT IOS) )
 132 OCV_OPTION(WITH_JPEG           "Include JPEG support"                        ON)
 133 OCV_OPTION(WITH_WEBP           "Include WebP support"                        ON   IF (NOT IOS) )
 134 OCV_OPTION(WITH_OPENEXR        "Include ILM support via OpenEXR"             ON   IF (NOT IOS) )
 135 OCV_OPTION(WITH_OPENGL         "Include OpenGL support"                      OFF  IF (NOT ANDROID AND NOT APPLE) )
 136 OCV_OPTION(WITH_OPENNI         "Include OpenNI support"                      OFF  IF (NOT ANDROID AND NOT IOS) )
 137 OCV_OPTION(WITH_PNG            "Include PNG support"                         ON)
 138 OCV_OPTION(WITH_PVAPI          "Include Prosilica GigE support"              ON   IF (NOT ANDROID AND NOT IOS) )
 139 OCV_OPTION(WITH_GIGEAPI        "Include Smartek GigE support"                ON   IF (NOT ANDROID AND NOT IOS) )
 140 OCV_OPTION(WITH_QT             "Build with Qt Backend support"               OFF  IF (NOT ANDROID AND NOT IOS) )
 141 OCV_OPTION(WITH_WIN32UI        "Build with Win32 UI Backend support"         ON   IF WIN32 )
 142 OCV_OPTION(WITH_QUICKTIME      "Use QuickTime for Video I/O insted of QTKit" OFF  IF APPLE )
 143 OCV_OPTION(WITH_TBB            "Include Intel TBB support"                   OFF  IF (NOT IOS) )
 144 OCV_OPTION(WITH_OPENMP         "Include OpenMP support"                      OFF)
 145 OCV_OPTION(WITH_CSTRIPES       "Include C= support"                          OFF  IF WIN32 )
 146 OCV_OPTION(WITH_TIFF           "Include TIFF support"                        ON   IF (NOT IOS) )
 147 OCV_OPTION(WITH_UNICAP         "Include Unicap support (GPL)"                OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 148 OCV_OPTION(WITH_V4L            "Include Video 4 Linux support"               ON   IF (UNIX AND NOT ANDROID) )
 149 OCV_OPTION(WITH_LIBV4L         "Use libv4l for Video 4 Linux support"        ON   IF (UNIX AND NOT ANDROID) )
 150 OCV_OPTION(WITH_DSHOW          "Build HighGUI with DirectShow support"       ON   IF (WIN32 AND NOT ARM) )
 151 OCV_OPTION(WITH_MSMF           "Build HighGUI with Media Foundation support" OFF  IF WIN32 )
 152 OCV_OPTION(WITH_XIMEA          "Include XIMEA cameras support"               OFF  IF (NOT ANDROID AND NOT APPLE) )
 153 OCV_OPTION(WITH_XINE           "Include Xine support (GPL)"                  OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 154 OCV_OPTION(WITH_CLP            "Include Clp support (EPL)"                   OFF)
 155 OCV_OPTION(WITH_OPENCL         "Include OpenCL Runtime support"              ON   IF (NOT IOS) )
 156 OCV_OPTION(WITH_OPENCLAMDFFT   "Include AMD OpenCL FFT library support"      ON   IF (NOT ANDROID AND NOT IOS) )
 157 OCV_OPTION(WITH_OPENCLAMDBLAS  "Include AMD OpenCL BLAS library support"     ON   IF (NOT ANDROID AND NOT IOS) )
 158 OCV_OPTION(WITH_DIRECTX        "Include DirectX support"                     ON   IF WIN32 )
 159
 160
 161 # OpenCV build components
 162 # ===================================================
 163 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR IOS) )
 164 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID) IF (NOT IOS) )
 165 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 166 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" ON )
 167 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 168 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON )
 169 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     ON  IF (NOT IOS) )
 170 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           ON  IF (NOT IOS) )
 171 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into debug libs (not MSCV only)" ON )
 172 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of staticaly linked CRT for staticaly linked OpenCV" ON IF MSVC )
 173 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create fat java wrapper containing the whole OpenCV library" ON IF NOT BUILD_SHARED_LIBS AND CMAKE_COMPILER_IS_GNUCXX )
 174 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID AND ANDROID_SOURCE_TREE )
 175 OCV_OPTION(BUILD_ANDROID_PACKAGE    "Build platform-specific package for Google Play" OFF IF ANDROID )
 176
 177 # 3rd party libs
 178 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             WIN32 OR APPLE )
 179 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          WIN32 OR ANDROID OR APPLE )
 180 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        WIN32 OR ANDROID OR APPLE )
 181 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          WIN32 OR ANDROID OR APPLE )
 182 OCV_OPTION(BUILD_PNG                "Build libpng from source"           WIN32 OR ANDROID OR APPLE )
 183 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          WIN32 OR ANDROID OR APPLE )
 184 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" ANDROID )
 185
 186 # OpenCV installation options
 187 # ===================================================
 188 OCV_OPTION(INSTALL_CREATE_DISTRIB   "Change install rules to build the distribution package" OFF )
 189 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 190 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 191 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 192 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT IOS AND BUILD_SHARED_LIBS) )
 193
 194
 195 # OpenCV build options
 196 # ===================================================
 197 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON   IF (NOT IOS) )
 198 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) )
 199 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CMAKE_COMPILER_IS_GNUCXX )
 200 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CMAKE_COMPILER_IS_GNUCXX AND NOT (APPLE AND CMAKE_COMPILER_IS_CLANGCXX) )
 201 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CMAKE_COMPILER_IS_GNUCXX AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 202 OCV_OPTION(ENABLE_FAST_MATH           "Enable -ffast-math (not recommended for GCC 4.6.x)"       OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 203 OCV_OPTION(ENABLE_SSE                 "Enable SSE instructions"                                  ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 204 OCV_OPTION(ENABLE_SSE2                "Enable SSE2 instructions"                                 ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 205 OCV_OPTION(ENABLE_SSE3                "Enable SSE3 instructions"                                 ON   IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 206 OCV_OPTION(ENABLE_SSSE3               "Enable SSSE3 instructions"                                OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 207 OCV_OPTION(ENABLE_SSE41               "Enable SSE4.1 instructions"                               OFF  IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 208 OCV_OPTION(ENABLE_SSE42               "Enable SSE4.2 instructions"                               OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 209 OCV_OPTION(ENABLE_AVX                 "Enable AVX instructions"                                  OFF  IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 210 OCV_OPTION(ENABLE_NEON                "Enable NEON instructions"                                 OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND ARM) )
 211 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 212 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 213 OCV_OPTION(ENABLE_WINRT_MODE          "Build with Windows Runtime support"                       OFF  IF WIN32 )
 214
 215
 216 # ----------------------------------------------------------------------------
 217 #  Get actual OpenCV version number from sources
 218 # ----------------------------------------------------------------------------
 219 include(cmake/OpenCVVersion.cmake)
 220
 221
 222 # ----------------------------------------------------------------------------
 223 #  Build & install layouts
 224 # ----------------------------------------------------------------------------
 225
 226 # Save libs and executables in the same place
 227 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications" )
 228
 229 if(ANDROID OR WIN32)
 230   set(OPENCV_DOC_INSTALL_PATH doc)
 231 elseif(INSTALL_TO_MANGLED_PATHS)
 232   set(OPENCV_DOC_INSTALL_PATH share/OpenCV-${OPENCV_VERSION}/doc)
 233 else()
 234   set(OPENCV_DOC_INSTALL_PATH share/OpenCV/doc)
 235 endif()
 236
 237 if(WIN32)
 238   if(DEFINED OpenCV_RUNTIME AND DEFINED OpenCV_ARCH)
 239     set(OpenCV_INSTALL_BINARIES_PREFIX "${OpenCV_ARCH}/${OpenCV_RUNTIME}/")
 240   else()
 241     message(STATUS "Can't detect runtime and/or arch")
 242     set(OpenCV_INSTALL_BINARIES_PREFIX "")
 243   endif()
 244 else()
 245   set(OpenCV_INSTALL_BINARIES_PREFIX "")
 246 endif()
 247
 248 set(OPENCV_SAMPLES_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}samples")
 249
 250 set(OPENCV_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}bin")
 251
 252 if(ANDROID)
 253   set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 254   set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 255   set(OPENCV_LIB_INSTALL_PATH     sdk/native/libs/${ANDROID_NDK_ABI_NAME})
 256   set(OPENCV_3P_LIB_INSTALL_PATH  sdk/native/3rdparty/libs/${ANDROID_NDK_ABI_NAME})
 257   set(OPENCV_CONFIG_INSTALL_PATH  sdk/native/jni)
 258   set(OPENCV_INCLUDE_INSTALL_PATH sdk/native/jni/include)
 259 else()
 260   set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib")
 261   set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib${LIB_SUFFIX}")
 262   if(WIN32)
 263     if(OpenCV_STATIC)
 264       set(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 265     else()
 266       set(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}lib${LIB_SUFFIX}")
 267     endif()
 268     set(OPENCV_3P_LIB_INSTALL_PATH  "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 269   else()
 270     set(OPENCV_LIB_INSTALL_PATH     lib${LIB_SUFFIX})
 271     set(OPENCV_3P_LIB_INSTALL_PATH  share/OpenCV/3rdparty/${OPENCV_LIB_INSTALL_PATH})
 272   endif()
 273   set(OPENCV_INCLUDE_INSTALL_PATH "include")
 274
 275   math(EXPR SIZEOF_VOID_P_BITS "8 * ${CMAKE_SIZEOF_VOID_P}")
 276   if(LIB_SUFFIX AND NOT SIZEOF_VOID_P_BITS EQUAL LIB_SUFFIX)
 277     set(OPENCV_CONFIG_INSTALL_PATH lib${LIB_SUFFIX}/cmake/opencv)
 278   else()
 279     set(OPENCV_CONFIG_INSTALL_PATH share/OpenCV)
 280   endif()
 281 endif()
 282
 283 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 284 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 285
 286 if(INSTALL_TO_MANGLED_PATHS)
 287   set(OPENCV_INCLUDE_INSTALL_PATH ${OPENCV_INCLUDE_INSTALL_PATH}/opencv-${OPENCV_VERSION})
 288 endif()
 289
 290 if(WIN32)
 291   # Postfix of DLLs:
 292   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 293   set(OPENCV_DEBUG_POSTFIX d)
 294 else()
 295   # Postfix of so's:
 296   set(OPENCV_DLLVERSION "")
 297   set(OPENCV_DEBUG_POSTFIX "")
 298 endif()
 299
 300 if(DEFINED CMAKE_DEBUG_POSTFIX)
 301   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 302 endif()
 303
 304
 305 # ----------------------------------------------------------------------------
 306 #  Path for build/platform -specific headers
 307 # ----------------------------------------------------------------------------
 308 set(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 309 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 310
 311 # ----------------------------------------------------------------------------
 312 #  Path for additional modules
 313 # ----------------------------------------------------------------------------
 314 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules")
 315
 316 # ----------------------------------------------------------------------------
 317 #  Autodetect if we are in a GIT repository
 318 # ----------------------------------------------------------------------------
 319 find_host_package(Git QUIET)
 320
 321 if(GIT_FOUND)
 322   execute_process(COMMAND "${GIT_EXECUTABLE}" describe --tags --always --dirty --match "2.[0-9].[0-9]*"
 323     WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 324     OUTPUT_VARIABLE OPENCV_VCSVERSION
 325     RESULT_VARIABLE GIT_RESULT
 326     ERROR_QUIET
 327     OUTPUT_STRIP_TRAILING_WHITESPACE
 328   )
 329   if(NOT GIT_RESULT EQUAL 0)
 330     set(OPENCV_VCSVERSION "unknown")
 331   endif()
 332 else()
 333   # We don't have git:
 334   set(OPENCV_VCSVERSION "unknown")
 335 endif()
 336
 337
 338 # ----------------------------------------------------------------------------
 339 # OpenCV compiler and linker options
 340 # ----------------------------------------------------------------------------
 341 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 342 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 343   set(CMAKE_BUILD_TYPE Release)
 344 endif()
 345
 346 include(cmake/OpenCVCompilerOptions.cmake)
 347
 348
 349 # ----------------------------------------------------------------------------
 350 # Use statically or dynamically linked CRT?
 351 # Default: dynamic
 352 # ----------------------------------------------------------------------------
 353 if(MSVC)
 354   include(cmake/OpenCVCRTLinkage.cmake)
 355 endif(MSVC)
 356
 357 if(WIN32 AND NOT MINGW)
 358   add_definitions(-D_VARIADIC_MAX=10)
 359 endif(WIN32 AND NOT MINGW)
 360
 361
 362 # ----------------------------------------------------------------------------
 363 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 364 # ----------------------------------------------------------------------------
 365 if(UNIX)
 366   find_package(PkgConfig QUIET)
 367   include(CheckFunctionExists)
 368   include(CheckIncludeFile)
 369
 370   if(NOT APPLE)
 371     CHECK_INCLUDE_FILE(pthread.h HAVE_LIBPTHREAD)
 372     if(ANDROID)
 373       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 374     elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD|NetBSD|DragonFly")
 375       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 376     else()
 377       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 378     endif()
 379   else()
 380     set(HAVE_LIBPTHREAD YES)
 381   endif()
 382 endif()
 383
 384 include(cmake/OpenCVPCHSupport.cmake)
 385 include(cmake/OpenCVModule.cmake)
 386
 387 # ----------------------------------------------------------------------------
 388 #  Detect 3rd-party libraries
 389 # ----------------------------------------------------------------------------
 390
 391 include(cmake/OpenCVFindLibsGrfmt.cmake)
 392 include(cmake/OpenCVFindLibsGUI.cmake)
 393 include(cmake/OpenCVFindLibsVideo.cmake)
 394 include(cmake/OpenCVFindLibsPerf.cmake)
 395
 396
 397 # ----------------------------------------------------------------------------
 398 #  Detect other 3rd-party libraries/tools
 399 # ----------------------------------------------------------------------------
 400
 401 # --- LATEX for pdf documentation ---
 402 if(BUILD_DOCS)
 403   include(cmake/OpenCVFindLATEX.cmake)
 404 endif(BUILD_DOCS)
 405
 406 # --- Python Support ---
 407 include(cmake/OpenCVDetectPython.cmake)
 408
 409 # --- Java Support ---
 410 include(cmake/OpenCVDetectApacheAnt.cmake)
 411 if(ANDROID)
 412   include(cmake/OpenCVDetectAndroidSDK.cmake)
 413
 414   if(NOT ANDROID_TOOLS_Pkg_Revision GREATER 13)
 415     message(WARNING "OpenCV requires Android SDK tools revision 14 or newer. Otherwise tests and samples will no be compiled.")
 416   endif()
 417 else()
 418   find_package(JNI)
 419 endif()
 420
 421 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 422   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 423 else()
 424   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 425 endif()
 426
 427 # --- OpenCL ---
 428 if(WITH_OPENCL)
 429   include(cmake/OpenCVDetectOpenCL.cmake)
 430 endif()
 431
 432 # --- DirectX ---
 433 if(WITH_DIRECTX)
 434   include(cmake/OpenCVDetectDirectX.cmake)
 435 endif()
 436
 437 # --- Matlab/Octave ---
 438 include(cmake/OpenCVFindMatlab.cmake)
 439
 440 include(cmake/OpenCVDetectVTK.cmake)
 441
 442 # ----------------------------------------------------------------------------
 443 # Add CUDA libraries (needed for apps/tools, samples)
 444 # ----------------------------------------------------------------------------
 445 if(HAVE_CUDA)
 446   set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_LIBRARIES} ${CUDA_npp_LIBRARY})
 447   if(HAVE_CUBLAS)
 448     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cublas_LIBRARY})
 449   endif()
 450   if(HAVE_CUFFT)
 451     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cufft_LIBRARY})
 452   endif()
 453 endif()
 454 # ----------------------------------------------------------------------------
 455 # Solution folders:
 456 # ----------------------------------------------------------------------------
 457 if(ENABLE_SOLUTION_FOLDERS)
 458   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 459   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 460 endif()
 461
 462 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 463 include(cmake/OpenCVExtraTargets.cmake)
 464
 465
 466 # ----------------------------------------------------------------------------
 467 # Process subdirectories
 468 # ----------------------------------------------------------------------------
 469
 470 # opencv.hpp and legacy headers
 471 add_subdirectory(include)
 472
 473 # OpenCV modules
 474 add_subdirectory(modules)
 475
 476 # Generate targets for documentation
 477 add_subdirectory(doc)
 478
 479 # various data that is used by cv libraries and/or demo applications.
 480 add_subdirectory(data)
 481
 482 # extra applications
 483 if(BUILD_opencv_apps)
 484   add_subdirectory(apps)
 485 endif()
 486
 487 # examples
 488 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES)
 489   add_subdirectory(samples)
 490 endif()
 491
 492 if(ANDROID)
 493   add_subdirectory(platforms/android/service)
 494 endif()
 495
 496 if(BUILD_ANDROID_PACKAGE)
 497   add_subdirectory(platforms/android/package)
 498 endif()
 499
 500 if (ANDROID)
 501   add_subdirectory(platforms/android/libinfo)
 502 endif()
 503
 504 # ----------------------------------------------------------------------------
 505 # Finalization: generate configuration-based files
 506 # ----------------------------------------------------------------------------
 507 ocv_track_build_dependencies()
 508
 509 # Generate platform-dependent and configuration-dependent headers
 510 include(cmake/OpenCVGenHeaders.cmake)
 511
 512 # Generate opencv.pc for pkg-config command
 513 include(cmake/OpenCVGenPkgconfig.cmake)
 514
 515 # Generate OpenCV.mk for ndk-build (Android build tool)
 516 include(cmake/OpenCVGenAndroidMK.cmake)
 517
 518 # Generate OpenCVСonfig.cmake and OpenCVConfig-version.cmake for cmake projects
 519 include(cmake/OpenCVGenConfig.cmake)
 520
 521 # Generate Info.plist for the IOS framework
 522 include(cmake/OpenCVGenInfoPlist.cmake)
 523
 524 # ----------------------------------------------------------------------------
 525 # Summary:
 526 # ----------------------------------------------------------------------------
 527 status("")
 528 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 529 if(OPENCV_VCSVERSION)
 530   status("  Version control:" ${OPENCV_VCSVERSION})
 531 endif()
 532
 533 # ========================== build platform ==========================
 534 status("")
 535 status("  Platform:")
 536 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
 537 if(CMAKE_CROSSCOMPILING)
 538   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
 539 endif()
 540 status("    CMake:"            ${CMAKE_VERSION})
 541 status("    CMake generator:"  ${CMAKE_GENERATOR})
 542 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
 543 if(MSVC)
 544   status("    MSVC:"           ${MSVC_VERSION})
 545 endif()
 546 if(CMAKE_GENERATOR MATCHES Xcode)
 547   status("    Xcode:"          ${XCODE_VERSION})
 548 endif()
 549 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
 550   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
 551 endif()
 552
 553 # ========================== C/C++ options ==========================
 554 if(CMAKE_CXX_COMPILER_VERSION)
 555   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
 556 elseif(CMAKE_COMPILER_IS_CLANGCXX)
 557   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CLANG_REGEX_VERSION})")
 558 elseif(CMAKE_COMPILER_IS_GNUCXX)
 559   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_GCC_REGEX_VERSION})")
 560 else()
 561   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 562 endif()
 563 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
 564
 565 status("")
 566 status("  C/C++:")
 567 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
 568 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
 569 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
 570 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
 571 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
 572 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
 573 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
 574 if(WIN32)
 575   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
 576   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
 577 else()
 578   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
 579   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
 580 endif()
 581 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
 582
 583 # ========================== OpenCV modules ==========================
 584 status("")
 585 status("  OpenCV modules:")
 586 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD}")
 587 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
 588 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
 589 set(OPENCV_MODULES_DISABLED_AUTO_ST "")
 590 foreach(m ${OPENCV_MODULES_DISABLED_AUTO})
 591   set(__mdeps "")
 592   foreach(d ${OPENCV_MODULE_${m}_DEPS})
 593     if(d MATCHES "^opencv_" AND NOT HAVE_${d})
 594       list(APPEND __mdeps ${d})
 595     endif()
 596   endforeach()
 597   if(__mdeps)
 598     list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}(deps: ${__mdeps})")
 599   else()
 600     list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}")
 601   endif()
 602 endforeach()
 603 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO_ST}")
 604
 605 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
 606 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
 607 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
 608 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
 609
 610 # ========================== Android details ==========================
 611 if(ANDROID)
 612   status("")
 613   status("  Android: ")
 614   status("    Android ABI:" ${ANDROID_ABI})
 615   status("    STL type:" ${ANDROID_STL})
 616   status("    Native API level:" android-${ANDROID_NATIVE_API_LEVEL})
 617   android_get_compatible_target(android_sdk_target_status ${ANDROID_NATIVE_API_LEVEL} ${ANDROID_SDK_TARGET} 11)
 618   status("    SDK target:" "${android_sdk_target_status}")
 619   if(BUILD_WITH_ANDROID_NDK)
 620     status("    Android NDK:" "${ANDROID_NDK} (toolchain: ${ANDROID_TOOLCHAIN_NAME})")
 621   elseif(BUILD_WITH_STANDALONE_TOOLCHAIN)
 622     status("    Android toolchain:" "${ANDROID_STANDALONE_TOOLCHAIN}")
 623   endif()
 624   status("    android tool:"  ANDROID_EXECUTABLE  THEN "${ANDROID_EXECUTABLE} (${ANDROID_TOOLS_Pkg_Desc})" ELSE NO)
 625   status("    Google Play package:" BUILD_ANDROID_PACKAGE                                         THEN YES ELSE NO)
 626   status("    Android examples:"    BUILD_ANDROID_EXAMPLES AND CAN_BUILD_ANDROID_PROJECTS         THEN YES ELSE NO)
 627 endif()
 628
 629 # ================== Windows RT features ==================
 630 if(WIN32)
 631 status("")
 632     status("  Windows RT support:" HAVE_WINRT THEN YES ELSE NO)
 633     if (ENABLE_WINRT_MODE)
 634       status("    Windows SDK v8.0:" ${WINDOWS_SDK_PATH})
 635       status("    Visual Studio 2012:" ${VISUAL_STUDIO_PATH})
 636     endif()
 637 endif(WIN32)
 638
 639 # ========================== GUI ==========================
 640 status("")
 641 status("  GUI: ")
 642
 643 if(HAVE_QT5)
 644   status("    QT 5.x:"            HAVE_QT        THEN "YES (ver ${Qt5Core_VERSION_STRING})" ELSE NO)
 645   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt5OpenGL_LIBRARIES} ${Qt5OpenGL_VERSION_STRING})" ELSE NO)
 646 elseif(HAVE_QT)
 647   status("    QT 4.x:"            HAVE_QT        THEN "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})" ELSE NO)
 648   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
 649 else()
 650   if(DEFINED WITH_QT)
 651     status("    QT:" NO)
 652   endif()
 653   if(DEFINED WITH_WIN32UI)
 654     status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
 655   else()
 656     if(APPLE)
 657       if(WITH_CARBON)
 658         status("    Carbon:" YES)
 659       else()
 660         status("    Cocoa:"  YES)
 661       endif()
 662     else()
 663       status("    GTK+ 2.x:" HAVE_GTK      THEN "YES (ver ${ALIASOF_gtk+-2.0_VERSION})"     ELSE NO)
 664       status("    GThread :" HAVE_GTHREAD  THEN "YES (ver ${ALIASOF_gthread-2.0_VERSION})"  ELSE NO)
 665       status("    GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${ALIASOF_gtkglext-1.0_VERSION})" ELSE NO)
 666     endif()
 667   endif()
 668 endif()
 669
 670 status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
 671 status("    VTK support:" HAVE_VTK THEN "YES (ver ${VTK_VERSION})" ELSE NO)
 672
 673 # ========================== MEDIA IO ==========================
 674 status("")
 675 status("  Media I/O: ")
 676 status("    ZLib:"         BUILD_ZLIB    THEN "build (ver ${ZLIB_VERSION_STRING})"               ELSE "${ZLIB_LIBRARIES} (ver ${ZLIB_VERSION_STRING})")
 677
 678 if(WITH_JPEG)
 679   status("    JPEG:"       JPEG_FOUND    THEN "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})"        ELSE "build (ver ${JPEG_LIB_VERSION})")
 680 else()
 681   status("    JPEG:"       "NO")
 682 endif()
 683
 684 if(WITH_WEBP)
 685   status("    WEBP:"       WEBP_FOUND    THEN "${WEBP_LIBRARY} (ver ${WEBP_VERSION})"        ELSE "build (ver ${WEBP_VERSION})")
 686 else()
 687   status("    WEBP:"       "NO")
 688 endif()
 689
 690 if(WITH_PNG)
 691   status("    PNG:"        PNG_FOUND     THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})"              ELSE "build (ver ${PNG_VERSION})")
 692 else()
 693   status("    PNG:"        "NO")
 694 endif()
 695 if(WITH_TIFF)
 696   if(TIFF_VERSION_STRING AND TIFF_FOUND)
 697     status("    TIFF:"     "${TIFF_LIBRARY} (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 698   else()
 699     status("    TIFF:"     TIFF_FOUND    THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION})"            ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 700   endif()
 701 else()
 702   status("    TIFF:"       "NO")
 703 endif()
 704 if(WITH_JASPER)
 705   status("    JPEG 2000:"  JASPER_FOUND  THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
 706 else()
 707   status("    JPEG 2000:"  "NO")
 708 endif()
 709 if(WITH_OPENEXR)
 710   status("    OpenEXR:"  OPENEXR_FOUND  THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
 711 else()
 712   status("    OpenEXR:"  "NO")
 713 endif()
 714
 715 # ========================== VIDEO IO ==========================
 716 status("")
 717 status("  Video I/O:")
 718
 719 if (DEFINED WITH_VFW)
 720   status("    Video for Windows:" HAVE_VFW         THEN YES                                        ELSE NO)
 721 endif(DEFINED WITH_VFW)
 722
 723 if(DEFINED WITH_1394)
 724   status("    DC1394 1.x:"     HAVE_DC1394         THEN "YES (ver ${ALIASOF_libdc1394_VERSION})"   ELSE NO)
 725   status("    DC1394 2.x:"     HAVE_DC1394_2       THEN "YES (ver ${ALIASOF_libdc1394-2_VERSION})" ELSE NO)
 726 endif(DEFINED WITH_1394)
 727
 728 if(ANDROID)
 729   if(HAVE_opencv_androidcamera)
 730     status("    AndroidNativeCamera:" BUILD_ANDROID_CAMERA_WRAPPER
 731                                                    THEN "YES, build for Android${ANDROID_VERSION}" ELSE "YES, use prebuilt libraries")
 732   else()
 733     status("    AndroidNativeCamera:" "NO (native camera requires Android API level 8 or higher)")
 734   endif()
 735 endif()
 736
 737 if(DEFINED WITH_AVFOUNDATION)
 738   status("    AVFoundation:"   WITH_AVFOUNDATION   THEN YES                                        ELSE NO)
 739 endif(DEFINED WITH_AVFOUNDATION)
 740
 741 if(DEFINED WITH_FFMPEG)
 742   if(WIN32)
 743     status("    FFMPEG:"       WITH_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
 744   else()
 745     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
 746   endif()
 747   status("      codec:"        HAVE_FFMPEG_CODEC   THEN "YES (ver ${ALIASOF_libavcodec_VERSION})"  ELSE NO)
 748   status("      format:"       HAVE_FFMPEG_FORMAT  THEN "YES (ver ${ALIASOF_libavformat_VERSION})" ELSE NO)
 749   status("      util:"         HAVE_FFMPEG_UTIL    THEN "YES (ver ${ALIASOF_libavutil_VERSION})"   ELSE NO)
 750   status("      swscale:"      HAVE_FFMPEG_SWSCALE THEN "YES (ver ${ALIASOF_libswscale_VERSION})"  ELSE NO)
 751   status("      gentoo-style:" HAVE_GENTOO_FFMPEG  THEN YES                                        ELSE NO)
 752 endif(DEFINED WITH_FFMPEG)
 753
 754 if(DEFINED WITH_GSTREAMER)
 755   status("    GStreamer:"      HAVE_GSTREAMER      THEN ""                                         ELSE NO)
 756   if(HAVE_GSTREAMER)
 757     status("      base:"       "YES (ver ${GSTREAMER_BASE_VERSION})")
 758     status("      video:"      "YES (ver ${GSTREAMER_VIDEO_VERSION})")
 759     status("      app:"        "YES (ver ${GSTREAMER_APP_VERSION})")
 760     status("      riff:"       "YES (ver ${GSTREAMER_RIFF_VERSION})")
 761     status("      pbutils:"    "YES (ver ${GSTREAMER_PBUTILS_VERSION})")
 762   endif(HAVE_GSTREAMER)
 763 endif(DEFINED WITH_GSTREAMER)
 764
 765 if(DEFINED WITH_OPENNI)
 766   status("    OpenNI:"         HAVE_OPENNI         THEN "YES (ver ${OPENNI_VERSION_STRING}, build ${OPENNI_VERSION_BUILD})"
 767                                                                                                    ELSE NO)
 768   status("    OpenNI PrimeSensor Modules:" HAVE_OPENNI_PRIME_SENSOR_MODULE
 769                                                    THEN "YES (${OPENNI_PRIME_SENSOR_MODULE})"      ELSE NO)
 770 endif(DEFINED WITH_OPENNI)
 771
 772 if(DEFINED WITH_PVAPI)
 773   status("    PvAPI:"          HAVE_PVAPI          THEN YES                                        ELSE NO)
 774 endif(DEFINED WITH_PVAPI)
 775
 776 if(DEFINED WITH_GIGEAPI)
 777   status("    GigEVisionSDK:"  HAVE_GIGE_API       THEN YES                                        ELSE NO)
 778 endif(DEFINED WITH_GIGEAPI)
 779
 780 if(DEFINED WITH_QUICKTIME)
 781   status("    QuickTime:"      HAVE_QUICKTIME      THEN YES                                        ELSE NO)
 782   status("    QTKit:"          HAVE_QTKIT          THEN YES                                        ELSE NO)
 783 endif(DEFINED WITH_QUICKTIME)
 784
 785 if(DEFINED WITH_UNICAP)
 786   status("    UniCap:"         HAVE_UNICAP         THEN "YES (ver ${ALIASOF_libunicap_VERSION})"   ELSE NO)
 787   status("    UniCap ucil:"    HAVE_UNICAP_UCIL    THEN "YES (ver ${ALIASOF_libucil_VERSION})"     ELSE NO)
 788 endif(DEFINED WITH_UNICAP)
 789
 790 if(DEFINED WITH_V4L)
 791   if(HAVE_CAMV4L)
 792     set(HAVE_CAMV4L_STR "YES")
 793   else()
 794     set(HAVE_CAMV4L_STR "NO")
 795   endif()
 796   if(HAVE_CAMV4L2)
 797     set(HAVE_CAMV4L2_STR "YES")
 798   elseif(HAVE_VIDEOIO)
 799     set(HAVE_CAMV4L2_STR "YES(videoio)")
 800   else()
 801     set(HAVE_CAMV4L2_STR "NO")
 802   endif()
 803   status("    V4L/V4L2:"       HAVE_LIBV4L         THEN "Using libv4l (ver ${ALIASOF_libv4l1_VERSION})"
 804                                                    ELSE "${HAVE_CAMV4L_STR}/${HAVE_CAMV4L2_STR}")
 805 endif(DEFINED WITH_V4L)
 806
 807 if(DEFINED WITH_DSHOW)
 808   status("    DirectShow:"     HAVE_DSHOW     THEN YES                                        ELSE NO)
 809 endif(DEFINED WITH_DSHOW)
 810
 811 if(DEFINED WITH_MSMF)
 812   status("    Media Foundation:" HAVE_MSMF    THEN YES                                        ELSE NO)
 813 endif(DEFINED WITH_MSMF)
 814
 815 if(DEFINED WITH_XIMEA)
 816   status("    XIMEA:"          HAVE_XIMEA          THEN YES                                        ELSE NO)
 817 endif(DEFINED WITH_XIMEA)
 818
 819 if(DEFINED WITH_XINE)
 820   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${ALIASOF_libxine_VERSION})"     ELSE NO)
 821 endif(DEFINED WITH_XINE)
 822
 823 # ========================== Other third-party libraries ==========================
 824 status("")
 825 status("  Other third-party libraries:")
 826
 827 if(WITH_IPP AND IPP_FOUND)
 828   status("    Use IPP:" "${IPP_LATEST_VERSION_STR} [${IPP_LATEST_VERSION_MAJOR}.${IPP_LATEST_VERSION_MINOR}.${IPP_LATEST_VERSION_BUILD}]")
 829   status("         at:" "${IPP_ROOT_DIR}")
 830 else()
 831   status("    Use IPP:"   WITH_IPP AND NOT IPP_FOUND THEN "IPP not found" ELSE NO)
 832 endif()
 833
 834 status("    Use Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
 835 status("    Use TBB:"        HAVE_TBB         THEN "YES (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})" ELSE NO)
 836 status("    Use OpenMP:"     HAVE_OPENMP      THEN YES ELSE NO)
 837 status("    Use GCD"         HAVE_GCD         THEN YES ELSE NO)
 838 status("    Use Concurrency" HAVE_CONCURRENCY THEN YES ELSE NO)
 839 status("    Use C=:"         HAVE_CSTRIPES    THEN YES ELSE NO)
 840 status("    Use Cuda:"       HAVE_CUDA        THEN "YES (ver ${CUDA_VERSION_STRING})" ELSE NO)
 841 status("    Use OpenCL:"     HAVE_OPENCL      THEN YES ELSE NO)
 842
 843 if(HAVE_CUDA)
 844   status("")
 845   status("  NVIDIA CUDA")
 846
 847   status("    Use CUFFT:"            HAVE_CUFFT   THEN YES ELSE NO)
 848   status("    Use CUBLAS:"           HAVE_CUBLAS  THEN YES ELSE NO)
 849   status("    USE NVCUVID:"          HAVE_NVCUVID THEN YES ELSE NO)
 850   status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
 851   status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
 852   status("    Use fast math:"        CUDA_FAST_MATH THEN YES ELSE NO)
 853 endif()
 854
 855 if(HAVE_OPENCL)
 856   status("")
 857   status("  OpenCL:")
 858   if(HAVE_OPENCL_STATIC)
 859     set(__opencl_ver "static")
 860   else()
 861     set(__opencl_ver "dynamic")
 862   endif()
 863   status("    Version:"       ${__opencl_ver})
 864   if(OPENCL_INCLUDE_DIR)
 865     status("    Include path:"       ${OPENCL_INCLUDE_DIRS})
 866   endif()
 867   if(OPENCL_LIBRARIES)
 868     set(__libs "")
 869     foreach(l ${OPENCL_LIBRARIES})
 870       if(TARGET ${l})
 871         get_target_property(p ${l} LOCATION)
 872         if(p MATCHES NOTFOUND)
 873           list(APPEND __libs "${l}")
 874         else()
 875           list(APPEND __libs "${p}")
 876         endif()
 877       else()
 878         list(APPEND __libs "${l}")
 879       endif()
 880     endforeach()
 881     status("    libraries:"          ${__libs})
 882   endif()
 883   status("    Use AMDFFT:"           HAVE_CLAMDFFT  THEN YES ELSE NO)
 884   status("    Use AMDBLAS:"          HAVE_CLAMDBLAS THEN YES ELSE NO)
 885 endif()
 886
 887 # ========================== python ==========================
 888 status("")
 889 status("  Python:")
 890 status("    Interpreter:"     PYTHONINTERP_FOUND  THEN "${PYTHON_EXECUTABLE} (ver ${PYTHON_VERSION_STRING})"       ELSE NO)
 891 if(BUILD_opencv_python)
 892   if(PYTHONLIBS_VERSION_STRING)
 893     status("    Libraries:"   HAVE_opencv_python  THEN  "${PYTHON_LIBRARIES} (ver ${PYTHONLIBS_VERSION_STRING})"   ELSE NO)
 894   else()
 895     status("    Libraries:"   HAVE_opencv_python  THEN  "${PYTHON_LIBRARIES}"                                      ELSE NO)
 896   endif()
 897   status("    numpy:"         PYTHON_NUMPY_INCLUDE_DIRS THEN "${PYTHON_NUMPY_INCLUDE_DIRS} (ver ${PYTHON_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
 898   status("    packages path:" PYTHON_EXECUTABLE         THEN "${PYTHON_PACKAGES_PATH}"                                    ELSE "-")
 899 endif()
 900
 901 # ========================== java ==========================
 902 status("")
 903 status("  Java:")
 904 status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
 905 if(NOT ANDROID)
 906   status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
 907 endif()
 908 status("    Java tests:"    BUILD_TESTS AND (CAN_BUILD_ANDROID_PROJECTS OR HAVE_opencv_java)            THEN YES ELSE NO)
 909
 910 # ========================= matlab =========================
 911 status("")
 912 status("  Matlab:")
 913 status("    mex:"         MATLAB_MEX_SCRIPT  THEN  "${MATLAB_MEX_SCRIPT}"   ELSE NO)
 914 if (MATLAB_FOUND)
 915   status("    Compiler/generator:" MEX_WORKS    THEN  "Working"                ELSE "Not working (bindings will not be generated)")
 916 endif()
 917
 918 # ========================== documentation ==========================
 919 if(BUILD_DOCS)
 920   status("")
 921   status("  Documentation:")
 922   if(HAVE_SPHINX)
 923     status("    Build Documentation:" PDFLATEX_COMPILER      THEN YES ELSE "YES (only HTML and without math expressions)")
 924   else()
 925     status("    Build Documentation:" NO)
 926   endif()
 927   status("    Sphinx:"              HAVE_SPHINX              THEN "${SPHINX_BUILD} (ver ${SPHINX_VERSION})" ELSE NO)
 928   status("    PdfLaTeX compiler:"   PDFLATEX_COMPILER        THEN "${PDFLATEX_COMPILER}" ELSE NO)
 929   status("    PlantUML:"            PLANTUML                 THEN "${PLANTUML}" ELSE NO)
 930 endif()
 931
 932 # ========================== samples and tests ==========================
 933 status("")
 934 status("  Tests and samples:")
 935 status("    Tests:"             BUILD_TESTS AND HAVE_opencv_ts       THEN YES ELSE NO)
 936 status("    Performance tests:" BUILD_PERF_TESTS AND HAVE_opencv_ts  THEN YES ELSE NO)
 937 status("    C/C++ Examples:"    BUILD_EXAMPLES                       THEN YES ELSE NO)
 938
 939 # ========================== auxiliary ==========================
 940 status("")
 941 status("  Install path:" "${CMAKE_INSTALL_PREFIX}")
 942 status("")
 943 status("  cvconfig.h is in:" "${OPENCV_CONFIG_FILE_INCLUDE_DIR}")
 944 status("-----------------------------------------------------------------")
 945 status("")
 946
 947 ocv_finalize_status()
 948
 949 # ----------------------------------------------------------------------------
 950 # Warn in the case of in-source build
 951 # ----------------------------------------------------------------------------
 952 if("${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 953   message(WARNING "The source directory is the same as binary directory. \"make clean\" may damage the source tree")
 954 endif()