CMakeLists.txt

   1 PROJECT (libsolv)
   2
   3 CMAKE_MINIMUM_REQUIRED (VERSION 2.4)
   4
   5 OPTION (ENABLE_STATIC "Build a static version of the libraries?" OFF)
   6 OPTION (DISABLE_SHARED "Do not build a shared version of the libraries?" OFF)
   7
   8 OPTION (ENABLE_PERL "Build the perl bindings?" OFF)
   9 OPTION (ENABLE_PYTHON "Build the python bindings?" OFF)
  10 OPTION (ENABLE_RUBY "Build the ruby bindings?" OFF)
  11 OPTION (ENABLE_TCL "Build the Tcl bindings?" OFF)
  12
  13 OPTION (USE_VENDORDIRS "Install the bindings in vendor directories?" OFF)
  14
  15 OPTION (ENABLE_RPMDB "Build with rpm database support?" OFF)
  16 OPTION (ENABLE_PUBKEY "Build with pubkey support?" OFF)
  17 OPTION (ENABLE_RPMDB_BYRPMHEADER "Build with rpmdb Header support?" OFF)
  18 OPTION (ENABLE_RPMMD "Build with rpmmd repository support?" OFF)
  19 OPTION (ENABLE_SUSEREPO "Build with suse repository support?" OFF)
  20 OPTION (ENABLE_COMPS "Build with fedora comps support?" OFF)
  21 OPTION (ENABLE_HELIXREPO "Build with helix repository support?" OFF)
  22 OPTION (ENABLE_DEBIAN "Build with debian database/repository support?" OFF)
  23 OPTION (ENABLE_MDKREPO "Build with mandriva/mageia repository support?" OFF)
  24 OPTION (ENABLE_ARCHREPO "Build with archlinux repository support?" OFF)
  25 OPTION (ENABLE_CUDFREPO "Build with cudf repository support?" OFF)
  26 OPTION (ENABLE_HAIKU "Build with Haiku package support?" OFF)
  27 OPTION (ENABLE_APPDATA "Build with AppStream appdata support?" OFF)
  28
  29 OPTION (MULTI_SEMANTICS "Build with support for multiple distribution types?" OFF)
  30
  31 OPTION (ENABLE_LZMA_COMPRESSION "Build with lzma/xz compression support?" OFF)
  32 OPTION (ENABLE_BZIP2_COMPRESSION "Build with bzip2 compression support?" OFF)
  33
  34 #IF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERISION} GREATER 2.4)
  35 #ENDIF(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERISION} GREATER 2.4)
  36
  37 IF (COMMAND cmake_policy)
  38   # escape preprocessor, see -DVERSION below
  39   CMAKE_POLICY (SET CMP0005 OLD)
  40 ENDIF (COMMAND cmake_policy)
  41
  42 # Library
  43 IF (DEFINED LIB)
  44   SET (LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${LIB}")
  45 ELSE (DEFINED  LIB)
  46   IF (CMAKE_SIZEOF_VOID_P MATCHES "8")
  47     SET (LIB_SUFFIX "64")
  48   ENDIF (CMAKE_SIZEOF_VOID_P MATCHES "8")
  49   SET (LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX}")
  50 ENDIF (DEFINED  LIB)
  51 MESSAGE (STATUS "Libraries will be installed in ${LIB_INSTALL_DIR}")
  52 # Library
  53 IF (DEFINED INCLUDE)
  54   SET (INCLUDE_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${INCLUDE}")
  55 else (DEFINED INCLUDE)
  56   SET (INCLUDE_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/include")
  57 ENDIF (DEFINED  INCLUDE)
  58 MESSAGE (STATUS "Header files will be installed in ${INCLUDE_INSTALL_DIR}")
  59 SET (BIN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/bin")
  60 SET (MAN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/share/man")
  61 IF (IS_DIRECTORY "${CMAKE_INSTALL_PREFIX}/man"  AND NOT IS_DIRECTORY "${CMAKE_INSTALL_PREFIX}/share/man")
  62   SET (MAN_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/man")
  63 ENDIF (IS_DIRECTORY "${CMAKE_INSTALL_PREFIX}/man"  AND NOT IS_DIRECTORY "${CMAKE_INSTALL_PREFIX}/share/man")
  64 MESSAGE(STATUS "Man pages will be installed in ${MAN_INSTALL_DIR}")
  65
  66 ####################################################################
  67 # CONFIGURATION                                                    #
  68 ####################################################################
  69
  70 # where to look first for cmake modules, before ${CMAKE_ROOT}/Modules/ is checked
  71 SET (CMAKE_MODULE_PATH ${CMAKE_SOURCE_DIR}/cmake/modules)
  72 INSTALL( FILES ${CMAKE_MODULE_PATH}/FindLibSolv.cmake DESTINATION ${CMAKE_INSTALL_PREFIX}/share/cmake/Modules )
  73
  74 INCLUDE (${CMAKE_SOURCE_DIR}/VERSION.cmake)
  75
  76 SET (have_system x)
  77
  78 IF (FEDORA)
  79 MESSAGE(STATUS "Building for Fedora")
  80 ADD_DEFINITIONS (-DFEDORA)
  81 SET (ENABLE_RPMDB ON)
  82 SET (ENABLE_RPMMD ON)
  83 SET (have_system ${have_system}x)
  84 ENDIF (FEDORA)
  85
  86 IF (DEBIAN)
  87 MESSAGE (STATUS "Building for Debian")
  88 ADD_DEFINITIONS (-DDEBIAN)
  89 SET (ENABLE_DEBIAN ON)
  90 SET (have_system ${have_system}x)
  91 ENDIF (DEBIAN)
  92
  93 IF (SUSE)
  94 MESSAGE (STATUS "Building for SUSE")
  95 ADD_DEFINITIONS (-DSUSE)
  96 SET (ENABLE_RPMDB ON)
  97 SET (ENABLE_PUBKEY ON)
  98 SET (ENABLE_RPMDB_BYRPMHEADER ON)
  99 SET (ENABLE_RPMMD ON)
 100 SET (ENABLE_SUSEREPO ON)
 101 SET (ENABLE_HELIXREPO ON)
 102 SET (ENABLE_LINKED_PKGS ON)
 103 SET (have_system ${have_system}x)
 104 ENDIF (SUSE)
 105
 106 IF (ARCHLINUX)
 107 MESSAGE (STATUS "Building for Archlinux")
 108 ADD_DEFINITIONS (-DARCHLINUX)
 109 SET (ENABLE_ARCHREPO ON)
 110 SET (have_system ${have_system}x)
 111 ENDIF (ARCHLINUX)
 112
 113 IF (MANDRIVA)
 114 MESSAGE (STATUS "Building for Mandriva")
 115 ADD_DEFINITIONS (-DMANDRIVA)
 116 SET (ENABLE_MDKREPO ON)
 117 SET (ENABLE_RPMDB ON)
 118 SET (have_system ${have_system}x)
 119 ENDIF (MANDRIVA)
 120
 121 IF (MAGEIA)
 122 MESSAGE (STATUS "Building for Mageia")
 123 ADD_DEFINITIONS (-DMAGEIA)
 124 SET (ENABLE_MDKREPO ON)
 125 SET (ENABLE_RPMDB ON)
 126 SET (ENABLE_RPMMD ON)
 127 SET (ENABLE_LZMA_COMPRESSION ON)
 128 SET (have_system ${have_system}x)
 129 ENDIF (MAGEIA)
 130
 131 IF (HAIKU)
 132 MESSAGE(STATUS "Building for Haiku")
 133 FIND_LIBRARY(HAIKU_BE_LIBRARY NAMES be)
 134 FIND_LIBRARY(HAIKU_NETWORK_LIBRARY NAMES network)
 135 FIND_LIBRARY(HAIKU_PACKAGE_LIBRARY NAMES package)
 136 SET (HAIKU_SYSTEM_LIBRARIES
 137     ${HAIKU_BE_LIBRARY} ${HAIKU_NETWORK_LIBRARY} ${HAIKU_PACKAGE_LIBRARY})
 138 ADD_DEFINITIONS (-DHAIKU)
 139 SET (ENABLE_HAIKU ON)
 140 SET (have_system ${have_system}x)
 141 ENDIF (HAIKU)
 142
 143 IF (${have_system} STREQUAL x)
 144     MESSAGE (STATUS "Building for no system")
 145 ENDIF (${have_system} STREQUAL x)
 146 IF (${have_system} STRGREATER xx)
 147     MESSAGE (FATAL_ERROR "Can only compile for one system type.")
 148 ENDIF (${have_system} STRGREATER xx)
 149
 150 IF (ENABLE_ARCHREPO)
 151 SET (ENABLE_LZMA_COMPRESSION ON)
 152 ENDIF (ENABLE_ARCHREPO)
 153
 154 FIND_PACKAGE (EXPAT REQUIRED)
 155 FIND_PACKAGE (ZLIB REQUIRED)
 156 IF (ENABLE_LZMA_COMPRESSION)
 157 FIND_PACKAGE (LZMA REQUIRED)
 158 ENDIF (ENABLE_LZMA_COMPRESSION)
 159 IF (ENABLE_BZIP2_COMPRESSION)
 160 FIND_PACKAGE (BZip2 REQUIRED)
 161 ENDIF (ENABLE_BZIP2_COMPRESSION)
 162
 163 IF (RPM5)
 164 MESSAGE (STATUS "Enabling RPM 5 support")
 165 ADD_DEFINITIONS (-DRPM5)
 166 SET (ENABLE_RPMDB ON)
 167 SET (ENABLE_RPMMD ON)
 168 FIND_PACKAGE (PkgConfig REQUIRED)
 169 PKG_CHECK_MODULES (RPM REQUIRED rpm)
 170 INCLUDE_DIRECTORIES (${RPM_INCLUDE_DIRS})
 171 ENDIF (RPM5)
 172
 173 IF (MULTI_SEMANTICS)
 174 MESSAGE (STATUS "Enabling multi dist support")
 175 ENDIF (MULTI_SEMANTICS)
 176
 177 INCLUDE (CheckIncludeFile)
 178 IF (ENABLE_RPMDB)
 179   FIND_LIBRARY (RPMDB_LIBRARY NAMES rpmdb)
 180
 181   IF (NOT RPMDB_LIBRARY)
 182     FIND_LIBRARY (RPMDB_LIBRARY NAMES rpm)
 183   ENDIF (NOT RPMDB_LIBRARY)
 184
 185   FIND_LIBRARY (RPMIO_LIBRARY NAMES rpmio)
 186   IF (RPMIO_LIBRARY)
 187     SET(RPMDB_LIBRARY ${RPMIO_LIBRARY} ${RPMDB_LIBRARY})
 188   ENDIF (RPMIO_LIBRARY)
 189
 190   IF (RPM5)
 191     FIND_LIBRARY (RPMMISC_LIBRARY NAMES rpmmisc)
 192     IF (RPMMISC_LIBRARY)
 193       SET (RPMDB_LIBRARY ${RPMMISC_LIBRARY} ${RPMDB_LIBRARY})
 194     ENDIF (RPMMISC_LIBRARY)
 195   ENDIF (RPM5)
 196
 197   # check if rpm contains a bundled berkeley db
 198   CHECK_INCLUDE_FILE(rpm/db.h HAVE_RPM_DB_H)
 199   IF (NOT HAVE_RPM_DB_H)
 200     FIND_LIBRARY (DB_LIBRARY NAMES db)
 201     IF (DB_LIBRARY)
 202       SET (RPMDB_LIBRARY ${DB_LIBRARY} ${RPMDB_LIBRARY})
 203     ENDIF (DB_LIBRARY)
 204   ENDIF (NOT HAVE_RPM_DB_H)
 205   INCLUDE (CheckLibraryExists)
 206   CHECK_LIBRARY_EXISTS(rpmio pgpDigGetParams "" HAVE_PGPDIGGETPARAMS)
 207 ENDIF (ENABLE_RPMDB)
 208
 209 IF (ENABLE_PUBKEY)
 210   SET (ENABLE_PGPVRFY ON)
 211 ENDIF (ENABLE_PUBKEY)
 212
 213 INCLUDE (CheckFunctionExists)
 214 INCLUDE (TestBigEndian)
 215
 216 CHECK_FUNCTION_EXISTS (strchrnul HAVE_STRCHRNUL)
 217 CHECK_FUNCTION_EXISTS (fopencookie HAVE_FOPENCOOKIE)
 218 CHECK_FUNCTION_EXISTS (funopen HAVE_FUNOPEN)
 219 TEST_BIG_ENDIAN (WORDS_BIGENDIAN)
 220
 221 IF (${CMAKE_MAJOR_VERSION} GREATER 2)
 222 INCLUDE (CMakePushCheckState)
 223 INCLUDE (CheckCCompilerFlag)
 224 MACRO (check_linker_flag FLAG VAR)
 225         CMAKE_PUSH_CHECK_STATE (RESET)
 226         SET (CMAKE_REQUIRED_FLAGS "${FLAG}")
 227         CHECK_C_COMPILER_FLAG ("" "${VAR}")
 228         CMAKE_POP_CHECK_STATE ()
 229 ENDMACRO (check_linker_flag)
 230 check_linker_flag("-Wl,--as-needed" HAVE_LINKER_AS_NEEDED)
 231 check_linker_flag("-Wl,--version-script=${CMAKE_SOURCE_DIR}/src/libsolv.ver" HAVE_LINKER_VERSION_SCRIPT)
 232 ELSE (${CMAKE_MAJOR_VERSION} GREATER 2)
 233 SET (HAVE_LINKER_AS_NEEDED 1)
 234 SET (HAVE_LINKER_VERSION_SCRIPT 1)
 235 ENDIF (${CMAKE_MAJOR_VERSION} GREATER 2)
 236
 237 # should create config.h with #cmakedefine instead...
 238 FOREACH (VAR HAVE_STRCHRNUL HAVE_FOPENCOOKIE HAVE_FUNOPEN WORDS_BIGENDIAN
 239   HAVE_RPM_DB_H HAVE_PGPDIGGETPARAMS)
 240   IF(${VAR})
 241     ADD_DEFINITIONS (-D${VAR}=1)
 242     SET (SWIG_FLAGS ${SWIG_FLAGS} -D${VAR})
 243   ENDIF (${VAR})
 244 ENDFOREACH (VAR)
 245
 246 FOREACH (VAR
 247   ENABLE_LINKED_PKGS ENABLE_COMPLEX_DEPS MULTI_SEMANTICS)
 248   IF(${VAR})
 249     ADD_DEFINITIONS (-D${VAR}=1)
 250     SET (SWIG_FLAGS ${SWIG_FLAGS} -D${VAR})
 251     STRING(REPLACE ENABLE_ "" VARX ${VAR})
 252     SET (LIBSOLV_FEATURE_${VARX} 1)
 253   ENDIF (${VAR})
 254 ENDFOREACH (VAR)
 255
 256 FOREACH (VAR
 257   ENABLE_RPMDB ENABLE_PUBKEY ENABLE_RPMMD ENABLE_RPMDB_BYRPMHEADER ENABLE_SUSEREPO ENABLE_COMPS
 258   ENABLE_HELIXREPO ENABLE_MDKREPO ENABLE_ARCHREPO ENABLE_DEBIAN ENABLE_HAIKU
 259   ENABLE_LZMA_COMPRESSION ENABLE_BZIP2_COMPRESSION ENABLE_PGPVRFY ENABLE_APPDATA)
 260   IF(${VAR})
 261     ADD_DEFINITIONS (-D${VAR}=1)
 262     SET (SWIG_FLAGS ${SWIG_FLAGS} -D${VAR})
 263     STRING(REPLACE ENABLE_ "" VARX ${VAR})
 264     SET (LIBSOLVEXT_FEATURE_${VARX} 1)
 265   ENDIF (${VAR})
 266 ENDFOREACH (VAR)
 267
 268 SET (PACKAGE "libsolv")
 269 SET (VERSION "${LIBSOLV_MAJOR}.${LIBSOLV_MINOR}.${LIBSOLV_PATCH}")
 270
 271 ADD_DEFINITIONS (-D_FILE_OFFSET_BITS=64)
 272 ADD_DEFINITIONS (-DVERSION=\\\"${VERSION}\\\")
 273 CONFIGURE_FILE (src/solvversion.h.in src/solvversion.h)
 274
 275 SET (CPACK_PACKAGE_DESCRIPTION_SUMMARY "Package dependency solver library")
 276 SET (CPACK_PACKAGE_VENDOR "SUSE")
 277 SET (CPACK_PACKAGE_VERSION_MAJOR ${LIBSOLV_MAJOR})
 278 SET (CPACK_PACKAGE_VERSION_MINOR ${LIBSOLV_MINOR})
 279 SET (CPACK_PACKAGE_VERSION_PATCH ${LIBSOLV_PATCH})
 280 SET (CPACK_GENERATOR "TBZ2")
 281 SET (CPACK_SOURCE_GENERATOR "TBZ2")
 282 SET (CPACK_SOURCE_PACKAGE_FILE_NAME "${PACKAGE}-${VERSION}")
 283 SET (CPACK_SOURCE_TOPLEVEL_TAG "Linux-Source:")
 284 SET (CPACK_TOPLEVEL_TAG "Linux-Source:")
 285
 286 # The following components are regex's to match anywhere (unless anchored)
 287 # in absolute path + filename to find files or directories to be excluded
 288 # from source tarball.
 289 SET (CPACK_SOURCE_IGNORE_FILES
 290 # temporary files
 291 "\\\\.swp$"
 292 # backup files
 293 "~$"
 294 # eclipse files
 295 "\\\\.cdtproject$"
 296 "\\\\.cproject$"
 297 "\\\\.project$"
 298 "\\\\.settings/"
 299 # others
 300 "\\\\.#"
 301 "/#"
 302 "/build/"
 303 "/_build/"
 304 "/\\\\.git/"
 305 # used before
 306 "/\\\\.libs/"
 307 "/\\\\.deps/"
 308 "\\\\.o$"
 309 "\\\\.lo$"
 310 "\\\\.la$"
 311 "Makefile$"
 312 "Makefile\\\\.in$"
 313 # cmake cache files
 314 "DartConfiguration.tcl$"
 315 "CMakeCache.txt"
 316 "CMakeFiles"
 317 "cmake_install.cmake$"
 318 "CMakeLists.txt.auto$"
 319 "CTestTestfile.cmake"
 320 "CPackConfig.cmake$"
 321 "CPackSourceConfig.cmake$"
 322 "libsolv.spec$"
 323 )
 324
 325 INCLUDE(CPack)
 326
 327 ####################################################################
 328 # INCLUDES                                                         #
 329 ####################################################################
 330
 331 #SET (CMAKE_INCLUDE_DIRECTORIES_BEFORE ON)
 332 INCLUDE_DIRECTORIES (${CMAKE_CURRENT_SOURCE_DIR} ${CMAKE_SOURCE_DIR} ${CMAKE_SOURCE_DIR}/src ${CMAKE_SOURCE_DIR}/ext ${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_BINARY_DIR}/src SYSTEM )
 333
 334 ####################################################################
 335
 336 MESSAGE (STATUS "Looking for modules in ${CMAKE_MODULE_PATH}")
 337
 338 set (CMAKE_C_FLAGS     "${CMAKE_C_FLAGS} -Wall")
 339 set (CMAKE_C_FLAGS_RELEASE "${CMAKE_C_FLAGS} -O3")
 340 set (CMAKE_C_FLAGS_RELWITHDEBINFO "${CMAKE_C_FLAGS} -g -O3")
 341 set (CMAKE_C_FLAGS_DEBUG     "${CMAKE_C_FLAGS} -g3 -O0")
 342
 343 SET (SYSTEM_LIBRARIES ${EXPAT_LIBRARY} ${ZLIB_LIBRARY})
 344 IF (ENABLE_LZMA_COMPRESSION)
 345 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${LZMA_LIBRARY})
 346 ENDIF (ENABLE_LZMA_COMPRESSION)
 347 IF (ENABLE_BZIP2_COMPRESSION)
 348 SET (SYSTEM_LIBRARIES ${SYSTEM_LIBRARIES} ${BZIP2_LIBRARIES})
 349 ENDIF (ENABLE_BZIP2_COMPRESSION)
 350 IF (ENABLE_RPMDB)
 351 SET (SYSTEM_LIBRARIES ${RPMDB_LIBRARY} ${SYSTEM_LIBRARIES})
 352 ENDIF (ENABLE_RPMDB)
 353 IF (ENABLE_HAIKU)
 354 SET (SYSTEM_LIBRARIES ${HAIKU_SYSTEM_LIBRARIES} ${SYSTEM_LIBRARIES})
 355 ENDIF (ENABLE_HAIKU)
 356 IF (HAVE_LINKER_AS_NEEDED)
 357 SET (SYSTEM_LIBRARIES "-Wl,--as-needed" ${SYSTEM_LIBRARIES})
 358 ENDIF (HAVE_LINKER_AS_NEEDED)
 359
 360 ADD_SUBDIRECTORY (src)
 361 ADD_SUBDIRECTORY (ext)
 362 ADD_SUBDIRECTORY (tools)
 363 IF (ENABLE_PERL OR ENABLE_PYTHON OR ENABLE_RUBY OR ENABLE_TCL)
 364     ADD_SUBDIRECTORY (bindings)
 365 ENDIF (ENABLE_PERL OR ENABLE_PYTHON OR ENABLE_RUBY OR ENABLE_TCL)
 366 ADD_SUBDIRECTORY (examples)
 367 ADD_SUBDIRECTORY (doc)
 368
 369 MESSAGE (STATUS "Version: ${VERSION}")
 370
 371 ####################################################################
 372 # RPM SPEC                                                         #
 373 ####################################################################
 374
 375 MACRO (SPECFILE)
 376   MESSAGE (STATUS "Writing spec file...")
 377   CONFIGURE_FILE (${CMAKE_SOURCE_DIR}/package/libsolv.spec.in ${CMAKE_BINARY_DIR}/package/libsolv.spec @ONLY)
 378 ENDMACRO (SPECFILE)
 379
 380 MACRO (PCFILE)
 381   MESSAGE (STATUS "Writing pkg-config file...")
 382   CONFIGURE_FILE (${CMAKE_SOURCE_DIR}/libsolv.pc.in ${CMAKE_BINARY_DIR}/libsolv.pc @ONLY)
 383   INSTALL( FILES ${CMAKE_BINARY_DIR}/libsolv.pc DESTINATION ${LIB_INSTALL_DIR}/pkgconfig )
 384 ENDMACRO (PCFILE)
 385
 386 SPECFILE ()
 387 PCFILE ()
 388
 389 SET (AUTOBUILD_COMMAND
 390   COMMAND ${CMAKE_COMMAND} -E remove ${CMAKE_BINARY_DIR}/package/*.tar.bz2
 391   COMMAND mkdir -p _CPack_Packages/${CPACK_TOPLEVEL_TAG}
 392   COMMAND ${CMAKE_MAKE_PROGRAM} package_source
 393   COMMAND ${CMAKE_COMMAND} -E copy ${CPACK_SOURCE_PACKAGE_FILE_NAME}.tar.bz2 ${CMAKE_BINARY_DIR}/package
 394   COMMAND ${CMAKE_COMMAND} -E remove ${CPACK_SOURCE_PACKAGE_FILE_NAME}.tar.bz2
 395   COMMAND ${CMAKE_COMMAND} -E copy "${CMAKE_SOURCE_DIR}/package/libsolv.changes" "${CMAKE_BINARY_DIR}/package/libsolv.changes"
 396 )
 397
 398 ADD_CUSTOM_TARGET (srcpackage
 399   ${AUTOBUILD_COMMAND}
 400 )
 401
 402 ADD_CUSTOM_TARGET (srcpackage_local
 403   ${AUTOBUILD_COMMAND}
 404 )
 405
 406 ENABLE_TESTING()
 407 ADD_SUBDIRECTORY (test)