CMakeLists.txt

   1 # The name of our project is "VULKAN". CMakeLists files in this project can
   2 # refer to the root source directory of the project as ${VULKAN_SOURCE_DIR} and
   3 # to the root binary directory of the project as ${VULKAN_BINARY_DIR}.
   4 cmake_minimum_required(VERSION 2.8.11)
   5 project (VULKAN)
   6 # set (CMAKE_VERBOSE_MAKEFILE 1)
   7
   8 # The API_NAME allows renaming builds to avoid conflicts with installed SDKs
   9 # The MAJOR number of the version we're building, used in naming
  10 # <api-name>-<major>.dll (and other files).
  11 set(API_NAME "Vulkan" CACHE STRING "API name to use when building")
  12 set(MAJOR "1")
  13 string(TOLOWER ${API_NAME} API_LOWERCASE)
  14
  15 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  16 find_package(PythonInterp 3 REQUIRED)
  17
  18 option(USE_CCACHE "Use ccache" OFF)
  19 if (USE_CCACHE)
  20     find_program(CCACHE_FOUND ccache)
  21     if(CCACHE_FOUND)
  22         set_property(GLOBAL PROPERTY RULE_LAUNCH_COMPILE ccache)
  23         set_property(GLOBAL PROPERTY RULE_LAUNCH_LINK ccache)
  24     endif(CCACHE_FOUND)
  25 endif()
  26
  27 # Enable cmake folders
  28 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  29 set(LVL_TARGET_FOLDER lvl_cmake_targets)
  30
  31 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
  32     set(FALLBACK_CONFIG_DIRS "/etc/xdg" CACHE STRING
  33         "Search path to use when XDG_CONFIG_DIRS is unset or empty or the current process is SUID/SGID. Default is freedesktop compliant.")
  34     set(FALLBACK_DATA_DIRS "/usr/local/share:/usr/share" CACHE STRING
  35         "Search path to use when XDG_DATA_DIRS is unset or empty or the current process is SUID/SGID. Default is freedesktop compliant.")
  36
  37     include(FindPkgConfig)
  38     option(BUILD_WSI_XCB_SUPPORT "Build XCB WSI support" ON)
  39     option(BUILD_WSI_XLIB_SUPPORT "Build Xlib WSI support" ON)
  40     option(BUILD_WSI_WAYLAND_SUPPORT "Build Wayland WSI support" ON)
  41     option(BUILD_WSI_MIR_SUPPORT "Build Mir WSI support" OFF)
  42     set(DEMOS_WSI_SELECTION "XCB" CACHE STRING "Select WSI target for demos (XCB, XLIB, WAYLAND, MIR, DISPLAY)")
  43
  44     if (BUILD_WSI_XCB_SUPPORT)
  45         find_package(XCB REQUIRED)
  46     endif()
  47
  48     if (BUILD_WSI_XLIB_SUPPORT)
  49         find_package(X11 REQUIRED)
  50     endif()
  51
  52     if (BUILD_WSI_WAYLAND_SUPPORT)
  53         find_package(Wayland REQUIRED)
  54         include_directories(${WAYLAND_CLIENT_INCLUDE_DIR})
  55     endif()
  56
  57     if (BUILD_WSI_MIR_SUPPORT)
  58         find_package(Mir REQUIRED)
  59     endif()
  60
  61     # This option can be used to suppress the installation of artifacts from the
  62     # Vulkan-LoaderAndValidationLayers repo while running "make install" for the
  63     # VulkanTools and VulkanSamples repos.  This can be used to prevent the
  64     # overwriting of LVL artifacts when installing these downstream repos.
  65     option(INSTALL_LVL_FILES "Install content from LoaderAndValidationLayers repo" ON)
  66 endif()
  67
  68 set(SCRIPTS_DIR "${CMAKE_CURRENT_SOURCE_DIR}/scripts")
  69
  70 # Header file for CMake settings
  71 include_directories("${PROJECT_SOURCE_DIR}/include")
  72
  73 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Clang")
  74     set(COMMON_COMPILE_FLAGS "-Wall -Wextra -Wno-unused-parameter -Wno-missing-field-initializers")
  75     set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -fno-strict-aliasing -fno-builtin-memcmp")
  76
  77     # For GCC version 7.1 or greater, we need to disable the implicit fallthrough warning since
  78     # there's no consistent way to satisfy all compilers until they all accept the C++17 standard
  79     if (CMAKE_COMPILER_IS_GNUCC AND NOT (CMAKE_CXX_COMPILER_VERSION LESS 7.1))
  80         set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -Wimplicit-fallthrough=0")
  81     endif()
  82
  83     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=c99 ${COMMON_COMPILE_FLAGS}")
  84     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${COMMON_COMPILE_FLAGS} -std=c++11 -fno-rtti")
  85     if (UNIX)
  86         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden")
  87         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")
  88     endif()
  89 endif()
  90
  91 if(WIN32)
  92     # Treat warnings as errors
  93     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/WX>")
  94     # Disable RTTI
  95     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/GR->")
  96     # Warn about nested declarations
  97     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34456>")
  98     # Warn about potentially uninitialized variables
  99     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34701>")
 100     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34703>")
 101     # Warn about different indirection types.
 102     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34057>")
 103     # Warn about signed/unsigned mismatch.
 104     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34245>")
 105 endif()
 106
 107 if(NOT WIN32)
 108     set (BUILDTGT_DIR build)
 109     set (BINDATA_DIR Bin)
 110     set (LIBSOURCE_DIR Lib)
 111 else()
 112     # is WIN32
 113     option(DISABLE_BUILD_PATH_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with MSVC build type info" OFF)
 114     option(DISABLE_BUILDTGT_DIR_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with target info" OFF)
 115
 116     # For Windows, since 32-bit and 64-bit items can co-exist, we build each in its own build directory.
 117     # 32-bit target data goes in build32, and 64-bit target data goes into build.  So, include/link the
 118     # appropriate data at build time.
 119     if (DISABLE_BUILDTGT_DIR_DECORATION)
 120         set (BUILDTGT_DIR "")
 121         set (BINDATA_DIR "")
 122         set (LIBSOURCE_DIR "")
 123     elseif (CMAKE_CL_64)
 124         set (BUILDTGT_DIR build)
 125         set (BINDATA_DIR Bin)
 126         set (LIBSOURCE_DIR Lib)
 127     else()
 128         set (BUILDTGT_DIR build32)
 129         set (BINDATA_DIR Bin32)
 130         set (LIBSOURCE_DIR Lib32)
 131     endif()
 132 endif()
 133
 134 option(BUILD_LOADER "Build loader" ON)
 135 option(BUILD_TESTS "Build tests" ON)
 136 option(BUILD_LAYERS "Build layers" ON)
 137 option(BUILD_DEMOS "Build demos" ON)
 138 option(BUILD_VKJSON "Build vkjson" ON)
 139 option(BUILD_ICD "Build icd" ON)
 140 option(CUSTOM_GLSLANG_BIN_ROOT "Use the user defined GLSLANG_BINARY_ROOT" OFF)
 141 option(CUSTOM_SPIRV_TOOLS_BIN_ROOT "Use the user defined SPIRV_TOOLS*BINARY_ROOT paths" OFF)
 142
 143 #Choose natural default paths for glslang and SPIRV-Tools binaries to support custom definition by the user on the CMake command line or in the GUI
 144 set(GLSLANG_BINARY_ROOT "${CMAKE_BINARY_DIR}/../glslang" CACHE STRING "User defined path to the glslang binaries for this project")
 145 set(SPIRV_TOOLS_BINARY_ROOT "${CMAKE_BINARY_DIR}/../SPIRV-Tools" CACHE STRING "User defined path to the SPIRV-Tools binaries for this project")
 146 set(SPIRV_TOOLS_OPT_BINARY_ROOT "${CMAKE_BINARY_DIR}/../SPIRV-Tools/opt" CACHE STRING "User defined path to the SPIRV-Tools-opt binaries for this project")
 147
 148 # Define a variable for a default root location to the gslang, SPIRV-Tools and other external sources and cache it to allow the user to customize it as needed
 149 set(EXTERNAL_SOURCE_ROOT "${CMAKE_CURRENT_SOURCE_DIR}/external" CACHE STRING "Root path to external sources such as glslang and SPIRV-Tools")
 150
 151
 152 if (WIN32)
 153     if(CUSTOM_GLSLANG_BIN_ROOT)
 154         set(GSLANG_FINAL_BINARY_PATH ${GLSLANG_BINARY_ROOT}/${BUILDTGT_DIR})
 155     else()
 156         set(GSLANG_FINAL_BINARY_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}")
 157     endif()
 158
 159     if(DISABLE_BUILD_PATH_DECORATION)
 160         set (DEBUG_DECORATION "")
 161         set (RELEASE_DECORATION "")
 162     else()
 163         set (DEBUG_DECORATION "Debug")
 164         set (RELEASE_DECORATION "Release")
 165     endif()
 166
 167     # Take some steps to set up a variable pointing to the final glslang binaries given the variety of input options
 168     set (GLSLANG_SEARCH_PATH "${GSLANG_FINAL_BINARY_PATH}/glslang/${RELEASE_DECORATION}"
 169                              "${GSLANG_FINAL_BINARY_PATH}/glslang/OSDependent/Windows/${RELEASE_DECORATION}"
 170                              "${GSLANG_FINAL_BINARY_PATH}/hlsl/${RELEASE_DECORATION}"
 171                              "${GSLANG_FINAL_BINARY_PATH}/OGLCompilersDLL/${RELEASE_DECORATION}"
 172                              "${GSLANG_FINAL_BINARY_PATH}/SPIRV/${RELEASE_DECORATION}" )
 173
 174     set (GLSLANG_DEBUG_SEARCH_PATH "${GSLANG_FINAL_BINARY_PATH}/glslang/${DEBUG_DECORATION}"
 175                                    "${GSLANG_FINAL_BINARY_PATH}/glslang/OSDependent/Windows/${DEBUG_DECORATION}"
 176                                    "${GSLANG_FINAL_BINARY_PATH}/hlsl/${DEBUG_DECORATION}"
 177                                    "${GSLANG_FINAL_BINARY_PATH}/OGLCompilersDLL/${DEBUG_DECORATION}"
 178                                    "${GSLANG_FINAL_BINARY_PATH}/SPIRV/${DEBUG_DECORATION}")
 179
 180     if(CUSTOM_SPIRV_TOOLS_BIN_ROOT)
 181         set (SPIRV_TOOLS_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/${BUILDTGT_DIR}/source/${RELEASE_DECORATION}")
 182         set (SPIRV_TOOLS_DEBUG_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/${BUILDTGT_DIR}/source/${DEBUG_DECORATION}")
 183         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${SPIRV_TOOLS_OPT_BINARY_ROOT}/${BUILDTGT_DIR}/source/opt/${RELEASE_DECORATION}")
 184         set (SPIRV_TOOLS_OPT_DEBUG_SEARCH_PATH "${SPIRV_TOOLS_OPT_BINARY_ROOT}/${BUILDTGT_DIR}/source/opt/${DEBUG_DECORATION}")
 185     else()
 186         set (SPIRV_TOOLS_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source/${RELEASE_DECORATION}")
 187         set (SPIRV_TOOLS_DEBUG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source/${DEBUG_DECORATION}")
 188         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source/opt/${RELEASE_DECORATION}")
 189         set (SPIRV_TOOLS_OPT_DEBUG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source/opt/${DEBUG_DECORATION}")
 190     endif()
 191 else()
 192     # not WIN32
 193     if(CUSTOM_GLSLANG_BIN_ROOT)
 194         set (GLSLANG_SEARCH_PATH "${GLSLANG_BINARY_ROOT}/install/lib"
 195                                  "${GLSLANG_BINARY_ROOT}/glslang"
 196                                  "${GLSLANG_BINARY_ROOT}/glslang/OSDependent/Unix"
 197                                  "${GLSLANG_BINARY_ROOT}/OGLCompilersDLL"
 198                                  "${GLSLANG_BINARY_ROOT}/SPIRV"
 199                                  "${GLSLANG_BINARY_ROOT}/hlsl"
 200                                  "${GLSLANG_BINARY_ROOT}/StandAlone")
 201     else()
 202         set (GLSLANG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/install/lib" "${CMAKE_SOURCE_DIR}/../x86_64/lib/glslang" )
 203     endif()
 204
 205     if(CUSTOM_SPIRV_TOOLS_BIN_ROOT)
 206         set (SPIRV_TOOLS_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/source" )
 207         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${SPIRV_TOOLS_OPT_BINARY_ROOT}/source/opt" )
 208     else()
 209         set (SPIRV_TOOLS_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source" "${CMAKE_SOURCE_DIR}/../x86_64/lib/spirv-tools" )
 210         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/External/spirv-tools/source/opt" "${CMAKE_SOURCE_DIR}/../x86_64/lib/spirv-tools" )
 211     endif()
 212 endif()
 213
 214 find_program(GLSLANG_VALIDATOR NAMES glslangValidator
 215              HINTS "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/install/bin"
 216                    "${GLSLANG_BINARY_ROOT}/StandAlone"
 217                    "${PROJECT_SOURCE_DIR}/external/${BINDATA_DIR}")
 218
 219 find_path(GLSLANG_SPIRV_INCLUDE_DIR SPIRV/spirv.hpp HINTS "${EXTERNAL_SOURCE_ROOT}/glslang"
 220                                                     "${CMAKE_SOURCE_DIR}/../glslang"
 221                                               DOC "Path to SPIRV/spirv.hpp")
 222
 223 find_path(SPIRV_TOOLS_INCLUDE_DIR spirv-tools/libspirv.h HINTS "${EXTERNAL_SOURCE_ROOT}/glslang/External/spirv-tools/include"
 224                                                    "${CMAKE_SOURCE_DIR}/../glslang/External/spirv-tools/include"
 225                                              DOC "Path to spirv-tools/libspirv.h")
 226
 227 find_library(GLSLANG_LIB NAMES glslang
 228              HINTS ${GLSLANG_SEARCH_PATH} )
 229
 230 find_library(OGLCompiler_LIB NAMES OGLCompiler
 231              HINTS ${GLSLANG_SEARCH_PATH} )
 232
 233 find_library(OSDependent_LIB NAMES OSDependent
 234              HINTS ${GLSLANG_SEARCH_PATH} )
 235
 236 find_library(HLSL_LIB NAMES HLSL
 237              HINTS ${GLSLANG_SEARCH_PATH} )
 238
 239 find_library(SPIRV_LIB NAMES SPIRV
 240              HINTS ${GLSLANG_SEARCH_PATH} )
 241
 242 find_library(SPIRV_REMAPPER_LIB NAMES SPVRemapper
 243              HINTS ${GLSLANG_SEARCH_PATH} )
 244
 245 find_library(SPIRV_TOOLS_LIB NAMES SPIRV-Tools
 246              HINTS ${SPIRV_TOOLS_SEARCH_PATH} )
 247
 248 find_library(SPIRV_TOOLS_OPT_LIB NAMES SPIRV-Tools-opt
 249              HINTS ${SPIRV_TOOLS_OPT_SEARCH_PATH} )
 250
 251 if (WIN32)
 252     add_library(glslang         STATIC IMPORTED)
 253     add_library(OGLCompiler     STATIC IMPORTED)
 254     add_library(OSDependent     STATIC IMPORTED)
 255     add_library(HLSL            STATIC IMPORTED)
 256     add_library(SPIRV           STATIC IMPORTED)
 257     add_library(SPVRemapper     STATIC IMPORTED)
 258     add_library(Loader          STATIC IMPORTED)
 259     add_library(SPIRV-Tools-opt STATIC IMPORTED)
 260     add_library(SPIRV-Tools     STATIC IMPORTED)
 261
 262     find_library(GLSLANG_DLIB NAMES glslangd
 263                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 264     find_library(OGLCompiler_DLIB NAMES OGLCompilerd
 265                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 266     find_library(OSDependent_DLIB NAMES OSDependentd
 267                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 268     find_library(HLSL_DLIB NAMES HLSLd
 269                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 270     find_library(SPIRV_DLIB NAMES SPIRVd
 271                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 272     find_library(SPIRV_REMAPPER_DLIB NAMES SPVRemapperd
 273                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 274     find_library(SPIRV_TOOLS_DLIB NAMES SPIRV-Toolsd
 275                  HINTS ${SPIRV_TOOLS_DEBUG_SEARCH_PATH} )
 276     find_library(SPIRV_TOOLS_OPT_DLIB NAMES SPIRV-Tools-optd
 277                  HINTS ${SPIRV_TOOLS_OPT_DEBUG_SEARCH_PATH} )
 278
 279     set_target_properties(glslang PROPERTIES
 280                          IMPORTED_LOCATION       "${GLSLANG_LIB}"
 281                          IMPORTED_LOCATION_DEBUG "${GLSLANG_DLIB}")
 282     set_target_properties(OGLCompiler PROPERTIES
 283                          IMPORTED_LOCATION       "${OGLCompiler_LIB}"
 284                          IMPORTED_LOCATION_DEBUG "${OGLCompiler_DLIB}")
 285     set_target_properties(OSDependent PROPERTIES
 286                          IMPORTED_LOCATION       "${OSDependent_LIB}"
 287                          IMPORTED_LOCATION_DEBUG "${OSDependent_DLIB}")
 288     set_target_properties(HLSL PROPERTIES
 289                          IMPORTED_LOCATION       "${HLSL_LIB}"
 290                          IMPORTED_LOCATION_DEBUG "${HLSL_DLIB}")
 291     set_target_properties(SPIRV PROPERTIES
 292                          IMPORTED_LOCATION       "${SPIRV_LIB}"
 293                          IMPORTED_LOCATION_DEBUG "${SPIRV_DLIB}")
 294     set_target_properties(SPVRemapper PROPERTIES
 295                          IMPORTED_LOCATION       "${SPIRV_REMAPPER_LIB}"
 296                          IMPORTED_LOCATION_DEBUG "${SPIRV_REMAPPER_DLIB}")
 297     set_target_properties(SPIRV-Tools PROPERTIES
 298                          IMPORTED_LOCATION       "${SPIRV_TOOLS_LIB}"
 299                          IMPORTED_LOCATION_DEBUG "${SPIRV_TOOLS_DLIB}")
 300     set_target_properties(SPIRV-Tools-opt PROPERTIES
 301                          IMPORTED_LOCATION       "${SPIRV_TOOLS_OPT_LIB}"
 302                          IMPORTED_LOCATION_DEBUG "${SPIRV_TOOLS_OPT_DLIB}")
 303
 304     set (SPIRV_TOOLS_LIBRARIES SPIRV-Tools-opt SPIRV-Tools)
 305     set (GLSLANG_LIBRARIES glslang OGLCompiler OSDependent HLSL SPIRV SPVRemapper ${SPIRV_TOOLS_LIBRARIES})
 306 else ()
 307     # not WIN32
 308     set (SPIRV_TOOLS_LIBRARIES ${SPIRV_TOOLS_OPT_LIB} ${SPIRV_TOOLS_LIB})
 309     set (GLSLANG_LIBRARIES ${GLSLANG_LIB} ${OGLCompiler_LIB} ${OSDependent_LIB} ${HLSL_LIB} ${SPIRV_LIB} ${SPIRV_REMAPPER_LIB} ${SPIRV_TOOLS_LIBRARIES})
 310 endif()
 311
 312 set (PYTHON_CMD ${PYTHON_EXECUTABLE})
 313
 314 # Define macro used for building vkxml generated files
 315 macro(run_vk_xml_generate dependency output)
 316     add_custom_command(OUTPUT ${output}
 317     COMMAND ${PYTHON_CMD} ${SCRIPTS_DIR}/lvl_genvk.py -registry ${SCRIPTS_DIR}/vk.xml ${output}
 318     DEPENDS ${SCRIPTS_DIR}/vk.xml ${SCRIPTS_DIR}/generator.py ${SCRIPTS_DIR}/${dependency} ${SCRIPTS_DIR}/lvl_genvk.py ${SCRIPTS_DIR}/reg.py
 319     )
 320 endmacro()
 321
 322 # Define macro used for generating header files containing commit IDs for external dependencies
 323 macro(run_external_revision_generate source_dir symbol_name output)
 324     add_custom_command(OUTPUT ${output}
 325     # NOTE: If you modify this call to use --rev_file instead of --git_dir (to read the commit ID from a file instead of
 326     # parsing from a Git repository), you probably also want to add the revision file to the list of DEPENDS on the
 327     # subsequent line (to ensure that the script is re-run when the revision file is modified).
 328     COMMAND ${PYTHON_CMD} ${SCRIPTS_DIR}/external_revision_generator.py --git_dir ${source_dir} -s ${symbol_name} -o ${output}
 329     DEPENDS ${SCRIPTS_DIR}/external_revision_generator.py ${source_dir}/.git/HEAD ${source_dir}/.git/index
 330     )
 331 endmacro()
 332
 333 # Custom target for generated vulkan helper file dependencies
 334 add_custom_target(generate_helper_files DEPENDS
 335     vk_enum_string_helper.h
 336     vk_struct_size_helper.h
 337     vk_struct_size_helper.c
 338     vk_safe_struct.h
 339     vk_safe_struct.cpp
 340     vk_object_types.h
 341     vk_layer_dispatch_table.h
 342     vk_dispatch_table_helper.h
 343     vk_extension_helper.h
 344     vk_typemap_helper.h
 345     spirv_tools_commit_id.h
 346     )
 347 set_target_properties(generate_helper_files PROPERTIES FOLDER ${LVL_TARGET_FOLDER})
 348
 349 # Rules to build generated helper files
 350 run_vk_xml_generate(loader_extension_generator.py vk_layer_dispatch_table.h)
 351 run_vk_xml_generate(dispatch_table_helper_generator.py vk_dispatch_table_helper.h)
 352 run_vk_xml_generate(helper_file_generator.py vk_safe_struct.h)
 353 run_vk_xml_generate(helper_file_generator.py vk_safe_struct.cpp)
 354 run_vk_xml_generate(helper_file_generator.py vk_struct_size_helper.h)
 355 run_vk_xml_generate(helper_file_generator.py vk_struct_size_helper.c)
 356 run_vk_xml_generate(helper_file_generator.py vk_enum_string_helper.h)
 357 run_vk_xml_generate(helper_file_generator.py vk_object_types.h)
 358 run_vk_xml_generate(helper_file_generator.py vk_extension_helper.h)
 359 run_vk_xml_generate(helper_file_generator.py vk_typemap_helper.h)
 360 run_external_revision_generate(${EXTERNAL_SOURCE_ROOT}/glslang/External/spirv-tools SPIRV_TOOLS_COMMIT_ID spirv_tools_commit_id.h)
 361
 362
 363
 364 if(NOT WIN32)
 365     include(GNUInstallDirs)
 366
 367     add_definitions(-DFALLBACK_CONFIG_DIRS="${FALLBACK_CONFIG_DIRS}")
 368     add_definitions(-DFALLBACK_DATA_DIRS="${FALLBACK_DATA_DIRS}")
 369     add_definitions(-DSYSCONFDIR="${CMAKE_INSTALL_FULL_SYSCONFDIR}")
 370
 371     # Make sure /etc is searched by the loader
 372     if(NOT (CMAKE_INSTALL_FULL_SYSCONFDIR STREQUAL "/etc"))
 373         add_definitions(-DEXTRASYSCONFDIR="/etc")
 374     endif()
 375 endif()
 376
 377 if(UNIX)
 378     if(INSTALL_LVL_FILES)
 379         install(DIRECTORY "${PROJECT_SOURCE_DIR}/include/vulkan" DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 380         install(FILES "${CMAKE_CURRENT_BINARY_DIR}/vk_layer_dispatch_table.h" DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/vulkan")
 381     endif()
 382
 383 # uninstall target
 384 configure_file(
 385     "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 386     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 387     IMMEDIATE @ONLY)
 388
 389 add_custom_target(uninstall
 390     COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)
 391 endif()
 392
 393 # Layer Utils Library
 394 # For Windows, we use a static lib because the Windows loader has a fairly restrictive loader search
 395 # path that can't be easily modified to point it to the same directory that contains the layers.
 396 set(VKLAYER_UTILS_VLF_SOURCES
 397     layers/vk_layer_config.cpp
 398     layers/vk_layer_extension_utils.cpp
 399     layers/vk_layer_utils.cpp
 400     layers/vk_format_utils.cpp
 401     )
 402 if (WIN32)
 403     add_library(VkLayer_utils STATIC ${VKLAYER_UTILS_VLF_SOURCES})
 404     target_compile_definitions(VkLayer_utils PUBLIC _CRT_SECURE_NO_WARNINGS)
 405 else()
 406     add_library(VkLayer_utils SHARED ${VKLAYER_UTILS_VLF_SOURCES})
 407     if(INSTALL_LVL_FILES)
 408         install(TARGETS VkLayer_utils DESTINATION ${CMAKE_INSTALL_LIBDIR})
 409     endif()
 410 endif()
 411 add_dependencies(VkLayer_utils generate_helper_files)
 412 target_include_directories(
 413     VkLayer_utils PUBLIC
 414     ${CMAKE_CURRENT_SOURCE_DIR}/loader
 415     ${CMAKE_CURRENT_SOURCE_DIR}/include/vulkan
 416     ${CMAKE_CURRENT_BINARY_DIR}
 417     )
 418
 419 add_definitions(-DAPI_NAME="${API_NAME}")
 420
 421 # loader: Generic VULKAN ICD loader
 422 # tests: VULKAN tests
 423 if(BUILD_LOADER)
 424     add_subdirectory(loader)
 425 endif()
 426
 427 if(BUILD_TESTS)
 428     add_subdirectory(tests)
 429 endif()
 430
 431 if(BUILD_LAYERS)
 432     add_subdirectory(layers)
 433 endif()
 434
 435 if(BUILD_DEMOS)
 436     add_subdirectory(demos)
 437 endif()
 438
 439 if(BUILD_VKJSON)
 440     add_subdirectory(libs/vkjson)
 441 endif()
 442
 443 if(BUILD_ICD)
 444     add_subdirectory(icd)
 445 endif()