CMakeLists.txt

   1 ##
   2 ## Author: Hank Anderson <hank@statease.com>
   3 ##
   4
   5 cmake_minimum_required(VERSION 2.8.5)
   6 project(OpenBLAS C ASM)
   7 set(OpenBLAS_MAJOR_VERSION 0)
   8 set(OpenBLAS_MINOR_VERSION 3)
   9 set(OpenBLAS_PATCH_VERSION 9.dev)
  10 set(OpenBLAS_VERSION "${OpenBLAS_MAJOR_VERSION}.${OpenBLAS_MINOR_VERSION}.${OpenBLAS_PATCH_VERSION}")
  11
  12 # Adhere to GNU filesystem layout conventions
  13 include(GNUInstallDirs)
  14
  15 include(CMakePackageConfigHelpers)
  16
  17
  18 #######
  19 if(MSVC)
  20 option(BUILD_WITHOUT_LAPACK "Do not build LAPACK and LAPACKE (Only BLAS or CBLAS)" ON)
  21 endif()
  22 option(BUILD_WITHOUT_CBLAS "Do not build the C interface (CBLAS) to the BLAS functions" OFF)
  23 option(DYNAMIC_ARCH "Include support for multiple CPU targets, with automatic selection at runtime (x86/x86_64, aarch64 or ppc only)" OFF)
  24 option(DYNAMIC_OLDER "Include specific support for older x86 cpu models (Penryn,Dunnington,Atom,Nano,Opteron) with DYNAMIC_ARCH" OFF)
  25 option(BUILD_RELAPACK "Build with ReLAPACK (recursive implementation of several LAPACK functions on top of standard LAPACK)" OFF)
  26 if(${CMAKE_SYSTEM_NAME} MATCHES "Linux")
  27 option(NO_AFFINITY "Disable support for CPU affinity masks to avoid binding processes from e.g. R or numpy/scipy to a single core" ON)
  28 else()
  29 set(NO_AFFINITY 1)
  30 endif()
  31
  32 # Add a prefix or suffix to all exported symbol names in the shared library.
  33 # Avoids conflicts with other BLAS libraries, especially when using
  34 # 64 bit integer interfaces in OpenBLAS.
  35
  36 set(SYMBOLPREFIX "" CACHE STRING  "Add a prefix to all exported symbol names in the shared library to avoid conflicts with other BLAS libraries" )
  37 set(SYMBOLSUFFIX "" CACHE STRING  "Add a suffix to all exported symbol names in the shared library, e.g. _64 for INTERFACE64 builds" )
  38 #######
  39 if(BUILD_WITHOUT_LAPACK)
  40 set(NO_LAPACK 1)
  41 set(NO_LAPACKE 1)
  42 endif()
  43
  44 if(BUILD_WITHOUT_CBLAS)
  45 set(NO_CBLAS 1)
  46 endif()
  47
  48 #######
  49
  50 if(MSVC AND MSVC_STATIC_CRT)
  51     set(CompilerFlags
  52             CMAKE_CXX_FLAGS
  53             CMAKE_CXX_FLAGS_DEBUG
  54             CMAKE_CXX_FLAGS_RELEASE
  55             CMAKE_C_FLAGS
  56             CMAKE_C_FLAGS_DEBUG
  57             CMAKE_C_FLAGS_RELEASE
  58             )
  59     foreach(CompilerFlag ${CompilerFlags})
  60       string(REPLACE "/MD" "/MT" ${CompilerFlag} "${${CompilerFlag}}")
  61     endforeach()
  62 endif()
  63
  64 message(WARNING "CMake support is experimental. It does not yet support all build options and may not produce the same Makefiles that OpenBLAS ships with.")
  65
  66 include("${PROJECT_SOURCE_DIR}/cmake/utils.cmake")
  67 include("${PROJECT_SOURCE_DIR}/cmake/system.cmake")
  68
  69 set(OpenBLAS_LIBNAME openblas${SUFFIX64_UNDERSCORE})
  70
  71 set(BLASDIRS interface driver/level2 driver/level3 driver/others)
  72
  73 if (NOT DYNAMIC_ARCH)
  74   list(APPEND BLASDIRS kernel)
  75 endif ()
  76
  77 if (DEFINED SANITY_CHECK)
  78   list(APPEND BLASDIRS reference)
  79 endif ()
  80
  81 set(SUBDIRS     ${BLASDIRS})
  82 if (NOT NO_LAPACK)
  83   if(BUILD_RELAPACK)
  84     list(APPEND SUBDIRS relapack/src)
  85   endif()
  86   list(APPEND SUBDIRS lapack)
  87 endif ()
  88
  89 # set which float types we want to build for
  90 if (NOT DEFINED BUILD_SINGLE AND NOT DEFINED BUILD_DOUBLE AND NOT DEFINED BUILD_COMPLEX AND NOT DEFINED BUILD_COMPLEX16)
  91   # if none are defined, build for all
  92   set(BUILD_HALF true)
  93   set(BUILD_SINGLE true)
  94   set(BUILD_DOUBLE true)
  95   set(BUILD_COMPLEX true)
  96   set(BUILD_COMPLEX16 true)
  97 endif ()
  98
  99 if (NOT DEFINED BUILD_MATGEN)
 100   set(BUILD_MATGEN true)
 101 endif()
 102
 103 set(FLOAT_TYPES "")
 104 if (BUILD_SINGLE)
 105   message(STATUS "Building Single Precision")
 106   list(APPEND FLOAT_TYPES "SINGLE") # defines nothing
 107 endif ()
 108
 109 if (BUILD_DOUBLE)
 110   message(STATUS "Building Double Precision")
 111   list(APPEND FLOAT_TYPES "DOUBLE") # defines DOUBLE
 112 endif ()
 113
 114 if (BUILD_COMPLEX)
 115   message(STATUS "Building Complex Precision")
 116   list(APPEND FLOAT_TYPES "COMPLEX") # defines COMPLEX
 117 endif ()
 118
 119 if (BUILD_COMPLEX16)
 120   message(STATUS "Building Double Complex Precision")
 121   list(APPEND FLOAT_TYPES "ZCOMPLEX") # defines COMPLEX and DOUBLE
 122 endif ()
 123
 124 if (BUILD_SINGLE OR BUILD_HALF)
 125   message(STATUS "Building Half Precision")
 126   list(APPEND FLOAT_TYPES "HALF") # defines nothing
 127 endif ()
 128
 129 if (NOT DEFINED CORE OR "${CORE}" STREQUAL "UNKNOWN")
 130   message(FATAL_ERROR "Detecting CPU failed. Please set TARGET explicitly, e.g. make TARGET=your_cpu_target. Please read README for details.")
 131 endif ()
 132
 133 #Set default output directory
 134 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
 135 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
 136 if(MSVC)
 137 set( CMAKE_LIBRARY_OUTPUT_DIRECTORY_DEBUG ${PROJECT_BINARY_DIR}/lib/Debug)
 138 set( CMAKE_ARCHIVE_OUTPUT_DIRECTORY_RELEASE ${PROJECT_BINARY_DIR}/lib/Release)
 139 endif ()
 140 # get obj vars into format that add_library likes: $<TARGET_OBJS:objlib> (see http://www.cmake.org/cmake/help/v3.0/command/add_library.html)
 141 set(TARGET_OBJS "")
 142 foreach (SUBDIR ${SUBDIRS})
 143   add_subdirectory(${SUBDIR})
 144   string(REPLACE "/" "_" subdir_obj ${SUBDIR})
 145   list(APPEND TARGET_OBJS "$<TARGET_OBJECTS:${subdir_obj}>")
 146 endforeach ()
 147
 148 # netlib:
 149
 150 # Can't just use lapack-netlib's CMake files, since they are set up to search for BLAS, build and install a binary. We just want to build a couple of lib files out of lapack and lapacke.
 151 # Not using add_subdirectory here because lapack-netlib already has its own CMakeLists.txt. Instead include a cmake script with the sources we want.
 152 if (NOT NOFORTRAN AND NOT NO_LAPACK)
 153   include("${PROJECT_SOURCE_DIR}/cmake/lapack.cmake")
 154   if (NOT NO_LAPACKE)
 155     include("${PROJECT_SOURCE_DIR}/cmake/lapacke.cmake")
 156   endif ()
 157 endif ()
 158
 159 # Only generate .def for dll on MSVC and always produce pdb files for debug and release
 160 if(MSVC)
 161   if (${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} VERSION_LESS 3.4)
 162     set(OpenBLAS_DEF_FILE "${PROJECT_BINARY_DIR}/openblas.def")
 163   endif()
 164   set(CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE} /Zi")
 165   set(CMAKE_SHARED_LINKER_FLAGS_RELEASE "${CMAKE_SHARED_LINKER_FLAGS_RELEASE} /DEBUG /OPT:REF /OPT:ICF")
 166 endif()
 167
 168 if (${DYNAMIC_ARCH})
 169   add_subdirectory(kernel)
 170   foreach(TARGET_CORE ${DYNAMIC_CORE})
 171     message("${TARGET_CORE}")
 172     list(APPEND TARGET_OBJS "$<TARGET_OBJECTS:kernel_${TARGET_CORE}>")
 173   endforeach()
 174 endif ()
 175
 176 # add objects to the openblas lib
 177 add_library(${OpenBLAS_LIBNAME} ${LA_SOURCES} ${LAPACKE_SOURCES} ${RELA_SOURCES} ${TARGET_OBJS} ${OpenBLAS_DEF_FILE})
 178 target_include_directories(${OpenBLAS_LIBNAME} INTERFACE $<INSTALL_INTERFACE:include/openblas${SUFFIX64}>)
 179
 180 # Android needs to explicitly link against libm
 181 if(ANDROID)
 182   target_link_libraries(${OpenBLAS_LIBNAME} m)
 183 endif()
 184
 185 # Handle MSVC exports
 186 if(MSVC AND BUILD_SHARED_LIBS)
 187   if (${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} VERSION_LESS 3.4)
 188     include("${PROJECT_SOURCE_DIR}/cmake/export.cmake")
 189   else()
 190     # Creates verbose .def file (51KB vs 18KB)
 191     set_target_properties(${OpenBLAS_LIBNAME} PROPERTIES WINDOWS_EXPORT_ALL_SYMBOLS true)
 192   endif()
 193 endif()
 194
 195 # Set output for libopenblas
 196 set_target_properties( ${OpenBLAS_LIBNAME} PROPERTIES RUNTIME_OUTPUT_DIRECTORY ${PROJECT_BINARY_DIR}/lib)
 197 set_target_properties( ${OpenBLAS_LIBNAME} PROPERTIES LIBRARY_OUTPUT_NAME_DEBUG "${OpenBLAS_LIBNAME}_d")
 198 set_target_properties( ${OpenBLAS_LIBNAME} PROPERTIES EXPORT_NAME "OpenBLAS")
 199
 200 foreach (OUTPUTCONFIG ${CMAKE_CONFIGURATION_TYPES})
 201   string( TOUPPER ${OUTPUTCONFIG} OUTPUTCONFIG )
 202
 203   set_target_properties( ${OpenBLAS_LIBNAME} PROPERTIES RUNTIME_OUTPUT_DIRECTORY_${OUTPUTCONFIG} ${PROJECT_BINARY_DIR}/lib/${OUTPUTCONFIG} )
 204   set_target_properties( ${OpenBLAS_LIBNAME} PROPERTIES LIBRARY_OUTPUT_DIRECTORY_${OUTPUTCONFIG} ${PROJECT_BINARY_DIR}/lib/${OUTPUTCONFIG} )
 205   set_target_properties( ${OpenBLAS_LIBNAME} PROPERTIES ARCHIVE_OUTPUT_DIRECTORY_${OUTPUTCONFIG} ${PROJECT_BINARY_DIR}/lib/${OUTPUTCONFIG} )
 206 endforeach()
 207
 208 enable_testing()
 209
 210 if (USE_THREAD)
 211   # Add threading library to linker
 212   find_package(Threads)
 213   if (THREADS_HAVE_PTHREAD_ARG)
 214     set_property(TARGET ${OpenBLAS_LIBNAME} PROPERTY COMPILE_OPTIONS "-pthread")
 215     set_property(TARGET ${OpenBLAS_LIBNAME} PROPERTY INTERFACE_COMPILE_OPTIONS "-pthread")
 216   endif()
 217   target_link_libraries(${OpenBLAS_LIBNAME} ${CMAKE_THREAD_LIBS_INIT})
 218 endif()
 219
 220 #if (MSVC OR NOT NOFORTRAN)
 221 if (NOT NO_CBLAS)
 222   # Broken without fortran on unix
 223   add_subdirectory(utest)
 224 endif()
 225
 226 if (NOT MSVC AND NOT NOFORTRAN)
 227   # Build test and ctest
 228   add_subdirectory(test)
 229   if(NOT NO_CBLAS)
 230     add_subdirectory(ctest)
 231   endif()
 232 endif()
 233
 234 set_target_properties(${OpenBLAS_LIBNAME} PROPERTIES
 235   VERSION ${OpenBLAS_MAJOR_VERSION}.${OpenBLAS_MINOR_VERSION}
 236   SOVERSION ${OpenBLAS_MAJOR_VERSION}
 237 )
 238
 239 if (BUILD_SHARED_LIBS AND BUILD_RELAPACK)
 240   if (NOT MSVC)
 241     target_link_libraries(${OpenBLAS_LIBNAME} "-Wl,-allow-multiple-definition")
 242   else()
 243     target_link_libraries(${OpenBLAS_LIBNAME} "/FORCE:MULTIPLE")
 244   endif()
 245 endif()
 246
 247 if (BUILD_SHARED_LIBS AND NOT ${SYMBOLPREFIX}${SYMBOLSUFIX} STREQUAL "")
 248 if (NOT DEFINED ARCH)
 249   set(ARCH_IN "x86_64")
 250 else()
 251   set(ARCH_IN ${ARCH})
 252 endif()
 253
 254 if (${CORE} STREQUAL "generic")
 255   set(ARCH_IN "GENERIC")
 256 endif ()
 257
 258 if (NOT DEFINED EXPRECISION)
 259   set(EXPRECISION_IN 0)
 260 else()
 261   set(EXPRECISION_IN ${EXPRECISION})
 262 endif()
 263
 264 if (NOT DEFINED NO_CBLAS)
 265   set(NO_CBLAS_IN 0)
 266 else()
 267   set(NO_CBLAS_IN ${NO_CBLAS})
 268 endif()
 269
 270 if (NOT DEFINED NO_LAPACK)
 271   set(NO_LAPACK_IN 0)
 272 else()
 273   set(NO_LAPACK_IN ${NO_LAPACK})
 274 endif()
 275
 276 if (NOT DEFINED NO_LAPACKE)
 277   set(NO_LAPACKE_IN 0)
 278 else()
 279   set(NO_LAPACKE_IN ${NO_LAPACKE})
 280 endif()
 281
 282 if (NOT DEFINED NEED2UNDERSCORES)
 283   set(NEED2UNDERSCORES_IN 0)
 284 else()
 285   set(NEED2UNDERSCORES_IN ${NEED2UNDERSCORES})
 286 endif()
 287
 288 if (NOT DEFINED ONLY_CBLAS)
 289   set(ONLY_CBLAS_IN 0)
 290 else()
 291   set(ONLY_CBLAS_IN ${ONLY_CBLAS})
 292 endif()
 293
 294 if (NOT DEFINED BU)
 295   set(BU _)
 296 endif()
 297
 298 if (NOT ${SYMBOLPREFIX} STREQUAL "")
 299 message(STATUS "adding prefix ${SYMBOLPREFIX} to names of exported symbols in ${OpenBLAS_LIBNAME}")
 300 endif()
 301 if (NOT ${SYMBOLSUFFIX} STREQUAL "")
 302 message(STATUS "adding suffix ${SYMBOLSUFFIX} to names of exported symbols in ${OpenBLAS_LIBNAME}")
 303 endif()
 304         add_custom_command(TARGET ${OpenBLAS_LIBNAME} POST_BUILD
 305         COMMAND perl  ${PROJECT_SOURCE_DIR}/exports/gensymbol "objcopy" "${ARCH}" "${BU}" "${EXPRECISION_IN}" "${NO_CBLAS_IN}" "${NO_LAPACK_IN}" "${NO_LAPACKE_IN}" "${NEED2UNDERSCORES_IN}" "${ONLY_CBLAS_IN}" \"${SYMBOLPREFIX}\" \"${SYMBOLSUFFIX}\" "${BUILD_LAPACK_DEPRECATED}" > ${PROJECT_BINARY_DIR}/objcopy.def
 306         COMMAND objcopy -v --redefine-syms ${PROJECT_BINARY_DIR}/objcopy.def  ${PROJECT_BINARY_DIR}/lib/lib${OpenBLAS_LIBNAME}.so
 307         COMMENT "renaming symbols"
 308         )
 309 endif()
 310
 311
 312 # Install project
 313
 314 # Install libraries
 315 install(TARGETS ${OpenBLAS_LIBNAME}
 316         EXPORT "OpenBLAS${SUFFIX64}Targets"
 317         RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 318         ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 319   LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR} )
 320
 321 # Install headers
 322 set(CMAKE_INSTALL_INCLUDEDIR ${CMAKE_INSTALL_INCLUDEDIR}/openblas${SUFFIX64})
 323 set(CMAKE_INSTALL_FULL_INCLUDEDIR ${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_INCLUDEDIR})
 324
 325 message(STATUS "Generating openblas_config.h in ${CMAKE_INSTALL_INCLUDEDIR}")
 326
 327 set(OPENBLAS_CONFIG_H ${CMAKE_BINARY_DIR}/openblas_config.h)
 328 file(WRITE  ${OPENBLAS_CONFIG_H} "#ifndef OPENBLAS_CONFIG_H\n")
 329 file(APPEND ${OPENBLAS_CONFIG_H} "#define OPENBLAS_CONFIG_H\n")
 330 file(STRINGS ${PROJECT_BINARY_DIR}/config.h __lines)
 331 foreach(line ${__lines})
 332   string(REPLACE "#define " "" line ${line})
 333   file(APPEND ${OPENBLAS_CONFIG_H} "#define OPENBLAS_${line}\n")
 334 endforeach()
 335 file(APPEND ${OPENBLAS_CONFIG_H} "#define OPENBLAS_VERSION \"OpenBLAS ${OpenBLAS_VERSION}\"\n")
 336 file(READ   ${CMAKE_CURRENT_SOURCE_DIR}/openblas_config_template.h OPENBLAS_CONFIG_TEMPLATE_H_CONTENTS)
 337 file(APPEND ${OPENBLAS_CONFIG_H} "${OPENBLAS_CONFIG_TEMPLATE_H_CONTENTS}\n")
 338 file(APPEND ${OPENBLAS_CONFIG_H} "#endif /* OPENBLAS_CONFIG_H */\n")
 339 install (FILES ${OPENBLAS_CONFIG_H} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 340
 341 if(NOT NOFORTRAN)
 342   message(STATUS "Generating f77blas.h in ${CMAKE_INSTALL_INCLUDEDIR}")
 343
 344   set(F77BLAS_H ${CMAKE_BINARY_DIR}/generated/f77blas.h)
 345   file(WRITE  ${F77BLAS_H} "#ifndef OPENBLAS_F77BLAS_H\n")
 346   file(APPEND ${F77BLAS_H} "#define OPENBLAS_F77BLAS_H\n")
 347   file(APPEND ${F77BLAS_H} "#include \"openblas_config.h\"\n")
 348   file(READ ${CMAKE_CURRENT_SOURCE_DIR}/common_interface.h COMMON_INTERFACE_H_CONTENTS)
 349   file(APPEND ${F77BLAS_H} "${COMMON_INTERFACE_H_CONTENTS}\n")
 350   file(APPEND ${F77BLAS_H} "#endif")
 351   install (FILES ${F77BLAS_H} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 352 endif()
 353
 354 if(NOT NO_CBLAS)
 355         message (STATUS "Generating cblas.h in ${CMAKE_INSTALL_INCLUDEDIR}")
 356
 357         set(CBLAS_H ${CMAKE_BINARY_DIR}/generated/cblas.h)
 358         file(READ ${CMAKE_CURRENT_SOURCE_DIR}/cblas.h CBLAS_H_CONTENTS)
 359         string(REPLACE "common" "openblas_config" CBLAS_H_CONTENTS_NEW "${CBLAS_H_CONTENTS}")
 360         file(WRITE ${CBLAS_H} "${CBLAS_H_CONTENTS_NEW}")
 361         install (FILES ${CBLAS_H} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 362 endif()
 363
 364 if(NOT NO_LAPACKE)
 365         message (STATUS "Copying LAPACKE header files to ${CMAKE_INSTALL_INCLUDEDIR}")
 366         add_dependencies( ${OpenBLAS_LIBNAME} genlapacke)
 367         FILE(GLOB_RECURSE INCLUDE_FILES "${CMAKE_CURRENT_SOURCE_DIR}/lapack-netlib/LAPACKE/*.h")
 368         install (FILES ${INCLUDE_FILES} DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
 369
 370         ADD_CUSTOM_TARGET(genlapacke
 371         COMMAND ${CMAKE_COMMAND} -E copy ${CMAKE_CURRENT_SOURCE_DIR}/lapack-netlib/LAPACKE/include/lapacke_mangling_with_flags.h.in "${CMAKE_BINARY_DIR}/lapacke_mangling.h"
 372         )
 373         install (FILES ${CMAKE_BINARY_DIR}/lapacke_mangling.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}/openblas${SUFFIX64})
 374 endif()
 375
 376 include(FindPkgConfig QUIET)
 377 if(PKG_CONFIG_FOUND)
 378         configure_file(${PROJECT_SOURCE_DIR}/cmake/openblas.pc.in ${PROJECT_BINARY_DIR}/openblas${SUFFIX64}.pc @ONLY)
 379         install (FILES ${PROJECT_BINARY_DIR}/openblas${SUFFIX64}.pc DESTINATION ${CMAKE_INSTALL_LIBDIR}/pkgconfig/)
 380 endif()
 381
 382
 383 # GNUInstallDirs "DATADIR" wrong here; CMake search path wants "share".
 384 set(PN OpenBLAS)
 385 set(CMAKECONFIG_INSTALL_DIR "share/cmake/${PN}${SUFFIX64}")
 386 configure_package_config_file(cmake/${PN}Config.cmake.in
 387                               "${CMAKE_CURRENT_BINARY_DIR}/${PN}${SUFFIX64}Config.cmake"
 388                               INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR})
 389 write_basic_package_version_file(${CMAKE_CURRENT_BINARY_DIR}/${PN}ConfigVersion.cmake
 390                                  VERSION ${${PN}_VERSION}
 391                                  COMPATIBILITY AnyNewerVersion)
 392 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${PN}${SUFFIX64}Config.cmake
 393         DESTINATION ${CMAKECONFIG_INSTALL_DIR})
 394 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${PN}ConfigVersion.cmake
 395         RENAME ${PN}${SUFFIX64}ConfigVersion.cmake
 396         DESTINATION ${CMAKECONFIG_INSTALL_DIR})
 397 install(EXPORT "${PN}${SUFFIX64}Targets"
 398         NAMESPACE "${PN}${SUFFIX64}::"
 399         DESTINATION ${CMAKECONFIG_INSTALL_DIR})
 400