CMakeLists.txt

   1 # dEQP cmake file
   2
   3 # Module FindGit requires cmake >= 2.8.2
   4 cmake_minimum_required(VERSION 3.10.2)
   5
   6 find_package(Git)
   7 find_package(PythonInterp 3)
   8
   9 # dEQP Target.
  10 set(DEQP_TARGET "default" CACHE STRING "dEQP Target (default, android...)")
  11
  12 if (DEFINED DEQP_TARGET_TOOLCHAIN)
  13         # \note Toolchain must be included before project() command
  14         include(targets/${DEQP_TARGET}/${DEQP_TARGET_TOOLCHAIN}.cmake NO_POLICY_SCOPE)
  15 endif ()
  16
  17 project(dEQP-Core-${DEQP_TARGET})
  18
  19 include(framework/delibs/cmake/Defs.cmake NO_POLICY_SCOPE)
  20 include(framework/delibs/cmake/CFlags.cmake)
  21
  22 add_definitions(-DDE_ASSERT_FAILURE_CALLBACK)
  23
  24 # dEQP-specific configuration. Target file should override these.
  25 set(DEQP_TARGET_NAME            "UNKNOWN")              # Target name
  26
  27 set(DEQP_GLES2_LIBRARIES        )                               # GLESv2 libraries. If empty, run-time linking is used
  28 set(DEQP_GLES3_LIBRARIES        )                               # GLESv3 libraries. If empty, run-time linking is used
  29 set(DEQP_EGL_LIBRARIES          )                               # EGL libraries
  30
  31 # Legacy APIs that don't use run-time loading
  32 set(DEQP_SUPPORT_GLES1          OFF)                    # Is GLESv1 supported
  33 set(DEQP_GLES1_LIBRARIES        )                               # GLESv1 libraries
  34 set(DEQP_SUPPORT_VG                     OFF)                    # Is OpenVG supported
  35 set(DEQP_VG_LIBRARIES           )                               # VG libraries
  36
  37 set(DEQP_SUPPORT_WGL            OFF)
  38 set(DEQP_SUPPORT_GLX            OFF)                    # Is GLX supported \todo [2016-10-12 pyry] X11 specific - move to framework/platform/
  39
  40 set(DEQP_PLATFORM_LIBRARIES     )                               # Other platform libraries
  41
  42 set(DEQP_PLATFORM_COPY_LIBRARIES        )               # Libraries / binaries that need to be copied to binary directory
  43
  44 # Delibs include directories
  45 include_directories(
  46         framework/delibs/debase
  47         framework/delibs/decpp
  48         framework/delibs/depool
  49         framework/delibs/dethread
  50         framework/delibs/deutil
  51         framework/delibs/destream
  52         )
  53
  54 # Include target-specific definitions
  55 include(targets/${DEQP_TARGET}/${DEQP_TARGET}.cmake)
  56
  57 # zlib
  58 find_package(ZLIB)
  59 # dEQP CMake compatibility (as for libpng)
  60 set(ZLIB_INCLUDE_PATH ${ZLIB_INCLUDE_DIRS})
  61 set(ZLIB_LIBRARY ${ZLIB_LIBRARIES})
  62
  63 if (NOT ZLIB_INCLUDE_PATH OR NOT ZLIB_LIBRARY)
  64         message(STATUS "System version of zlib not found, using external/zlib")
  65         add_subdirectory(external/zlib)
  66         # \note ZLIB_LIBRARY and ZLIB_INCLUDE_PATH are promoted from external/zlib/CMakeLists.txt
  67 endif ()
  68
  69 if (EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/external/renderdoc/src/renderdoc_app.h")
  70         message(STATUS "Renderdoc header found, integration enabled")
  71         set(DEQP_HAVE_RENDERDOC_HEADER 1)
  72 else ()
  73         message(STATUS "Renderdoc header not found, integration will not work")
  74 endif ()
  75
  76 include_directories(${ZLIB_INCLUDE_PATH})
  77
  78 # libpng
  79 #
  80 # The FindPNG module defines PNG_INCLUDE_DIRS and PNG_LIBRARIES. But dEQP's
  81 # CMake files expect the non-standard PNG_INCLUDE_PATH and PNG_LIBRARY. Set the
  82 # non-standard variables here to retain compatibility with dEQP's existing
  83 # CMake files.
  84 find_package(PNG)
  85 set(PNG_INCLUDE_PATH ${PNG_INCLUDE_DIRS})
  86 set(PNG_LIBRARY ${PNG_LIBRARIES})
  87
  88 if (NOT PNG_INCLUDE_PATH OR NOT PNG_LIBRARY)
  89         message(STATUS "System version of libpng not found, using external/libpng")
  90         add_subdirectory(external/libpng)
  91         # \note PNG_LIBRARY and PNG_INCLUDE_PATH are promoted from external/libpng/CMakeLists.txt
  92 endif ()
  93
  94 # glslang
  95 add_subdirectory(external/glslang)
  96
  97 # spirv-tools
  98 add_subdirectory(external/spirv-tools)
  99
 100 # spirv-headers
 101 set(SPIRV_INCLUDE_PATH "${PROJECT_SOURCE_DIR}/external/spirv-headers/src/include")
 102 if (NOT EXISTS ${SPIRV_INCLUDE_PATH})
 103         message(FATAL_ERROR "SPIR-V headers not found, please run external/fetch_sources.py")
 104 endif()
 105 include_directories(${SPIRV_INCLUDE_PATH})
 106
 107 # Amber
 108 add_subdirectory(external/amber)
 109 include_directories(external/amber)
 110
 111 # jsoncpp
 112 add_subdirectory(external/jsoncpp)
 113 include_directories(external/jsoncpp/src/include)
 114
 115 # RenderDoc API
 116 include_directories(external/renderdoc/src)
 117
 118 include_directories(${PNG_INCLUDE_PATH})
 119
 120 # DRM (Direct Rendering Manager) Headers
 121 find_path(XF86DRM_H_PATH NAMES xf86drm.h)
 122 find_path(DRM_H_PATH NAMES drm.h PATH_SUFFIXES libdrm drm)
 123
 124 if (XF86DRM_H_PATH AND DRM_H_PATH)
 125         include_directories(${XF86DRM_H_PATH})
 126         include_directories(${DRM_H_PATH})
 127         set(DEQP_SUPPORT_DRM ON CACHE BOOL "Build code requiring the Linux/Unix Direct Rendering Manager")
 128         mark_as_advanced(XF86DRM_H_PATH)
 129         mark_as_advanced(DRM_H_PATH)
 130 else ()
 131         set(DEQP_SUPPORT_DRM OFF CACHE BOOL "Build code requiring the Linux/Unix Direct Rendering Manager")
 132 endif ()
 133
 134 message(STATUS "DEQP_TARGET_NAME        = ${DEQP_TARGET_NAME}")
 135 message(STATUS "DEQP_SUPPORT_GLES1      = ${DEQP_SUPPORT_GLES1}")
 136 message(STATUS "DEQP_GLES1_LIBRARIES    = ${DEQP_GLES1_LIBRARIES}")
 137 message(STATUS "DEQP_GLES2_LIBRARIES    = ${DEQP_GLES2_LIBRARIES}")
 138 message(STATUS "DEQP_GLES3_LIBRARIES    = ${DEQP_GLES3_LIBRARIES}")
 139 message(STATUS "DEQP_GLES31_LIBRARIES   = ${DEQP_GLES31_LIBRARIES}")
 140 message(STATUS "DEQP_GLES32_LIBRARIES   = ${DEQP_GLES32_LIBRARIES}")
 141 message(STATUS "DEQP_SUPPORT_VG         = ${DEQP_SUPPORT_VG}")
 142 message(STATUS "DEQP_VG_LIBRARIES       = ${DEQP_VG_LIBRARIES}")
 143 message(STATUS "DEQP_EGL_LIBRARIES      = ${DEQP_EGL_LIBRARIES}")
 144 message(STATUS "DEQP_PLATFORM_LIBRARIES = ${DEQP_PLATFORM_LIBRARIES}")
 145 message(STATUS "DEQP_SUPPORT_DRM        = ${DEQP_SUPPORT_DRM}")
 146
 147 # Defines
 148 add_definitions(-DDEQP_TARGET_NAME="${DEQP_TARGET_NAME}")
 149
 150 # Entry points loaded directly by linking to libGL*?
 151 if (DEFINED DEQP_GLES2_LIBRARIES)
 152         add_definitions(-DDEQP_GLES2_DIRECT_LINK=1)
 153 endif ()
 154
 155 if (DEFINED DEQP_GLES3_LIBRARIES)
 156         add_definitions(-DDEQP_GLES3_DIRECT_LINK=1)
 157 endif ()
 158
 159 if (DEFINED DEQP_GLES31_LIBRARIES)
 160         add_definitions(-DDEQP_GLES31_DIRECT_LINK=1)
 161 endif ()
 162
 163 if (DEFINED DEQP_GLES32_LIBRARIES)
 164         add_definitions(-DDEQP_GLES32_DIRECT_LINK=1)
 165 endif ()
 166
 167 if (DEFINED DEQP_EGL_LIBRARIES)
 168         add_definitions(-DDEQP_EGL_DIRECT_LINK=1)
 169 endif ()
 170
 171 # Legacy APIs that don't support run-time loading
 172 if (DEQP_SUPPORT_GLES1)
 173         add_definitions(-DDEQP_SUPPORT_GLES1=1)
 174
 175         if (NOT DEFINED DEQP_GLES1_LIBRARIES)
 176                 message(FATAL_ERROR "Run-time loading of GLES1 is not supported (DEQP_GLES1_LIBRARIES is not set)")
 177         endif ()
 178 endif ()
 179
 180 if (DEQP_SUPPORT_VG)
 181         add_definitions(-DDEQP_SUPPORT_VG=1)
 182
 183         if (NOT DEFINED DEQP_VG_LIBRARIES)
 184                 message(FATAL_ERROR "Run-time loading of VG is not supported (DEQP_VG_LIBRARIES is not set)")
 185         endif ()
 186 endif ()
 187
 188 if (DEQP_SUPPORT_DRM)
 189         add_definitions(-DDEQP_SUPPORT_DRM=1)
 190 else ()
 191         add_definitions(-DDEQP_SUPPORT_DRM=0)
 192 endif ()
 193
 194 if (DE_COMPILER_IS_MSC)
 195         # Don't nag about std::copy for example
 196         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -D_SCL_SECURE_NO_WARNINGS")
 197 endif ()
 198
 199 # Precompiled header macro. Parameters are source file list and filename for pch cpp file.
 200 macro(PCH SRCS PCHCPP)
 201   if(MSVC AND CMAKE_GENERATOR MATCHES "^Visual Studio")
 202     set(PCH_NAME "$(IntDir)\\pch.pch")
 203     # make source files use/depend on PCH_NAME
 204     set_source_files_properties(${${SRCS}} PROPERTIES COMPILE_FLAGS "/Yupch.h /FIpch.h /Fp${PCH_NAME}" OBJECT_DEPENDS "${PCH_NAME}")
 205     # make PCHCPP file compile and generate PCH_NAME
 206     set_source_files_properties(${PCHCPP} PROPERTIES COMPILE_FLAGS "/Ycpch.h /Fp${PCH_NAME}" OBJECT_OUTPUTS "${PCH_NAME}")
 207     list(APPEND ${SRCS} "${PCHCPP}")
 208   endif()
 209 endmacro(PCH)
 210
 211 # delibs projects
 212 add_subdirectory(framework/delibs/debase)
 213 add_subdirectory(framework/delibs/depool)
 214 add_subdirectory(framework/delibs/dethread)
 215 add_subdirectory(framework/delibs/destream)
 216 add_subdirectory(framework/delibs/deutil)
 217 add_subdirectory(framework/delibs/decpp)
 218
 219 # ExecServer
 220 add_subdirectory(execserver)
 221
 222 # Executor framework and tools
 223 if (IS_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}/executor)
 224         add_subdirectory(executor)
 225 endif ()
 226
 227 # Test framework include directories
 228 include_directories(
 229         framework/common
 230         framework/qphelper
 231         framework/opengl
 232         framework/opengl/wrapper
 233         framework/referencerenderer
 234         framework/opengl/simplereference
 235         framework/randomshaders
 236         framework/egl
 237         framework/egl/wrapper
 238         framework/xexml
 239         external/vulkancts/framework/vulkan
 240         external/vulkancts/framework/vulkan/generated/vulkan
 241         )
 242
 243 if (DE_OS_IS_ANDROID OR DE_OS_IS_IOS)
 244         # On Android deqp modules are compiled as libraries and linked into final .so
 245         set(DEQP_MODULE_LIBRARIES )
 246         set(DEQP_MODULE_ENTRY_POINTS )
 247 endif ()
 248
 249 # Macro for adding targets for copying binaries (usually target libraries) to the target destination dir
 250 macro (target_copy_files target dep_name files)
 251         if (NOT "${files}" STREQUAL "")
 252                 set(COPY_TARGETS )
 253                 foreach (SRCNAME ${files})
 254                         get_filename_component(BASENAME ${SRCNAME} NAME)
 255                         set(DSTNAME "${CMAKE_CURRENT_BINARY_DIR}/${BASENAME}")
 256                         add_custom_command(OUTPUT ${DSTNAME}
 257                                                            COMMAND ${CMAKE_COMMAND} -E copy_if_different ${SRCNAME} ${DSTNAME})
 258                         set(COPY_TARGETS ${COPY_TARGETS} ${DSTNAME})
 259                 endforeach ()
 260
 261                 add_custom_target(${dep_name} ALL DEPENDS ${COPY_TARGETS})
 262                 add_dependencies(${target} ${dep_name})
 263         endif ()
 264 endmacro (target_copy_files)
 265
 266 set(MODULE_LIB_TARGET_POSTFIX   "-package")
 267 set(MODULE_DATA_TARGET_POSTFIX  "-data")
 268
 269 # Macro for adding dEQP module
 270 # This adds 3 targets:
 271 #       ${MODULE_NAME}-package:         Static library that contains all SRCS and links to LIBS
 272 #       ${MODULE_NAME}-data:            Custom target that is used for data file copies
 273 #       ${MODULE_NAME}:                         Executable binary (if supported by the platform)
 274 macro (add_deqp_module MODULE_NAME SRCS LIBS EXECLIBS ENTRY)
 275
 276         # Library target
 277         add_library("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" STATIC ${SRCS})
 278         target_link_libraries("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" ${LIBS})
 279
 280         set(DEQP_MODULE_LIBRARIES               ${DEQP_MODULE_LIBRARIES} "${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}")
 281         set(DEQP_MODULE_ENTRY_POINTS    ${DEQP_MODULE_ENTRY_POINTS} "${CMAKE_CURRENT_SOURCE_DIR}/${ENTRY}")
 282
 283         # Forward to parent scope
 284         set(DEQP_MODULE_LIBRARIES               ${DEQP_MODULE_LIBRARIES} PARENT_SCOPE)
 285         set(DEQP_MODULE_ENTRY_POINTS    ${DEQP_MODULE_ENTRY_POINTS} PARENT_SCOPE)
 286
 287         if (NOT DE_OS_IS_ANDROID AND NOT DE_OS_IS_IOS)
 288                 # Executable target
 289                 add_executable(${MODULE_NAME} ${PROJECT_SOURCE_DIR}/framework/platform/tcuMain.cpp ${ENTRY})
 290                 target_link_libraries(${MODULE_NAME} PUBLIC "${EXECLIBS}" "${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}")
 291                 target_copy_files(${MODULE_NAME} platform-libs-${MODULE_NAME} "${DEQP_PLATFORM_COPY_LIBRARIES}")
 292         endif ()
 293
 294         # Data file target
 295         add_custom_target("${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}")
 296         add_dependencies("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}")
 297 endmacro (add_deqp_module)
 298
 299 # Macro add_deqp_module_skip_android does not add module to DEQP_MODULE_LIBRARIES, so that it is not created on Android.
 300 # It's a temporary solution to disable Vulkan SC tests on Android, because later defined deqp library
 301 # uses both deqp-vk and deqp-vksc and this means that definitions CTS_USES_VULKAN and CTS_USES_VULKANSC
 302 # exist in deqp library at the same time which causes code to not compile.
 303 macro (add_deqp_module_skip_android MODULE_NAME SRCS LIBS EXECLIBS ENTRY)
 304
 305         # Library target
 306         add_library("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" STATIC ${SRCS})
 307         target_link_libraries("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" ${LIBS})
 308
 309         if (NOT DE_OS_IS_ANDROID AND NOT DE_OS_IS_IOS)
 310                 # Executable target
 311                 add_executable(${MODULE_NAME} ${PROJECT_SOURCE_DIR}/framework/platform/tcuMain.cpp ${ENTRY})
 312                 target_link_libraries(${MODULE_NAME} PUBLIC "${EXECLIBS}" "${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}")
 313                 target_copy_files(${MODULE_NAME} platform-libs-${MODULE_NAME} "${DEQP_PLATFORM_COPY_LIBRARIES}")
 314         endif ()
 315
 316         # Data file target
 317         add_custom_target("${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}")
 318         add_dependencies("${MODULE_NAME}${MODULE_LIB_TARGET_POSTFIX}" "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}")
 319 endmacro (add_deqp_module_skip_android)
 320
 321 # Macro for adding data dirs to module
 322 macro (add_data_dir MODULE_NAME SRC_DIR DST_DIR)
 323         if (DE_OS_IS_WIN32 OR DE_OS_IS_UNIX OR DE_OS_IS_OSX OR DE_OS_IS_QNX)
 324                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_CURRENT_BINARY_DIR}/${DST_DIR})
 325
 326         elseif (DE_OS_IS_ANDROID)
 327                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_BINARY_DIR}/assets/${DST_DIR})
 328
 329         elseif (DE_OS_IS_IOS)
 330                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_directory ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_DIR} ${CMAKE_BINARY_DIR}/\${CONFIGURATION}\${EFFECTIVE_PLATFORM_NAME}/deqp.app/${DST_DIR})
 331         endif ()
 332 endmacro (add_data_dir)
 333
 334 # Macro for adding individual data files to module
 335 macro (add_data_file MODULE_NAME SRC_FILE DST_FILE)
 336         if (DE_OS_IS_WIN32 OR DE_OS_IS_UNIX OR DE_OS_IS_OSX OR DE_OS_IS_QNX)
 337                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_CURRENT_BINARY_DIR}/${DST_FILE})
 338
 339         elseif (DE_OS_IS_ANDROID)
 340                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_BINARY_DIR}/assets/${DST_FILE})
 341
 342         elseif (DE_OS_IS_IOS)
 343                 add_custom_command(TARGET "${MODULE_NAME}${MODULE_DATA_TARGET_POSTFIX}" POST_BUILD COMMAND ${CMAKE_COMMAND} -E copy_if_different ${CMAKE_CURRENT_SOURCE_DIR}/${SRC_FILE} ${CMAKE_BINARY_DIR}/\${CONFIGURATION}\${EFFECTIVE_PLATFORM_NAME}/deqp.app/${DST_FILE})
 344         endif ()
 345 endmacro (add_data_file)
 346
 347 add_subdirectory(framework)
 348 add_subdirectory(external/vulkancts/framework/vulkan)
 349
 350 if (DE_COMPILER_IS_MSC)
 351         add_compile_options(/bigobj) # Required by glsBuiltinPrecisionTests.cpp
 352 endif ()
 353
 354 add_subdirectory(modules)
 355 add_subdirectory(external/vulkancts/modules/vulkan)
 356 add_subdirectory(external/vulkancts/vkscserver)
 357 add_subdirectory(external/vulkancts/vkscpc)
 358 add_subdirectory(external/openglcts)
 359
 360 # Single-binary targets
 361 if (DE_OS_IS_ANDROID)
 362         include_directories(executor)
 363         include_directories(${PROJECT_BINARY_DIR}/external/vulkancts/framework/vulkan)
 364
 365         set(DEQP_SRCS
 366                 framework/platform/android/tcuAndroidMain.cpp
 367                 framework/platform/android/tcuAndroidJNI.cpp
 368                 framework/platform/android/tcuAndroidPlatformCapabilityQueryJNI.cpp
 369                 framework/platform/android/tcuTestLogParserJNI.cpp
 370                 ${DEQP_MODULE_ENTRY_POINTS}
 371                 )
 372
 373         set(DEQP_LIBS
 374                 tcutil-platform
 375                 xecore
 376                 ${DEQP_MODULE_LIBRARIES}
 377                 )
 378
 379         add_library(deqp SHARED ${DEQP_SRCS})
 380         target_link_libraries(deqp ${DEQP_LIBS})
 381
 382         # Separate out the debug information because it's enormous
 383         add_custom_command(TARGET deqp POST_BUILD
 384                 COMMAND ${CMAKE_STRIP} --only-keep-debug -o $<TARGET_FILE:deqp>.debug $<TARGET_FILE:deqp>
 385                 COMMAND ${CMAKE_STRIP} -g $<TARGET_FILE:deqp>)
 386
 387         # Needed by OpenGL CTS that defines its own activity but depends on
 388         # common Android support code.
 389         target_include_directories(deqp PRIVATE framework/platform/android)
 390
 391 elseif (DE_OS_IS_IOS)
 392         # Code sign identity
 393         set(DEQP_IOS_CODE_SIGN_IDENTITY "drawElements" CACHE STRING "Code sign identity for iOS build")
 394
 395         set(MACOSX_BUNDLE_PRODUCT_NAME "\${PRODUCT_NAME}")
 396         set(MACOSX_BUNDLE_GUI_IDENTIFIER "com.drawelements.\${PRODUCT_NAME:identifier}")
 397
 398         include_directories(framework/platform/ios)
 399         set(TESTERCORE_SRC_FILES
 400                 framework/platform/ios/tcuEAGLView.h
 401                 framework/platform/ios/tcuEAGLView.m
 402                 framework/platform/ios/tcuIOSAppDelegate.h
 403                 framework/platform/ios/tcuIOSAppDelegate.m
 404                 framework/platform/ios/tcuIOSViewController.h
 405                 framework/platform/ios/tcuIOSViewController.m
 406                 framework/platform/ios/tcuIOSMain.m
 407                 )
 408         set_source_files_properties(${TESTERCORE_SRC_FILES} COMPILE_FLAGS "-std=c99")
 409
 410         add_executable(deqp MACOSX_BUNDLE ${TESTERCORE_SRC_FILES} ${DEQP_MODULE_ENTRY_POINTS})
 411         target_link_libraries(deqp tcutil-platform xscore ${DEQP_MODULE_LIBRARIES})
 412         set_target_properties(deqp PROPERTIES XCODE_ATTRIBUTE_TARGETED_DEVICE_FAMILY "1,2")
 413         set_target_properties(deqp PROPERTIES XCODE_ATTRIBUTE_CODE_SIGN_IDENTITY "iPhone Developer: ${DEQP_IOS_CODE_SIGN_IDENTITY}")
 414 endif ()