CMakeLists.txt

   1 # The name of our project is "VULKAN". CMakeLists files in this project can
   2 # refer to the root source directory of the project as ${VULKAN_SOURCE_DIR} and
   3 # to the root binary directory of the project as ${VULKAN_BINARY_DIR}.
   4 cmake_minimum_required(VERSION 2.8.11)
   5 project (VULKAN)
   6 # set (CMAKE_VERBOSE_MAKEFILE 1)
   7
   8 # The API_NAME allows renaming builds to avoid conflicts with installed SDKs
   9 # The MAJOR number of the version we're building, used in naming
  10 # <api-name>-<major>.dll (and other files).
  11 set(API_NAME "Vulkan" CACHE STRING "API name to use when building")
  12 set(MAJOR "1")
  13 string(TOLOWER ${API_NAME} API_LOWERCASE)
  14
  15 set(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
  16 find_package(PythonInterp 3 REQUIRED)
  17
  18 if(CMAKE_SYSTEM_NAME STREQUAL "Linux")
  19     set(FALLBACK_CONFIG_DIRS "/etc/xdg" CACHE STRING
  20         "Search path to use when XDG_CONFIG_DIRS is unset or empty or the current process is SUID/SGID. Default is freedesktop compliant.")
  21     set(FALLBACK_DATA_DIRS "/usr/local/share:/usr/share" CACHE STRING
  22         "Search path to use when XDG_DATA_DIRS is unset or empty or the current process is SUID/SGID. Default is freedesktop compliant.")
  23
  24     include(FindPkgConfig)
  25     option(BUILD_WSI_XCB_SUPPORT "Build XCB WSI support" ON)
  26     option(BUILD_WSI_XLIB_SUPPORT "Build Xlib WSI support" ON)
  27     option(BUILD_WSI_WAYLAND_SUPPORT "Build Wayland WSI support" ON)
  28     option(BUILD_WSI_MIR_SUPPORT "Build Mir WSI support" OFF)
  29     set(DEMOS_WSI_SELECTION "XCB" CACHE STRING "Select WSI target for demos (XCB, XLIB, WAYLAND, MIR, DISPLAY)")
  30
  31     if (BUILD_WSI_XCB_SUPPORT)
  32         find_package(XCB REQUIRED)
  33     endif()
  34
  35     if (BUILD_WSI_XLIB_SUPPORT)
  36         find_package(X11 REQUIRED)
  37     endif()
  38
  39     if (BUILD_WSI_WAYLAND_SUPPORT)
  40         find_package(Wayland REQUIRED)
  41         include_directories(${WAYLAND_CLIENT_INCLUDE_DIR})
  42     endif()
  43
  44     if (BUILD_WSI_MIR_SUPPORT)
  45         find_package(Mir REQUIRED)
  46     endif()
  47
  48     # This option can be used to suppress the installation of artifacts from the
  49     # Vulkan-LoaderAndValidationLayers repo while running "make install" for the
  50     # VulkanTools and VulkanSamples repos.  This can be used to prevent the
  51     # overwriting of LVL artifacts when installing these downstream repos.
  52     option(INSTALL_LVL_FILES "Install content from LoaderAndValidationLayers repo" ON)
  53 endif()
  54
  55 set(SCRIPTS_DIR "${CMAKE_CURRENT_SOURCE_DIR}/scripts")
  56
  57 # Header file for CMake settings
  58 include_directories("${PROJECT_SOURCE_DIR}/include")
  59
  60 if (CMAKE_COMPILER_IS_GNUCC OR CMAKE_C_COMPILER_ID MATCHES "Clang")
  61     set(COMMON_COMPILE_FLAGS "-Wall -Wextra -Wno-unused-parameter -Wno-missing-field-initializers")
  62     set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -fno-strict-aliasing -fno-builtin-memcmp")
  63
  64     # For GCC version 7.1 or greater, we need to disable the implicit fallthrough warning since
  65     # there's no consistent way to satisfy all compilers until they all accept the C++17 standard
  66     if (CMAKE_COMPILER_IS_GNUCC AND NOT (CMAKE_CXX_COMPILER_VERSION LESS 7.1))
  67         set(COMMON_COMPILE_FLAGS "${COMMON_COMPILE_FLAGS} -Wimplicit-fallthrough=0")
  68     endif()
  69
  70     set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -std=c99 ${COMMON_COMPILE_FLAGS}")
  71     set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${COMMON_COMPILE_FLAGS} -std=c++11 -fno-rtti")
  72     if (UNIX)
  73         set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fvisibility=hidden")
  74         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -fvisibility=hidden")
  75     endif()
  76 endif()
  77
  78 if(WIN32)
  79     # Treat warnings as errors
  80     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/WX>")
  81     # Disable RTTI
  82     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/GR->")
  83     # Warn about nested declarations
  84     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34456>")
  85     # Warn about potentially uninitialized variables
  86     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34701>")
  87     add_compile_options("$<$<CXX_COMPILER_ID:MSVC>:/w34703>")
  88 endif()
  89
  90 if(NOT WIN32)
  91     set (BUILDTGT_DIR build)
  92     set (BINDATA_DIR Bin)
  93     set (LIBSOURCE_DIR Lib)
  94 else()
  95     # is WIN32
  96     option(DISABLE_BUILD_PATH_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with MSVC build type info" OFF)
  97     option(DISABLE_BUILDTGT_DIR_DECORATION "Disable the decoration of the gslang and SPIRV-Tools build path with target info" OFF)
  98
  99     # For Windows, since 32-bit and 64-bit items can co-exist, we build each in its own build directory.
 100     # 32-bit target data goes in build32, and 64-bit target data goes into build.  So, include/link the
 101     # appropriate data at build time.
 102     if (DISABLE_BUILDTGT_DIR_DECORATION)
 103         set (BUILDTGT_DIR "")
 104         set (BINDATA_DIR "")
 105         set (LIBSOURCE_DIR "")
 106     elseif (CMAKE_CL_64)
 107         set (BUILDTGT_DIR build)
 108         set (BINDATA_DIR Bin)
 109         set (LIBSOURCE_DIR Lib)
 110     else()
 111         set (BUILDTGT_DIR build32)
 112         set (BINDATA_DIR Bin32)
 113         set (LIBSOURCE_DIR Lib32)
 114     endif()
 115 endif()
 116
 117 option(BUILD_LOADER "Build loader" ON)
 118 option(BUILD_TESTS "Build tests" ON)
 119 option(BUILD_LAYERS "Build layers" ON)
 120 option(BUILD_DEMOS "Build demos" ON)
 121 option(BUILD_VKJSON "Build vkjson" ON)
 122 option(BUILD_ICD "Build icd" ON)
 123 option(CUSTOM_GLSLANG_BIN_ROOT "Use the user defined GLSLANG_BINARY_ROOT" OFF)
 124 option(CUSTOM_SPIRV_TOOLS_BIN_ROOT "Use the user defined SPIRV_TOOLS*BINARY_ROOT paths" OFF)
 125
 126 #Choose natural default paths for glslang and SPIRV-Tools binaries to support custom definition by the user on the CMake command line or in the GUI
 127 set(GLSLANG_BINARY_ROOT "${CMAKE_BINARY_DIR}/../glslang" CACHE STRING "User defined path to the glslang binaries for this project")
 128 set(SPIRV_TOOLS_BINARY_ROOT "${CMAKE_BINARY_DIR}/../SPIRV-Tools" CACHE STRING "User defined path to the SPIRV-Tools binaries for this project")
 129 set(SPIRV_TOOLS_OPT_BINARY_ROOT "${CMAKE_BINARY_DIR}/../SPIRV-Tools/opt" CACHE STRING "User defined path to the SPIRV-Tools-opt binaries for this project")
 130
 131 # Define a variable for a default root location to the gslang, SPIRV-Tools and other external sources and cache it to allow the user to customize it as needed
 132 set(EXTERNAL_SOURCE_ROOT "${CMAKE_SOURCE_DIR}/external" CACHE STRING "Root path to external sources such as glslang and SPIRV-Tools")
 133
 134
 135 if (WIN32)
 136     if(CUSTOM_GLSLANG_BIN_ROOT)
 137         set(GSLANG_FINAL_BINARY_PATH ${GLSLANG_BINARY_ROOT}/${BUILDTGT_DIR})
 138     else()
 139         set(GSLANG_FINAL_BINARY_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}")
 140     endif()
 141
 142     if(DISABLE_BUILD_PATH_DECORATION)
 143         set (DEBUG_DECORATION "")
 144         set (RELEASE_DECORATION "")
 145     else()
 146         set (DEBUG_DECORATION "Debug")
 147         set (RELEASE_DECORATION "Release")
 148     endif()
 149
 150     # Take some steps to set up a variable pointing to the final glslang binaries given the variety of input options
 151     set (GLSLANG_SEARCH_PATH "${GSLANG_FINAL_BINARY_PATH}/glslang/${RELEASE_DECORATION}"
 152                              "${GSLANG_FINAL_BINARY_PATH}/glslang/OSDependent/Windows/${RELEASE_DECORATION}"
 153                              "${GSLANG_FINAL_BINARY_PATH}/hlsl/${RELEASE_DECORATION}"
 154                              "${GSLANG_FINAL_BINARY_PATH}/OGLCompilersDLL/${RELEASE_DECORATION}"
 155                              "${GSLANG_FINAL_BINARY_PATH}/SPIRV/${RELEASE_DECORATION}" )
 156
 157     set (GLSLANG_DEBUG_SEARCH_PATH "${GSLANG_FINAL_BINARY_PATH}/glslang/${DEBUG_DECORATION}"
 158                                    "${GSLANG_FINAL_BINARY_PATH}/glslang/OSDependent/Windows/${DEBUG_DECORATION}"
 159                                    "${GSLANG_FINAL_BINARY_PATH}/hlsl/${DEBUG_DECORATION}"
 160                                    "${GSLANG_FINAL_BINARY_PATH}/OGLCompilersDLL/${DEBUG_DECORATION}"
 161                                    "${GSLANG_FINAL_BINARY_PATH}/SPIRV/${DEBUG_DECORATION}")
 162
 163     if(CUSTOM_SPIRV_TOOLS_BIN_ROOT)
 164         set (SPIRV_TOOLS_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/${BUILDTGT_DIR}/source/${RELEASE_DECORATION}")
 165         set (SPIRV_TOOLS_DEBUG_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/${BUILDTGT_DIR}/source/${DEBUG_DECORATION}")
 166         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${SPIRV_TOOLS_OPT_BINARY_ROOT}/${BUILDTGT_DIR}/source/opt/${RELEASE_DECORATION}")
 167         set (SPIRV_TOOLS_OPT_DEBUG_SEARCH_PATH "${SPIRV_TOOLS_OPT_BINARY_ROOT}/${BUILDTGT_DIR}/source/opt/${DEBUG_DECORATION}")
 168     else()
 169         set (SPIRV_TOOLS_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source/${RELEASE_DECORATION}")
 170         set (SPIRV_TOOLS_DEBUG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source/${DEBUG_DECORATION}")
 171         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source/opt/${RELEASE_DECORATION}")
 172         set (SPIRV_TOOLS_OPT_DEBUG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source/opt/${DEBUG_DECORATION}")
 173     endif()
 174 else()
 175     # not WIN32
 176     if(CUSTOM_GLSLANG_BIN_ROOT)
 177         set (GLSLANG_SEARCH_PATH "${GLSLANG_BINARY_ROOT}/install/lib"
 178                                  "${GLSLANG_BINARY_ROOT}/glslang"
 179                                  "${GLSLANG_BINARY_ROOT}/glslang/OSDependent/Unix"
 180                                  "${GLSLANG_BINARY_ROOT}/OGLCompilersDLL"
 181                                  "${GLSLANG_BINARY_ROOT}/SPIRV"
 182                                  "${GLSLANG_BINARY_ROOT}/hlsl"
 183                                  "${GLSLANG_BINARY_ROOT}/StandAlone")
 184     else()
 185         set (GLSLANG_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/glslang/${BUILDTGT_DIR}/install/lib" "${CMAKE_SOURCE_DIR}/../x86_64/lib/glslang" )
 186     endif()
 187
 188     if(CUSTOM_SPIRV_TOOLS_BIN_ROOT)
 189         set (SPIRV_TOOLS_SEARCH_PATH "${SPIRV_TOOLS_BINARY_ROOT}/source" )
 190         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${SPIRV_TOOLS_OPT_BINARY_ROOT}/source/opt" )
 191     else()
 192         set (SPIRV_TOOLS_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source" "${CMAKE_SOURCE_DIR}/../x86_64/lib/spirv-tools" )
 193         set (SPIRV_TOOLS_OPT_SEARCH_PATH "${EXTERNAL_SOURCE_ROOT}/spirv-tools/${BUILDTGT_DIR}/source/opt" "${CMAKE_SOURCE_DIR}/../x86_64/lib/spirv-tools" )
 194     endif()
 195 endif()
 196
 197 find_program(GLSLANG_VALIDATOR NAMES glslangValidator
 198              HINTS "${CMAKE_SOURCE_DIR}/external/glslang/${BUILDTGT_DIR}/install/bin"
 199                    "${GLSLANG_BINARY_ROOT}/StandAlone"
 200                    "${PROJECT_SOURCE_DIR}/external/${BINDATA_DIR}")
 201
 202 find_path(GLSLANG_SPIRV_INCLUDE_DIR SPIRV/spirv.hpp HINTS "${EXTERNAL_SOURCE_ROOT}/glslang"
 203                                                     "${CMAKE_SOURCE_DIR}/../glslang"
 204                                               DOC "Path to SPIRV/spirv.hpp")
 205
 206 find_path(SPIRV_TOOLS_INCLUDE_DIR spirv-tools/libspirv.h HINTS "${EXTERNAL_SOURCE_ROOT}/spirv-tools/include"
 207                                                    "${EXTERNAL_SOURCE_ROOT}/SPIRV-Tools/include"
 208                                                    "${CMAKE_SOURCE_DIR}/../spirv-tools/include"
 209                                                    "${CMAKE_SOURCE_DIR}/../SPIRV-Tools/include"
 210                                                    "${EXTERNAL_SOURCE_ROOT}/source/spirv-tools/external/include"
 211                                              DOC "Path to spirv-tools/libspirv.h")
 212
 213 find_library(GLSLANG_LIB NAMES glslang
 214              HINTS ${GLSLANG_SEARCH_PATH} )
 215
 216 find_library(OGLCompiler_LIB NAMES OGLCompiler
 217              HINTS ${GLSLANG_SEARCH_PATH} )
 218
 219 find_library(OSDependent_LIB NAMES OSDependent
 220              HINTS ${GLSLANG_SEARCH_PATH} )
 221
 222 find_library(HLSL_LIB NAMES HLSL
 223              HINTS ${GLSLANG_SEARCH_PATH} )
 224
 225 find_library(SPIRV_LIB NAMES SPIRV
 226              HINTS ${GLSLANG_SEARCH_PATH} )
 227
 228 find_library(SPIRV_REMAPPER_LIB NAMES SPVRemapper
 229              HINTS ${GLSLANG_SEARCH_PATH} )
 230
 231 find_library(SPIRV_TOOLS_LIB NAMES SPIRV-Tools
 232              HINTS ${SPIRV_TOOLS_SEARCH_PATH} )
 233
 234 find_library(SPIRV_TOOLS_OPT_LIB NAMES SPIRV-Tools-opt
 235              HINTS ${SPIRV_TOOLS_OPT_SEARCH_PATH} )
 236
 237 if (WIN32)
 238     add_library(glslang         STATIC IMPORTED)
 239     add_library(OGLCompiler     STATIC IMPORTED)
 240     add_library(OSDependent     STATIC IMPORTED)
 241     add_library(HLSL            STATIC IMPORTED)
 242     add_library(SPIRV           STATIC IMPORTED)
 243     add_library(SPVRemapper     STATIC IMPORTED)
 244     add_library(Loader          STATIC IMPORTED)
 245     add_library(SPIRV-Tools-opt STATIC IMPORTED)
 246     add_library(SPIRV-Tools     STATIC IMPORTED)
 247
 248     find_library(GLSLANG_DLIB NAMES glslangd
 249                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 250     find_library(OGLCompiler_DLIB NAMES OGLCompilerd
 251                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 252     find_library(OSDependent_DLIB NAMES OSDependentd
 253                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 254     find_library(HLSL_DLIB NAMES HLSLd
 255                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 256     find_library(SPIRV_DLIB NAMES SPIRVd
 257                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 258     find_library(SPIRV_REMAPPER_DLIB NAMES SPVRemapperd
 259                  HINTS ${GLSLANG_DEBUG_SEARCH_PATH} )
 260     find_library(SPIRV_TOOLS_DLIB NAMES SPIRV-Tools
 261                  HINTS ${SPIRV_TOOLS_DEBUG_SEARCH_PATH} )
 262     find_library(SPIRV_TOOLS_OPT_DLIB NAMES SPIRV-Tools-opt
 263                  HINTS ${SPIRV_TOOLS_OPT_DEBUG_SEARCH_PATH} )
 264
 265     set_target_properties(glslang PROPERTIES
 266                          IMPORTED_LOCATION       "${GLSLANG_LIB}"
 267                          IMPORTED_LOCATION_DEBUG "${GLSLANG_DLIB}")
 268     set_target_properties(OGLCompiler PROPERTIES
 269                          IMPORTED_LOCATION       "${OGLCompiler_LIB}"
 270                          IMPORTED_LOCATION_DEBUG "${OGLCompiler_DLIB}")
 271     set_target_properties(OSDependent PROPERTIES
 272                          IMPORTED_LOCATION       "${OSDependent_LIB}"
 273                          IMPORTED_LOCATION_DEBUG "${OSDependent_DLIB}")
 274     set_target_properties(HLSL PROPERTIES
 275                          IMPORTED_LOCATION       "${HLSL_LIB}"
 276                          IMPORTED_LOCATION_DEBUG "${HLSL_DLIB}")
 277     set_target_properties(SPIRV PROPERTIES
 278                          IMPORTED_LOCATION       "${SPIRV_LIB}"
 279                          IMPORTED_LOCATION_DEBUG "${SPIRV_DLIB}")
 280     set_target_properties(SPVRemapper PROPERTIES
 281                          IMPORTED_LOCATION       "${SPIRV_REMAPPER_LIB}"
 282                          IMPORTED_LOCATION_DEBUG "${SPIRV_REMAPPER_DLIB}")
 283     set_target_properties(SPIRV-Tools PROPERTIES
 284                          IMPORTED_LOCATION       "${SPIRV_TOOLS_LIB}"
 285                          IMPORTED_LOCATION_DEBUG "${SPIRV_TOOLS_DLIB}")
 286     set_target_properties(SPIRV-Tools-opt PROPERTIES
 287                          IMPORTED_LOCATION       "${SPIRV_TOOLS_OPT_LIB}"
 288                          IMPORTED_LOCATION_DEBUG "${SPIRV_TOOLS_OPT_DLIB}")
 289
 290     set (SPIRV_TOOLS_LIBRARIES SPIRV-Tools-opt SPIRV-Tools)
 291     set (GLSLANG_LIBRARIES glslang OGLCompiler OSDependent HLSL SPIRV SPVRemapper ${SPIRV_TOOLS_LIBRARIES})
 292 else ()
 293     # not WIN32
 294     set (SPIRV_TOOLS_LIBRARIES ${SPIRV_TOOLS_OPT_LIB} ${SPIRV_TOOLS_LIB})
 295     set (GLSLANG_LIBRARIES ${GLSLANG_LIB} ${OGLCompiler_LIB} ${OSDependent_LIB} ${HLSL_LIB} ${SPIRV_LIB} ${SPIRV_REMAPPER_LIB} ${SPIRV_TOOLS_LIBRARIES})
 296 endif()
 297
 298 set (PYTHON_CMD ${PYTHON_EXECUTABLE})
 299
 300 # Define macro used for building vkxml generated files
 301 macro(run_vk_xml_generate dependency output)
 302     add_custom_command(OUTPUT ${output}
 303     COMMAND ${PYTHON_CMD} ${SCRIPTS_DIR}/lvl_genvk.py -registry ${SCRIPTS_DIR}/vk.xml ${output}
 304     DEPENDS ${SCRIPTS_DIR}/vk.xml ${SCRIPTS_DIR}/generator.py ${SCRIPTS_DIR}/${dependency} ${SCRIPTS_DIR}/lvl_genvk.py ${SCRIPTS_DIR}/reg.py
 305     )
 306 endmacro()
 307
 308 # Custom target for generated vulkan helper file dependencies
 309 add_custom_target(generate_helper_files DEPENDS
 310     vk_enum_string_helper.h
 311     vk_struct_size_helper.h
 312     vk_struct_size_helper.c
 313     vk_safe_struct.h
 314     vk_safe_struct.cpp
 315     vk_object_types.h
 316     vk_layer_dispatch_table.h
 317     vk_dispatch_table_helper.h
 318     vk_extension_helper.h
 319     vk_typemap_helper.h
 320     )
 321
 322 # Rules to build generated helper files
 323 run_vk_xml_generate(loader_extension_generator.py vk_layer_dispatch_table.h)
 324 run_vk_xml_generate(dispatch_table_helper_generator.py vk_dispatch_table_helper.h)
 325 run_vk_xml_generate(helper_file_generator.py vk_safe_struct.h)
 326 run_vk_xml_generate(helper_file_generator.py vk_safe_struct.cpp)
 327 run_vk_xml_generate(helper_file_generator.py vk_struct_size_helper.h)
 328 run_vk_xml_generate(helper_file_generator.py vk_struct_size_helper.c)
 329 run_vk_xml_generate(helper_file_generator.py vk_enum_string_helper.h)
 330 run_vk_xml_generate(helper_file_generator.py vk_object_types.h)
 331 run_vk_xml_generate(helper_file_generator.py vk_extension_helper.h)
 332 run_vk_xml_generate(helper_file_generator.py vk_typemap_helper.h)
 333
 334 if(NOT WIN32)
 335     include(GNUInstallDirs)
 336
 337     add_definitions(-DFALLBACK_CONFIG_DIRS="${FALLBACK_CONFIG_DIRS}")
 338     add_definitions(-DFALLBACK_DATA_DIRS="${FALLBACK_DATA_DIRS}")
 339     add_definitions(-DSYSCONFDIR="${CMAKE_INSTALL_FULL_SYSCONFDIR}")
 340
 341     # Make sure /etc is searched by the loader
 342     if(NOT (CMAKE_INSTALL_FULL_SYSCONFDIR STREQUAL "/etc"))
 343         add_definitions(-DEXTRASYSCONFDIR="/etc")
 344     endif()
 345 endif()
 346
 347 if(UNIX)
 348     if(INSTALL_LVL_FILES)
 349         install(DIRECTORY "${PROJECT_SOURCE_DIR}/include/vulkan" DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 350         install(FILES "${CMAKE_CURRENT_BINARY_DIR}/vk_layer_dispatch_table.h" DESTINATION "${CMAKE_INSTALL_INCLUDEDIR}/vulkan")
 351     endif()
 352
 353 # uninstall target
 354 configure_file(
 355     "${CMAKE_CURRENT_SOURCE_DIR}/cmake/cmake_uninstall.cmake.in"
 356     "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 357     IMMEDIATE @ONLY)
 358
 359 add_custom_target(uninstall
 360     COMMAND ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake)
 361 endif()
 362
 363 add_definitions(-DAPI_NAME="${API_NAME}")
 364
 365 # loader: Generic VULKAN ICD loader
 366 # tests: VULKAN tests
 367 if(BUILD_LOADER)
 368     add_subdirectory(loader)
 369 endif()
 370
 371 if(BUILD_TESTS)
 372     add_subdirectory(tests)
 373 endif()
 374
 375 if(BUILD_LAYERS)
 376     add_subdirectory(layers)
 377 endif()
 378
 379 if(BUILD_DEMOS)
 380     add_subdirectory(demos)
 381 endif()
 382
 383 if(BUILD_VKJSON)
 384     add_subdirectory(libs/vkjson)
 385 endif()
 386
 387 if(BUILD_ICD)
 388     add_subdirectory(icd)
 389 endif()