CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 #
   8 #   - OCT-2008: Initial version <joseluisblancoc@gmail.com>
   9 #
  10 # ----------------------------------------------------------------------------
  11
  12 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  13
  14 # --------------------------------------------------------------
  15 # Indicate CMake 2.7 and above that we don't want to mix relative
  16 #  and absolute paths in linker lib lists.
  17 # Run "cmake --help-policy CMP0003" for more information.
  18 # --------------------------------------------------------------
  19 if(COMMAND cmake_policy)
  20   cmake_policy(SET CMP0003 NEW)
  21 endif()
  22
  23 # Following block can broke build in case of cross-compilng
  24 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  25 # so we will try to detect crosscompiling by presense of CMAKE_TOOLCHAIN_FILE
  26 if(NOT CMAKE_TOOLCHAIN_FILE)
  27   # it _must_ go before project(OpenCV) in order to work
  28   if(WIN32)
  29     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  30   else()
  31     set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  32   endif()
  33
  34   if(MSVC)
  35     set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
  36   endif()
  37 else(NOT CMAKE_TOOLCHAIN_FILE)
  38   #Android: set output folder to ${CMAKE_BINARY_DIR}
  39   set( LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  40   # any crosscompiling
  41   set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  42 endif(NOT CMAKE_TOOLCHAIN_FILE)
  43
  44 # --------------------------------------------------------------
  45 # Top level OpenCV project
  46 # --------------------------------------------------------------
  47 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  48   cmake_minimum_required(VERSION 2.8.8)
  49 elseif(IOS)
  50   cmake_minimum_required(VERSION 2.8.0)
  51 else()
  52   cmake_minimum_required(VERSION 2.6.3)
  53 endif()
  54
  55 # must go before the project command
  56 set(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  57 if(DEFINED CMAKE_BUILD_TYPE AND CMAKE_VERSION VERSION_GREATER "2.8")
  58   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
  59 endif()
  60
  61 project(OpenCV CXX C)
  62
  63 include(cmake/OpenCVUtils.cmake)
  64
  65 # ----------------------------------------------------------------------------
  66 # Break in case of popular CMake configuration mistakes
  67 # ----------------------------------------------------------------------------
  68 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
  69   message(FATAL_ERROR "CMake fails to deterimine the bitness of target platform.
  70   Please check your CMake and compiler installation. If you are crosscompiling then ensure that your CMake toolchain file correctly sets the compiler details.")
  71 endif()
  72
  73 # ----------------------------------------------------------------------------
  74 # Detect compiler and target platform architecture
  75 # ----------------------------------------------------------------------------
  76 include(cmake/OpenCVDetectCXXCompiler.cmake)
  77
  78 # Add these standard paths to the search paths for FIND_LIBRARY
  79 # to find libraries from these locations first
  80 if(UNIX AND NOT ANDROID)
  81   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
  82     if(EXISTS /lib64)
  83       list(APPEND CMAKE_LIBRARY_PATH /lib64)
  84     else()
  85       list(APPEND CMAKE_LIBRARY_PATH /lib)
  86     endif()
  87     if(EXISTS /usr/lib64)
  88       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
  89     else()
  90       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
  91     endif()
  92   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
  93     if(EXISTS /lib32)
  94       list(APPEND CMAKE_LIBRARY_PATH /lib32)
  95     else()
  96       list(APPEND CMAKE_LIBRARY_PATH /lib)
  97     endif()
  98     if(EXISTS /usr/lib32)
  99       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 100     else()
 101       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 102     endif()
 103   endif()
 104 endif()
 105
 106 # Add these standard paths to the search paths for FIND_PATH
 107 # to find include files from these locations first
 108 if(MINGW)
 109   if(EXISTS /mingw)
 110       list(APPEND CMAKE_INCLUDE_PATH /mingw)
 111   endif()
 112   if(EXISTS /mingw32)
 113       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
 114   endif()
 115   if(EXISTS /mingw64)
 116       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 117   endif()
 118 endif()
 119
 120 # ----------------------------------------------------------------------------
 121 # OpenCV cmake options
 122 # ----------------------------------------------------------------------------
 123
 124 # Optional 3rd party components
 125 # ===================================================
 126 OCV_OPTION(WITH_1394           "Include IEEE1394 support"                    ON   IF (NOT ANDROID AND NOT IOS) )
 127 OCV_OPTION(WITH_AVFOUNDATION   "Use AVFoundation for Video I/O"              ON   IF IOS)
 128 OCV_OPTION(WITH_CARBON         "Use Carbon for UI instead of Cocoa"          OFF  IF APPLE )
 129 OCV_OPTION(WITH_CUDA           "Include NVidia Cuda Runtime support"         ON   IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 130 OCV_OPTION(WITH_CUFFT          "Include NVidia Cuda Fast Fourier Transform (FFT) library support"            ON  IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 131 OCV_OPTION(WITH_CUBLAS         "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" OFF IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS) )
 132 OCV_OPTION(WITH_NVCUVID        "Include NVidia Video Decoding library support"                               OFF IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS AND NOT APPLE) )
 133 OCV_OPTION(WITH_EIGEN          "Include Eigen2/Eigen3 support"               ON)
 134 OCV_OPTION(WITH_VFW            "Include Video for Windows support"           ON   IF WIN32 )
 135 OCV_OPTION(WITH_FFMPEG         "Include FFMPEG support"                      ON   IF (NOT ANDROID AND NOT IOS))
 136 OCV_OPTION(WITH_GSTREAMER      "Include Gstreamer support"                   ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 137 OCV_OPTION(WITH_GTK            "Include GTK support"                         ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 138 OCV_OPTION(WITH_IMAGEIO        "ImageIO support for OS X"                    OFF  IF APPLE )
 139 OCV_OPTION(WITH_IPP            "Include Intel IPP support"                   OFF  IF (MSVC OR X86 OR X86_64) )
 140 OCV_OPTION(WITH_JASPER         "Include JPEG2K support"                      ON   IF (NOT IOS) )
 141 OCV_OPTION(WITH_JPEG           "Include JPEG support"                        ON)
 142 OCV_OPTION(WITH_OPENEXR        "Include ILM support via OpenEXR"             ON   IF (NOT IOS) )
 143 OCV_OPTION(WITH_OPENGL         "Include OpenGL support"                      OFF  IF (NOT ANDROID AND NOT APPLE) )
 144 OCV_OPTION(WITH_OPENNI         "Include OpenNI support"                      OFF  IF (NOT ANDROID AND NOT IOS) )
 145 OCV_OPTION(WITH_PNG            "Include PNG support"                         ON)
 146 OCV_OPTION(WITH_PVAPI          "Include Prosilica GigE support"              ON   IF (NOT ANDROID AND NOT IOS) )
 147 OCV_OPTION(WITH_GIGEAPI        "Include Smartek GigE support"                ON   IF (NOT ANDROID AND NOT IOS) )
 148 OCV_OPTION(WITH_QT             "Build with Qt Backend support"               OFF  IF (NOT ANDROID AND NOT IOS) )
 149 OCV_OPTION(WITH_WIN32UI        "Build with Win32 UI Backend support"         ON   IF WIN32 )
 150 OCV_OPTION(WITH_QUICKTIME      "Use QuickTime for Video I/O insted of QTKit" OFF  IF APPLE )
 151 OCV_OPTION(WITH_TBB            "Include Intel TBB support"                   OFF  IF (NOT IOS) )
 152 OCV_OPTION(WITH_CSTRIPES       "Include C= support"                          OFF  IF WIN32 )
 153 OCV_OPTION(WITH_TIFF           "Include TIFF support"                        ON   IF (NOT IOS) )
 154 OCV_OPTION(WITH_UNICAP         "Include Unicap support (GPL)"                OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 155 OCV_OPTION(WITH_V4L            "Include Video 4 Linux support"               ON   IF (UNIX AND NOT ANDROID) )
 156 OCV_OPTION(WITH_DSHOW          "Build HighGUI with DirectShow support"       ON   IF (WIN32 AND NOT ARM) )
 157 OCV_OPTION(WITH_MSMF           "Build HighGUI with Media Foundation support" OFF  IF WIN32 )
 158 OCV_OPTION(WITH_XIMEA          "Include XIMEA cameras support"               OFF  IF (NOT ANDROID AND NOT APPLE) )
 159 OCV_OPTION(WITH_XINE           "Include Xine support (GPL)"                  OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 160 OCV_OPTION(WITH_OPENCL         "Include OpenCL Runtime support"              ON   IF (NOT ANDROID AND NOT IOS) )
 161 OCV_OPTION(WITH_OPENCLAMDFFT   "Include AMD OpenCL FFT library support"      ON   IF (NOT ANDROID AND NOT IOS) )
 162 OCV_OPTION(WITH_OPENCLAMDBLAS  "Include AMD OpenCL BLAS library support"     ON   IF (NOT ANDROID AND NOT IOS) )
 163
 164
 165 # OpenCV build components
 166 # ===================================================
 167 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR IOS) )
 168 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID) IF (NOT IOS) )
 169 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 170 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" ON )
 171 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 172 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON )
 173 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     ON  IF (NOT IOS) )
 174 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           ON  IF (NOT IOS) )
 175 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into debug libs (not MSCV only)" ON )
 176 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of staticaly linked CRT for staticaly linked OpenCV" ON IF MSVC )
 177 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create fat java wrapper containing the whole OpenCV library" ON IF NOT BUILD_SHARED_LIBS AND CMAKE_COMPILER_IS_GNUCXX )
 178 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID AND ANDROID_SOURCE_TREE )
 179 OCV_OPTION(BUILD_ANDROID_PACKAGE    "Build platform-specific package for Google Play" OFF IF ANDROID )
 180
 181 # 3rd party libs
 182 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             WIN32 OR APPLE )
 183 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          WIN32 OR ANDROID OR APPLE )
 184 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        WIN32 OR ANDROID OR APPLE )
 185 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          WIN32 OR ANDROID OR APPLE )
 186 OCV_OPTION(BUILD_PNG                "Build libpng from source"           WIN32 OR ANDROID OR APPLE )
 187 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          WIN32 OR ANDROID OR APPLE )
 188 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" ANDROID )
 189
 190 # OpenCV installation options
 191 # ===================================================
 192 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 193 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 194 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 195 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT IOS AND BUILD_SHARED_LIBS) )
 196
 197
 198 # OpenCV build options
 199 # ===================================================
 200 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON   IF (NOT IOS) )
 201 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) IF (CMAKE_VERSION VERSION_GREATER "2.8.0") )
 202 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CMAKE_COMPILER_IS_GNUCXX )
 203 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CMAKE_COMPILER_IS_GNUCXX AND NOT (APPLE AND CMAKE_COMPILER_IS_CLANGCXX) )
 204 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CMAKE_COMPILER_IS_GNUCXX AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 205 OCV_OPTION(ENABLE_FAST_MATH           "Enable -ffast-math (not recommended for GCC 4.6.x)"       OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 206 OCV_OPTION(ENABLE_SSE                 "Enable SSE instructions"                                  ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 207 OCV_OPTION(ENABLE_SSE2                "Enable SSE2 instructions"                                 ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 208 OCV_OPTION(ENABLE_SSE3                "Enable SSE3 instructions"                                 ON   IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 209 OCV_OPTION(ENABLE_SSSE3               "Enable SSSE3 instructions"                                OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 210 OCV_OPTION(ENABLE_SSE41               "Enable SSE4.1 instructions"                               OFF  IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 211 OCV_OPTION(ENABLE_SSE42               "Enable SSE4.2 instructions"                               OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 212 OCV_OPTION(ENABLE_AVX                 "Enable AVX instructions"                                  OFF  IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 213 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 214 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 215 OCV_OPTION(ENABLE_WINRT_MODE          "Build with Windows Runtime support"                       OFF  IF WIN32 )
 216
 217 # uncategorized options
 218 # ===================================================
 219 OCV_OPTION(CMAKE_VERBOSE "Verbose mode" OFF )
 220
 221 # backward compatibility
 222 # ===================================================
 223 include(cmake/OpenCVLegacyOptions.cmake OPTIONAL)
 224
 225
 226 # ----------------------------------------------------------------------------
 227 #  Get actual OpenCV version number from sources
 228 # ----------------------------------------------------------------------------
 229 include(cmake/OpenCVVersion.cmake)
 230
 231
 232 # ----------------------------------------------------------------------------
 233 #  Build & install layouts
 234 # ----------------------------------------------------------------------------
 235
 236 # Save libs and executables in the same place
 237 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications" )
 238
 239 if(ANDROID OR WIN32)
 240   set(OPENCV_DOC_INSTALL_PATH doc)
 241 elseif(INSTALL_TO_MANGLED_PATHS)
 242   set(OPENCV_DOC_INSTALL_PATH share/OpenCV-${OPENCV_VERSION}/doc)
 243 else()
 244   set(OPENCV_DOC_INSTALL_PATH share/OpenCV/doc)
 245 endif()
 246
 247 if(ANDROID)
 248   set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 249   set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 250   set(OPENCV_LIB_INSTALL_PATH     sdk/native/libs/${ANDROID_NDK_ABI_NAME})
 251   set(OPENCV_3P_LIB_INSTALL_PATH  sdk/native/3rdparty/libs/${ANDROID_NDK_ABI_NAME})
 252   set(OPENCV_CONFIG_INSTALL_PATH  sdk/native/jni)
 253   set(OPENCV_INCLUDE_INSTALL_PATH sdk/native/jni/include)
 254 else()
 255   set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib")
 256   set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib${LIB_SUFFIX}")
 257   set(OPENCV_LIB_INSTALL_PATH     lib${LIB_SUFFIX})
 258   set(OPENCV_3P_LIB_INSTALL_PATH  share/OpenCV/3rdparty/${OPENCV_LIB_INSTALL_PATH})
 259   set(OPENCV_INCLUDE_INSTALL_PATH include)
 260
 261   math(EXPR SIZEOF_VOID_P_BITS "8 * ${CMAKE_SIZEOF_VOID_P}")
 262   if(LIB_SUFFIX AND NOT SIZEOF_VOID_P_BITS EQUAL LIB_SUFFIX)
 263     set(OPENCV_CONFIG_INSTALL_PATH lib${LIB_SUFFIX}/cmake/opencv)
 264   else()
 265     set(OPENCV_CONFIG_INSTALL_PATH share/OpenCV)
 266   endif()
 267 endif()
 268
 269 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 270 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 271
 272 if(INSTALL_TO_MANGLED_PATHS)
 273   set(OPENCV_INCLUDE_INSTALL_PATH ${OPENCV_INCLUDE_INSTALL_PATH}/opencv-${OPENCV_VERSION})
 274 endif()
 275
 276 if(WIN32)
 277   # Postfix of DLLs:
 278   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 279   set(OPENCV_DEBUG_POSTFIX d)
 280 else()
 281   # Postfix of so's:
 282   set(OPENCV_DLLVERSION "")
 283   set(OPENCV_DEBUG_POSTFIX "")
 284 endif()
 285
 286 if(DEFINED CMAKE_DEBUG_POSTFIX)
 287   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 288 endif()
 289
 290 if(CMAKE_VERBOSE)
 291   set(CMAKE_VERBOSE_MAKEFILE 1)
 292 endif()
 293
 294
 295 # ----------------------------------------------------------------------------
 296 #  Path for build/platform -specific headers
 297 # ----------------------------------------------------------------------------
 298 set(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 299 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 300
 301 # ----------------------------------------------------------------------------
 302 #  Path for additional modules
 303 # ----------------------------------------------------------------------------
 304 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules")
 305
 306 # ----------------------------------------------------------------------------
 307 #  Autodetect if we are in a GIT repository
 308 # ----------------------------------------------------------------------------
 309
 310 # don't use FindGit because it requires CMake 2.8.2
 311 set(git_names git eg) # eg = easy git
 312 # Prefer .cmd variants on Windows unless running in a Makefile in the MSYS shell
 313 if(CMAKE_HOST_WIN32)
 314   if(NOT CMAKE_GENERATOR MATCHES "MSYS")
 315     set(git_names git.cmd git eg.cmd eg)
 316   endif()
 317 endif()
 318
 319 find_host_program(GIT_EXECUTABLE NAMES ${git_names} PATH_SUFFIXES Git/cmd Git/bin DOC "git command line client")
 320 mark_as_advanced(GIT_EXECUTABLE)
 321
 322 if(GIT_EXECUTABLE)
 323   execute_process(COMMAND ${GIT_EXECUTABLE} describe --tags --always --dirty --match "2.[0-9].[0-9]*"
 324     WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 325     OUTPUT_VARIABLE OPENCV_VCSVERSION
 326     RESULT_VARIABLE GIT_RESULT
 327     ERROR_QUIET
 328     OUTPUT_STRIP_TRAILING_WHITESPACE
 329   )
 330   if(NOT GIT_RESULT EQUAL 0)
 331     set(OPENCV_VCSVERSION "unknown")
 332   endif()
 333 else()
 334   # We don't have git:
 335   set(OPENCV_VCSVERSION "unknown")
 336 endif()
 337
 338
 339 # ----------------------------------------------------------------------------
 340 # OpenCV compiler and linker options
 341 # ----------------------------------------------------------------------------
 342 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 343 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 344   set(CMAKE_BUILD_TYPE Release)
 345 endif()
 346
 347 include(cmake/OpenCVCompilerOptions.cmake)
 348
 349
 350 # ----------------------------------------------------------------------------
 351 # Use statically or dynamically linked CRT?
 352 # Default: dynamic
 353 # ----------------------------------------------------------------------------
 354 if(MSVC)
 355   include(cmake/OpenCVCRTLinkage.cmake)
 356 endif(MSVC)
 357
 358 if(WIN32 AND NOT MINGW)
 359   add_definitions(-D_VARIADIC_MAX=10)
 360 endif(WIN32 AND NOT MINGW)
 361
 362
 363 # ----------------------------------------------------------------------------
 364 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 365 # ----------------------------------------------------------------------------
 366 if(UNIX)
 367   include(cmake/OpenCVFindPkgConfig.cmake OPTIONAL)
 368   include(CheckFunctionExists)
 369   include(CheckIncludeFile)
 370
 371   if(NOT APPLE)
 372     CHECK_INCLUDE_FILE(pthread.h HAVE_LIBPTHREAD)
 373     if(ANDROID)
 374       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 375     elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD|NetBSD|DragonFly")
 376       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 377     else()
 378       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 379     endif()
 380   else()
 381     set(HAVE_LIBPTHREAD YES)
 382   endif()
 383 endif()
 384
 385 include(cmake/OpenCVPCHSupport.cmake)
 386 include(cmake/OpenCVModule.cmake)
 387
 388 # ----------------------------------------------------------------------------
 389 #  Detect 3rd-party libraries
 390 # ----------------------------------------------------------------------------
 391
 392 include(cmake/OpenCVFindLibsGrfmt.cmake)
 393 include(cmake/OpenCVFindLibsGUI.cmake)
 394 include(cmake/OpenCVFindLibsVideo.cmake)
 395 include(cmake/OpenCVFindLibsPerf.cmake)
 396
 397
 398 # ----------------------------------------------------------------------------
 399 #  Detect other 3rd-party libraries/tools
 400 # ----------------------------------------------------------------------------
 401
 402 # --- LATEX for pdf documentation ---
 403 if(BUILD_DOCS)
 404   include(cmake/OpenCVFindLATEX.cmake)
 405 endif(BUILD_DOCS)
 406
 407 # --- Python Support ---
 408 include(cmake/OpenCVDetectPython.cmake)
 409
 410 # --- Java Support ---
 411 include(cmake/OpenCVDetectApacheAnt.cmake)
 412 if(ANDROID)
 413   include(cmake/OpenCVDetectAndroidSDK.cmake)
 414
 415   if(NOT ANDROID_TOOLS_Pkg_Revision GREATER 13)
 416     message(WARNING "OpenCV requires Android SDK tools revision 14 or newer. Otherwise tests and samples will no be compiled.")
 417   endif()
 418 else()
 419   find_package(JNI)
 420 endif()
 421
 422 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 423   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 424 else()
 425   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 426 endif()
 427
 428 # --- OpenCL ---
 429 if(WITH_OPENCL)
 430   include(cmake/OpenCVDetectOpenCL.cmake)
 431 endif()
 432
 433 # ----------------------------------------------------------------------------
 434 # Solution folders:
 435 # ----------------------------------------------------------------------------
 436 if(ENABLE_SOLUTION_FOLDERS)
 437   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 438   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 439 endif()
 440
 441 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 442 include(cmake/OpenCVExtraTargets.cmake)
 443
 444
 445 # ----------------------------------------------------------------------------
 446 # Process subdirectories
 447 # ----------------------------------------------------------------------------
 448
 449 # opencv.hpp and legacy headers
 450 add_subdirectory(include)
 451
 452 # OpenCV modules
 453 add_subdirectory(modules)
 454
 455 # Generate targets for documentation
 456 add_subdirectory(doc)
 457
 458 # various data that is used by cv libraries and/or demo applications.
 459 add_subdirectory(data)
 460
 461 # extra applications
 462 if(BUILD_opencv_apps)
 463   add_subdirectory(apps)
 464 endif()
 465
 466 # examples
 467 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES)
 468   add_subdirectory(samples)
 469 endif()
 470
 471 if(ANDROID)
 472   add_subdirectory(platforms/android/service)
 473 endif()
 474
 475 if(BUILD_ANDROID_PACKAGE)
 476   add_subdirectory(platforms/android/package)
 477 endif()
 478
 479 if (ANDROID)
 480   add_subdirectory(platforms/android/libinfo)
 481 endif()
 482
 483 # ----------------------------------------------------------------------------
 484 # Finalization: generate configuration-based files
 485 # ----------------------------------------------------------------------------
 486 ocv_track_build_dependencies()
 487
 488 # Generate platform-dependent and configuration-dependent headers
 489 include(cmake/OpenCVGenHeaders.cmake)
 490
 491 # Generate opencv.pc for pkg-config command
 492 include(cmake/OpenCVGenPkgconfig.cmake)
 493
 494 # Generate OpenCV.mk for ndk-build (Android build tool)
 495 include(cmake/OpenCVGenAndroidMK.cmake)
 496
 497 # Generate OpenCVСonfig.cmake and OpenCVConfig-version.cmake for cmake projects
 498 include(cmake/OpenCVGenConfig.cmake)
 499
 500
 501 # ----------------------------------------------------------------------------
 502 # Summary:
 503 # ----------------------------------------------------------------------------
 504 status("")
 505 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 506 if(OPENCV_VCSVERSION)
 507   status("  Version control:" ${OPENCV_VCSVERSION})
 508 endif()
 509
 510 # ========================== build platform ==========================
 511 status("")
 512 status("  Platform:")
 513 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
 514 if(CMAKE_CROSSCOMPILING)
 515   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
 516 endif()
 517 status("    CMake:"            ${CMAKE_VERSION})
 518 status("    CMake generator:"  ${CMAKE_GENERATOR})
 519 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
 520 if(MSVC)
 521   status("    MSVC:"           ${MSVC_VERSION})
 522 endif()
 523 if(CMAKE_GENERATOR MATCHES Xcode)
 524   status("    Xcode:"          ${XCODE_VERSION})
 525 endif()
 526 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
 527   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
 528 endif()
 529
 530 # ========================== C/C++ options ==========================
 531 if(CMAKE_CXX_COMPILER_VERSION)
 532   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
 533 elseif(CMAKE_COMPILER_IS_CLANGCXX)
 534   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CLANG_REGEX_VERSION})")
 535 elseif(CMAKE_COMPILER_IS_GNUCXX)
 536   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_GCC_REGEX_VERSION})")
 537 else()
 538   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 539 endif()
 540 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
 541
 542 status("")
 543 status("  C/C++:")
 544 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
 545 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
 546 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
 547 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
 548 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
 549 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
 550 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
 551 if(WIN32)
 552   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
 553   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
 554 else()
 555   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
 556   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
 557 endif()
 558 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
 559
 560 # ========================== OpenCV modules ==========================
 561 status("")
 562 status("  OpenCV modules:")
 563 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD}")
 564 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
 565 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
 566 set(OPENCV_MODULES_DISABLED_AUTO_ST "")
 567 foreach(m ${OPENCV_MODULES_DISABLED_AUTO})
 568   set(__mdeps "")
 569   foreach(d ${OPENCV_MODULE_${m}_DEPS})
 570     if(d MATCHES "^opencv_" AND NOT HAVE_${d})
 571       list(APPEND __mdeps ${d})
 572     endif()
 573   endforeach()
 574   if(__mdeps)
 575     list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}(deps: ${__mdeps})")
 576   else()
 577     list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}")
 578   endif()
 579 endforeach()
 580 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO_ST}")
 581
 582 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
 583 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
 584 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
 585 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
 586
 587 # ========================== Android details ==========================
 588 if(ANDROID)
 589   status("")
 590   status("  Android: ")
 591   status("    Android ABI:" ${ANDROID_ABI})
 592   status("    STL type:" ${ANDROID_STL})
 593   status("    Native API level:" android-${ANDROID_NATIVE_API_LEVEL})
 594   android_get_compatible_target(android_sdk_target_status ${ANDROID_NATIVE_API_LEVEL} ${ANDROID_SDK_TARGET} 11)
 595   status("    SDK target:" "${android_sdk_target_status}")
 596   if(BUILD_WITH_ANDROID_NDK)
 597     status("    Android NDK:" "${ANDROID_NDK} (toolchain: ${ANDROID_TOOLCHAIN_NAME})")
 598   elseif(BUILD_WITH_STANDALONE_TOOLCHAIN)
 599     status("    Android toolchain:" "${ANDROID_STANDALONE_TOOLCHAIN}")
 600   endif()
 601   status("    android tool:"  ANDROID_EXECUTABLE  THEN "${ANDROID_EXECUTABLE} (${ANDROID_TOOLS_Pkg_Desc})" ELSE NO)
 602   status("    Google Play package:" BUILD_ANDROID_PACKAGE                                         THEN YES ELSE NO)
 603   status("    Android examples:"    BUILD_ANDROID_EXAMPLES AND CAN_BUILD_ANDROID_PROJECTS         THEN YES ELSE NO)
 604 endif()
 605
 606 # ================== Windows RT features ==================
 607 if(WIN32)
 608 status("")
 609     status("  Windows RT support:" HAVE_WINRT THEN YES ELSE NO)
 610     if (ENABLE_WINRT_MODE)
 611       status("    Windows SDK v8.0:" ${WINDOWS_SDK_PATH})
 612       status("    Visual Studio 2012:" ${VISUAL_STUDIO_PATH})
 613     endif()
 614 endif(WIN32)
 615
 616 # ========================== GUI ==========================
 617 status("")
 618 status("  GUI: ")
 619
 620 if(HAVE_QT5)
 621   status("    QT 5.x:"            HAVE_QT        THEN "YES (ver ${Qt5Core_VERSION_STRING})" ELSE NO)
 622   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt5OpenGL_LIBRARIES} ${Qt5OpenGL_VERSION_STRING})" ELSE NO)
 623 elseif(HAVE_QT)
 624   status("    QT 4.x:"            HAVE_QT        THEN "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})" ELSE NO)
 625   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
 626 else()
 627   if(DEFINED WITH_QT)
 628     status("    QT:" NO)
 629   endif()
 630   if(DEFINED WITH_WIN32UI)
 631     status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
 632   else()
 633     if(APPLE)
 634       if(WITH_CARBON)
 635         status("    Carbon:" YES)
 636       else()
 637         status("    Cocoa:"  YES)
 638       endif()
 639     else()
 640       status("    GTK+ 2.x:" HAVE_GTK      THEN "YES (ver ${ALIASOF_gtk+-2.0_VERSION})"     ELSE NO)
 641       status("    GThread :" HAVE_GTHREAD  THEN "YES (ver ${ALIASOF_gthread-2.0_VERSION})"  ELSE NO)
 642       status("    GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${ALIASOF_gtkglext-1.0_VERSION})" ELSE NO)
 643     endif()
 644   endif()
 645 endif()
 646
 647 status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
 648
 649 # ========================== MEDIA IO ==========================
 650 status("")
 651 status("  Media I/O: ")
 652 status("    ZLib:"         BUILD_ZLIB    THEN "build (ver ${ZLIB_VERSION_STRING})"               ELSE "${ZLIB_LIBRARY} (ver ${ZLIB_VERSION_STRING})")
 653
 654 if(WITH_JPEG)
 655   status("    JPEG:"       JPEG_FOUND    THEN "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})"        ELSE "build (ver ${JPEG_LIB_VERSION})")
 656 else()
 657   status("    JPEG:"       "NO")
 658 endif()
 659 if(WITH_PNG)
 660   status("    PNG:"        PNG_FOUND     THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})"              ELSE "build (ver ${PNG_VERSION})")
 661 else()
 662   status("    PNG:"        "NO")
 663 endif()
 664 if(WITH_TIFF)
 665   if(TIFF_VERSION_STRING AND TIFF_FOUND)
 666     status("    TIFF:"     "${TIFF_LIBRARY} (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 667   else()
 668     status("    TIFF:"     TIFF_FOUND    THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION})"            ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 669   endif()
 670 else()
 671   status("    TIFF:"       "NO")
 672 endif()
 673 if(WITH_JASPER)
 674   status("    JPEG 2000:"  JASPER_FOUND  THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
 675 else()
 676   status("    JPEG 2000:"  "NO")
 677 endif()
 678 if(WITH_OPENEXR)
 679   status("    OpenEXR:"  OPENEXR_FOUND  THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
 680 else()
 681   status("    OpenEXR:"  "NO")
 682 endif()
 683
 684 # ========================== VIDEO IO ==========================
 685 status("")
 686 status("  Video I/O:")
 687
 688 if (DEFINED WITH_VFW)
 689   status("    Video for Windows:" HAVE_VFW         THEN YES                                        ELSE NO)
 690 endif(DEFINED WITH_VFW)
 691
 692 if(DEFINED WITH_1394)
 693   status("    DC1394 1.x:"     HAVE_DC1394         THEN "YES (ver ${ALIASOF_libdc1394_VERSION})"   ELSE NO)
 694   status("    DC1394 2.x:"     HAVE_DC1394_2       THEN "YES (ver ${ALIASOF_libdc1394-2_VERSION})" ELSE NO)
 695 endif(DEFINED WITH_1394)
 696
 697 if(ANDROID)
 698   if(HAVE_opencv_androidcamera)
 699     status("    AndroidNativeCamera:" BUILD_ANDROID_CAMERA_WRAPPER
 700                                                    THEN "YES, build for Android${ANDROID_VERSION}" ELSE "YES, use prebuilt libraries")
 701   else()
 702     status("    AndroidNativeCamera:" "NO (native camera requires Android API level 8 or higher)")
 703   endif()
 704 endif()
 705
 706 if(DEFINED WITH_AVFOUNDATION)
 707   status("    AVFoundation:"   WITH_AVFOUNDATION   THEN YES                                        ELSE NO)
 708 endif(DEFINED WITH_AVFOUNDATION)
 709
 710 if(DEFINED WITH_FFMPEG)
 711   if(WIN32)
 712     status("    FFMPEG:"       WITH_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
 713   else()
 714     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
 715   endif()
 716   status("      codec:"        HAVE_FFMPEG_CODEC   THEN "YES (ver ${ALIASOF_libavcodec_VERSION})"  ELSE NO)
 717   status("      format:"       HAVE_FFMPEG_FORMAT  THEN "YES (ver ${ALIASOF_libavformat_VERSION})" ELSE NO)
 718   status("      util:"         HAVE_FFMPEG_UTIL    THEN "YES (ver ${ALIASOF_libavutil_VERSION})"   ELSE NO)
 719   status("      swscale:"      HAVE_FFMPEG_SWSCALE THEN "YES (ver ${ALIASOF_libswscale_VERSION})"  ELSE NO)
 720   status("      gentoo-style:" HAVE_GENTOO_FFMPEG  THEN YES                                        ELSE NO)
 721 endif(DEFINED WITH_FFMPEG)
 722
 723 if(DEFINED WITH_GSTREAMER)
 724   status("    GStreamer:"      HAVE_GSTREAMER      THEN ""                                         ELSE NO)
 725   if(HAVE_GSTREAMER)
 726     status("      base:"       "YES (ver ${ALIASOF_gstreamer-base-0.10_VERSION})")
 727     status("      app:"        "YES (ver ${ALIASOF_gstreamer-app-0.10_VERSION})")
 728     status("      video:"      "YES (ver ${ALIASOF_gstreamer-video-0.10_VERSION})")
 729   endif()
 730 endif(DEFINED WITH_GSTREAMER)
 731
 732 if(DEFINED WITH_OPENNI)
 733   status("    OpenNI:"         HAVE_OPENNI         THEN "YES (ver ${OPENNI_VERSION_STRING}, build ${OPENNI_VERSION_BUILD})"
 734                                                                                                    ELSE NO)
 735   status("    OpenNI PrimeSensor Modules:" HAVE_OPENNI_PRIME_SENSOR_MODULE
 736                                                    THEN "YES (${OPENNI_PRIME_SENSOR_MODULE})"      ELSE NO)
 737 endif(DEFINED WITH_OPENNI)
 738
 739 if(DEFINED WITH_PVAPI)
 740   status("    PvAPI:"          HAVE_PVAPI          THEN YES                                        ELSE NO)
 741 endif(DEFINED WITH_PVAPI)
 742
 743 if(DEFINED WITH_GIGEAPI)
 744   status("    GigEVisionSDK:"  HAVE_GIGE_API       THEN YES                                        ELSE NO)
 745 endif(DEFINED WITH_GIGEAPI)
 746
 747 if(DEFINED WITH_QUICKTIME)
 748   status("    QuickTime:"      WITH_QUICKTIME      THEN YES                                        ELSE NO)
 749   status("    QTKit:"          WITH_QUICKTIME      THEN NO                                         ELSE YES)
 750 endif(DEFINED WITH_QUICKTIME)
 751
 752 if(DEFINED WITH_UNICAP)
 753   status("    UniCap:"         HAVE_UNICAP         THEN "YES (ver ${ALIASOF_libunicap_VERSION})"   ELSE NO)
 754   status("    UniCap ucil:"    HAVE_UNICAP_UCIL    THEN "YES (ver ${ALIASOF_libucil_VERSION})"     ELSE NO)
 755 endif(DEFINED WITH_UNICAP)
 756
 757 if(DEFINED WITH_V4L)
 758   if(HAVE_CAMV4L)
 759     set(HAVE_CAMV4L_STR "YES")
 760   else()
 761     set(HAVE_CAMV4L_STR "NO")
 762   endif()
 763   if(HAVE_CAMV4L2)
 764     set(HAVE_CAMV4L2_STR "YES")
 765   elseif(HAVE_VIDEOIO)
 766     set(HAVE_CAMV4L2_STR "YES(videoio)")
 767   else()
 768     set(HAVE_CAMV4L2_STR "NO")
 769   endif()
 770   status("    V4L/V4L2:"       HAVE_LIBV4L         THEN "Using libv4l (ver ${ALIASOF_libv4l1_VERSION})"
 771                                                    ELSE "${HAVE_CAMV4L_STR}/${HAVE_CAMV4L2_STR}")
 772 endif(DEFINED WITH_V4L)
 773
 774 if(DEFINED WITH_DSHOW)
 775   status("    DirectShow:"     HAVE_DSHOW     THEN YES                                        ELSE NO)
 776 endif(DEFINED WITH_DSHOW)
 777
 778 if(DEFINED WITH_MSMF)
 779   status("    Media Foundation:" HAVE_MSMF    THEN YES                                        ELSE NO)
 780 endif(DEFINED WITH_MSMF)
 781
 782 if(DEFINED WITH_XIMEA)
 783   status("    XIMEA:"          HAVE_XIMEA          THEN YES                                        ELSE NO)
 784 endif(DEFINED WITH_XIMEA)
 785
 786 if(DEFINED WITH_XINE)
 787   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${ALIASOF_libxine_VERSION})"     ELSE NO)
 788 endif(DEFINED WITH_XINE)
 789
 790 # ========================== Other third-party libraries ==========================
 791 status("")
 792 status("  Other third-party libraries:")
 793
 794 if(WITH_IPP AND IPP_FOUND)
 795   status("    Use IPP:" "${IPP_LATEST_VERSION_STR} [${IPP_LATEST_VERSION_MAJOR}.${IPP_LATEST_VERSION_MINOR}.${IPP_LATEST_VERSION_BUILD}]")
 796   status("         at:" "${IPP_ROOT_DIR}")
 797 else()
 798   status("    Use IPP:"   WITH_IPP AND NOT IPP_FOUND THEN "IPP not found" ELSE NO)
 799 endif()
 800
 801 status("    Use Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
 802 status("    Use TBB:"        HAVE_TBB         THEN "YES (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})" ELSE NO)
 803 status("    Use OpenMP:"     HAVE_OPENMP      THEN YES ELSE NO)
 804 status("    Use GCD"         HAVE_GCD         THEN YES ELSE NO)
 805 status("    Use Concurrency" HAVE_CONCURRENCY THEN YES ELSE NO)
 806 status("    Use C=:"         HAVE_CSTRIPES    THEN YES ELSE NO)
 807 status("    Use Cuda:"       HAVE_CUDA        THEN "YES (ver ${CUDA_VERSION_STRING})" ELSE NO)
 808 status("    Use OpenCL:"     HAVE_OPENCL      THEN YES ELSE NO)
 809
 810 if(HAVE_CUDA)
 811   status("")
 812   status("  NVIDIA CUDA")
 813
 814   status("    Use CUFFT:"            HAVE_CUFFT   THEN YES ELSE NO)
 815   status("    Use CUBLAS:"           HAVE_CUBLAS  THEN YES ELSE NO)
 816   status("    USE NVCUVID:"          HAVE_NVCUVID THEN YES ELSE NO)
 817   status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
 818   status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
 819   status("    Use fast math:"        CUDA_FAST_MATH THEN YES ELSE NO)
 820 endif()
 821
 822 if(HAVE_OPENCL)
 823   status("")
 824   status("  OpenCL")
 825   if(OPENCL_INCLUDE_DIR)
 826     status("    Include path:"       ${OPENCL_INCLUDE_DIRS})
 827   endif()
 828   if(OPENCL_LIBRARIES)
 829     status("    libraries:"          ${OPENCL_LIBRARIES})
 830   endif()
 831   status("    Use AMD FFT:"          HAVE_CLAMDFFT  THEN YES ELSE NO)
 832   status("    Use AMD BLAS:"         HAVE_CLAMDBLAS THEN YES ELSE NO)
 833 endif()
 834
 835 # ========================== python ==========================
 836 status("")
 837 status("  Python:")
 838 status("    Interpreter:"     PYTHON_EXECUTABLE   THEN "${PYTHON_EXECUTABLE} (ver ${PYTHON_VERSION_FULL})"         ELSE NO)
 839 if(BUILD_opencv_python)
 840   if(PYTHONLIBS_VERSION_STRING)
 841     status("    Libraries:"   HAVE_opencv_python  THEN  "${PYTHON_LIBRARIES} (ver ${PYTHONLIBS_VERSION_STRING})"   ELSE NO)
 842   else()
 843     status("    Libraries:"   HAVE_opencv_python  THEN  ${PYTHON_LIBRARIES}                                        ELSE NO)
 844   endif()
 845   status("    numpy:"         PYTHON_USE_NUMPY    THEN "${PYTHON_NUMPY_INCLUDE_DIR} (ver ${PYTHON_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
 846   status("    packages path:" PYTHON_EXECUTABLE   THEN "${PYTHON_PACKAGES_PATH}"                                   ELSE "-")
 847 endif()
 848
 849 # ========================== java ==========================
 850 status("")
 851 status("  Java:")
 852 status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
 853 if(NOT ANDROID)
 854   status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
 855 endif()
 856 status("    Java tests:"    BUILD_TESTS AND (CAN_BUILD_ANDROID_PROJECTS OR HAVE_opencv_java)            THEN YES ELSE NO)
 857
 858 # ========================== documentation ==========================
 859 if(BUILD_DOCS)
 860   status("")
 861   status("  Documentation:")
 862   if(HAVE_SPHINX)
 863     status("    Build Documentation:" PDFLATEX_COMPILER      THEN YES ELSE "YES (only HTML and without math expressions)")
 864   else()
 865     status("    Build Documentation:" NO)
 866   endif()
 867   status("    Sphinx:"              HAVE_SPHINX              THEN "${SPHINX_BUILD} (ver ${SPHINX_VERSION})" ELSE NO)
 868   status("    PdfLaTeX compiler:"   PDFLATEX_COMPILER        THEN "${PDFLATEX_COMPILER}" ELSE NO)
 869 endif()
 870
 871 # ========================== samples and tests ==========================
 872 status("")
 873 status("  Tests and samples:")
 874 status("    Tests:"             BUILD_TESTS AND HAVE_opencv_ts       THEN YES ELSE NO)
 875 status("    Performance tests:" BUILD_PERF_TESTS AND HAVE_opencv_ts  THEN YES ELSE NO)
 876 status("    C/C++ Examples:"    BUILD_EXAMPLES                       THEN YES ELSE NO)
 877
 878 # ========================== auxiliary ==========================
 879 status("")
 880 status("  Install path:" "${CMAKE_INSTALL_PREFIX}")
 881 status("")
 882 status("  cvconfig.h is in:" "${OPENCV_CONFIG_FILE_INCLUDE_DIR}")
 883 status("-----------------------------------------------------------------")
 884 status("")
 885
 886 ocv_finalize_status()
 887
 888 # ----------------------------------------------------------------------------
 889 # Warn in the case of in-source build
 890 # ----------------------------------------------------------------------------
 891 if("${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 892   message(WARNING "The source directory is the same as binary directory. \"make clean\" may damage the source tree")
 893 endif()
 894