CMakeLists.txt

   1 #=============================================================================
   2 # CMake - Cross Platform Makefile Generator
   3 # Copyright 2000-2011 Kitware, Inc., Insight Software Consortium
   4 #
   5 # Distributed under the OSI-approved BSD License (the "License");
   6 # see accompanying file Copyright.txt for details.
   7 #
   8 # This software is distributed WITHOUT ANY WARRANTY; without even the
   9 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
  10 # See the License for more information.
  11 #=============================================================================
  12 CMAKE_MINIMUM_REQUIRED(VERSION 2.6.3 FATAL_ERROR)
  13 SET(CMAKE_LEGACY_CYGWIN_WIN32 0) # Remove when CMake >= 2.8.4 is required
  14 PROJECT(CMake)
  15
  16 IF(CMAKE_BOOTSTRAP)
  17   # Running from bootstrap script.  Set local variable and remove from cache.
  18   SET(CMAKE_BOOTSTRAP 1)
  19   UNSET(CMAKE_BOOTSTRAP CACHE)
  20 ENDIF()
  21
  22 SET(CMake_BIN_DIR ${CMake_BINARY_DIR}/bin)
  23
  24 IF("${CMake_SOURCE_DIR}" STREQUAL "${CMAKE_SOURCE_DIR}")
  25   # Disallow architecture-specific try_run.  It may not run on the host.
  26   MACRO(TRY_RUN)
  27     IF(CMAKE_TRY_COMPILE_OSX_ARCHITECTURES)
  28       MESSAGE(FATAL_ERROR "TRY_RUN not allowed with CMAKE_TRY_COMPILE_OSX_ARCHITECTURES=[${CMAKE_TRY_COMPILE_OSX_ARCHITECTURES}]")
  29     ELSE()
  30       _TRY_RUN(${ARGV})
  31     ENDIF()
  32   ENDMACRO()
  33 ENDIF()
  34
  35 #-----------------------------------------------------------------------
  36 # a macro to deal with system libraries, implemented as a macro
  37 # simply to improve readability of the main script
  38 #-----------------------------------------------------------------------
  39 MACRO(CMAKE_HANDLE_SYSTEM_LIBRARIES)
  40   # Options have dependencies.
  41   INCLUDE(CMakeDependentOption)
  42
  43   # Optionally use system xmlrpc.  We no longer build or use it by default.
  44   OPTION(CTEST_USE_XMLRPC "Enable xmlrpc submission method in CTest." OFF)
  45   MARK_AS_ADVANCED(CTEST_USE_XMLRPC)
  46
  47   # Allow the user to enable/disable all system utility library options by
  48   # defining CMAKE_USE_SYSTEM_LIBRARIES or CMAKE_USE_SYSTEM_LIBRARY_${util}.
  49   SET(UTILITIES BZIP2 CURL EXPAT LIBARCHIVE ZLIB)
  50   FOREACH(util ${UTILITIES})
  51     IF(NOT DEFINED CMAKE_USE_SYSTEM_LIBRARY_${util}
  52         AND DEFINED CMAKE_USE_SYSTEM_LIBRARIES)
  53       SET(CMAKE_USE_SYSTEM_LIBRARY_${util} "${CMAKE_USE_SYSTEM_LIBRARIES}")
  54     ENDIF()
  55     IF(DEFINED CMAKE_USE_SYSTEM_LIBRARY_${util})
  56       IF(CMAKE_USE_SYSTEM_LIBRARY_${util})
  57         SET(CMAKE_USE_SYSTEM_LIBRARY_${util} ON)
  58       ELSE()
  59         SET(CMAKE_USE_SYSTEM_LIBRARY_${util} OFF)
  60       ENDIF()
  61       IF(CMAKE_BOOTSTRAP)
  62         UNSET(CMAKE_USE_SYSTEM_LIBRARY_${util} CACHE)
  63       ENDIF()
  64       STRING(TOLOWER "${util}" lutil)
  65       SET(CMAKE_USE_SYSTEM_${util} "${CMAKE_USE_SYSTEM_LIBRARY_${util}}"
  66         CACHE BOOL "Use system-installed ${lutil}" FORCE)
  67     ELSE()
  68       SET(CMAKE_USE_SYSTEM_LIBRARY_${util} OFF)
  69     ENDIF()
  70   ENDFOREACH(util)
  71   IF(CMAKE_BOOTSTRAP)
  72     UNSET(CMAKE_USE_SYSTEM_LIBRARIES CACHE)
  73   ENDIF()
  74
  75   # Optionally use system utility libraries.
  76   OPTION(CMAKE_USE_SYSTEM_LIBARCHIVE "Use system-installed libarchive" "${CMAKE_USE_SYSTEM_LIBRARY_LIBARCHIVE}")
  77   CMAKE_DEPENDENT_OPTION(CMAKE_USE_SYSTEM_CURL "Use system-installed curl"
  78     "${CMAKE_USE_SYSTEM_LIBRARY_CURL}" "NOT CTEST_USE_XMLRPC" ON)
  79   CMAKE_DEPENDENT_OPTION(CMAKE_USE_SYSTEM_EXPAT "Use system-installed expat"
  80     "${CMAKE_USE_SYSTEM_LIBRARY_EXPAT}" "NOT CTEST_USE_XMLRPC" ON)
  81   CMAKE_DEPENDENT_OPTION(CMAKE_USE_SYSTEM_ZLIB "Use system-installed zlib"
  82     "${CMAKE_USE_SYSTEM_LIBRARY_ZLIB}" "NOT CMAKE_USE_SYSTEM_LIBARCHIVE;NOT CMAKE_USE_SYSTEM_CURL" ON)
  83   CMAKE_DEPENDENT_OPTION(CMAKE_USE_SYSTEM_BZIP2 "Use system-installed bzip2"
  84     "${CMAKE_USE_SYSTEM_LIBRARY_BZIP2}" "NOT CMAKE_USE_SYSTEM_LIBARCHIVE" ON)
  85
  86   # Mention to the user what system libraries are being used.
  87   FOREACH(util ${UTILITIES})
  88     IF(CMAKE_USE_SYSTEM_${util})
  89       MESSAGE(STATUS "Using system-installed ${util}")
  90     ENDIF(CMAKE_USE_SYSTEM_${util})
  91   ENDFOREACH(util)
  92
  93   # Inform utility library header wrappers whether to use system versions.
  94   CONFIGURE_FILE(${CMake_SOURCE_DIR}/Utilities/cmThirdParty.h.in
  95     ${CMake_BINARY_DIR}/Utilities/cmThirdParty.h
  96     @ONLY)
  97
  98 ENDMACRO(CMAKE_HANDLE_SYSTEM_LIBRARIES)
  99
 100
 101
 102
 103 SET(CMAKE_BUILD_ON_VISUAL_STUDIO 0)
 104 IF(WIN32 AND NOT UNIX AND NOT BORLAND AND NOT MINGW )
 105   SET(CMAKE_BUILD_ON_VISUAL_STUDIO 1)
 106 ENDIF(WIN32 AND NOT UNIX AND NOT BORLAND AND NOT MINGW )
 107
 108
 109 #-----------------------------------------------------------------------
 110 # a macro to determine the generator and ctest executable to use
 111 # for testing. Simply to improve readability of the main script.
 112 #-----------------------------------------------------------------------
 113 MACRO(CMAKE_SETUP_TESTING)
 114   IF (NOT DART_ROOT)
 115     SET(MAKEPROGRAM ${CMAKE_MAKE_PROGRAM})
 116   ENDIF (NOT DART_ROOT)
 117
 118   IF(BUILD_TESTING)
 119     SET(CMAKE_TEST_GENERATOR "" CACHE STRING
 120       "Generator used when running tests")
 121     SET(CMAKE_TEST_MAKEPROGRAM "" CACHE FILEPATH
 122       "Generator used when running tests")
 123     IF(NOT CMAKE_TEST_GENERATOR)
 124       SET(CMAKE_TEST_GENERATOR "${CMAKE_GENERATOR}")
 125       SET(CMAKE_TEST_MAKEPROGRAM "${MAKEPROGRAM}")
 126     ELSE(NOT CMAKE_TEST_GENERATOR)
 127       SET(CMAKE_TEST_DIFFERENT_GENERATOR TRUE)
 128     ENDIF(NOT CMAKE_TEST_GENERATOR)
 129
 130     # Are we testing with the MSVC compiler?
 131     SET(CMAKE_TEST_MSVC 0)
 132     IF(MSVC AND NOT CMAKE_TEST_DIFFERENT_GENERATOR)
 133       SET(CMAKE_TEST_MSVC 1)
 134     ELSE(MSVC AND NOT CMAKE_TEST_DIFFERENT_GENERATOR)
 135       IF("${CMAKE_TEST_GENERATOR}" MATCHES "NMake" OR
 136           "${CMAKE_TEST_GENERATOR}" MATCHES "Visual Studio")
 137         SET(CMAKE_TEST_MSVC 1)
 138       ENDIF("${CMAKE_TEST_GENERATOR}" MATCHES "NMake" OR
 139         "${CMAKE_TEST_GENERATOR}" MATCHES "Visual Studio")
 140     ENDIF(MSVC AND NOT CMAKE_TEST_DIFFERENT_GENERATOR)
 141
 142     SET(CMAKE_TEST_SYSTEM_LIBRARIES 0)
 143     FOREACH(util CURL EXPAT XMLRPC ZLIB)
 144       IF(CMAKE_USE_SYSTEM_${util})
 145         SET(CMAKE_TEST_SYSTEM_LIBRARIES 1)
 146       ENDIF(CMAKE_USE_SYSTEM_${util})
 147     ENDFOREACH(util)
 148
 149     # This variable is set by cmake, however to
 150     # test cmake we want to make sure that
 151     # the ctest from this cmake is used for testing
 152     # and not the ctest from the cmake building and testing
 153     # cmake.
 154     SET(CMAKE_CTEST_COMMAND "${CMake_BIN_DIR}/ctest")
 155     SET(CMAKE_CMAKE_COMMAND "${CMake_BIN_DIR}/cmake")
 156     SET(CMAKE_CPACK_COMMAND "${CMake_BIN_DIR}/cpack")
 157   ENDIF(BUILD_TESTING)
 158
 159   # configure some files for testing
 160   CONFIGURE_FILE("${CMAKE_CURRENT_SOURCE_DIR}/Templates/CTestScript.cmake.in"
 161     "${CMAKE_CURRENT_BINARY_DIR}/CTestScript.cmake"
 162     @ONLY)
 163   CONFIGURE_FILE(${CMake_SOURCE_DIR}/Tests/.NoDartCoverage
 164     ${CMake_BINARY_DIR}/Tests/.NoDartCoverage)
 165   CONFIGURE_FILE(${CMake_SOURCE_DIR}/Tests/.NoDartCoverage
 166     ${CMake_BINARY_DIR}/Modules/.NoDartCoverage)
 167   CONFIGURE_FILE(${CMake_SOURCE_DIR}/CTestCustom.cmake.in
 168     ${CMake_BINARY_DIR}/CTestCustom.cmake @ONLY)
 169   CONFIGURE_FILE(${CMake_SOURCE_DIR}/CTestCustom.ctest.in
 170     ${CMake_BINARY_DIR}/CTestCustom.ctest @ONLY)
 171   IF(BUILD_TESTING AND DART_ROOT)
 172     CONFIGURE_FILE(${CMake_SOURCE_DIR}/CMakeLogo.gif
 173       ${CMake_BINARY_DIR}/Testing/HTML/TestingResults/Icons/Logo.gif COPYONLY)
 174   ENDIF(BUILD_TESTING AND DART_ROOT)
 175   MARK_AS_ADVANCED(DART_ROOT)
 176   MARK_AS_ADVANCED(CURL_TESTING)
 177 ENDMACRO(CMAKE_SETUP_TESTING)
 178
 179
 180 # Provide a way for Visual Studio Express users to turn OFF the new FOLDER
 181 # organization feature. Default to ON for non-Express users. Express users must
 182 # explicitly turn off this option to build CMake in the Express IDE...
 183 #
 184 OPTION(CMAKE_USE_FOLDERS "Enable folder grouping of projects in IDEs." ON)
 185 MARK_AS_ADVANCED(CMAKE_USE_FOLDERS)
 186
 187
 188 #-----------------------------------------------------------------------
 189 # a macro that only sets the FOLDER target property if it's
 190 # "appropriate"
 191 #-----------------------------------------------------------------------
 192 MACRO(CMAKE_SET_TARGET_FOLDER tgt folder)
 193   IF(CMAKE_USE_FOLDERS)
 194     SET_PROPERTY(GLOBAL PROPERTY USE_FOLDERS ON)
 195
 196     # Really, I just want this to be an "if(TARGET ${tgt})" ...
 197     # but I'm not sure that our min req'd., CMake 2.4.5 can handle
 198     # that... so I'm just activating this for now, with a version
 199     # compare, and only for MSVC builds.
 200     IF(MSVC)
 201       IF(NOT ${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} LESS 2.8)
 202         SET_PROPERTY(TARGET "${tgt}" PROPERTY FOLDER "${folder}")
 203       ENDIF()
 204     ENDIF()
 205   ELSE()
 206     SET_PROPERTY(GLOBAL PROPERTY USE_FOLDERS OFF)
 207   ENDIF()
 208 ENDMACRO(CMAKE_SET_TARGET_FOLDER)
 209
 210
 211 #-----------------------------------------------------------------------
 212 # a macro to build the utilities used by CMake
 213 # Simply to improve readability of the main script.
 214 #-----------------------------------------------------------------------
 215 MACRO (CMAKE_BUILD_UTILITIES)
 216   #---------------------------------------------------------------------
 217   # Create the kwsys library for CMake.
 218   SET(KWSYS_NAMESPACE cmsys)
 219   SET(KWSYS_USE_SystemTools 1)
 220   SET(KWSYS_USE_Directory 1)
 221   SET(KWSYS_USE_RegularExpression 1)
 222   SET(KWSYS_USE_Base64 1)
 223   SET(KWSYS_USE_MD5 1)
 224   SET(KWSYS_USE_Process 1)
 225   SET(KWSYS_USE_CommandLineArguments 1)
 226   SET(KWSYS_HEADER_ROOT ${CMake_BINARY_DIR}/Source)
 227   SET(KWSYS_INSTALL_DOC_DIR "${CMake_DOC_DEST}")
 228   ADD_SUBDIRECTORY(Source/kwsys)
 229   SET(kwsys_folder "Utilities/KWSys")
 230   CMAKE_SET_TARGET_FOLDER(${KWSYS_NAMESPACE} "${kwsys_folder}")
 231   CMAKE_SET_TARGET_FOLDER(${KWSYS_NAMESPACE}_c "${kwsys_folder}")
 232   CMAKE_SET_TARGET_FOLDER(${KWSYS_NAMESPACE}EncodeExecutable "${kwsys_folder}")
 233   CMAKE_SET_TARGET_FOLDER(${KWSYS_NAMESPACE}ProcessFwd9x "${kwsys_folder}")
 234   CMAKE_SET_TARGET_FOLDER(${KWSYS_NAMESPACE}TestDynload "${kwsys_folder}")
 235   CMAKE_SET_TARGET_FOLDER(${KWSYS_NAMESPACE}TestProcess "${kwsys_folder}")
 236   CMAKE_SET_TARGET_FOLDER(${KWSYS_NAMESPACE}TestsC "${kwsys_folder}")
 237   CMAKE_SET_TARGET_FOLDER(${KWSYS_NAMESPACE}TestsCxx "${kwsys_folder}")
 238   CMAKE_SET_TARGET_FOLDER(${KWSYS_NAMESPACE}TestSharedForward "${kwsys_folder}")
 239
 240   #---------------------------------------------------------------------
 241   # Setup third-party libraries.
 242   # Everything in the tree should be able to include files from the
 243   # Utilities directory.
 244   INCLUDE_DIRECTORIES(
 245     ${CMake_BINARY_DIR}/Utilities
 246     ${CMake_SOURCE_DIR}/Utilities
 247     )
 248
 249   # check for the use of system libraries versus builtin ones
 250   # (a macro defined in this file)
 251   CMAKE_HANDLE_SYSTEM_LIBRARIES()
 252
 253   #---------------------------------------------------------------------
 254   # Build zlib library for Curl, CMake, and CTest.
 255   SET(CMAKE_ZLIB_HEADER "cm_zlib.h")
 256   IF(CMAKE_USE_SYSTEM_ZLIB)
 257     FIND_PACKAGE(ZLIB)
 258     IF(NOT ZLIB_FOUND)
 259       MESSAGE(FATAL_ERROR
 260         "CMAKE_USE_SYSTEM_ZLIB is ON but a zlib is not found!")
 261     ENDIF(NOT ZLIB_FOUND)
 262     SET(CMAKE_ZLIB_INCLUDES ${ZLIB_INCLUDE_DIR})
 263     SET(CMAKE_ZLIB_LIBRARIES ${ZLIB_LIBRARIES})
 264   ELSE(CMAKE_USE_SYSTEM_ZLIB)
 265     SET(CMAKE_ZLIB_INCLUDES)
 266     SET(CMAKE_ZLIB_LIBRARIES cmzlib)
 267     ADD_SUBDIRECTORY(Utilities/cmzlib)
 268     CMAKE_SET_TARGET_FOLDER(cmzlib "Utilities/3rdParty")
 269   ENDIF(CMAKE_USE_SYSTEM_ZLIB)
 270
 271   #---------------------------------------------------------------------
 272   # Build Curl library for CTest.
 273   IF(CMAKE_USE_SYSTEM_CURL)
 274     FIND_PACKAGE(CURL)
 275     IF(NOT CURL_FOUND)
 276       MESSAGE(FATAL_ERROR
 277         "CMAKE_USE_SYSTEM_CURL is ON but a curl is not found!")
 278     ENDIF(NOT CURL_FOUND)
 279     SET(CMAKE_CURL_INCLUDES ${CURL_INCLUDE_DIRS})
 280     SET(CMAKE_CURL_LIBRARIES ${CURL_LIBRARIES})
 281   ELSE(CMAKE_USE_SYSTEM_CURL)
 282     SET(CURL_SPECIAL_ZLIB_H ${CMAKE_ZLIB_HEADER})
 283     SET(CURL_SPECIAL_LIBZ_INCLUDES ${CMAKE_ZLIB_INCLUDES})
 284     SET(CURL_SPECIAL_LIBZ ${CMAKE_ZLIB_LIBRARIES})
 285     OPTION(CMAKE_BUILD_CURL_SHARED "Should curl be built shared" FALSE)
 286     IF(NOT CMAKE_BUILD_CURL_SHARED)
 287       ADD_DEFINITIONS(-DCURL_STATICLIB)
 288     ENDIF(NOT CMAKE_BUILD_CURL_SHARED)
 289     SET(CMAKE_CURL_INCLUDES)
 290     SET(CMAKE_CURL_LIBRARIES cmcurl)
 291     IF(CMAKE_TESTS_CDASH_SERVER)
 292       SET(CMAKE_CURL_TEST_URL "${CMAKE_TESTS_CDASH_SERVER}/user.php")
 293     ENDIF(CMAKE_TESTS_CDASH_SERVER)
 294     ADD_SUBDIRECTORY(Utilities/cmcurl)
 295     CMAKE_SET_TARGET_FOLDER(cmcurl "Utilities/3rdParty")
 296     CMAKE_SET_TARGET_FOLDER(LIBCURL "Utilities/3rdParty")
 297   ENDIF(CMAKE_USE_SYSTEM_CURL)
 298
 299   #---------------------------------------------------------------------
 300   # Build Compress library for CTest.
 301   SET(CMAKE_COMPRESS_INCLUDES
 302     "${CMAKE_CURRENT_BINARY_DIR}/Utilities/cmcompress")
 303   SET(CMAKE_COMPRESS_LIBRARIES "cmcompress")
 304   ADD_SUBDIRECTORY(Utilities/cmcompress)
 305   CMAKE_SET_TARGET_FOLDER(cmcompress "Utilities/3rdParty")
 306   IF(CMAKE_USE_SYSTEM_BZIP2)
 307     FIND_PACKAGE(BZip2)
 308   ELSE()
 309     SET(BZIP2_INCLUDE_DIR
 310       "${CMAKE_CURRENT_SOURCE_DIR}/Utilities/cmbzip2")
 311     SET(BZIP2_LIBRARIES cmbzip2)
 312     ADD_SUBDIRECTORY(Utilities/cmbzip2)
 313     CMAKE_SET_TARGET_FOLDER(cmbzip2 "Utilities/3rdParty")
 314   ENDIF()
 315
 316   #---------------------------------------------------------------------
 317   # Build or use system libarchive for CMake and CTest.
 318   IF(CMAKE_USE_SYSTEM_LIBARCHIVE)
 319     IF(EXISTS ${CMAKE_ROOT}/Modules/FindLibArchive.cmake)
 320       FIND_PACKAGE(LibArchive)
 321     ELSE()
 322       CMAKE_MINIMUM_REQUIRED(VERSION 2.8.0 FATAL_ERROR)
 323       INCLUDE(${CMake_SOURCE_DIR}/Modules/FindLibArchive.cmake)
 324     ENDIF()
 325     IF(NOT LibArchive_FOUND)
 326       MESSAGE(FATAL_ERROR "CMAKE_USE_SYSTEM_LIBARCHIVE is ON but LibArchive is not found!")
 327     ENDIF()
 328     SET(CMAKE_TAR_INCLUDES ${LibArchive_INCLUDE_DIRS})
 329     SET(CMAKE_TAR_LIBRARIES ${LibArchive_LIBRARIES})
 330   ELSE(CMAKE_USE_SYSTEM_LIBARCHIVE)
 331     SET(HAVE_LIBZ 1)
 332     SET(HAVE_ZLIB_H 1)
 333     SET(ZLIB_INCLUDE_DIR ${CMAKE_ZLIB_INCLUDES})
 334     SET(ZLIB_LIBRARIES ${CMAKE_ZLIB_LIBRARIES})
 335     SET(ZLIB_LIBRARY ${CMAKE_ZLIB_LIBRARIES})
 336     SET(BUILD_ARCHIVE_WITHIN_CMAKE TRUE)
 337     ADD_DEFINITIONS(-DLIBARCHIVE_STATIC)
 338     ADD_SUBDIRECTORY(Utilities/cmlibarchive)
 339     CMAKE_SET_TARGET_FOLDER(cmlibarchive "Utilities/3rdParty")
 340     SET(CMAKE_TAR_LIBRARIES cmlibarchive ${BZIP2_LIBRARIES})
 341   ENDIF(CMAKE_USE_SYSTEM_LIBARCHIVE)
 342
 343   #---------------------------------------------------------------------
 344   # Build expat library for CMake and CTest.
 345   IF(CMAKE_USE_SYSTEM_EXPAT)
 346     FIND_PACKAGE(EXPAT)
 347     IF(NOT EXPAT_FOUND)
 348       MESSAGE(FATAL_ERROR
 349         "CMAKE_USE_SYSTEM_EXPAT is ON but a expat is not found!")
 350     ENDIF(NOT EXPAT_FOUND)
 351     SET(CMAKE_EXPAT_INCLUDES ${EXPAT_INCLUDE_DIRS})
 352     SET(CMAKE_EXPAT_LIBRARIES ${EXPAT_LIBRARIES})
 353   ELSE(CMAKE_USE_SYSTEM_EXPAT)
 354     SET(CMAKE_EXPAT_INCLUDES)
 355     SET(CMAKE_EXPAT_LIBRARIES cmexpat)
 356     ADD_SUBDIRECTORY(Utilities/cmexpat)
 357     CMAKE_SET_TARGET_FOLDER(cmexpat "Utilities/3rdParty")
 358   ENDIF(CMAKE_USE_SYSTEM_EXPAT)
 359
 360   #---------------------------------------------------------------------
 361   # Build XMLRPC library for CMake and CTest.
 362   IF(CTEST_USE_XMLRPC)
 363     FIND_PACKAGE(XMLRPC QUIET REQUIRED libwww-client)
 364     IF(NOT XMLRPC_FOUND)
 365       MESSAGE(FATAL_ERROR
 366         "CTEST_USE_XMLRPC is ON but xmlrpc is not found!")
 367     ENDIF(NOT XMLRPC_FOUND)
 368     SET(CMAKE_XMLRPC_INCLUDES ${XMLRPC_INCLUDE_DIRS})
 369     SET(CMAKE_XMLRPC_LIBRARIES ${XMLRPC_LIBRARIES})
 370   ENDIF(CTEST_USE_XMLRPC)
 371
 372   #---------------------------------------------------------------------
 373   # Use curses?
 374   IF (UNIX)
 375     # there is a bug in the Syllable libraries which makes linking ccmake fail, Alex
 376     IF(NOT "${CMAKE_SYSTEM_NAME}" MATCHES syllable)
 377       SET(CURSES_NEED_NCURSES TRUE)
 378       FIND_PACKAGE(Curses QUIET)
 379       IF (CURSES_LIBRARY)
 380         OPTION(BUILD_CursesDialog "Build the CMake Curses Dialog ccmake" ON)
 381       ELSE (CURSES_LIBRARY)
 382         MESSAGE("Curses libraries were not found. Curses GUI for CMake will not be built.")
 383         SET(BUILD_CursesDialog 0)
 384       ENDIF (CURSES_LIBRARY)
 385     ELSE(NOT "${CMAKE_SYSTEM_NAME}" MATCHES syllable)
 386       SET(BUILD_CursesDialog 0)
 387     ENDIF(NOT "${CMAKE_SYSTEM_NAME}" MATCHES syllable)
 388   ELSE (UNIX)
 389     SET(BUILD_CursesDialog 0)
 390   ENDIF (UNIX)
 391   IF(BUILD_CursesDialog)
 392     ADD_SUBDIRECTORY(Source/CursesDialog/form)
 393   ENDIF(BUILD_CursesDialog)
 394 ENDMACRO (CMAKE_BUILD_UTILITIES)
 395
 396 #-----------------------------------------------------------------------
 397 IF(CMAKE_CXX_PLATFORM_ID MATCHES "OpenBSD")
 398   EXECUTE_PROCESS(COMMAND ${CMAKE_CXX_COMPILER}
 399     ${CMAKE_CXX_COMPILER_ARG1} -dumpversion
 400     OUTPUT_VARIABLE _GXX_VERSION
 401   )
 402   STRING(REGEX REPLACE "([0-9])\\.([0-9])(\\.[0-9])?" "\\1\\2"
 403     _GXX_VERSION_SHORT ${_GXX_VERSION})
 404   IF(_GXX_VERSION_SHORT EQUAL 33)
 405     MESSAGE(FATAL_ERROR
 406       "GXX 3.3 on OpenBSD is known to cause CPack to Crash.\n"
 407       "Please use GXX 4.2 or greater to build CMake on OpenBSD\n"
 408       "${CMAKE_CXX_COMPILER} version is: ${_GXX_VERSION}")
 409   ENDIF()
 410 ENDIF()
 411
 412 #-----------------------------------------------------------------------
 413 # The main section of the CMakeLists file
 414 #
 415 #-----------------------------------------------------------------------
 416 # The CMake version number.
 417 SET(CMake_VERSION_MAJOR 2)
 418 SET(CMake_VERSION_MINOR 8)
 419 SET(CMake_VERSION_PATCH 5)
 420 SET(CMake_VERSION_TWEAK 0)
 421 #SET(CMake_VERSION_RC 3)
 422
 423 # Releases define a tweak level.
 424 IF(DEFINED CMake_VERSION_TWEAK)
 425   SET(CMake_VERSION_IS_RELEASE 1)
 426   SET(CMake_VERSION_SOURCE "")
 427 ELSE()
 428   SET(CMake_VERSION_IS_RELEASE 0)
 429
 430   # Use the date as the tweak level.
 431   INCLUDE(${CMake_SOURCE_DIR}/Source/kwsys/kwsysDateStamp.cmake)
 432   SET(CMake_VERSION_TWEAK
 433     "${KWSYS_DATE_STAMP_YEAR}${KWSYS_DATE_STAMP_MONTH}${KWSYS_DATE_STAMP_DAY}"
 434     )
 435
 436   INCLUDE(${CMake_SOURCE_DIR}/Source/CMakeVersionSource.cmake)
 437 ENDIF()
 438
 439 # Compute the full version string.
 440 SET(CMake_VERSION ${CMake_VERSION_MAJOR}.${CMake_VERSION_MINOR}.${CMake_VERSION_PATCH})
 441 IF(${CMake_VERSION_TWEAK} GREATER 0)
 442   SET(CMake_VERSION ${CMake_VERSION}.${CMake_VERSION_TWEAK})
 443 ENDIF()
 444 IF(CMake_VERSION_RC)
 445   SET(CMake_VERSION ${CMake_VERSION}-rc${CMake_VERSION_RC})
 446 ENDIF()
 447 IF(CMake_VERSION_SOURCE)
 448   SET(CMake_VERSION ${CMake_VERSION}-${CMake_VERSION_SOURCE})
 449 ENDIF()
 450
 451 # Include the standard Dart testing module
 452 ENABLE_TESTING()
 453 INCLUDE (${CMAKE_ROOT}/Modules/Dart.cmake)
 454
 455 # Set up test-time configuration.
 456 SET_DIRECTORY_PROPERTIES(PROPERTIES
 457   TEST_INCLUDE_FILE "${CMake_BINARY_DIR}/Tests/EnforceConfig.cmake")
 458
 459 # where to write the resulting executables and libraries
 460 SET(BUILD_SHARED_LIBS OFF)
 461 SET(EXECUTABLE_OUTPUT_PATH "" CACHE INTERNAL "No configurable exe dir.")
 462 SET(LIBRARY_OUTPUT_PATH "" CACHE INTERNAL
 463   "Where to put the libraries for CMake")
 464
 465 # The CMake executables usually do not need any rpath to run in the build or
 466 # install tree.
 467 SET(CMAKE_SKIP_RPATH ON CACHE INTERNAL "CMake does not need RPATHs.")
 468
 469 SET(CMAKE_DATA_DIR "/share/cmake-${CMake_VERSION_MAJOR}.${CMake_VERSION_MINOR}" CACHE STRING
 470   "Install location for data (relative to prefix).")
 471 SET(CMAKE_DOC_DIR "/doc/cmake-${CMake_VERSION_MAJOR}.${CMake_VERSION_MINOR}" CACHE STRING
 472   "Install location for documentation (relative to prefix).")
 473 SET(CMAKE_MAN_DIR "/man" CACHE STRING
 474   "Install location for man pages (relative to prefix).")
 475 MARK_AS_ADVANCED(CMAKE_DATA_DIR CMAKE_DOC_DIR CMAKE_MAN_DIR)
 476 IF(CYGWIN AND EXISTS "${CMAKE_ROOT}/Modules/CPack.cmake")
 477   # Force doc, data and man dirs to conform to cygwin layout.
 478   SET(CMAKE_DOC_DIR  "/share/doc/cmake-${CMake_VERSION}")
 479   SET(CMAKE_DATA_DIR "/share/cmake-${CMake_VERSION}")
 480   SET(CMAKE_MAN_DIR  "/share/man")
 481   # let the user know we just forced these values
 482   MESSAGE(STATUS "Setup for Cygwin packaging")
 483   MESSAGE(STATUS "Override cache CMAKE_DOC_DIR = ${CMAKE_DOC_DIR}")
 484   MESSAGE(STATUS "Override cache CMAKE_DATA_DIR = ${CMAKE_DATA_DIR}")
 485   MESSAGE(STATUS "Override cache CMAKE_MAN_DIR = ${CMAKE_MAN_DIR}")
 486 ENDIF()
 487 STRING(REGEX REPLACE "^/" "" CMake_DATA_DEST "${CMAKE_DATA_DIR}")
 488 STRING(REGEX REPLACE "^/" "" CMake_DOC_DEST "${CMAKE_DOC_DIR}")
 489
 490 IF(BUILD_TESTING)
 491   INCLUDE(${CMake_SOURCE_DIR}/Tests/CMakeInstall.cmake)
 492 ENDIF()
 493
 494 # include special compile flags for some compilers
 495 INCLUDE(CompileFlags.cmake)
 496
 497 # no clue why we are testing for this here
 498 INCLUDE(CheckSymbolExists)
 499 CHECK_SYMBOL_EXISTS(unsetenv "stdlib.h" HAVE_UNSETENV)
 500 CHECK_SYMBOL_EXISTS(environ "stdlib.h" HAVE_ENVIRON_NOT_REQUIRE_PROTOTYPE)
 501
 502 # CMAKE_TESTS_CDASH_SERVER: CDash server used by CMake/Tests.
 503 #
 504 # If not defined or "", this variable defaults to the server at
 505 # http://www.cdash.org/CDash.
 506 #
 507 # If set explicitly to "NOTFOUND", curl tests and ctest tests that use
 508 # the network are skipped.
 509 #
 510 # If set to something starting with "http://localhost/", the CDash is
 511 # expected to be an instance of CDash used for CDash testing, pointing
 512 # to a cdash4simpletest database. In these cases, the CDash dashboards
 513 # should be run first.
 514 #
 515 IF("x${CMAKE_TESTS_CDASH_SERVER}" STREQUAL "x")
 516   SET(CMAKE_TESTS_CDASH_SERVER "http://www.cdash.org/CDash")
 517 ENDIF("x${CMAKE_TESTS_CDASH_SERVER}" STREQUAL "x")
 518
 519 # build the utilities (a macro defined in this file)
 520 CMAKE_BUILD_UTILITIES()
 521
 522 # On NetBSD ncurses is required, since curses doesn't have the wsyncup()
 523 # function. ncurses is installed via pkgsrc, so the library is in /usr/pkg/lib,
 524 # which isn't in the default linker search path. So without RPATH ccmake
 525 # doesn't run and the build doesn't succeed since ccmake is executed for
 526 # generating the documentation.
 527 IF(BUILD_CursesDialog)
 528   GET_FILENAME_COMPONENT(_CURSES_DIR "${CURSES_LIBRARY}" PATH)
 529   SET(CURSES_NEED_RPATH FALSE)
 530   IF(NOT "${_CURSES_DIR}" STREQUAL "/lib" AND NOT "${_CURSES_DIR}" STREQUAL "/usr/lib" AND NOT "${_CURSES_DIR}" STREQUAL "/lib64" AND NOT "${_CURSES_DIR}" STREQUAL "/usr/lib64")
 531     SET(CURSES_NEED_RPATH TRUE)
 532   ENDIF(NOT "${_CURSES_DIR}" STREQUAL "/lib" AND NOT "${_CURSES_DIR}" STREQUAL "/usr/lib" AND NOT "${_CURSES_DIR}" STREQUAL "/lib64" AND NOT "${_CURSES_DIR}" STREQUAL "/usr/lib64")
 533 ENDIF(BUILD_CursesDialog)
 534
 535 IF(BUILD_QtDialog)
 536   IF(APPLE)
 537     SET(CMAKE_BUNDLE_NAME
 538       "CMake ${CMake_VERSION_MAJOR}.${CMake_VERSION_MINOR}-${CMake_VERSION_PATCH}")
 539     SET(CMAKE_BUNDLE_LOCATION "${CMAKE_INSTALL_PREFIX}")
 540     # make sure CMAKE_INSTALL_PREFIX ends in /
 541     STRING(LENGTH "${CMAKE_INSTALL_PREFIX}" LEN)
 542     MATH(EXPR LEN "${LEN} -1" )
 543     STRING(SUBSTRING "${CMAKE_INSTALL_PREFIX}" ${LEN} 1 ENDCH)
 544     IF(NOT "${ENDCH}" STREQUAL "/")
 545       SET(CMAKE_INSTALL_PREFIX "${CMAKE_INSTALL_PREFIX}/")
 546     ENDIF(NOT "${ENDCH}" STREQUAL "/")
 547     SET(CMAKE_INSTALL_PREFIX
 548       "${CMAKE_INSTALL_PREFIX}${CMAKE_BUNDLE_NAME}.app/Contents")
 549   ENDIF(APPLE)
 550
 551   SET(QT_NEED_RPATH FALSE)
 552   IF(NOT "${QT_LIBRARY_DIR}" STREQUAL "/lib" AND NOT "${QT_LIBRARY_DIR}" STREQUAL "/usr/lib" AND NOT "${QT_LIBRARY_DIR}" STREQUAL "/lib64" AND NOT "${QT_LIBRARY_DIR}" STREQUAL "/usr/lib64")
 553     SET(QT_NEED_RPATH TRUE)
 554   ENDIF(NOT "${QT_LIBRARY_DIR}" STREQUAL "/lib" AND NOT "${QT_LIBRARY_DIR}" STREQUAL "/usr/lib" AND NOT "${QT_LIBRARY_DIR}" STREQUAL "/lib64" AND NOT "${QT_LIBRARY_DIR}" STREQUAL "/usr/lib64")
 555 ENDIF(BUILD_QtDialog)
 556
 557
 558 # The same might be true on other systems for other libraries.
 559 # Then only enable RPATH if we have are building at least with cmake 2.4,
 560 # since this one has much better RPATH features than cmake 2.2.
 561 # The executables are then built with the RPATH for the libraries outside
 562 # the build tree, which is both the build and the install RPATH.
 563 IF (UNIX)
 564   IF(   CMAKE_USE_SYSTEM_CURL   OR  CMAKE_USE_SYSTEM_ZLIB
 565         OR  CMAKE_USE_SYSTEM_EXPAT  OR  CTEST_USE_XMLRPC  OR  CURSES_NEED_RPATH  OR  QT_NEED_RPATH)
 566     SET(CMAKE_SKIP_RPATH OFF CACHE INTERNAL "CMake built with RPATH.")
 567     SET(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
 568     SET(CMAKE_BUILD_WITH_INSTALL_RPATH TRUE)
 569   ENDIF(CMAKE_USE_SYSTEM_CURL   OR  CMAKE_USE_SYSTEM_ZLIB
 570         OR  CMAKE_USE_SYSTEM_EXPAT  OR  CTEST_USE_XMLRPC  OR  CURSES_NEED_RPATH  OR  QT_NEED_RPATH)
 571 ENDIF (UNIX)
 572
 573
 574 # add the uninstall support
 575 CONFIGURE_FILE(
 576   "${CMAKE_CURRENT_SOURCE_DIR}/cmake_uninstall.cmake.in"
 577   "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake"
 578   @ONLY)
 579 ADD_CUSTOM_TARGET(uninstall
 580   "${CMAKE_COMMAND}" -P "${CMAKE_CURRENT_BINARY_DIR}/cmake_uninstall.cmake")
 581
 582 INCLUDE (CMakeCPack.cmake)
 583
 584 # setup some Testing support (a macro defined in this file)
 585 CMAKE_SETUP_TESTING()
 586 CONFIGURE_FILE(
 587   "${CMAKE_CURRENT_SOURCE_DIR}/DartLocal.conf.in"
 588   "${CMAKE_CURRENT_BINARY_DIR}/DartLocal.conf"
 589   COPYONLY)
 590
 591 OPTION(CMAKE_STRICT
 592   "Perform strict testing to record property and variable access. Can be used to report any undefined properties or variables" OFF)
 593 MARK_AS_ADVANCED(CMAKE_STRICT)
 594
 595
 596 # build the remaining subdirectories
 597 ADD_SUBDIRECTORY(Source)
 598 ADD_SUBDIRECTORY(Utilities)
 599 ADD_SUBDIRECTORY(Tests)
 600
 601 CMAKE_SET_TARGET_FOLDER(CMakeLibTests "Tests")
 602 CMAKE_SET_TARGET_FOLDER(cmw9xcom "Utilities/Win9xCompat")
 603 CMAKE_SET_TARGET_FOLDER(documentation "Documentation")
 604
 605 # add a test
 606 ADD_TEST(SystemInformationNew "${CMAKE_CMAKE_COMMAND}"
 607   --system-information  -G "${CMAKE_TEST_GENERATOR}" )
 608
 609 # Install license file as it requires.
 610 INSTALL(FILES Copyright.txt DESTINATION ${CMake_DOC_DEST})
 611
 612 # Install script directories.
 613 INSTALL(
 614   DIRECTORY Modules Templates
 615   DESTINATION "${CMake_DATA_DEST}"
 616   FILE_PERMISSIONS OWNER_READ OWNER_WRITE GROUP_READ WORLD_READ
 617   DIRECTORY_PERMISSIONS OWNER_READ OWNER_EXECUTE OWNER_WRITE
 618                         GROUP_READ GROUP_EXECUTE
 619                         WORLD_READ WORLD_EXECUTE
 620   PATTERN "*.sh*" PERMISSIONS OWNER_READ OWNER_EXECUTE OWNER_WRITE
 621                               GROUP_READ GROUP_EXECUTE
 622                               WORLD_READ WORLD_EXECUTE
 623   PATTERN "CVS" EXCLUDE
 624   )
 625
 626 #-----------------------------------------------------------------------
 627 # End of the main section of the CMakeLists file
 628 #-----------------------------------------------------------------------
 629
 630 # As a special case when building CMake itself, CMake 2.8.0 and below
 631 # look up EXECUTABLE_OUTPUT_PATH in the top-level CMakeLists.txt file
 632 # to compute the location of the "cmake" executable.  We set it here
 633 # so that those CMake versions can find it.  We wait until after all
 634 # the add_subdirectory() calls to avoid affecting the subdirectories.
 635 SET(EXECUTABLE_OUTPUT_PATH ${CMake_BIN_DIR})