CMakeLists.txt

   1 ## CMake configuration file of gflags project
   2 ##
   3 ## This CMakeLists.txt defines some gflags specific configuration variables
   4 ## using the "gflags_define" utility macro. The default values of these variables
   5 ## can be overridden either on the CMake command-line using the -D option of
   6 ## the cmake command or in a super-project which includes the gflags source
   7 ## tree by setting the GFLAGS_<varname> CMake variables before adding the
   8 ## gflags source directory via CMake's "add_subdirectory" command. Only when
   9 ## the non-cached variable GFLAGS_IS_SUBPROJECT has a value equivalent to FALSE,
  10 ## these configuration variables are added to the CMake cache so they can be
  11 ## edited in the CMake GUI. By default, GFLAGS_IS_SUBPROJECT is set to TRUE when
  12 ## the CMAKE_SOURCE_DIR is not identical to the directory of this CMakeLists.txt
  13 ## file, i.e., the top-level directory of the gflags project source tree.
  14 ##
  15 ## When this project is a subproject (GFLAGS_IS_SUBPROJECT is TRUE), the default
  16 ## settings are such that only the static single-threaded library is built without
  17 ## installation of the gflags files. The "gflags" target is in this case an ALIAS
  18 ## library target for the "gflags_nothreads_static" library target. Targets which
  19 ## depend on the gflags library should link to the "gflags" library target.
  20 ##
  21 ## Example CMakeLists.txt of user project which requires separate gflags installation:
  22 ##   cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
  23 ##
  24 ##   project(Foo)
  25 ##
  26 ##   find_package(gflags REQUIRED)
  27 ##
  28 ##   add_executable(foo src/foo.cc)
  29 ##   target_link_libraries(foo gflags)
  30 ##
  31 ## Example CMakeLists.txt of user project which requires separate single-threaded static gflags installation:
  32 ##   cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
  33 ##
  34 ##   project(Foo)
  35 ##
  36 ##   find_package(gflags COMPONENTS nothreads_static)
  37 ##
  38 ##   add_executable(foo src/foo.cc)
  39 ##   target_link_libraries(foo gflags)
  40 ##
  41 ## Example CMakeLists.txt of super-project which contains gflags source tree:
  42 ##   cmake_minimum_required(VERSION 2.8.12 FATAL_ERROR)
  43 ##
  44 ##   project(Foo)
  45 ##
  46 ##   add_subdirectory(gflags)
  47 ##
  48 ##   add_executable(foo src/foo.cc)
  49 ##   target_link_libraries(foo gflags)
  50 ##
  51 ## Variables to configure the source files:
  52 ## - GFLAGS_IS_A_DLL
  53 ## - GFLAGS_NAMESPACE
  54 ## - GFLAGS_ATTRIBUTE_UNUSED
  55 ## - GFLAGS_INTTYPES_FORMAT
  56 ##
  57 ## Variables to configure the build:
  58 ## - GFLAGS_SOVERSION
  59 ## - GFLAGS_BUILD_SHARED_LIBS
  60 ## - GFLAGS_BUILD_STATIC_LIBS
  61 ## - GFLAGS_BUILD_gflags_LIB
  62 ## - GFLAGS_BUILD_gflags_nothreads_LIB
  63 ## - GFLAGS_BUILD_TESTING
  64 ## - GFLAGS_BUILD_PACKAGING
  65 ##
  66 ## Variables to configure the installation:
  67 ## - GFLAGS_INCLUDE_DIR
  68 ## - GFLAGS_LIBRARY_INSTALL_DIR or LIB_INSTALL_DIR or LIB_SUFFIX
  69 ## - GFLAGS_INSTALL_HEADERS
  70 ## - GFLAGS_INSTALL_SHARED_LIBS
  71 ## - GFLAGS_INSTALL_STATIC_LIBS
  72
  73 cmake_minimum_required (VERSION 2.8.12 FATAL_ERROR)
  74
  75 if (POLICY CMP0042)
  76   cmake_policy (SET CMP0042 NEW)
  77 endif ()
  78
  79 # ----------------------------------------------------------------------------
  80 # includes
  81 set (CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  82 include (utils)
  83
  84 # ----------------------------------------------------------------------------
  85 # package information
  86 set (PACKAGE_NAME        "gflags")
  87 set (PACKAGE_VERSION     "2.2.0")
  88 set (PACKAGE_STRING      "${PACKAGE_NAME} ${PACKAGE_VERSION}")
  89 set (PACKAGE_TARNAME     "${PACKAGE_NAME}-${PACKAGE_VERSION}")
  90 set (PACKAGE_BUGREPORT   "https://github.com/gflags/gflags/issues")
  91 set (PACKAGE_DESCRIPTION "A commandline flags library that allows for distributed flags.")
  92 set (PACKAGE_URL         "http://gflags.github.io/gflags")
  93
  94 project (${PACKAGE_NAME} CXX)
  95 if (CMAKE_VERSION VERSION_LESS 100)
  96   # C language still needed because the following required CMake modules
  97   # (or their dependencies, respectively) are not correctly handling
  98   # the case where only CXX is enabled.
  99   # - CheckTypeSize.cmake (fixed in CMake 3.1, cf. http://www.cmake.org/Bug/view.php?id=14056)
 100   # - FindThreads.cmake (--> CheckIncludeFiles.cmake <--)
 101   enable_language (C)
 102 endif ()
 103
 104 version_numbers (
 105   ${PACKAGE_VERSION}
 106     PACKAGE_VERSION_MAJOR
 107     PACKAGE_VERSION_MINOR
 108     PACKAGE_VERSION_PATCH
 109 )
 110
 111 # shared library ABI version number, can be overridden by package maintainers
 112 # using -DGFLAGS_SOVERSION=XXX on the command-line
 113 if (GFLAGS_SOVERSION)
 114   set (PACKAGE_SOVERSION "${GFLAGS_SOVERSION}")
 115 else ()
 116   # TODO: Change default SOVERSION back to PACKAGE_VERSION_MAJOR with the
 117   #       next increase of major version number (i.e., 3.0.0 -> SOVERSION 3)
 118   #       The <major>.<minor> SOVERSION should be used for the 2.x releases
 119   #       versions only which temporarily broke the API by changing the default
 120   #       namespace from "google" to "gflags".
 121   set (PACKAGE_SOVERSION "${PACKAGE_VERSION_MAJOR}.${PACKAGE_VERSION_MINOR}")
 122 endif ()
 123
 124 # when gflags is included as subproject (e.g., as Git submodule/subtree) in the source
 125 # tree of a project that uses it, no variables should be added to the CMake cache;
 126 # users may set the non-cached variable GFLAGS_IS_SUBPROJECT before add_subdirectory(gflags)
 127 if (NOT DEFINED GFLAGS_IS_SUBPROJECT)
 128   if ("^${CMAKE_SOURCE_DIR}$" STREQUAL "^${PROJECT_SOURCE_DIR}$")
 129     set (GFLAGS_IS_SUBPROJECT FALSE)
 130   else ()
 131     set (GFLAGS_IS_SUBPROJECT TRUE)
 132   endif ()
 133 endif ()
 134
 135 # prefix for package variables in CMake configuration file
 136 string (TOUPPER "${PACKAGE_NAME}" PACKAGE_PREFIX)
 137
 138 # convert file path on Windows with back slashes to path with forward slashes
 139 # otherwise this causes an issue with the cmake_install.cmake script
 140 file (TO_CMAKE_PATH "${CMAKE_INSTALL_PREFIX}" CMAKE_INSTALL_PREFIX)
 141
 142 # ----------------------------------------------------------------------------
 143 # options
 144
 145 # maintain binary backwards compatibility with gflags library version <= 2.0,
 146 # but at the same time enable the use of the preferred new "gflags" namespace
 147 gflags_define (STRING NAMESPACE "Name(s) of library namespace (separate multiple options by semicolon)" "google;${PACKAGE_NAME}" "${PACKAGE_NAME}")
 148 gflags_property (NAMESPACE ADVANCED TRUE)
 149 set (GFLAGS_NAMESPACE_SECONDARY "${NAMESPACE}")
 150 list (REMOVE_DUPLICATES GFLAGS_NAMESPACE_SECONDARY)
 151 if (NOT GFLAGS_NAMESPACE_SECONDARY)
 152   message (FATAL_ERROR "GFLAGS_NAMESPACE must be set to one (or more) valid C++ namespace identifier(s separated by semicolon \";\").")
 153 endif ()
 154 foreach (ns IN LISTS GFLAGS_NAMESPACE_SECONDARY)
 155   if (NOT ns MATCHES "^[a-zA-Z][a-zA-Z0-9_]*$")
 156     message (FATAL_ERROR "GFLAGS_NAMESPACE contains invalid namespace identifier: ${ns}")
 157   endif ()
 158 endforeach ()
 159 list (GET       GFLAGS_NAMESPACE_SECONDARY 0 GFLAGS_NAMESPACE)
 160 list (REMOVE_AT GFLAGS_NAMESPACE_SECONDARY 0)
 161
 162 # cached build options when gflags is not a subproject, otherwise non-cached CMake variables
 163 # usage: gflags_define(BOOL <name> <doc> <default> [<subproject default>])
 164 gflags_define (BOOL BUILD_SHARED_LIBS          "Request build of shared libraries."                                       OFF OFF)
 165 gflags_define (BOOL BUILD_STATIC_LIBS          "Request build of static libraries (default if BUILD_SHARED_LIBS is OFF)." OFF ON)
 166 gflags_define (BOOL BUILD_gflags_LIB           "Request build of the multi-threaded gflags library."                      ON  OFF)
 167 gflags_define (BOOL BUILD_gflags_nothreads_LIB "Request build of the single-threaded gflags library."                     ON  ON)
 168 gflags_define (BOOL BUILD_PACKAGING            "Enable build of distribution packages using CPack."                       OFF OFF)
 169 gflags_define (BOOL BUILD_TESTING              "Enable build of the unit tests and their execution using CTest."          OFF OFF)
 170 gflags_define (BOOL INSTALL_HEADERS            "Request installation of headers and other development files."             ON  OFF)
 171 gflags_define (BOOL INSTALL_SHARED_LIBS        "Request installation of shared libraries."                                ON  ON)
 172 gflags_define (BOOL INSTALL_STATIC_LIBS        "Request installation of static libraries."                                ON  OFF)
 173 gflags_define (BOOL REGISTER_BUILD_DIR         "Request entry of build directory in CMake's package registry."            OFF OFF)
 174 gflags_define (BOOL REGISTER_INSTALL_PREFIX    "Request entry of installed package in CMake's package registry."          ON  OFF)
 175
 176 gflags_property (BUILD_STATIC_LIBS   ADVANCED TRUE)
 177 gflags_property (INSTALL_HEADERS     ADVANCED TRUE)
 178 gflags_property (INSTALL_SHARED_LIBS ADVANCED TRUE)
 179 gflags_property (INSTALL_STATIC_LIBS ADVANCED TRUE)
 180
 181 if (NOT GFLAGS_IS_SUBPROJECT)
 182   foreach (varname IN ITEMS CMAKE_INSTALL_PREFIX)
 183     gflags_property (${varname} ADVANCED FALSE)
 184   endforeach ()
 185   foreach (varname IN ITEMS CMAKE_CONFIGURATION_TYPES CMAKE_OSX_ARCHITECTURES CMAKE_OSX_DEPLOYMENT_TARGET CMAKE_OSX_SYSROOT)
 186     gflags_property (${varname} ADVANCED TRUE)
 187   endforeach ()
 188   if (NOT CMAKE_BUILD_TYPE AND NOT CMAKE_CXX_FLAGS)
 189     gflags_set (CMAKE_BUILD_TYPE Release)
 190   endif ()
 191   if (CMAKE_CONFIGURATION_TYPES)
 192     gflags_property (CMAKE_BUILD_TYPE STRINGS "${CMAKE_CONFIGURATION_TYPES}")
 193   endif ()
 194 endif () # NOT GFLAGS_IS_SUBPROJECT
 195
 196 if (NOT BUILD_SHARED_LIBS AND NOT BUILD_STATIC_LIBS)
 197   set (BUILD_STATIC_LIBS ON)
 198 endif ()
 199 if (NOT BUILD_gflags_LIB AND NOT BUILD_gflags_nothreads_LIB)
 200   message (FATAL_ERROR "At least one of [GFLAGS_]BUILD_gflags_LIB and [GFLAGS_]BUILD_gflags_nothreads_LIB must be ON.")
 201 endif ()
 202
 203 gflags_define (STRING INCLUDE_DIR "Name of include directory of installed header files relative to CMAKE_INSTALL_PREFIX/include/" "${PACKAGE_NAME}")
 204 gflags_property (INCLUDE_DIR ADVANCED TRUE)
 205 file (TO_CMAKE_PATH "${INCLUDE_DIR}" INCLUDE_DIR)
 206 if (IS_ABSOLUTE INCLUDE_DIR)
 207   message (FATAL_ERROR "[GFLAGS_]INCLUDE_DIR must be a path relative to CMAKE_INSTALL_PREFIX/include/")
 208 endif ()
 209 if (INCLUDE_DIR MATCHES "^\\.\\.[/\\]")
 210   message (FATAL_ERROR "[GFLAGS_]INCLUDE_DIR must not start with parent directory reference (../)")
 211 endif ()
 212 set (GFLAGS_INCLUDE_DIR "${INCLUDE_DIR}")
 213
 214 # ----------------------------------------------------------------------------
 215 # system checks
 216 include (CheckTypeSize)
 217 include (CheckIncludeFileCXX)
 218 include (CheckCXXSymbolExists)
 219
 220 if (WIN32 AND NOT CYGWIN)
 221   set (OS_WINDOWS 1)
 222 else ()
 223   set (OS_WINDOWS 0)
 224 endif ()
 225
 226 if (MSVC)
 227   set (HAVE_SYS_TYPES_H 1)
 228   set (HAVE_STDINT_H    1)
 229   set (HAVE_STDDEF_H    1) # used by CheckTypeSize module
 230   set (HAVE_INTTYPES_H  0)
 231   set (HAVE_UNISTD_H    0)
 232   set (HAVE_SYS_STAT_H  1)
 233   set (HAVE_SHLWAPI_H   1)
 234 else ()
 235   foreach (fname IN ITEMS unistd stdint inttypes sys/types sys/stat fnmatch)
 236     string (TOUPPER "${fname}" FNAME)
 237     string (REPLACE "/" "_" FNAME "${FNAME}")
 238     if (NOT HAVE_${FNAME}_H)
 239       check_include_file_cxx ("${fname}.h" HAVE_${FNAME}_H)
 240     endif ()
 241   endforeach ()
 242   # the following are used in #if directives not #ifdef
 243   bool_to_int (HAVE_STDINT_H)
 244   bool_to_int (HAVE_SYS_TYPES_H)
 245   bool_to_int (HAVE_INTTYPES_H)
 246   if (NOT HAVE_FNMATCH_H AND OS_WINDOWS)
 247     check_include_file_cxx ("shlwapi.h" HAVE_SHLWAPI_H)
 248   endif ()
 249 endif ()
 250
 251 gflags_define (STRING INTTYPES_FORMAT "Format of integer types: \"C99\" (uint32_t), \"BSD\" (u_int32_t), \"VC7\" (__int32)" "")
 252 gflags_property (INTTYPES_FORMAT STRINGS "C99;BSD;VC7")
 253 gflags_property (INTTYPES_FORMAT ADVANCED TRUE)
 254 if (NOT INTTYPES_FORMAT)
 255   set (TYPES uint32_t u_int32_t)
 256   if (MSVC)
 257     list (INSERT TYPES 0 __int32)
 258   endif ()
 259   foreach (type IN LISTS TYPES)
 260     check_type_size (${type} ${type} LANGUAGE CXX)
 261     if (HAVE_${type})
 262       break ()
 263     endif ()
 264   endforeach ()
 265   if (HAVE_uint32_t)
 266     gflags_set (INTTYPES_FORMAT C99)
 267   elseif (HAVE_u_int32_t)
 268     gflags_set (INTTYPES_FORMAT BSD)
 269   elseif (HAVE___int32)
 270     gflags_set (INTTYPES_FORMAT VC7)
 271   else ()
 272     gflags_property (INTTYPES_FORMAT ADVANCED FALSE)
 273     message (FATAL_ERROR "Do not know how to define a 32-bit integer quantity on your system!"
 274                          " Neither uint32_t, u_int32_t, nor __int32 seem to be available."
 275                          " Set [GFLAGS_]INTTYPES_FORMAT to either C99, BSD, or VC7 and try again.")
 276   endif ()
 277 endif ()
 278 # use of special characters in strings to circumvent bug #0008226
 279 if ("^${INTTYPES_FORMAT}$" STREQUAL "^WIN$")
 280   gflags_set (INTTYPES_FORMAT VC7)
 281 endif ()
 282 if (NOT INTTYPES_FORMAT MATCHES "^(C99|BSD|VC7)$")
 283   message (FATAL_ERROR "Invalid value for [GFLAGS_]INTTYPES_FORMAT! Choose one of \"C99\", \"BSD\", or \"VC7\"")
 284 endif ()
 285 set (GFLAGS_INTTYPES_FORMAT "${INTTYPES_FORMAT}")
 286 set (GFLAGS_INTTYPES_FORMAT_C99 0)
 287 set (GFLAGS_INTTYPES_FORMAT_BSD 0)
 288 set (GFLAGS_INTTYPES_FORMAT_VC7 0)
 289 set ("GFLAGS_INTTYPES_FORMAT_${INTTYPES_FORMAT}" 1)
 290
 291 if (MSVC)
 292   set (HAVE_strtoll 0)
 293   set (HAVE_strtoq  0)
 294 else ()
 295   check_cxx_symbol_exists (strtoll stdlib.h HAVE_STRTOLL)
 296   if (NOT HAVE_STRTOLL)
 297     check_cxx_symbol_exists (strtoq stdlib.h HAVE_STRTOQ)
 298   endif ()
 299 endif ()
 300
 301 if (BUILD_gflags_LIB)
 302   set (CMAKE_THREAD_PREFER_PTHREAD TRUE)
 303   find_package (Threads)
 304   if (Threads_FOUND AND CMAKE_USE_PTHREADS_INIT)
 305     set (HAVE_PTHREAD 1)
 306     check_type_size (pthread_rwlock_t RWLOCK LANGUAGE CXX)
 307   else ()
 308     set (HAVE_PTHREAD 0)
 309   endif ()
 310   if (UNIX AND NOT HAVE_PTHREAD)
 311     if (CMAKE_HAVE_PTHREAD_H)
 312       set (what "library")
 313     else ()
 314       set (what ".h file")
 315     endif ()
 316     message (FATAL_ERROR "Could not find pthread${what}. Check the log file"
 317                          "\n\t${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log"
 318                          "\nor disable the build of the multi-threaded gflags library (BUILD_gflags_LIB=OFF).")
 319   endif ()
 320 else ()
 321   set (HAVE_PTHREAD 0)
 322 endif ()
 323
 324 # ----------------------------------------------------------------------------
 325 # source files - excluding root subdirectory and/or .in suffix
 326 set (PUBLIC_HDRS
 327   "gflags.h"
 328   "gflags_declare.h"
 329   "gflags_completions.h"
 330 )
 331
 332 if (GFLAGS_NAMESPACE_SECONDARY)
 333   set (INCLUDE_GFLAGS_NS_H "// Import gflags library symbols into alternative/deprecated namespace(s)")
 334   foreach (ns IN LISTS GFLAGS_NAMESPACE_SECONDARY)
 335     string (TOUPPER "${ns}" NS)
 336     set (gflags_ns_h "${PROJECT_BINARY_DIR}/include/${GFLAGS_INCLUDE_DIR}/gflags_${ns}.h")
 337     configure_file ("${PROJECT_SOURCE_DIR}/src/gflags_ns.h.in" "${gflags_ns_h}" @ONLY)
 338     list (APPEND PUBLIC_HDRS "${gflags_ns_h}")
 339     set (INCLUDE_GFLAGS_NS_H "${INCLUDE_GFLAGS_NS_H}\n#include \"gflags_${ns}.h\"")
 340   endforeach ()
 341 else ()
 342   set (INCLUDE_GFLAGS_NS_H)
 343 endif ()
 344
 345 set (PRIVATE_HDRS
 346   "config.h"
 347   "util.h"
 348   "mutex.h"
 349 )
 350
 351 set (GFLAGS_SRCS
 352   "gflags.cc"
 353   "gflags_reporting.cc"
 354   "gflags_completions.cc"
 355 )
 356
 357 if (OS_WINDOWS)
 358   list (APPEND PRIVATE_HDRS "windows_port.h")
 359   list (APPEND GFLAGS_SRCS  "windows_port.cc")
 360 endif ()
 361
 362 # ----------------------------------------------------------------------------
 363 # configure source files
 364 if (NOT DEFINED GFLAGS_ATTRIBUTE_UNUSED)
 365   if (CMAKE_COMPILER_IS_GNUCXX)
 366     set (GFLAGS_ATTRIBUTE_UNUSED "__attribute((unused))")
 367   else ()
 368     set (GFLAGS_ATTRIBUTE_UNUSED)
 369   endif ()
 370 endif ()
 371
 372 # whenever we build a shared library (DLL on Windows), configure the public
 373 # headers of the API for use of this shared library rather than the optionally
 374 # also build statically linked library; users can override GFLAGS_DLL_DECL
 375 # in particular, this done by setting the INTERFACE_COMPILE_DEFINITIONS of
 376 # static libraries to include an empty definition for GFLAGS_DLL_DECL
 377 if (NOT DEFINED GFLAGS_IS_A_DLL)
 378   if (BUILD_SHARED_LIBS)
 379     set (GFLAGS_IS_A_DLL 1)
 380   else ()
 381     set (GFLAGS_IS_A_DLL 0)
 382   endif ()
 383 endif ()
 384
 385 configure_headers (PUBLIC_HDRS  ${PUBLIC_HDRS})
 386 configure_sources (PRIVATE_HDRS ${PRIVATE_HDRS})
 387 configure_sources (GFLAGS_SRCS  ${GFLAGS_SRCS})
 388
 389 # ----------------------------------------------------------------------------
 390 # output directories
 391 if (NOT GFLAGS_IS_SUBPROJECT)
 392   set (CMAKE_RUNTIME_OUTPUT_DIRECTORY "bin")
 393   set (CMAKE_LIBRARY_OUTPUT_DIRECTORY "lib")
 394   set (CMAKE_ARCHIVE_OUTPUT_DIRECTORY "lib")
 395 endif ()
 396
 397 # ----------------------------------------------------------------------------
 398 # installation directories
 399 if (OS_WINDOWS)
 400   set (RUNTIME_INSTALL_DIR Bin)
 401   set (LIBRARY_INSTALL_DIR Lib)
 402   set (INCLUDE_INSTALL_DIR Include)
 403   set (CONFIG_INSTALL_DIR  CMake)
 404   set (PKGCONFIG_INSTALL_DIR)
 405 else ()
 406   set (RUNTIME_INSTALL_DIR bin)
 407   # The LIB_INSTALL_DIR and LIB_SUFFIX variables are used by the Fedora
 408   # package maintainers. Also package maintainers of other distribution
 409   # packages need to be able to specify the name of the library directory.
 410   if (NOT GFLAGS_LIBRARY_INSTALL_DIR AND LIB_INSTALL_DIR)
 411     set (GFLAGS_LIBRARY_INSTALL_DIR "${LIB_INSTALL_DIR}")
 412   endif ()
 413   gflags_define (PATH LIBRARY_INSTALL_DIR "Directory of installed libraries, e.g., \"lib64\"" "lib${LIB_SUFFIX}")
 414   gflags_property (LIBRARY_INSTALL_DIR ADVANCED TRUE)
 415   set (INCLUDE_INSTALL_DIR include)
 416   set (CONFIG_INSTALL_DIR  ${LIBRARY_INSTALL_DIR}/cmake/${PACKAGE_NAME})
 417   set (PKGCONFIG_INSTALL_DIR ${LIBRARY_INSTALL_DIR}/pkgconfig)
 418 endif ()
 419
 420 # ----------------------------------------------------------------------------
 421 # add library targets
 422 set (TARGETS)
 423 # static vs. shared
 424 foreach (TYPE IN ITEMS STATIC SHARED)
 425   if (BUILD_${TYPE}_LIBS)
 426     string (TOLOWER "${TYPE}" type)
 427     # whether or not targets are a DLL
 428     if (OS_WINDOWS AND "^${TYPE}$" STREQUAL "^SHARED$")
 429       set (GFLAGS_IS_A_DLL 1)
 430     else ()
 431       set (GFLAGS_IS_A_DLL 0)
 432     endif ()
 433     # filename suffix for static libraries on Windows
 434     if (OS_WINDOWS AND "^${TYPE}$" STREQUAL "^STATIC$")
 435       set (type_suffix "_${type}")
 436     else ()
 437       set (type_suffix "")
 438     endif ()
 439     # multi-threaded vs. single-threaded
 440     foreach (opts IN ITEMS "" _nothreads)
 441       if (BUILD_gflags${opts}_LIB)
 442         set (target_name "gflags${opts}_${type}")
 443         add_library (${target_name} ${TYPE} ${GFLAGS_SRCS} ${PRIVATE_HDRS} ${PUBLIC_HDRS})
 444         set_target_properties (${target_name} PROPERTIES
 445           OUTPUT_NAME "gflags${opts}${type_suffix}"
 446           VERSION     "${PACKAGE_VERSION}"
 447           SOVERSION   "${PACKAGE_SOVERSION}"
 448         )
 449         set (include_dirs "$<BUILD_INTERFACE:${PROJECT_BINARY_DIR}/include>")
 450         if (INSTALL_HEADERS)
 451           list (APPEND include_dirs "$<INSTALL_INTERFACE:${INCLUDE_INSTALL_DIR}>")
 452         endif ()
 453         target_include_directories (${target_name}
 454           PUBLIC  "${include_dirs}"
 455           PRIVATE "${PROJECT_SOURCE_DIR}/src;${PROJECT_BINARY_DIR}/include/${GFLAGS_INCLUDE_DIR}"
 456         )
 457         target_compile_definitions (${target_name} PUBLIC GFLAGS_IS_A_DLL=${GFLAGS_IS_A_DLL})
 458         if (opts MATCHES "nothreads")
 459           target_compile_definitions (${target_name} PRIVATE NO_THREADS)
 460         elseif (CMAKE_USE_PTHREADS_INIT)
 461           target_link_libraries (${target_name} ${CMAKE_THREAD_LIBS_INIT})
 462         endif ()
 463         if (HAVE_SHLWAPI_H)
 464           target_link_libraries (${target_name} shlwapi.lib)
 465         endif ()
 466         list (APPEND TARGETS ${target_name})
 467         # add convenience make target for build of both shared and static libraries
 468         if (NOT GFLAGS_IS_SUBPROJECT)
 469           if (NOT TARGET gflags${opts})
 470             add_custom_target (gflags${opts})
 471           endif ()
 472           add_dependencies (gflags${opts} ${target_name})
 473         endif ()
 474       endif ()
 475     endforeach ()
 476   endif ()
 477 endforeach ()
 478
 479 # add ALIAS target for use in super-project, prefer static over shared, single-threaded over multi-threaded
 480 if (GFLAGS_IS_SUBPROJECT)
 481   foreach (type IN ITEMS static shared)
 482     foreach (opts IN ITEMS "_nothreads" "")
 483       if (TARGET gflags${opts}_${type})
 484         add_library (gflags ALIAS gflags${opts}_${type})
 485         break ()
 486       endif ()
 487     endforeach ()
 488     if (TARGET gflags)
 489        break ()
 490     endif ()
 491   endforeach ()
 492 endif ()
 493
 494 # ----------------------------------------------------------------------------
 495 # installation rules
 496 set (EXPORT_NAME ${PACKAGE_NAME}-targets)
 497 file (RELATIVE_PATH INSTALL_PREFIX_REL2CONFIG_DIR "${CMAKE_INSTALL_PREFIX}/${CONFIG_INSTALL_DIR}" "${CMAKE_INSTALL_PREFIX}")
 498 configure_file (cmake/config.cmake.in  "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-config-install.cmake" @ONLY)
 499 configure_file (cmake/version.cmake.in "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-config-version.cmake" @ONLY)
 500
 501 if (BUILD_SHARED_LIBS AND INSTALL_SHARED_LIBS)
 502   foreach (opts IN ITEMS "" _nothreads)
 503     if (BUILD_gflags${opts}_LIB)
 504       install (TARGETS gflags${opts}_shared DESTINATION ${LIBRARY_INSTALL_DIR} EXPORT ${EXPORT_NAME})
 505     endif ()
 506   endforeach ()
 507 endif ()
 508 if (BUILD_STATIC_LIBS AND INSTALL_STATIC_LIBS)
 509   foreach (opts IN ITEMS "" _nothreads)
 510     if (BUILD_gflags${opts}_LIB)
 511       install (TARGETS gflags${opts}_static DESTINATION ${LIBRARY_INSTALL_DIR} EXPORT ${EXPORT_NAME})
 512     endif ()
 513   endforeach ()
 514 endif ()
 515
 516 if (INSTALL_HEADERS)
 517   install (FILES ${PUBLIC_HDRS} DESTINATION ${INCLUDE_INSTALL_DIR}/${GFLAGS_INCLUDE_DIR})
 518   install (
 519     FILES "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-config-install.cmake"
 520     RENAME ${PACKAGE_NAME}-config.cmake
 521     DESTINATION ${CONFIG_INSTALL_DIR}
 522   )
 523   install (
 524     FILES "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-config-version.cmake"
 525     DESTINATION ${CONFIG_INSTALL_DIR}
 526   )
 527   install (EXPORT ${EXPORT_NAME} DESTINATION ${CONFIG_INSTALL_DIR})
 528   if (UNIX)
 529     install (PROGRAMS src/gflags_completions.sh DESTINATION ${RUNTIME_INSTALL_DIR})
 530   endif ()
 531 endif ()
 532
 533 if (PKGCONFIG_INSTALL_DIR)
 534   configure_file ("cmake/package.pc.in" "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}.pc" @ONLY)
 535   install (FILES "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}.pc" DESTINATION "${PKGCONFIG_INSTALL_DIR}")
 536 endif ()
 537
 538 # ----------------------------------------------------------------------------
 539 # support direct use of build tree
 540 set (INSTALL_PREFIX_REL2CONFIG_DIR .)
 541 export (TARGETS ${TARGETS} FILE "${PROJECT_BINARY_DIR}/${EXPORT_NAME}.cmake")
 542 if (REGISTER_BUILD_DIR)
 543   export (PACKAGE ${PACKAGE_NAME})
 544 endif ()
 545 if (REGISTER_INSTALL_PREFIX)
 546   register_gflags_package(${CONFIG_INSTALL_DIR})
 547 endif ()
 548 configure_file (cmake/config.cmake.in "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-config.cmake" @ONLY)
 549
 550 # ----------------------------------------------------------------------------
 551 # testing - MUST follow the generation of the build tree config file
 552 if (BUILD_TESTING)
 553   include (CTest)
 554   enable_testing ()
 555   add_subdirectory (test)
 556 endif ()
 557
 558 # ----------------------------------------------------------------------------
 559 # packaging
 560 if (BUILD_PACKAGING)
 561
 562   if (NOT BUILD_SHARED_LIBS AND NOT INSTALL_HEADERS)
 563     message (WARNING "Package will contain static libraries without headers!"
 564                      "\nRecommended options for generation of runtime package:"
 565                      "\n  BUILD_SHARED_LIBS=ON"
 566                      "\n  BUILD_STATIC_LIBS=OFF"
 567                      "\n  INSTALL_HEADERS=OFF"
 568                      "\n  INSTALL_SHARED_LIBS=ON"
 569                      "\nRecommended options for generation of development package:"
 570                      "\n  BUILD_SHARED_LIBS=ON"
 571                      "\n  BUILD_STATIC_LIBS=ON"
 572                      "\n  INSTALL_HEADERS=ON"
 573                      "\n  INSTALL_SHARED_LIBS=ON"
 574                      "\n  INSTALL_STATIC_LIBS=ON")
 575   endif ()
 576
 577   # default package generators
 578   if (APPLE)
 579     set (PACKAGE_GENERATOR        "PackageMaker")
 580     set (PACKAGE_SOURCE_GENERATOR "TGZ;ZIP")
 581   elseif (UNIX)
 582     set (PACKAGE_GENERATOR        "DEB;RPM")
 583     set (PACKAGE_SOURCE_GENERATOR "TGZ;ZIP")
 584   else ()
 585     set (PACKAGE_GENERATOR        "ZIP")
 586     set (PACKAGE_SOURCE_GENERATOR "ZIP")
 587   endif ()
 588
 589   # used package generators
 590   set (CPACK_GENERATOR        "${PACKAGE_GENERATOR}"        CACHE STRING "List of binary package generators (CPack).")
 591   set (CPACK_SOURCE_GENERATOR "${PACKAGE_SOURCE_GENERATOR}" CACHE STRING "List of source package generators (CPack).")
 592   mark_as_advanced (CPACK_GENERATOR CPACK_SOURCE_GENERATOR)
 593
 594   # some package generators (e.g., PackageMaker) do not allow .md extension
 595   configure_file ("${CMAKE_CURRENT_LIST_DIR}/README.md" "${CMAKE_CURRENT_BINARY_DIR}/README.txt" COPYONLY)
 596
 597   # common package information
 598   set (CPACK_PACKAGE_VENDOR              "Andreas Schuh")
 599   set (CPACK_PACKAGE_CONTACT             "google-gflags@googlegroups.com")
 600   set (CPACK_PACKAGE_NAME                "${PACKAGE_NAME}")
 601   set (CPACK_PACKAGE_VERSION             "${PACKAGE_VERSION}")
 602   set (CPACK_PACKAGE_VERSION_MAJOR       "${PACKAGE_VERSION_MAJOR}")
 603   set (CPACK_PACKAGE_VERSION_MINOR       "${PACKAGE_VERSION_MINOR}")
 604   set (CPACK_PACKAGE_VERSION_PATCH       "${PACKAGE_VERSION_PATCH}")
 605   set (CPACK_PACKAGE_DESCRIPTION_SUMMARY "${PACKAGE_DESCRIPTION}")
 606   set (CPACK_RESOURCE_FILE_WELCOME       "${CMAKE_CURRENT_BINARY_DIR}/README.txt")
 607   set (CPACK_RESOURCE_FILE_LICENSE       "${CMAKE_CURRENT_LIST_DIR}/COPYING.txt")
 608   set (CPACK_PACKAGE_DESCRIPTION_FILE    "${CMAKE_CURRENT_BINARY_DIR}/README.txt")
 609   set (CPACK_INSTALL_PREFIX              "${CMAKE_INSTALL_PREFIX}")
 610   set (CPACK_OUTPUT_FILE_PREFIX          packages)
 611   set (CPACK_PACKAGE_RELOCATABLE         TRUE)
 612   set (CPACK_MONOLITHIC_INSTALL          TRUE)
 613
 614   # RPM package information -- used in cmake/package.cmake.in also for DEB
 615   set (CPACK_RPM_PACKAGE_GROUP   "Development/Libraries")
 616   set (CPACK_RPM_PACKAGE_LICENSE "BSD")
 617   set (CPACK_RPM_PACKAGE_URL     "${PACKAGE_URL}")
 618   set (CPACK_RPM_CHANGELOG_FILE  "${CMAKE_CURRENT_LIST_DIR}/ChangeLog.txt")
 619
 620   if (INSTALL_HEADERS)
 621     set (CPACK_RESOURCE_FILE_README "${CMAKE_CURRENT_LIST_DIR}/doc/index.html")
 622   else ()
 623     set (CPACK_RESOURCE_FILE_README "${CMAKE_CURRENT_LIST_DIR}/cmake/README_runtime.txt")
 624   endif ()
 625
 626   # system/architecture
 627   if (WINDOWS)
 628     if (CMAKE_CL_64)
 629       set (CPACK_SYSTEM_NAME "win64")
 630     else ()
 631       set (CPACK_SYSTEM_NAME "win32")
 632     endif ()
 633     set (CPACK_PACKAGE_ARCHITECTURE)
 634   elseif (APPLE)
 635     set (CPACK_PACKAGE_ARCHITECTURE darwin)
 636   else ()
 637     string (TOLOWER "${CMAKE_SYSTEM_NAME}" CPACK_SYSTEM_NAME)
 638     if (CMAKE_CXX_FLAGS MATCHES "-m32")
 639       set (CPACK_PACKAGE_ARCHITECTURE i386)
 640     else ()
 641       execute_process (
 642         COMMAND         dpkg --print-architecture
 643         RESULT_VARIABLE RV
 644         OUTPUT_VARIABLE CPACK_PACKAGE_ARCHITECTURE
 645       )
 646       if (RV EQUAL 0)
 647               string (STRIP "${CPACK_PACKAGE_ARCHITECTURE}" CPACK_PACKAGE_ARCHITECTURE)
 648       else ()
 649         execute_process (COMMAND uname -m OUTPUT_VARIABLE CPACK_PACKAGE_ARCHITECTURE)
 650         if (CPACK_PACKAGE_ARCHITECTURE MATCHES "x86_64")
 651                 set (CPACK_PACKAGE_ARCHITECTURE amd64)
 652         else ()
 653           set (CPACK_PACKAGE_ARCHITECTURE i386)
 654         endif ()
 655       endif ()
 656     endif ()
 657   endif ()
 658
 659   # source package settings
 660   set (CPACK_SOURCE_TOPLEVEL_TAG      "source")
 661   set (CPACK_SOURCE_PACKAGE_FILE_NAME "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}")
 662   set (CPACK_SOURCE_IGNORE_FILES      "/\\\\.git/;\\\\.swp$;\\\\.#;/#;\\\\.*~;cscope\\\\.*;/[Bb]uild[.+-_a-zA-Z0-9]*/")
 663
 664   # default binary package settings
 665   set (CPACK_INCLUDE_TOPLEVEL_DIRECTORY TRUE)
 666   set (CPACK_PACKAGE_FILE_NAME          "${CPACK_PACKAGE_NAME}-${CPACK_PACKAGE_VERSION}-${CPACK_SYSTEM_NAME}")
 667   if (CPACK_PACKAGE_ARCHITECTURE)
 668     set (CPACK_PACKAGE_FILE_NAME "${CPACK_PACKAGE_FILE_NAME}-${CPACK_PACKAGE_ARCHITECTURE}")
 669   endif ()
 670
 671   # generator specific configuration file
 672   #
 673   # allow package maintainers to use their own configuration file
 674   # $ cmake -DCPACK_PROJECT_CONFIG_FILE:FILE=/path/to/package/config
 675   if (NOT CPACK_PROJECT_CONFIG_FILE)
 676     configure_file (
 677       "${CMAKE_CURRENT_LIST_DIR}/cmake/package.cmake.in"
 678       "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-package.cmake" @ONLY
 679     )
 680     set (CPACK_PROJECT_CONFIG_FILE "${PROJECT_BINARY_DIR}/${PACKAGE_NAME}-package.cmake")
 681   endif ()
 682
 683   include (CPack)
 684
 685 endif () # BUILD_PACKAGING