CMakeLists.txt

   1 # ----------------------------------------------------------------------------
   2 #  Root CMake file for OpenCV
   3 #
   4 #    From the off-tree build directory, invoke:
   5 #      $ cmake <PATH_TO_OPENCV_ROOT>
   6 #
   7 # ----------------------------------------------------------------------------
   8
   9 include(cmake/OpenCVMinDepVersions.cmake)
  10
  11 if(CMAKE_GENERATOR MATCHES Xcode AND XCODE_VERSION VERSION_GREATER 4.3)
  12   cmake_minimum_required(VERSION 2.8.8 FATAL_ERROR)
  13 else()
  14   cmake_minimum_required(VERSION "${MIN_VER_CMAKE}" FATAL_ERROR)
  15 endif()
  16
  17 # Following block can broke build in case of cross-compilng
  18 # but CMAKE_CROSSCOMPILING variable will be set only on project(OpenCV) command
  19 # so we will try to detect crosscompiling by presense of CMAKE_TOOLCHAIN_FILE
  20 if(NOT CMAKE_TOOLCHAIN_FILE)
  21   # it _must_ go before project(OpenCV) in order to work
  22   if(WIN32)
  23     set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  24   else()
  25     set(CMAKE_INSTALL_PREFIX "/usr/local" CACHE PATH "Installation Directory")
  26   endif()
  27 else(NOT CMAKE_TOOLCHAIN_FILE)
  28   #Android: set output folder to ${CMAKE_BINARY_DIR}
  29   set( LIBRARY_OUTPUT_PATH_ROOT ${CMAKE_BINARY_DIR} CACHE PATH "root for library output, set this to change where android libs are compiled to" )
  30   # any crosscompiling
  31   set(CMAKE_INSTALL_PREFIX "${CMAKE_BINARY_DIR}/install" CACHE PATH "Installation Directory")
  32 endif(NOT CMAKE_TOOLCHAIN_FILE)
  33
  34
  35 # must go before the project command
  36 set(CMAKE_CONFIGURATION_TYPES "Debug;Release" CACHE STRING "Configs" FORCE)
  37 if(DEFINED CMAKE_BUILD_TYPE)
  38   set_property( CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS ${CMAKE_CONFIGURATION_TYPES} )
  39 endif()
  40
  41 project(OpenCV CXX C)
  42
  43 if(MSVC)
  44   set(CMAKE_USE_RELATIVE_PATHS ON CACHE INTERNAL "" FORCE)
  45 endif()
  46
  47 include(cmake/OpenCVUtils.cmake)
  48
  49 # ----------------------------------------------------------------------------
  50 # Break in case of popular CMake configuration mistakes
  51 # ----------------------------------------------------------------------------
  52 if(NOT CMAKE_SIZEOF_VOID_P GREATER 0)
  53   message(FATAL_ERROR "CMake fails to deterimine the bitness of target platform.
  54   Please check your CMake and compiler installation. If you are crosscompiling then ensure that your CMake toolchain file correctly sets the compiler details.")
  55 endif()
  56
  57 # ----------------------------------------------------------------------------
  58 # Detect compiler and target platform architecture
  59 # ----------------------------------------------------------------------------
  60 include(cmake/OpenCVDetectCXXCompiler.cmake)
  61
  62 # Add these standard paths to the search paths for FIND_LIBRARY
  63 # to find libraries from these locations first
  64 if(UNIX AND NOT ANDROID)
  65   if(X86_64 OR CMAKE_SIZEOF_VOID_P EQUAL 8)
  66     if(EXISTS /lib64)
  67       list(APPEND CMAKE_LIBRARY_PATH /lib64)
  68     else()
  69       list(APPEND CMAKE_LIBRARY_PATH /lib)
  70     endif()
  71     if(EXISTS /usr/lib64)
  72       list(APPEND CMAKE_LIBRARY_PATH /usr/lib64)
  73     else()
  74       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
  75     endif()
  76   elseif(X86 OR CMAKE_SIZEOF_VOID_P EQUAL 4)
  77     if(EXISTS /lib32)
  78       list(APPEND CMAKE_LIBRARY_PATH /lib32)
  79     else()
  80       list(APPEND CMAKE_LIBRARY_PATH /lib)
  81     endif()
  82     if(EXISTS /usr/lib32)
  83       list(APPEND CMAKE_LIBRARY_PATH /usr/lib32)
  84     else()
  85       list(APPEND CMAKE_LIBRARY_PATH /usr/lib)
  86     endif()
  87   endif()
  88 endif()
  89
  90 # Add these standard paths to the search paths for FIND_PATH
  91 # to find include files from these locations first
  92 if(MINGW)
  93   if(EXISTS /mingw)
  94       list(APPEND CMAKE_INCLUDE_PATH /mingw)
  95   endif()
  96   if(EXISTS /mingw32)
  97       list(APPEND CMAKE_INCLUDE_PATH /mingw32)
  98   endif()
  99   if(EXISTS /mingw64)
 100       list(APPEND CMAKE_INCLUDE_PATH /mingw64)
 101   endif()
 102 endif()
 103
 104 # ----------------------------------------------------------------------------
 105 # OpenCV cmake options
 106 # ----------------------------------------------------------------------------
 107
 108 # Optional 3rd party components
 109 # ===================================================
 110 OCV_OPTION(WITH_1394           "Include IEEE1394 support"                    ON   IF (NOT ANDROID AND NOT IOS) )
 111 OCV_OPTION(WITH_AVFOUNDATION   "Use AVFoundation for Video I/O"              ON   IF IOS)
 112 OCV_OPTION(WITH_CARBON         "Use Carbon for UI instead of Cocoa"          OFF  IF APPLE )
 113 OCV_OPTION(WITH_CUDA           "Include NVidia Cuda Runtime support"                                         ON  IF (NOT ANDROID AND NOT IOS) )
 114 OCV_OPTION(WITH_CUFFT          "Include NVidia Cuda Fast Fourier Transform (FFT) library support"            ON  IF (NOT ANDROID AND NOT IOS) )
 115 OCV_OPTION(WITH_CUBLAS         "Include NVidia Cuda Basic Linear Algebra Subprograms (BLAS) library support" OFF IF (NOT ANDROID AND NOT IOS) )
 116 OCV_OPTION(WITH_NVCUVID        "Include NVidia Video Decoding library support"                               OFF IF (NOT ANDROID AND NOT IOS AND NOT APPLE) )
 117 OCV_OPTION(WITH_EIGEN          "Include Eigen2/Eigen3 support"               ON)
 118 OCV_OPTION(WITH_VFW            "Include Video for Windows support"           ON   IF WIN32 )
 119 OCV_OPTION(WITH_FFMPEG         "Include FFMPEG support"                      ON   IF (NOT ANDROID AND NOT IOS))
 120 OCV_OPTION(WITH_GSTREAMER      "Include Gstreamer support"                   ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 121 OCV_OPTION(WITH_GSTREAMER_1_X  "Include Gstreamer 1.x support"               OFF)
 122 OCV_OPTION(WITH_GTK            "Include GTK support"                         ON   IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 123 OCV_OPTION(WITH_IPP            "Include Intel IPP support"                   OFF  IF (MSVC OR X86 OR X86_64) )
 124 OCV_OPTION(WITH_JASPER         "Include JPEG2K support"                      ON   IF (NOT IOS) )
 125 OCV_OPTION(WITH_JPEG           "Include JPEG support"                        ON)
 126 OCV_OPTION(WITH_WEBP           "Include WebP support"                        ON   IF (NOT IOS) )
 127 OCV_OPTION(WITH_OPENEXR        "Include ILM support via OpenEXR"             ON   IF (NOT IOS) )
 128 OCV_OPTION(WITH_OPENGL         "Include OpenGL support"                      OFF  IF (NOT ANDROID AND NOT APPLE) )
 129 OCV_OPTION(WITH_OPENNI         "Include OpenNI support"                      OFF  IF (NOT ANDROID AND NOT IOS) )
 130 OCV_OPTION(WITH_PNG            "Include PNG support"                         ON)
 131 OCV_OPTION(WITH_PVAPI          "Include Prosilica GigE support"              ON   IF (NOT ANDROID AND NOT IOS) )
 132 OCV_OPTION(WITH_GIGEAPI        "Include Smartek GigE support"                ON   IF (NOT ANDROID AND NOT IOS) )
 133 OCV_OPTION(WITH_QT             "Build with Qt Backend support"               OFF  IF (NOT ANDROID AND NOT IOS) )
 134 OCV_OPTION(WITH_WIN32UI        "Build with Win32 UI Backend support"         ON   IF WIN32 )
 135 OCV_OPTION(WITH_QUICKTIME      "Use QuickTime for Video I/O insted of QTKit" OFF  IF APPLE )
 136 OCV_OPTION(WITH_TBB            "Include Intel TBB support"                   OFF  IF (NOT IOS) )
 137 OCV_OPTION(WITH_CSTRIPES       "Include C= support"                          OFF  IF WIN32 )
 138 OCV_OPTION(WITH_TIFF           "Include TIFF support"                        ON   IF (NOT IOS) )
 139 OCV_OPTION(WITH_UNICAP         "Include Unicap support (GPL)"                OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 140 OCV_OPTION(WITH_V4L            "Include Video 4 Linux support"               ON   IF (UNIX AND NOT ANDROID) )
 141 OCV_OPTION(WITH_LIBV4L         "Use libv4l for Video 4 Linux support"        ON   IF (UNIX AND NOT ANDROID) )
 142 OCV_OPTION(WITH_DSHOW          "Build HighGUI with DirectShow support"       ON   IF (WIN32 AND NOT ARM) )
 143 OCV_OPTION(WITH_MSMF           "Build HighGUI with Media Foundation support" OFF  IF WIN32 )
 144 OCV_OPTION(WITH_XIMEA          "Include XIMEA cameras support"               OFF  IF (NOT ANDROID AND NOT APPLE) )
 145 OCV_OPTION(WITH_XINE           "Include Xine support (GPL)"                  OFF  IF (UNIX AND NOT APPLE AND NOT ANDROID) )
 146 OCV_OPTION(WITH_CLP            "Include Clp support (EPL)"                   OFF)
 147 OCV_OPTION(WITH_OPENCL         "Include OpenCL Runtime support"              ON  IF (NOT ANDROID AND NOT IOS) )
 148 OCV_OPTION(WITH_OPENCLAMDFFT   "Include AMD OpenCL FFT library support"      ON  IF (NOT ANDROID AND NOT IOS) )
 149 OCV_OPTION(WITH_OPENCLAMDBLAS  "Include AMD OpenCL BLAS library support"     ON  IF (NOT ANDROID AND NOT IOS) )
 150
 151
 152 # OpenCV build components
 153 # ===================================================
 154 OCV_OPTION(BUILD_SHARED_LIBS        "Build shared libraries (.dll/.so) instead of static ones (.lib/.a)" NOT (ANDROID OR IOS) )
 155 OCV_OPTION(BUILD_opencv_apps        "Build utility applications (used for example to train classifiers)" (NOT ANDROID) IF (NOT IOS) )
 156 OCV_OPTION(BUILD_ANDROID_EXAMPLES   "Build examples for Android platform"         ON  IF ANDROID )
 157 OCV_OPTION(BUILD_DOCS               "Create build rules for OpenCV Documentation" ON )
 158 OCV_OPTION(BUILD_EXAMPLES           "Build all examples"                          OFF )
 159 OCV_OPTION(BUILD_PACKAGE            "Enables 'make package_source' command"       ON )
 160 OCV_OPTION(BUILD_PERF_TESTS         "Build performance tests"                     ON  IF (NOT IOS) )
 161 OCV_OPTION(BUILD_TESTS              "Build accuracy & regression tests"           ON  IF (NOT IOS) )
 162 OCV_OPTION(BUILD_WITH_DEBUG_INFO    "Include debug info into debug libs (not MSCV only)" ON )
 163 OCV_OPTION(BUILD_WITH_STATIC_CRT    "Enables use of staticaly linked CRT for staticaly linked OpenCV" ON IF MSVC )
 164 OCV_OPTION(BUILD_FAT_JAVA_LIB       "Create fat java wrapper containing the whole OpenCV library" ON IF NOT BUILD_SHARED_LIBS AND CMAKE_COMPILER_IS_GNUCXX )
 165 OCV_OPTION(BUILD_ANDROID_SERVICE    "Build OpenCV Manager for Google Play" OFF IF ANDROID AND ANDROID_SOURCE_TREE )
 166 OCV_OPTION(BUILD_ANDROID_PACKAGE    "Build platform-specific package for Google Play" OFF IF ANDROID )
 167
 168 # 3rd party libs
 169 OCV_OPTION(BUILD_ZLIB               "Build zlib from source"             WIN32 OR APPLE )
 170 OCV_OPTION(BUILD_TIFF               "Build libtiff from source"          WIN32 OR ANDROID OR APPLE )
 171 OCV_OPTION(BUILD_JASPER             "Build libjasper from source"        WIN32 OR ANDROID OR APPLE )
 172 OCV_OPTION(BUILD_JPEG               "Build libjpeg from source"          WIN32 OR ANDROID OR APPLE )
 173 OCV_OPTION(BUILD_PNG                "Build libpng from source"           WIN32 OR ANDROID OR APPLE )
 174 OCV_OPTION(BUILD_OPENEXR            "Build openexr from source"          WIN32 OR ANDROID OR APPLE )
 175 OCV_OPTION(BUILD_TBB                "Download and build TBB from source" ANDROID )
 176
 177 # OpenCV installation options
 178 # ===================================================
 179 OCV_OPTION(INSTALL_CREATE_DISTRIB   "Change install rules to build the distribution package" OFF )
 180 OCV_OPTION(INSTALL_C_EXAMPLES       "Install C examples"        OFF )
 181 OCV_OPTION(INSTALL_PYTHON_EXAMPLES  "Install Python examples"   OFF )
 182 OCV_OPTION(INSTALL_ANDROID_EXAMPLES "Install Android examples"  OFF IF ANDROID )
 183 OCV_OPTION(INSTALL_TO_MANGLED_PATHS "Enables mangled install paths, that help with side by side installs." OFF IF (UNIX AND NOT ANDROID AND NOT IOS AND BUILD_SHARED_LIBS) )
 184
 185
 186 # OpenCV build options
 187 # ===================================================
 188 OCV_OPTION(ENABLE_PRECOMPILED_HEADERS "Use precompiled headers"                                  ON   IF (NOT IOS) )
 189 OCV_OPTION(ENABLE_SOLUTION_FOLDERS    "Solution folder in Visual Studio or in other IDEs"        (MSVC_IDE OR CMAKE_GENERATOR MATCHES Xcode) )
 190 OCV_OPTION(ENABLE_PROFILING           "Enable profiling in the GCC compiler (Add flags: -g -pg)" OFF  IF CMAKE_COMPILER_IS_GNUCXX )
 191 OCV_OPTION(ENABLE_OMIT_FRAME_POINTER  "Enable -fomit-frame-pointer for GCC"                      ON   IF CMAKE_COMPILER_IS_GNUCXX AND NOT (APPLE AND CMAKE_COMPILER_IS_CLANGCXX) )
 192 OCV_OPTION(ENABLE_POWERPC             "Enable PowerPC for GCC"                                   ON   IF (CMAKE_COMPILER_IS_GNUCXX AND CMAKE_SYSTEM_PROCESSOR MATCHES powerpc.*) )
 193 OCV_OPTION(ENABLE_FAST_MATH           "Enable -ffast-math (not recommended for GCC 4.6.x)"       OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 194 OCV_OPTION(ENABLE_SSE                 "Enable SSE instructions"                                  ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 195 OCV_OPTION(ENABLE_SSE2                "Enable SSE2 instructions"                                 ON   IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 196 OCV_OPTION(ENABLE_SSE3                "Enable SSE3 instructions"                                 ON   IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 197 OCV_OPTION(ENABLE_SSSE3               "Enable SSSE3 instructions"                                OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 198 OCV_OPTION(ENABLE_SSE41               "Enable SSE4.1 instructions"                               OFF  IF ((CV_ICC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 199 OCV_OPTION(ENABLE_SSE42               "Enable SSE4.2 instructions"                               OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND (X86 OR X86_64)) )
 200 OCV_OPTION(ENABLE_AVX                 "Enable AVX instructions"                                  OFF  IF ((MSVC OR CMAKE_COMPILER_IS_GNUCXX) AND (X86 OR X86_64)) )
 201 OCV_OPTION(ENABLE_NEON                "Enable NEON instructions"                                 OFF  IF (CMAKE_COMPILER_IS_GNUCXX AND ARM) )
 202 OCV_OPTION(ENABLE_NOISY_WARNINGS      "Show all warnings even if they are too noisy"             OFF )
 203 OCV_OPTION(OPENCV_WARNINGS_ARE_ERRORS "Treat warnings as errors"                                 OFF )
 204 OCV_OPTION(ENABLE_WINRT_MODE          "Build with Windows Runtime support"                       OFF  IF WIN32 )
 205
 206
 207 # ----------------------------------------------------------------------------
 208 #  Get actual OpenCV version number from sources
 209 # ----------------------------------------------------------------------------
 210 include(cmake/OpenCVVersion.cmake)
 211
 212
 213 # ----------------------------------------------------------------------------
 214 #  Build & install layouts
 215 # ----------------------------------------------------------------------------
 216
 217 # Save libs and executables in the same place
 218 set(EXECUTABLE_OUTPUT_PATH "${CMAKE_BINARY_DIR}/bin" CACHE PATH "Output directory for applications" )
 219
 220 if(ANDROID OR WIN32)
 221   set(OPENCV_DOC_INSTALL_PATH doc)
 222 elseif(INSTALL_TO_MANGLED_PATHS)
 223   set(OPENCV_DOC_INSTALL_PATH share/OpenCV-${OPENCV_VERSION}/doc)
 224 else()
 225   set(OPENCV_DOC_INSTALL_PATH share/OpenCV/doc)
 226 endif()
 227
 228 if(WIN32)
 229   if(DEFINED OpenCV_RUNTIME AND DEFINED OpenCV_ARCH)
 230     set(OpenCV_INSTALL_BINARIES_PREFIX "${OpenCV_ARCH}/${OpenCV_RUNTIME}/")
 231   else()
 232     message(STATUS "Can't detect runtime and/or arch")
 233     set(OpenCV_INSTALL_BINARIES_PREFIX "")
 234   endif()
 235 else()
 236   set(OpenCV_INSTALL_BINARIES_PREFIX "")
 237 endif()
 238
 239 set(OPENCV_SAMPLES_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}samples")
 240
 241 set(OPENCV_BIN_INSTALL_PATH "${OpenCV_INSTALL_BINARIES_PREFIX}bin")
 242
 243 if(ANDROID)
 244   set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib/${ANDROID_NDK_ABI_NAME}")
 245   set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib/${ANDROID_NDK_ABI_NAME}")
 246   set(OPENCV_LIB_INSTALL_PATH     sdk/native/libs/${ANDROID_NDK_ABI_NAME})
 247   set(OPENCV_3P_LIB_INSTALL_PATH  sdk/native/3rdparty/libs/${ANDROID_NDK_ABI_NAME})
 248   set(OPENCV_CONFIG_INSTALL_PATH  sdk/native/jni)
 249   set(OPENCV_INCLUDE_INSTALL_PATH sdk/native/jni/include)
 250 else()
 251   set(LIBRARY_OUTPUT_PATH         "${OpenCV_BINARY_DIR}/lib")
 252   set(3P_LIBRARY_OUTPUT_PATH      "${OpenCV_BINARY_DIR}/3rdparty/lib${LIB_SUFFIX}")
 253   if(WIN32)
 254     if(OpenCV_STATIC)
 255       set(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 256     else()
 257       set(OPENCV_LIB_INSTALL_PATH   "${OpenCV_INSTALL_BINARIES_PREFIX}lib${LIB_SUFFIX}")
 258     endif()
 259     set(OPENCV_3P_LIB_INSTALL_PATH  "${OpenCV_INSTALL_BINARIES_PREFIX}staticlib${LIB_SUFFIX}")
 260   else()
 261     set(OPENCV_LIB_INSTALL_PATH     lib${LIB_SUFFIX})
 262     set(OPENCV_3P_LIB_INSTALL_PATH  share/OpenCV/3rdparty/${OPENCV_LIB_INSTALL_PATH})
 263   endif()
 264   set(OPENCV_INCLUDE_INSTALL_PATH "include")
 265
 266   math(EXPR SIZEOF_VOID_P_BITS "8 * ${CMAKE_SIZEOF_VOID_P}")
 267   if(LIB_SUFFIX AND NOT SIZEOF_VOID_P_BITS EQUAL LIB_SUFFIX)
 268     set(OPENCV_CONFIG_INSTALL_PATH lib${LIB_SUFFIX}/cmake/opencv)
 269   else()
 270     set(OPENCV_CONFIG_INSTALL_PATH share/OpenCV)
 271   endif()
 272 endif()
 273
 274 set(CMAKE_INSTALL_RPATH "${CMAKE_INSTALL_PREFIX}/${OPENCV_LIB_INSTALL_PATH}")
 275 set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 276
 277 if(INSTALL_TO_MANGLED_PATHS)
 278   set(OPENCV_INCLUDE_INSTALL_PATH ${OPENCV_INCLUDE_INSTALL_PATH}/opencv-${OPENCV_VERSION})
 279 endif()
 280
 281 if(WIN32)
 282   # Postfix of DLLs:
 283   set(OPENCV_DLLVERSION "${OPENCV_VERSION_MAJOR}${OPENCV_VERSION_MINOR}${OPENCV_VERSION_PATCH}")
 284   set(OPENCV_DEBUG_POSTFIX d)
 285 else()
 286   # Postfix of so's:
 287   set(OPENCV_DLLVERSION "")
 288   set(OPENCV_DEBUG_POSTFIX "")
 289 endif()
 290
 291 if(DEFINED CMAKE_DEBUG_POSTFIX)
 292   set(OPENCV_DEBUG_POSTFIX "${CMAKE_DEBUG_POSTFIX}")
 293 endif()
 294
 295
 296 # ----------------------------------------------------------------------------
 297 #  Path for build/platform -specific headers
 298 # ----------------------------------------------------------------------------
 299 set(OPENCV_CONFIG_FILE_INCLUDE_DIR "${CMAKE_BINARY_DIR}/" CACHE PATH "Where to create the platform-dependant cvconfig.h")
 300 ocv_include_directories(${OPENCV_CONFIG_FILE_INCLUDE_DIR})
 301
 302 # ----------------------------------------------------------------------------
 303 #  Path for additional modules
 304 # ----------------------------------------------------------------------------
 305 set(OPENCV_EXTRA_MODULES_PATH "" CACHE PATH "Where to look for additional OpenCV modules")
 306
 307 # ----------------------------------------------------------------------------
 308 #  Autodetect if we are in a GIT repository
 309 # ----------------------------------------------------------------------------
 310 find_host_package(Git QUIET)
 311
 312 if(GIT_FOUND)
 313   execute_process(COMMAND "${GIT_EXECUTABLE}" describe --tags --always --dirty --match "2.[0-9].[0-9]*"
 314     WORKING_DIRECTORY "${OpenCV_SOURCE_DIR}"
 315     OUTPUT_VARIABLE OPENCV_VCSVERSION
 316     RESULT_VARIABLE GIT_RESULT
 317     ERROR_QUIET
 318     OUTPUT_STRIP_TRAILING_WHITESPACE
 319   )
 320   if(NOT GIT_RESULT EQUAL 0)
 321     set(OPENCV_VCSVERSION "unknown")
 322   endif()
 323 else()
 324   # We don't have git:
 325   set(OPENCV_VCSVERSION "unknown")
 326 endif()
 327
 328
 329 # ----------------------------------------------------------------------------
 330 # OpenCV compiler and linker options
 331 # ----------------------------------------------------------------------------
 332 # In case of Makefiles if the user does not setup CMAKE_BUILD_TYPE, assume it's Release:
 333 if(CMAKE_GENERATOR MATCHES "Makefiles|Ninja" AND "${CMAKE_BUILD_TYPE}" STREQUAL "")
 334   set(CMAKE_BUILD_TYPE Release)
 335 endif()
 336
 337 include(cmake/OpenCVCompilerOptions.cmake)
 338
 339
 340 # ----------------------------------------------------------------------------
 341 # Use statically or dynamically linked CRT?
 342 # Default: dynamic
 343 # ----------------------------------------------------------------------------
 344 if(MSVC)
 345   include(cmake/OpenCVCRTLinkage.cmake)
 346 endif(MSVC)
 347
 348 if(WIN32 AND NOT MINGW)
 349   add_definitions(-D_VARIADIC_MAX=10)
 350 endif(WIN32 AND NOT MINGW)
 351
 352
 353 # ----------------------------------------------------------------------------
 354 #       CHECK FOR SYSTEM LIBRARIES, OPTIONS, ETC..
 355 # ----------------------------------------------------------------------------
 356 if(UNIX)
 357   find_package(PkgConfig QUIET)
 358   include(CheckFunctionExists)
 359   include(CheckIncludeFile)
 360
 361   if(NOT APPLE)
 362     CHECK_INCLUDE_FILE(pthread.h HAVE_LIBPTHREAD)
 363     if(ANDROID)
 364       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m log)
 365     elseif(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD|NetBSD|DragonFly")
 366       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} m pthread)
 367     else()
 368       set(OPENCV_LINKER_LIBS ${OPENCV_LINKER_LIBS} dl m pthread rt)
 369     endif()
 370   else()
 371     set(HAVE_LIBPTHREAD YES)
 372   endif()
 373 endif()
 374
 375 include(cmake/OpenCVPCHSupport.cmake)
 376 include(cmake/OpenCVModule.cmake)
 377
 378 # ----------------------------------------------------------------------------
 379 #  Detect 3rd-party libraries
 380 # ----------------------------------------------------------------------------
 381
 382 include(cmake/OpenCVFindLibsGrfmt.cmake)
 383 include(cmake/OpenCVFindLibsGUI.cmake)
 384 include(cmake/OpenCVFindLibsVideo.cmake)
 385 include(cmake/OpenCVFindLibsPerf.cmake)
 386
 387
 388 # ----------------------------------------------------------------------------
 389 #  Detect other 3rd-party libraries/tools
 390 # ----------------------------------------------------------------------------
 391
 392 # --- LATEX for pdf documentation ---
 393 if(BUILD_DOCS)
 394   include(cmake/OpenCVFindLATEX.cmake)
 395 endif(BUILD_DOCS)
 396
 397 # --- Python Support ---
 398 include(cmake/OpenCVDetectPython.cmake)
 399
 400 # --- Java Support ---
 401 include(cmake/OpenCVDetectApacheAnt.cmake)
 402 if(ANDROID)
 403   include(cmake/OpenCVDetectAndroidSDK.cmake)
 404
 405   if(NOT ANDROID_TOOLS_Pkg_Revision GREATER 13)
 406     message(WARNING "OpenCV requires Android SDK tools revision 14 or newer. Otherwise tests and samples will no be compiled.")
 407   endif()
 408 else()
 409   find_package(JNI)
 410 endif()
 411
 412 if(ANDROID AND ANDROID_EXECUTABLE AND ANT_EXECUTABLE AND (ANT_VERSION VERSION_GREATER 1.7) AND (ANDROID_TOOLS_Pkg_Revision GREATER 13))
 413   SET(CAN_BUILD_ANDROID_PROJECTS TRUE)
 414 else()
 415   SET(CAN_BUILD_ANDROID_PROJECTS FALSE)
 416 endif()
 417
 418 # --- OpenCL ---
 419 if(WITH_OPENCL)
 420   include(cmake/OpenCVDetectOpenCL.cmake)
 421 endif()
 422
 423 # --- Matlab/Octave ---
 424 include(cmake/OpenCVFindMatlab.cmake)
 425
 426 # ----------------------------------------------------------------------------
 427 # Solution folders:
 428 # ----------------------------------------------------------------------------
 429 if(ENABLE_SOLUTION_FOLDERS)
 430   set_property(GLOBAL PROPERTY USE_FOLDERS ON)
 431   set_property(GLOBAL PROPERTY PREDEFINED_TARGETS_FOLDER "CMakeTargets")
 432 endif()
 433
 434 # Extra OpenCV targets: uninstall, package_source, perf, etc.
 435 include(cmake/OpenCVExtraTargets.cmake)
 436
 437
 438 # ----------------------------------------------------------------------------
 439 # Process subdirectories
 440 # ----------------------------------------------------------------------------
 441
 442 # opencv.hpp and legacy headers
 443 add_subdirectory(include)
 444
 445 # OpenCV modules
 446 add_subdirectory(modules)
 447
 448 # Generate targets for documentation
 449 add_subdirectory(doc)
 450
 451 # various data that is used by cv libraries and/or demo applications.
 452 add_subdirectory(data)
 453
 454 # extra applications
 455 if(BUILD_opencv_apps)
 456   add_subdirectory(apps)
 457 endif()
 458
 459 # examples
 460 if(BUILD_EXAMPLES OR BUILD_ANDROID_EXAMPLES OR INSTALL_PYTHON_EXAMPLES)
 461   add_subdirectory(samples)
 462 endif()
 463
 464 if(ANDROID)
 465   add_subdirectory(platforms/android/service)
 466 endif()
 467
 468 if(BUILD_ANDROID_PACKAGE)
 469   add_subdirectory(platforms/android/package)
 470 endif()
 471
 472 if (ANDROID)
 473   add_subdirectory(platforms/android/libinfo)
 474 endif()
 475
 476 # ----------------------------------------------------------------------------
 477 # Finalization: generate configuration-based files
 478 # ----------------------------------------------------------------------------
 479 ocv_track_build_dependencies()
 480
 481 # Generate platform-dependent and configuration-dependent headers
 482 include(cmake/OpenCVGenHeaders.cmake)
 483
 484 # Generate opencv.pc for pkg-config command
 485 include(cmake/OpenCVGenPkgconfig.cmake)
 486
 487 # Generate OpenCV.mk for ndk-build (Android build tool)
 488 include(cmake/OpenCVGenAndroidMK.cmake)
 489
 490 # Generate OpenCVСonfig.cmake and OpenCVConfig-version.cmake for cmake projects
 491 include(cmake/OpenCVGenConfig.cmake)
 492
 493 # Generate Info.plist for the IOS framework
 494 include(cmake/OpenCVGenInfoPlist.cmake)
 495
 496 # ----------------------------------------------------------------------------
 497 # Summary:
 498 # ----------------------------------------------------------------------------
 499 status("")
 500 status("General configuration for OpenCV ${OPENCV_VERSION} =====================================")
 501 if(OPENCV_VCSVERSION)
 502   status("  Version control:" ${OPENCV_VCSVERSION})
 503 endif()
 504
 505 # ========================== build platform ==========================
 506 status("")
 507 status("  Platform:")
 508 status("    Host:"             ${CMAKE_HOST_SYSTEM_NAME} ${CMAKE_HOST_SYSTEM_VERSION} ${CMAKE_HOST_SYSTEM_PROCESSOR})
 509 if(CMAKE_CROSSCOMPILING)
 510   status("    Target:"         ${CMAKE_SYSTEM_NAME} ${CMAKE_SYSTEM_VERSION} ${CMAKE_SYSTEM_PROCESSOR})
 511 endif()
 512 status("    CMake:"            ${CMAKE_VERSION})
 513 status("    CMake generator:"  ${CMAKE_GENERATOR})
 514 status("    CMake build tool:" ${CMAKE_BUILD_TOOL})
 515 if(MSVC)
 516   status("    MSVC:"           ${MSVC_VERSION})
 517 endif()
 518 if(CMAKE_GENERATOR MATCHES Xcode)
 519   status("    Xcode:"          ${XCODE_VERSION})
 520 endif()
 521 if(NOT CMAKE_GENERATOR MATCHES "Xcode|Visual Studio")
 522   status("    Configuration:"  ${CMAKE_BUILD_TYPE})
 523 endif()
 524
 525 # ========================== C/C++ options ==========================
 526 if(CMAKE_CXX_COMPILER_VERSION)
 527   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CXX_COMPILER_VERSION})")
 528 elseif(CMAKE_COMPILER_IS_CLANGCXX)
 529   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_CLANG_REGEX_VERSION})")
 530 elseif(CMAKE_COMPILER_IS_GNUCXX)
 531   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1} (ver ${CMAKE_GCC_REGEX_VERSION})")
 532 else()
 533   set(OPENCV_COMPILER_STR "${CMAKE_CXX_COMPILER} ${CMAKE_CXX_COMPILER_ARG1}")
 534 endif()
 535 string(STRIP "${OPENCV_COMPILER_STR}" OPENCV_COMPILER_STR)
 536
 537 status("")
 538 status("  C/C++:")
 539 status("    Built as dynamic libs?:" BUILD_SHARED_LIBS THEN YES ELSE NO)
 540 status("    C++ Compiler:"           ${OPENCV_COMPILER_STR})
 541 status("    C++ flags (Release):"    ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_RELEASE})
 542 status("    C++ flags (Debug):"      ${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_DEBUG})
 543 status("    C Compiler:"             ${CMAKE_C_COMPILER} ${CMAKE_C_COMPILER_ARG1})
 544 status("    C flags (Release):"      ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_RELEASE})
 545 status("    C flags (Debug):"        ${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_DEBUG})
 546 if(WIN32)
 547   status("    Linker flags (Release):" ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_RELEASE})
 548   status("    Linker flags (Debug):"   ${CMAKE_EXE_LINKER_FLAGS} ${CMAKE_EXE_LINKER_FLAGS_DEBUG})
 549 else()
 550   status("    Linker flags (Release):" ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_RELEASE})
 551   status("    Linker flags (Debug):"   ${CMAKE_SHARED_LINKER_FLAGS} ${CMAKE_SHARED_LINKER_FLAGS_DEBUG})
 552 endif()
 553 status("    Precompiled headers:"     PCHSupport_FOUND AND ENABLE_PRECOMPILED_HEADERS THEN YES ELSE NO)
 554
 555 # ========================== OpenCV modules ==========================
 556 status("")
 557 status("  OpenCV modules:")
 558 string(REPLACE "opencv_" "" OPENCV_MODULES_BUILD_ST          "${OPENCV_MODULES_BUILD}")
 559 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_USER_ST  "${OPENCV_MODULES_DISABLED_USER}")
 560 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_FORCE_ST "${OPENCV_MODULES_DISABLED_FORCE}")
 561 set(OPENCV_MODULES_DISABLED_AUTO_ST "")
 562 foreach(m ${OPENCV_MODULES_DISABLED_AUTO})
 563   set(__mdeps "")
 564   foreach(d ${OPENCV_MODULE_${m}_DEPS})
 565     if(d MATCHES "^opencv_" AND NOT HAVE_${d})
 566       list(APPEND __mdeps ${d})
 567     endif()
 568   endforeach()
 569   if(__mdeps)
 570     list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}(deps: ${__mdeps})")
 571   else()
 572     list(APPEND OPENCV_MODULES_DISABLED_AUTO_ST "${m}")
 573   endif()
 574 endforeach()
 575 string(REPLACE "opencv_" "" OPENCV_MODULES_DISABLED_AUTO_ST  "${OPENCV_MODULES_DISABLED_AUTO_ST}")
 576
 577 status("    To be built:"            OPENCV_MODULES_BUILD          THEN ${OPENCV_MODULES_BUILD_ST}          ELSE "-")
 578 status("    Disabled:"               OPENCV_MODULES_DISABLED_USER  THEN ${OPENCV_MODULES_DISABLED_USER_ST}  ELSE "-")
 579 status("    Disabled by dependency:" OPENCV_MODULES_DISABLED_AUTO  THEN ${OPENCV_MODULES_DISABLED_AUTO_ST}  ELSE "-")
 580 status("    Unavailable:"            OPENCV_MODULES_DISABLED_FORCE THEN ${OPENCV_MODULES_DISABLED_FORCE_ST} ELSE "-")
 581
 582 # ========================== Android details ==========================
 583 if(ANDROID)
 584   status("")
 585   status("  Android: ")
 586   status("    Android ABI:" ${ANDROID_ABI})
 587   status("    STL type:" ${ANDROID_STL})
 588   status("    Native API level:" android-${ANDROID_NATIVE_API_LEVEL})
 589   android_get_compatible_target(android_sdk_target_status ${ANDROID_NATIVE_API_LEVEL} ${ANDROID_SDK_TARGET} 11)
 590   status("    SDK target:" "${android_sdk_target_status}")
 591   if(BUILD_WITH_ANDROID_NDK)
 592     status("    Android NDK:" "${ANDROID_NDK} (toolchain: ${ANDROID_TOOLCHAIN_NAME})")
 593   elseif(BUILD_WITH_STANDALONE_TOOLCHAIN)
 594     status("    Android toolchain:" "${ANDROID_STANDALONE_TOOLCHAIN}")
 595   endif()
 596   status("    android tool:"  ANDROID_EXECUTABLE  THEN "${ANDROID_EXECUTABLE} (${ANDROID_TOOLS_Pkg_Desc})" ELSE NO)
 597   status("    Google Play package:" BUILD_ANDROID_PACKAGE                                         THEN YES ELSE NO)
 598   status("    Android examples:"    BUILD_ANDROID_EXAMPLES AND CAN_BUILD_ANDROID_PROJECTS         THEN YES ELSE NO)
 599 endif()
 600
 601 # ================== Windows RT features ==================
 602 if(WIN32)
 603 status("")
 604     status("  Windows RT support:" HAVE_WINRT THEN YES ELSE NO)
 605     if (ENABLE_WINRT_MODE)
 606       status("    Windows SDK v8.0:" ${WINDOWS_SDK_PATH})
 607       status("    Visual Studio 2012:" ${VISUAL_STUDIO_PATH})
 608     endif()
 609 endif(WIN32)
 610
 611 # ========================== GUI ==========================
 612 status("")
 613 status("  GUI: ")
 614
 615 if(HAVE_QT5)
 616   status("    QT 5.x:"            HAVE_QT        THEN "YES (ver ${Qt5Core_VERSION_STRING})" ELSE NO)
 617   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${Qt5OpenGL_LIBRARIES} ${Qt5OpenGL_VERSION_STRING})" ELSE NO)
 618 elseif(HAVE_QT)
 619   status("    QT 4.x:"            HAVE_QT        THEN "YES (ver ${QT_VERSION_MAJOR}.${QT_VERSION_MINOR}.${QT_VERSION_PATCH} ${QT_EDITION})" ELSE NO)
 620   status("    QT OpenGL support:" HAVE_QT_OPENGL THEN "YES (${QT_QTOPENGL_LIBRARY})" ELSE NO)
 621 else()
 622   if(DEFINED WITH_QT)
 623     status("    QT:" NO)
 624   endif()
 625   if(DEFINED WITH_WIN32UI)
 626     status("    Win32 UI:" HAVE_WIN32UI THEN YES ELSE NO)
 627   else()
 628     if(APPLE)
 629       if(WITH_CARBON)
 630         status("    Carbon:" YES)
 631       else()
 632         status("    Cocoa:"  YES)
 633       endif()
 634     else()
 635       status("    GTK+ 2.x:" HAVE_GTK      THEN "YES (ver ${ALIASOF_gtk+-2.0_VERSION})"     ELSE NO)
 636       status("    GThread :" HAVE_GTHREAD  THEN "YES (ver ${ALIASOF_gthread-2.0_VERSION})"  ELSE NO)
 637       status("    GtkGlExt:" HAVE_GTKGLEXT THEN "YES (ver ${ALIASOF_gtkglext-1.0_VERSION})" ELSE NO)
 638     endif()
 639   endif()
 640 endif()
 641
 642 status("    OpenGL support:" HAVE_OPENGL THEN "YES (${OPENGL_LIBRARIES})" ELSE NO)
 643
 644 # ========================== MEDIA IO ==========================
 645 status("")
 646 status("  Media I/O: ")
 647 status("    ZLib:"         BUILD_ZLIB    THEN "build (ver ${ZLIB_VERSION_STRING})"               ELSE "${ZLIB_LIBRARIES} (ver ${ZLIB_VERSION_STRING})")
 648
 649 if(WITH_JPEG)
 650   status("    JPEG:"       JPEG_FOUND    THEN "${JPEG_LIBRARY} (ver ${JPEG_LIB_VERSION})"        ELSE "build (ver ${JPEG_LIB_VERSION})")
 651 else()
 652   status("    JPEG:"       "NO")
 653 endif()
 654
 655 if(WITH_WEBP)
 656   status("    WEBP:"       WEBP_FOUND    THEN "${WEBP_LIBRARY} (ver ${WEBP_VERSION})"        ELSE "build (ver ${WEBP_VERSION})")
 657 else()
 658   status("    WEBP:"       "NO")
 659 endif()
 660
 661 if(WITH_PNG)
 662   status("    PNG:"        PNG_FOUND     THEN "${PNG_LIBRARY} (ver ${PNG_VERSION})"              ELSE "build (ver ${PNG_VERSION})")
 663 else()
 664   status("    PNG:"        "NO")
 665 endif()
 666 if(WITH_TIFF)
 667   if(TIFF_VERSION_STRING AND TIFF_FOUND)
 668     status("    TIFF:"     "${TIFF_LIBRARY} (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 669   else()
 670     status("    TIFF:"     TIFF_FOUND    THEN "${TIFF_LIBRARY} (ver ${TIFF_VERSION})"            ELSE "build (ver ${TIFF_VERSION} - ${TIFF_VERSION_STRING})")
 671   endif()
 672 else()
 673   status("    TIFF:"       "NO")
 674 endif()
 675 if(WITH_JASPER)
 676   status("    JPEG 2000:"  JASPER_FOUND  THEN "${JASPER_LIBRARY} (ver ${JASPER_VERSION_STRING})" ELSE "build (ver ${JASPER_VERSION_STRING})")
 677 else()
 678   status("    JPEG 2000:"  "NO")
 679 endif()
 680 if(WITH_OPENEXR)
 681   status("    OpenEXR:"  OPENEXR_FOUND  THEN "${OPENEXR_LIBRARIES} (ver ${OPENEXR_VERSION})" ELSE "build (ver ${OPENEXR_VERSION})")
 682 else()
 683   status("    OpenEXR:"  "NO")
 684 endif()
 685
 686 # ========================== VIDEO IO ==========================
 687 status("")
 688 status("  Video I/O:")
 689
 690 if (DEFINED WITH_VFW)
 691   status("    Video for Windows:" HAVE_VFW         THEN YES                                        ELSE NO)
 692 endif(DEFINED WITH_VFW)
 693
 694 if(DEFINED WITH_1394)
 695   status("    DC1394 1.x:"     HAVE_DC1394         THEN "YES (ver ${ALIASOF_libdc1394_VERSION})"   ELSE NO)
 696   status("    DC1394 2.x:"     HAVE_DC1394_2       THEN "YES (ver ${ALIASOF_libdc1394-2_VERSION})" ELSE NO)
 697 endif(DEFINED WITH_1394)
 698
 699 if(ANDROID)
 700   if(HAVE_opencv_androidcamera)
 701     status("    AndroidNativeCamera:" BUILD_ANDROID_CAMERA_WRAPPER
 702                                                    THEN "YES, build for Android${ANDROID_VERSION}" ELSE "YES, use prebuilt libraries")
 703   else()
 704     status("    AndroidNativeCamera:" "NO (native camera requires Android API level 8 or higher)")
 705   endif()
 706 endif()
 707
 708 if(DEFINED WITH_AVFOUNDATION)
 709   status("    AVFoundation:"   WITH_AVFOUNDATION   THEN YES                                        ELSE NO)
 710 endif(DEFINED WITH_AVFOUNDATION)
 711
 712 if(DEFINED WITH_FFMPEG)
 713   if(WIN32)
 714     status("    FFMPEG:"       WITH_FFMPEG         THEN "YES (prebuilt binaries)"                  ELSE NO)
 715   else()
 716     status("    FFMPEG:"       HAVE_FFMPEG         THEN YES ELSE NO)
 717   endif()
 718   status("      codec:"        HAVE_FFMPEG_CODEC   THEN "YES (ver ${ALIASOF_libavcodec_VERSION})"  ELSE NO)
 719   status("      format:"       HAVE_FFMPEG_FORMAT  THEN "YES (ver ${ALIASOF_libavformat_VERSION})" ELSE NO)
 720   status("      util:"         HAVE_FFMPEG_UTIL    THEN "YES (ver ${ALIASOF_libavutil_VERSION})"   ELSE NO)
 721   status("      swscale:"      HAVE_FFMPEG_SWSCALE THEN "YES (ver ${ALIASOF_libswscale_VERSION})"  ELSE NO)
 722   status("      gentoo-style:" HAVE_GENTOO_FFMPEG  THEN YES                                        ELSE NO)
 723 endif(DEFINED WITH_FFMPEG)
 724
 725 if(DEFINED WITH_GSTREAMER)
 726   status("    GStreamer:"      HAVE_GSTREAMER      THEN ""                                         ELSE NO)
 727   if(HAVE_GSTREAMER)
 728     status("      base:"       "YES (ver ${GSTREAMER_BASE_VERSION})")
 729     status("      video:"      "YES (ver ${GSTREAMER_VIDEO_VERSION})")
 730     status("      app:"        "YES (ver ${GSTREAMER_APP_VERSION})")
 731     status("      riff:"       "YES (ver ${GSTREAMER_RIFF_VERSION})")
 732     status("      pbutils:"    "YES (ver ${GSTREAMER_PBUTILS_VERSION})")
 733   endif(HAVE_GSTREAMER)
 734 endif(DEFINED WITH_GSTREAMER)
 735
 736 if(DEFINED WITH_OPENNI)
 737   status("    OpenNI:"         HAVE_OPENNI         THEN "YES (ver ${OPENNI_VERSION_STRING}, build ${OPENNI_VERSION_BUILD})"
 738                                                                                                    ELSE NO)
 739   status("    OpenNI PrimeSensor Modules:" HAVE_OPENNI_PRIME_SENSOR_MODULE
 740                                                    THEN "YES (${OPENNI_PRIME_SENSOR_MODULE})"      ELSE NO)
 741 endif(DEFINED WITH_OPENNI)
 742
 743 if(DEFINED WITH_PVAPI)
 744   status("    PvAPI:"          HAVE_PVAPI          THEN YES                                        ELSE NO)
 745 endif(DEFINED WITH_PVAPI)
 746
 747 if(DEFINED WITH_GIGEAPI)
 748   status("    GigEVisionSDK:"  HAVE_GIGE_API       THEN YES                                        ELSE NO)
 749 endif(DEFINED WITH_GIGEAPI)
 750
 751 if(DEFINED WITH_QUICKTIME)
 752   status("    QuickTime:"      HAVE_QUICKTIME      THEN YES                                        ELSE NO)
 753   status("    QTKit:"          HAVE_QTKIT          THEN YES                                        ELSE NO)
 754 endif(DEFINED WITH_QUICKTIME)
 755
 756 if(DEFINED WITH_UNICAP)
 757   status("    UniCap:"         HAVE_UNICAP         THEN "YES (ver ${ALIASOF_libunicap_VERSION})"   ELSE NO)
 758   status("    UniCap ucil:"    HAVE_UNICAP_UCIL    THEN "YES (ver ${ALIASOF_libucil_VERSION})"     ELSE NO)
 759 endif(DEFINED WITH_UNICAP)
 760
 761 if(DEFINED WITH_V4L)
 762   if(HAVE_CAMV4L)
 763     set(HAVE_CAMV4L_STR "YES")
 764   else()
 765     set(HAVE_CAMV4L_STR "NO")
 766   endif()
 767   if(HAVE_CAMV4L2)
 768     set(HAVE_CAMV4L2_STR "YES")
 769   elseif(HAVE_VIDEOIO)
 770     set(HAVE_CAMV4L2_STR "YES(videoio)")
 771   else()
 772     set(HAVE_CAMV4L2_STR "NO")
 773   endif()
 774   status("    V4L/V4L2:"       HAVE_LIBV4L         THEN "Using libv4l (ver ${ALIASOF_libv4l1_VERSION})"
 775                                                    ELSE "${HAVE_CAMV4L_STR}/${HAVE_CAMV4L2_STR}")
 776 endif(DEFINED WITH_V4L)
 777
 778 if(DEFINED WITH_DSHOW)
 779   status("    DirectShow:"     HAVE_DSHOW     THEN YES                                        ELSE NO)
 780 endif(DEFINED WITH_DSHOW)
 781
 782 if(DEFINED WITH_MSMF)
 783   status("    Media Foundation:" HAVE_MSMF    THEN YES                                        ELSE NO)
 784 endif(DEFINED WITH_MSMF)
 785
 786 if(DEFINED WITH_XIMEA)
 787   status("    XIMEA:"          HAVE_XIMEA          THEN YES                                        ELSE NO)
 788 endif(DEFINED WITH_XIMEA)
 789
 790 if(DEFINED WITH_XINE)
 791   status("    Xine:"           HAVE_XINE           THEN "YES (ver ${ALIASOF_libxine_VERSION})"     ELSE NO)
 792 endif(DEFINED WITH_XINE)
 793
 794 # ========================== Other third-party libraries ==========================
 795 status("")
 796 status("  Other third-party libraries:")
 797
 798 if(WITH_IPP AND IPP_FOUND)
 799   status("    Use IPP:" "${IPP_LATEST_VERSION_STR} [${IPP_LATEST_VERSION_MAJOR}.${IPP_LATEST_VERSION_MINOR}.${IPP_LATEST_VERSION_BUILD}]")
 800   status("         at:" "${IPP_ROOT_DIR}")
 801 else()
 802   status("    Use IPP:"   WITH_IPP AND NOT IPP_FOUND THEN "IPP not found" ELSE NO)
 803 endif()
 804
 805 status("    Use Eigen:"      HAVE_EIGEN       THEN "YES (ver ${EIGEN_WORLD_VERSION}.${EIGEN_MAJOR_VERSION}.${EIGEN_MINOR_VERSION})" ELSE NO)
 806 status("    Use TBB:"        HAVE_TBB         THEN "YES (ver ${TBB_VERSION_MAJOR}.${TBB_VERSION_MINOR} interface ${TBB_INTERFACE_VERSION})" ELSE NO)
 807 status("    Use OpenMP:"     HAVE_OPENMP      THEN YES ELSE NO)
 808 status("    Use GCD"         HAVE_GCD         THEN YES ELSE NO)
 809 status("    Use Concurrency" HAVE_CONCURRENCY THEN YES ELSE NO)
 810 status("    Use C=:"         HAVE_CSTRIPES    THEN YES ELSE NO)
 811 status("    Use Cuda:"       HAVE_CUDA        THEN "YES (ver ${CUDA_VERSION_STRING})" ELSE NO)
 812 status("    Use OpenCL:"     HAVE_OPENCL      THEN YES ELSE NO)
 813
 814 if(HAVE_CUDA)
 815   status("")
 816   status("  NVIDIA CUDA")
 817
 818   status("    Use CUFFT:"            HAVE_CUFFT   THEN YES ELSE NO)
 819   status("    Use CUBLAS:"           HAVE_CUBLAS  THEN YES ELSE NO)
 820   status("    USE NVCUVID:"          HAVE_NVCUVID THEN YES ELSE NO)
 821   status("    NVIDIA GPU arch:"      ${OPENCV_CUDA_ARCH_BIN})
 822   status("    NVIDIA PTX archs:"     ${OPENCV_CUDA_ARCH_PTX})
 823   status("    Use fast math:"        CUDA_FAST_MATH THEN YES ELSE NO)
 824 endif()
 825
 826 if(HAVE_OPENCL)
 827   status("")
 828   status("  OpenCL:")
 829   set(__opencl_ver "invalid")
 830   if(HAVE_OPENCL12)
 831     set(__opencl_ver "1.2")
 832   elseif(HAVE_OPENCL11)
 833     set(__opencl_ver "1.1")
 834   endif()
 835   status("    Version:"       ${__opencl_ver})
 836   if(OPENCL_INCLUDE_DIR)
 837     status("    Include path:"       ${OPENCL_INCLUDE_DIRS})
 838   endif()
 839   if(OPENCL_LIBRARIES)
 840     set(__libs "")
 841     foreach(l ${OPENCL_LIBRARIES})
 842       if(TARGET ${l})
 843         get_target_property(p ${l} LOCATION)
 844         if(p MATCHES NOTFOUND)
 845           list(APPEND __libs "${l}")
 846         else()
 847           list(APPEND __libs "${p}")
 848         endif()
 849       else()
 850         list(APPEND __libs "${l}")
 851       endif()
 852     endforeach()
 853     status("    libraries:"          ${__libs})
 854   endif()
 855   status("    Use AMDFFT:"           HAVE_CLAMDFFT  THEN YES ELSE NO)
 856   status("    Use AMDBLAS:"          HAVE_CLAMDBLAS THEN YES ELSE NO)
 857 endif()
 858
 859 # ========================== python ==========================
 860 status("")
 861 status("  Python:")
 862 status("    Interpreter:"     PYTHONINTERP_FOUND  THEN "${PYTHON_EXECUTABLE} (ver ${PYTHON_VERSION_STRING})"       ELSE NO)
 863 if(BUILD_opencv_python)
 864   if(PYTHONLIBS_VERSION_STRING)
 865     status("    Libraries:"   HAVE_opencv_python  THEN  "${PYTHON_LIBRARIES} (ver ${PYTHONLIBS_VERSION_STRING})"   ELSE NO)
 866   else()
 867     status("    Libraries:"   HAVE_opencv_python  THEN  "${PYTHON_LIBRARIES}"                                      ELSE NO)
 868   endif()
 869   status("    numpy:"         PYTHON_NUMPY_INCLUDE_DIRS THEN "${PYTHON_NUMPY_INCLUDE_DIRS} (ver ${PYTHON_NUMPY_VERSION})" ELSE "NO (Python wrappers can not be generated)")
 870   status("    packages path:" PYTHON_EXECUTABLE         THEN "${PYTHON_PACKAGES_PATH}"                                    ELSE "-")
 871 endif()
 872
 873 # ========================== java ==========================
 874 status("")
 875 status("  Java:")
 876 status("    ant:"           ANT_EXECUTABLE      THEN "${ANT_EXECUTABLE} (ver ${ANT_VERSION})"                    ELSE NO)
 877 if(NOT ANDROID)
 878   status("    JNI:"         JNI_INCLUDE_DIRS    THEN "${JNI_INCLUDE_DIRS}"                                       ELSE NO)
 879 endif()
 880 status("    Java tests:"    BUILD_TESTS AND (CAN_BUILD_ANDROID_PROJECTS OR HAVE_opencv_java)            THEN YES ELSE NO)
 881
 882 # ========================= matlab =========================
 883 status("")
 884 status("  Matlab:")
 885 status("    mex:"         MATLAB_MEX_SCRIPT  THEN  "${MATLAB_MEX_SCRIPT}"   ELSE NO)
 886 if (MATLAB_FOUND)
 887   status("    Compiler/generator:" MEX_WORKS    THEN  "Working"                ELSE "Not working (bindings will not be generated)")
 888 endif()
 889
 890 # ========================== documentation ==========================
 891 if(BUILD_DOCS)
 892   status("")
 893   status("  Documentation:")
 894   if(HAVE_SPHINX)
 895     status("    Build Documentation:" PDFLATEX_COMPILER      THEN YES ELSE "YES (only HTML and without math expressions)")
 896   else()
 897     status("    Build Documentation:" NO)
 898   endif()
 899   status("    Sphinx:"              HAVE_SPHINX              THEN "${SPHINX_BUILD} (ver ${SPHINX_VERSION})" ELSE NO)
 900   status("    PdfLaTeX compiler:"   PDFLATEX_COMPILER        THEN "${PDFLATEX_COMPILER}" ELSE NO)
 901   status("    PlantUML:"            PLANTUML                 THEN "${PLANTUML}" ELSE NO)
 902 endif()
 903
 904 # ========================== samples and tests ==========================
 905 status("")
 906 status("  Tests and samples:")
 907 status("    Tests:"             BUILD_TESTS AND HAVE_opencv_ts       THEN YES ELSE NO)
 908 status("    Performance tests:" BUILD_PERF_TESTS AND HAVE_opencv_ts  THEN YES ELSE NO)
 909 status("    C/C++ Examples:"    BUILD_EXAMPLES                       THEN YES ELSE NO)
 910
 911 # ========================== auxiliary ==========================
 912 status("")
 913 status("  Install path:" "${CMAKE_INSTALL_PREFIX}")
 914 status("")
 915 status("  cvconfig.h is in:" "${OPENCV_CONFIG_FILE_INCLUDE_DIR}")
 916 status("-----------------------------------------------------------------")
 917 status("")
 918
 919 ocv_finalize_status()
 920
 921 # ----------------------------------------------------------------------------
 922 # Warn in the case of in-source build
 923 # ----------------------------------------------------------------------------
 924 if("${CMAKE_CURRENT_SOURCE_DIR}" STREQUAL "${CMAKE_CURRENT_BINARY_DIR}")
 925   message(WARNING "The source directory is the same as binary directory. \"make clean\" may damage the source tree")
 926 endif()