CMakeLists.txt

   1 # dEQP cmake file
   2
   3 cmake_minimum_required(VERSION 2.8)
   4
   5 # dEQP Target.
   6 set(DEQP_TARGET "default" CACHE STRING "dEQP Target (default, android...)")
   7
   8 project(dEQP-Core-${DEQP_TARGET})
   9
  10 include(framework/delibs/cmake/Defs.cmake NO_POLICY_SCOPE)
  11 include(framework/delibs/cmake/CFlags.cmake)
  12
  13 add_definitions(-DDE_ASSERT_FAILURE_CALLBACK)
  14
  15 # dEQP-specific configuration. Target file should override these.
  16 set(DEQP_TARGET_NAME            "UNKNOWN")              # Target name
  17
  18 set(DEQP_GLES2_LIBRARIES        )                               # GLESv2 libraries. If empty, run-time linking is used
  19 set(DEQP_GLES3_LIBRARIES        )                               # GLESv3 libraries. If empty, run-time linking is used
  20 set(DEQP_EGL_LIBRARIES          )                               # EGL libraries
  21
  22 # Legacy APIs that don't use run-time loading
  23 set(DEQP_SUPPORT_GLES1          OFF)                    # Is GLESv1 supported
  24 set(DEQP_GLES1_LIBRARIES        )                               # GLESv1 libraries
  25 set(DEQP_SUPPORT_VG                     OFF)                    # Is OpenVG supported
  26 set(DEQP_VG_LIBRARIES           )                               # VG libraries
  27
  28 set(DEQP_SUPPORT_WGL            OFF)
  29 set(DEQP_SUPPORT_GLX            OFF)                    # Is GLX supported \todo [2016-10-12 pyry] X11 specific - move to framework/platform/
  30
  31 set(DEQP_PLATFORM_LIBRARIES     )                               # Other platform libraries
  32
  33 set(DEQP_PLATFORM_COPY_LIBRARIES        )               # Libraries / binaries that need to be copied to binary directory
  34
  35 # Delibs include directories
  36 include_directories(
  37         framework/delibs/debase
  38         framework/delibs/decpp
  39         framework/delibs/depool
  40         framework/delibs/dethread
  41         framework/delibs/deutil
  42         framework/delibs/destream
  43         )
  44
  45 # Include target-specific definitions
  46 include(targets/${DEQP_TARGET}/${DEQP_TARGET}.cmake)
  47
  48 # zlib
  49 find_path(ZLIB_INCLUDE_PATH     zlib.h)
  50 find_library(ZLIB_LIBRARY       z)
  51
  52 if (NOT ZLIB_INCLUDE_PATH OR NOT ZLIB_LIBRARY)
  53         message(STATUS "System version of zlib not found, using external/zlib")
  54         add_subdirectory(external/zlib)
  55         # \note ZLIB_LIBRARY and ZLIB_INCLUDE_PATH are promoted from external/zlib/CMakeLists.txt
  56 endif ()
  57
  58 include_directories(${ZLIB_INCLUDE_PATH})
  59
  60 # libpng
  61 find_path(PNG_INCLUDE_PATH      png.h)
  62 find_library(PNG_LIBRARY        png)
  63
  64 if (NOT PNG_INCLUDE_PATH OR NOT PNG_LIBRARY)
  65         message(STATUS "System version of libpng not found, using external/libpng")
  66         add_subdirectory(external/libpng)
  67         # \note PNG_LIBRARY and PNG_INCLUDE_PATH are promoted from external/libpng/CMakeLists.txt
  68 endif ()
  69
  70 # glslang
  71 add_subdirectory(external/glslang)
  72
  73 # spirv-tools
  74 add_subdirectory(external/spirv-tools)
  75
  76 include_directories(${PNG_INCLUDE_PATH})
  77
  78 message(STATUS "DEQP_TARGET_NAME        = ${DEQP_TARGET_NAME}")
  79 message(STATUS "DEQP_SUPPORT_GLES1      = ${DEQP_SUPPORT_GLES1}")
  80 message(STATUS "DEQP_GLES1_LIBRARIES    = ${DEQP_GLES1_LIBRARIES}")
  81 message(STATUS "DEQP_GLES2_LIBRARIES    = ${DEQP_GLES2_LIBRARIES}")
  82 message(STATUS "DEQP_GLES3_LIBRARIES    = ${DEQP_GLES3_LIBRARIES}")
  83 message(STATUS "DEQP_GLES31_LIBRARIES   = ${DEQP_GLES31_LIBRARIES}")
  84 message(STATUS "DEQP_GLES32_LIBRARIES   = ${DEQP_GLES32_LIBRARIES}")
  85 message(STATUS "DEQP_SUPPORT_VG         = ${DEQP_SUPPORT_VG}")
  86 message(STATUS "DEQP_VG_LIBRARIES       = ${DEQP_VG_LIBRARIES}")
  87 message(STATUS "DEQP_EGL_LIBRARIES      = ${DEQP_EGL_LIBRARIES}")
  88 message(STATUS "DEQP_PLATFORM_LIBRARIES = ${DEQP_PLATFORM_LIBRARIES}")
  89
  90 # Defines
  91 add_definitions(-DDEQP_TARGET_NAME="${DEQP_TARGET_NAME}")
  92
  93 # Entry points loaded directly by linking to libGL*?
  94 if (DEFINED DEQP_GLES2_LIBRARIES)
  95         add_definitions(-DDEQP_GLES2_DIRECT_LINK=1)
  96 endif ()
  97
  98 if (DEFINED DEQP_GLES3_LIBRARIES)
  99         add_definitions(-DDEQP_GLES3_DIRECT_LINK=1)
 100 endif ()
 101
 102 if (DEFINED DEQP_GLES31_LIBRARIES)
 103         add_definitions(-DDEQP_GLES31_DIRECT_LINK=1)
 104 endif ()
 105
 106 if (DEFINED DEQP_GLES32_LIBRARIES)
 107         add_definitions(-DDEQP_GLES32_DIRECT_LINK=1)
 108 endif ()
 109
 110 if (DEFINED DEQP_EGL_LIBRARIES)
 111         add_definitions(-DDEQP_EGL_DIRECT_LINK=1)
 112 endif ()
 113
 114 # Legacy APIs that don't support run-time loading
 115 if (DEQP_SUPPORT_GLES1)
 116         add_definitions(-DDEQP_SUPPORT_GLES1=1)
 117
 118         if (NOT DEFINED DEQP_GLES1_LIBRARIES)
 119                 message(FATAL_ERROR "Run-time loading of GLES1 is not supported (DEQP_GLES1_LIBRARIES is not set)")
 120         endif ()
 121 endif ()
 122
 123 if (DEQP_SUPPORT_VG)
 124         add_definitions(-DDEQP_SUPPORT_VG=1)
 125
 126         if (NOT DEFINED DEQP_VG_LIBRARIES)
 127                 message(FATAL_ERROR "Run-time loading of VG is not supported (DEQP_VG_LIBRARIES is not set)")
 128         endif ()
 129 endif ()
 130
 131 if (DE_COMPILER_IS_MSC)
 132         # Don't nag about std::copy for example
 133         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -D_SCL_SECURE_NO_WARNINGS")
 134 endif ()
 135
 136 # delibs projects
 137 add_subdirectory(framework/delibs/debase)
 138 add_subdirectory(framework/delibs/depool)
 139 add_subdirectory(framework/delibs/dethread)
 140 add_subdirectory(framework/delibs/destream)
 141 add_subdirectory(framework/delibs/deutil)
 142 add_subdirectory(framework/delibs/decpp)
 143
 144 # ExecServer
 145 add_subdirectory(execserver)
 146
 147 # Executor framework and tools
 148 if (IS_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/executor)
 149         add_subdirectory(executor)
 150 endif ()
 151
 152 # Test framework include directories
 153 include_directories(
 154         framework/common
 155         framework/qphelper
 156         framework/opengl
 157         framework/opengl/wrapper
 158         framework/referencerenderer
 159         framework/opengl/simplereference
 160         framework/randomshaders
 161         framework/egl
 162         framework/egl/wrapper
 163         external/vulkancts/framework/vulkan
 164         )
 165
 166 if (DE_OS_IS_ANDROID OR DE_OS_IS_IOS)
 167         # On Android deqp modules are compiled as libraries and linked into final .so
 168         set(DEQP_MODULE_LIBRARIES )
 169         set(DEQP_MODULE_ENTRY_POINTS )
 170 endif ()
 171
 172 # Macro for adding targets for copying binaries (usually target libraries) to the target destination dir
 173 macro (target_copy_files target dep_name files)
 174         if (NOT "${files}" STREQUAL "")
 175                 set(COPY_TARGETS )
 176                 foreach (SRCNAME ${files})
 177                         get_filename_component(BASENAME ${SRCNAME} NAME)
 178                         set(DSTNAME "${CMAKE_CURRENT_BINARY_DIR}/${BASENAME}")
 179                         add_custom_command(OUTPUT ${DSTNAME}
 180                                                            COMMAND ${CMAKE_COMMAND} -E copy_if_different ${SRCNAME} ${DSTNAME})
 181                         set(COPY_TARGETS ${COPY_TARGETS} ${DSTNAME})
 182                 endforeach ()
 183
 184                 add_custom_target(${dep_name} ALL DEPENDS ${COPY_TARGETS})
 185                 add_dependencies(${target} ${dep_name})
 186         endif ()
 187 endmacro (target_copy_files)
 188
 189 set(MODULE_LIB_TARGET_POSTFIX   "-package")
 190 set(MODULE_DATA_TARGET_POSTFIX  "-data")
 191
 192 # Macro for adding dEQP module
 193 # This adds 3 targets:
 194 #       ${MODULE_NAME}-package:         Static library that contains all SRCS and links to LIBS
 195 #       ${MODULE_NAME}-data:            Custom target that is used for data file copies
 196 #       ${MODULE_NAME}:                         Executable binary (if supported by the platform)
 197 macro (add_deqp_module MODULE_NAME SRCS LIBS ENTRY)
 198
 199         # Library target
 200         add_library("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" STATIC ${SRCS})
 201         target_link_libraries("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" ${LIBS})
 202
 203         set(DEQP_MODULE_LIBRARIES               ${DEQP_MODULE_LIBRARIES} "${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}")
 204         set(DEQP_MODULE_ENTRY_POINTS    ${DEQP_MODULE_ENTRY_POINTS} "${CMAKE_CURRENT_SOURCE_DIR}/${ENTRY}")
 205
 206         # Forward to parent scope
 207         set(DEQP_MODULE_LIBRARIES               ${DEQP_MODULE_LIBRARIES} PARENT_SCOPE)
 208         set(DEQP_MODULE_ENTRY_POINTS    ${DEQP_MODULE_ENTRY_POINTS} PARENT_SCOPE)
 209
 210         if (NOT DE_OS_IS_ANDROID AND NOT DE_OS_IS_IOS)
 211                 # Executable target
 212                 add_executable(${MODULE_NAME} ${PROJECT_SOURCE_DIR}/framework/platform/tcuMain.cpp ${ENTRY})
 213                 target_link_libraries(${MODULE_NAME} tcutil-platform "${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}")
 214                 target_copy_files(${MODULE_NAME} platform-libs-${MODULE_NAME} "${DEQP_PLATFORM_COPY_LIBRARIES}")
 215         endif ()
 216
 217         # Data file target
 218         add_custom_target("${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}")
 219         add_dependencies("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}")
 220 endmacro (add_deqp_module)
 221
 222 # Macro for adding data dirs to module
 223 macro (add_data_dir MODULE_NAME SRC_DIR DST_DIR)
 224         if (DE_OS_IS_WIN32 OR DE_OS_IS_UNIX OR DE_OS_IS_OSX OR DE_OS_IS_QNX)
 225                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_CURRENT_BINARY_DIR}/${DST_DIR})
 226
 227         elseif (DE_OS_IS_ANDROID)
 228                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_BINARY_DIR}/assets/${DST_DIR})
 229
 230         elseif (DE_OS_IS_IOS)
 231                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_BINARY_DIR}/\${CONFIGURATION}\${EFFECTIVE_PLATFORM_NAME}/deqp.app/${DST_DIR})
 232         endif ()
 233 endmacro (add_data_dir)
 234
 235 # Macro for adding individual data files to module
 236 macro (add_data_file MODULE_NAME SRC_FILE DST_FILE)
 237         if (DE_OS_IS_WIN32 OR DE_OS_IS_UNIX OR DE_OS_IS_OSX OR DE_OS_IS_QNX)
 238                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_CURRENT_BINARY_DIR}/${DST_FILE})
 239
 240         elseif (DE_OS_IS_ANDROID)
 241                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_BINARY_DIR}/assets/${DST_FILE})
 242
 243         elseif (DE_OS_IS_IOS)
 244                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_BINARY_DIR}/\${CONFIGURATION}\${EFFECTIVE_PLATFORM_NAME}/deqp.app/${DST_FILE})
 245         endif ()
 246 endmacro (add_data_file)
 247
 248 add_subdirectory(framework)
 249 add_subdirectory(external/vulkancts/framework/vulkan)
 250
 251 if (DE_COMPILER_IS_MSC)
 252         add_compile_options(/bigobj) # Required by glsBuiltinPrecisionTests.cpp
 253 endif ()
 254
 255 add_subdirectory(modules)
 256 add_subdirectory(external/vulkancts/modules/vulkan)
 257 add_subdirectory(external/openglcts)
 258
 259 # Single-binary targets
 260 if (DE_OS_IS_ANDROID)
 261         include_directories(executor)
 262
 263         set(DEQP_SRCS
 264                 framework/platform/android/tcuAndroidMain.cpp
 265                 framework/platform/android/tcuAndroidJNI.cpp
 266                 framework/platform/android/tcuAndroidPlatformCapabilityQueryJNI.cpp
 267                 framework/platform/android/tcuTestLogParserJNI.cpp
 268                 ${DEQP_MODULE_ENTRY_POINTS}
 269                 )
 270
 271         set(DEQP_LIBS
 272                 tcutil-platform
 273                 xecore
 274                 ${DEQP_MODULE_LIBRARIES}
 275                 )
 276
 277         add_library(deqp SHARED ${DEQP_SRCS})
 278         target_link_libraries(deqp ${DEQP_LIBS})
 279
 280         # Needed by OpenGL CTS that defines its own activity but depends on
 281         # common Android support code.
 282         target_include_directories(deqp PRIVATE framework/platform/android)
 283
 284 elseif (DE_OS_IS_IOS)
 285         # Code sign identity
 286         set(DEQP_IOS_CODE_SIGN_IDENTITY "drawElements" CACHE STRING "Code sign identity for iOS build")
 287
 288         set(MACOSX_BUNDLE_PRODUCT_NAME "\${PRODUCT_NAME}")
 289         set(MACOSX_BUNDLE_GUI_IDENTIFIER "com.drawelements.\${PRODUCT_NAME:identifier}")
 290
 291         include_directories(framework/platform/ios)
 292         set(TESTERCORE_SRC_FILES
 293                 framework/platform/ios/tcuEAGLView.h
 294                 framework/platform/ios/tcuEAGLView.m
 295                 framework/platform/ios/tcuIOSAppDelegate.h
 296                 framework/platform/ios/tcuIOSAppDelegate.m
 297                 framework/platform/ios/tcuIOSViewController.h
 298                 framework/platform/ios/tcuIOSViewController.m
 299                 framework/platform/ios/tcuIOSMain.m
 300                 )
 301         set_source_files_properties(${TESTERCORE_SRC_FILES} COMPILE_FLAGS "-std=c99")
 302
 303         add_executable(deqp MACOSX_BUNDLE ${TESTERCORE_SRC_FILES} ${DEQP_MODULE_ENTRY_POINTS})
 304         target_link_libraries(deqp tcutil-platform xscore ${DEQP_MODULE_LIBRARIES})
 305         set_target_properties(deqp PROPERTIES XCODE_ATTRIBUTE_TARGETED_DEVICE_FAMILY "1,2")
 306         set_target_properties(deqp PROPERTIES XCODE_ATTRIBUTE_CODE_SIGN_IDENTITY "iPhone Developer: ${DEQP_IOS_CODE_SIGN_IDENTITY}")
 307 endif ()