CMakeLists.txt

   1 # Copyright (c) 2019-2021 Arm Limited.
   2 #
   3 # SPDX-License-Identifier: MIT
   4 #
   5 # Permission is hereby granted, free of charge, to any person obtaining a copy
   6 # of this software and associated documentation files (the "Software"), to
   7 # deal in the Software without restriction, including without limitation the
   8 # rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
   9 # sell copies of the Software, and to permit persons to whom the Software is
  10 # furnished to do so, subject to the following conditions:
  11 #
  12 # The above copyright notice and this permission notice shall be included in all
  13 # copies or substantial portions of the Software.
  14 #
  15 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  16 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  17 # FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  18 # AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  19 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
  20 # OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
  21 # SOFTWARE.
  22
  23 cmake_minimum_required(VERSION 3.4.3)
  24 project(VkLayer_window_system_integration)
  25
  26 find_package(PkgConfig REQUIRED)
  27 pkg_check_modules(VULKAN_PKG_CONFIG vulkan)
  28
  29 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -pthread -fPIC")
  30 if (DEFINED DEBUG)
  31    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -g -O0")
  32    set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -g -O0")
  33 endif()
  34 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -fPIC")
  35 set(CMAKE_CXX_STANDARD 11)
  36
  37 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--no-undefined")
  38 set(CMAKE_CXX_VISIBILITY_PRESET hidden)
  39 set(CMAKE_C_VISIBILITY_PRESET hidden)
  40
  41 if(NOT DEFINED VULKAN_CXX_INCLUDE)
  42    set(VULKAN_CXX_INCLUDE ${VULKAN_PKG_CONFIG_INCLUDEDIR})
  43 endif()
  44
  45 if(DEFINED VULKAN_CXX_INCLUDE)
  46    message(STATUS "Using Vulkan include directories: ${VULKAN_CXX_INCLUDE}")
  47    separate_arguments(VULKAN_CXX_INCLUDE)
  48 else()
  49    message(FATAL_ERROR "Either vulkan.pc must be available or VULKAN_CXX_INCLUDE must be defined")
  50 endif()
  51
  52 # Build Configuration options
  53 option(BUILD_WSI_HEADLESS "Build with support for VK_EXT_headless_surface" ON)
  54 option(BUILD_WSI_WAYLAND "Build with support for VK_KHR_wayland_surface" OFF)
  55 set(SELECT_EXTERNAL_ALLOCATOR "none" CACHE STRING "Select an external system allocator (none, ion)")
  56 set(EXTERNAL_WSIALLOC_LIBRARY "" CACHE STRING "External implementation of the wsialloc interface to use")
  57
  58 if(BUILD_WSI_WAYLAND)
  59    if(SELECT_EXTERNAL_ALLOCATOR STREQUAL "none")
  60       message(FATAL_ERROR "Wayland only supported with an external allocator.")
  61    endif()
  62    set(BUILD_DRM_UTILS True)
  63 endif()
  64
  65 # DRM Utilities
  66 if(BUILD_DRM_UTILS)
  67    add_library(drm_utils STATIC util/drm/drm_utils.cpp)
  68
  69    pkg_check_modules(LIBDRM REQUIRED libdrm)
  70    message(STATUS "Using libdrm include directories: ${LIBDRM_INCLUDE_DIRS}")
  71    message(STATUS "Using libdrm cflags: ${LIBDRM_CFLAGS}")
  72
  73    target_sources(drm_utils PRIVATE util/drm/format_table.c)
  74    target_include_directories(drm_utils PRIVATE ${VULKAN_CXX_INCLUDE})
  75    target_include_directories(drm_utils PUBLIC ${LIBDRM_INCLUDE_DIRS})
  76    target_compile_options(drm_utils PUBLIC ${LIBDRM_CFLAGS})
  77 endif()
  78
  79 # External WSI Alloctator
  80 if(NOT SELECT_EXTERNAL_ALLOCATOR STREQUAL "none" AND EXTERNAL_WSIALLOC_LIBRARY STREQUAL "")
  81    add_library(wsialloc STATIC)
  82    set_target_properties(wsialloc PROPERTIES C_STANDARD 99)
  83
  84    if(SELECT_EXTERNAL_ALLOCATOR STREQUAL "ion")
  85       target_sources(wsialloc PRIVATE util/wsialloc/wsialloc_ion.c)
  86       target_link_libraries(wsialloc drm_utils)
  87       if(DEFINED KERNEL_DIR)
  88          target_include_directories(wsialloc PRIVATE "${KERNEL_DIR}/drivers/staging/android/uapi")
  89       else()
  90          message(FATAL_ERROR "KERNEL_DIR must be defined as the root of the Linux kernel source.")
  91       endif()
  92    else()
  93       message(FATAL_ERROR "Invalid external allocator selected: ${SELECT_EXTERNAL_ALLOCATOR}")
  94    endif()
  95
  96    target_include_directories(wsialloc PRIVATE ${VULKAN_CXX_INCLUDE})
  97    target_include_directories(wsialloc PRIVATE util/drm)
  98 endif()
  99
 100 # Wayland WSI
 101 if(BUILD_WSI_WAYLAND)
 102    add_library(wayland_wsi STATIC
 103       wsi/wayland/surface_properties.cpp
 104       wsi/wayland/surface.cpp
 105       wsi/wayland/wl_helpers.cpp
 106       wsi/wayland/swapchain.cpp)
 107
 108    pkg_check_modules(WAYLAND_CLIENT REQUIRED wayland-client)
 109    message(STATUS "Using Wayland client include directories: ${WAYLAND_CLIENT_INCLUDE_DIRS}")
 110    message(STATUS "Using Wayland client cflags: ${WAYLAND_CLIENT_CFLAGS}")
 111    message(STATUS "Using Wayland client ldflags: ${WAYLAND_CLIENT_LDFLAGS}")
 112
 113    pkg_check_modules(WAYLAND_SCANNER REQUIRED wayland-scanner)
 114    pkg_get_variable(WAYLAND_SCANNER_EXEC wayland-scanner wayland_scanner)
 115    message(STATUS "Using wayland-scanner : ${WAYLAND_SCANNER_EXEC}")
 116
 117    pkg_check_modules(WAYLAND_PROTOCOLS REQUIRED wayland-protocols)
 118    pkg_get_variable(WAYLAND_PROTOCOLS_DIR wayland-protocols pkgdatadir)
 119    message(STATUS "Using wayland protocols dir : ${WAYLAND_PROTOCOLS_DIR}")
 120
 121    add_custom_target(wayland_generated_files
 122       COMMAND ${WAYLAND_SCANNER_EXEC} client-header
 123       ${WAYLAND_PROTOCOLS_DIR}/unstable/linux-dmabuf/linux-dmabuf-unstable-v1.xml
 124       ${CMAKE_CURRENT_BINARY_DIR}/linux-dmabuf-unstable-v1-client-protocol.h
 125       COMMAND ${WAYLAND_SCANNER_EXEC} code
 126       ${WAYLAND_PROTOCOLS_DIR}/unstable/linux-dmabuf/linux-dmabuf-unstable-v1.xml
 127       ${CMAKE_CURRENT_BINARY_DIR}/linux-dmabuf-unstable-v1-protocol.c
 128       COMMAND ${WAYLAND_SCANNER_EXEC} client-header
 129       ${WAYLAND_PROTOCOLS_DIR}/unstable/linux-explicit-synchronization/linux-explicit-synchronization-unstable-v1.xml
 130       ${CMAKE_CURRENT_BINARY_DIR}/linux-explicit-synchronization-unstable-v1-protocol.h
 131       COMMAND ${WAYLAND_SCANNER_EXEC} code
 132       ${WAYLAND_PROTOCOLS_DIR}/unstable/linux-explicit-synchronization/linux-explicit-synchronization-unstable-v1.xml
 133       ${CMAKE_CURRENT_BINARY_DIR}/linux-explicit-synchronization-unstable-v1-protocol.c
 134       BYPRODUCTS linux-dmabuf-unstable-v1-protocol.c linux-dmabuf-unstable-v1-client-protocol.h
 135                  linux-explicit-synchronization-unstable-v1-protocol.c linux-explicit-synchronization-unstable-v1-protocol.h)
 136
 137    target_sources(wayland_wsi PRIVATE
 138       ${CMAKE_CURRENT_BINARY_DIR}/linux-dmabuf-unstable-v1-protocol.c
 139       ${CMAKE_CURRENT_BINARY_DIR}/linux-dmabuf-unstable-v1-client-protocol.h
 140       ${CMAKE_CURRENT_BINARY_DIR}/linux-explicit-synchronization-unstable-v1-protocol.c
 141       ${CMAKE_CURRENT_BINARY_DIR}/linux-explicit-synchronization-unstable-v1-protocol.h)
 142    add_dependencies(wayland_wsi wayland_generated_files)
 143
 144    target_include_directories(wayland_wsi PRIVATE
 145       ${PROJECT_SOURCE_DIR}
 146       ${VULKAN_CXX_INCLUDE}
 147       ${WAYLAND_CLIENT_INCLUDE_DIRS}
 148       ${CMAKE_CURRENT_BINARY_DIR})
 149
 150    target_compile_options(wayland_wsi PRIVATE ${WAYLAND_CLIENT_CFLAGS})
 151    target_compile_options(wayland_wsi INTERFACE "-DBUILD_WSI_WAYLAND=1")
 152    if(NOT EXTERNAL_WSIALLOC_LIBRARY STREQUAL "")
 153       target_link_libraries(wayland_wsi ${EXTERNAL_WSIALLOC_LIBRARY})
 154    else()
 155       target_link_libraries(wayland_wsi wsialloc)
 156    endif()
 157    target_link_libraries(wayland_wsi drm_utils ${WAYLAND_CLIENT_LDFLAGS})
 158    list(APPEND LINK_WSI_LIBS wayland_wsi)
 159 else()
 160    list(APPEND JSON_COMMANDS COMMAND sed -i '/VK_KHR_wayland_surface/d' ${CMAKE_CURRENT_BINARY_DIR}/VkLayer_window_system_integration.json)
 161 endif()
 162
 163 # Headless
 164 if(BUILD_WSI_HEADLESS)
 165    add_library(wsi_headless STATIC
 166       wsi/headless/surface_properties.cpp
 167       wsi/headless/surface.cpp
 168       wsi/headless/swapchain.cpp)
 169
 170    target_include_directories(wsi_headless PRIVATE
 171       ${PROJECT_SOURCE_DIR}
 172       ${VULKAN_CXX_INCLUDE}
 173       ${CMAKE_CURRENT_BINARY_DIR})
 174
 175    target_compile_options(wsi_headless INTERFACE "-DBUILD_WSI_HEADLESS=1")
 176    list(APPEND LINK_WSI_LIBS wsi_headless)
 177 else()
 178    list(APPEND JSON_COMMANDS COMMAND sed -i '/VK_EXT_headless_surface/d' ${CMAKE_CURRENT_BINARY_DIR}/VkLayer_window_system_integration.json)
 179 endif()
 180
 181 # Layer
 182 add_library(${PROJECT_NAME} SHARED
 183    layer/layer.cpp
 184    layer/private_data.cpp
 185    layer/surface_api.cpp
 186    layer/swapchain_api.cpp
 187    util/timed_semaphore.cpp
 188    util/custom_allocator.cpp
 189    util/extension_list.cpp
 190    util/log.cpp
 191    wsi/swapchain_base.cpp
 192    wsi/synchronization.cpp
 193    wsi/wsi_factory.cpp)
 194
 195 target_compile_definitions(${PROJECT_NAME} PRIVATE ${WSI_DEFINES})
 196 target_include_directories(${PROJECT_NAME} PRIVATE
 197         ${PROJECT_SOURCE_DIR} ${CMAKE_CURRENT_BINARY_DIR} ${VULKAN_CXX_INCLUDE})
 198
 199 target_link_libraries(${PROJECT_NAME} ${LINK_WSI_LIBS})
 200
 201 add_custom_target(manifest_json ALL COMMAND
 202    cp ${PROJECT_SOURCE_DIR}/layer/VkLayer_window_system_integration.json ${CMAKE_CURRENT_BINARY_DIR}
 203    ${JSON_COMMANDS})