CMakeLists.txt

   1 cmake_minimum_required (VERSION 3.1)
   2
   3 project (OpenCL-ICD-Loader VERSION 1.2)
   4 include (GNUInstallDirs)
   5 find_package (Threads REQUIRED)
   6
   7 # The option below allows building the ICD Loader library as a shared library
   8 # (ON, default) or a static library (OFF).
   9 #
  10 # Khronos OpenCL Working Group strongly recommends building and using the ICD
  11 # loader as a shared library due to the following benefits:
  12 #
  13 # 1. The shared library can be updated independent of the application. This
  14 #    allows releasing new fixes and features in the ICD loader without updating
  15 #    the application.
  16 #
  17 #    In rare cases when there are backward-incompatible changes to the ICD
  18 #    loader (due to platform requirements, for instance), using a shared
  19 #    library allows updating the library to make the transition seamless to
  20 #    installed applications.
  21 #
  22 # 2. On platforms that require the ICD mechanism there are multiple vendors
  23 #    shipping their OpenCL implementations. The vendor installers collaborate
  24 #    to make sure that the installed ICD shared library version is suitable for
  25 #    working with all vendor implementations installed on the system.
  26 #
  27 #    If applications statically link to ICD Loader then that version of the ICD
  28 #    loader may not work with one or more installed vendor implementations.
  29 #
  30 # Using the OpenCL ICD loader as a static library is NOT recommended for
  31 # end-user installations in general. However in some controlled environments it
  32 # may be useful to simplify the build and distribution of the application. E.g.
  33 # in test farms, or in cases where the end-user system configs are known in
  34 # advance. Use it with discretion.
  35 option (BUILD_SHARED_LIBS "Build shared libs" ON)
  36
  37 include(CheckFunctionExists)
  38 check_function_exists(secure_getenv HAVE_SECURE_GETENV)
  39 check_function_exists(__secure_getenv HAVE___SECURE_GETENV)
  40 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/loader/icd_cmake_config.h.in
  41     ${CMAKE_CURRENT_BINARY_DIR}/icd_cmake_config.h)
  42
  43 set (OPENCL_ICD_LOADER_SOURCES
  44     loader/icd.c
  45     loader/icd.h
  46     loader/icd_dispatch.c
  47     loader/icd_dispatch.h
  48     loader/icd_dispatch_generated.c
  49     loader/icd_envvars.h
  50     loader/icd_platform.h)
  51
  52 if (WIN32)
  53     list (APPEND OPENCL_ICD_LOADER_SOURCES
  54         loader/windows/adapter.h
  55         loader/windows/icd_windows.c
  56         loader/windows/icd_windows.h
  57         loader/windows/icd_windows_dxgk.c
  58         loader/windows/icd_windows_dxgk.h
  59         loader/windows/icd_windows_envvars.c
  60         loader/windows/icd_windows_hkr.c
  61         loader/windows/icd_windows_hkr.h
  62         loader/windows/icd_windows_apppackage.cpp
  63         loader/windows/icd_windows_apppackage.h
  64         loader/windows/OpenCL.def
  65         loader/windows/OpenCL.rc)
  66     # Only add the DXSDK include directory if the environment variable is
  67     # defined.  Since the DXSDK has merged into the Windows SDK, this is
  68     # only required in rare cases.
  69     if (DEFINED ENV{DXSDK_DIR} AND NOT (MINGW OR MSYS OR CYGWIN))
  70         include_directories ($ENV{DXSDK_DIR}/Include)
  71     endif ()
  72 else ()
  73     list (APPEND OPENCL_ICD_LOADER_SOURCES
  74         loader/linux/icd_linux.c
  75         loader/linux/icd_linux_envvars.c
  76         loader/linux/icd_exports.map)
  77 endif ()
  78
  79 set (OPENCL_ICD_LOADER_HEADERS_DIR ${CMAKE_CURRENT_SOURCE_DIR}/inc CACHE PATH "Path to OpenCL Headers")
  80
  81 add_library (OpenCL ${OPENCL_ICD_LOADER_SOURCES})
  82 set_target_properties (OpenCL PROPERTIES VERSION "1.2" SOVERSION "1")
  83 target_include_directories(OpenCL SYSTEM PUBLIC ${OPENCL_ICD_LOADER_HEADERS_DIR})
  84
  85 if (WIN32)
  86     target_link_libraries (OpenCL cfgmgr32.lib runtimeobject.lib)
  87
  88     option (OPENCL_ICD_LOADER_DISABLE_OPENCLON12 "Disable support for OpenCLOn12. Support for OpenCLOn12 should only be disabled when building an import lib to link with, and must be enabled when building an ICD loader for distribution!" OFF)
  89     if (OPENCL_ICD_LOADER_DISABLE_OPENCLON12)
  90         target_compile_definitions(OpenCL PRIVATE OPENCL_ICD_LOADER_DISABLE_OPENCLON12)
  91     endif()
  92
  93     if(NOT USE_DYNAMIC_VCXX_RUNTIME)
  94         string(REPLACE "/MD" "/MT" CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS_RELEASE}")
  95         string(REPLACE "/MD" "/MT" CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE}")
  96         string(REPLACE "/MD" "/MT" CMAKE_C_FLAGS_MINSIZEREL "${CMAKE_C_FLAGS_MINSIZEREL}")
  97         string(REPLACE "/MD" "/MT" CMAKE_CXX_FLAGS_MINSIZEREL "${CMAKE_CXX_FLAGS_MINSIZEREL}")
  98         string(REPLACE "/MD" "/MT" CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS_RELWITHDEBINFO}")
  99         string(REPLACE "/MD" "/MT" CMAKE_CXX_FLAGS_RELWITHDEBINFO "${CMAKE_CXX_FLAGS_RELWITHDEBINFO}")
 100         string(REPLACE "/MDd" "/MTd" CMAKE_C_FLAGS_DEBUG "${CMAKE_C_FLAGS_DEBUG}")
 101         string(REPLACE "/MDd" "/MTd" CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG}")
 102     endif()
 103 else()
 104     if (APPLE)
 105         target_link_libraries (OpenCL ${CMAKE_THREAD_LIBS_INIT})
 106     else ()
 107         set_target_properties (OpenCL PROPERTIES LINK_FLAGS "-Wl,--version-script -Wl,${CMAKE_CURRENT_SOURCE_DIR}/loader/linux/icd_exports.map")
 108         if (OPENCL_ICD_LOADER_PIC)
 109             set_target_properties(OpenCL PROPERTIES POSITION_INDEPENDENT_CODE ON)
 110         endif ()
 111         target_link_libraries (OpenCL ${CMAKE_THREAD_LIBS_INIT})
 112     endif ()
 113 endif ()
 114
 115 include_directories (${OPENCL_ICD_LOADER_HEADERS_DIR})
 116 add_definitions (-DCL_TARGET_OPENCL_VERSION=300)
 117
 118 target_include_directories (OpenCL PRIVATE ${CMAKE_CURRENT_BINARY_DIR} loader)
 119 target_link_libraries (OpenCL ${CMAKE_DL_LIBS})
 120
 121 option (OPENCL_ICD_LOADER_BUILD_TESTING "Enable support for OpenCL ICD Loader testing." OFF)
 122
 123 if(CMAKE_PROJECT_NAME STREQUAL PROJECT_NAME OR OPENCL_ICD_LOADER_BUILD_TESTING)
 124     include(CTest)
 125 endif()
 126 if((CMAKE_PROJECT_NAME STREQUAL PROJECT_NAME OR OPENCL_ICD_LOADER_BUILD_TESTING) AND BUILD_TESTING)
 127     add_subdirectory (test)
 128 endif()
 129
 130 install (TARGETS OpenCL
 131     RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
 132     ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
 133     LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR})