CMakeLists.txt

   1 PROJECT (libsolv)
   2
   3 CMAKE_MINIMUM_REQUIRED (VERSION 2.4)
   4
   5 OPTION (ENABLE_STATIC "Build a static version of the libraries?" OFF)
   6 OPTION (DISABLE_SHARED "Do not build a shared version of the libraries?" OFF)
   7
   8 OPTION (ENABLE_PERL "Build the perl bindings?" OFF)
   9 OPTION (ENABLE_PYTHON "Build the python bindings?" OFF)
  10 OPTION (ENABLE_RUBY "Build the ruby bindings?" OFF)
  11
  12 OPTION (USE_VENDORDIRS "Install the bindings in vendor directories?" OFF)
  13
  14 OPTION (ENABLE_RPMDB "Build with rpm database support?" OFF)
  15 OPTION (ENABLE_RPMDB_PUBKEY "Build with rpmdb pubkey support?" OFF)
  16 OPTION (ENABLE_RPMDB_BYRPMHEADER "Build with rpmdb Header support?" OFF)
  17 OPTION (ENABLE_RPMMD "Build with rpmmd repository support?" OFF)
  18 OPTION (ENABLE_SUSEREPO "Build with suse repository support?" OFF)
  19 OPTION (ENABLE_COMPS "Build with fedora comps support?" OFF)
  20 OPTION (ENABLE_HELIXREPO "Build with helix repository support?" OFF)
  21 OPTION (ENABLE_DEBIAN "Build with debian database/repository support?" OFF)
  22 OPTION (ENABLE_MDKREPO "Build with mandriva/mageia repository support?" OFF)
  23 OPTION (ENABLE_ARCHREPO "Build with archlinux repository support?" OFF)
  24 OPTION (ENABLE_CUDFREPO "Build with cudf repository support?" OFF)
  25 OPTION (ENABLE_HAIKU "Build with Haiku package support?" OFF)
  26
  27 OPTION (ENABLE_LZMA_COMPRESSION "Build with lzma/xz compression support?" OFF)
  28 OPTION (ENABLE_BZIP2_COMPRESSION "Build with bzip2 compression support?" OFF)
  29
  30 #IF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERISION} GREATER 2.4)
  31 #ENDIF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERISION} GREATER 2.4)
  32
  33 IF (COMMAND cmake_policy)
  34   # escape preprocessor, see -DVERSION below
  35   CMAKE_POLICY (SET CMP0005 OLD)
  36 ENDIF (COMMAND cmake_policy)
  37
  38 # Library
  39 IF (DEFINED LIB)
  40   SET (LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${LIB}")
  41 ELSE (DEFINED  LIB)
  42   IF (CMAKE_SIZEOF_VOID_P MATCHES "8")
  43     SET (LIB_SUFFIX "64")
  44   ENDIF (CMAKE_SIZEOF_VOID_P MATCHES "8")
  45   SET (LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX}")
  46 ENDIF (DEFINED  LIB)
  47 MESSAGE (STATUS "Libraries will be installed in ${LIB_INSTALL_DIR}")
  48 SET (BIN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/bin")
  49 SET (MAN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/man")
  50
  51 ####################################################################
  52 # CONFIGURATION                                                    #
  53 ####################################################################
  54
  55 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
  56 SET (CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  57 INSTALL( FILES ${CMAKE_MODULE_PATH}/FindLibSolv.cmake DESTINATION ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules )
  58
  59 INCLUDE (${CMAKE_SOURCE_DIR}/VERSION.cmake)
  60
  61 SET (have_system x)
  62
  63 IF (FEDORA)
  64 MESSAGE(STATUS "Building for Fedora")
  65 ADD_DEFINITIONS (-DFEDORA)
  66 SET (ENABLE_RPMDB ON)
  67 SET (ENABLE_RPMMD ON)
  68 SET (have_system ${have_system}x)
  69 ENDIF (FEDORA)
  70
  71 IF (DEBIAN)
  72 MESSAGE (STATUS "Building for Debian")
  73 ADD_DEFINITIONS (-DDEBIAN)
  74 SET (ENABLE_DEBIAN ON)
  75 SET (have_system ${have_system}x)
  76 ENDIF (DEBIAN)
  77
  78 IF (SUSE)
  79 MESSAGE (STATUS "Building for SUSE")
  80 ADD_DEFINITIONS (-DSUSE)
  81 SET (ENABLE_RPMDB ON)
  82 SET (ENABLE_RPMDB_PUBKEY ON)
  83 SET (ENABLE_RPMDB_BYRPMHEADER ON)
  84 SET (ENABLE_RPMMD ON)
  85 SET (ENABLE_SUSEREPO ON)
  86 SET (ENABLE_HELIXREPO ON)
  87 SET (have_system ${have_system}x)
  88 ENDIF (SUSE)
  89
  90 IF (ARCHLINUX)
  91 MESSAGE (STATUS "Building for Archlinux")
  92 ADD_DEFINITIONS (-DARCHLINUX)
  93 SET (ENABLE_ARCHREPO ON)
  94 SET (have_system ${have_system}x)
  95 ENDIF (ARCHLINUX)
  96
  97 IF (MANDRIVA)
  98 MESSAGE (STATUS "Building for Mandriva/Mageia")
  99 ADD_DEFINITIONS (-DMANDRIVA)
 100 SET (ENABLE_MDKREPO ON)
 101 SET (ENABLE_RPMDB ON)
 102 SET (have_system ${have_system}x)
 103 ENDIF (MANDRIVA)
 104
 105 IF (HAIKU)
 106 MESSAGE(STATUS "Building for Haiku")
 107 FIND_LIBRARY(HAIKU_BE_LIBRARY NAMES be)
 108 FIND_LIBRARY(HAIKU_NETWORK_LIBRARY NAMES network)
 109 FIND_LIBRARY(HAIKU_PACKAGE_LIBRARY NAMES package)
 110 SET (HAIKU_SYSTEM_LIBRARIES
 111     ${HAIKU_BE_LIBRARY} ${HAIKU_NETWORK_LIBRARY} ${HAIKU_PACKAGE_LIBRARY})
 112 ADD_DEFINITIONS (-DHAIKU)
 113 SET (ENABLE_HAIKU ON)
 114 SET (have_system ${have_system}x)
 115 ENDIF (HAIKU)
 116
 117 IF (${have_system} STREQUAL x)
 118     MESSAGE (STATUS "Building for no system")
 119     ADD_DEFINITIONS (-DNOSYSTEM)
 120 ENDIF (${have_system} STREQUAL x)
 121 IF (${have_system} STRGREATER xx)
 122     MESSAGE (FATAL_ERROR "Can only compile for one system type.")
 123 ENDIF (${have_system} STRGREATER xx)
 124
 125 IF (ENABLE_ARCHREPO)
 126 SET (ENABLE_LZMA_COMPRESSION ON)
 127 ENDIF (ENABLE_ARCHREPO)
 128
 129 FIND_PACKAGE (EXPAT REQUIRED)
 130 FIND_PACKAGE (ZLIB REQUIRED)
 131 IF (ENABLE_LZMA_COMPRESSION)
 132 FIND_PACKAGE (LZMA REQUIRED)
 133 ENDIF (ENABLE_LZMA_COMPRESSION)
 134 IF (ENABLE_BZIP2_COMPRESSION)
 135 FIND_PACKAGE (BZip2 REQUIRED)
 136 ENDIF (ENABLE_BZIP2_COMPRESSION)
 137
 138 IF (RPM5)
 139 MESSAGE (STATUS "Enabling RPM 5 support")
 140 ADD_DEFINITIONS (-DRPM5)
 141 SET (ENABLE_RPMDB ON)
 142 SET (ENABLE_RPMMD ON)
 143 FIND_PACKAGE (PkgConfig REQUIRED)
 144 PKG_CHECK_MODULES (RPM REQUIRED rpm)
 145 INCLUDE_DIRECTORIES (${RPM_INCLUDE_DIRS})
 146 ENDIF (RPM5)
 147
 148 IF (MULTI_SEMANTICS)
 149 MESSAGE (STATUS "Enabling multi dist support")
 150 ADD_DEFINITIONS (-DMULTI_SEMANTICS)
 151 ENDIF (MULTI_SEMANTICS)
 152
 153 INCLUDE (CheckIncludeFile)
 154 IF (ENABLE_RPMDB)
 155   FIND_LIBRARY (RPMDB_LIBRARY NAMES rpmdb)
 156
 157   IF (NOT RPMDB_LIBRARY)
 158     FIND_LIBRARY (RPMDB_LIBRARY NAMES rpm)
 159   ENDIF (NOT RPMDB_LIBRARY)
 160
 161   FIND_LIBRARY (RPMIO_LIBRARY NAMES rpmio)
 162   IF (RPMIO_LIBRARY)
 163     SET(RPMDB_LIBRARY ${RPMIO_LIBRARY} ${RPMDB_LIBRARY})
 164   ENDIF (RPMIO_LIBRARY)
 165
 166   IF (RPM5)
 167     FIND_LIBRARY (RPMMISC_LIBRARY NAMES rpmmisc)
 168     IF (RPMMISC_LIBRARY)
 169       SET (RPMDB_LIBRARY ${RPMMISC_LIBRARY} ${RPMDB_LIBRARY})
 170     ENDIF (RPMMISC_LIBRARY)
 171   ENDIF (RPM5)
 172
 173   IF (RPM5 OR FEDORA)
 174     FIND_LIBRARY (DB_LIBRARY NAMES db)
 175     IF (DB_LIBRARY)
 176       SET (RPMDB_LIBRARY ${DB_LIBRARY} ${RPMDB_LIBRARY})
 177     ENDIF (DB_LIBRARY)
 178   ENDIF (RPM5 OR FEDORA)
 179   CHECK_INCLUDE_FILE(rpm/db.h HAVE_RPM_DB_H)
 180   INCLUDE (CheckLibraryExists)
 181   CHECK_LIBRARY_EXISTS(rpmio pgpDigGetParams "" HAVE_PGPDIGGETPARAMS)
 182 ENDIF (ENABLE_RPMDB)
 183
 184 INCLUDE (CheckFunctionExists)
 185 INCLUDE (TestBigEndian)
 186
 187 CHECK_FUNCTION_EXISTS (strchrnul HAVE_STRCHRNUL)
 188 CHECK_FUNCTION_EXISTS (fopencookie HAVE_FOPENCOOKIE)
 189 CHECK_FUNCTION_EXISTS (funopen HAVE_FUNOPEN)
 190 TEST_BIG_ENDIAN (WORDS_BIGENDIAN)
 191
 192 # should create config.h with #cmakedefine instead...
 193 FOREACH (VAR HAVE_STRCHRNUL HAVE_FOPENCOOKIE HAVE_FUNOPEN WORDS_BIGENDIAN
 194   HAVE_RPM_DB_H HAVE_PGPDIGGETPARAMS
 195   ENABLE_RPMDB ENABLE_RPMDB_PUBKEY ENABLE_RPMMD ENABLE_SUSEREPO ENABLE_COMPS
 196   ENABLE_HELIXREPO ENABLE_MDKREPO ENABLE_ARCHREPO ENABLE_DEBIAN ENABLE_HAIKU
 197   ENABLE_LZMA_COMPRESSION ENABLE_BZIP2_COMPRESSION)
 198   IF(${VAR})
 199     ADD_DEFINITIONS (-D${VAR}=1)
 200     SET (SWIG_FLAGS ${SWIG_FLAGS} -D${VAR})
 201   ENDIF (${VAR})
 202 ENDFOREACH (VAR)
 203
 204 SET (PACKAGE "libsolv")
 205 SET (VERSION "${LIBSOLV_MAJOR}.${LIBSOLV_MINOR}.${LIBSOLV_PATCH}")
 206
 207 ADD_DEFINITIONS (-D_FILE_OFFSET_BITS=64)
 208 ADD_DEFINITIONS (-DVERSION=\\\"${VERSION}\\\")
 209 CONFIGURE_FILE (src/solvversion.h.in src/solvversion.h)
 210
 211 SET (CPACK_PACKAGE_DESCRIPTION_SUMMARY "Package dependency solver library")
 212 SET (CPACK_PACKAGE_VENDOR "SUSE")
 213 SET (CPACK_PACKAGE_VERSION_MAJOR ${LIBSOLV_MAJOR})
 214 SET (CPACK_PACKAGE_VERSION_MINOR ${LIBSOLV_MINOR})
 215 SET (CPACK_PACKAGE_VERSION_PATCH ${LIBSOLV_PATCH})
 216 SET (CPACK_GENERATOR "TBZ2")
 217 SET (CPACK_SOURCE_GENERATOR "TBZ2")
 218 SET (CPACK_SOURCE_PACKAGE_FILE_NAME "${PACKAGE}-${VERSION}")
 219 SET (CPACK_SOURCE_TOPLEVEL_TAG "Linux-Source:")
 220 SET (CPACK_TOPLEVEL_TAG "Linux-Source:")
 221
 222 # The following components are regex's to match anywhere (unless anchored)
 223 # in absolute path + filename to find files or directories to be excluded
 224 # from source tarball.
 225 SET (CPACK_SOURCE_IGNORE_FILES
 226 # temporary files
 227 "\\\\.swp$"
 228 # backup files
 229 "~$"
 230 # eclipse files
 231 "\\\\.cdtproject$"
 232 "\\\\.cproject$"
 233 "\\\\.project$"
 234 "\\\\.settings/"
 235 # others
 236 "\\\\.#"
 237 "/#"
 238 "/build/"
 239 "/_build/"
 240 "/\\\\.git/"
 241 # used before
 242 "/\\\\.libs/"
 243 "/\\\\.deps/"
 244 "\\\\.o$"
 245 "\\\\.lo$"
 246 "\\\\.la$"
 247 "Makefile$"
 248 "Makefile\\\\.in$"
 249 # cmake cache files
 250 "DartConfiguration.tcl$"
 251 "CMakeCache.txt"
 252 "CMakeFiles"
 253 "cmake_install.cmake$"
 254 "CMakeLists.txt.auto$"
 255 "CTestTestfile.cmake"
 256 "CPackConfig.cmake$"
 257 "CPackSourceConfig.cmake$"
 258 "libsolv.spec$"
 259 )
 260
 261 INCLUDE(CPack)
 262
 263 ####################################################################
 264 # INCLUDES                                                         #
 265 ####################################################################
 266
 267 #SET (CMAKE_INCLUDE_DIRECTORIES_BEFORE ON)
 268 INCLUDE_DIRECTORIES (${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_SOURCE_DIR} ${CMAKE_SOURCE_DIR}/src ${CMAKE_SOURCE_DIR}/ext ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_BINARY_DIR}/src SYSTEM )
 269
 270 ####################################################################
 271
 272 MESSAGE (STATUS "Looking for modules in ${CMAKE_MODULE_PATH}")
 273
 274 set (CMAKE_C_FLAGS     "${CMAKE_C_FLAGS} -Wall")
 275 set (CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS} -O3")
 276 set (CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS} -g -O3")
 277 set (CMAKE_C_FLAGS_DEBUG     "${CMAKE_C_FLAGS} -g3 -O0")
 278
 279 SET (SYSTEM_LIBRARIES "-Wl,--as-needed" ${EXPAT_LIBRARY} ${ZLIB_LIBRARY})
 280 IF (ENABLE_LZMA_COMPRESSION)
 281 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${LZMA_LIBRARY})
 282 ENDIF (ENABLE_LZMA_COMPRESSION)
 283 IF (ENABLE_BZIP2_COMPRESSION)
 284 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${BZIP2_LIBRARIES})
 285 ENDIF (ENABLE_BZIP2_COMPRESSION)
 286 IF (ENABLE_RPMDB)
 287 SET (SYSTEM_LIBRARIES ${RPMDB_LIBRARY} ${SYSTEM_LIBRARIES})
 288 ENDIF (ENABLE_RPMDB)
 289 IF (ENABLE_HAIKU)
 290 SET (SYSTEM_LIBRARIES ${HAIKU_SYSTEM_LIBRARIES} ${SYSTEM_LIBRARIES})
 291 ENDIF (ENABLE_HAIKU)
 292
 293 ADD_SUBDIRECTORY (src)
 294 ADD_SUBDIRECTORY (ext)
 295 ADD_SUBDIRECTORY (tools)
 296 IF (ENABLE_PERL OR ENABLE_PYTHON OR ENABLE_RUBY)
 297     ADD_SUBDIRECTORY (bindings)
 298 ENDIF (ENABLE_PERL OR ENABLE_PYTHON OR ENABLE_RUBY)
 299 ADD_SUBDIRECTORY (examples)
 300 ADD_SUBDIRECTORY (doc)
 301
 302 MESSAGE (STATUS "Version: ${VERSION}")
 303
 304 ####################################################################
 305 # RPM SPEC                                                         #
 306 ####################################################################
 307
 308 MACRO (SPECFILE)
 309   MESSAGE (STATUS "Writing spec file...")
 310   CONFIGURE_FILE (${CMAKE_SOURCE_DIR}/package/libsolv.spec.in ${CMAKE_BINARY_DIR}/package/libsolv.spec @ONLY)
 311 ENDMACRO (SPECFILE)
 312
 313 SPECFILE ()
 314
 315 SET (AUTOBUILD_COMMAND
 316   COMMAND ${CMAKE_COMMAND} -E remove ${CMAKE_BINARY_DIR}/package/*.tar.bz2
 317   COMMAND mkdir -p _CPack_Packages/${CPACK_TOPLEVEL_TAG}
 318   COMMAND ${CMAKE_MAKE_PROGRAM} package_source
 319   COMMAND ${CMAKE_COMMAND} -E copy ${CPACK_SOURCE_PACKAGE_FILE_NAME}.tar.bz2 ${CMAKE_BINARY_DIR}/package
 320   COMMAND ${CMAKE_COMMAND} -E remove ${CPACK_SOURCE_PACKAGE_FILE_NAME}.tar.bz2
 321   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_SOURCE_DIR}/package/libsolv.changes" "${CMAKE_BINARY_DIR}/package/libsolv.changes"
 322 )
 323
 324 ADD_CUSTOM_TARGET (srcpackage
 325   ${AUTOBUILD_COMMAND}
 326 )
 327
 328 ADD_CUSTOM_TARGET (srcpackage_local
 329   ${AUTOBUILD_COMMAND}
 330 )
 331
 332 ENABLE_TESTING()
 333 ADD_SUBDIRECTORY (test)