CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 #
   8 #   - OCT-2008: Initial version <joseluisblancoc@gmail.com>
   9 #
  10 # ----------------------------------------------------------------------------
  11
  12 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS true)
  13
  14 # Following block can broke build in case of cross-compilng
  15 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  16 # so we will try to detect crosscompiling by presense of CMAKE_TOOLCHAIN_FILE
  17 if(NOT CMAKE_TOOLCHAIN_FILE)
  18   # it _must_ go before project(OpenCV) in order to work
  19   if(WIN32)
  20     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  21   else()
  22     set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  23   endif()
  24 else(NOT CMAKE_TOOLCHAIN_FILE)
  25   #Android: set output folder to ${CMAKE_BINARY_DIR}
  26   set( LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  27   # any crosscompiling
  28   set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  29 endif(NOT CMAKE_TOOLCHAIN_FILE)
  30
  31 # --------------------------------------------------------------
  32 # Top level OpenCV project
  33 # --------------------------------------------------------------
  34 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  35   cmake_minimum_required(VERSION 2.8.8)
  36 elseif(IOS)
  37   cmake_minimum_required(VERSION 2.8.0)
  38 else()
  39   cmake_minimum_required(VERSION 2.6.3)
  40 endif()
  41
  42 if(POLICY CMP0017)
  43   cmake_policy(SET CMP0017 NEW)
  44 endif()
  45
  46 if(POLICY CMP0022)
  47   cmake_policy(SET CMP0022 OLD)
  48 endif()
  49
  50 # must go before the project command
  51 set(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  52 if(DEFINED CMAKE_BUILD_TYPE AND CMAKE_VERSION VERSION_GREATER "2.8")
  53   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
  54 endif()
  55
  56 project(OpenCV CXX C)
  57
  58 if(MSVC)
  59   set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
  60 endif()
  61
  62 include(cmake/OpenCVUtils.cmake)
  63
  64 ocv_clear_vars(OpenCVModules_TARGETS)
  65
  66 # ----------------------------------------------------------------------------
  67 # Break in case of popular CMake configuration mistakes
  68 # ----------------------------------------------------------------------------
  69 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
  70   message(FATAL_ERROR "CMake fails to deterimine the bitness of target platform.
  71   Please check your CMake and compiler installation. If you are crosscompiling then ensure that your CMake toolchain file correctly sets the compiler details.")
  72 endif()
  73
  74 # ----------------------------------------------------------------------------
  75 # Detect compiler and target platform architecture
  76 # ----------------------------------------------------------------------------
  77 include(cmake/OpenCVDetectCXXCompiler.cmake)
  78
  79 # Add these standard paths to the search paths for FIND_LIBRARY
  80 # to find libraries from these locations first
  81 if(UNIX AND NOT ANDROID)
  82   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
  83     if(EXISTS /lib64)
  84       list(APPEND CMAKE_LIBRARY_PATH /lib64)
  85     else()
  86       list(APPEND CMAKE_LIBRARY_PATH /lib)
  87     endif()
  88     if(EXISTS /usr/lib64)
  89       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
  90     else()
  91       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
  92     endif()
  93   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
  94     if(EXISTS /lib32)
  95       list(APPEND CMAKE_LIBRARY_PATH /lib32)
  96     else()
  97       list(APPEND CMAKE_LIBRARY_PATH /lib)
  98     endif()
  99     if(EXISTS /usr/lib32)
 100       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
 101     else()
 102       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
 103     endif()
 104   endif()
 105 endif()
 106
 107 # Add these standard paths to the search paths for FIND_PATH
 108 # to find include files from these locations first
 109 if(MINGW)
 110   if(EXISTS /mingw)
 111       list(APPEND CMAKE_INCLUDE_PATH /mingw)
 112   endif()
 113   if(EXISTS /mingw32)
 114       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
 115   endif()
 116   if(EXISTS /mingw64)
 117       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 118   endif()
 119 endif()
 120
 121 # ----------------------------------------------------------------------------
 122 # OpenCV cmake options
 123 # ----------------------------------------------------------------------------
 124
 125 # Optional 3rd party components
 126 # ===================================================
 127 OCV_OPTION(WITH_1394           "Include IEEE1394 support"                    ON   IF (NOT ANDROID AND NOT IOS) )
 128 OCV_OPTION(WITH_AVFOUNDATION   "Use AVFoundation for Video I/O"              ON   IF IOS)
 129 OCV_OPTION(WITH_CARBON         "Use Carbon for UI instead of Cocoa"          OFF  IF APPLE )
 130 OCV_OPTION(WITH_CUDA           "Include NVidia Cuda Runtime support"         ON   IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT IOS) )
 131 OCV_OPTION(WITH_CUFFT          "Include NVidia Cuda Fast Fourier Transform (FFT) library support"            ON  IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT IOS) )
 132 OCV_OPTION(WITH_CUBLAS         "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" OFF IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT IOS) )
 133 OCV_OPTION(WITH_NVCUVID        "Include NVidia Video Decoding library support"                               OFF IF (CMAKE_VERSION VERSION_GREATER "2.8" AND NOT ANDROID AND NOT IOS AND NOT APPLE) )
 134 OCV_OPTION(WITH_EIGEN          "Include Eigen2/Eigen3 support"               ON)
 135 OCV_OPTION(WITH_VFW            "Include Video for Windows support"           ON   IF WIN32 )
 136 OCV_OPTION(WITH_FFMPEG         "Include FFMPEG support"                      ON   IF (NOT ANDROID AND NOT IOS))
 137 OCV_OPTION(WITH_GSTREAMER      "Include Gstreamer support"                   ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 138 OCV_OPTION(WITH_GTK            "Include GTK support"                         ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 139 OCV_OPTION(WITH_IMAGEIO        "ImageIO support for OS X"                    OFF  IF APPLE )
 140 OCV_OPTION(WITH_IPP            "Include Intel IPP support"                   OFF  IF (MSVC OR X86 OR X86_64) )
 141 OCV_OPTION(WITH_JASPER         "Include JPEG2K support"                      ON   IF (NOT IOS) )
 142 OCV_OPTION(WITH_JPEG           "Include JPEG support"                        ON)
 143 OCV_OPTION(WITH_OPENEXR        "Include ILM support via OpenEXR"             ON   IF (NOT IOS) )
 144 OCV_OPTION(WITH_OPENGL         "Include OpenGL support"                      OFF  IF (NOT ANDROID AND NOT APPLE) )
 145 OCV_OPTION(WITH_OPENNI         "Include OpenNI support"                      OFF  IF (NOT ANDROID AND NOT IOS) )
 146 OCV_OPTION(WITH_PNG            "Include PNG support"                         ON)
 147 OCV_OPTION(WITH_PVAPI          "Include Prosilica GigE support"              ON   IF (NOT ANDROID AND NOT IOS) )
 148 OCV_OPTION(WITH_GIGEAPI        "Include Smartek GigE support"                ON   IF (NOT ANDROID AND NOT IOS) )
 149 OCV_OPTION(WITH_QT             "Build with Qt Backend support"               OFF  IF (NOT ANDROID AND NOT IOS) )
 150 OCV_OPTION(WITH_WIN32UI        "Build with Win32 UI Backend support"         ON   IF WIN32 )
 151 OCV_OPTION(WITH_QUICKTIME      "Use QuickTime for Video I/O insted of QTKit" OFF  IF APPLE )
 152 OCV_OPTION(WITH_TBB            "Include Intel TBB support"                   OFF  IF (NOT IOS) )
 153 OCV_OPTION(WITH_OPENMP         "Include OpenMP support"                      OFF)
 154 OCV_OPTION(WITH_CSTRIPES       "Include C= support"                          OFF  IF WIN32 )
 155 OCV_OPTION(WITH_TIFF           "Include TIFF support"                        ON   IF (NOT IOS) )
 156 OCV_OPTION(WITH_UNICAP         "Include Unicap support (GPL)"                OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 157 OCV_OPTION(WITH_V4L            "Include Video 4 Linux support"               ON   IF (UNIX AND NOT ANDROID) )
 158 OCV_OPTION(WITH_LIBV4L         "Use libv4l for Video 4 Linux support"        ON   IF (UNIX AND NOT ANDROID) )
 159 OCV_OPTION(WITH_DSHOW          "Build HighGUI with DirectShow support"       ON   IF (WIN32 AND NOT ARM) )
 160 OCV_OPTION(WITH_MSMF           "Build HighGUI with Media Foundation support" OFF  IF WIN32 )
 161 OCV_OPTION(WITH_XIMEA          "Include XIMEA cameras support"               OFF  IF (NOT ANDROID AND NOT APPLE) )
 162 OCV_OPTION(WITH_XINE           "Include Xine support (GPL)"                  OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 163 OCV_OPTION(WITH_OPENCL         "Include OpenCL Runtime support"              ON   IF (NOT IOS) )
 164 OCV_OPTION(WITH_OPENCLAMDFFT   "Include AMD OpenCL FFT library support"      ON   IF (NOT ANDROID AND NOT IOS) )
 165 OCV_OPTION(WITH_OPENCLAMDBLAS  "Include AMD OpenCL BLAS library support"     ON   IF (NOT ANDROID AND NOT IOS) )
 166 OCV_OPTION(WITH_INTELPERC      "Include Intel Perceptual Computing support"  OFF  IF WIN32 )
 167
 168 # OpenCV build components
 169 # ===================================================
 170 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR IOS) )
 171 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID) IF (NOT IOS) )
 172 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 173 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" ON )
 174 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 175 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON )
 176 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     ON  IF (NOT IOS) )
 177 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           ON  IF (NOT IOS) )
 178 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into debug libs (not MSCV only)" ON )
 179 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of staticaly linked CRT for staticaly linked OpenCV" ON IF MSVC )
 180 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create fat java wrapper containing the whole OpenCV library" ON IF NOT BUILD_SHARED_LIBS AND CMAKE_COMPILER_IS_GNUCXX )
 181 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID AND ANDROID_SOURCE_TREE )
 182 OCV_OPTION(BUILD_ANDROID_PACKAGE    "Build platform-specific package for Google Play" OFF IF ANDROID )
 183
 184 # 3rd party libs
 185 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             WIN32 OR APPLE )
 186 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          WIN32 OR ANDROID OR APPLE )
 187 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        WIN32 OR ANDROID OR APPLE )
 188 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          WIN32 OR ANDROID OR APPLE )
 189 OCV_OPTION(BUILD_PNG                "Build libpng from source"           WIN32 OR ANDROID OR APPLE )
 190 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          WIN32 OR ANDROID OR APPLE )
 191 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" ANDROID )
 192
 193 # OpenCV installation options
 194 # ===================================================
 195 OCV_OPTION(INSTALL_CREATE_DISTRIB   "Change install rules to build the distribution package" OFF )
 196 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 197 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 198 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 199 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT IOS AND BUILD_SHARED_LIBS) )
 200
 201
 202 # OpenCV build options
 203 # ===================================================
 204 OCV_OPTION(ENABLE_DYNAMIC_CUDA        "Enabled dynamic CUDA linkage"                             ON   IF ANDROID )
 205 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON   IF (NOT IOS) )
 206 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) IF (CMAKE_VERSION VERSION_GREATER "2.8.0") )
 207 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CMAKE_COMPILER_IS_GNUCXX )
 208 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CMAKE_COMPILER_IS_GNUCXX AND NOT (APPLE AND CMAKE_COMPILER_IS_CLANGCXX) )
 209 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CMAKE_COMPILER_IS_GNUCXX AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 210 OCV_OPTION(ENABLE_FAST_MATH           "Enable -ffast-math (not recommended for GCC 4.6.x)"       OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 211 OCV_OPTION(ENABLE_SSE                 "Enable SSE instructions"                                  ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 212 OCV_OPTION(ENABLE_SSE2                "Enable SSE2 instructions"                                 ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 213 OCV_OPTION(ENABLE_SSE3                "Enable SSE3 instructions"                                 ON   IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 214 OCV_OPTION(ENABLE_SSSE3               "Enable SSSE3 instructions"                                OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 215 OCV_OPTION(ENABLE_SSE41               "Enable SSE4.1 instructions"                               OFF  IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 216 OCV_OPTION(ENABLE_SSE42               "Enable SSE4.2 instructions"                               OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 217 OCV_OPTION(ENABLE_AVX                 "Enable AVX instructions"                                  OFF  IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 218 OCV_OPTION(ENABLE_NEON                "Enable NEON instructions"                                 OFF  IF CMAKE_COMPILER_IS_GNUCXX AND ARM )
 219 OCV_OPTION(ENABLE_VFPV3               "Enable VFPv3-D32 instructions"                            OFF  IF CMAKE_COMPILER_IS_GNUCXX AND ARM )
 220 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 221 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 222 OCV_OPTION(ENABLE_WINRT_MODE          "Build with Windows Runtime support"                       OFF  IF WIN32 )
 223
 224 # uncategorized options
 225 # ===================================================
 226 OCV_OPTION(CMAKE_VERBOSE "Verbose mode" OFF )
 227
 228 # backward compatibility
 229 # ===================================================
 230 include(cmake/OpenCVLegacyOptions.cmake OPTIONAL)
 231
 232
 233 # ----------------------------------------------------------------------------
 234 #  Get actual OpenCV version number from sources
 235 # ----------------------------------------------------------------------------
 236 include(cmake/OpenCVVersion.cmake)
 237
 238
 239 # ----------------------------------------------------------------------------
 240 #  Build & install layouts
 241 # ----------------------------------------------------------------------------
 242
 243 # Save libs and executables in the same place
 244 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications" )
 245
 246 if (ANDROID)
 247   if (ANDROID_ABI MATCHES "NEON")
 248     set(ENABLE_NEON ON)
 249   endif()
 250   if (ANDROID_ABI MATCHES "VFPV3")
 251     set(ENABLE_VFPV3 ON)
 252   endif()
 253 endif()
 254
 255 if(ANDROID OR WIN32)
 256   set(OPENCV_DOC_INSTALL_PATH doc)
 257 elseif(INSTALL_TO_MANGLED_PATHS)
 258   set(OPENCV_DOC_INSTALL_PATH share/OpenCV-${OPENCV_VERSION}/doc)
 259 else()
 260   set(OPENCV_DOC_INSTALL_PATH share/OpenCV/doc)
 261 endif()
 262
 263 if(WIN32)
 264   if(DEFINED OpenCV_RUNTIME AND DEFINED OpenCV_ARCH)
 265     set(OpenCV_INSTALL_BINARIES_PREFIX "${OpenCV_ARCH}/${OpenCV_RUNTIME}/")
 266   else()
 267     message(STATUS "Can't detect runtime and/or arch")
 268     set(OpenCV_INSTALL_BINARIES_PREFIX "")
 269   endif()
 270 else()
 271   set(OpenCV_INSTALL_BINARIES_PREFIX "")
 272 endif()
 273
 274 set(OPENCV_SAMPLES_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}samples")
 275
 276 set(OPENCV_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}bin")
 277
 278 if(ANDROID)
 279   set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 280   set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 281   set(OPENCV_LIB_INSTALL_PATH     sdk/native/libs/${ANDROID_NDK_ABI_NAME})
 282   set(OPENCV_3P_LIB_INSTALL_PATH  sdk/native/3rdparty/libs/${ANDROID_NDK_ABI_NAME})
 283   set(OPENCV_CONFIG_INSTALL_PATH  sdk/native/jni)
 284   set(OPENCV_INCLUDE_INSTALL_PATH sdk/native/jni/include)
 285 else()
 286   set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib")
 287   set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib${LIB_SUFFIX}")
 288   if(WIN32)
 289     if(OpenCV_STATIC)
 290       set(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 291     else()
 292       set(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}lib${LIB_SUFFIX}")
 293     endif()
 294     set(OPENCV_3P_LIB_INSTALL_PATH  "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 295   else()
 296     set(OPENCV_LIB_INSTALL_PATH     lib${LIB_SUFFIX})
 297     set(OPENCV_3P_LIB_INSTALL_PATH  share/OpenCV/3rdparty/${OPENCV_LIB_INSTALL_PATH})
 298   endif()
 299   set(OPENCV_INCLUDE_INSTALL_PATH "include")
 300
 301   math(EXPR SIZEOF_VOID_P_BITS "8 * ${CMAKE_SIZEOF_VOID_P}")
 302   if(LIB_SUFFIX AND NOT SIZEOF_VOID_P_BITS EQUAL LIB_SUFFIX)
 303     set(OPENCV_CONFIG_INSTALL_PATH lib${LIB_SUFFIX}/cmake/opencv)
 304   else()
 305     set(OPENCV_CONFIG_INSTALL_PATH share/OpenCV)
 306   endif()
 307 endif()
 308
 309 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 310 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 311
 312 if(INSTALL_TO_MANGLED_PATHS)
 313   set(OPENCV_INCLUDE_INSTALL_PATH ${OPENCV_INCLUDE_INSTALL_PATH}/opencv-${OPENCV_VERSION})
 314 endif()
 315
 316 if(WIN32)
 317   # Postfix of DLLs:
 318   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 319   set(OPENCV_DEBUG_POSTFIX d)
 320 else()
 321   # Postfix of so's:
 322   set(OPENCV_DLLVERSION "")
 323   set(OPENCV_DEBUG_POSTFIX "")
 324 endif()
 325
 326 if(DEFINED CMAKE_DEBUG_POSTFIX)
 327   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 328 endif()
 329
 330 if(CMAKE_VERBOSE)
 331   set(CMAKE_VERBOSE_MAKEFILE 1)
 332 endif()
 333
 334
 335 # ----------------------------------------------------------------------------
 336 #  Path for build/platform -specific headers
 337 # ----------------------------------------------------------------------------
 338 set(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 339 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 340
 341 # ----------------------------------------------------------------------------
 342 #  Path for additional modules
 343 # ----------------------------------------------------------------------------
 344 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules")
 345
 346 # ----------------------------------------------------------------------------
 347 #  Autodetect if we are in a GIT repository
 348 # ----------------------------------------------------------------------------
 349
 350 # don't use FindGit because it requires CMake 2.8.2
 351 set(git_names git eg) # eg = easy git
 352 # Prefer .cmd variants on Windows unless running in a Makefile in the MSYS shell
 353 if(CMAKE_HOST_WIN32)
 354   if(NOT CMAKE_GENERATOR MATCHES "MSYS")
 355     set(git_names git.cmd git eg.cmd eg)
 356   endif()
 357 endif()
 358
 359 find_host_program(GIT_EXECUTABLE NAMES ${git_names} PATH_SUFFIXES Git/cmd Git/bin DOC "git command line client")
 360 mark_as_advanced(GIT_EXECUTABLE)
 361
 362 if(GIT_EXECUTABLE)
 363   execute_process(COMMAND ${GIT_EXECUTABLE} describe --tags --always --dirty --match "2.[0-9].[0-9]*"
 364     WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 365     OUTPUT_VARIABLE OPENCV_VCSVERSION
 366     RESULT_VARIABLE GIT_RESULT
 367     ERROR_QUIET
 368     OUTPUT_STRIP_TRAILING_WHITESPACE
 369   )
 370   if(NOT GIT_RESULT EQUAL 0)
 371     set(OPENCV_VCSVERSION "unknown")
 372   endif()
 373 else()
 374   # We don't have git:
 375   set(OPENCV_VCSVERSION "unknown")
 376 endif()
 377
 378
 379 # ----------------------------------------------------------------------------
 380 # OpenCV compiler and linker options
 381 # ----------------------------------------------------------------------------
 382 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 383 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 384   set(CMAKE_BUILD_TYPE Release)
 385 endif()
 386
 387 include(cmake/OpenCVCompilerOptions.cmake)
 388
 389
 390 # ----------------------------------------------------------------------------
 391 # Use statically or dynamically linked CRT?
 392 # Default: dynamic
 393 # ----------------------------------------------------------------------------
 394 if(MSVC)
 395   include(cmake/OpenCVCRTLinkage.cmake)
 396 endif(MSVC)
 397
 398 if(WIN32 AND NOT MINGW)
 399   add_definitions(-D_VARIADIC_MAX=10)
 400 endif(WIN32 AND NOT MINGW)
 401
 402
 403 # ----------------------------------------------------------------------------
 404 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 405 # ----------------------------------------------------------------------------
 406 if(UNIX)
 407   include(cmake/OpenCVFindPkgConfig.cmake OPTIONAL)
 408   include(CheckFunctionExists)
 409   include(CheckIncludeFile)
 410
 411   if(NOT APPLE)
 412     CHECK_INCLUDE_FILE(pthread.h HAVE_LIBPTHREAD)
 413     if(ANDROID)
 414       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 415     elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD|NetBSD|DragonFly")
 416       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 417     else()
 418       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 419     endif()
 420   else()
 421     set(HAVE_LIBPTHREAD YES)
 422   endif()
 423 endif()
 424
 425 include(cmake/OpenCVPCHSupport.cmake)
 426 include(cmake/OpenCVModule.cmake)
 427
 428 # ----------------------------------------------------------------------------
 429 #  Detect 3rd-party libraries
 430 # ----------------------------------------------------------------------------
 431
 432 include(cmake/OpenCVFindLibsGrfmt.cmake)
 433 include(cmake/OpenCVFindLibsGUI.cmake)
 434 include(cmake/OpenCVFindLibsVideo.cmake)
 435 include(cmake/OpenCVFindLibsPerf.cmake)
 436
 437
 438 # ----------------------------------------------------------------------------
 439 #  Detect other 3rd-party libraries/tools
 440 # ----------------------------------------------------------------------------
 441
 442 # --- LATEX for pdf documentation ---
 443 if(BUILD_DOCS)
 444   include(cmake/OpenCVFindLATEX.cmake)
 445 endif(BUILD_DOCS)
 446
 447 # --- Python Support ---
 448 include(cmake/OpenCVDetectPython.cmake)
 449
 450 # --- Java Support ---
 451 include(cmake/OpenCVDetectApacheAnt.cmake)
 452 if(ANDROID)
 453   include(cmake/OpenCVDetectAndroidSDK.cmake)
 454
 455   if(NOT ANDROID_TOOLS_Pkg_Revision GREATER 13)
 456     message(WARNING "OpenCV requires Android SDK tools revision 14 or newer. Otherwise tests and samples will no be compiled.")
 457   endif()
 458 else()
 459   find_package(JNI)
 460 endif()
 461
 462 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 463   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 464 else()
 465   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 466 endif()
 467
 468 # --- OpenCL ---
 469 if(WITH_OPENCL)
 470   include(cmake/OpenCVDetectOpenCL.cmake)
 471 endif()
 472
 473 # ----------------------------------------------------------------------------
 474 # Add CUDA libraries (needed for apps/tools, samples)
 475 # ----------------------------------------------------------------------------
 476 if(NOT HAVE_CUDA)
 477   set(ENABLE_DYNAMIC_CUDA OFF)
 478 endif()
 479
 480 if(HAVE_CUDA AND NOT ENABLE_DYNAMIC_CUDA)
 481   set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_LIBRARIES} ${CUDA_npp_LIBRARY})
 482   if(HAVE_CUBLAS)
 483     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cublas_LIBRARY})
 484   endif()
 485   if(HAVE_CUFFT)
 486     set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} ${CUDA_cufft_LIBRARY})
 487   endif()
 488 endif()
 489
 490 # ----------------------------------------------------------------------------
 491 # Solution folders:
 492 # ----------------------------------------------------------------------------
 493 if(ENABLE_SOLUTION_FOLDERS)
 494   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 495   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 496 endif()
 497
 498 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 499 include(cmake/OpenCVExtraTargets.cmake)
 500
 501
 502 # ----------------------------------------------------------------------------
 503 # Process subdirectories
 504 # ----------------------------------------------------------------------------
 505
 506 # opencv.hpp and legacy headers
 507 add_subdirectory(include)
 508
 509 # OpenCV modules
 510 add_subdirectory(modules)
 511
 512 # Generate targets for documentation
 513 add_subdirectory(doc)
 514
 515 # various data that is used by cv libraries and/or demo applications.
 516 add_subdirectory(data)
 517
 518 # extra applications
 519 if(BUILD_opencv_apps)
 520   add_subdirectory(apps)
 521 endif()
 522
 523 # examples
 524 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES)
 525   add_subdirectory(samples)
 526 endif()
 527
 528 if(ANDROID)
 529   add_subdirectory(platforms/android/service)
 530 endif()
 531
 532 if(BUILD_ANDROID_PACKAGE)
 533   add_subdirectory(platforms/android/package)
 534 endif()
 535
 536 if (ANDROID)
 537   add_subdirectory(platforms/android/libinfo)
 538 endif()
 539
 540 # ----------------------------------------------------------------------------
 541 # Finalization: generate configuration-based files
 542 # ----------------------------------------------------------------------------
 543 ocv_track_build_dependencies()
 544
 545 # Generate platform-dependent and configuration-dependent headers
 546 include(cmake/OpenCVGenHeaders.cmake)
 547
 548 # Generate opencv.pc for pkg-config command
 549 include(cmake/OpenCVGenPkgconfig.cmake)
 550
 551 # Generate OpenCV.mk for ndk-build (Android build tool)
 552 include(cmake/OpenCVGenAndroidMK.cmake)
 553
 554 # Generate OpenCVСonfig.cmake and OpenCVConfig-version.cmake for cmake projects
 555 include(cmake/OpenCVGenConfig.cmake)
 556
 557 # Generate Info.plist for the IOS framework
 558 include(cmake/OpenCVGenInfoPlist.cmake)
 559
 560 # ----------------------------------------------------------------------------
 561 # Summary:
 562 # ----------------------------------------------------------------------------
 563 status("")
 564 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 565 if(OPENCV_VCSVERSION)
 566   status("  Version control:" ${OPENCV_VCSVERSION})
 567 endif()
 568
 569 # ========================== build platform ==========================
 570 status("")
 571 status("  Platform:")
 572 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
 573 if(CMAKE_CROSSCOMPILING)
 574   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
 575 endif()
 576 status("    CMake:"            ${CMAKE_VERSION})
 577 status("    CMake generator:"  ${CMAKE_GENERATOR})
 578 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
 579 if(MSVC)
 580   status("    MSVC:"           ${MSVC_VERSION})
 581 endif()
 582 if(CMAKE_GENERATOR MATCHES Xcode)
 583   status("    Xcode:"          ${XCODE_VERSION})
 584 endif()
 585 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
 586   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
 587 endif()
 588
 589 # ========================== C/C++ options ==========================
 590 if(CMAKE_CXX_COMPILER_VERSION)
 591   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
 592 elseif(CMAKE_COMPILER_IS_CLANGCXX)
 593   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CLANG_REGEX_VERSION})")
 594 elseif(CMAKE_COMPILER_IS_GNUCXX)
 595   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_GCC_REGEX_VERSION})")
 596 else()
 597   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 598 endif()
 599 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
 600
 601 status("")
 602 status("  C/C++:")
 603 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
 604 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
 605 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
 606 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
 607 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
 608 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
 609 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
 610 if(WIN32)
 611   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
 612   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
 613 else()
 614   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
 615   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
 616 endif()
 617 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
 618
 619 # ========================== OpenCV modules ==========================
 620 status("")
 621 status("  OpenCV modules:")
 622 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD}")
 623 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
 624 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
 625 set(OPENCV_MODULES_DISABLED_AUTO_ST "")
 626 foreach(m ${OPENCV_MODULES_DISABLED_AUTO})
 627   set(__mdeps "")
 628   foreach(d ${OPENCV_MODULE_${m}_DEPS})
 629     if(d MATCHES "^opencv_" AND NOT HAVE_${d})
 630       list(APPEND __mdeps ${d})
 631     endif()
 632   endforeach()
 633   if(__mdeps)
 634     list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}(deps: ${__mdeps})")
 635   else()
 636     list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}")
 637   endif()
 638 endforeach()
 639 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO_ST}")
 640
 641 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
 642 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
 643 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
 644 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
 645
 646 # ========================== Android details ==========================
 647 if(ANDROID)
 648   status("")
 649   status("  Android: ")
 650   status("    Android ABI:" ${ANDROID_ABI})
 651   status("    STL type:" ${ANDROID_STL})
 652   status("    Native API level:" android-${ANDROID_NATIVE_API_LEVEL})
 653   android_get_compatible_target(android_sdk_target_status ${ANDROID_NATIVE_API_LEVEL} ${ANDROID_SDK_TARGET} 11)
 654   status("    SDK target:" "${android_sdk_target_status}")
 655   if(BUILD_WITH_ANDROID_NDK)
 656     status("    Android NDK:" "${ANDROID_NDK} (toolchain: ${ANDROID_TOOLCHAIN_NAME})")
 657   elseif(BUILD_WITH_STANDALONE_TOOLCHAIN)
 658     status("    Android toolchain:" "${ANDROID_STANDALONE_TOOLCHAIN}")
 659   endif()
 660   status("    android tool:"  ANDROID_EXECUTABLE  THEN "${ANDROID_EXECUTABLE} (${ANDROID_TOOLS_Pkg_Desc})" ELSE NO)
 661   status("    Google Play package:" BUILD_ANDROID_PACKAGE                                         THEN YES ELSE NO)
 662   status("    Android examples:"    BUILD_ANDROID_EXAMPLES AND CAN_BUILD_ANDROID_PROJECTS         THEN YES ELSE NO)
 663 endif()
 664
 665 # ================== Windows RT features ==================
 666 if(WIN32)
 667 status("")
 668     status("  Windows RT support:" HAVE_WINRT THEN YES ELSE NO)
 669     if (ENABLE_WINRT_MODE)
 670       status("    Windows SDK v8.0:" ${WINDOWS_SDK_PATH})
 671       status("    Visual Studio 2012:" ${VISUAL_STUDIO_PATH})
 672     endif()
 673 endif(WIN32)
 674
 675 # ========================== GUI ==========================
 676 status("")
 677 status("  GUI: ")
 678
 679 if(HAVE_QT5)
 680   status("    QT 5.x:"            HAVE_QT        THEN "YES (ver ${Qt5Core_VERSION_STRING})" ELSE NO)
 681   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt5OpenGL_LIBRARIES} ${Qt5OpenGL_VERSION_STRING})" ELSE NO)
 682 elseif(HAVE_QT)
 683   status("    QT 4.x:"            HAVE_QT        THEN "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})" ELSE NO)
 684   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
 685 else()
 686   if(DEFINED WITH_QT)
 687     status("    QT:" NO)
 688   endif()
 689   if(DEFINED WITH_WIN32UI)
 690     status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
 691   else()
 692     if(APPLE)
 693       if(WITH_CARBON)
 694         status("    Carbon:" YES)
 695       else()
 696         status("    Cocoa:"  YES)
 697       endif()
 698     else()
 699       status("    GTK+ 2.x:" HAVE_GTK      THEN "YES (ver ${ALIASOF_gtk+-2.0_VERSION})"     ELSE NO)
 700       status("    GThread :" HAVE_GTHREAD  THEN "YES (ver ${ALIASOF_gthread-2.0_VERSION})"  ELSE NO)
 701       status("    GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${ALIASOF_gtkglext-1.0_VERSION})" ELSE NO)
 702     endif()
 703   endif()
 704 endif()
 705
 706 status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
 707
 708 # ========================== MEDIA IO ==========================
 709 status("")
 710 status("  Media I/O: ")
 711 status("    ZLib:"         BUILD_ZLIB    THEN "build (ver ${ZLIB_VERSION_STRING})"               ELSE "${ZLIB_LIBRARY} (ver ${ZLIB_VERSION_STRING})")
 712
 713 if(WITH_JPEG)
 714   status("    JPEG:"       JPEG_FOUND    THEN "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})"        ELSE "build (ver ${JPEG_LIB_VERSION})")
 715 else()
 716   status("    JPEG:"       "NO")
 717 endif()
 718 if(WITH_PNG)
 719   status("    PNG:"        PNG_FOUND     THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})"              ELSE "build (ver ${PNG_VERSION})")
 720 else()
 721   status("    PNG:"        "NO")
 722 endif()
 723 if(WITH_TIFF)
 724   if(TIFF_VERSION_STRING AND TIFF_FOUND)
 725     status("    TIFF:"     "${TIFF_LIBRARY} (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 726   else()
 727     status("    TIFF:"     TIFF_FOUND    THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION})"            ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 728   endif()
 729 else()
 730   status("    TIFF:"       "NO")
 731 endif()
 732 if(WITH_JASPER)
 733   status("    JPEG 2000:"  JASPER_FOUND  THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
 734 else()
 735   status("    JPEG 2000:"  "NO")
 736 endif()
 737 if(WITH_OPENEXR)
 738   status("    OpenEXR:"  OPENEXR_FOUND  THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
 739 else()
 740   status("    OpenEXR:"  "NO")
 741 endif()
 742
 743 # ========================== VIDEO IO ==========================
 744 status("")
 745 status("  Video I/O:")
 746
 747 if (DEFINED WITH_VFW)
 748   status("    Video for Windows:" HAVE_VFW         THEN YES                                        ELSE NO)
 749 endif(DEFINED WITH_VFW)
 750
 751 if(DEFINED WITH_1394)
 752   status("    DC1394 1.x:"     HAVE_DC1394         THEN "YES (ver ${ALIASOF_libdc1394_VERSION})"   ELSE NO)
 753   status("    DC1394 2.x:"     HAVE_DC1394_2       THEN "YES (ver ${ALIASOF_libdc1394-2_VERSION})" ELSE NO)
 754 endif(DEFINED WITH_1394)
 755
 756 if(ANDROID)
 757   if(HAVE_opencv_androidcamera)
 758     status("    AndroidNativeCamera:" BUILD_ANDROID_CAMERA_WRAPPER
 759                                                    THEN "YES, build for Android${ANDROID_VERSION}" ELSE "YES, use prebuilt libraries")
 760   else()
 761     status("    AndroidNativeCamera:" "NO (native camera requires Android API level 8 or higher)")
 762   endif()
 763 endif()
 764
 765 if(DEFINED WITH_AVFOUNDATION)
 766   status("    AVFoundation:"   WITH_AVFOUNDATION   THEN YES                                        ELSE NO)
 767 endif(DEFINED WITH_AVFOUNDATION)
 768
 769 if(DEFINED WITH_FFMPEG)
 770   if(WIN32)
 771     status("    FFMPEG:"       WITH_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
 772   else()
 773     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
 774   endif()
 775   status("      codec:"        HAVE_FFMPEG_CODEC   THEN "YES (ver ${ALIASOF_libavcodec_VERSION})"  ELSE NO)
 776   status("      format:"       HAVE_FFMPEG_FORMAT  THEN "YES (ver ${ALIASOF_libavformat_VERSION})" ELSE NO)
 777   status("      util:"         HAVE_FFMPEG_UTIL    THEN "YES (ver ${ALIASOF_libavutil_VERSION})"   ELSE NO)
 778   status("      swscale:"      HAVE_FFMPEG_SWSCALE THEN "YES (ver ${ALIASOF_libswscale_VERSION})"  ELSE NO)
 779   status("      gentoo-style:" HAVE_GENTOO_FFMPEG  THEN YES                                        ELSE NO)
 780 endif(DEFINED WITH_FFMPEG)
 781
 782 if(DEFINED WITH_GSTREAMER)
 783   status("    GStreamer:"      HAVE_GSTREAMER      THEN ""                                         ELSE NO)
 784   if(HAVE_GSTREAMER)
 785     status("      base:"       "YES (ver ${ALIASOF_gstreamer-base-0.10_VERSION})")
 786     status("      app:"        "YES (ver ${ALIASOF_gstreamer-app-0.10_VERSION})")
 787     status("      video:"      "YES (ver ${ALIASOF_gstreamer-video-0.10_VERSION})")
 788   endif()
 789 endif(DEFINED WITH_GSTREAMER)
 790
 791 if(DEFINED WITH_OPENNI)
 792   status("    OpenNI:"         HAVE_OPENNI         THEN "YES (ver ${OPENNI_VERSION_STRING}, build ${OPENNI_VERSION_BUILD})"
 793                                                                                                    ELSE NO)
 794   status("    OpenNI PrimeSensor Modules:" HAVE_OPENNI_PRIME_SENSOR_MODULE
 795                                                    THEN "YES (${OPENNI_PRIME_SENSOR_MODULE})"      ELSE NO)
 796 endif(DEFINED WITH_OPENNI)
 797
 798 if(DEFINED WITH_PVAPI)
 799   status("    PvAPI:"          HAVE_PVAPI          THEN YES                                        ELSE NO)
 800 endif(DEFINED WITH_PVAPI)
 801
 802 if(DEFINED WITH_GIGEAPI)
 803   status("    GigEVisionSDK:"  HAVE_GIGE_API       THEN YES                                        ELSE NO)
 804 endif(DEFINED WITH_GIGEAPI)
 805
 806 if(DEFINED WITH_QUICKTIME)
 807   status("    QuickTime:"      HAVE_QUICKTIME      THEN YES                                        ELSE NO)
 808   status("    QTKit:"          HAVE_QTKIT          THEN YES                                        ELSE NO)
 809 endif(DEFINED WITH_QUICKTIME)
 810
 811 if(DEFINED WITH_UNICAP)
 812   status("    UniCap:"         HAVE_UNICAP         THEN "YES (ver ${ALIASOF_libunicap_VERSION})"   ELSE NO)
 813   status("    UniCap ucil:"    HAVE_UNICAP_UCIL    THEN "YES (ver ${ALIASOF_libucil_VERSION})"     ELSE NO)
 814 endif(DEFINED WITH_UNICAP)
 815
 816 if(DEFINED WITH_V4L)
 817   if(HAVE_CAMV4L)
 818     set(HAVE_CAMV4L_STR "YES")
 819   else()
 820     set(HAVE_CAMV4L_STR "NO")
 821   endif()
 822   if(HAVE_CAMV4L2)
 823     set(HAVE_CAMV4L2_STR "YES")
 824   elseif(HAVE_VIDEOIO)
 825     set(HAVE_CAMV4L2_STR "YES(videoio)")
 826   else()
 827     set(HAVE_CAMV4L2_STR "NO")
 828   endif()
 829   status("    V4L/V4L2:"       HAVE_LIBV4L         THEN "Using libv4l (ver ${ALIASOF_libv4l1_VERSION})"
 830                                                    ELSE "${HAVE_CAMV4L_STR}/${HAVE_CAMV4L2_STR}")
 831 endif(DEFINED WITH_V4L)
 832
 833 if(DEFINED WITH_DSHOW)
 834   status("    DirectShow:"     HAVE_DSHOW     THEN YES                                        ELSE NO)
 835 endif(DEFINED WITH_DSHOW)
 836
 837 if(DEFINED WITH_MSMF)
 838   status("    Media Foundation:" HAVE_MSMF    THEN YES                                        ELSE NO)
 839 endif(DEFINED WITH_MSMF)
 840
 841 if(DEFINED WITH_XIMEA)
 842   status("    XIMEA:"          HAVE_XIMEA          THEN YES                                        ELSE NO)
 843 endif(DEFINED WITH_XIMEA)
 844
 845 if(DEFINED WITH_XINE)
 846   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${ALIASOF_libxine_VERSION})"     ELSE NO)
 847 endif(DEFINED WITH_XINE)
 848
 849 if(DEFINED WITH_INTELPERC)
 850   status("    Intel PerC:"     HAVE_INTELPERC      THEN "YES"                                 ELSE NO)
 851 endif(DEFINED WITH_INTELPERC)
 852
 853
 854 # ========================== Other third-party libraries ==========================
 855 status("")
 856 status("  Other third-party libraries:")
 857
 858 if(WITH_IPP AND IPP_FOUND)
 859   status("    Use IPP:" "${IPP_LATEST_VERSION_STR} [${IPP_LATEST_VERSION_MAJOR}.${IPP_LATEST_VERSION_MINOR}.${IPP_LATEST_VERSION_BUILD}]")
 860   status("         at:" "${IPP_ROOT_DIR}")
 861 else()
 862   status("    Use IPP:"   WITH_IPP AND NOT IPP_FOUND THEN "IPP not found" ELSE NO)
 863 endif()
 864
 865 status("    Use Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
 866 status("    Use TBB:"        HAVE_TBB         THEN "YES (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})" ELSE NO)
 867 status("    Use OpenMP:"     HAVE_OPENMP      THEN YES ELSE NO)
 868 status("    Use GCD"         HAVE_GCD         THEN YES ELSE NO)
 869 status("    Use Concurrency" HAVE_CONCURRENCY THEN YES ELSE NO)
 870 status("    Use C=:"         HAVE_CSTRIPES    THEN YES ELSE NO)
 871 status("    Use Cuda:"       HAVE_CUDA        THEN "YES (ver ${CUDA_VERSION_STRING})" ELSE NO)
 872 status("    Use OpenCL:"     HAVE_OPENCL      THEN YES ELSE NO)
 873
 874 if(HAVE_CUDA)
 875   status("")
 876   status("  NVIDIA CUDA")
 877
 878   status("    Use CUFFT:"            HAVE_CUFFT   THEN YES ELSE NO)
 879   status("    Use CUBLAS:"           HAVE_CUBLAS  THEN YES ELSE NO)
 880   status("    USE NVCUVID:"          HAVE_NVCUVID THEN YES ELSE NO)
 881   status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
 882   status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
 883   status("    Use fast math:"        CUDA_FAST_MATH THEN YES ELSE NO)
 884 endif()
 885
 886 if(HAVE_OPENCL)
 887   status("")
 888   status("  OpenCL:")
 889   if(HAVE_OPENCL_STATIC)
 890     set(__opencl_ver "static")
 891   else()
 892     set(__opencl_ver "dynamic")
 893   endif()
 894   status("    Version:"       ${__opencl_ver})
 895   if(OPENCL_INCLUDE_DIR)
 896     status("    Include path:"       ${OPENCL_INCLUDE_DIRS})
 897   endif()
 898   if(OPENCL_LIBRARIES)
 899     set(__libs "")
 900     foreach(l ${OPENCL_LIBRARIES})
 901       if(TARGET ${l})
 902         get_target_property(p ${l} LOCATION)
 903         if(p MATCHES NOTFOUND)
 904           list(APPEND __libs "${l}")
 905         else()
 906           list(APPEND __libs "${p}")
 907         endif()
 908       else()
 909         list(APPEND __libs "${l}")
 910       endif()
 911     endforeach()
 912     status("    libraries:"          ${__libs})
 913   endif()
 914   status("    Use AMD FFT:"          HAVE_CLAMDFFT  THEN YES ELSE NO)
 915   status("    Use AMD BLAS:"         HAVE_CLAMDBLAS THEN YES ELSE NO)
 916 endif()
 917
 918 # ========================== python ==========================
 919 status("")
 920 status("  Python:")
 921 status("    Interpreter:"     PYTHON_EXECUTABLE   THEN "${PYTHON_EXECUTABLE} (ver ${PYTHON_VERSION_FULL})"         ELSE NO)
 922 if(BUILD_opencv_python)
 923   if(PYTHONLIBS_VERSION_STRING)
 924     status("    Libraries:"   HAVE_opencv_python  THEN  "${PYTHON_LIBRARIES} (ver ${PYTHONLIBS_VERSION_STRING})"   ELSE NO)
 925   else()
 926     status("    Libraries:"   HAVE_opencv_python  THEN  ${PYTHON_LIBRARIES}                                        ELSE NO)
 927   endif()
 928   status("    numpy:"         PYTHON_USE_NUMPY    THEN "${PYTHON_NUMPY_INCLUDE_DIR} (ver ${PYTHON_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
 929   status("    packages path:" PYTHON_EXECUTABLE   THEN "${PYTHON_PACKAGES_PATH}"                                   ELSE "-")
 930 endif()
 931
 932 # ========================== java ==========================
 933 status("")
 934 status("  Java:")
 935 status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
 936 if(NOT ANDROID)
 937   status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
 938 endif()
 939 status("    Java tests:"    BUILD_TESTS AND (CAN_BUILD_ANDROID_PROJECTS OR HAVE_opencv_java)            THEN YES ELSE NO)
 940
 941 # ========================== documentation ==========================
 942 if(BUILD_DOCS)
 943   status("")
 944   status("  Documentation:")
 945   if(HAVE_SPHINX)
 946     status("    Build Documentation:" PDFLATEX_COMPILER      THEN YES ELSE "YES (only HTML and without math expressions)")
 947   else()
 948     status("    Build Documentation:" NO)
 949   endif()
 950   status("    Sphinx:"              HAVE_SPHINX              THEN "${SPHINX_BUILD} (ver ${SPHINX_VERSION})" ELSE NO)
 951   status("    PdfLaTeX compiler:"   PDFLATEX_COMPILER        THEN "${PDFLATEX_COMPILER}" ELSE NO)
 952 endif()
 953
 954 # ========================== samples and tests ==========================
 955 status("")
 956 status("  Tests and samples:")
 957 status("    Tests:"             BUILD_TESTS AND HAVE_opencv_ts       THEN YES ELSE NO)
 958 status("    Performance tests:" BUILD_PERF_TESTS AND HAVE_opencv_ts  THEN YES ELSE NO)
 959 status("    C/C++ Examples:"    BUILD_EXAMPLES                       THEN YES ELSE NO)
 960
 961 # ========================== auxiliary ==========================
 962 status("")
 963 status("  Install path:" "${CMAKE_INSTALL_PREFIX}")
 964 status("")
 965 status("  cvconfig.h is in:" "${OPENCV_CONFIG_FILE_INCLUDE_DIR}")
 966 status("-----------------------------------------------------------------")
 967 status("")
 968
 969 ocv_finalize_status()
 970
 971 # ----------------------------------------------------------------------------
 972 # Warn in the case of in-source build
 973 # ----------------------------------------------------------------------------
 974 if("${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 975   message(WARNING "The source directory is the same as binary directory. \"make clean\" may damage the source tree")
 976 endif()